Pileus Git - ~andy/git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision
   8                 $_q $_authors %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 $ENV{GIT_DIR} ||= '.git';
  13 $Git::SVN::default_repo_id = 'git-svn';
  14 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  15
  16 $Git::SVN::Log::TZ = $ENV{TZ};
  17 $ENV{TZ} = 'UTC';
  18 $| = 1; # unbuffer STDOUT
  19
  20 sub fatal (@) { print STDERR @_; exit 1 }
  21 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  22 require SVN::Ra;
  23 require SVN::Delta;
  24 if ($SVN::Core::VERSION lt '1.1.0') {
  25         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)\n";
  26 }
  27 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  28 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  29 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  30 use Carp qw/croak/;
  31 use IO::File qw//;
  32 use File::Basename qw/dirname basename/;
  33 use File::Path qw/mkpath/;
  34 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev pass_through/;
  35 use IPC::Open3;
  36 use Git;
  37
  38 BEGIN {
  39         my $s;
  40         foreach (qw/command command_oneline command_noisy command_output_pipe
  41                     command_input_pipe command_close_pipe/) {
  42                 $s .= "*SVN::Git::Editor::$_ = *SVN::Git::Fetcher::$_ = ".
  43                       "*Git::SVN::Migration::$_ = ".
  44                       "*Git::SVN::Log::$_ = *Git::SVN::$_ = *$_ = *Git::$_; ";
  45         }
  46         eval $s;
  47 }
  48
  49 my ($SVN);
  50
  51 my $_optimize_commits = 1 unless $ENV{GIT_SVN_NO_OPTIMIZE_COMMITS};
  52 $sha1 = qr/[a-f\d]{40}/;
  53 $sha1_short = qr/[a-f\d]{4,40}/;
  54 my ($_stdin, $_help, $_edit,
  55         $_message, $_file,
  56         $_template, $_shared,
  57         $_version,
  58         $_merge, $_strategy, $_dry_run,
  59         $_prefix);
  60
  61 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  62                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  63                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
  64 my %fc_opts = ( 'follow-parent|follow' => \$Git::SVN::_follow_parent,
  65                 'authors-file|A=s' => \$_authors,
  66                 'repack:i' => \$Git::SVN::_repack,
  67                 'no-metadata' => \$Git::SVN::_no_metadata,
  68                 'quiet|q' => \$_q,
  69                 'repack-flags|repack-args|repack-opts=s' =>
  70                    \$Git::SVN::_repack_flags,
  71                 %remote_opts );
  72
  73 my ($_trunk, $_tags, $_branches);
  74 my %multi_opts = ( 'trunk|T=s' => \$_trunk,
  75                 'tags|t=s' => \$_tags,
  76                 'branches|b=s' => \$_branches );
  77 my %init_opts = ( 'template=s' => \$_template, 'shared' => \$_shared );
  78 my %cmt_opts = ( 'edit|e' => \$_edit,
  79                 'rmdir' => \$SVN::Git::Editor::_rmdir,
  80                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
  81                 'l=i' => \$SVN::Git::Editor::_rename_limit,
  82                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
  83 );
  84
  85 my %cmd = (
  86         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
  87                         { 'revision|r=s' => \$_revision, %fc_opts } ],
  88         init => [ \&cmd_init, "Initialize a repo for tracking" .
  89                           " (requires URL argument)",
  90                           \%init_opts ],
  91         dcommit => [ \&cmd_dcommit,
  92                      'Commit several diffs to merge with upstream',
  93                         { 'merge|m|M' => \$_merge,
  94                           'strategy|s=s' => \$_strategy,
  95                           'dry-run|n' => \$_dry_run,
  96                         %cmt_opts, %fc_opts } ],
  97         'set-tree' => [ \&cmd_set_tree,
  98                         "Set an SVN repository to a git tree-ish",
  99                         { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
 100         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 101                         { 'revision|r=i' => \$_revision } ],
 102         'multi-init' => [ \&cmd_multi_init,
 103                         'Initialize multiple trees (like git-svnimport)',
 104                         { %multi_opts, %init_opts, %remote_opts,
 105                          'revision|r=i' => \$_revision,
 106                          'prefix=s' => \$_prefix,
 107                         } ],
 108         'multi-fetch' => [ \&cmd_multi_fetch,
 109                         'Fetch multiple trees (like git-svnimport)',
 110                         \%fc_opts ],
 111         'migrate' => [ sub { },
 112                        # no-op, we automatically run this anyways,
 113                        'Migrate configuration/metadata/layout from
 114                         previous versions of git-svn',
 115                         \%remote_opts ],
 116         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 117                         { 'limit=i' => \$Git::SVN::Log::limit,
 118                           'revision|r=s' => \$_revision,
 119                           'verbose|v' => \$Git::SVN::Log::verbose,
 120                           'incremental' => \$Git::SVN::Log::incremental,
 121                           'oneline' => \$Git::SVN::Log::oneline,
 122                           'show-commit' => \$Git::SVN::Log::show_commit,
 123                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 124                           'authors-file|A=s' => \$_authors,
 125                           'color' => \$Git::SVN::Log::color,
 126                           'pager=s' => \$Git::SVN::Log::pager,
 127                         } ],
 128         'commit-diff' => [ \&cmd_commit_diff,
 129                            'Commit a diff between two trees',
 130                         { 'message|m=s' => \$_message,
 131                           'file|F=s' => \$_file,
 132                           'revision|r=s' => \$_revision,
 133                         %cmt_opts } ],
 134 );
 135
 136 my $cmd;
 137 for (my $i = 0; $i < @ARGV; $i++) {
 138         if (defined $cmd{$ARGV[$i]}) {
 139                 $cmd = $ARGV[$i];
 140                 splice @ARGV, $i, 1;
 141                 last;
 142         }
 143 };
 144
 145 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 146
 147 read_repo_config(\%opts);
 148 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 149                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 150                     'id|i=s' => \$Git::SVN::default_ref_id,
 151                     'svn-remote|remote|R=s' => \$Git::SVN::default_repo_id);
 152 exit 1 if (!$rv && $cmd ne 'log');
 153
 154 usage(0) if $_help;
 155 version() if $_version;
 156 usage(1) unless defined $cmd;
 157 load_authors() if $_authors;
 158 unless ($cmd =~ /^(?:init|multi-init|commit-diff)$/) {
 159         Git::SVN::Migration::migration_check();
 160 }
 161 Git::SVN::init_vars();
 162 eval {
 163         Git::SVN::verify_remotes_sanity();
 164         $cmd{$cmd}->[0]->(@ARGV);
 165 };
 166 fatal $@ if $@;
 167 exit 0;
 168
 169 ####################### primary functions ######################
 170 sub usage {
 171         my $exit = shift || 0;
 172         my $fd = $exit ? \*STDERR : \*STDOUT;
 173         print $fd <<"";
 174 git-svn - bidirectional operations between a single Subversion tree and git
 175 Usage: $0 <command> [options] [arguments]\n
 176
 177         print $fd "Available commands:\n" unless $cmd;
 178
 179         foreach (sort keys %cmd) {
 180                 next if $cmd && $cmd ne $_;
 181                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 182                 foreach (keys %{$cmd{$_}->[2]}) {
 183                         # prints out arguments as they should be passed:
 184                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 185                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 186                                                         "--$_" : "-$_" }
 187                                                 split /\|/,$_)," $x\n";
 188                 }
 189         }
 190         print $fd <<"";
 191 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 192 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 193 one git repository and want to keep them separate.  See git-svn(1) for more
 194 information.
 195
 196         exit $exit;
 197 }
 198
 199 sub version {
 200         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 201         exit 0;
 202 }
 203
 204 sub do_git_init_db {
 205         unless (-d $ENV{GIT_DIR}) {
 206                 my @init_db = ('init');
 207                 push @init_db, "--template=$_template" if defined $_template;
 208                 push @init_db, "--shared" if defined $_shared;
 209                 command_noisy(@init_db);
 210         }
 211 }
 212
 213 sub cmd_init {
 214         my $url = shift or die "SVN repository location required " .
 215                                 "as a command-line argument\n";
 216         if (my $repo_path = shift) {
 217                 unless (-d $repo_path) {
 218                         mkpath([$repo_path]);
 219                 }
 220                 chdir $repo_path or croak $!;
 221                 $ENV{GIT_DIR} = $repo_path . "/.git";
 222         }
 223         do_git_init_db();
 224
 225         Git::SVN->init($url);
 226 }
 227
 228 sub cmd_fetch {
 229         if (@_) {
 230                 die "Additional fetch arguments are no longer supported.\n",
 231                     "Use --follow-parent if you have moved/copied directories
 232                     instead.\n";
 233         }
 234         my $gs = Git::SVN->new;
 235         $gs->fetch(parse_revision_argument());
 236         if ($gs->{last_commit} && !verify_ref('refs/heads/master^0')) {
 237                 command_noisy(qw(update-ref refs/heads/master),
 238                               $gs->{last_commit});
 239         }
 240 }
 241
 242 sub cmd_set_tree {
 243         my (@commits) = @_;
 244         if ($_stdin || !@commits) {
 245                 print "Reading from stdin...\n";
 246                 @commits = ();
 247                 while (<STDIN>) {
 248                         if (/\b($sha1_short)\b/o) {
 249                                 unshift @commits, $1;
 250                         }
 251                 }
 252         }
 253         my @revs;
 254         foreach my $c (@commits) {
 255                 my @tmp = command('rev-parse',$c);
 256                 if (scalar @tmp == 1) {
 257                         push @revs, $tmp[0];
 258                 } elsif (scalar @tmp > 1) {
 259                         push @revs, reverse(command('rev-list',@tmp));
 260                 } else {
 261                         fatal "Failed to rev-parse $c\n";
 262                 }
 263         }
 264         my $gs = Git::SVN->new;
 265         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 266         $gs->fetch;
 267         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 268                 fatal "There are new revisions that were fetched ",
 269                       "and need to be merged (or acknowledged) ",
 270                       "before committing.\nlast rev: $r_last\n",
 271                       " current: $gs->{last_rev}\n";
 272         }
 273         $gs->set_tree($_) foreach @revs;
 274         print "Done committing ",scalar @revs," revisions to SVN\n";
 275 }
 276
 277 sub cmd_dcommit {
 278         my $head = shift;
 279         my $gs = Git::SVN->new;
 280         $head ||= 'HEAD';
 281         my @refs = command(qw/rev-list --no-merges/, $gs->refname."..$head");
 282         my $last_rev;
 283         foreach my $d (reverse @refs) {
 284                 if (!verify_ref("$d~1")) {
 285                         fatal "Commit $d\n",
 286                               "has no parent commit, and therefore ",
 287                               "nothing to diff against.\n",
 288                               "You should be working from a repository ",
 289                               "originally created by git-svn\n";
 290                 }
 291                 unless (defined $last_rev) {
 292                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 293                         unless (defined $last_rev) {
 294                                 fatal "Unable to extract revision information ",
 295                                       "from commit $d~1\n";
 296                         }
 297                 }
 298                 if ($_dry_run) {
 299                         print "diff-tree $d~1 $d\n";
 300                 } else {
 301                         my %ed_opts = ( r => $last_rev,
 302                                         log => get_commit_entry($d)->{log},
 303                                         ra => $gs->ra,
 304                                         tree_a => "$d~1",
 305                                         tree_b => $d,
 306                                         editor_cb => sub {
 307                                                print "Committed r$_[0]\n";
 308                                                $last_rev = $_[0]; },
 309                                         svn_path => $gs->{path} );
 310                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 311                                 print "No changes\n$d~1 == $d\n";
 312                         }
 313                 }
 314         }
 315         return if $_dry_run;
 316         $gs->fetch;
 317         # we always want to rebase against the current HEAD, not any
 318         # head that was passed to us
 319         my @diff = command('diff-tree', 'HEAD', $gs->refname, '--');
 320         my @finish;
 321         if (@diff) {
 322                 @finish = qw/rebase/;
 323                 push @finish, qw/--merge/ if $_merge;
 324                 push @finish, "--strategy=$_strategy" if $_strategy;
 325                 print STDERR "W: HEAD and ", $gs->refname, " differ, ",
 326                              "using @finish:\n", "@diff";
 327         } else {
 328                 print "No changes between current HEAD and ",
 329                       $gs->refname, "\nResetting to the latest ",
 330                       $gs->refname, "\n";
 331                 @finish = qw/reset --mixed/;
 332         }
 333         command_noisy(@finish, $gs->refname);
 334 }
 335
 336 sub cmd_show_ignore {
 337         my $gs = Git::SVN->new;
 338         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 339         $gs->traverse_ignore(\*STDOUT, '', $r);
 340 }
 341
 342 sub cmd_multi_init {
 343         my $url = shift;
 344         unless (defined $_trunk || defined $_branches || defined $_tags) {
 345                 usage(1);
 346         }
 347         do_git_init_db();
 348         $_prefix = '' unless defined $_prefix;
 349         $url =~ s#/+$## if defined $url;
 350         if (defined $_trunk) {
 351                 my $trunk_ref = $_prefix . 'trunk';
 352                 # try both old-style and new-style lookups:
 353                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 354                 unless ($gs_trunk) {
 355                         my ($trunk_url, $trunk_path) =
 356                                               complete_svn_url($url, $_trunk);
 357                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 358                                                    undef, $trunk_ref);
 359                 }
 360         }
 361         return unless defined $_branches || defined $_tags;
 362         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 363         complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
 364         complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
 365 }
 366
 367 sub cmd_multi_fetch {
 368         my $remotes = Git::SVN::read_all_remotes();
 369         foreach my $repo_id (sort keys %$remotes) {
 370                 my $url = $remotes->{$repo_id}->{url} or next;
 371                 my $fetch = $remotes->{$repo_id}->{fetch} or next;
 372                 Git::SVN::fetch_all($repo_id, $url, $fetch);
 373         }
 374 }
 375
 376 # this command is special because it requires no metadata
 377 sub cmd_commit_diff {
 378         my ($ta, $tb, $url) = @_;
 379         my $usage = "Usage: $0 commit-diff -r<revision> ".
 380                     "<tree-ish> <tree-ish> [<URL>]\n";
 381         fatal($usage) if (!defined $ta || !defined $tb);
 382         my $svn_path;
 383         if (!defined $url) {
 384                 my $gs = eval { Git::SVN->new };
 385                 if (!$gs) {
 386                         fatal("Needed URL or usable git-svn --id in ",
 387                               "the command-line\n", $usage);
 388                 }
 389                 $url = $gs->{url};
 390                 $svn_path = $gs->{path};
 391         }
 392         unless (defined $_revision) {
 393                 fatal("-r|--revision is a required argument\n", $usage);
 394         }
 395         if (defined $_message && defined $_file) {
 396                 fatal("Both --message/-m and --file/-F specified ",
 397                       "for the commit message.\n",
 398                       "I have no idea what you mean\n");
 399         }
 400         if (defined $_file) {
 401                 $_message = file_to_s($_file);
 402         } else {
 403                 $_message ||= get_commit_entry($tb)->{log};
 404         }
 405         my $ra ||= Git::SVN::Ra->new($url);
 406         $svn_path ||= $ra->{svn_path};
 407         my $r = $_revision;
 408         if ($r eq 'HEAD') {
 409                 $r = $ra->get_latest_revnum;
 410         } elsif ($r !~ /^\d+$/) {
 411                 die "revision argument: $r not understood by git-svn\n";
 412         }
 413         my %ed_opts = ( r => $r,
 414                         log => $_message,
 415                         ra => $ra,
 416                         tree_a => $ta,
 417                         tree_b => $tb,
 418                         editor_cb => sub { print "Committed r$_[0]\n" },
 419                         svn_path => $svn_path );
 420         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 421                 print "No changes\n$ta == $tb\n";
 422         }
 423 }
 424
 425 ########################### utility functions #########################
 426
 427 sub parse_revision_argument {
 428         if (!defined $_revision || $_revision eq 'BASE:HEAD') {
 429                 return (undef, undef);
 430         }
 431         return ($1, $2) if ($_revision =~ /^(\d+):(\d+)$/);
 432         return ($_revision, $_revision) if ($_revision =~ /^\d+$/);
 433         return (undef, $1) if ($_revision =~ /^BASE:(\d+)$/);
 434         return ($1, undef) if ($_revision =~ /^(\d+):HEAD$/);
 435         die "revision argument: $_revision not understood by git-svn\n",
 436             "Try using the command-line svn client instead\n";
 437 }
 438
 439 sub complete_svn_url {
 440         my ($url, $path) = @_;
 441         $path =~ s#/+$##;
 442         if ($path !~ m#^[a-z\+]+://#) {
 443                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
 444                         fatal("E: '$path' is not a complete URL ",
 445                               "and a separate URL is not specified\n");
 446                 }
 447                 return ($url, $path);
 448         }
 449         return ($path, '');
 450 }
 451
 452 sub complete_url_ls_init {
 453         my ($ra, $repo_path, $switch, $pfx) = @_;
 454         unless ($repo_path) {
 455                 print STDERR "W: $switch not specified\n";
 456                 return;
 457         }
 458         $repo_path =~ s#/+$##;
 459         if ($repo_path =~ m#^[a-z\+]+://#) {
 460                 $ra = Git::SVN::Ra->new($repo_path);
 461                 $repo_path = '';
 462         } else {
 463                 $repo_path =~ s#^/+##;
 464                 unless ($ra) {
 465                         fatal("E: '$repo_path' is not a complete URL ",
 466                               "and a separate URL is not specified\n");
 467                 }
 468         }
 469         my $r = defined $_revision ? $_revision : $ra->get_latest_revnum;
 470         my ($dirent, undef, undef) = $ra->get_dir($repo_path, $r);
 471         my $url = $ra->{url};
 472         my $remote_id;
 473         my $remote_path;
 474         foreach my $d (sort keys %$dirent) {
 475                 next if ($dirent->{$d}->kind != $SVN::Node::dir);
 476                 my $path =  "$repo_path/$d";
 477                 my $ref = "$pfx$d";
 478                 my $gs = eval { Git::SVN->new($ref) };
 479                 # don't try to init already existing refs
 480                 unless ($gs) {
 481                         print "init $url/$path => $ref\n";
 482                         $gs = Git::SVN->init($url, $path, undef, $ref);
 483                 }
 484                 $remote_id ||= $gs->{repo_id} if $gs;
 485         }
 486         if (defined $remote_id) {
 487                 $remote_path = "$ra->{svn_path}/$repo_path/*";
 488                 $remote_path =~ s#/+#/#g;
 489                 $remote_path =~ s#^/##g;
 490                 my ($n) = ($switch =~ /^--(\w+)/);
 491                 command_noisy('config', "svn-remote.$remote_id.$n",
 492                                         $remote_path);
 493         }
 494 }
 495
 496 sub verify_ref {
 497         my ($ref) = @_;
 498         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
 499                                { STDERR => 0 }); };
 500 }
 501
 502 sub get_tree_from_treeish {
 503         my ($treeish) = @_;
 504         # $treeish can be a symbolic ref, too:
 505         my $type = command_oneline(qw/cat-file -t/, $treeish);
 506         my $expected;
 507         while ($type eq 'tag') {
 508                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
 509         }
 510         if ($type eq 'commit') {
 511                 $expected = (grep /^tree /, command(qw/cat-file commit/,
 512                                                     $treeish))[0];
 513                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
 514                 die "Unable to get tree from $treeish\n" unless $expected;
 515         } elsif ($type eq 'tree') {
 516                 $expected = $treeish;
 517         } else {
 518                 die "$treeish is a $type, expected tree, tag or commit\n";
 519         }
 520         return $expected;
 521 }
 522
 523 sub get_commit_entry {
 524         my ($treeish) = shift;
 525         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
 526         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
 527         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
 528         open my $log_fh, '>', $commit_editmsg or croak $!;
 529
 530         my $type = command_oneline(qw/cat-file -t/, $treeish);
 531         if ($type eq 'commit' || $type eq 'tag') {
 532                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
 533                                                          $type, $treeish);
 534                 my $in_msg = 0;
 535                 while (<$msg_fh>) {
 536                         if (!$in_msg) {
 537                                 $in_msg = 1 if (/^\s*$/);
 538                         } elsif (/^git-svn-id: /) {
 539                                 # skip this for now, we regenerate the
 540                                 # correct one on re-fetch anyways
 541                                 # TODO: set *:merge properties or like...
 542                         } else {
 543                                 print $log_fh $_ or croak $!;
 544                         }
 545                 }
 546                 command_close_pipe($msg_fh, $ctx);
 547         }
 548         close $log_fh or croak $!;
 549
 550         if ($_edit || ($type eq 'tree')) {
 551                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
 552                 # TODO: strip out spaces, comments, like git-commit.sh
 553                 system($editor, $commit_editmsg);
 554         }
 555         rename $commit_editmsg, $commit_msg or croak $!;
 556         open $log_fh, '<', $commit_msg or croak $!;
 557         { local $/; chomp($log_entry{log} = <$log_fh>); }
 558         close $log_fh or croak $!;
 559         unlink $commit_msg;
 560         \%log_entry;
 561 }
 562
 563 sub s_to_file {
 564         my ($str, $file, $mode) = @_;
 565         open my $fd,'>',$file or croak $!;
 566         print $fd $str,"\n" or croak $!;
 567         close $fd or croak $!;
 568         chmod ($mode &~ umask, $file) if (defined $mode);
 569 }
 570
 571 sub file_to_s {
 572         my $file = shift;
 573         open my $fd,'<',$file or croak "$!: file: $file\n";
 574         local $/;
 575         my $ret = <$fd>;
 576         close $fd or croak $!;
 577         $ret =~ s/\s*$//s;
 578         return $ret;
 579 }
 580
 581 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
 582 sub load_authors {
 583         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
 584         my $log = $cmd eq 'log';
 585         while (<$authors>) {
 586                 chomp;
 587                 next unless /^(\S+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
 588                 my ($user, $name, $email) = ($1, $2, $3);
 589                 if ($log) {
 590                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
 591                 } else {
 592                         $users{$user} = [$name, $email];
 593                 }
 594         }
 595         close $authors or croak $!;
 596 }
 597
 598 # convert GetOpt::Long specs for use by git-config
 599 sub read_repo_config {
 600         return unless -d $ENV{GIT_DIR};
 601         my $opts = shift;
 602         foreach my $o (keys %$opts) {
 603                 my $v = $opts->{$o};
 604                 my ($key) = ($o =~ /^([a-z\-]+)/);
 605                 $key =~ s/-//g;
 606                 my $arg = 'git-config';
 607                 $arg .= ' --int' if ($o =~ /[:=]i$/);
 608                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
 609                 if (ref $v eq 'ARRAY') {
 610                         chomp(my @tmp = `$arg --get-all svn.$key`);
 611                         @$v = @tmp if @tmp;
 612                 } else {
 613                         chomp(my $tmp = `$arg --get svn.$key`);
 614                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
 615                                 $$v = $tmp;
 616                         }
 617                 }
 618         }
 619 }
 620
 621 sub extract_metadata {
 622         my $id = shift or return (undef, undef, undef);
 623         my ($url, $rev, $uuid) = ($id =~ /^git-svn-id:\s(\S+?)\@(\d+)
 624                                                         \s([a-f\d\-]+)$/x);
 625         if (!defined $rev || !$uuid || !$url) {
 626                 # some of the original repositories I made had
 627                 # identifiers like this:
 628                 ($rev, $uuid) = ($id =~/^git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
 629         }
 630         return ($url, $rev, $uuid);
 631 }
 632
 633 sub cmt_metadata {
 634         return extract_metadata((grep(/^git-svn-id: /,
 635                 command(qw/cat-file commit/, shift)))[-1]);
 636 }
 637
 638 package Git::SVN;
 639 use strict;
 640 use warnings;
 641 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
 642             $_repack $_repack_flags/;
 643 use Carp qw/croak/;
 644 use File::Path qw/mkpath/;
 645 use File::Copy qw/copy/;
 646 use IPC::Open3;
 647
 648 my $_repack_nr;
 649 # properties that we do not log:
 650 my %SKIP_PROP;
 651 BEGIN {
 652         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
 653                                         svn:special svn:executable
 654                                         svn:entry:committed-rev
 655                                         svn:entry:last-author
 656                                         svn:entry:uuid
 657                                         svn:entry:committed-date/;
 658 }
 659
 660 my %LOCKFILES;
 661 END { unlink keys %LOCKFILES if %LOCKFILES }
 662
 663 sub fetch_all {
 664         my ($repo_id, $url, $fetch) = @_;
 665         my @gs;
 666         my $ra = Git::SVN::Ra->new($url);
 667         my $head = $ra->get_latest_revnum;
 668         my $base = $head;
 669         foreach my $p (sort keys %$fetch) {
 670                 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
 671                 my $lr = $gs->rev_db_max;
 672                 if (defined $lr) {
 673                         $base = $lr if ($lr < $base);
 674                 }
 675                 push @gs, $gs;
 676         }
 677         return if (++$base > $head);
 678         $ra->gs_fetch_loop_common($base, $head, @gs);
 679 }
 680
 681 sub read_all_remotes {
 682         my $r = {};
 683         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
 684                 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
 685                         $r->{$1}->{fetch}->{$2} = $3;
 686                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
 687                         $r->{$1}->{url} = $2;
 688                 }
 689         }
 690         $r;
 691 }
 692
 693 sub init_vars {
 694         if (defined $_repack) {
 695                 $_repack = 1000 if ($_repack <= 0);
 696                 $_repack_nr = $_repack;
 697                 $_repack_flags ||= '-d';
 698         }
 699 }
 700
 701 sub verify_remotes_sanity {
 702         return unless -d $ENV{GIT_DIR};
 703         my %seen;
 704         foreach (command(qw/config -l/)) {
 705                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
 706                         if ($seen{$1}) {
 707                                 die "Remote ref refs/remote/$1 is tracked by",
 708                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
 709                                     "Please resolve this ambiguity in ",
 710                                     "your git configuration file before ",
 711                                     "continuing\n";
 712                         }
 713                         $seen{$1} = $_;
 714                 }
 715         }
 716 }
 717
 718 # we allow more chars than remotes2config.sh...
 719 sub sanitize_remote_name {
 720         my ($name) = @_;
 721         $name =~ tr{A-Za-z0-9:,/+-}{.}c;
 722         $name;
 723 }
 724
 725 sub find_existing_remote {
 726         my ($url, $remotes) = @_;
 727         my $existing;
 728         foreach my $repo_id (keys %$remotes) {
 729                 my $u = $remotes->{$repo_id}->{url} or next;
 730                 next if $u ne $url;
 731                 $existing = $repo_id;
 732                 last;
 733         }
 734         $existing;
 735 }
 736
 737 sub init_remote_config {
 738         my ($self, $url, $no_write) = @_;
 739         $url =~ s!/+$!!; # strip trailing slash
 740         my $r = read_all_remotes();
 741         my $existing = find_existing_remote($url, $r);
 742         if ($existing) {
 743                 print STDERR "Using existing ",
 744                              "[svn-remote \"$existing\"]\n";
 745                 $self->{repo_id} = $existing;
 746         } else {
 747                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
 748                 $existing = find_existing_remote($min_url, $r);
 749                 if ($existing) {
 750                         print STDERR "Using existing ",
 751                                      "[svn-remote \"$existing\"]\n";
 752                         $self->{repo_id} = $existing;
 753                 }
 754                 if ($min_url ne $url) {
 755                         print STDERR "Using higher level of URL: ",
 756                                      "$url => $min_url\n";
 757                         my $old_path = $self->{path};
 758                         $self->{path} = $url;
 759                         $self->{path} =~ s!^\Q$min_url\E/*!!;
 760                         if (length $old_path) {
 761                                 $self->{path} .= "/$old_path";
 762                         }
 763                         $url = $min_url;
 764                 }
 765         }
 766         my $orig_url;
 767         if (!$existing) {
 768                 # verify that we aren't overwriting anything:
 769                 $orig_url = eval {
 770                         command_oneline('config', '--get',
 771                                         "svn-remote.$self->{repo_id}.url")
 772                 };
 773                 if ($orig_url && ($orig_url ne $url)) {
 774                         die "svn-remote.$self->{repo_id}.url already set: ",
 775                             "$orig_url\nwanted to set to: $url\n";
 776                 }
 777         }
 778         my ($xrepo_id, $xpath) = find_ref($self->refname);
 779         if (defined $xpath) {
 780                 die "svn-remote.$xrepo_id.fetch already set to track ",
 781                     "$xpath:refs/remotes/", $self->refname, "\n";
 782         }
 783         unless ($no_write) {
 784                 command_noisy('config',
 785                               "svn-remote.$self->{repo_id}.url", $url);
 786                 command_noisy('config', '--add',
 787                               "svn-remote.$self->{repo_id}.fetch",
 788                               "$self->{path}:".$self->refname);
 789         }
 790         $self->{url} = $url;
 791 }
 792
 793 sub init {
 794         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
 795         my $self = _new($class, $repo_id, $ref_id, $path);
 796         if (defined $url) {
 797                 $self->init_remote_config($url, $no_write);
 798         }
 799         $self;
 800 }
 801
 802 sub find_ref {
 803         my ($ref_id) = @_;
 804         foreach (command(qw/config -l/)) {
 805                 next unless m!^svn-remote\.(.+)\.fetch=
 806                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
 807                 my ($repo_id, $path, $ref) = ($1, $2, $3);
 808                 if ($ref eq $ref_id) {
 809                         $path = '' if ($path =~ m#^\./?#);
 810                         return ($repo_id, $path);
 811                 }
 812         }
 813         (undef, undef, undef);
 814 }
 815
 816 sub new {
 817         my ($class, $ref_id, $repo_id, $path) = @_;
 818         if (defined $ref_id && !defined $repo_id && !defined $path) {
 819                 ($repo_id, $path) = find_ref($ref_id);
 820                 if (!defined $repo_id) {
 821                         die "Could not find a \"svn-remote.*.fetch\" key ",
 822                             "in the repository configuration matching: ",
 823                             "refs/remotes/$ref_id\n";
 824                 }
 825         }
 826         my $self = _new($class, $repo_id, $ref_id, $path);
 827         if (!defined $self->{path} || !length $self->{path}) {
 828                 my $fetch = command_oneline('config', '--get',
 829                                             "svn-remote.$repo_id.fetch",
 830                                             ":refs/remotes/$ref_id\$") or
 831                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
 832                          "\":refs/remotes/$ref_id\$\" in config\n";
 833                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
 834         }
 835         $self->{url} = command_oneline('config', '--get',
 836                                        "svn-remote.$repo_id.url") or
 837                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
 838         if (-z $self->{db_path} && ::verify_ref($self->refname.'^0')) {
 839                 $self->rebuild;
 840         }
 841         $self;
 842 }
 843
 844 sub refname { "refs/remotes/$_[0]->{ref_id}" }
 845
 846 sub ra {
 847         my ($self) = shift;
 848         Git::SVN::Ra->new($self->{url});
 849 }
 850
 851 sub rel_path {
 852         my ($self) = @_;
 853         my $repos_root = $self->ra->{repos_root};
 854         return $self->{path} if ($self->{url} eq $repos_root);
 855         my $url = $self->{url} .
 856                   (length $self->{path} ? "/$self->{path}" : $self->{path});
 857         $url =~ s!^\Q$repos_root\E/*!!g;
 858         $url;
 859 }
 860
 861 sub traverse_ignore {
 862         my ($self, $fh, $path, $r) = @_;
 863         $path =~ s#^/+##g;
 864         my $ra = $self->ra;
 865         my ($dirent, undef, $props) = $ra->get_dir($path, $r);
 866         my $p = $path;
 867         $p =~ s#^\Q$ra->{svn_path}\E/##;
 868         print $fh length $p ? "\n# $p\n" : "\n# /\n";
 869         if (my $s = $props->{'svn:ignore'}) {
 870                 $s =~ s/[\r\n]+/\n/g;
 871                 chomp $s;
 872                 if (length $p == 0) {
 873                         $s =~ s#\n#\n/$p#g;
 874                         print $fh "/$s\n";
 875                 } else {
 876                         $s =~ s#\n#\n/$p/#g;
 877                         print $fh "/$p/$s\n";
 878                 }
 879         }
 880         foreach (sort keys %$dirent) {
 881                 next if $dirent->{$_}->kind != $SVN::Node::dir;
 882                 $self->traverse_ignore($fh, "$path/$_", $r);
 883         }
 884 }
 885
 886 sub last_rev { ($_[0]->last_rev_commit)[0] }
 887 sub last_commit { ($_[0]->last_rev_commit)[1] }
 888
 889 # returns the newest SVN revision number and newest commit SHA1
 890 sub last_rev_commit {
 891         my ($self) = @_;
 892         if (defined $self->{last_rev} && defined $self->{last_commit}) {
 893                 return ($self->{last_rev}, $self->{last_commit});
 894         }
 895         my $c = ::verify_ref($self->refname.'^0');
 896         if ($c) {
 897                 my $rev = (::cmt_metadata($c))[1];
 898                 if (defined $rev) {
 899                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
 900                         return ($rev, $c);
 901                 }
 902         }
 903         my $offset = -41; # from tail
 904         my $rl;
 905         open my $fh, '<', $self->{db_path} or
 906                                  croak "$self->{db_path} not readable: $!\n";
 907         sysseek($fh, $offset, 2); # don't care for errors
 908         sysread($fh, $rl, 41) == 41 or return (undef, undef);
 909         chomp $rl;
 910         while (('0' x40) eq $rl && sysseek($fh, 0, 1) != 0) {
 911                 $offset -= 41;
 912                 sysseek($fh, $offset, 2); # don't care for errors
 913                 sysread($fh, $rl, 41) == 41 or return (undef, undef);
 914                 chomp $rl;
 915         }
 916         if ($c) {
 917                 die "$self->{db_path} and ", $self->refname,
 918                     " inconsistent!:\n$c != $rl\n";
 919         }
 920         my $rev = sysseek($fh, 0, 1) or croak $!;
 921         $rev =  ($rev - 41) / 41;
 922         close $fh or croak $!;
 923         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
 924         return ($rev, $c);
 925 }
 926
 927 sub get_fetch_range {
 928         my ($self, $min, $max) = @_;
 929         $max ||= $self->ra->get_latest_revnum;
 930         $min ||= $self->rev_db_max;
 931         (++$min, $max);
 932 }
 933
 934 sub tmp_index_do {
 935         my ($self, $sub) = @_;
 936         my $old_index = $ENV{GIT_INDEX_FILE};
 937         $ENV{GIT_INDEX_FILE} = $self->{index};
 938         my @ret = &$sub;
 939         if ($old_index) {
 940                 $ENV{GIT_INDEX_FILE} = $old_index;
 941         } else {
 942                 delete $ENV{GIT_INDEX_FILE};
 943         }
 944         wantarray ? @ret : $ret[0];
 945 }
 946
 947 sub assert_index_clean {
 948         my ($self, $treeish) = @_;
 949
 950         $self->tmp_index_do(sub {
 951                 command_noisy('read-tree', $treeish) unless -e $self->{index};
 952                 my $x = command_oneline('write-tree');
 953                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
 954                            /^tree ($::sha1)/mo);
 955                 if ($y ne $x) {
 956                         unlink $self->{index} or croak $!;
 957                         command_noisy('read-tree', $treeish);
 958                 }
 959                 $x = command_oneline('write-tree');
 960                 if ($y ne $x) {
 961                         ::fatal "trees ($treeish) $y != $x\n",
 962                                 "Something is seriously wrong...\n";
 963                 }
 964         });
 965 }
 966
 967 sub get_commit_parents {
 968         my ($self, $log_entry) = @_;
 969         my (%seen, @ret, @tmp);
 970         # legacy support for 'set-tree'; this is only used by set_tree_cb:
 971         if (my $ip = $self->{inject_parents}) {
 972                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
 973                         push @tmp, $commit;
 974                 }
 975         }
 976         if (my $cur = ::verify_ref($self->refname.'^0')) {
 977                 push @tmp, $cur;
 978         }
 979         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
 980         while (my $p = shift @tmp) {
 981                 next if $seen{$p};
 982                 $seen{$p} = 1;
 983                 push @ret, $p;
 984                 # MAXPARENT is defined to 16 in commit-tree.c:
 985                 last if @ret >= 16;
 986         }
 987         if (@tmp) {
 988                 die "r$log_entry->{revision}: No room for parents:\n\t",
 989                     join("\n\t", @tmp), "\n";
 990         }
 991         @ret;
 992 }
 993
 994 sub full_url {
 995         my ($self) = @_;
 996         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
 997 }
 998
 999 sub do_git_commit {
1000         my ($self, $log_entry) = @_;
1001         my $lr = $self->last_rev;
1002         if (defined $lr && $lr >= $log_entry->{revision}) {
1003                 die "Last fetched revision of ", $self->refname,
1004                     " was r$lr, but we are about to fetch: ",
1005                     "r$log_entry->{revision}!\n";
1006         }
1007         if (my $c = $self->rev_db_get($log_entry->{revision})) {
1008                 croak "$log_entry->{revision} = $c already exists! ",
1009                       "Why are we refetching it?\n";
1010         }
1011         my $author = $log_entry->{author};
1012         my ($name, $email) = (defined $::users{$author} ? @{$::users{$author}}
1013                            : ($author, "$author\@".$self->ra->uuid));
1014         $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $name;
1015         $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} = $email;
1016         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
1017
1018         my $tree = $log_entry->{tree};
1019         if (!defined $tree) {
1020                 $tree = $self->tmp_index_do(sub {
1021                                             command_oneline('write-tree') });
1022         }
1023         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1024
1025         my @exec = ('git-commit-tree', $tree);
1026         foreach ($self->get_commit_parents($log_entry)) {
1027                 push @exec, '-p', $_;
1028         }
1029         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1030                                                                    or croak $!;
1031         print $msg_fh $log_entry->{log} or croak $!;
1032         unless ($_no_metadata) {
1033                 print $msg_fh "\ngit-svn-id: ", $self->full_url, '@',
1034                               $log_entry->{revision}, ' ',
1035                               $self->ra->uuid, "\n" or croak $!;
1036         }
1037         $msg_fh->flush == 0 or croak $!;
1038         close $msg_fh or croak $!;
1039         chomp(my $commit = do { local $/; <$out_fh> });
1040         close $out_fh or croak $!;
1041         waitpid $pid, 0;
1042         croak $? if $?;
1043         if ($commit !~ /^$::sha1$/o) {
1044                 die "Failed to commit, invalid sha1: $commit\n";
1045         }
1046
1047         $self->rev_db_set($log_entry->{revision}, $commit, 1);
1048
1049         $self->{last_rev} = $log_entry->{revision};
1050         $self->{last_commit} = $commit;
1051         print "r$log_entry->{revision} = $commit ($self->{ref_id})\n";
1052         if (defined $_repack && (--$_repack_nr == 0)) {
1053                 $_repack_nr = $_repack;
1054                 # repack doesn't use any arguments with spaces in them, does it?
1055                 print "Running git repack $_repack_flags ...\n";
1056                 command_noisy('repack', split(/\s+/, $_repack_flags));
1057                 print "Done repacking\n";
1058         }
1059         return $commit;
1060 }
1061
1062 sub revisions_eq {
1063         my ($self, $r0, $r1) = @_;
1064         return 1 if $r0 == $r1;
1065         my $nr = 0;
1066         $self->ra->get_log([$self->{path}], $r0, $r1,
1067                            0, 0, 1, sub { $nr++ });
1068         return 0 if ($nr > 1);
1069         return 1;
1070 }
1071
1072 sub find_parent_branch {
1073         my ($self, $paths, $rev) = @_;
1074         return undef unless $_follow_parent;
1075         unless (defined $paths) {
1076                 my $err_handler = $SVN::Error::handler;
1077                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
1078                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
1079                                    $paths =
1080                                       Git::SVN::Ra::dup_changed_paths($_[0]) });
1081                 $SVN::Error::handler = $err_handler;
1082         }
1083         return undef unless defined $paths;
1084
1085         # look for a parent from another branch:
1086         my @b_path_components = split m#/#, $self->rel_path;
1087         my @a_path_components;
1088         my $i;
1089         while (@b_path_components) {
1090                 $i = $paths->{'/'.join('/', @b_path_components)};
1091                 last if $i;
1092                 unshift(@a_path_components, pop(@b_path_components));
1093         }
1094         goto not_found unless defined $i;
1095         my $branch_from = $i->{copyfrom_path} or goto not_found;
1096         if (@a_path_components) {
1097                 print STDERR "branch_from: $branch_from => ";
1098                 $branch_from .= '/'.join('/', @a_path_components);
1099                 print STDERR $branch_from, "\n";
1100         }
1101         my $r = $i->{copyfrom_rev};
1102         my $repos_root = $self->ra->{repos_root};
1103         my $url = $self->ra->{url};
1104         my $new_url = $repos_root . $branch_from;
1105         print STDERR  "Found possible branch point: ",
1106                       "$new_url => ", $self->full_url, ", $r\n";
1107         $branch_from =~ s#^/##;
1108         my $remotes = read_all_remotes();
1109         my $gs;
1110         foreach my $repo_id (keys %$remotes) {
1111                 my $u = $remotes->{$repo_id}->{url} or next;
1112                 next if $url ne $u;
1113                 my $fetch = $remotes->{$repo_id}->{fetch};
1114                 foreach my $f (keys %$fetch) {
1115                         next if $f ne $branch_from;
1116                         $gs = Git::SVN->new($fetch->{$f}, $repo_id, $f);
1117                         last;
1118                 }
1119                 last if $gs;
1120         }
1121         unless ($gs) {
1122                 my $ref_id = $self->{ref_id};
1123                 $ref_id =~ s/\@\d+$//;
1124                 $ref_id .= "\@$r";
1125                 # just grow a tail if we're not unique enough :x
1126                 $ref_id .= '-' while find_ref($ref_id);
1127                 print STDERR "Initializing parent: $ref_id\n";
1128                 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id, 1);
1129         }
1130         my ($r0, $parent) = $gs->find_rev_before($r, 1);
1131         if ($_follow_parent && (!defined $r0 || !defined $parent)) {
1132                 $gs->fetch(0, $r);
1133                 ($r0, $parent) = $gs->last_rev_commit;
1134         }
1135         if (defined $r0 && defined $parent && $gs->revisions_eq($r0, $r)) {
1136                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
1137                 $self->assert_index_clean($parent);
1138                 my $ed;
1139                 if ($self->ra->can_do_switch) {
1140                         print STDERR "Following parent with do_switch\n";
1141                         # do_switch works with svn/trunk >= r22312, but that
1142                         # is not included with SVN 1.4.3 (the latest version
1143                         # at the moment), so we can't rely on it
1144                         $self->{last_commit} = $parent;
1145                         $ed = SVN::Git::Fetcher->new($self);
1146                         $gs->ra->gs_do_switch($r0, $rev, $gs,
1147                                               $self->full_url, $ed)
1148                           or die "SVN connection failed somewhere...\n";
1149                 } else {
1150                         print STDERR "Following parent with do_update\n";
1151                         $ed = SVN::Git::Fetcher->new($self);
1152                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
1153                           or die "SVN connection failed somewhere...\n";
1154                 }
1155                 print STDERR "Successfully followed parent\n";
1156                 return $self->make_log_entry($rev, [$parent], $ed);
1157         }
1158 not_found:
1159         print STDERR "Branch parent for path: '/",
1160                      $self->rel_path, "' @ r$rev not found:\n";
1161         return undef unless $paths;
1162         print STDERR "Changed paths:\n";
1163         foreach my $x (sort keys %$paths) {
1164                 my $p = $paths->{$x};
1165                 print STDERR "\t$p->{action}\t$x";
1166                 if ($p->{copyfrom_path}) {
1167                         print STDERR "(from $p->{copyfrom_path}: ",
1168                                      "$p->{copyfrom_rev})";
1169                 }
1170                 print STDERR "\n";
1171         }
1172         print STDERR '-'x72, "\n";
1173         return undef;
1174 }
1175
1176 sub do_fetch {
1177         my ($self, $paths, $rev) = @_;
1178         my $ed;
1179         my ($last_rev, @parents);
1180         if ($self->{last_commit}) {
1181                 $ed = SVN::Git::Fetcher->new($self);
1182                 $last_rev = $self->{last_rev};
1183                 $ed->{c} = $self->{last_commit};
1184                 @parents = ($self->{last_commit});
1185         } else {
1186                 $last_rev = $rev;
1187                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1188                         return $log_entry;
1189                 }
1190                 $ed = SVN::Git::Fetcher->new($self);
1191         }
1192         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
1193                 die "SVN connection failed somewhere...\n";
1194         }
1195         $self->make_log_entry($rev, \@parents, $ed);
1196 }
1197
1198 sub get_untracked {
1199         my ($self, $ed) = @_;
1200         my @out;
1201         my $h = $ed->{empty};
1202         foreach (sort keys %$h) {
1203                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1204                 push @out, "  $act: " . uri_encode($_);
1205                 warn "W: $act: $_\n";
1206         }
1207         foreach my $t (qw/dir_prop file_prop/) {
1208                 $h = $ed->{$t} or next;
1209                 foreach my $path (sort keys %$h) {
1210                         my $ppath = $path eq '' ? '.' : $path;
1211                         foreach my $prop (sort keys %{$h->{$path}}) {
1212                                 next if $SKIP_PROP{$prop};
1213                                 my $v = $h->{$path}->{$prop};
1214                                 my $t_ppath_prop = "$t: " .
1215                                                     uri_encode($ppath) . ' ' .
1216                                                     uri_encode($prop);
1217                                 if (defined $v) {
1218                                         push @out, "  +$t_ppath_prop " .
1219                                                    uri_encode($v);
1220                                 } else {
1221                                         push @out, "  -$t_ppath_prop";
1222                                 }
1223                         }
1224                 }
1225         }
1226         foreach my $t (qw/absent_file absent_directory/) {
1227                 $h = $ed->{$t} or next;
1228                 foreach my $parent (sort keys %$h) {
1229                         foreach my $path (sort @{$h->{$parent}}) {
1230                                 push @out, "  $t: " .
1231                                            uri_encode("$parent/$path");
1232                                 warn "W: $t: $parent/$path ",
1233                                      "Insufficient permissions?\n";
1234                         }
1235                 }
1236         }
1237         \@out;
1238 }
1239
1240 sub parse_svn_date {
1241         my $date = shift || return '+0000 1970-01-01 00:00:00';
1242         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1243                                             (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
1244                                          croak "Unable to parse date: $date\n";
1245         "+0000 $Y-$m-$d $H:$M:$S";
1246 }
1247
1248 sub check_author {
1249         my ($author) = @_;
1250         if (!defined $author || length $author == 0) {
1251                 $author = '(no author)';
1252         }
1253         if (defined $::_authors && ! defined $::users{$author}) {
1254                 die "Author: $author not defined in $::_authors file\n";
1255         }
1256         $author;
1257 }
1258
1259 sub make_log_entry {
1260         my ($self, $rev, $parents, $ed) = @_;
1261         my $untracked = $self->get_untracked($ed);
1262
1263         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1264         print $un "r$rev\n" or croak $!;
1265         print $un $_, "\n" foreach @$untracked;
1266         my %log_entry = ( parents => $parents || [], revision => $rev,
1267                           log => '');
1268         my $rp = $self->ra->rev_proplist($rev);
1269         foreach (sort keys %$rp) {
1270                 my $v = $rp->{$_};
1271                 if (/^svn:(author|date|log)$/) {
1272                         $log_entry{$1} = $v;
1273                 } else {
1274                         print $un "  rev_prop: ", uri_encode($_), ' ',
1275                                   uri_encode($v), "\n";
1276                 }
1277         }
1278         close $un or croak $!;
1279
1280         $log_entry{date} = parse_svn_date($log_entry{date});
1281         $log_entry{author} = check_author($log_entry{author});
1282         $log_entry{log} .= "\n";
1283         \%log_entry;
1284 }
1285
1286 sub fetch {
1287         my ($self, $min_rev, $max_rev, @parents) = @_;
1288         my ($last_rev, $last_commit) = $self->last_rev_commit;
1289         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
1290         return if ($base > $head);
1291         $self->ra->gs_fetch_loop_common($base, $head, $self);
1292 }
1293
1294 sub set_tree_cb {
1295         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
1296         # TODO: enable and test optimized commits:
1297         if (0 && $rev == ($self->{last_rev} + 1)) {
1298                 $log_entry->{revision} = $rev;
1299                 $log_entry->{author} = $author;
1300                 $self->do_git_commit($log_entry, "$rev=$tree");
1301         } else {
1302                 $self->{inject_parents} = { $rev => $tree };
1303                 $self->fetch(undef, undef);
1304         }
1305 }
1306
1307 sub set_tree {
1308         my ($self, $tree) = (shift, shift);
1309         my $log_entry = ::get_commit_entry($tree);
1310         unless ($self->{last_rev}) {
1311                 fatal("Must have an existing revision to commit\n");
1312         }
1313         my %ed_opts = ( r => $self->{last_rev},
1314                         log => $log_entry->{log},
1315                         ra => $self->ra,
1316                         tree_a => $self->{last_commit},
1317                         tree_b => $tree,
1318                         editor_cb => sub {
1319                                $self->set_tree_cb($log_entry, $tree, @_) },
1320                         svn_path => $self->{path} );
1321         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1322                 print "No changes\nr$self->{last_rev} = $tree\n";
1323         }
1324 }
1325
1326 sub rebuild {
1327         my ($self) = @_;
1328         print "Rebuilding $self->{db_path} ...\n";
1329         my ($rev_list, $ctx) = command_output_pipe("rev-list", $self->refname);
1330         my $latest;
1331         my $full_url = $self->full_url;
1332         my $svn_uuid;
1333         while (<$rev_list>) {
1334                 chomp;
1335                 my $c = $_;
1336                 die "Non-SHA1: $c\n" unless $c =~ /^$::sha1$/o;
1337                 my ($url, $rev, $uuid) = ::cmt_metadata($c);
1338
1339                 # ignore merges (from set-tree)
1340                 next if (!defined $rev || !$uuid);
1341
1342                 # if we merged or otherwise started elsewhere, this is
1343                 # how we break out of it
1344                 if ((defined $svn_uuid && ($uuid ne $svn_uuid)) ||
1345                     ($full_url && $url && ($url ne $full_url))) {
1346                         next;
1347                 }
1348                 $latest ||= $rev;
1349                 $svn_uuid ||= $uuid;
1350
1351                 $self->rev_db_set($rev, $c);
1352                 print "r$rev = $c\n";
1353         }
1354         command_close_pipe($rev_list, $ctx);
1355         print "Done rebuilding $self->{db_path}\n";
1356 }
1357
1358 # rev_db:
1359 # Tie::File seems to be prone to offset errors if revisions get sparse,
1360 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
1361 # one of my favorite modules is out :<  Next up would be one of the DBM
1362 # modules, but I'm not sure which is most portable...  So I'll just
1363 # go with something that's plain-text, but still capable of
1364 # being randomly accessed.  So here's my ultra-simple fixed-width
1365 # database.  All records are 40 characters + "\n", so it's easy to seek
1366 # to a revision: (41 * rev) is the byte offset.
1367 # A record of 40 0s denotes an empty revision.
1368 # And yes, it's still pretty fast (faster than Tie::File).
1369 # These files are disposable unless --no-metadata is set
1370
1371 sub rev_db_set {
1372         my ($self, $rev, $commit, $update_ref) = @_;
1373         length $commit == 40 or croak "arg3 must be a full SHA1 hexsum\n";
1374         my ($db, $db_lock) = ($self->{db_path}, "$self->{db_path}.lock");
1375         my $sig;
1376         if ($update_ref) {
1377                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
1378                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
1379         }
1380         $LOCKFILES{$db_lock} = 1;
1381         if ($_no_metadata) {
1382                 copy($db, $db_lock) or die "rev_db_set(@_): ",
1383                                            "Failed to copy: ",
1384                                            "$db => $db_lock ($!)\n";
1385         } else {
1386                 rename $db, $db_lock or die "rev_db_set(@_): ",
1387                                             "Failed to rename: ",
1388                                             "$db => $db_lock ($!)\n";
1389         }
1390         open my $fh, '+<', $db_lock or croak $!;
1391         my $offset = $rev * 41;
1392         # assume that append is the common case:
1393         seek $fh, 0, 2 or croak $!;
1394         my $pos = tell $fh;
1395         if ($pos < $offset) {
1396                 for (1 .. (($offset - $pos) / 41)) {
1397                         print $fh (('0' x 40),"\n") or croak $!;
1398                 }
1399         }
1400         seek $fh, $offset, 0 or croak $!;
1401         print $fh $commit,"\n" or croak $!;
1402         close $fh or croak $!;
1403         if ($update_ref) {
1404                 command_noisy('update-ref', '-m', "r$rev",
1405                               $self->refname, $commit);
1406         }
1407         rename $db_lock, $db or die "rev_db_set(@_): ", "Failed to rename: ",
1408                                     "$db_lock => $db ($!)\n";
1409         delete $LOCKFILES{$db_lock};
1410         if ($update_ref) {
1411                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
1412                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
1413                 kill $sig, $$ if defined $sig;
1414         }
1415 }
1416
1417 sub rev_db_max {
1418         my ($self) = @_;
1419         my @stat = stat $self->{db_path} or
1420                         die "Couldn't stat $self->{db_path}: $!\n";
1421         ($stat[7] % 41) == 0 or
1422                         die "$self->{db_path} inconsistent size:$stat[7]\n";
1423         my $max = $stat[7] / 41;
1424         (($max > 0) ? $max - 1 : 0);
1425 }
1426
1427 sub rev_db_get {
1428         my ($self, $rev) = @_;
1429         my $ret;
1430         my $offset = $rev * 41;
1431         open my $fh, '<', $self->{db_path} or croak $!;
1432         if (sysseek($fh, $offset, 0) == $offset) {
1433                 my $read = sysread($fh, $ret, 40);
1434                 $ret = undef if ($read != 40 || $ret eq ('0'x40));
1435         }
1436         close $fh or croak $!;
1437         $ret;
1438 }
1439
1440 sub find_rev_before {
1441         my ($self, $rev, $eq_ok) = @_;
1442         --$rev unless $eq_ok;
1443         while ($rev > 0) {
1444                 if (my $c = $self->rev_db_get($rev)) {
1445                         return ($rev, $c);
1446                 }
1447                 --$rev;
1448         }
1449         return (undef, undef);
1450 }
1451
1452 sub _new {
1453         my ($class, $repo_id, $ref_id, $path) = @_;
1454         unless (defined $repo_id && length $repo_id) {
1455                 $repo_id = $Git::SVN::default_repo_id;
1456         }
1457         unless (defined $ref_id && length $ref_id) {
1458                 $_[2] = $ref_id = $Git::SVN::default_ref_id;
1459         }
1460         $_[1] = $repo_id = sanitize_remote_name($repo_id);
1461         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
1462         $_[3] = $path = '' unless (defined $path);
1463         mkpath([$dir]);
1464         unless (-f "$dir/.rev_db") {
1465                 open my $fh, '>>', "$dir/.rev_db" or croak $!;
1466                 close $fh or croak $!;
1467         }
1468         bless { ref_id => $ref_id, dir => $dir, index => "$dir/index",
1469                 path => $path,
1470                 db_path => "$dir/.rev_db", repo_id => $repo_id }, $class;
1471 }
1472
1473 sub uri_encode {
1474         my ($f) = @_;
1475         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
1476         $f
1477 }
1478
1479 package Git::SVN::Prompt;
1480 use strict;
1481 use warnings;
1482 require SVN::Core;
1483 use vars qw/$_no_auth_cache $_username/;
1484
1485 sub simple {
1486         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
1487         $may_save = undef if $_no_auth_cache;
1488         $default_username = $_username if defined $_username;
1489         if (defined $default_username && length $default_username) {
1490                 if (defined $realm && length $realm) {
1491                         print STDERR "Authentication realm: $realm\n";
1492                         STDERR->flush;
1493                 }
1494                 $cred->username($default_username);
1495         } else {
1496                 username($cred, $realm, $may_save, $pool);
1497         }
1498         $cred->password(_read_password("Password for '" .
1499                                        $cred->username . "': ", $realm));
1500         $cred->may_save($may_save);
1501         $SVN::_Core::SVN_NO_ERROR;
1502 }
1503
1504 sub ssl_server_trust {
1505         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
1506         $may_save = undef if $_no_auth_cache;
1507         print STDERR "Error validating server certificate for '$realm':\n";
1508         if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
1509                 print STDERR " - The certificate is not issued by a trusted ",
1510                       "authority. Use the\n",
1511                       "   fingerprint to validate the certificate manually!\n";
1512         }
1513         if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
1514                 print STDERR " - The certificate hostname does not match.\n";
1515         }
1516         if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
1517                 print STDERR " - The certificate is not yet valid.\n";
1518         }
1519         if ($failures & $SVN::Auth::SSL::EXPIRED) {
1520                 print STDERR " - The certificate has expired.\n";
1521         }
1522         if ($failures & $SVN::Auth::SSL::OTHER) {
1523                 print STDERR " - The certificate has an unknown error.\n";
1524         }
1525         printf STDERR
1526                 "Certificate information:\n".
1527                 " - Hostname: %s\n".
1528                 " - Valid: from %s until %s\n".
1529                 " - Issuer: %s\n".
1530                 " - Fingerprint: %s\n",
1531                 map $cert_info->$_, qw(hostname valid_from valid_until
1532                                        issuer_dname fingerprint);
1533         my $choice;
1534 prompt:
1535         print STDERR $may_save ?
1536               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
1537               "(R)eject or accept (t)emporarily? ";
1538         STDERR->flush;
1539         $choice = lc(substr(<STDIN> || 'R', 0, 1));
1540         if ($choice =~ /^t$/i) {
1541                 $cred->may_save(undef);
1542         } elsif ($choice =~ /^r$/i) {
1543                 return -1;
1544         } elsif ($may_save && $choice =~ /^p$/i) {
1545                 $cred->may_save($may_save);
1546         } else {
1547                 goto prompt;
1548         }
1549         $cred->accepted_failures($failures);
1550         $SVN::_Core::SVN_NO_ERROR;
1551 }
1552
1553 sub ssl_client_cert {
1554         my ($cred, $realm, $may_save, $pool) = @_;
1555         $may_save = undef if $_no_auth_cache;
1556         print STDERR "Client certificate filename: ";
1557         STDERR->flush;
1558         chomp(my $filename = <STDIN>);
1559         $cred->cert_file($filename);
1560         $cred->may_save($may_save);
1561         $SVN::_Core::SVN_NO_ERROR;
1562 }
1563
1564 sub ssl_client_cert_pw {
1565         my ($cred, $realm, $may_save, $pool) = @_;
1566         $may_save = undef if $_no_auth_cache;
1567         $cred->password(_read_password("Password: ", $realm));
1568         $cred->may_save($may_save);
1569         $SVN::_Core::SVN_NO_ERROR;
1570 }
1571
1572 sub username {
1573         my ($cred, $realm, $may_save, $pool) = @_;
1574         $may_save = undef if $_no_auth_cache;
1575         if (defined $realm && length $realm) {
1576                 print STDERR "Authentication realm: $realm\n";
1577         }
1578         my $username;
1579         if (defined $_username) {
1580                 $username = $_username;
1581         } else {
1582                 print STDERR "Username: ";
1583                 STDERR->flush;
1584                 chomp($username = <STDIN>);
1585         }
1586         $cred->username($username);
1587         $cred->may_save($may_save);
1588         $SVN::_Core::SVN_NO_ERROR;
1589 }
1590
1591 sub _read_password {
1592         my ($prompt, $realm) = @_;
1593         print STDERR $prompt;
1594         STDERR->flush;
1595         require Term::ReadKey;
1596         Term::ReadKey::ReadMode('noecho');
1597         my $password = '';
1598         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
1599                 last if $key =~ /[\012\015]/; # \n\r
1600                 $password .= $key;
1601         }
1602         Term::ReadKey::ReadMode('restore');
1603         print STDERR "\n";
1604         STDERR->flush;
1605         $password;
1606 }
1607
1608 package main;
1609
1610 {
1611         my $kill_stupid_warnings = $SVN::Node::none.$SVN::Node::file.
1612                                 $SVN::Node::dir.$SVN::Node::unknown.
1613                                 $SVN::Node::none.$SVN::Node::file.
1614                                 $SVN::Node::dir.$SVN::Node::unknown.
1615                                 $SVN::Auth::SSL::CNMISMATCH.
1616                                 $SVN::Auth::SSL::NOTYETVALID.
1617                                 $SVN::Auth::SSL::EXPIRED.
1618                                 $SVN::Auth::SSL::UNKNOWNCA.
1619                                 $SVN::Auth::SSL::OTHER;
1620 }
1621
1622 package SVN::Git::Fetcher;
1623 use vars qw/@ISA/;
1624 use strict;
1625 use warnings;
1626 use Carp qw/croak/;
1627 use IO::File qw//;
1628 use Digest::MD5;
1629
1630 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
1631 sub new {
1632         my ($class, $git_svn) = @_;
1633         my $self = SVN::Delta::Editor->new;
1634         bless $self, $class;
1635         $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
1636         $self->{empty} = {};
1637         $self->{dir_prop} = {};
1638         $self->{file_prop} = {};
1639         $self->{absent_dir} = {};
1640         $self->{absent_file} = {};
1641         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
1642         $self;
1643 }
1644
1645 sub set_path_strip {
1646         my ($self, $path) = @_;
1647         $self->{path_strip} = qr/^\Q$path\E\/?/;
1648 }
1649
1650 sub open_root {
1651         { path => '' };
1652 }
1653
1654 sub open_directory {
1655         my ($self, $path, $pb, $rev) = @_;
1656         { path => $path };
1657 }
1658
1659 sub git_path {
1660         my ($self, $path) = @_;
1661         if ($self->{path_strip}) {
1662                 $path =~ s!$self->{path_strip}!! or
1663                   die "Failed to strip path '$path' ($self->{path_strip})\n";
1664         }
1665         $path;
1666 }
1667
1668 sub delete_entry {
1669         my ($self, $path, $rev, $pb) = @_;
1670
1671         my $gpath = $self->git_path($path);
1672         return undef if ($gpath eq '');
1673
1674         # remove entire directories.
1675         if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
1676                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
1677                                                      -r --name-only -z/,
1678                                                      $self->{c}, '--', $gpath);
1679                 local $/ = "\0";
1680                 while (<$ls>) {
1681                         chomp;
1682                         $self->{gii}->remove($_);
1683                         print "\tD\t$_\n" unless $self->{q};
1684                 }
1685                 print "\tD\t$gpath/\n" unless $self->{q};
1686                 command_close_pipe($ls, $ctx);
1687                 $self->{empty}->{$path} = 0
1688         } else {
1689                 $self->{gii}->remove($gpath);
1690                 print "\tD\t$gpath\n" unless $self->{q};
1691         }
1692         undef;
1693 }
1694
1695 sub open_file {
1696         my ($self, $path, $pb, $rev) = @_;
1697         my $gpath = $self->git_path($path);
1698         my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
1699                              =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
1700         unless (defined $mode && defined $blob) {
1701                 die "$path was not found in commit $self->{c} (r$rev)\n";
1702         }
1703         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
1704           pool => SVN::Pool->new, action => 'M' };
1705 }
1706
1707 sub add_file {
1708         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
1709         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1710         delete $self->{empty}->{$dir};
1711         { path => $path, mode_a => 100644, mode_b => 100644,
1712           pool => SVN::Pool->new, action => 'A' };
1713 }
1714
1715 sub add_directory {
1716         my ($self, $path, $cp_path, $cp_rev) = @_;
1717         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1718         delete $self->{empty}->{$dir};
1719         $self->{empty}->{$path} = 1;
1720         { path => $path };
1721 }
1722
1723 sub change_dir_prop {
1724         my ($self, $db, $prop, $value) = @_;
1725         $self->{dir_prop}->{$db->{path}} ||= {};
1726         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
1727         undef;
1728 }
1729
1730 sub absent_directory {
1731         my ($self, $path, $pb) = @_;
1732         $self->{absent_dir}->{$pb->{path}} ||= [];
1733         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
1734         undef;
1735 }
1736
1737 sub absent_file {
1738         my ($self, $path, $pb) = @_;
1739         $self->{absent_file}->{$pb->{path}} ||= [];
1740         push @{$self->{absent_file}->{$pb->{path}}}, $path;
1741         undef;
1742 }
1743
1744 sub change_file_prop {
1745         my ($self, $fb, $prop, $value) = @_;
1746         if ($prop eq 'svn:executable') {
1747                 if ($fb->{mode_b} != 120000) {
1748                         $fb->{mode_b} = defined $value ? 100755 : 100644;
1749                 }
1750         } elsif ($prop eq 'svn:special') {
1751                 $fb->{mode_b} = defined $value ? 120000 : 100644;
1752         } else {
1753                 $self->{file_prop}->{$fb->{path}} ||= {};
1754                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
1755         }
1756         undef;
1757 }
1758
1759 sub apply_textdelta {
1760         my ($self, $fb, $exp) = @_;
1761         my $fh = IO::File->new_tmpfile;
1762         $fh->autoflush(1);
1763         # $fh gets auto-closed() by SVN::TxDelta::apply(),
1764         # (but $base does not,) so dup() it for reading in close_file
1765         open my $dup, '<&', $fh or croak $!;
1766         my $base = IO::File->new_tmpfile;
1767         $base->autoflush(1);
1768         if ($fb->{blob}) {
1769                 defined (my $pid = fork) or croak $!;
1770                 if (!$pid) {
1771                         open STDOUT, '>&', $base or croak $!;
1772                         print STDOUT 'link ' if ($fb->{mode_a} == 120000);
1773                         exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
1774                 }
1775                 waitpid $pid, 0;
1776                 croak $? if $?;
1777
1778                 if (defined $exp) {
1779                         seek $base, 0, 0 or croak $!;
1780                         my $md5 = Digest::MD5->new;
1781                         $md5->addfile($base);
1782                         my $got = $md5->hexdigest;
1783                         die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
1784                             "expected: $exp\n",
1785                             "     got: $got\n" if ($got ne $exp);
1786                 }
1787         }
1788         seek $base, 0, 0 or croak $!;
1789         $fb->{fh} = $dup;
1790         $fb->{base} = $base;
1791         [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
1792 }
1793
1794 sub close_file {
1795         my ($self, $fb, $exp) = @_;
1796         my $hash;
1797         my $path = $self->git_path($fb->{path});
1798         if (my $fh = $fb->{fh}) {
1799                 seek($fh, 0, 0) or croak $!;
1800                 my $md5 = Digest::MD5->new;
1801                 $md5->addfile($fh);
1802                 my $got = $md5->hexdigest;
1803                 die "Checksum mismatch: $path\n",
1804                     "expected: $exp\n    got: $got\n" if ($got ne $exp);
1805                 seek($fh, 0, 0) or croak $!;
1806                 if ($fb->{mode_b} == 120000) {
1807                         read($fh, my $buf, 5) == 5 or croak $!;
1808                         $buf eq 'link ' or die "$path has mode 120000",
1809                                                "but is not a link\n";
1810                 }
1811                 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
1812                 if (!$pid) {
1813                         open STDIN, '<&', $fh or croak $!;
1814                         exec qw/git-hash-object -w --stdin/ or croak $!;
1815                 }
1816                 chomp($hash = do { local $/; <$out> });
1817                 close $out or croak $!;
1818                 close $fh or croak $!;
1819                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
1820                 close $fb->{base} or croak $!;
1821         } else {
1822                 $hash = $fb->{blob} or die "no blob information\n";
1823         }
1824         $fb->{pool}->clear;
1825         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
1826         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $self->{q};
1827         undef;
1828 }
1829
1830 sub abort_edit {
1831         my $self = shift;
1832         $self->{nr} = $self->{gii}->{nr};
1833         delete $self->{gii};
1834         $self->SUPER::abort_edit(@_);
1835 }
1836
1837 sub close_edit {
1838         my $self = shift;
1839         $self->{git_commit_ok} = 1;
1840         $self->{nr} = $self->{gii}->{nr};
1841         delete $self->{gii};
1842         $self->SUPER::close_edit(@_);
1843 }
1844
1845 package SVN::Git::Editor;
1846 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
1847 use strict;
1848 use warnings;
1849 use Carp qw/croak/;
1850 use IO::File;
1851 use Digest::MD5;
1852
1853 sub new {
1854         my ($class, $opts) = @_;
1855         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
1856                 die "$_ required!\n" unless (defined $opts->{$_});
1857         }
1858
1859         my $pool = SVN::Pool->new;
1860         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
1861         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
1862                                      $opts->{r}, $mods);
1863
1864         # $opts->{ra} functions should not be used after this:
1865         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
1866                                                 $opts->{editor_cb}, $pool);
1867         my $self = SVN::Delta::Editor->new(@ce, $pool);
1868         bless $self, $class;
1869         foreach (qw/svn_path r tree_a tree_b/) {
1870                 $self->{$_} = $opts->{$_};
1871         }
1872         $self->{url} = $opts->{ra}->{url};
1873         $self->{mods} = $mods;
1874         $self->{types} = $types;
1875         $self->{pool} = $pool;
1876         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
1877         $self->{rm} = { };
1878         $self->{path_prefix} = length $self->{svn_path} ?
1879                                "$self->{svn_path}/" : '';
1880         return $self;
1881 }
1882
1883 sub generate_diff {
1884         my ($tree_a, $tree_b) = @_;
1885         my @diff_tree = qw(diff-tree -z -r);
1886         if ($_cp_similarity) {
1887                 push @diff_tree, "-C$_cp_similarity";
1888         } else {
1889                 push @diff_tree, '-C';
1890         }
1891         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
1892         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
1893         push @diff_tree, $tree_a, $tree_b;
1894         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
1895         local $/ = "\0";
1896         my $state = 'meta';
1897         my @mods;
1898         while (<$diff_fh>) {
1899                 chomp $_; # this gets rid of the trailing "\0"
1900                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
1901                                         $::sha1\s($::sha1)\s
1902                                         ([MTCRAD])\d*$/xo) {
1903                         push @mods, {   mode_a => $1, mode_b => $2,
1904                                         sha1_b => $3, chg => $4 };
1905                         if ($4 =~ /^(?:C|R)$/) {
1906                                 $state = 'file_a';
1907                         } else {
1908                                 $state = 'file_b';
1909                         }
1910                 } elsif ($state eq 'file_a') {
1911                         my $x = $mods[$#mods] or croak "Empty array\n";
1912                         if ($x->{chg} !~ /^(?:C|R)$/) {
1913                                 croak "Error parsing $_, $x->{chg}\n";
1914                         }
1915                         $x->{file_a} = $_;
1916                         $state = 'file_b';
1917                 } elsif ($state eq 'file_b') {
1918                         my $x = $mods[$#mods] or croak "Empty array\n";
1919                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
1920                                 croak "Error parsing $_, $x->{chg}\n";
1921                         }
1922                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
1923                                 croak "Error parsing $_, $x->{chg}\n";
1924                         }
1925                         $x->{file_b} = $_;
1926                         $state = 'meta';
1927                 } else {
1928                         croak "Error parsing $_\n";
1929                 }
1930         }
1931         command_close_pipe($diff_fh, $ctx);
1932         \@mods;
1933 }
1934
1935 sub check_diff_paths {
1936         my ($ra, $pfx, $rev, $mods) = @_;
1937         my %types;
1938         $pfx .= '/' if length $pfx;
1939
1940         sub type_diff_paths {
1941                 my ($ra, $types, $path, $rev) = @_;
1942                 my @p = split m#/+#, $path;
1943                 my $c = shift @p;
1944                 unless (defined $types->{$c}) {
1945                         $types->{$c} = $ra->check_path($c, $rev);
1946                 }
1947                 while (@p) {
1948                         $c .= '/' . shift @p;
1949                         next if defined $types->{$c};
1950                         $types->{$c} = $ra->check_path($c, $rev);
1951                 }
1952         }
1953
1954         foreach my $m (@$mods) {
1955                 foreach my $f (qw/file_a file_b/) {
1956                         next unless defined $m->{$f};
1957                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
1958                         if (length $pfx.$dir && ! defined $types{$dir}) {
1959                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
1960                         }
1961                 }
1962         }
1963         \%types;
1964 }
1965
1966 sub split_path {
1967         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
1968 }
1969
1970 sub repo_path {
1971         my ($self, $path) = @_;
1972         $self->{path_prefix}.(defined $path ? $path : '');
1973 }
1974
1975 sub url_path {
1976         my ($self, $path) = @_;
1977         $self->{url} . '/' . $self->repo_path($path);
1978 }
1979
1980 sub rmdirs {
1981         my ($self) = @_;
1982         my $rm = $self->{rm};
1983         delete $rm->{''}; # we never delete the url we're tracking
1984         return unless %$rm;
1985
1986         foreach (keys %$rm) {
1987                 my @d = split m#/#, $_;
1988                 my $c = shift @d;
1989                 $rm->{$c} = 1;
1990                 while (@d) {
1991                         $c .= '/' . shift @d;
1992                         $rm->{$c} = 1;
1993                 }
1994         }
1995         delete $rm->{$self->{svn_path}};
1996         delete $rm->{''}; # we never delete the url we're tracking
1997         return unless %$rm;
1998
1999         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
2000                                              $self->{tree_b});
2001         local $/ = "\0";
2002         while (<$fh>) {
2003                 chomp;
2004                 my @dn = split m#/#, $_;
2005                 while (pop @dn) {
2006                         delete $rm->{join '/', @dn};
2007                 }
2008                 unless (%$rm) {
2009                         close $fh;
2010                         return;
2011                 }
2012         }
2013         command_close_pipe($fh, $ctx);
2014
2015         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
2016         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
2017                 $self->close_directory($bat->{$d}, $p);
2018                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
2019                 print "\tD+\t$d/\n" unless $::_q;
2020                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
2021                 delete $bat->{$d};
2022         }
2023 }
2024
2025 sub open_or_add_dir {
2026         my ($self, $full_path, $baton) = @_;
2027         my $t = $self->{types}->{$full_path};
2028         if (!defined $t) {
2029                 die "$full_path not known in r$self->{r} or we have a bug!\n";
2030         }
2031         if ($t == $SVN::Node::none) {
2032                 return $self->add_directory($full_path, $baton,
2033                                                 undef, -1, $self->{pool});
2034         } elsif ($t == $SVN::Node::dir) {
2035                 return $self->open_directory($full_path, $baton,
2036                                                 $self->{r}, $self->{pool});
2037         }
2038         print STDERR "$full_path already exists in repository at ",
2039                 "r$self->{r} and it is not a directory (",
2040                 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
2041         exit 1;
2042 }
2043
2044 sub ensure_path {
2045         my ($self, $path) = @_;
2046         my $bat = $self->{bat};
2047         my $repo_path = $self->repo_path($path);
2048         return $bat->{''} unless (length $repo_path);
2049         my @p = split m#/+#, $repo_path;
2050         my $c = shift @p;
2051         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
2052         while (@p) {
2053                 my $c0 = $c;
2054                 $c .= '/' . shift @p;
2055                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
2056         }
2057         return $bat->{$c};
2058 }
2059
2060 sub A {
2061         my ($self, $m) = @_;
2062         my ($dir, $file) = split_path($m->{file_b});
2063         my $pbat = $self->ensure_path($dir);
2064         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2065                                         undef, -1);
2066         print "\tA\t$m->{file_b}\n" unless $::_q;
2067         $self->chg_file($fbat, $m);
2068         $self->close_file($fbat,undef,$self->{pool});
2069 }
2070
2071 sub C {
2072         my ($self, $m) = @_;
2073         my ($dir, $file) = split_path($m->{file_b});
2074         my $pbat = $self->ensure_path($dir);
2075         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2076                                 $self->url_path($m->{file_a}), $self->{r});
2077         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2078         $self->chg_file($fbat, $m);
2079         $self->close_file($fbat,undef,$self->{pool});
2080 }
2081
2082 sub delete_entry {
2083         my ($self, $path, $pbat) = @_;
2084         my $rpath = $self->repo_path($path);
2085         my ($dir, $file) = split_path($rpath);
2086         $self->{rm}->{$dir} = 1;
2087         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
2088 }
2089
2090 sub R {
2091         my ($self, $m) = @_;
2092         my ($dir, $file) = split_path($m->{file_b});
2093         my $pbat = $self->ensure_path($dir);
2094         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2095                                 $self->url_path($m->{file_a}), $self->{r});
2096         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2097         $self->chg_file($fbat, $m);
2098         $self->close_file($fbat,undef,$self->{pool});
2099
2100         ($dir, $file) = split_path($m->{file_a});
2101         $pbat = $self->ensure_path($dir);
2102         $self->delete_entry($m->{file_a}, $pbat);
2103 }
2104
2105 sub M {
2106         my ($self, $m) = @_;
2107         my ($dir, $file) = split_path($m->{file_b});
2108         my $pbat = $self->ensure_path($dir);
2109         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
2110                                 $pbat,$self->{r},$self->{pool});
2111         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
2112         $self->chg_file($fbat, $m);
2113         $self->close_file($fbat,undef,$self->{pool});
2114 }
2115
2116 sub T { shift->M(@_) }
2117
2118 sub change_file_prop {
2119         my ($self, $fbat, $pname, $pval) = @_;
2120         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
2121 }
2122
2123 sub chg_file {
2124         my ($self, $fbat, $m) = @_;
2125         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
2126                 $self->change_file_prop($fbat,'svn:executable','*');
2127         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
2128                 $self->change_file_prop($fbat,'svn:executable',undef);
2129         }
2130         my $fh = IO::File->new_tmpfile or croak $!;
2131         if ($m->{mode_b} =~ /^120/) {
2132                 print $fh 'link ' or croak $!;
2133                 $self->change_file_prop($fbat,'svn:special','*');
2134         } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
2135                 $self->change_file_prop($fbat,'svn:special',undef);
2136         }
2137         defined(my $pid = fork) or croak $!;
2138         if (!$pid) {
2139                 open STDOUT, '>&', $fh or croak $!;
2140                 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
2141         }
2142         waitpid $pid, 0;
2143         croak $? if $?;
2144         $fh->flush == 0 or croak $!;
2145         seek $fh, 0, 0 or croak $!;
2146
2147         my $md5 = Digest::MD5->new;
2148         $md5->addfile($fh) or croak $!;
2149         seek $fh, 0, 0 or croak $!;
2150
2151         my $exp = $md5->hexdigest;
2152         my $pool = SVN::Pool->new;
2153         my $atd = $self->apply_textdelta($fbat, undef, $pool);
2154         my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
2155         die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
2156         $pool->clear;
2157
2158         close $fh or croak $!;
2159 }
2160
2161 sub D {
2162         my ($self, $m) = @_;
2163         my ($dir, $file) = split_path($m->{file_b});
2164         my $pbat = $self->ensure_path($dir);
2165         print "\tD\t$m->{file_b}\n" unless $::_q;
2166         $self->delete_entry($m->{file_b}, $pbat);
2167 }
2168
2169 sub close_edit {
2170         my ($self) = @_;
2171         my ($p,$bat) = ($self->{pool}, $self->{bat});
2172         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
2173                 $self->close_directory($bat->{$_}, $p);
2174         }
2175         $self->SUPER::close_edit($p);
2176         $p->clear;
2177 }
2178
2179 sub abort_edit {
2180         my ($self) = @_;
2181         $self->SUPER::abort_edit($self->{pool});
2182 }
2183
2184 sub DESTROY {
2185         my $self = shift;
2186         $self->SUPER::DESTROY(@_);
2187         $self->{pool}->clear;
2188 }
2189
2190 # this drives the editor
2191 sub apply_diff {
2192         my ($self) = @_;
2193         my $mods = $self->{mods};
2194         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
2195         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
2196                 my $f = $m->{chg};
2197                 if (defined $o{$f}) {
2198                         $self->$f($m);
2199                 } else {
2200                         fatal("Invalid change type: $f\n");
2201                 }
2202         }
2203         $self->rmdirs if $_rmdir;
2204         if (@$mods == 0) {
2205                 $self->abort_edit;
2206         } else {
2207                 $self->close_edit;
2208         }
2209         return scalar @$mods;
2210 }
2211
2212 package Git::SVN::Ra;
2213 use vars qw/@ISA $config_dir/;
2214 use strict;
2215 use warnings;
2216 my ($can_do_switch);
2217 my $RA;
2218
2219 BEGIN {
2220         # enforce temporary pool usage for some simple functions
2221         my $e;
2222         foreach (qw/get_latest_revnum rev_proplist get_file
2223                     check_path get_dir get_uuid get_repos_root/) {
2224                 $e .= "sub $_ {
2225                         my \$self = shift;
2226                         my \$pool = SVN::Pool->new;
2227                         my \@ret = \$self->SUPER::$_(\@_,\$pool);
2228                         \$pool->clear;
2229                         wantarray ? \@ret : \$ret[0]; }\n";
2230         }
2231         eval $e;
2232 }
2233
2234 sub new {
2235         my ($class, $url) = @_;
2236         $url =~ s!/+$!!;
2237         return $RA if ($RA && $RA->{url} eq $url);
2238
2239         SVN::_Core::svn_config_ensure($config_dir, undef);
2240         my ($baton, $callbacks) = SVN::Core::auth_open_helper([
2241             SVN::Client::get_simple_provider(),
2242             SVN::Client::get_ssl_server_trust_file_provider(),
2243             SVN::Client::get_simple_prompt_provider(
2244               \&Git::SVN::Prompt::simple, 2),
2245             SVN::Client::get_ssl_client_cert_prompt_provider(
2246               \&Git::SVN::Prompt::ssl_client_cert, 2),
2247             SVN::Client::get_ssl_client_cert_pw_prompt_provider(
2248               \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
2249             SVN::Client::get_username_provider(),
2250             SVN::Client::get_ssl_server_trust_prompt_provider(
2251               \&Git::SVN::Prompt::ssl_server_trust),
2252             SVN::Client::get_username_prompt_provider(
2253               \&Git::SVN::Prompt::username, 2),
2254           ]);
2255         my $config = SVN::Core::config_get_config($config_dir);
2256         my $self = SVN::Ra->new(url => $url, auth => $baton,
2257                               config => $config,
2258                               pool => SVN::Pool->new,
2259                               auth_provider_callbacks => $callbacks);
2260         $self->{svn_path} = $url;
2261         $self->{repos_root} = $self->get_repos_root;
2262         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E/*##;
2263         $RA = bless $self, $class;
2264 }
2265
2266 sub DESTROY {
2267         # do not call the real DESTROY since we store ourselves in $RA
2268 }
2269
2270 sub get_log {
2271         my ($self, @args) = @_;
2272         my $pool = SVN::Pool->new;
2273         splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
2274         my $ret = $self->SUPER::get_log(@args, $pool);
2275         $pool->clear;
2276         $ret;
2277 }
2278
2279 sub get_commit_editor {
2280         my ($self, $log, $cb, $pool) = @_;
2281         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
2282         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
2283 }
2284
2285 sub uuid {
2286         my ($self) = @_;
2287         $self->{uuid} ||= $self->get_uuid;
2288 }
2289
2290 sub gs_do_update {
2291         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
2292         my $new = ($rev_a == $rev_b);
2293         my $path = $gs->{path};
2294
2295         my $ta = $self->check_path($path, $rev_a);
2296         my $tb = $new ? $ta : $self->check_path($path, $rev_b);
2297         return 1 if ($tb != $SVN::Node::dir && $ta != $SVN::Node::dir);
2298         if ($ta == $SVN::Node::none) {
2299                 $rev_a = $rev_b;
2300                 $new = 1;
2301         }
2302
2303         my $pool = SVN::Pool->new;
2304         $editor->set_path_strip($path);
2305         my (@pc) = split m#/#, $path;
2306         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
2307                                         1, $editor, $pool);
2308         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2309
2310         # Since we can't rely on svn_ra_reparent being available, we'll
2311         # just have to do some magic with set_path to make it so
2312         # we only want a partial path.
2313         my $sp = '';
2314         my $final = join('/', @pc);
2315         while (@pc) {
2316                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
2317                 $sp .= '/' if length $sp;
2318                 $sp .= shift @pc;
2319         }
2320         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
2321
2322         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
2323
2324         $reporter->finish_report($pool);
2325         $pool->clear;
2326         $editor->{git_commit_ok};
2327 }
2328
2329 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
2330 # svn_ra_reparent didn't work before 1.4)
2331 sub gs_do_switch {
2332         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
2333         my $path = $gs->{path};
2334         my $pool = SVN::Pool->new;
2335
2336         my $full_url = $self->{url};
2337         my $old_url = $full_url;
2338         $full_url .= "/$path" if length $path;
2339         my ($ra, $reparented);
2340         if ($old_url ne $full_url) {
2341                 if ($old_url !~ m#^svn(\+ssh)?://#) {
2342                         SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
2343                                                   $pool);
2344                         $self->{url} = $full_url;
2345                         $reparented = 1;
2346                 } else {
2347                         $ra = Git::SVN::Ra->new($full_url);
2348                 }
2349         }
2350         $ra ||= $self;
2351         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
2352         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2353         $reporter->set_path('', $rev_a, 0, @lock, $pool);
2354         $reporter->finish_report($pool);
2355
2356         if ($reparented) {
2357                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
2358                 $self->{url} = $old_url;
2359         }
2360
2361         $pool->clear;
2362         $editor->{git_commit_ok};
2363 }
2364
2365 sub gs_fetch_loop_common {
2366         my ($self, $base, $head, @gs) = @_;
2367         my $inc = 1000;
2368         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
2369         foreach my $gs (@gs) {
2370                 if (my $last_commit = $gs->last_commit) {
2371                         $gs->assert_index_clean($last_commit);
2372                 }
2373         }
2374         while (1) {
2375                 my %revs;
2376                 my $err;
2377                 my $err_handler = $SVN::Error::handler;
2378                 $SVN::Error::handler = sub {
2379                         ($err) = @_;
2380                         skip_unknown_revs($err);
2381                 };
2382                 foreach my $gs (@gs) {
2383                         $self->get_log([$gs->{path}], $min, $max, 0, 1, 1, sub
2384                                        { my ($paths, $rev) = @_;
2385                                          push @{$revs{$rev}},
2386                                               [ $gs,
2387                                                 dup_changed_paths($paths) ] });
2388
2389                         next unless ($err && $max >= $head);
2390
2391                         print STDERR "Path '$gs->{path}' ",
2392                                      "was probably deleted:\n",
2393                                      $err->expanded_message,
2394                                      "\nWill attempt to follow ",
2395                                      "revisions r$min .. r$max ",
2396                                      "committed before the deletion\n";
2397                         my $hi = $max;
2398                         while (--$hi >= $min) {
2399                                 my $ok;
2400                                 $self->get_log([$gs->{path}], $min, $hi,
2401                                                0, 1, 1, sub {
2402                                         my ($paths, $rev) = @_;
2403                                         $ok = $rev;
2404                                         push @{$revs{$rev}}, [ $gs,
2405                                            dup_changed_paths($_[0])]});
2406                                 if ($ok) {
2407                                         print STDERR "r$min .. r$ok OK\n";
2408                                         last;
2409                                 }
2410                         }
2411                 }
2412                 $SVN::Error::handler = $err_handler;
2413                 foreach my $r (sort {$a <=> $b} keys %revs) {
2414                         foreach (@{$revs{$r}}) {
2415                                 my ($gs, $paths) = @$_;
2416                                 my $lr = $gs->last_rev;
2417                                 next if defined $lr && $lr >= $r;
2418                                 next if defined $gs->rev_db_get($r);
2419                                 if (my $log_entry = $gs->do_fetch($paths, $r)) {
2420                                         $gs->do_git_commit($log_entry);
2421                                 }
2422                         }
2423                 }
2424                 # pre-fill the .rev_db since it'll eventually get filled in
2425                 # with '0' x40 if something new gets committed
2426                 foreach my $gs (@gs) {
2427                         next if defined $gs->rev_db_get($max);
2428                         $gs->rev_db_set($max, 0 x40);
2429                 }
2430                 last if $max >= $head;
2431                 $min = $max + 1;
2432                 $max += $inc;
2433                 $max = $head if ($max > $head);
2434         }
2435 }
2436
2437 sub minimize_url {
2438         my ($self) = @_;
2439         return $self->{url} if ($self->{url} eq $self->{repos_root});
2440         my $url = $self->{repos_root};
2441         my @components = split(m!/!, $self->{svn_path});
2442         my $c = '';
2443         do {
2444                 $url .= "/$c" if length $c;
2445                 eval { (ref $self)->new($url)->get_latest_revnum };
2446         } while ($@ && ($c = shift @components));
2447         $url;
2448 }
2449
2450 sub can_do_switch {
2451         my $self = shift;
2452         unless (defined $can_do_switch) {
2453                 my $pool = SVN::Pool->new;
2454                 my $rep = eval {
2455                         $self->do_switch(1, '', 0, $self->{url},
2456                                          SVN::Delta::Editor->new, $pool);
2457                 };
2458                 if ($@) {
2459                         $can_do_switch = 0;
2460                 } else {
2461                         $rep->abort_report($pool);
2462                         $can_do_switch = 1;
2463                 }
2464                 $pool->clear;
2465         }
2466         $can_do_switch;
2467 }
2468
2469 sub skip_unknown_revs {
2470         my ($err) = @_;
2471         my $errno = $err->apr_err();
2472         # Maybe the branch we're tracking didn't
2473         # exist when the repo started, so it's
2474         # not an error if it doesn't, just continue
2475         #
2476         # Wonderfully consistent library, eh?
2477         # 160013 - svn:// and file://
2478         # 175002 - http(s)://
2479         # 175007 - http(s):// (this repo required authorization, too...)
2480         #   More codes may be discovered later...
2481         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
2482                 return;
2483         }
2484         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
2485 }
2486
2487 # svn_log_changed_path_t objects passed to get_log are likely to be
2488 # overwritten even if only the refs are copied to an external variable,
2489 # so we should dup the structures in their entirety.  Using an externally
2490 # passed pool (instead of our temporary and quickly cleared pool in
2491 # Git::SVN::Ra) does not help matters at all...
2492 sub dup_changed_paths {
2493         my ($paths) = @_;
2494         return undef unless $paths;
2495         my %ret;
2496         foreach my $p (keys %$paths) {
2497                 my $i = $paths->{$p};
2498                 my %s = map { $_ => $i->$_ }
2499                               qw/copyfrom_path copyfrom_rev action/;
2500                 $ret{$p} = \%s;
2501         }
2502         \%ret;
2503 }
2504
2505 package Git::SVN::Log;
2506 use strict;
2507 use warnings;
2508 use POSIX qw/strftime/;
2509 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
2510             %rusers $show_commit $incremental/;
2511 my $l_fmt;
2512
2513 sub cmt_showable {
2514         my ($c) = @_;
2515         return 1 if defined $c->{r};
2516         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
2517                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
2518                 my @log = command(qw/cat-file commit/, $c->{c});
2519                 shift @log while ($log[0] ne "\n");
2520                 shift @log;
2521                 @{$c->{l}} = grep !/^git-svn-id: /, @log;
2522
2523                 (undef, $c->{r}, undef) = ::extract_metadata(
2524                                 (grep(/^git-svn-id: /, @log))[-1]);
2525         }
2526         return defined $c->{r};
2527 }
2528
2529 sub log_use_color {
2530         return 1 if $color;
2531         my ($dc, $dcvar);
2532         $dcvar = 'color.diff';
2533         $dc = `git-config --get $dcvar`;
2534         if ($dc eq '') {
2535                 # nothing at all; fallback to "diff.color"
2536                 $dcvar = 'diff.color';
2537                 $dc = `git-config --get $dcvar`;
2538         }
2539         chomp($dc);
2540         if ($dc eq 'auto') {
2541                 my $pc;
2542                 $pc = `git-config --get color.pager`;
2543                 if ($pc eq '') {
2544                         # does not have it -- fallback to pager.color
2545                         $pc = `git-config --bool --get pager.color`;
2546                 }
2547                 else {
2548                         $pc = `git-config --bool --get color.pager`;
2549                         if ($?) {
2550                                 $pc = 'false';
2551                         }
2552                 }
2553                 chomp($pc);
2554                 if (-t *STDOUT || (defined $pager && $pc eq 'true')) {
2555                         return ($ENV{TERM} && $ENV{TERM} ne 'dumb');
2556                 }
2557                 return 0;
2558         }
2559         return 0 if $dc eq 'never';
2560         return 1 if $dc eq 'always';
2561         chomp($dc = `git-config --bool --get $dcvar`);
2562         return ($dc eq 'true');
2563 }
2564
2565 sub git_svn_log_cmd {
2566         my ($r_min, $r_max) = @_;
2567         my $gs = Git::SVN->_new;
2568         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
2569                    $gs->refname);
2570         push @cmd, '-r' unless $non_recursive;
2571         push @cmd, qw/--raw --name-status/ if $verbose;
2572         push @cmd, '--color' if log_use_color();
2573         return @cmd unless defined $r_max;
2574         if ($r_max == $r_min) {
2575                 push @cmd, '--max-count=1';
2576                 if (my $c = $gs->rev_db_get($r_max)) {
2577                         push @cmd, $c;
2578                 }
2579         } else {
2580                 my ($c_min, $c_max);
2581                 $c_max = $gs->rev_db_get($r_max);
2582                 $c_min = $gs->rev_db_get($r_min);
2583                 if (defined $c_min && defined $c_max) {
2584                         if ($r_max > $r_max) {
2585                                 push @cmd, "$c_min..$c_max";
2586                         } else {
2587                                 push @cmd, "$c_max..$c_min";
2588                         }
2589                 } elsif ($r_max > $r_min) {
2590                         push @cmd, $c_max;
2591                 } else {
2592                         push @cmd, $c_min;
2593                 }
2594         }
2595         return @cmd;
2596 }
2597
2598 # adapted from pager.c
2599 sub config_pager {
2600         $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
2601         if (!defined $pager) {
2602                 $pager = 'less';
2603         } elsif (length $pager == 0 || $pager eq 'cat') {
2604                 $pager = undef;
2605         }
2606 }
2607
2608 sub run_pager {
2609         return unless -t *STDOUT;
2610         pipe my $rfd, my $wfd or return;
2611         defined(my $pid = fork) or ::fatal "Can't fork: $!\n";
2612         if (!$pid) {
2613                 open STDOUT, '>&', $wfd or
2614                                      ::fatal "Can't redirect to stdout: $!\n";
2615                 return;
2616         }
2617         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!\n";
2618         $ENV{LESS} ||= 'FRSX';
2619         exec $pager or ::fatal "Can't run pager: $! ($pager)\n";
2620 }
2621
2622 sub tz_to_s_offset {
2623         my ($tz) = @_;
2624         $tz =~ s/(\d\d)$//;
2625         return ($1 * 60) + ($tz * 3600);
2626 }
2627
2628 sub get_author_info {
2629         my ($dest, $author, $t, $tz) = @_;
2630         $author =~ s/(?:^\s*|\s*$)//g;
2631         $dest->{a_raw} = $author;
2632         my $au;
2633         if ($::_authors) {
2634                 $au = $rusers{$author} || undef;
2635         }
2636         if (!$au) {
2637                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
2638         }
2639         $dest->{t} = $t;
2640         $dest->{tz} = $tz;
2641         $dest->{a} = $au;
2642         # Date::Parse isn't in the standard Perl distro :(
2643         if ($tz =~ s/^\+//) {
2644                 $t += tz_to_s_offset($tz);
2645         } elsif ($tz =~ s/^\-//) {
2646                 $t -= tz_to_s_offset($tz);
2647         }
2648         $dest->{t_utc} = $t;
2649 }
2650
2651 sub process_commit {
2652         my ($c, $r_min, $r_max, $defer) = @_;
2653         if (defined $r_min && defined $r_max) {
2654                 if ($r_min == $c->{r} && $r_min == $r_max) {
2655                         show_commit($c);
2656                         return 0;
2657                 }
2658                 return 1 if $r_min == $r_max;
2659                 if ($r_min < $r_max) {
2660                         # we need to reverse the print order
2661                         return 0 if (defined $limit && --$limit < 0);
2662                         push @$defer, $c;
2663                         return 1;
2664                 }
2665                 if ($r_min != $r_max) {
2666                         return 1 if ($r_min < $c->{r});
2667                         return 1 if ($r_max > $c->{r});
2668                 }
2669         }
2670         return 0 if (defined $limit && --$limit < 0);
2671         show_commit($c);
2672         return 1;
2673 }
2674
2675 sub show_commit {
2676         my $c = shift;
2677         if ($oneline) {
2678                 my $x = "\n";
2679                 if (my $l = $c->{l}) {
2680                         while ($l->[0] =~ /^\s*$/) { shift @$l }
2681                         $x = $l->[0];
2682                 }
2683                 $l_fmt ||= 'A' . length($c->{r});
2684                 print 'r',pack($l_fmt, $c->{r}),' | ';
2685                 print "$c->{c} | " if $show_commit;
2686                 print $x;
2687         } else {
2688                 show_commit_normal($c);
2689         }
2690 }
2691
2692 sub show_commit_changed_paths {
2693         my ($c) = @_;
2694         return unless $c->{changed};
2695         print "Changed paths:\n", @{$c->{changed}};
2696 }
2697
2698 sub show_commit_normal {
2699         my ($c) = @_;
2700         print '-' x72, "\nr$c->{r} | ";
2701         print "$c->{c} | " if $show_commit;
2702         print "$c->{a} | ", strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)",
2703                                  localtime($c->{t_utc})), ' | ';
2704         my $nr_line = 0;
2705
2706         if (my $l = $c->{l}) {
2707                 while ($l->[$#$l] eq "\n" && $#$l > 0
2708                                           && $l->[($#$l - 1)] eq "\n") {
2709                         pop @$l;
2710                 }
2711                 $nr_line = scalar @$l;
2712                 if (!$nr_line) {
2713                         print "1 line\n\n\n";
2714                 } else {
2715                         if ($nr_line == 1) {
2716                                 $nr_line = '1 line';
2717                         } else {
2718                                 $nr_line .= ' lines';
2719                         }
2720                         print $nr_line, "\n";
2721                         show_commit_changed_paths($c);
2722                         print "\n";
2723                         print $_ foreach @$l;
2724                 }
2725         } else {
2726                 print "1 line\n";
2727                 show_commit_changed_paths($c);
2728                 print "\n";
2729
2730         }
2731         foreach my $x (qw/raw diff/) {
2732                 if ($c->{$x}) {
2733                         print "\n";
2734                         print $_ foreach @{$c->{$x}}
2735                 }
2736         }
2737 }
2738
2739 sub cmd_show_log {
2740         my (@args) = @_;
2741         my ($r_min, $r_max);
2742         my $r_last = -1; # prevent dupes
2743         if (defined $TZ) {
2744                 $ENV{TZ} = $TZ;
2745         } else {
2746                 delete $ENV{TZ};
2747         }
2748         if (defined $::_revision) {
2749                 if ($::_revision =~ /^(\d+):(\d+)$/) {
2750                         ($r_min, $r_max) = ($1, $2);
2751                 } elsif ($::_revision =~ /^\d+$/) {
2752                         $r_min = $r_max = $::_revision;
2753                 } else {
2754                         ::fatal "-r$::_revision is not supported, use ",
2755                                 "standard \'git log\' arguments instead\n";
2756                 }
2757         }
2758
2759         config_pager();
2760         @args = (git_svn_log_cmd($r_min, $r_max), @args);
2761         my $log = command_output_pipe(@args);
2762         run_pager();
2763         my (@k, $c, $d);
2764         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
2765         while (<$log>) {
2766                 if (/^${esc_color}commit ($::sha1_short)/o) {
2767                         my $cmt = $1;
2768                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
2769                                 $r_last = $c->{r};
2770                                 process_commit($c, $r_min, $r_max, \@k) or
2771                                                                 goto out;
2772                         }
2773                         $d = undef;
2774                         $c = { c => $cmt };
2775                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
2776                         get_author_info($c, $1, $2, $3);
2777                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
2778                         # ignore
2779                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
2780                         push @{$c->{raw}}, $_;
2781                 } elsif (/^${esc_color}[ACRMDT]\t/) {
2782                         # we could add $SVN->{svn_path} here, but that requires
2783                         # remote access at the moment (repo_path_split)...
2784                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
2785                         push @{$c->{changed}}, $_;
2786                 } elsif (/^${esc_color}diff /o) {
2787                         $d = 1;
2788                         push @{$c->{diff}}, $_;
2789                 } elsif ($d) {
2790                         push @{$c->{diff}}, $_;
2791                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
2792                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
2793                 } elsif (s/^${esc_color}    //o) {
2794                         push @{$c->{l}}, $_;
2795                 }
2796         }
2797         if ($c && defined $c->{r} && $c->{r} != $r_last) {
2798                 $r_last = $c->{r};
2799                 process_commit($c, $r_min, $r_max, \@k);
2800         }
2801         if (@k) {
2802                 my $swap = $r_max;
2803                 $r_max = $r_min;
2804                 $r_min = $swap;
2805                 process_commit($_, $r_min, $r_max) foreach reverse @k;
2806         }
2807 out:
2808         close $log;
2809         print '-' x72,"\n" unless $incremental || $oneline;
2810 }
2811
2812 package Git::SVN::Migration;
2813 # these version numbers do NOT correspond to actual version numbers
2814 # of git nor git-svn.  They are just relative.
2815 #
2816 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
2817 #
2818 # v1 layout: .git/$id/info/url, refs/remotes/$id
2819 #
2820 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
2821 #
2822 # v3 layout: .git/svn/$id, refs/remotes/$id
2823 #            - info/url may remain for backwards compatibility
2824 #            - this is what we migrate up to this layout automatically,
2825 #            - this will be used by git svn init on single branches
2826 #
2827 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
2828 #            - this is only created for newly multi-init-ed
2829 #              repositories.  Similar in spirit to the
2830 #              --use-separate-remotes option in git-clone (now default)
2831 #            - we do not automatically migrate to this (following
2832 #              the example set by core git)
2833 use strict;
2834 use warnings;
2835 use Carp qw/croak/;
2836 use File::Path qw/mkpath/;
2837 use File::Basename qw/dirname basename/;
2838 use vars qw/$_minimize/;
2839
2840 sub migrate_from_v0 {
2841         my $git_dir = $ENV{GIT_DIR};
2842         return undef unless -d $git_dir;
2843         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2844         my $migrated = 0;
2845         while (<$fh>) {
2846                 chomp;
2847                 my ($id, $orig_ref) = ($_, $_);
2848                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
2849                 next unless -f "$git_dir/$id/info/url";
2850                 my $new_ref = "refs/remotes/$id";
2851                 if (::verify_ref("$new_ref^0")) {
2852                         print STDERR "W: $orig_ref is probably an old ",
2853                                      "branch used by an ancient version of ",
2854                                      "git-svn.\n",
2855                                      "However, $new_ref also exists.\n",
2856                                      "We will not be able ",
2857                                      "to use this branch until this ",
2858                                      "ambiguity is resolved.\n";
2859                         next;
2860                 }
2861                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
2862                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
2863                 command_noisy('update-ref', $new_ref, $orig_ref);
2864                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
2865                 $migrated++;
2866         }
2867         command_close_pipe($fh, $ctx);
2868         print STDERR "Done migrating from v0 layout...\n" if $migrated;
2869         $migrated;
2870 }
2871
2872 sub migrate_from_v1 {
2873         my $git_dir = $ENV{GIT_DIR};
2874         my $migrated = 0;
2875         return $migrated unless -d $git_dir;
2876         my $svn_dir = "$git_dir/svn";
2877
2878         # just in case somebody used 'svn' as their $id at some point...
2879         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
2880
2881         print STDERR "Migrating from a git-svn v1 layout...\n";
2882         mkpath([$svn_dir]);
2883         print STDERR "Data from a previous version of git-svn exists, but\n\t",
2884                      "$svn_dir\n\t(required for this version ",
2885                      "($::VERSION) of git-svn) does not. exist\n";
2886         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2887         while (<$fh>) {
2888                 my $x = $_;
2889                 next unless $x =~ s#^refs/remotes/##;
2890                 chomp $x;
2891                 next unless -f "$git_dir/$x/info/url";
2892                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
2893                 next unless $u;
2894                 my $dn = dirname("$git_dir/svn/$x");
2895                 mkpath([$dn]) unless -d $dn;
2896                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
2897                         mkpath(["$git_dir/svn/svn"]);
2898                         print STDERR " - $git_dir/$x/info => ",
2899                                         "$git_dir/svn/$x/info\n";
2900                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
2901                                croak "$!: $x";
2902                         # don't worry too much about these, they probably
2903                         # don't exist with repos this old (save for index,
2904                         # and we can easily regenerate that)
2905                         foreach my $f (qw/unhandled.log index .rev_db/) {
2906                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
2907                         }
2908                 } else {
2909                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
2910                         rename "$git_dir/$x", "$git_dir/svn/$x" or
2911                                croak "$!: $x";
2912                 }
2913                 $migrated++;
2914         }
2915         command_close_pipe($fh, $ctx);
2916         print STDERR "Done migrating from a git-svn v1 layout\n";
2917         $migrated;
2918 }
2919
2920 sub read_old_urls {
2921         my ($l_map, $pfx, $path) = @_;
2922         my @dir;
2923         foreach (<$path/*>) {
2924                 if (-r "$_/info/url") {
2925                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
2926                         my $ref_id = $pfx . basename $_;
2927                         my $url = ::file_to_s("$_/info/url");
2928                         $l_map->{$ref_id} = $url;
2929                 } elsif (-d $_) {
2930                         push @dir, $_;
2931                 }
2932         }
2933         foreach (@dir) {
2934                 my $x = $_;
2935                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
2936                 read_old_urls($l_map, $x, $_);
2937         }
2938 }
2939
2940 sub migrate_from_v2 {
2941         my @cfg = command(qw/config -l/);
2942         return if grep /^svn-remote\..+\.url=/, @cfg;
2943         my %l_map;
2944         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
2945         my $migrated = 0;
2946
2947         foreach my $ref_id (sort keys %l_map) {
2948                 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
2949                 $migrated++;
2950         }
2951         $migrated;
2952 }
2953
2954 sub minimize_connections {
2955         my $r = Git::SVN::read_all_remotes();
2956         my $new_urls = {};
2957         my $root_repos = {};
2958         foreach my $repo_id (keys %$r) {
2959                 my $url = $r->{$repo_id}->{url} or next;
2960                 my $fetch = $r->{$repo_id}->{fetch} or next;
2961                 my $ra = Git::SVN::Ra->new($url);
2962
2963                 # skip existing cases where we already connect to the root
2964                 if (($ra->{url} eq $ra->{repos_root}) ||
2965                     (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
2966                      $repo_id)) {
2967                         $root_repos->{$ra->{url}} = $repo_id;
2968                         next;
2969                 }
2970
2971                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
2972                 my $root_path = $ra->{url};
2973                 $root_path =~ s#^\Q$ra->{repos_root}\E/*##;
2974                 foreach my $path (keys %$fetch) {
2975                         my $ref_id = $fetch->{$path};
2976                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
2977
2978                         # make sure we can read when connecting to
2979                         # a higher level of a repository
2980                         my ($last_rev, undef) = $gs->last_rev_commit;
2981                         if (!defined $last_rev) {
2982                                 $last_rev = eval {
2983                                         $root_ra->get_latest_revnum;
2984                                 };
2985                                 next if $@;
2986                         }
2987                         my $new = $root_path;
2988                         $new .= length $path ? "/$path" : '';
2989                         eval {
2990                                 $root_ra->get_log([$new], $last_rev, $last_rev,
2991                                                   0, 0, 1, sub { });
2992                         };
2993                         next if $@;
2994                         $new_urls->{$ra->{repos_root}}->{$new} =
2995                                 { ref_id => $ref_id,
2996                                   old_repo_id => $repo_id,
2997                                   old_path => $path };
2998                 }
2999         }
3000
3001         my @emptied;
3002         foreach my $url (keys %$new_urls) {
3003                 # see if we can re-use an existing [svn-remote "repo_id"]
3004                 # instead of creating a(n ugly) new section:
3005                 my $repo_id = $root_repos->{$url} ||
3006                               Git::SVN::sanitize_remote_name($url);
3007
3008                 my $fetch = $new_urls->{$url};
3009                 foreach my $path (keys %$fetch) {
3010                         my $x = $fetch->{$path};
3011                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
3012                         my $pfx = "svn-remote.$x->{old_repo_id}";
3013
3014                         my $old_fetch = quotemeta("$x->{old_path}:".
3015                                                   "refs/remotes/$x->{ref_id}");
3016                         command_noisy(qw/config --unset/,
3017                                       "$pfx.fetch", '^'. $old_fetch . '$');
3018                         delete $r->{$x->{old_repo_id}}->
3019                                {fetch}->{$x->{old_path}};
3020                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
3021                                 command_noisy(qw/config --unset/,
3022                                               "$pfx.url");
3023                                 push @emptied, $x->{old_repo_id}
3024                         }
3025                 }
3026         }
3027         if (@emptied) {
3028                 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
3029                            "$ENV{GIT_DIR}/config";
3030                 print STDERR <<EOF;
3031 The following [svn-remote] sections in your config file ($file) are empty
3032 and can be safely removed:
3033 EOF
3034                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
3035         }
3036 }
3037
3038 sub migration_check {
3039         migrate_from_v0();
3040         migrate_from_v1();
3041         migrate_from_v2();
3042         minimize_connections() if $_minimize;
3043 }
3044
3045 package Git::IndexInfo;
3046 use strict;
3047 use warnings;
3048 use Git qw/command_input_pipe command_close_pipe/;
3049
3050 sub new {
3051         my ($class) = @_;
3052         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
3053         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
3054 }
3055
3056 sub remove {
3057         my ($self, $path) = @_;
3058         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
3059                 return ++$self->{nr};
3060         }
3061         undef;
3062 }
3063
3064 sub update {
3065         my ($self, $mode, $hash, $path) = @_;
3066         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
3067                 return ++$self->{nr};
3068         }
3069         undef;
3070 }
3071
3072 sub DESTROY {
3073         my ($self) = @_;
3074         command_close_pipe($self->{gui}, $self->{ctx});
3075 }
3076
3077 __END__
3078
3079 Data structures:
3080
3081 $log_entry hashref as returned by libsvn_log_entry()
3082 {
3083         log => 'whitespace-formatted log entry
3084 ',                                              # trailing newline is preserved
3085         revision => '8',                        # integer
3086         date => '2004-02-24T17:01:44.108345Z',  # commit date
3087         author => 'committer name'
3088 };
3089
3090
3091 # this is generated by generate_diff();
3092 @mods = array of diff-index line hashes, each element represents one line
3093         of diff-index output
3094
3095 diff-index line ($m hash)
3096 {
3097         mode_a => first column of diff-index output, no leading ':',
3098         mode_b => second column of diff-index output,
3099         sha1_b => sha1sum of the final blob,
3100         chg => change type [MCRADT],
3101         file_a => original file name of a file (iff chg is 'C' or 'R')
3102         file_b => new/current file name of a file (any chg)
3103 }
3104 ;
3105
3106 # retval of read_url_paths{,_all}();
3107 $l_map = {
3108         # repository root url
3109         'https://svn.musicpd.org' => {
3110                 # repository path               # GIT_SVN_ID
3111                 'mpd/trunk'             =>      'trunk',
3112                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
3113         },
3114 }
3115
3116 Notes:
3117         I don't trust the each() function on unless I created %hash myself
3118         because the internal iterator may not have started at base.