Pileus Git - ~andy/sunrise/blob - games-strategy/openra-bin/openra-bin-20120315.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=3
   6
   7 inherit eutils gnome2-utils games
   8
   9 MY_PN=${PN%-bin}
  10
  11 DESCRIPTION="A Libre/Free RTS engine supporting early Westwood games like Command & Conquer and Red Alert"
  12 HOMEPAGE="http://open-ra.org/"
  13 SRC_URI="http://${MY_PN}.res0l.net/assets/downloads/linux/arch/${MY_PN}-release.${PV}-1-any.pkg.tar.xz"
  14
  15 LICENSE="GPL-3"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="cg"
  19
  20 RDEPEND="dev-dotnet/libgdiplus
  21         dev-lang/mono
  22         !games-strategy/openra
  23         media-libs/freetype:2[X]
  24         media-libs/libsdl[X,audio,video]
  25         media-libs/openal
  26         virtual/jpeg
  27         virtual/opengl
  28         cg? ( >=media-gfx/nvidia-cg-toolkit-2.1.0017 )"
  29
  30 src_prepare() {
  31         # register game-version
  32         sed \
  33                 -e "/Version/s/{DEV_VERSION}/release-${PN}/" \
  34                 -i usr/share/${MY_PN}/mods/{ra,cnc}/mod.yaml || die
  35 }
  36
  37 src_install() {
  38         # docs
  39         dodoc usr/share/${MY_PN}/{CHANGELOG,HACKING} || die
  40         rm usr/share/${MY_PN}/{CHANGELOG,HACKING} || die
  41
  42         # data files
  43         rm usr/share/${MY_PN}/COPYING || die
  44         insinto "${GAMES_DATADIR}"
  45         doins -r usr/share/${MY_PN} || die
  46
  47         # icons
  48         insinto /usr/share/icons
  49         doins -r usr/share/icons/* || die
  50
  51         # wrappers scripts
  52         games_make_wrapper ${MY_PN} "mono ./OpenRA.Game.exe" \
  53                 "${GAMES_DATADIR}/${MY_PN}"
  54         games_make_wrapper ${MY_PN}-editor "mono ./OpenRA.Editor.exe" \
  55                 "${GAMES_DATADIR}/${MY_PN}"
  56
  57         # .desktop files
  58         domenu "${FILESDIR}"/${MY_PN}-{cnc,editor,ra}.desktop || die
  59
  60         if use cg ; then
  61                 # set default renderer to cg
  62                 sed \
  63                         -e '/Renderer/s/Gl/Cg/' \
  64                         -i "${D}"/usr/share/applications/${MY_PN}-{cnc,ra}.desktop \
  65                         || die "setting default renderer in desktop file failed"
  66         fi
  67
  68         # file permissions
  69         prepgamesdirs
  70 }
  71
  72 pkg_preinst() {
  73         games_pkg_preinst
  74         gnome2_icon_savelist
  75 }
  76
  77 pkg_postinst() {
  78         games_pkg_postinst
  79         gnome2_icon_cache_update
  80
  81         if use cg ; then
  82                 elog "If you have problems starting the game consider switching"
  83                 elog "back to Graphics.Renderer=Gl in openra*.desktop or pass that"
  84                 elog "argument on the command line:"
  85                 elog "openra Game.Mods=... Graphics.Renderer=Gl"
  86         fi
  87 }
  88
  89 pkg_postrm() {
  90         gnome2_icon_cache_update
  91 }