Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(gdk/gdktypes.h)
   3
   4 # Save this value here, since automake will set cflags later
   5 cflags_set=${CFLAGS+set}
   6
   7 # Making releases:
   8 #   GTK_MICRO_VERSION += 1;
   9 #   GTK_INTERFACE_AGE += 1;
  10 #   GTK_BINARY_AGE += 1;
  11 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  12 # if backwards compatibility has been broken,
  13 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  14 #
  15 GTK_MAJOR_VERSION=1
  16 GTK_MINOR_VERSION=1
  17 GTK_MICRO_VERSION=2
  18 GTK_INTERFACE_AGE=0
  19 GTK_BINARY_AGE=0
  20 GTK_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$GTK_MICRO_VERSION
  21 AC_SUBST(GTK_MAJOR_VERSION)
  22 AC_SUBST(GTK_MINOR_VERSION)
  23 AC_SUBST(GTK_MICRO_VERSION)
  24 AC_SUBST(GTK_INTERFACE_AGE)
  25 AC_SUBST(GTK_BINARY_AGE)
  26 AC_SUBST(GTK_VERSION)
  27
  28 # libtool versioning
  29 LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  30 LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  31 LT_REVISION=$GTK_INTERFACE_AGE
  32 LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  33 AC_SUBST(LT_RELEASE)
  34 AC_SUBST(LT_CURRENT)
  35 AC_SUBST(LT_REVISION)
  36 AC_SUBST(LT_AGE)
  37
  38 # For automake.
  39 VERSION=$GTK_VERSION
  40 PACKAGE=gtk+
  41
  42 # Save this value here, since automake will set cflags later
  43 cflags_set=${CFLAGS+set}
  44
  45 dnl Initialize automake stuff
  46 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  47
  48 # Specify a configuration file
  49 AM_CONFIG_HEADER(config.h)
  50
  51 dnl Initialize libtool
  52 AM_PROG_LIBTOOL
  53
  54 dnl Initialize maintainer mode
  55 AM_MAINTAINER_MODE
  56
  57 AC_CANONICAL_HOST
  58
  59 AC_ARG_ENABLE(shm, [  --enable-shm            support shared memory if available [default=yes]],
  60                    echo $enable_shm, enable_shm="yes")
  61 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=minimum]],,enable_debug=minimum)
  62 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  63                     , enable_ansi=no)
  64 AC_ARG_WITH(glib, [  --with-glib=DIR         Use uninstalled copy of glib])
  65 AC_ARG_ENABLE(xim, [  --enable-xim            support XIM [default=yes]],
  66                         echo $enable_xim, enable_xim="yes")
  67 AC_ARG_WITH(locale, [  --with-locale=LOCALE    locale name you want to use ])
  68
  69 AC_ARG_WITH(xinput, [  --with-xinput=[no/gxi/xfree] support XInput ])
  70 AC_ARG_WITH(threads, [  --with-threads=[posix] support threading ])
  71
  72 if test "x$enable_debug" = "xyes"; then
  73   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
  74   CFLAGS="$CFLAGS -DG_ENABLE_DEBUG"
  75 else
  76   if test "x$enable_debug" = "xno"; then
  77     CFLAGS="$CFLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DGTK_NO_CHECK_CASTS"
  78   else
  79     CFLAGS="$CFLAGS -DGTK_NO_CHECK_CASTS"
  80   fi
  81 fi
  82
  83 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
  84
  85 # Build time sanity check...
  86 AM_SANITY_CHECK
  87
  88 # Checks for programs.
  89 AC_PROG_CC
  90 AM_PROG_CC_STDC
  91 AC_PROG_INSTALL
  92 AC_PROG_MAKE_SET
  93
  94 if test "x$GCC" = "xyes"; then
  95   if test -z "`echo "$CFLAGS" | grep "\-Wall" 2> /dev/null`" ; then
  96     CFLAGS="$CFLAGS -Wall"
  97   fi
  98
  99   if test "x$enable_ansi" = "xyes"; then
 100     if test -z "`echo "$CFLAGS" | grep "\-ansi" 2> /dev/null`" ; then
 101       CFLAGS="$CFLAGS -ansi"
 102     fi
 103
 104     if test -z "`echo "$CFLAGS" | grep "\-pedantic" 2> /dev/null`" ; then
 105       CFLAGS="$CFLAGS -pedantic"
 106     fi
 107   fi
 108 fi
 109
 110 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 111 gtk_save_LDFLAGS=$LDFLAGS
 112 LIBS="$LIBS -lm"
 113 AC_TRY_RUN([#include <math.h>
 114              int main (void) { return (log(1) != log(1.)); }],
 115      AC_MSG_RESULT(none needed),
 116      gtk_save_CFLAGS=$CFLAGS
 117      CFLAGS="$CFLAGS -std1"
 118      AC_TRY_RUN([#include <math.h>
 119                  int main (void) { return (log(1) != log(1.)); }],
 120          AC_MSG_RESULT(-std1),
 121          AC_MSG_RESULT()
 122          CFLAGS=$gtk_save_CFLAGS
 123          AC_MSG_WARN(
 124                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 125      )
 126 )
 127 LIBS=$gtk_save_LIBS
 128
 129 if test "x$enable_xim" = "xyes"; then
 130   CFLAGS="$CFLAGS -DUSE_XIM"
 131 fi
 132
 133 if test x$with_glib = xyes ; then
 134   AC_MSG_ERROR([
 135 *** Directory must be specified for --with-glib])
 136 fi
 137
 138 if test x$with_glib = x ; then
 139   # Look for separately installed glib
 140
 141   AM_PATH_GLIB(1.1.3,,
 142     AC_MSG_ERROR([
 143 *** GLIB 1.1.3 or better is required. The latest version of GLIB
 144 *** is always available from ftp://ftp.gtk.org.]),
 145     gmodule)
 146
 147   glib_cflags=$GLIB_CFLAGS
 148   glib_libs=$GLIB_LIBS
 149 else
 150   # Use uninstalled glib (assume they got the version right)
 151
 152   if test -x $with_glib/glib-config ; then
 153     :
 154   else
 155     AC_MSG_ERROR([GLIB directory ($with_glib) not present or not configured])
 156   fi
 157
 158   # For use in gtk-config
 159   glib_cflags=`$with_glib/glib-config --cflags`
 160   glib_libs=`$with_glib/glib-config --libs`
 161
 162   glib_release=`$with_glib/glib-config --version | sed 's%\\.[[0-9]]*$%%'`
 163
 164   # canonicalize relative paths
 165   case $with_glib in
 166     /*)
 167       glib_dir=$with_glib
 168       ;;
 169     *)
 170       glib_dir="\$(top_builddir)/$with_glib"
 171       ;;
 172   esac
 173
 174   GLIB_CFLAGS="-I$glib_dir"
 175   GLIB_LIBS=$glib_dir/libglib-$glib_release.la
 176
 177   AC_SUBST(GLIB_CFLAGS)
 178   AC_SUBST(GLIB_LIBS)
 179 fi
 180
 181 AC_SUBST(glib_cflags)
 182 AC_SUBST(glib_libs)
 183
 184 # Find the X11 include and library directories
 185 AC_PATH_X
 186 AC_PATH_XTRA
 187
 188 if test "x$x_includes" = "x"; then
 189   x_includes="/usr/include"
 190 fi
 191
 192 saved_cflags="$CFLAGS"
 193 saved_ldflags="$LDFLAGS"
 194
 195 CFLAGS="$CFLAGS $X_CFLAGS"
 196 LDFLAGS="$LDFLAGS $X_LDFLAGS $X_LIBS"
 197
 198 if test "x$no_x" = "xyes"; then
 199   AC_MSG_ERROR([
 200 *** X libraries or include files not found. Check 'config.log' for
 201 *** more details.])
 202 fi
 203
 204 # Checks for libraries.
 205 # Check for the X11 library
 206 AC_CHECK_LIB(X11, XOpenDisplay, x_libs="-lX11 $X_EXTRA_LIBS",
 207   AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
 208   $X_EXTRA_LIBS)
 209
 210 if test "x$enable_shm" = "xyes"; then
 211   # Check for the Xext library (needed for XShm extention)
 212   AC_CHECK_LIB(Xext, XShmAttach,
 213       x_libs="-lXext $x_libs",
 214       # On AIX, it is in XextSam instead, but we still need -lXext
 215       AC_CHECK_LIB(XextSam, XShmAttach,
 216           x_libs="-lXextSam -lXext $x_libs",
 217           no_xext_lib=yes, $x_libs),
 218       $x_libs)
 219 fi
 220
 221 # Check for shaped window extension
 222
 223 AC_CHECK_LIB(Xext, XShapeCombineMask,
 224       if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 225            x_libs="-lXext $x_libs"
 226       fi
 227       AC_DEFINE(HAVE_SHAPE_EXT),
 228       ,
 229       $x_libs)
 230
 231 # Check for XConvertCase (X11R6 specific)
 232
 233 AC_CHECK_LIB(X11, XConvertCase,
 234       AC_DEFINE(HAVE_XCONVERTCASE),
 235       ,
 236       $x_libs)
 237
 238 x_cflags="$X_CFLAGS"
 239 x_ldflags="$X_LDFLAGS $X_LIBS"
 240
 241 # set up things for XInput
 242
 243 if test "x$with_xinput" = "xgxi" || test "x$with_xinput" = "xyes"; then
 244   AC_DEFINE(XINPUT_GXI)
 245   xinput_progs=gxid
 246   x_libs="-lXi $x_libs"
 247 elif test "x$with_xinput" = "xxfree"; then
 248   AC_DEFINE(XINPUT_XFREE)
 249   x_libs="-lXi $x_libs"
 250 else
 251   AC_DEFINE(XINPUT_NONE)
 252 fi
 253
 254 # Threads
 255
 256 if test "x$with_threads" = "xposix" || test "x$with_threads" = "xyes"; then
 257   AC_CHECK_LIB(pthread, pthread_attr_init,
 258     AC_DEFINE(USE_PTHREADS)
 259     x_libs="$x_libs -lpthread"
 260     CFLAGS="$CFLAGS -D_REENTRANT")
 261 fi
 262
 263 AC_SUBST(x_cflags)
 264 AC_SUBST(x_includes)
 265 AC_SUBST(x_ldflags)
 266 AC_SUBST(x_libs)
 267 AC_SUBST(xinput_progs)
 268
 269 CFLAGS="$saved_cflags"
 270 LDFLAGS="$saved_ldflags"
 271
 272 if test "x$enable_shm" = "xyes"; then
 273   # Check for shared memory
 274   AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
 275   AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
 276
 277   # Check whether shmctl IPC_RMID allowes subsequent attaches
 278   if test "$ac_cv_header_sys_shm_h" = "yes"; then
 279     AC_MSG_CHECKING(whether shmctl IPC_RMID allowes subsequent attaches)
 280     AC_TRY_RUN([
 281           #include <sys/types.h>
 282           #include <sys/ipc.h>
 283           #include <sys/shm.h>
 284           int main()
 285           {
 286             int id;
 287             char *shmaddr;
 288           id = shmget (IPC_PRIVATE, 4, IPC_CREAT | 0777);
 289           if (id == -1)
 290             exit (2);
 291             shmaddr = shmat (id, 0, 0);
 292             shmctl (id, IPC_RMID, 0);
 293             if ((char*) shmat (id, 0, 0) == (char*) -1)
 294             {
 295               shmdt (shmaddr);
 296               exit (1);
 297             }
 298             shmdt (shmaddr);
 299             shmdt (shmaddr);
 300             exit (0);
 301           }
 302       ],
 303       AC_DEFINE(IPC_RMID_DEFERRED_RELEASE)
 304         AC_MSG_RESULT(yes),
 305       AC_MSG_RESULT(no),
 306       AC_MSG_RESULT(assuming no))
 307   fi
 308
 309   # Check for the X shared memory extension header file
 310   AC_MSG_CHECKING(X11/extensions/XShm.h)
 311   if test "x$no_xext_lib" = "xyes"; then
 312     AC_MSG_RESULT(no)
 313     no_xshm=yes
 314   else
 315     if test -f "$x_includes/X11/extensions/XShm.h"; then
 316       AC_MSG_RESULT(yes)
 317       AC_DEFINE(HAVE_XSHM_H)
 318     else
 319       AC_MSG_RESULT(no)
 320       no_xshm=yes
 321     fi
 322   fi
 323 fi
 324
 325 # Check for private display resource base variable
 326 AC_MSG_CHECKING(resource base field in XDisplay)
 327 AC_CACHE_VAL(gtk_cv_display_resource_base,
 328 [AC_TRY_RUN([
 329 #define XLIB_ILLEGAL_ACCESS
 330 #include <X11/Xlib.h>
 331
 332 int
 333 main ()
 334 {
 335   Display *display;
 336
 337   return 0;
 338
 339   display->resource_base;
 340 }],
 341 gtk_cv_display_resource_base="resource_base",
 342 gtk_cv_display_resource_base="private3")])
 343 AC_MSG_RESULT($gtk_cv_display_resource_base)
 344 AC_DEFINE_UNQUOTED(RESOURCE_BASE, gdk_display->$gtk_cv_display_resource_base)
 345
 346 # Check if X_LOCALE definition is necessary
 347
 348 AC_MSG_CHECKING(need -DX_LOCALE)
 349
 350 AC_TRY_RUN([
 351 #include <stdio.h>
 352 #include <locale.h>
 353
 354 int
 355 main ()
 356 {
 357   return setlocale (LC_ALL, "${with_locale}") == NULL;
 358 }],
 359 need_x_locale=no,
 360 need_x_locale=yes)
 361 AC_MSG_RESULT($need_x_locale)
 362
 363 if test $need_x_locale = yes; then
 364   CFLAGS="$CFLAGS -DX_LOCALE"
 365 fi
 366
 367 # Checks for header files.
 368 AC_HEADER_STDC
 369
 370 # Checks for typedefs, structures, and compiler characteristics.
 371 AC_C_CONST
 372
 373 # Checks for endianness (needed by GdkRgb).
 374 AC_C_BIGENDIAN
 375
 376 # Checks for library functions.
 377 AC_TYPE_SIGNAL
 378 AC_FUNC_MMAP
 379
 380 # Check if <sys/select.h> needs to be included for fd_set
 381 AC_MSG_CHECKING([for fd_set])
 382 AC_TRY_COMPILE([#include <sys/types.h>],
 383         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 384 if test $gtk_ok = yes; then
 385     AC_MSG_RESULT([yes, found in sys/types.h])
 386 else
 387     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 388     if test $gtk_ok = yes; then
 389         AC_DEFINE(HAVE_SYS_SELECT_H)
 390         AC_MSG_RESULT([yes, found in sys/select.h])
 391     else
 392         AC_DEFINE(NO_FD_SET)
 393         AC_MSG_RESULT(no)
 394     fi
 395 fi
 396
 397 AC_OUTPUT([
 398 Makefile
 399 gtk-config
 400 docs/Makefile
 401 gdk/Makefile
 402 gtk/Makefile
 403 gtk/gtkfeatures.h
 404 ], [chmod +x gtk-config])