Pileus Git - ~andy/sunrise/blob - dev-libs/liblightscribe/liblightscribe-1.18.24.1.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="2"
   6
   7 inherit eutils rpm multilib
   8
   9 SDK_PV=1.18.6.1
  10
  11 DESCRIPTION="LightScribe System Software (binary only library)"
  12 HOMEPAGE="http://www.lightscribe.com/downloadSection/linux/index.aspx"
  13 SRC_URI="http://download.lightscribe.com/ls/lightscribe-${PV}-linux-2.6-intel.rpm
  14         http://download.lightscribe.com/ls/lightscribePublicSDK-${SDK_PV}-linux-2.6-intel.rpm"
  15
  16 LICENSE="lightscribe lightscribeSDK"
  17 SLOT="0"
  18 KEYWORDS="~amd64 ~x86"
  19 IUSE="multilib"
  20
  21 RDEPEND="x86? ( sys-libs/libstdc++-v3 )
  22         amd64? ( sys-libs/libstdc++-v3[multilib] )"
  23
  24 RESTRICT="mirror fetch"
  25
  26 S="${WORKDIR}"
  27
  28 QA_PRESTRIPPED="
  29         opt/lightscribe/lib32/liblightscribe.so.0.0.1
  30         opt/lightscribe/lib32/libstdcv3.so.5.0.7
  31         opt/lightscribe/lib/liblightscribe.so.0.0.1
  32         opt/lightscribe/lib/libstdcv3.so.5.0.7"
  33
  34 QA_DT_HASH="
  35         opt/lightscribe/lib32/liblightscribe.so.0.0.1
  36         opt/lightscribe/lib32/libstdcv3.so.5.0.7
  37         opt/lightscribe/lib/liblightscribe.so.0.0.1
  38         opt/lightscribe/lib/libstdcv3.so.5.0.7"
  39
  40 pkg_setup() {
  41         # This is a binary x86 package => ABI=x86
  42         # Please keep this in future versions
  43         has_multilib_profile && ABI="x86"
  44 }
  45
  46 src_prepare() {
  47         # hack in to use provided libstdc++ rename it to libstdcv3
  48         # can't add an rpath or a LD_PRELOAD to a already build lib to work around
  49         # the libstdc++ "no version information available" problem Bug 152031 comment 66
  50         sed -i "s/libstdc++.so.5/libstdcv3.so.5/g" usr/lib/liblightscribe.so.1 || die "sed failed"
  51         sed -i "s/libstdc++.so.5/libstdcv3.so.5/g" usr/lib/lightscribe/libstdc++.so.5.0.7 || die "sed failed"
  52 }
  53
  54 src_install() {
  55         local LSDIR="opt/lightscribe/$(get_libdir)"
  56
  57         exeinto /${LSDIR}/lightscribe/updates
  58         doexe usr/lib/lightscribe/updates/fallback.sh || die "fallback.sh install failed"
  59         exeinto /${LSDIR}/lightscribe
  60         doexe usr/lib/lightscribe/elcu.sh || die "elcu.sh install failed"
  61         into /opt/lightscribe
  62         # make revdep-rebuild happy Bug 152031 comment 74
  63         newlib.so usr/lib/liblightscribe.so.1 liblightscribe.so.0.0.1 || die "liblightscribe.so.* install failed"
  64         newlib.so usr/lib/lightscribe/libstdc++.so.5.0.7 libstdcv3.so.5.0.7 || die "libstdcv3.so.* install failed"
  65         dosym liblightscribe.so.0.0.1 /${LSDIR}/liblightscribe.so
  66         insinto /usr/include/lightscribe
  67         doins -r usr/include/* || die "includes install failed"
  68         insinto /etc
  69         doins -r etc/* || die "config install failed"
  70         sed -e "s%/usr/lib%${ROOT}${LSDIR}%" \
  71             -e"s%update%updates%" -i "${D}"/etc/lightscribe.rc || die "sed failed"
  72         dodoc usr/share/doc/*.* \
  73               usr/share/doc/lightscribe-sdk/*.* \
  74               usr/share/doc/lightscribe-sdk/docs/* || die "doc install failed"
  75         docinto sample/lsprint
  76         dodoc usr/share/doc/lightscribe-sdk/sample/lsprint/* || die "lsprint sample install failed"
  77         dodir /etc/env.d
  78         echo "LDPATH=${ROOT}${LSDIR}" > "${D}"/etc/env.d/80lightscribe
  79 }
  80
  81 pkg_postinst() {
  82         elog "This version also support Enhanced Contrast"
  83         elog "You can activate it by running:"
  84         elog "${ROOT}opt/lightscribe/$(get_libdir)/lightscribe/elcu.sh"
  85 }
  86
  87 pkg_nofetch() {
  88         einfo "Please download the appropriate Lightscribe System Software & Linux Public SDK archive's"
  89         einfo "( lightscribe-${PV}-linux-2.6-intel.rpm"
  90         einfo "  lightscribePublicSDK-${SDK_PV}-linux-2.6-intel.rpm )"
  91         einfo "from ${HOMEPAGE} (requires to accept license)"
  92         einfo
  93         einfo "Then put the files in ${DISTDIR}"
  94 }