Pileus Git - ~andy/sunrise/blob - games-board/holtz/holtz-1.3.1.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 # Note: the current version is not compatible with wxWidgets 2.9, but a future
   6 # version might be. Check again when upstream releases a new version.
   7
   8 EAPI=2
   9 WX_GTK_VER=2.8
  10
  11 inherit autotools eutils games wxwidgets
  12
  13 DESCRIPTION="A program to play the abstract board games Zertz, Dvonn and Relax"
  14 HOMEPAGE="http://holtz.sourceforge.net/"
  15 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  16
  17 LICENSE="GPL-2"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 IUSE="linguas_de"
  21
  22 DEPEND="dev-libs/boost x11-libs/wxGTK:${WX_GTK_VER}[X]"
  23 RDEPEND="${DEPEND}"
  24
  25 src_prepare() {
  26         # Restrict localization to selected languages:
  27         echo "SUBDIRS=${LINGUAS}" >locale/Makefile.am || die
  28
  29         # Don't build/install this test program:
  30         sed -i '/^bin_PROGRAMS=/d' relax/Makefile.am || die
  31
  32         eautomake
  33 }
  34
  35 src_configure() {
  36         egamesconf --enable-wxconfig="${WX_CONFIG}"
  37 }
  38
  39 src_install() {
  40         # Install files:
  41         emake DESTDIR="${D}" install || die
  42
  43         # Create a desktop entry with an application icon:
  44         newicon icon.xpm ${PN}.xpm || die
  45         make_desktop_entry ${PN} Holtz ${PN}
  46
  47         prepgamesdirs
  48 }