Pileus Git - ~andy/sunrise/blob - games-roguelike/dwarf-fortress/dwarf-fortress-0.34.05.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=3
   6
   7 inherit games versionator
   8
   9 MY_PV=$(replace_all_version_separators _ "$(get_version_component_range 2-)")
  10 MY_PN=df
  11 MY_P=${MY_PN}_${MY_PV}
  12
  13 DESCRIPTION="A single-player fantasy game"
  14 HOMEPAGE="http://www.bay12games.com/dwarves"
  15 SRC_URI="http://www.bay12games.com/dwarves/${MY_P}_linux.tar.bz2"
  16
  17 LICENSE="as-is"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86 -*"
  20 IUSE=""
  21 # this is all precompiled
  22 RESTRICT="strip"
  23
  24 RDEPEND="
  25         virtual/glu
  26         amd64? (
  27                 app-emulation/emul-linux-x86-baselibs
  28                 app-emulation/emul-linux-x86-gtklibs
  29                 app-emulation/emul-linux-x86-opengl
  30                 app-emulation/emul-linux-x86-sdl
  31                 app-emulation/emul-linux-x86-soundlibs
  32                 app-emulation/emul-linux-x86-xlibs
  33         )
  34         x86? (
  35                 media-libs/fmod:1
  36                 media-libs/freetype
  37                 media-libs/libsdl[opengl,video,X]
  38                 media-libs/libsndfile[alsa]
  39                 media-libs/openal
  40                 media-libs/sdl-image[png,tiff,jpeg]
  41                 media-libs/sdl-ttf
  42                 sys-libs/zlib
  43                 x11-libs/cairo[xcb,X]
  44                 x11-libs/gtk+:2[xinerama]
  45                 x11-libs/libXcomposite
  46                 x11-libs/libXcursor
  47                 x11-libs/pango[X]
  48         )"
  49
  50 S=${WORKDIR}/${MY_PN}_linux
  51
  52 src_install() {
  53         # install config stuff
  54         insinto "${GAMES_SYSCONFDIR}"/${PN}
  55         doins -r data/init/* || die
  56
  57         # keep saves, movies and objects directories
  58         keepdir "${GAMES_STATEDIR}"/${PN}/save \
  59                 "${GAMES_STATEDIR}"/${PN}/movies \
  60                 "${GAMES_STATEDIR}"/${PN}/objects || die
  61
  62         # install data-files and libs
  63         local gamesdir="${GAMES_PREFIX_OPT}/${PN}"
  64         insinto "${gamesdir}"
  65         rm -r data/{movies,init} || die
  66         doins -r raw data libs || die
  67
  68         # install our wrapper
  69         newgamesbin "${FILESDIR}"/${PN}-wrapper ${PN} || die
  70
  71         # install docs
  72         dodoc README.linux *.txt || die
  73
  74         # create symlinks for several directories we want to have
  75         # in a different place
  76         dosym "${GAMES_SYSCONFDIR}"/${PN} "${gamesdir}"/data/init || die
  77         dosym "${GAMES_STATEDIR}"/${PN}/save "${gamesdir}"/data/save || die
  78         dosym "${GAMES_STATEDIR}"/${PN}/movies "${gamesdir}"/data/movies || die
  79         dosym "${GAMES_STATEDIR}"/${PN}/objects "${gamesdir}"/data/objects || die
  80
  81         prepgamesdirs
  82
  83         # fix a few permissions
  84         fperms 0755 \
  85                 "${gamesdir}"/libs/{Dwarf_Fortress,libgcc_s.so.1,libgraphics.so,libstdc++.so.6} || die
  86         fperms -R g+w "${GAMES_STATEDIR}"/${PN} || die
  87         fperms g+w "${gamesdir}"/data/index || die
  88         fperms -R g+w "${gamesdir}"/data/{announcement,dipscript,help} || die
  89 }