Pileus Git - ~andy/sunrise/blob - dev-vcs/tortoisehg/tortoisehg-2.0.3.ebuild

   1 # Copyright 1999-2011 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="2"
   6
   7 SUPPORT_PYTHON_ABIS="1"
   8 PYTHON_DEPEND="2:2.5"
   9 RESTRICT_PYTHON_ABIS="2.4 3.*"
  10
  11 inherit distutils multilib
  12
  13 DESCRIPTION="Set of graphical tools for Mercurial"
  14 HOMEPAGE="http://tortoisehg.bitbucket.org"
  15 SRC_URI="http://bitbucket.org/${PN}/targz/downloads/${P}.tar.gz"
  16
  17 LICENSE="GPL-2"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 IUSE="doc nautilus"
  21
  22 RDEPEND="dev-python/iniparse
  23         dev-python/pygments
  24         dev-python/PyQt4
  25         dev-python/qscintilla-python
  26         >=dev-vcs/mercurial-1.8
  27         nautilus? ( dev-python/nautilus-python )"
  28 DEPEND="${RDEPEND}
  29         doc? ( >=dev-python/sphinx-1.0.3 )"
  30
  31 src_prepare() {
  32         # make the install respect multilib.
  33         sed -i -e "s:lib/nautilus:$(get_libdir)/nautilus:" setup.py || die
  34         distutils_src_prepare
  35 }
  36
  37 src_compile() {
  38         distutils_src_compile
  39
  40         if use doc ; then
  41                 emake -C doc html || die
  42         fi
  43 }
  44
  45 src_install() {
  46         distutils_src_install
  47         dodoc doc/ReadMe*.txt doc/TODO || die
  48
  49         if use doc ; then
  50                 dohtml -r doc/build/html || die
  51         fi
  52
  53         if ! use nautilus; then
  54                 rm -vr "${D}usr/$(get_libdir)/nautilus" || die
  55         fi
  56 }