Pileus Git - ~andy/sunrise/blob - dev-util/adobe-air-sdk-bin/adobe-air-sdk-bin-1.5.3.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=2
   6
   7 inherit eutils fdo-mime multilib
   8
   9 DESCRIPTION="Adobe AIR SDK"
  10 HOMEPAGE="http://www.adobe.com/products/air/tools/sdk/"
  11 SRC_URI="http://airdownload.adobe.com/air/lin/download/${PV}/AdobeAIRSDK.tbz2 -> AdobeAIRSDK-${PV}.tbz2"
  12
  13 LICENSE="AdobeAirSDK"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE=""
  17
  18 RDEPEND="app-arch/unzip
  19         x86? ( dev-libs/libxml2
  20                 dev-libs/nspr
  21                 dev-libs/nss
  22                 media-libs/libpng
  23                 net-misc/curl
  24                 www-plugins/adobe-flash
  25                 x11-libs/cairo
  26                 x11-libs/gtk+:2 )
  27         amd64? ( app-emulation/emul-linux-x86-baselibs
  28                 app-emulation/emul-linux-x86-gtklibs )"
  29
  30 QA_PRESTRIPPED=".*\.so
  31         /opt/Adobe/AirSDK/bin/adl"
  32 QA_EXECSTACK="*/libCore.so"
  33
  34 src_install() {
  35         local sdkdir=opt/Adobe/AirSDK
  36         local rtdir='runtimes/air/linux/Adobe AIR/Versions/1.0'
  37
  38         # remove the broken symlinks
  39         rm -r "${rtdir}"/Resources/nss3/{0d,1d,None} || die "removing cruft failed"
  40         if use x86; then
  41                 rm "${rtdir}"/Resources/lib{curl,flashplayer}.so || die "removing cruft failed"
  42         fi
  43
  44         insinto /${sdkdir}
  45         doins -r * || die "doins failed"
  46
  47         cd "${D}"
  48         fperms 0755 ${sdkdir}/bin/* ${sdkdir}/"${rtdir}"/{libCore.so,Resources/lib*.so*} \
  49                 || die "chmod failed"
  50
  51         use x86 && make_wrapper adl /${sdkdir}/bin/adl . /usr/lib/nss:/usr/lib/nspr:/opt/netscape/plugins /opt/bin
  52         use amd64 && make_wrapper adl /${sdkdir}/bin/adl . /usr/lib32:/usr/lib32/nss:/usr/lib32/nspr /opt/bin
  53
  54         exeinto /opt/bin
  55         doexe "${FILESDIR}"/airstart || die "doexe failed"
  56
  57         # install the file association
  58         # (we can't use make_desktop_entry because we like to have NoDisplay)
  59         domenu "${FILESDIR}"/airstart.desktop || die "domenu failed"
  60
  61         insinto /usr/share/mime/packages
  62         doins "${FILESDIR}"/${PN}.xml || die "doins failed"
  63 }
  64
  65 pkg_postinst() {
  66         fdo-mime_desktop_database_update
  67         fdo-mime_mime_database_update
  68 }
  69
  70 pkg_postrm() {
  71         fdo-mime_desktop_database_update
  72         fdo-mime_mime_database_update
  73 }