Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(gdk/gdktypes.h)
   3
   4 #
   5 # For each of the libraries we build, we define the following
   6 # substituted variables:
   7 #
   8 # foo_PACKAGES:     pkg-config packages this library requires
   9 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  10 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  11 # foo_DEP_LIBS:     All libraries this module requires
  12 # foo_DEP_CFLAGS:   All cflags this module requires
  13
  14
  15 ## We could have pkg-config uniquify the ldflags and cflags by calling
  16 ## it once with both the GLib and Pango package names, but we don't,
  17 ## someone should fix that.
  18
  19
  20 # Save this value here, since automake will set cflags later
  21 cflags_set=${CFLAGS+set}
  22
  23 dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  24 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  25 GLIB_AC_DIVERT_BEFORE_HELP([
  26 #
  27 # Making releases:
  28 #   GTK_MICRO_VERSION += 1;
  29 #   GTK_INTERFACE_AGE += 1;
  30 #   GTK_BINARY_AGE += 1;
  31 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  32 # if backwards compatibility has been broken,
  33 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  34 #
  35 GTK_MAJOR_VERSION=1
  36 GTK_MINOR_VERSION=3
  37 GTK_MICRO_VERSION=12
  38 GTK_INTERFACE_AGE=0
  39 GTK_BINARY_AGE=0
  40 GTK_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$GTK_MICRO_VERSION
  41 dnl
  42 ])dnl
  43
  44 AC_SUBST(GTK_MAJOR_VERSION)
  45 AC_SUBST(GTK_MINOR_VERSION)
  46 AC_SUBST(GTK_MICRO_VERSION)
  47 AC_SUBST(GTK_INTERFACE_AGE)
  48 AC_SUBST(GTK_BINARY_AGE)
  49 AC_SUBST(GTK_VERSION)
  50
  51 # libtool versioning
  52 LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  53 LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  54 LT_REVISION=$GTK_INTERFACE_AGE
  55 LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  56 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  57 AC_SUBST(LT_RELEASE)
  58 AC_SUBST(LT_CURRENT)
  59 AC_SUBST(LT_REVISION)
  60 AC_SUBST(LT_AGE)
  61 AC_SUBST(LT_CURRENT_MINUS_AGE)
  62
  63 # Define a string for the earliest version that this release has
  64 # binary compatibility with. This is used for module locations.
  65 #
  66 GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  67 AC_SUBST(GTK_BINARY_VERSION)
  68
  69 #
  70 # gdk-pixbuf gets versioned separately, and for now, using standard
  71 # libtool versioning, not GTK+-style versioning
  72 #
  73 GDK_PIXBUF_MAJOR=$GTK_MAJOR_VERSION
  74 GDK_PIXBUF_MINOR=$GTK_MINOR_VERSION
  75 GDK_PIXBUF_MICRO=$GTK_MICRO_VERSION
  76 GDK_PIXBUF_VERSION="${GDK_PIXBUF_MAJOR}.${GDK_PIXBUF_MINOR}.${GDK_PIXBUF_MICRO}"
  77 AC_SUBST(GDK_PIXBUF_MAJOR)
  78 AC_SUBST(GDK_PIXBUF_MINOR)
  79 AC_SUBST(GDK_PIXBUF_MICRO)
  80 AC_SUBST(GDK_PIXBUF_VERSION)
  81
  82 ## Versions of dependencies
  83 GLIB_REQUIRED_VERSION=1.3.12
  84 PANGO_REQUIRED_VERSION=0.23
  85 ATK_REQUIRED_VERSION=0.8
  86
  87 # For automake.
  88 VERSION=$GTK_VERSION
  89 PACKAGE=gtk+
  90
  91 GETTEXT_PACKAGE=gtk20
  92 AC_SUBST(GETTEXT_PACKAGE)
  93 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
  94
  95 # Save this value here, since automake will set cflags later
  96 cflags_set=${CFLAGS+set}
  97
  98 dnl Initialize automake stuff
  99 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
 100
 101 # Specify a configuration file
 102 AM_CONFIG_HEADER(config.h)
 103
 104 dnl Initialize libtool
 105 AC_PROG_CC
 106 AC_LIBTOOL_WIN32_DLL
 107 AM_PROG_LIBTOOL
 108
 109 dnl Set AS and ASFLAGS so that automake 1.5 will be happy
 110 AS="\${CC}"
 111 ASFLAGS="\${CFLAGS}"
 112 AC_SUBST(AS)
 113 AC_SUBST(ASFLAGS)
 114
 115 dnl Initialize maintainer mode
 116 AM_MAINTAINER_MODE
 117
 118 AC_CANONICAL_HOST
 119
 120 AC_MSG_CHECKING([for some Win32 platform])
 121 case "$host" in
 122   *-*-mingw*|*-*-cygwin*)
 123     platform_win32=yes
 124     ;;
 125   *)
 126     platform_win32=no
 127     ;;
 128 esac
 129 AC_MSG_RESULT([$platform_win32])
 130 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 131
 132 AC_MSG_CHECKING([for native Win32])
 133 case "$host" in
 134   *-*-mingw*)
 135     os_win32=yes
 136     ;;
 137   *)
 138     os_win32=no
 139     ;;
 140 esac
 141 AC_MSG_RESULT([$os_win32])
 142 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 143
 144 if test "$os_win32" = "yes"; then
 145   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 146 fi
 147 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 148
 149 dnl figure debugging default, prior to $ac_help setup
 150 dnl
 151 GLIB_AC_DIVERT_BEFORE_HELP([
 152 if test `expr $GTK_MINOR_VERSION \% 2` = 1 ; then
 153         debug_default=yes
 154 else
 155         debug_default=minimum
 156 fi
 157 ])dnl
 158
 159 dnl declare --enable-* args and collect ac_help strings
 160 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 161 AC_ARG_ENABLE(shm, [  --enable-shm            support shared memory if available [default=yes]],
 162                    echo $enable_shm, enable_shm="yes")
 163 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 164                     , enable_ansi=no)
 165 AC_ARG_ENABLE(xim, [  --enable-xim            support XIM [default=yes]],
 166                         , enable_xim="yes")
 167 AC_ARG_ENABLE(xim_inst, [  --disable-xim-inst      does not use xim instantiate callback],
 168                         , enable_xim_inst="maybe")
 169 AC_ARG_ENABLE(xkb, [  --enable-xkb            support XKB [default=maybe]],
 170                         , enable_xkb="maybe")
 171 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 172
 173 AC_ARG_WITH(xinput, [  --with-xinput=[no/gxi/xfree] support XInput ])
 174
 175 AC_ARG_WITH(wintab, [  --with-wintab=DIRECTORY use Wintab API with win32 backend])
 176 AC_ARG_WITH(ie55, [  --with-ie55=DIRECTORY IE5.5 libs and headers (for Active IMM)])
 177
 178 GLIB_AC_DIVERT_BEFORE_HELP([
 179 if test "$platform_win32" = yes; then
 180   gdktarget=win32
 181 else
 182   gdktarget=x11
 183 fi
 184 ])
 185
 186 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/linux-fb/win32]] select GDK target [default=$gdktarget]],
 187         gdktarget=$with_gdktarget)
 188
 189 AC_SUBST(gdktarget)
 190 case $gdktarget in
 191   x11|linux-fb|win32) ;;
 192   *) AC_MSG_ERROR([Invalid target for GDK: use x11, linux-fb or win32.]);;
 193 esac
 194
 195 gdktargetlib=libgdk-$gdktarget-1.3.la
 196 gtktargetlib=libgtk-$gdktarget-1.3.la
 197
 198 AC_SUBST(gdktargetlib)
 199 AC_SUBST(gtktargetlib)
 200
 201 AC_ARG_ENABLE(shadowfb, [  --disable-shadowfb      disable shadowfb support for linux-fb],,enable_shadowfb=yes)
 202
 203 AC_ARG_ENABLE(fbmanager, [  --enable-fbmanager      enable framebuffer manager support (GtkFB)],enable_fbmanager=yes,enable_fbmanager=no)
 204
 205 if test "x$enable_debug" = "xyes"; then
 206   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 207   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 208 else
 209   if test "x$enable_debug" = "xno"; then
 210     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 211   else
 212     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 213   fi
 214 fi
 215
 216 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 217
 218
 219 # Build time sanity check...
 220 AM_SANITY_CHECK
 221
 222 # Checks for programs.
 223 AC_ISC_POSIX
 224 AM_PROG_CC_STDC
 225 AC_PROG_INSTALL
 226 AC_PROG_MAKE_SET
 227
 228 changequote(,)dnl
 229 if test "x$GCC" = "xyes"; then
 230   case " $CFLAGS " in
 231   *[\ \ ]-Wall[\ \      ]*) ;;
 232   *) CFLAGS="$CFLAGS -Wall" ;;
 233   esac
 234
 235   if test "x$enable_ansi" = "xyes"; then
 236     case " $CFLAGS " in
 237     *[\ \       ]-ansi[\ \      ]*) ;;
 238     *) CFLAGS="$CFLAGS -ansi" ;;
 239     esac
 240
 241     case " $CFLAGS " in
 242     *[\ \       ]-pedantic[\ \  ]*) ;;
 243     *) CFLAGS="$CFLAGS -pedantic" ;;
 244     esac
 245   fi
 246
 247   if test "$os_win32" = "yes"; then
 248     case "$CC $CFLAGS " in
 249     *[[\ \      ]]-fnative-struct[[\ \  ]]*) ;;
 250     *) CFLAGS="$CFLAGS -fnative-struct" ;;
 251     esac
 252   fi
 253 fi
 254 changequote([,])dnl
 255
 256 # Honor aclocal flags
 257 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 258
 259 ## Initial sanity check, done here so that users get told they
 260 ## have the wrong dependencies as early in the process as possible.
 261 ## Later on we actually use the cflags/libs from separate pkg-config
 262 ## calls. Oh, also the later pkg-config calls don't include
 263 ## the version requirements since those make the module lists
 264 ## annoying to construct
 265 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION atk >= $ATK_REQUIRED_VERSION pango >= $PANGO_REQUIRED_VERSION)
 266
 267 if test "$os_win32" != yes; then
 268     # libtool option to control which symbols are exported
 269     # right now, symbols starting with _ are not exported
 270     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 271 else
 272     # We currently use .def files on Windows (for gdk-pixbuf, gdk and gtk)
 273     LIBTOOL_EXPORT_OPTIONS=
 274 fi
 275 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 276
 277 # define a MAINT-like variable REBUILD which is set if Perl
 278 # and awk are found, so autogenerated sources can be rebuilt
 279
 280 AC_PROG_AWK
 281 AC_CHECK_PROGS(PERL, perl5 perl)
 282
 283 # We would like indent, but don't require it.
 284 AC_CHECK_PROG(INDENT, indent, indent)
 285
 286 REBUILD=\#
 287 if test "x$enable_rebuilds" = "xyes" && \
 288      test -n "$PERL" && \
 289      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 290      test -n "$AWK" ; then
 291   REBUILD=
 292 fi
 293 AC_SUBST(REBUILD)
 294
 295 AC_CHECK_FUNCS(lstat mkstemp bind_textdomain_codeset)
 296
 297 # sigsetjmp is a macro on some platforms, so AC_CHECK_FUNCS is not reliable
 298 AC_MSG_CHECKING(for sigsetjmp)
 299 AC_TRY_LINK([#include <setjmp.h>], [
 300 sigjmp_buf env;
 301 sigsetjmp(env, 0);
 302 ], gtk_ok=yes, gtk_ok=no)
 303 AC_MSG_RESULT($gtk_ok)
 304 if test "$gtk_ok" = "yes"; then
 305   AC_DEFINE(HAVE_SIGSETJMP)
 306 fi
 307
 308 AC_MSG_CHECKING(whether make is GNU Make)
 309 STRIP_BEGIN=
 310 STRIP_END=
 311 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 312         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 313         STRIP_END=')'
 314         AC_MSG_RESULT(yes)
 315 else
 316         AC_MSG_RESULT(no)
 317 fi
 318 STRIP_DUMMY=
 319 AC_SUBST(STRIP_DUMMY)
 320 AC_SUBST(STRIP_BEGIN)
 321 AC_SUBST(STRIP_END)
 322
 323 # i18n stuff
 324 ALL_LINGUAS="az ca cs da de el en_GB en@IPA es et eu fa fi fr ga gl he hr hu ia it ja ko lt nl nn no pl pt pt_BR ro ru sk sl sp sr sv tr uk vi wa zh_TW zh_CN"
 325 AM_GLIB_GNU_GETTEXT
 326 LIBS="$LIBS $INTLLIBS"
 327
 328 # AM_GLIB_GNU_GETTEXT above substs $DATADIRNAME
 329 # this is the directory where the *.{mo,gmo} files are installed
 330 gtklocaledir='${prefix}/${DATADIRNAME}/locale'
 331 AC_SUBST(gtklocaledir)
 332
 333 dnl The DU4 header files don't provide library prototypes unless
 334 dnl -std1 is given to the native cc.
 335 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 336
 337 gtk_save_LIBS=$LIBS
 338 LIBS="$LIBS -lm"
 339 AC_TRY_RUN([#include <math.h>
 340              int main (void) { return (log(1) != log(1.)); }],
 341      AC_MSG_RESULT(none needed),
 342      gtk_save_CFLAGS="$CFLAGS"
 343      CFLAGS="$CFLAGS -std1"
 344      AC_TRY_RUN([#include <math.h>
 345                  int main (void) { return (log(1) != log(1.)); }],
 346          AC_MSG_RESULT(-std1),
 347          AC_MSG_RESULT()
 348          CFLAGS="$gtk_save_CFLAGS"
 349          AC_MSG_WARN(
 350                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 351          true
 352      ),
 353      AC_MSG_RESULT(none needed)
 354 )
 355 LIBS=$gtk_save_LIBS
 356
 357 MATH_LIB=-lm
 358 AC_MSG_CHECKING(for the BeOS)
 359 case $host in
 360   *-*-beos*)
 361     AC_MSG_RESULT(yes)
 362     MATH_LIB=
 363   ;;
 364   *)
 365     AC_MSG_RESULT(no)
 366   ;;
 367 esac
 368
 369 dnl NeXTStep cc seems to need this
 370 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 371 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 372   AC_MSG_RESULT(none needed),
 373   gtk_save_CFLAGS="$CFLAGS"
 374   CFLAGS="$CFLAGS -posix"
 375   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 376     AC_MSG_RESULT(-posix),
 377     AC_MSG_RESULT()
 378     CFLAGS="$gtk_save_CFLAGS"
 379     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 380
 381 #
 382 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 383 #
 384
 385 GLIB_PACKAGES="gobject-2.0 gmodule-2.0"
 386
 387 AM_PATH_GLIB_2_0($GLIB_REQUIRED_VERSION, :,
 388   AC_MSG_ERROR([
 389 *** GLIB $GLIB_REQUIRED_VERSION or better is required. The latest version of
 390 *** GLIB is always available from ftp://ftp.gtk.org/.]),
 391   gobject gmodule gthread)
 392
 393 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 394 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 395 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 396 AC_CHECK_HEADERS(winsock.h, AC_DEFINE(HAVE_WINSOCK_H))
 397
 398 if test "${with_ie55+set}" = set && test $with_ie55 != no; then
 399   AC_MSG_CHECKING([for dimm.h])
 400   saved_CFLAGS="$CFLAGS"
 401   CFLAGS="$CFLAGS -idirafter $with_ie55/Include"
 402   AC_TRY_COMPILE([#include <windows.h>
 403 #include <objbase.h>
 404 #ifdef __GNUC__
 405 /* The w32api imm.h clashes a bit with the IE5.5 dimm.h */
 406 #define IMEMENUITEMINFOA hidden_IMEMENUITEMINFOA
 407 #define IMEMENUITEMINFOW hidden_IMEMENUITEMINFOW
 408 #include <imm.h>
 409 #undef IMEMENUITEMINFOA
 410 #undef IMEMENUITEMINFOW
 411 #endif
 412 #include <dimm.h>
 413 ],
 414    [],
 415    [AC_MSG_RESULT(yes)
 416     AC_MSG_CHECKING([for IE55 uuid.lib])
 417     if test -f $with_ie55/Lib/uuid.lib ; then
 418       AC_MSG_RESULT(yes)
 419       have_ie55=yes
 420       AC_DEFINE(HAVE_DIMM_H)
 421       IE55_UUID_LIB="$with_ie55/Lib/uuid.lib"
 422       AC_SUBST(IE55_UUID_LIB)
 423     else
 424       AC_MSG_RESULT(no)
 425       CFLAGS="$saved_CFLAGS"
 426       have_ie55=no
 427     fi
 428     ],
 429    [AC_MSG_RESULT(no)
 430     CFLAGS="$saved_CFLAGS"
 431     have_ie55=no])
 432 fi
 433 AM_CONDITIONAL(HAVE_IE55, test x$have_ie55 = xyes)
 434
 435 if test "${with_wintab+set}" = set && test $with_wintab != no; then
 436   AC_MSG_CHECKING([for wintab.h])
 437   saved_CFLAGS="$CFLAGS"
 438   CFLAGS="$CFLAGS -I$with_wintab/include"
 439   AC_TRY_COMPILE([#include <windows.h>
 440 #include <wintab.h>],
 441    [],
 442    [AC_MSG_RESULT(yes)
 443     AC_MSG_CHECKING([for wntab32x.lib])
 444     if test -f $with_wintab/lib/i386/wntab32x.lib ; then
 445       AC_MSG_RESULT(yes)
 446       have_wintab=yes
 447       AC_DEFINE(HAVE_WINTAB)
 448       WINTAB_LIB="$with_wintab/lib/i386/wntab32x.lib"
 449       AC_SUBST(WINTAB_LIB)
 450     else
 451       AC_MSG_RESULT(no)
 452       CFLAGS="$saved_cflags"
 453       have_wintab=no
 454     fi
 455     ],
 456    [AC_MSG_RESULT(no)
 457     CFLAGS="$saved_cflags"
 458     have_wintab=no])
 459 fi
 460 AM_CONDITIONAL(HAVE_WINTAB, test x$have_wintab = xyes)
 461
 462 saved_cflags="$CFLAGS"
 463 saved_ldflags="$LDFLAGS"
 464
 465
 466 # Checks for header files.
 467 AC_HEADER_STDC
 468
 469 # Checks for typedefs, structures, and compiler characteristics.
 470 AC_C_CONST
 471
 472 # Checks for library functions.
 473 AC_TYPE_SIGNAL
 474 AC_FUNC_MMAP
 475
 476 AC_CHECK_FUNCS(getresuid)
 477 AC_TYPE_UID_T
 478
 479 # Check if <sys/select.h> needs to be included for fd_set
 480 AC_MSG_CHECKING([for fd_set])
 481 AC_TRY_COMPILE([#include <sys/types.h>],
 482         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 483 if test $gtk_ok = yes; then
 484     AC_MSG_RESULT([yes, found in sys/types.h])
 485 else
 486     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 487     if test $gtk_ok = yes; then
 488         AC_DEFINE(HAVE_SYS_SELECT_H)
 489         AC_MSG_RESULT([yes, found in sys/select.h])
 490     else
 491         AC_DEFINE(NO_FD_SET)
 492         AC_MSG_RESULT(no)
 493     fi
 494 fi
 495
 496 # `widechar' tests for gdki18n.h
 497 AC_MSG_CHECKING(for wchar.h)
 498 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 499 if test $gdk_wchar_h = yes; then
 500    AC_DEFINE(HAVE_WCHAR_H,1,[Have wchar.h include file])
 501 fi
 502 AC_MSG_RESULT($gdk_wchar_h)
 503
 504 # Check for wctype.h (for iswalnum)
 505 AC_MSG_CHECKING(for wctype.h)
 506 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 507 if test $gdk_wctype_h = yes; then
 508    AC_DEFINE(HAVE_WCTYPE_H,1,[Have wctype.h include file])
 509 fi
 510 AC_MSG_RESULT($gdk_wctype_h)
 511
 512 # in Solaris 2.5, `iswalnum' is in -lw
 513 GDK_WLIBS=
 514 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 515
 516 oLIBS="$LIBS"
 517 LIBS="$LIBS $GDK_WLIBS"
 518 # The following is necessary for Linux libc-5.4.38
 519 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 520 AC_TRY_LINK([#include <stdlib.h>],[
 521 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 522 #  ifdef HAVE_WCTYPE_H
 523 #    include <wctype.h>
 524 #  else
 525 #    ifdef HAVE_WCHAR_H
 526 #      include <wchar.h>
 527 #    endif
 528 #  endif
 529 #else
 530 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 531 #endif
 532 iswalnum((wchar_t) 0);
 533 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 534 LIBS="$oLIBS"
 535
 536 if test $gdk_working_wctype = no; then
 537    AC_DEFINE(HAVE_BROKEN_WCTYPE,1,[Is the wctype implementation broken])
 538    GDK_WLIBS=
 539 fi
 540 AC_MSG_RESULT($gdk_working_wctype)
 541 AC_SUBST(GDK_WLIBS)
 542
 543
 544
 545 ##################################################
 546 # Checks for gdk-pixbuf
 547 ##################################################
 548
 549 AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
 550
 551 AC_ARG_ENABLE(modules, [  --disable-modules       Disables dynamic module loading],[
 552         if test x$withval = xyes; then
 553             with_modules=yes
 554         else
 555             with_modules=no
 556         fi
 557 ])
 558
 559 dynworks=false
 560 deps=
 561 if test x$with_modules = xno; then
 562     AC_MSG_RESULT(no)
 563 else
 564     AC_MSG_RESULT(yes)
 565     AC_MSG_CHECKING(whether dynamic modules work)
 566     ## for loop is to strip newline
 567     tmp=`pkg-config --variable=gmodule_supported gmodule-2.0`
 568     for I in $tmp; do
 569         dynworks=$I
 570     done
 571 fi
 572
 573 dnl Now we check to see if our libtool supports shared lib deps
 574 dnl (in a rather ugly way even)
 575 if $dynworks; then
 576    pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 577    pixbuf_deplibs_check=`$pixbuf_libtool_config | \
 578       grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 579       sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 580    if test "x$pixbuf_deplibs_check" = "xnone" || \
 581       test "x$pixbuf_deplibs_check" = "xunknown" || \
 582       test "x$pixbuf_deplibs_check" = "x"; then
 583       dynworks=false
 584    fi
 585 fi
 586
 587 if $dynworks; then
 588    AC_DEFINE(USE_GMODULE)
 589    AC_MSG_RESULT(yes)
 590 else
 591    AC_MSG_RESULT(no)
 592 fi
 593
 594 dnl Test for libtiff
 595   if test -z "$LIBTIFF"; then
 596     AC_CHECK_LIB(tiff, TIFFReadScanline,
 597       [AC_CHECK_HEADER(tiffio.h,
 598         TIFF='tiff'; LIBTIFF='-ltiff',
 599         AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 600       [AC_CHECK_LIB(tiff, TIFFWriteScanline,
 601         [AC_CHECK_HEADER(tiffio.h,
 602           TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
 603           AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 604         [AC_CHECK_LIB(tiff34, TIFFFlushData,
 605           [AC_CHECK_HEADER(tiffio.h,
 606             TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
 607             AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 608         AC_MSG_WARN(*** TIFF plug-in will not be built (TIFF library not found) ***), -ljpeg -lz -lm)], -ljpeg -lz -lm)], -lm)
 609   fi
 610
 611 dnl Test for libjpeg
 612   if test -z "$LIBJPEG"; then
 613     AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 614       jpeg_ok=yes,
 615       jpeg_ok=no
 616       AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
 617     if test "$jpeg_ok" = yes; then
 618       AC_MSG_CHECKING([for jpeglib.h])
 619       AC_TRY_CPP(
 620 [#include <stdio.h>
 621 #undef PACKAGE
 622 #undef VERSION
 623 #undef HAVE_STDLIB_H
 624 #include <jpeglib.h>],
 625         jpeg_ok=yes,
 626         jpeg_ok=no)
 627       AC_MSG_RESULT($jpeg_ok)
 628       if test "$jpeg_ok" = yes; then
 629         LIBJPEG='-ljpeg'
 630         AC_CHECK_LIB(jpeg, jpeg_simple_progression,
 631           AC_DEFINE(HAVE_PROGRESSIVE_JPEG),
 632           AC_MSG_WARN(JPEG library does not support progressive saving.))
 633       else
 634           AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
 635       fi
 636     fi
 637   fi
 638
 639 dnl Test for libpng
 640   if test -z "$LIBPNG"; then
 641     AC_CHECK_LIB(png, png_read_info,
 642       [AC_CHECK_HEADER(png.h,
 643         png_ok=yes,
 644         png_ok=no)],
 645       AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
 646     if test "$png_ok" = yes; then
 647       AC_MSG_CHECKING([for png_structp in png.h])
 648       AC_TRY_COMPILE([#include <png.h>],
 649         [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 650         png_ok=yes,
 651         png_ok=no)
 652       AC_MSG_RESULT($png_ok)
 653       if test "$png_ok" = yes; then
 654         PNG='png'; LIBPNG='-lpng -lz'
 655       else
 656         AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
 657       fi
 658     else
 659      AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
 660     fi
 661   fi
 662
 663 AC_SUBST(LIBTIFF)
 664 AC_SUBST(LIBJPEG)
 665 AC_SUBST(LIBPNG)
 666
 667 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 668
 669 #
 670 # Allow building some or all gdk-pixbuf loaders included
 671 #
 672 AC_MSG_CHECKING(pixbuf loaders to build)
 673
 674 AC_ARG_WITH(included_loaders, [  --with-included-loaders=LOADER1,LOADER2,... Build the specified loaders into gdk-pixbuf (only used if module loading disabled)])
 675
 676 if $dynworks; then
 677         :
 678 else
 679    ## if the option was specified, leave it; otherwise disable included loaders
 680    if test x$with_included_loaders = xno; then
 681            with_included_loaders=yes
 682    fi
 683 fi
 684
 685 all_loaders="png,bmp,wbmp,gif,ico,jpeg,pnm,ras,tiff,xpm,tga"
 686 included_loaders=""
 687 # If no loaders specified, include all
 688 if test "x$with_included_loaders" = xyes ; then
 689   included_loaders="$all_loaders"
 690 else
 691   included_loaders="$with_included_loaders"
 692 fi
 693
 694 AC_MSG_RESULT($included_loaders)
 695
 696 INCLUDED_LOADER_OBJ=
 697 INCLUDED_LOADER_DEFINE=
 698
 699 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 700 for loader in $included_loaders; do
 701  if echo "$all_loaders" | grep "\(^\|\,\)$loader\(\$\|\,\)" > /dev/null; then
 702    :
 703  else
 704    AC_MSG_ERROR([the specified loader $loader does not exist])
 705  fi
 706
 707  INCLUDED_LOADER_OBJ="$INCLUDED_LOADER_OBJ libpixbufloader-static-$loader.la"
 708  INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_$loader"
 709 done
 710 IFS="$gtk_save_ifs"
 711 AC_SUBST(INCLUDED_LOADER_OBJ)
 712 AC_SUBST(INCLUDED_LOADER_DEFINE)
 713
 714 AC_HEADER_SYS_WAIT
 715
 716 AC_TYPE_SIGNAL
 717
 718 AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
 719 AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
 720 AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
 721
 722 if $dynworks ; then
 723   STATIC_LIB_DEPS=
 724   if echo "$included_loaders" | grep "\(^\|\,\)tiff\(\$\|\,\)" > /dev/null; then
 725     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBTIFF"
 726   fi
 727   if echo "$included_loaders" | grep "\(^\|\,\)jpeg\(\$\|\,\)" > /dev/null; then
 728     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBJPEG"
 729   fi
 730   if echo "$included_loaders" | grep "\(^\|\,\)png\(\$\|\,\)" > /dev/null; then
 731     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBPNG"
 732   fi
 733 else
 734   STATIC_LIB_DEPS="$LIBTIFF $LIBJPEG $LIBPNG"
 735 fi
 736
 737 # Checks to see if we should compile in MMX support (there will be
 738 # a runtime test when the code is actually run to see if it should
 739 # be used - this just checks if we can compile it.)
 740 #
 741 # This code is partially taken from Mesa
 742 #
 743 AC_MSG_CHECKING(for x86 platform)
 744 case $host_cpu in
 745   i386|i486|i586|i686|i786|k6|k7)
 746         use_x86_asm=yes
 747         ;;
 748    *)
 749         use_x86_asm=no
 750 esac
 751 AC_MSG_RESULT($use_x86_asm)
 752
 753 use_mmx_asm=no
 754 if test $use_x86_asm = yes; then
 755     save_ac_ext=$ac_ext
 756     ac_ext=S
 757
 758     AC_MSG_CHECKING(compiler support for MMX)
 759     cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
 760     if AC_TRY_EVAL(ac_compile); then
 761         use_mmx_asm=yes
 762     fi
 763
 764     rm -rf conftest*
 765
 766     ac_ext=$save_ac_ext
 767     if test $use_mmx_asm = yes; then
 768       AC_DEFINE(USE_MMX)
 769       AC_MSG_RESULT(yes)
 770     else
 771       AC_MSG_RESULT(no)
 772     fi
 773 fi
 774
 775 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
 776
 777
 778 GDK_PIXBUF_PACKAGES="gmodule-2.0 gobject-2.0"
 779 GDK_PIXBUF_EXTRA_LIBS="$STATIC_LIB_DEPS $MATH_LIB"
 780 GDK_PIXBUF_EXTRA_CFLAGS=
 781 GDK_PIXBUF_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
 782 GDK_PIXBUF_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS"
 783
 784 AC_SUBST(GDK_PIXBUF_PACKAGES)
 785 AC_SUBST(GDK_PIXBUF_EXTRA_LIBS)
 786 AC_SUBST(GDK_PIXBUF_EXTRA_CFLAGS)
 787 AC_SUBST(GDK_PIXBUF_DEP_LIBS)
 788 AC_SUBST(GDK_PIXBUF_DEP_CFLAGS)
 789
 790
 791 ########################################
 792 # Windowing system checks
 793 ########################################
 794
 795 GDK_EXTRA_LIBS=$GDK_WLIBS
 796 GDK_EXTRA_CFLAGS=
 797
 798 if test "x$gdktarget" = "xx11"; then
 799   # We start off with the libraries from Pango
 800
 801   ## be sure we also have Pango built with xft support
 802   if $PKG_CONFIG --exists pangoxft ; then
 803     PANGO_PACKAGES="pangox pangoxft"
 804     have_xft=true
 805     AC_DEFINE(HAVE_XFT)
 806   else
 807     PANGO_PACKAGES="pangox"
 808     have_xft=false
 809   fi
 810
 811   AM_CONDITIONAL(HAVE_XFT, $have_xft)
 812
 813   x_libs="`$PKG_CONFIG --libs $PANGO_PACKAGES`"
 814   x_cflags="`$PKG_CONFIG --cflags $PANGO_PACKAGES`"
 815   x_extra_libs=
 816
 817   ## Strip the .la files
 818
 819   x_libs_for_checks=""
 820   for I in $x_libs ; do
 821     case $I in
 822       *.la) ;;
 823       *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 824     esac
 825   done
 826
 827   # Sanity check for the X11 library
 828   AC_CHECK_LIB(X11, XOpenDisplay, :,
 829             AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
 830             $x_libs_for_checks)
 831
 832   if test "x$enable_shm" = "xyes"; then
 833     # Check for the Xext library (needed for XShm extention)
 834     AC_CHECK_LIB(Xext, XShmAttach,
 835         if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 836           x_extra_libs="-lXext"
 837         fi,
 838         # On AIX, it is in XextSam instead, but we still need -lXext
 839         AC_CHECK_LIB(XextSam, XShmAttach,
 840             if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 841                x_extra_libs="-lXextSam -lXext"
 842             else
 843                x_extra_libs="-lXextSam"
 844             fi, , $x_libs_for_checks),
 845         $x_libs_for_checks)
 846   fi
 847
 848   GDK_PIXBUF_XLIB_EXTRA_CFLAGS="$x_cflags"
 849   # Don't ever pull in the pangoxft libraries for gdk-pixbuf-x11
 850   GDK_PIXBUF_XLIB_EXTRA_LIBS="$x_extra_libs `$PKG_CONFIG --libs pangox`"
 851
 852   # Check for shaped window extension
 853
 854   AC_CHECK_LIB(Xext, XShapeCombineMask,
 855       if test -z "`echo $x_extra_libs $x_libs | grep "\-lXext" 2> /dev/null`"; then
 856            x_extra_libs="-lXext $x_extra_libs"
 857       fi
 858       AC_DEFINE(HAVE_SHAPE_EXT),
 859       ,
 860       $x_libs_for_checks)
 861
 862   # Check for XConvertCase (X11R6 specific)
 863
 864   AC_CHECK_LIB(X11, XConvertCase,
 865       AC_DEFINE(HAVE_XCONVERTCASE),
 866       ,
 867       $x_libs_for_checks)
 868
 869   # Check for XIM support.
 870
 871   AC_CHECK_LIB(X11, XUnregisterIMInstantiateCallback,
 872             : ,
 873             enable_xim_inst="no",
 874             $x_libs_for_checks)
 875
 876   # On Solaris, calling XRegisterIMInstantiateCallback seems to
 877   # cause an immediate segfault, so we disable it, unless
 878   # the user specifically forces it to be on.
 879
 880   if test x$enable_xim_inst = xmaybe ; then
 881     case host in
 882           *-*-solaris*)
 883             enable_xim_inst="no"
 884             ;;
 885           *)
 886             enable_xim_inst="yes"
 887             ;;
 888     esac
 889   fi
 890
 891   if test "x$enable_xim" = "xyes"; then
 892     GTK_XIM_FLAGS="-DUSE_XIM"
 893     if test "x$enable_xim_inst" = "xyes"; then
 894       AC_DEFINE(USE_X11R6_XIM)
 895     fi
 896   fi
 897
 898   # Check for XKB support.
 899
 900   if test "x$enable_xkb" = "xyes"; then
 901         AC_MSG_WARN(XKB support explicitly enabled)
 902         AC_DEFINE(HAVE_XKB)
 903   elif test "x$enable_xkb" = "xmaybe"; then
 904         AC_CHECK_LIB(X11, XkbQueryExtension,
 905                      AC_DEFINE(HAVE_XKB),
 906                      ,
 907                      $x_libs_for_checks)
 908   else
 909         AC_MSG_WARN(XKB support explicitly disabled)
 910   fi
 911
 912   x_cflags="$X_CFLAGS"
 913   x_ldflags="$X_LDFLAGS"
 914
 915   # set up things for XInput
 916
 917   if test "x$with_xinput" = "xgxi" || test "x$with_xinput" = "xyes"; then
 918     AC_DEFINE(XINPUT_GXI)
 919     xinput_progs=gxid
 920     x_extra_libs="-lXi $x_extra_libs"
 921   elif test "x$with_xinput" = "xxfree"; then
 922     AC_DEFINE(XINPUT_XFREE)
 923     x_extra_libs="-lXi $x_extra_libs"
 924   else
 925     AC_DEFINE(XINPUT_NONE)
 926   fi
 927
 928   AM_CONDITIONAL(XINPUT_GXI, test x$with_xinput = xgxi)
 929   AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree)
 930
 931   if test "x$enable_shm" = "xyes"; then
 932     # Check for shared memory
 933     AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
 934     AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
 935
 936     # Check for the X shared memory extension header file
 937     have_xshm=no
 938     AC_MSG_CHECKING(X11/extensions/XShm.h)
 939     if test "x$no_xext_lib" = "xyes"; then
 940       :
 941     else
 942       gtk_save_CFLAGS="$CFLAGS"
 943       CFLAGS="$CFLAGS $x_cflags"
 944       AC_TRY_COMPILE([
 945 #include <stdlib.h>
 946 #include <sys/types.h>
 947 #include <sys/ipc.h>
 948 #include <sys/shm.h>
 949 #include <X11/Xlib.h>
 950 #include <X11/Xutil.h>
 951 #include <X11/extensions/XShm.h>
 952 ], [XShmSegmentInfo *x_shm_info;], have_xshm=yes)
 953       CFLAGS="$gtk_save_CFLAGS"
 954     fi
 955     AC_MSG_RESULT($have_xshm)
 956     if test $have_xshm = yes ; then
 957       AC_DEFINE(HAVE_XSHM_H)
 958     fi
 959   fi
 960
 961   GDK_EXTRA_CFLAGS=
 962   GDK_EXTRA_LIBS="$x_extra_libs"
 963
 964   AM_CONDITIONAL(USE_X11, true)
 965 else
 966   AM_CONDITIONAL(USE_X11, false)
 967 fi
 968
 969 if test "x$gdktarget" = "xwin32"; then
 970   # We start off with the libraries from Pango
 971
 972   ## be sure we also have Pango built with win32 support
 973   PANGO_PACKAGES="pangowin32"
 974
 975   if test x$have_wintab = xyes; then
 976     GDK_WIN32_EXTRA_CFLAGS="-I $with_wintab/include"
 977     AC_SUBST(GDK_WIN32_EXTRA_CFLAGS)
 978   fi
 979
 980   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -user32 -limm32 -lshell32 -lole32 -luuid"
 981   AM_CONDITIONAL(USE_WIN32, true)
 982 else
 983   AM_CONDITIONAL(USE_WIN32, false)
 984 fi
 985
 986 AC_SUBST(xinput_progs)
 987
 988 GDK_PIXBUF_XLIB_PACKAGES=
 989 GDK_PIXBUF_XLIB_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_XLIB_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
 990 GDK_PIXBUF_XLIB_DEP_CFLAGS="`$PKG_CONFIG --cflags  $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_PIXBUF_XLIB_EXTRA_CFLAGS"
 991
 992 AC_SUBST(GDK_PIXBUF_XLIB_PACKAGES)
 993 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_LIBS)
 994 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_CFLAGS)
 995 AC_SUBST(GDK_PIXBUF_XLIB_DEP_LIBS)
 996 AC_SUBST(GDK_PIXBUF_XLIB_DEP_CFLAGS)
 997
 998 if test "x$gdktarget" = "xlinux-fb"; then
 999   AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
1000   if test x$FREETYPE_CONFIG = xno ; then
1001     AC_MSG_ERROR([*** freetype-config not found])
1002   fi
1003
1004   FREETYPE_CFLAGS="`$FREETYPE_CONFIG --cflags`"
1005   FREETYPE_LIBS="`$FREETYPE_CONFIG --libs`"
1006   CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
1007
1008   if test x$enable_shadowfb = xyes ; then
1009     AC_DEFINE(ENABLE_SHADOW_FB)
1010   fi
1011
1012   if test x$enable_fbmanager = xyes ; then
1013     AC_DEFINE(ENABLE_FB_MANAGER)
1014     AM_CONDITIONAL(ENABLE_FB_MANAGER, true)
1015   else
1016     AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
1017   fi
1018
1019   GDK_EXTRA_CFLAGS="$FREETYPE_CFLAGS"
1020   GDK_EXTRA_LIBS="$FREETYPE_LIBS $GDK_EXTRA_LIBS"
1021
1022   AM_CONDITIONAL(USE_LINUX_FB, true)
1023 else
1024   AM_CONDITIONAL(USE_LINUX_FB, false)
1025   AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
1026 fi
1027
1028 #
1029 # Pick correct Pango packages to use
1030 #
1031
1032 if test "x$gdktarget" = "xx11"; then
1033         if $have_xft = true ; then
1034             PANGO_PACKAGES="pangox pangoxft"
1035         else
1036             PANGO_PACKAGES=pangox
1037         fi
1038 elif test "x$gdktarget" = "xwin32"; then
1039         PANGO_PACKAGES=pangowin32
1040 elif test "x$gdktarget" = "xlinux-fb"; then
1041         PANGO_PACKAGES=pangoft2
1042 else
1043         PANGO_PACKAGES=pango
1044 fi
1045
1046 # Check for Pango flags
1047
1048 AC_MSG_CHECKING(Pango flags)
1049 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1050         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1051         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1052
1053         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1054 else
1055         AC_MSG_ERROR([
1056 *** Pango not found. Pango is required to build GTK+.
1057 *** See http://www.pango.org for Pango information.
1058 *** For the framebuffer target, you will need to build
1059 *** Pango with freetype support.
1060 ])
1061 fi
1062
1063 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1064
1065 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1066         :
1067 else
1068         AC_CHECK_LIB(pango, pango_context_new, :, AC_MSG_ERROR([
1069 *** Can't link to Pango. Pango is required to build
1070 *** GTK+. For more information see http://www.pango.org]), $PANGO_LIBS)
1071 fi
1072
1073 CFLAGS="$saved_cflags"
1074 LDFLAGS="$saved_ldflags"
1075
1076 GDK_PACKAGES=$PANGO_PACKAGES
1077 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
1078 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS"
1079
1080 AC_SUBST(GDK_PACKAGES)
1081 AC_SUBST(GDK_EXTRA_LIBS)
1082 AC_SUBST(GDK_EXTRA_CFLAGS)
1083 AC_SUBST(GDK_DEP_LIBS)
1084 AC_SUBST(GDK_DEP_CFLAGS)
1085
1086
1087 ########################################
1088 # Check for Accessibility Toolkit flags
1089 ########################################
1090
1091 ATK_PACKAGES=atk
1092 AC_MSG_CHECKING(ATK flags)
1093 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1094         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1095         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1096
1097         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1098 else
1099         AC_MSG_ERROR([
1100 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1101 *** to build GTK+.
1102 ])
1103 fi
1104
1105 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1106         :
1107 else
1108         AC_CHECK_LIB(atk, atk_object_get_type, : , AC_MSG_ERROR([
1109                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1110                 *** to build GTK+]), $ATK_LIBS $GLIB_LIBS)
1111 fi
1112
1113 GTK_PACKAGES=atk
1114 GTK_EXTRA_LIBS=
1115 GTK_EXTRA_CFLAGS=
1116 GTK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GTK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GTK_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
1117 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  $GTK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1118
1119 AC_SUBST(GTK_PACKAGES)
1120 AC_SUBST(GTK_EXTRA_LIBS)
1121 AC_SUBST(GTK_EXTRA_CFLAGS)
1122 AC_SUBST(GTK_DEP_LIBS)
1123 AC_SUBST(GTK_DEP_CFLAGS)
1124
1125
1126 AC_SUBST(GTK_DEBUG_FLAGS)
1127 AC_SUBST(GTK_XIM_FLAGS)
1128
1129 ##################################################
1130 # Checks for gtk-doc and docbook-tools
1131 ##################################################
1132
1133 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH    path to installed docs ])
1134
1135 if test "x$with_html_dir" = "x" ; then
1136   HTML_DIR='${datadir}/gtk-doc/html'
1137 else
1138   HTML_DIR=$with_html_dir
1139 fi
1140
1141 AC_SUBST(HTML_DIR)
1142
1143 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1144
1145 gtk_doc_min_version=0.6
1146 if $GTKDOC ; then
1147     gtk_doc_version=`gtkdoc-mkdb --version`
1148     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
1149     if perl <<EOF ; then
1150       exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
1151             ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
1152 EOF
1153       AC_MSG_RESULT(yes)
1154    else
1155       AC_MSG_RESULT(no)
1156       GTKDOC=false
1157    fi
1158 fi
1159
1160 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1161 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1162
1163 dnl Let people disable the gtk-doc stuff.
1164 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc        Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1165
1166 if test x$enable_gtk_doc = xauto ; then
1167   if test x$GTKDOC = xtrue ; then
1168     enable_gtk_doc=yes
1169   else
1170     enable_gtk_doc=no
1171   fi
1172 fi
1173
1174 dnl NOTE: We need to use a separate automake conditional for this
1175 dnl       to make this work with the tarballs.
1176 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1177
1178
1179 ##################################################
1180 # Output commands
1181 ##################################################
1182
1183 AC_OUTPUT_COMMANDS([
1184
1185 ## Generate `gdk/gdkconfig.h' in two cases
1186 ## 1. `config.status' is run either explicitly, or via configure.
1187 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1188 ##     config.h
1189 ## 2. CONFIG_OTHER is set explicitly
1190 ##
1191 ## Case 1 is difficult.  We know that `automake' sets one of
1192 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1193 ## only when AM_CONFIG_HEADER is set, however.
1194
1195 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1196   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1197   CONFIG_OTHER=${CONFIG_OTHER:-gdk/gdkconfig.h}
1198 fi
1199 case "$CONFIG_OTHER" in
1200 *gdk/gdkconfig.h*)
1201         echo creating gdk/gdkconfig.h
1202         outfile=gdkconfig.h-tmp
1203         cat > $outfile <<\_______EOF
1204 /* gdkconfig.h
1205  *
1206  * This is a generated file.  Please modify `configure.in'
1207  */
1208
1209 #ifndef GDKCONFIG_H
1210 #define GDKCONFIG_H
1211
1212 #ifdef __cplusplus
1213 extern "C" {
1214 #endif /* __cplusplus */
1215
1216 _______EOF
1217
1218         cat >>$outfile <<_______EOF
1219 $gdk_windowing
1220 $gdk_wc
1221 _______EOF
1222
1223         cat >>$outfile <<_______EOF
1224
1225 #ifdef __cplusplus
1226 }
1227 #endif /* __cplusplus */
1228
1229 #endif /* GDKCONFIG_H */
1230 _______EOF
1231
1232
1233         if cmp -s $outfile gdk/gdkconfig.h; then
1234           echo gdk/gdkconfig.h is unchanged
1235           rm -f $outfile
1236         else
1237           mv $outfile gdk/gdkconfig.h
1238         fi ;;
1239 esac
1240 ],[
1241 if test "x$gdktarget" = "xx11" ; then
1242   gdk_windowing='
1243 #define GDK_WINDOWING_X11'
1244 elif test "x$gdktarget" = "xwin32" ; then
1245   gdk_windowing='
1246 #define GDK_WINDOWING_WIN32'
1247 elif test "x$gdktarget" = "xlinux-fb" ; then
1248   gdk_windowing='
1249 #define GDK_WINDOWING_FB
1250 #define GDK_NATIVE_WINDOW_POINTER'
1251 fi
1252
1253 if test x$gdk_wchar_h = xyes; then
1254   gdk_wc='
1255 #define GDK_HAVE_WCHAR_H 1'
1256 fi
1257 if test x$gdk_wctype_h = xyes; then
1258   gdk_wc="\$gdk_wc
1259 #define GDK_HAVE_WCTYPE_H 1"
1260 fi
1261 if test x$gdk_working_wctype = xno; then
1262   gdk_wc="\$gdk_wc
1263 #define GDK_HAVE_BROKEN_WCTYPE 1"
1264 fi
1265
1266
1267 ])
1268
1269 AC_PATH_PROG(SGML2HTML, sgml2html, no)
1270 AM_CONDITIONAL(HAVE_SGML2HTML, ! test x$SGML2HTML = xno)
1271
1272 AC_OUTPUT([
1273 config.h.win32
1274 gtk-zip.sh
1275 gtk+.spec
1276 Makefile
1277 gdk-pixbuf-2.0.pc
1278 gdk-2.0.pc
1279 gtk+-2.0.pc
1280 gdk-pixbuf-2.0-uninstalled.pc
1281 gdk-2.0-uninstalled.pc
1282 gtk+-2.0-uninstalled.pc
1283 m4macros/Makefile
1284 po/Makefile.in
1285 build/Makefile
1286 build/win32/Makefile
1287 build/win32/dirent/Makefile
1288 demos/Makefile
1289 demos/gtk-demo/Makefile
1290 tests/Makefile
1291 docs/Makefile
1292 docs/reference/Makefile
1293 docs/reference/gdk-pixbuf/Makefile
1294 docs/reference/gdk/Makefile
1295 docs/reference/gtk/Makefile
1296 docs/faq/Makefile
1297 docs/tutorial/Makefile
1298 gdk-pixbuf/Makefile
1299 gdk-pixbuf/makefile.mingw
1300 gdk-pixbuf/gdk-pixbuf-features.h
1301 gdk-pixbuf/pixops/Makefile
1302 gdk-pixbuf/pixops/makefile.mingw
1303 gdk/Makefile
1304 gdk/makefile.mingw
1305 gdk/x11/Makefile
1306 gdk/win32/Makefile
1307 gdk/win32/makefile.mingw
1308 gdk/win32/rc/Makefile
1309 gdk/win32/rc/gdk.rc
1310 gdk/linux-fb/Makefile
1311 gtk/Makefile
1312 gtk/makefile.mingw
1313 gtk/makefile.msc
1314 gtk/gtkversion.h
1315 gtk/gtk-win32.rc
1316 gtk/stock-icons/Makefile
1317 modules/Makefile
1318 modules/input/Makefile
1319 contrib/Makefile
1320 contrib/gdk-pixbuf-xlib/Makefile
1321 contrib/gdk-pixbuf-xlib/gdk-pixbuf-xlib-2.0.pc
1322 ])