Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 # Making releases:
   6 #   GTK_MICRO_VERSION += 1;
   7 #   GTK_INTERFACE_AGE += 1;
   8 #   GTK_BINARY_AGE += 1;
   9 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  10 # if backwards compatibility has been broken,
  11 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  12
  13 m4_define([gtk_major_version], [2])
  14 m4_define([gtk_minor_version], [5])
  15 m4_define([gtk_micro_version], [6])
  16 m4_define([gtk_version],
  17           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  18 m4_define([gtk_interface_age], [0])
  19 m4_define([gtk_binary_age],
  20           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  21 # This is the X.Y used in -lgtk-FOO-X.Y
  22 m4_define([gtk_api_version], [2.0])
  23
  24 # Define a string for the earliest version that this release has
  25 # forward/backwards binary compatibility with. This is used for module
  26 # locations. (Should this be backwards-compat instead?)
  27 #
  28 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  29 m4_define([gtk_binary_version], [2.4.0])
  30
  31 # required versions of other packages
  32 m4_define([glib_required_version], [2.5.4])
  33 m4_define([pango_required_version], [1.5.1])
  34 m4_define([atk_required_version], [1.0.1])
  35
  36
  37 AC_INIT([gtk+], [gtk_version],
  38         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk+],
  39         [gtk+])
  40
  41 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  42
  43 # Save this value here, since automake will set cflags later
  44 cflags_set=${CFLAGS+set}
  45
  46 AM_INIT_AUTOMAKE(no-define)
  47 AM_CONFIG_HEADER(config.h)
  48
  49 #
  50 # For each of the libraries we build, we define the following
  51
  52 # substituted variables:
  53 #
  54 # foo_PACKAGES:     pkg-config packages this library requires
  55 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  56 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  57 # foo_DEP_LIBS:     All libraries this module requires
  58 # foo_DEP_CFLAGS:   All cflags this module requires
  59
  60
  61 GTK_MAJOR_VERSION=gtk_major_version
  62 GTK_MINOR_VERSION=gtk_minor_version
  63 GTK_MICRO_VERSION=gtk_micro_version
  64 GTK_INTERFACE_AGE=gtk_interface_age
  65 GTK_BINARY_AGE=gtk_binary_age
  66 GTK_VERSION=gtk_version
  67 GTK_API_VERSION=gtk_api_version
  68 GTK_BINARY_VERSION=gtk_binary_version
  69 AC_SUBST(GTK_MAJOR_VERSION)
  70 AC_SUBST(GTK_MINOR_VERSION)
  71 AC_SUBST(GTK_MICRO_VERSION)
  72 AC_SUBST(GTK_INTERFACE_AGE)
  73 AC_SUBST(GTK_BINARY_AGE)
  74 AC_SUBST(GTK_API_VERSION)
  75 AC_SUBST(GTK_VERSION)
  76 AC_SUBST(GTK_BINARY_VERSION)
  77
  78 # libtool versioning
  79 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  80 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  81 #LT_REVISION=$GTK_INTERFACE_AGE
  82 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  83 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  84
  85 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
  86 m4_define([lt_revision], [gtk_interface_age])
  87 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
  88 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
  89 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
  90 AC_SUBST(LT_VERSION_INFO)
  91 AC_SUBST(LT_CURRENT_MINUS_AGE)
  92
  93
  94 #
  95 # gdk-pixbuf gets versioned separately, and for now, using standard
  96 # libtool versioning, not GTK+-style versioning
  97 #
  98 GDK_PIXBUF_MAJOR=gtk_major_version
  99 GDK_PIXBUF_MINOR=gtk_minor_version
 100 GDK_PIXBUF_MICRO=gtk_micro_version
 101 GDK_PIXBUF_VERSION="${GDK_PIXBUF_MAJOR}.${GDK_PIXBUF_MINOR}.${GDK_PIXBUF_MICRO}"
 102 AC_SUBST(GDK_PIXBUF_MAJOR)
 103 AC_SUBST(GDK_PIXBUF_MINOR)
 104 AC_SUBST(GDK_PIXBUF_MICRO)
 105 AC_SUBST(GDK_PIXBUF_VERSION)
 106
 107 GETTEXT_PACKAGE=gtk20
 108 AC_SUBST(GETTEXT_PACKAGE)
 109 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
 110
 111 AC_CANONICAL_HOST
 112
 113 MATH_LIB=-lm
 114 AC_MSG_CHECKING([for native Win32])
 115 case "$host" in
 116   *-*-mingw*)
 117     os_win32=yes
 118     MATH_LIB=
 119     ;;
 120   *)
 121     os_win32=no
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$os_win32])
 125
 126 dnl Initialize libtool
 127 AC_PROG_CC
 128 AM_DISABLE_STATIC
 129
 130 if test "$os_win32" = "yes"; then
 131   if test x$enable_static = xyes -o x$enable_static = x; then
 132     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 133     enable_static=no
 134   fi
 135   if test x$enable_shared = xno; then
 136     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 137   fi
 138   enable_shared=yes
 139 fi
 140
 141 AM_PROG_LIBTOOL
 142
 143 # Make sure we use 64-bit versions of various file stuff.
 144 AC_SYS_LARGEFILE
 145
 146 AM_PROG_AS
 147
 148 dnl Initialize maintainer mode
 149 AM_MAINTAINER_MODE
 150
 151 AC_MSG_CHECKING([for some Win32 platform])
 152 case "$host" in
 153   *-*-mingw*|*-*-cygwin*)
 154     platform_win32=yes
 155     ;;
 156   *)
 157     platform_win32=no
 158     ;;
 159 esac
 160 AC_MSG_RESULT([$platform_win32])
 161 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 162
 163 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 164 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 165
 166 if test "$os_win32" = "yes"; then
 167   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 168 fi
 169 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 170
 171 m4_define([debug_default],
 172           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 173
 174 dnl declare --enable-* args and collect ac_help strings
 175 AC_ARG_ENABLE(debug,
 176               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 177                              [turn on debugging @<:@default=debug_default@:>@]),,
 178               enable_debug=debug_default)
 179 AC_ARG_ENABLE(shm,
 180               [AC_HELP_STRING([--enable-shm],
 181                               [support shared memory if available [default=yes]])],,
 182               [enable_shm="yes"])
 183 AC_ARG_ENABLE(ansi,
 184               [AC_HELP_STRING([--enable-ansi],
 185                               [turn on strict ansi [default=no]])],,
 186               [enable_ansi=no])
 187 AC_ARG_ENABLE(xkb,
 188               [AC_HELP_STRING([--enable-xkb],
 189                               [support XKB [default=maybe]])],,
 190               [enable_xkb="maybe"])
 191 AC_ARG_ENABLE(rebuilds,
 192               [AC_HELP_STRING([--disable-rebuilds],
 193                               [disable all source autogeneration rules])],,
 194               [enable_rebuilds=yes])
 195 AC_ARG_ENABLE(visibility,
 196               [AC_HELP_STRING([--disable-visibility],
 197                               [don't use ELF visibility attributes])],,
 198               [enable_visibility=yes])
 199
 200 AC_ARG_WITH(xinput,
 201             [AC_HELP_STRING([--with-xinput=@<:@no/yes@:>@], [support XInput])])
 202
 203 AC_ARG_WITH(wintab,
 204             [AC_HELP_STRING([--with-wintab=DIRECTORY],
 205                             [use Wintab API with win32 backend])])
 206 AC_ARG_WITH(ie55,
 207             [AC_HELP_STRING([--with-ie55=DIRECTORY],
 208                             [IE5.5 libs and headers (for Active IMM)])])
 209
 210 GLIB_AC_DIVERT_BEFORE_HELP([
 211 if test "$platform_win32" = yes; then
 212   gdktarget=win32
 213 else
 214   gdktarget=x11
 215 fi
 216 ])
 217
 218 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/linux-fb/win32]] select GDK target [default=$gdktarget]],
 219         gdktarget=$with_gdktarget)
 220
 221 AC_SUBST(gdktarget)
 222 case $gdktarget in
 223   x11|linux-fb|win32) ;;
 224   *) AC_MSG_ERROR([Invalid target for GDK: use x11, linux-fb or win32.]);;
 225 esac
 226
 227 gdktargetlib=libgdk-$gdktarget-$GTK_API_VERSION.la
 228 gtktargetlib=libgtk-$gdktarget-$GTK_API_VERSION.la
 229
 230 AC_SUBST(gdktargetlib)
 231 AC_SUBST(gtktargetlib)
 232
 233 AC_ARG_ENABLE(shadowfb,
 234               [AC_HELP_STRING([--disable-shadowfb],
 235                               [disable shadowfb support for linux-fb])],,
 236               [enable_shadowfb=yes])
 237
 238 AC_ARG_ENABLE(fbmanager,
 239               [AC_HELP_STRING([--enable-fbmanager],
 240                               [enable framebuffer manager support (GtkFB)])],,
 241               enable_fbmanager=no)
 242
 243 if test "x$enable_debug" = "xyes"; then
 244   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 245   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 246 else
 247   if test "x$enable_debug" = "xno"; then
 248     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 249   else
 250     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 251   fi
 252 fi
 253
 254 if test "x$enable_visibility" = "xno"; then
 255   GTK_DEBUG_FLAGS="$GTK_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 256 fi
 257
 258
 259 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 260
 261
 262 # Build time sanity check...
 263 AM_SANITY_CHECK
 264
 265 # Checks for programs.
 266 AC_ISC_POSIX
 267 AM_PROG_CC_STDC
 268 AC_PROG_INSTALL
 269 AC_PROG_MAKE_SET
 270
 271 changequote(,)dnl
 272 if test "x$GCC" = "xyes"; then
 273   case " $CFLAGS " in
 274   *[\ \ ]-Wall[\ \      ]*) ;;
 275   *) CFLAGS="$CFLAGS -Wall" ;;
 276   esac
 277
 278   if test "x$enable_ansi" = "xyes"; then
 279     case " $CFLAGS " in
 280     *[\ \       ]-ansi[\ \      ]*) ;;
 281     *) CFLAGS="$CFLAGS -ansi" ;;
 282     esac
 283
 284     case " $CFLAGS " in
 285     *[\ \       ]-pedantic[\ \  ]*) ;;
 286     *) CFLAGS="$CFLAGS -pedantic" ;;
 287     esac
 288   fi
 289 fi
 290 changequote([,])dnl
 291
 292 # Ensure MSVC-compatible struct packing convention is used when
 293 # compiling for Win32 with gcc.
 294 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 295 # gcc2 uses "-fnative-struct".
 296 if test x"$os_win32" = xyes; then
 297   if test x"$GCC" = xyes; then
 298     msnative_struct=''
 299     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 300     if test -z "$ac_cv_prog_CC"; then
 301       our_gcc="$CC"
 302     else
 303       our_gcc="$ac_cv_prog_CC"
 304     fi
 305     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 306       2.)
 307         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 308           msnative_struct='-fnative-struct'
 309         fi
 310         ;;
 311       *)
 312         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 313           msnative_struct='-mms-bitfields'
 314         fi
 315         ;;
 316     esac
 317     if test x"$msnative_struct" = x ; then
 318       AC_MSG_RESULT([no way])
 319       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 320     else
 321       CFLAGS="$CFLAGS $msnative_struct"
 322       AC_MSG_RESULT([${msnative_struct}])
 323     fi
 324   fi
 325 fi
 326
 327 # Honor aclocal flags
 328 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 329
 330 ## Initial sanity check, done here so that users get told they
 331 ## have the wrong dependencies as early in the process as possible.
 332 ## Later on we actually use the cflags/libs from separate pkg-config
 333 ## calls. Oh, also the later pkg-config calls don't include
 334 ## the version requirements since those make the module lists
 335 ## annoying to construct
 336 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 337   [glib-2.0 >= glib_required_version dnl
 338    atk >= atk_required_version dnl
 339    pango >= pango_required_version])
 340
 341 if test "$os_win32" != yes; then
 342     # libtool option to control which symbols are exported
 343     # right now, symbols starting with _ are not exported
 344     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 345 else
 346     # We currently use .def files on Windows (for gdk-pixbuf, gdk and gtk)
 347     LIBTOOL_EXPORT_OPTIONS=
 348 fi
 349 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 350
 351 dnl ******************************************************
 352 dnl * See whether to include shared library dependencies *
 353 dnl ******************************************************
 354
 355 AC_ARG_ENABLE(explicit-deps,
 356               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 357                               [use explicit dependencies in .pc files [default=auto]])],,
 358               [enable_explicit_deps=auto])
 359
 360 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 361 case $enable_explicit_deps in
 362   auto)
 363     deplib_check_method=`(./libtool --config; echo eval echo \\$deplib_check_method) | sh`
 364     if test "X$deplib_check_method" = Xnone || test "x$enable_static" = xyes ; then
 365       enable_explicit_deps=yes
 366     else
 367       enable_explicit_deps=no
 368     fi
 369   ;;
 370   yes|no)
 371   ;;
 372   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 373   ;;
 374 esac
 375 AC_MSG_RESULT($enable_explicit_deps)
 376
 377 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 378
 379 # define a MAINT-like variable REBUILD which is set if Perl
 380 # and awk are found, so autogenerated sources can be rebuilt
 381
 382 AC_PATH_PROGS(PERL, perl5 perl)
 383
 384 # We would like indent, but don't require it.
 385 AC_CHECK_PROG(INDENT, indent, indent)
 386
 387 REBUILD=\#
 388 if test "x$enable_rebuilds" = "xyes" && \
 389      test -n "$PERL" && \
 390      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 391   REBUILD=
 392 fi
 393 AC_SUBST(REBUILD)
 394
 395 AC_CHECK_FUNCS(lstat mkstemp flockfile)
 396
 397 # sigsetjmp is a macro on some platforms, so AC_CHECK_FUNCS is not reliable
 398 AC_MSG_CHECKING(for sigsetjmp)
 399 AC_TRY_LINK([#include <setjmp.h>], [
 400 sigjmp_buf env;
 401 sigsetjmp(env, 0);
 402 ], gtk_ok=yes, gtk_ok=no)
 403 AC_MSG_RESULT($gtk_ok)
 404 if test "$gtk_ok" = "yes"; then
 405   AC_DEFINE(HAVE_SIGSETJMP)
 406 fi
 407
 408 # i18n stuff
 409 # TRANSLATORS:  Please note that gtk+ has both po/ and po-properties/
 410 # directories.  If you add a new language to ALL_LINGUAS, please make
 411 # sure that both po/ and po-properties/ have .po files that correspond
 412 # to your language.  If you only add one to po/, the build will break
 413 # in po-properties/.
 414 ALL_LINGUAS="af am ar az az_IR be bg bn br bs ca cs cy da de el en_CA en_GB es et eu fa fi fr ga gl gu he hi hr hu ia id is it ja ko li lt lv mi mk ml mn mr ms ne nl nn no pa pl pt pt_BR ro ru sk sl sq sr sr@ije sr@Latn sv ta th tk tr uk uz uz@Latn vi wa yi zh_CN zh_TW"
 415 AM_GLIB_GNU_GETTEXT
 416 LIBS="$LIBS $INTLLIBS"
 417 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 418         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 419       esac])
 420
 421 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 422
 423 dnl The DU4 header files don't provide library prototypes unless
 424 dnl -std1 is given to the native cc.
 425 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 426
 427 gtk_save_LIBS=$LIBS
 428 LIBS="$LIBS -lm"
 429 AC_TRY_RUN([#include <math.h>
 430              int main (void) { return (log(1) != log(1.)); }],
 431      AC_MSG_RESULT(none needed),
 432      gtk_save_CFLAGS="$CFLAGS"
 433      CFLAGS="$CFLAGS -std1"
 434      AC_TRY_RUN([#include <math.h>
 435                  int main (void) { return (log(1) != log(1.)); }],
 436          AC_MSG_RESULT(-std1),
 437          AC_MSG_RESULT()
 438          CFLAGS="$gtk_save_CFLAGS"
 439          AC_MSG_WARN(
 440                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 441          true
 442      ),
 443      AC_MSG_RESULT(none needed)
 444 )
 445 LIBS=$gtk_save_LIBS
 446
 447 AC_MSG_CHECKING(for the BeOS)
 448 case $host in
 449   *-*-beos*)
 450     AC_MSG_RESULT(yes)
 451     MATH_LIB=
 452   ;;
 453   *)
 454     AC_MSG_RESULT(no)
 455   ;;
 456 esac
 457
 458 dnl NeXTStep cc seems to need this
 459 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 460 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 461   AC_MSG_RESULT(none needed),
 462   gtk_save_CFLAGS="$CFLAGS"
 463   CFLAGS="$CFLAGS -posix"
 464   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 465     AC_MSG_RESULT(-posix),
 466     AC_MSG_RESULT()
 467     CFLAGS="$gtk_save_CFLAGS"
 468     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 469
 470 #
 471 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 472 #
 473
 474 GLIB_PACKAGES="gobject-2.0 gmodule-2.0"
 475
 476 AM_PATH_GLIB_2_0(glib_required_version, :,
 477   AC_MSG_ERROR([
 478 *** GLIB glib_required_version or better is required. The latest version of
 479 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 480   gobject gmodule gthread)
 481
 482 dnl
 483 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 484 dnl
 485 gtk_save_LIBS=$LIBS
 486 LIBS="$LIBS $GLIB_LIBS"
 487 AC_CHECK_FUNCS(bind_textdomain_codeset)
 488 LIBS=$gtk_save_LIBS
 489
 490 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 491 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 492 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 493
 494 if test "${with_ie55+set}" = set && test $with_ie55 != no; then
 495   AC_MSG_CHECKING([for dimm.h])
 496   saved_CFLAGS="$CFLAGS"
 497   CFLAGS="$CFLAGS -idirafter $with_ie55/Include"
 498   AC_TRY_COMPILE([/* The w32api imm.h clashes a bit with the IE5.5 dimm.h */
 499 #ifdef __GNUC__
 500 #define IMEMENUITEMINFOA hidden_IMEMENUITEMINFOA
 501 #define IMEMENUITEMINFOW hidden_IMEMENUITEMINFOW
 502 #endif
 503 #include <windows.h>
 504 #include <objbase.h>
 505 #include <imm.h>
 506 #ifdef __GNUC__
 507 #undef IMEMENUITEMINFOA
 508 #undef IMEMENUITEMINFOW
 509 #endif
 510 #include <dimm.h>
 511 ],
 512    [],
 513    [AC_MSG_RESULT(yes)
 514     AC_MSG_CHECKING([for IE55 uuid.lib])
 515     if test -f $with_ie55/Lib/uuid.lib ; then
 516       AC_MSG_RESULT(yes)
 517       have_ie55=yes
 518       AC_DEFINE(HAVE_DIMM_H)
 519       IE55_UUID_LIB="$with_ie55/Lib/uuid.lib"
 520       AC_SUBST(IE55_UUID_LIB)
 521     else
 522       AC_MSG_RESULT(no)
 523       CFLAGS="$saved_CFLAGS"
 524       have_ie55=no
 525     fi
 526     ],
 527    [AC_MSG_RESULT(no)
 528     CFLAGS="$saved_CFLAGS"
 529     have_ie55=no])
 530 fi
 531 AM_CONDITIONAL(HAVE_IE55, test x$have_ie55 = xyes)
 532
 533 if test "${with_wintab+set}" = set && test $with_wintab != no; then
 534   AC_MSG_CHECKING([for wintab.h])
 535   saved_CFLAGS="$CFLAGS"
 536   CFLAGS="$CFLAGS -I$with_wintab/include"
 537   AC_TRY_COMPILE([#include <windows.h>
 538 #include <wintab.h>],
 539    [],
 540    [AC_MSG_RESULT(yes)
 541     AC_MSG_CHECKING([for wntab32x.lib])
 542     if test -f $with_wintab/lib/i386/wntab32x.lib ; then
 543       AC_MSG_RESULT(yes)
 544       have_wintab=yes
 545       AC_DEFINE(HAVE_WINTAB)
 546       WINTAB_LIB="$with_wintab/lib/i386/wntab32x.lib"
 547       AC_SUBST(WINTAB_LIB)
 548     else
 549       AC_MSG_RESULT(no)
 550       CFLAGS="$saved_cflags"
 551       have_wintab=no
 552     fi
 553     ],
 554    [AC_MSG_RESULT(no)
 555     CFLAGS="$saved_cflags"
 556     have_wintab=no])
 557 fi
 558 AM_CONDITIONAL(HAVE_WINTAB, test x$have_wintab = xyes)
 559
 560 saved_cflags="$CFLAGS"
 561 saved_ldflags="$LDFLAGS"
 562
 563
 564 # Checks for header files.
 565 AC_HEADER_STDC
 566
 567 # Checks for typedefs, structures, and compiler characteristics.
 568 AC_C_CONST
 569
 570 # Checks for library functions.
 571 AC_TYPE_SIGNAL
 572 AC_FUNC_MMAP
 573
 574 AC_CHECK_FUNCS(mallinfo)
 575 AC_CHECK_FUNCS(getresuid)
 576 AC_TYPE_UID_T
 577
 578 # Check if <sys/select.h> needs to be included for fd_set
 579 AC_MSG_CHECKING([for fd_set])
 580 AC_TRY_COMPILE([#include <sys/types.h>],
 581         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 582 if test $gtk_ok = yes; then
 583     AC_MSG_RESULT([yes, found in sys/types.h])
 584 else
 585     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 586     if test $gtk_ok = yes; then
 587         AC_DEFINE(HAVE_SYS_SELECT_H)
 588         AC_MSG_RESULT([yes, found in sys/select.h])
 589     else
 590         AC_DEFINE(NO_FD_SET)
 591         AC_MSG_RESULT(no)
 592     fi
 593 fi
 594
 595 # `widechar' tests for gdki18n.h
 596 AC_MSG_CHECKING(for wchar.h)
 597 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 598 if test $gdk_wchar_h = yes; then
 599    AC_DEFINE(HAVE_WCHAR_H,1,[Have wchar.h include file])
 600 fi
 601 AC_MSG_RESULT($gdk_wchar_h)
 602
 603 # Check for wctype.h (for iswalnum)
 604 AC_MSG_CHECKING(for wctype.h)
 605 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 606 if test $gdk_wctype_h = yes; then
 607    AC_DEFINE(HAVE_WCTYPE_H,1,[Have wctype.h include file])
 608 fi
 609 AC_MSG_RESULT($gdk_wctype_h)
 610
 611 # in Solaris 2.5, `iswalnum' is in -lw
 612 GDK_WLIBS=
 613 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 614
 615 oLIBS="$LIBS"
 616 LIBS="$LIBS $GDK_WLIBS"
 617 # The following is necessary for Linux libc-5.4.38
 618 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 619 AC_TRY_LINK([#include <stdlib.h>],[
 620 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 621 #  ifdef HAVE_WCTYPE_H
 622 #    include <wctype.h>
 623 #  else
 624 #    ifdef HAVE_WCHAR_H
 625 #      include <wchar.h>
 626 #    endif
 627 #  endif
 628 #else
 629 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 630 #endif
 631 iswalnum((wchar_t) 0);
 632 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 633 LIBS="$oLIBS"
 634
 635 if test $gdk_working_wctype = no; then
 636    AC_DEFINE(HAVE_BROKEN_WCTYPE,1,[Is the wctype implementation broken])
 637    GDK_WLIBS=
 638 fi
 639 AC_MSG_RESULT($gdk_working_wctype)
 640 AC_SUBST(GDK_WLIBS)
 641
 642 # Check for uxtheme.h (for MS-Windows Engine)
 643 AC_MSG_CHECKING(for uxtheme.h)
 644 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 645 if test $gtk_uxtheme_h = yes; then
 646    AC_DEFINE(HAVE_UXTHEME_H,1,[Have uxtheme.h include file])
 647 fi
 648 AC_MSG_RESULT($gtk_uxtheme_h)
 649
 650
 651 ##################################################
 652 # Checks for gdk-pixbuf
 653 ##################################################
 654
 655 dnl ********************************************************
 656 dnl * See whether we need to load our modules as .la files *
 657 dnl ********************************************************
 658
 659 use_la_modules=false
 660 case $host in
 661   *-aix*) use_la_modules=true
 662 esac
 663
 664 if $use_la_modules ; then
 665    AC_DEFINE(USE_LA_MODULES, 1, [Whether to load modules via .la files rather than directly])
 666 fi
 667
 668
 669 AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
 670
 671 AC_ARG_ENABLE(modules,
 672               [AC_HELP_STRING([--disable-modules],
 673                               [disable dynamic module loading])])
 674
 675 dynworks=false
 676 deps=
 677 if test x$enable_modules = xno; then
 678     AC_MSG_RESULT(no)
 679 else
 680     AC_MSG_RESULT(yes)
 681     AC_MSG_CHECKING(whether dynamic modules work)
 682     ## for loop is to strip newline
 683     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-2.0`
 684     for I in $tmp; do
 685         dynworks=$I
 686     done
 687
 688     dnl Now we check to see if our libtool supports shared lib deps
 689     dnl (in a rather ugly way even)
 690     if $dynworks; then
 691         pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 692         pixbuf_deplibs_check=`$pixbuf_libtool_config | \
 693             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 694             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 695         if test "x$pixbuf_deplibs_check" = "xnone" || \
 696            test "x$pixbuf_deplibs_check" = "xunknown" || \
 697            test "x$pixbuf_deplibs_check" = "x"; then
 698             dynworks=false
 699         fi
 700     fi
 701
 702     if $dynworks; then
 703         AC_DEFINE(USE_GMODULE)
 704         AC_MSG_RESULT(yes)
 705     else
 706         AC_MSG_RESULT(no)
 707     fi
 708 fi
 709
 710 dnl We allow people to disable image loaders explicitely, but if they don't we error
 711 dnl out so that people don't accidentally build without them.
 712
 713 AC_ARG_WITH(libpng,
 714             [AC_HELP_STRING([--without-libpng],
 715                             [disable PNG loader for gdk-pixbuf])])
 716 AC_ARG_WITH(libjpeg,
 717             [AC_HELP_STRING([--without-libjpeg],
 718                             [disable JPEG loader for gdk-pixbuf])])
 719 AC_ARG_WITH(libtiff,
 720             [AC_HELP_STRING([--without-libtiff],
 721                             [disable TIFF loader for gdk-pixbuf])])
 722
 723 dnl Test for libtiff
 724   if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
 725     AC_CHECK_LIB(tiff, TIFFReadScanline,
 726       [AC_CHECK_HEADER(tiffio.h,
 727         TIFF='tiff'; LIBTIFF='-ltiff',
 728         AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 729       [AC_CHECK_LIB(tiff, TIFFWriteScanline,
 730         [AC_CHECK_HEADER(tiffio.h,
 731           TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
 732           AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 733         [AC_CHECK_LIB(tiff34, TIFFFlushData,
 734           [AC_CHECK_HEADER(tiffio.h,
 735             TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
 736             AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 737         AC_MSG_WARN(*** TIFF plug-in will not be built (TIFF library not found) ***), -ljpeg -lz -lm)], -ljpeg -lz -lm)], -lm)
 738   fi
 739
 740   if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
 741      AC_MSG_ERROR([
 742 *** Checks for TIFF loader failed. You can build without it by passing
 743 *** --without-libtiff to configure but some programs using GTK+ may
 744 *** not work properly])
 745   fi
 746
 747 dnl Test for libjpeg
 748   if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
 749     AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 750       jpeg_ok=yes,
 751       jpeg_ok=no
 752       AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
 753     if test "$jpeg_ok" = yes; then
 754       AC_MSG_CHECKING([for jpeglib.h])
 755       AC_TRY_CPP(
 756 [#include <stdio.h>
 757 #undef PACKAGE
 758 #undef VERSION
 759 #undef HAVE_STDLIB_H
 760 #include <jpeglib.h>],
 761         jpeg_ok=yes,
 762         jpeg_ok=no)
 763       AC_MSG_RESULT($jpeg_ok)
 764       if test "$jpeg_ok" = yes; then
 765         LIBJPEG='-ljpeg'
 766         AC_CHECK_LIB(jpeg, jpeg_simple_progression,
 767           AC_DEFINE(HAVE_PROGRESSIVE_JPEG),
 768           AC_MSG_WARN(JPEG library does not support progressive saving.))
 769       else
 770           AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
 771       fi
 772     fi
 773   fi
 774
 775   if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
 776      AC_MSG_ERROR([
 777 *** Checks for JPEG loader failed. You can build without it by passing
 778 *** --without-libjpeg to configure but some programs using GTK+ may
 779 *** not work properly])
 780   fi
 781
 782 dnl Test for libpng
 783   if test x$with_libpng != xno && test -z "$LIBPNG"; then
 784     AC_MSG_CHECKING(for libpng12)
 785     if $PKG_CONFIG --exists libpng12 ; then
 786         AC_MSG_RESULT(yes)
 787         PNG='png'
 788         PNG_DEP_CFLAGS_PACKAGES=libpng12
 789         LIBPNG=`$PKG_CONFIG --libs libpng12`
 790     else
 791       AC_MSG_RESULT(no)
 792       AC_CHECK_LIB(png, png_read_info,
 793         [AC_CHECK_HEADER(png.h,
 794           png_ok=yes,
 795           png_ok=no)],
 796         AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
 797       if test "$png_ok" = yes; then
 798         AC_MSG_CHECKING([for png_structp in png.h])
 799         AC_TRY_COMPILE([#include <png.h>],
 800           [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 801           png_ok=yes,
 802           png_ok=no)
 803         AC_MSG_RESULT($png_ok)
 804         if test "$png_ok" = yes; then
 805           PNG='png'; LIBPNG='-lpng -lz'
 806         else
 807           AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
 808         fi
 809       else
 810        AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
 811       fi
 812     fi
 813   fi
 814
 815   if test x$with_libpng != xno && test -z "$LIBPNG"; then
 816      AC_MSG_ERROR([
 817 *** Checks for PNG loader failed. You can build without it by passing
 818 *** --without-libpng to configure but many programs using GTK+ will
 819 *** not work properly. The PNG loader is also needed if you are compiling
 820 *** from CVS.])
 821   fi
 822
 823 AC_SUBST(LIBTIFF)
 824 AC_SUBST(LIBJPEG)
 825 AC_SUBST(LIBPNG)
 826
 827 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 828
 829 #
 830 # Allow building some or all gdk-pixbuf loaders included
 831 #
 832 AC_MSG_CHECKING(pixbuf loaders to build)
 833
 834 dnl due to an autoconf bug, commas in the first arg to
 835 dnl AC_HELP_STRING cause problems.
 836 dnl AC_HELP_STRING([--with-included-loaders=LOADER1 LOADER2 ...],
 837 dnl                [build the specified loaders into gdk-pixbuf (only used if module loading disabled)])
 838 AC_ARG_WITH(included_loaders,
 839 [  --with-included-loaders=LOADER1,LOADER2,...
 840                           build the specified loaders into gdk-pixbuf (only
 841                           used if module loading disabled)])
 842
 843 if $dynworks; then
 844         :
 845 else
 846    ## if the option was specified, leave it; otherwise disable included loaders
 847    if test x$with_included_loaders = xno; then
 848            with_included_loaders=yes
 849    fi
 850 fi
 851
 852 all_loaders="png,bmp,wbmp,gif,ico,ani,jpeg,pnm,ras,tiff,xpm,tga,pcx"
 853 included_loaders=""
 854 # If no loaders specified, include all
 855 if test "x$with_included_loaders" = xyes ; then
 856   included_loaders="$all_loaders"
 857 else
 858   included_loaders="$with_included_loaders"
 859 fi
 860
 861 AC_MSG_RESULT($included_loaders)
 862
 863 INCLUDED_LOADER_OBJ=
 864 INCLUDED_LOADER_DEFINE=
 865
 866 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 867 for loader in $included_loaders; do
 868  if echo "$all_loaders" | egrep "(^|,)$loader(\$|,)" > /dev/null; then
 869    :
 870  else
 871    AC_MSG_ERROR([the specified loader $loader does not exist])
 872  fi
 873
 874  INCLUDED_LOADER_OBJ="$INCLUDED_LOADER_OBJ libpixbufloader-static-$loader.la"
 875  INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_$loader"
 876 done
 877 IFS="$gtk_save_ifs"
 878 AC_SUBST(INCLUDED_LOADER_OBJ)
 879 AC_SUBST(INCLUDED_LOADER_DEFINE)
 880
 881 AC_HEADER_SYS_WAIT
 882
 883 AC_TYPE_SIGNAL
 884
 885 AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
 886 AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
 887 AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
 888
 889 if $dynworks ; then
 890   STATIC_LIB_DEPS=
 891   if echo "$included_loaders" | egrep '(^|,)tiff($|,)' > /dev/null; then
 892     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBTIFF"
 893   fi
 894   if echo "$included_loaders" | egrep '(^|,)jpeg($|,)' > /dev/null; then
 895     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBJPEG"
 896   fi
 897   if echo "$included_loaders" | egrep '(^|,)png($|,)' > /dev/null; then
 898     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBPNG"
 899   fi
 900 else
 901   STATIC_LIB_DEPS="$LIBTIFF $LIBJPEG $LIBPNG"
 902 fi
 903
 904 # Checks to see if we should compile in MMX support (there will be
 905 # a runtime test when the code is actually run to see if it should
 906 # be used - this just checks if we can compile it.)
 907 #
 908 # This code is partially taken from Mesa
 909 #
 910 AC_MSG_CHECKING(for x86 platform)
 911 case $host_cpu in
 912   i386|i486|i586|i686|i786|k6|k7)
 913         use_x86_asm=yes
 914         ;;
 915    *)
 916         use_x86_asm=no
 917 esac
 918 AC_MSG_RESULT($use_x86_asm)
 919
 920 use_mmx_asm=no
 921 if test $use_x86_asm = yes; then
 922     save_ac_ext=$ac_ext
 923     ac_ext=S
 924
 925     AC_MSG_CHECKING(compiler support for MMX)
 926     cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
 927     if AC_TRY_EVAL(ac_compile); then
 928         use_mmx_asm=yes
 929     fi
 930
 931     rm -rf conftest*
 932
 933     ac_ext=$save_ac_ext
 934     if test $use_mmx_asm = yes; then
 935       AC_DEFINE(USE_MMX)
 936       AC_MSG_RESULT(yes)
 937     else
 938       AC_MSG_RESULT(no)
 939     fi
 940 fi
 941
 942 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
 943
 944 REBUILD_PNGS=
 945 if test -z "$LIBPNG"; then
 946   REBUILD_PNGS=#
 947 fi
 948
 949 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 950
 951 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 952
 953 if test $cross_compiling = yes; then
 954   AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 955   if test x$GDK_PIXBUF_CSOURCE = xno; then
 956     REBUILD_PNGS=#
 957   fi
 958 fi
 959
 960 if test ! -f $srcdir/gtk/stock-icons/gtkstockpixbufs.h &&
 961    test "x$REBUILD_PNGS" = "x#" ; then
 962      AC_MSG_ERROR([
 963 *** gtkstockpixbufs.h is not in the tree, and cannot be built
 964 *** because you don't have libpng, or (when cross-compiling) you
 965 *** don't have a prebuilt gdk-pixbuf-csource on the host system.])
 966 fi
 967
 968 AC_SUBST(REBUILD_PNGS)
 969
 970 GDK_PIXBUF_PACKAGES="gmodule-2.0 gobject-2.0"
 971 GDK_PIXBUF_EXTRA_LIBS="$STATIC_LIB_DEPS $MATH_LIB"
 972 GDK_PIXBUF_EXTRA_CFLAGS=
 973 GDK_PIXBUF_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
 974 GDK_PIXBUF_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $PNG_DEP_CFLAGS_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS"
 975
 976 AC_SUBST(GDK_PIXBUF_PACKAGES)
 977 AC_SUBST(GDK_PIXBUF_EXTRA_LIBS)
 978 AC_SUBST(GDK_PIXBUF_EXTRA_CFLAGS)
 979 AC_SUBST(GDK_PIXBUF_DEP_LIBS)
 980 AC_SUBST(GDK_PIXBUF_DEP_CFLAGS)
 981
 982
 983 ########################################
 984 # Windowing system checks
 985 ########################################
 986
 987 GDK_EXTRA_LIBS=$GDK_WLIBS
 988 GDK_EXTRA_CFLAGS=
 989 GTK_DEP_LIBS_FOR_X=
 990
 991 FREETYPE_LIBS=
 992 FREETYPE_CFLAGS=
 993 if test "x$gdktarget" = "xlinux-fb" || test "x$gdktarget" = "xx11" ; then
 994   #
 995   # Checks for FreeType
 996   #
 997   have_freetype=false
 998   AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
 999   if test "x$FREETYPE_CONFIG" != "xno" ; then
1000     FREETYPE_CFLAGS=`$FREETYPE_CONFIG --cflags`
1001     FREETYPE_LIBS=`$FREETYPE_CONFIG --libs`
1002
1003     gtk_save_LIBS="$LIBS"
1004     LIBS="$FREETYPE_LIBS $LIBS"
1005     AC_TRY_LINK_FUNC(FT_New_Face, have_freetype=true,:)
1006     LIBS="$gtk_save_LIBS"
1007
1008     if $have_freetype ; then
1009       gtk_save_cppflags="$CPPFLAGS"
1010       CPPFLAGS="$CPPFLAGS $FREETYPE_CFLAGS"
1011
1012       AC_MSG_CHECKING([For sufficiently new FreeType (at least 2.0.1)])
1013       AC_TRY_COMPILE([
1014 #include <ft2build.h>
1015 #include FT_FREETYPE_H
1016 #include FT_ERRORS_H
1017     ],
1018                      [(void)1;],:,have_freetype=false)
1019       if $have_freetype ; then
1020         AC_MSG_RESULT(yes)
1021       else
1022         AC_MSG_RESULT(no)
1023       fi
1024
1025       CPPFLAGS="$gtk_save_cppflags"
1026     fi
1027   fi
1028   AC_SUBST(FREETYPE_LIBS)
1029   AC_SUBST(FREETYPE_CFLAGS)
1030 fi
1031
1032 if test "x$gdktarget" = "xx11"; then
1033   # We start off with the libraries from Pango
1034
1035   ## be sure we also have Pango built with Xft2 support
1036   if $PKG_CONFIG --exists 'pangoxft >= 1.2.0' ; then
1037     if $have_freetype ; then
1038       :
1039     else
1040       AC_MSG_ERROR([Xft Pango backend found but did not find freetype libraries])
1041     fi
1042   else
1043     AC_MSG_ERROR([Pango 1.2.0 and Xft backend is required for x11 target])
1044   fi
1045
1046   if $PKG_CONFIG --exists xft ; then : ; else
1047     AC_MSG_ERROR([Xft version 2 is required for x11 target])
1048   fi
1049
1050   #
1051   # If Pango included the shared library dependencies from X11 in
1052   # the pkg-config output, then we use that (to avoid duplicates).
1053   # but if they were omitted to avoid binary compatibility problems,
1054   # then we need to repeat the checks.
1055   #
1056   x_libs="`$PKG_CONFIG --libs pangoxft`"
1057   case "$x_libs" in
1058     *-lX11*) pango_omitted_x_deps=no ;;
1059     *)       pango_omitted_x_deps=yes ;;
1060   esac
1061
1062   x_cflags="`$PKG_CONFIG --cflags pangoxft`"
1063   x_extra_libs=
1064
1065   AC_PATH_XTRA
1066   if test x$no_x = xyes ; then
1067     AC_MSG_ERROR([X development libraries not found])
1068   fi
1069
1070   if test $pango_omitted_x_deps = yes ; then
1071     # Old versions of Xft didn't necessarily include -lX11 in the output
1072     x_libs="`pkg-config --libs xft` -lX11 $X_EXTRA_LIBS"
1073   fi
1074
1075   ## Strip the .la files
1076
1077   x_libs_for_checks=""
1078   for I in $x_libs ; do
1079     case $I in
1080       *.la) ;;
1081       *) x_libs_for_checks="$x_libs_for_checks $I" ;;
1082     esac
1083   done
1084
1085   # Sanity check for the X11 library
1086   AC_CHECK_LIB(X11, XOpenDisplay, :,
1087             AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
1088             $x_libs_for_checks)
1089
1090   if test "x$enable_shm" = "xyes"; then
1091     # Check for the Xext library (needed for XShm extention)
1092     AC_CHECK_LIB(Xext, XShmAttach,
1093         [GTK_ADD_LIB(x_extra_libs,Xext)],
1094         # On AIX, it is in XextSam instead, but we still need -lXext
1095         [AC_CHECK_LIB(XextSam, XShmAttach,
1096             [GTK_ADD_LIB(x_extra_libs,Xext)
1097              GTK_ADD_LIB(x_extra_libs,XextSam)
1098             ], , -lXext $x_libs_for_checks)],
1099         $x_libs_for_checks)
1100   fi
1101
1102   GDK_PIXBUF_XLIB_EXTRA_CFLAGS="$x_cflags"
1103   # Don't ever pull in the pangoxft libraries for gdk-pixbuf-x11
1104   GDK_PIXBUF_XLIB_EXTRA_LIBS="$X_LIBS -lX11 $x_extra_libs $X_EXTRA_LIBS"
1105
1106   # GTK+ uses some X calls, so needs to link against X directly
1107   if test $enable_explicit_deps != yes ; then
1108     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
1109   fi
1110
1111   # Check for Xinerama extension (Solaris impl or Xfree impl)
1112
1113   gtk_save_cppflags="$CPPFLAGS"
1114   CPPFLAGS="$CPPFLAGS $x_cflags"
1115
1116   case "$host" in
1117       *-*-solaris*)
1118           # Check for solaris
1119           use_solaris_xinerama=yes
1120           AC_CHECK_LIB(Xext, XineramaGetInfo,
1121                         use_solaris_xinerama=yes,
1122                         use_solaris_xinerama=no,
1123                         -lXext $x_libs_for_checks)
1124           if test "x$use_solaris_xinerama" = "xyes"; then
1125               AC_CHECK_HEADER(X11/extensions/xinerama.h,
1126                 [GTK_ADD_LIB(x_extra_libs,Xext)
1127                 AC_DEFINE(HAVE_SOLARIS_XINERAMA)
1128                 AC_DEFINE(HAVE_XINERAMA)],
1129                 use_solaris_xinerama=no,[#include <X11/Xlib.h>])
1130           fi
1131           AC_MSG_CHECKING(for Xinerama support on Solaris)
1132           AC_MSG_RESULT($use_solaris_xinerama);
1133           ;;
1134       *)
1135           # Check for XFree
1136           use_xfree_xinerama=yes
1137           AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1138               [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1139                   [GTK_ADD_LIB(x_extra_libs,Xext)
1140                   GTK_ADD_LIB(x_extra_libs,Xinerama)
1141                   AC_DEFINE(HAVE_XFREE_XINERAMA)
1142                   AC_DEFINE(HAVE_XINERAMA)],
1143                   use_xfree_xinerama=no,
1144                   [#include <X11/Xlib.h>])],
1145               use_xfree_xinerama=no, -lXext $x_libs_for_checks)
1146           AC_MSG_CHECKING(for Xinerama support on XFree86)
1147           AC_MSG_RESULT($use_xfree_xinerama);
1148           ;;
1149   esac
1150
1151   CPPFLAGS="$gtk_save_cppflags"
1152
1153   # Check for xReply
1154
1155   gtk_save_cppflags="$CPPFLAGS"
1156   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1157
1158   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
1159   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
1160       [xReply *rep;],
1161       [AC_MSG_RESULT([no])],
1162       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
1163 #include <X11/Xlibint.h>],
1164            [xReply *rep;],
1165            [AC_MSG_RESULT([yes])
1166             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
1167                 [Define if <X11/extensions/XIproto.h> needed for xReply])],
1168            [AC_MSG_RESULT([unknown])
1169             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1170
1171   CPPFLAGS="$gtk_save_cppflags"
1172
1173   # Check for shaped window extension
1174
1175   AC_CHECK_LIB(Xext, XShapeCombineMask,
1176       [GTK_ADD_LIB(x_extra_libs,Xext)
1177        AC_DEFINE(HAVE_SHAPE_EXT)],
1178       ,
1179       $x_libs_for_checks)
1180
1181   # Check for XConvertCase (X11R6 specific)
1182
1183   AC_CHECK_LIB(X11, XConvertCase,
1184       AC_DEFINE(HAVE_XCONVERTCASE),
1185       ,
1186       $x_libs_for_checks)
1187
1188   # Check for XInternAtoms (X11R6 specific)
1189
1190   AC_CHECK_LIB(X11, XInternAtoms,
1191       AC_DEFINE([HAVE_XINTERNATOMS], 1,
1192           [Define to 1 if you have the `XInternAtoms' function.]),
1193       ,
1194       $x_libs_for_checks)
1195
1196   # Generic X11R6 check needed for XIM support; we could
1197   # probably use this to replace the above, but we'll
1198   # leave the separate checks for XConvertCase and XInternAtoms
1199   # for clarity
1200   have_x11r6=false
1201   AC_CHECK_LIB(X11, XAddConnectionWatch,
1202       have_x11r6=true,
1203       ,
1204       $x_libs_for_checks)
1205
1206   if $have_x11r6; then
1207     AC_DEFINE(HAVE_X11R6,1,[Define if we have X11R6])
1208   fi
1209   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1210
1211   # Check for XKB support.
1212
1213   if test "x$enable_xkb" = "xyes"; then
1214         AC_MSG_WARN(XKB support explicitly enabled)
1215         AC_DEFINE(HAVE_XKB)
1216   elif test "x$enable_xkb" = "xmaybe"; then
1217         AC_CHECK_LIB(X11, XkbQueryExtension,
1218                      AC_DEFINE(HAVE_XKB),
1219                      ,
1220                      $x_libs_for_checks)
1221   else
1222         AC_MSG_WARN(XKB support explicitly disabled)
1223   fi
1224
1225   x_cflags="$X_CFLAGS"
1226   x_ldflags="$X_LDFLAGS"
1227
1228   # set up things for XInput
1229
1230   if test "x$with_xinput" = "xxfree" || test "x$with_xinput" = "xyes"; then
1231     AC_DEFINE(XINPUT_XFREE)
1232     GTK_ADD_LIB(x_extra_libs, Xi)
1233   else
1234     AC_DEFINE(XINPUT_NONE)
1235   fi
1236
1237   AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree || test x$with_xinput = xyes)
1238
1239   # Check for the RANDR extension
1240
1241   AC_CHECK_LIB(Xrandr, XRRUpdateConfiguration,
1242       [AC_CHECK_HEADER(X11/extensions/Xrandr.h,
1243           # RANDR requires RENDER
1244           [GTK_ADD_LIB(x_extra_libs, Xrender)
1245           GTK_ADD_LIB(x_extra_libs, Xrandr)
1246           AC_DEFINE(HAVE_RANDR, 1, Have the Xrandr extension library)],
1247           :, [#include <X11/Xlib.h>])], : ,
1248        $X_LIBS -lXrandr -lXrender -lX11 $X_EXTRA_LIBS)
1249
1250   # Checks for Xcursor library
1251
1252   have_xcursor=false
1253   PKG_CHECK_MODULES(XCURSOR, xcursor, have_xcursor=true, :)
1254
1255   if $have_xcursor ; then
1256     AC_DEFINE(HAVE_XCURSOR, 1, Have the Xcursor library)
1257     GDK_EXTRA_CFLAGS="`$PKG_CONFIG --cflags xcursor` $GDK_EXTRA_CFLAGS"
1258     GDK_EXTRA_LIBS="`$PKG_CONFIG --libs xcursor` $GDK_EXTRA_LIBS"
1259   fi
1260
1261   # X SYNC check
1262   AC_CHECK_LIB(Xext, XSyncQueryExtension,
1263       [AC_CHECK_HEADER(X11/extensions/sync.h,
1264           [GTK_ADD_LIB(x_extra_libs, Xext)
1265           AC_DEFINE(HAVE_XSYNC, 1, Have the SYNC extension library)],
1266           :, [#include <X11/Xlib.h>])], : ,
1267        $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
1268
1269   # Checks for XFixes extension
1270
1271   have_xfixes=false
1272   PKG_CHECK_MODULES(XFIXES, xfixes, have_xfixes=true, :)
1273
1274   if $have_xfixes ; then
1275     AC_DEFINE(HAVE_XFIXES, 1, Have the XFIXES X extension)
1276     GDK_EXTRA_CFLAGS="`$PKG_CONFIG --cflags xfixes` $GDK_EXTRA_CFLAGS"
1277     GDK_EXTRA_LIBS="`$PKG_CONFIG --libs xfixes` $GDK_EXTRA_LIBS"
1278   fi
1279
1280   # Xshm checks
1281
1282   if test "x$enable_shm" = "xyes"; then
1283     # Check for shared memory
1284     AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
1285     AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
1286
1287     # Check for the X shared memory extension header file
1288     have_xshm=no
1289     AC_MSG_CHECKING(X11/extensions/XShm.h)
1290     if test "x$no_xext_lib" = "xyes"; then
1291       :
1292     else
1293       gtk_save_CFLAGS="$CFLAGS"
1294       CFLAGS="$CFLAGS $x_cflags"
1295       AC_TRY_COMPILE([
1296 #include <stdlib.h>
1297 #include <sys/types.h>
1298 #include <sys/ipc.h>
1299 #include <sys/shm.h>
1300 #include <X11/Xlib.h>
1301 #include <X11/Xutil.h>
1302 #include <X11/extensions/XShm.h>
1303 ], [XShmSegmentInfo *x_shm_info;], have_xshm=yes)
1304       CFLAGS="$gtk_save_CFLAGS"
1305     fi
1306     AC_MSG_RESULT($have_xshm)
1307     if test $have_xshm = yes ; then
1308       AC_DEFINE(HAVE_XSHM_H)
1309     fi
1310   fi
1311
1312   if test $pango_omitted_x_deps = yes ; then
1313     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs $x_libs $GDK_EXTRA_LIBS"
1314   else
1315     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs $GDK_EXTRA_LIBS"
1316   fi
1317
1318   AM_CONDITIONAL(USE_X11, true)
1319 else
1320   AM_CONDITIONAL(XINPUT_XFREE, false)
1321   AM_CONDITIONAL(USE_X11, false)
1322   AM_CONDITIONAL(HAVE_X11R6, false)
1323 fi
1324
1325 if test "x$gdktarget" = "xwin32"; then
1326   # We start off with the libraries from Pango
1327
1328   if test x$have_wintab = xyes; then
1329     GDK_WIN32_EXTRA_CFLAGS="-I $with_wintab/include"
1330     AC_SUBST(GDK_WIN32_EXTRA_CFLAGS)
1331   fi
1332
1333   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -user32 -limm32 -lshell32 -lole32 -luuid"
1334   AM_CONDITIONAL(USE_WIN32, true)
1335 else
1336   AM_CONDITIONAL(USE_WIN32, false)
1337 fi
1338
1339 GDK_PIXBUF_XLIB_PACKAGES=
1340 GDK_PIXBUF_XLIB_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_XLIB_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
1341 GDK_PIXBUF_XLIB_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_PIXBUF_XLIB_EXTRA_CFLAGS"
1342
1343 AC_SUBST(GDK_PIXBUF_XLIB_PACKAGES)
1344 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_LIBS)
1345 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_CFLAGS)
1346 AC_SUBST(GDK_PIXBUF_XLIB_DEP_LIBS)
1347 AC_SUBST(GDK_PIXBUF_XLIB_DEP_CFLAGS)
1348
1349 if test "x$gdktarget" = "xlinux-fb"; then
1350   if $have_freetype ; then
1351     :
1352   else
1353     AC_MSG_ERROR([Using linux-fb backend but freetype was not found])
1354   fi
1355
1356   ft2_libs="`$PKG_CONFIG --libs pangoft2`"
1357   case "$ft2_libs" in
1358     *-lfreetype*) pango_omitted_ft2_deps=no ;;
1359     *)            pango_omitted_ft2_deps=yes ;;
1360   esac
1361
1362   CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
1363
1364   if test x$enable_shadowfb = xyes ; then
1365     AC_DEFINE(ENABLE_SHADOW_FB)
1366   fi
1367
1368   if test x$enable_fbmanager = xyes ; then
1369     AC_DEFINE(ENABLE_FB_MANAGER)
1370     AM_CONDITIONAL(ENABLE_FB_MANAGER, true)
1371   else
1372     AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
1373   fi
1374
1375   if test $pango_omitted_ft2_deps = yes ; then
1376     GDK_EXTRA_LIBS="$FREETYPE_LIBS $GDK_EXTRA_LIBS"
1377   fi
1378
1379   AM_CONDITIONAL(USE_LINUX_FB, true)
1380 else
1381   AM_CONDITIONAL(USE_LINUX_FB, false)
1382   AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
1383 fi
1384
1385 #
1386 # Pick correct Pango packages to use
1387 #
1388
1389 if test "x$gdktarget" = "xx11"; then
1390         PANGO_PACKAGES=pangoxft
1391
1392         # We no longer use pangox, but if we find it, we link to it
1393         # for binary compatibility.
1394         if $PKG_CONFIG --exists pangox ; then
1395                 PANGO_PACKAGES="$PANGO_PACKAGES pangox"
1396         fi
1397 elif test "x$gdktarget" = "xwin32"; then
1398         PANGO_PACKAGES=pangowin32
1399 elif test "x$gdktarget" = "xlinux-fb"; then
1400         PANGO_PACKAGES=pangoft2
1401 else
1402         PANGO_PACKAGES=pango
1403 fi
1404
1405 # Check for Pango flags
1406
1407 AC_MSG_CHECKING(Pango flags)
1408 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1409         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1410         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1411
1412         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1413 else
1414         AC_MSG_ERROR([
1415 *** Pango not found. Pango is required to build GTK+.
1416 *** See http://www.pango.org for Pango information.
1417 *** For the framebuffer target, you will need to build
1418 *** Pango with freetype support.
1419 ])
1420 fi
1421
1422 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1423
1424 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1425         :
1426 else
1427         gtk_save_LIBS="$LIBS"
1428         LIBS="$PANGO_LIBS $LIBS"
1429         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1430 *** Can't link to Pango. Pango is required to build
1431 *** GTK+. For more information see http://www.pango.org]))
1432         LIBS="$gtk_save_LIBS"
1433 fi
1434
1435 CFLAGS="$saved_cflags"
1436 LDFLAGS="$saved_ldflags"
1437
1438 GDK_PACKAGES="$PANGO_PACKAGES"
1439 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
1440 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS"
1441
1442 #
1443 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1444 # into the pkg-config files
1445 #
1446 if test $enable_explicit_deps != yes ; then
1447   GDK_EXTRA_LIBS=
1448 fi
1449
1450 AC_SUBST(GDK_PACKAGES)
1451 AC_SUBST(GDK_EXTRA_LIBS)
1452 AC_SUBST(GDK_EXTRA_CFLAGS)
1453 AC_SUBST(GDK_DEP_LIBS)
1454 AC_SUBST(GDK_DEP_CFLAGS)
1455
1456
1457 ########################################
1458 # Check for Accessibility Toolkit flags
1459 ########################################
1460
1461 ATK_PACKAGES=atk
1462 AC_MSG_CHECKING(ATK flags)
1463 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1464         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1465         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1466
1467         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1468 else
1469         AC_MSG_ERROR([
1470 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1471 *** to build GTK+.
1472 ])
1473 fi
1474
1475 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1476         :
1477 else
1478         gtk_save_LIBS="$LIBS"
1479         LIBS="$ATK_LIBS $LIBS"
1480         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1481                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1482                 *** to build GTK+]))
1483         LIBS="$gtk_save_LIBS"
1484 fi
1485
1486 GTK_PACKAGES=atk
1487 GTK_EXTRA_LIBS=
1488 GTK_EXTRA_CFLAGS=
1489 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GTK_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
1490 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1491
1492 AC_SUBST(GTK_PACKAGES)
1493 AC_SUBST(GTK_EXTRA_LIBS)
1494 AC_SUBST(GTK_EXTRA_CFLAGS)
1495 AC_SUBST(GTK_DEP_LIBS)
1496 AC_SUBST(GTK_DEP_CFLAGS)
1497
1498
1499 AC_SUBST(GTK_DEBUG_FLAGS)
1500 AC_SUBST(GTK_XIM_FLAGS)
1501
1502 ################################################################
1503 # Strip -export-dynamic from the link lines of various libraries
1504 ################################################################
1505
1506 #
1507 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1508 #  but this flag is only meaningful for executables. For libraries
1509 #  the effect is undefined; what it causes on Linux is that the
1510 #  export list from -export-symbols-regex is ignored and everything
1511 #  is exported
1512 #
1513 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1514 if test -n "$export_dynamic"; then
1515   GDK_PIXBUF_DEP_LIBS=`echo $GDK_PIXBUF_DEP_LIBS | sed -e "s/$export_dynamic//"`
1516   GDK_PIXBUF_XLIB_DEP_LIBS=`echo $GDK_PIXBUF_XLIB_DEP_LIBS | sed -e "s/$export_dynamic//"`
1517   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1518   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1519 fi
1520
1521
1522 ##################################################
1523 # Checks for gtk-doc and docbook-tools
1524 ##################################################
1525
1526 GTK_DOC_CHECK([1.0])
1527
1528 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1529 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1530
1531 AC_ARG_ENABLE(man,
1532               [AC_HELP_STRING([--enable-man],
1533                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1534               enable_man=no)
1535
1536 if test "${enable_man}" != no; then
1537   dnl
1538   dnl Check for xsltproc
1539   dnl
1540   AC_PATH_PROG([XSLTPROC], [xsltproc])
1541   if test -z "$XSLTPROC"; then
1542     enable_man=no
1543   fi
1544
1545   dnl check for DocBook DTD and stylesheets in the local catalog.
1546   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1547      [DocBook XML DTD V4.1.2],,enable_man=no)
1548   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1549      [DocBook XSL Stylesheets],,enable_man=no)
1550 fi
1551
1552 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1553
1554 ##################################################
1555 # Output commands
1556 ##################################################
1557
1558 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1559         outfile=gdkconfig.h-tmp
1560         cat > $outfile <<\_______EOF
1561 /* gdkconfig.h
1562  *
1563  * This is a generated file.  Please modify `configure.in'
1564  */
1565
1566 #ifndef GDKCONFIG_H
1567 #define GDKCONFIG_H
1568
1569 #ifdef __cplusplus
1570 extern "C" {
1571 #endif /* __cplusplus */
1572
1573 _______EOF
1574
1575         cat >>$outfile <<_______EOF
1576 $gdk_windowing
1577 $gdk_wc
1578 _______EOF
1579
1580         cat >>$outfile <<_______EOF
1581
1582 #ifdef __cplusplus
1583 }
1584 #endif /* __cplusplus */
1585
1586 #endif /* GDKCONFIG_H */
1587 _______EOF
1588
1589
1590         if cmp -s $outfile gdk/gdkconfig.h; then
1591           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1592           rm -f $outfile
1593         else
1594           mv $outfile gdk/gdkconfig.h
1595         fi
1596 ],[
1597 if test "x$gdktarget" = "xx11" ; then
1598   gdk_windowing='
1599 #define GDK_WINDOWING_X11'
1600 elif test "x$gdktarget" = "xwin32" ; then
1601   gdk_windowing='
1602 #define GDK_WINDOWING_WIN32'
1603 elif test "x$gdktarget" = "xlinux-fb" ; then
1604   gdk_windowing='
1605 #define GDK_WINDOWING_FB
1606 #define GDK_NATIVE_WINDOW_POINTER'
1607 fi
1608
1609 if test x$gdk_wchar_h = xyes; then
1610   gdk_wc='
1611 #define GDK_HAVE_WCHAR_H 1'
1612 fi
1613 if test x$gdk_wctype_h = xyes; then
1614   gdk_wc="\$gdk_wc
1615 #define GDK_HAVE_WCTYPE_H 1"
1616 fi
1617 if test x$gdk_working_wctype = xno; then
1618   gdk_wc="\$gdk_wc
1619 #define GDK_HAVE_BROKEN_WCTYPE 1"
1620 fi
1621
1622
1623 ])
1624
1625 AC_CONFIG_FILES([
1626 config.h.win32
1627 gtk-zip.sh
1628 Makefile
1629 gdk-pixbuf-2.0.pc
1630 gdk-2.0.pc
1631 gtk+-2.0.pc
1632 gdk-pixbuf-2.0-uninstalled.pc
1633 gdk-2.0-uninstalled.pc
1634 gtk+-2.0-uninstalled.pc
1635 m4macros/Makefile
1636 po/Makefile.in
1637 po-properties/Makefile.in
1638 build/Makefile
1639 build/win32/Makefile
1640 build/win32/dirent/Makefile
1641 demos/Makefile
1642 demos/gtk-demo/Makefile
1643 demos/gtk-demo/geninclude.pl
1644 tests/Makefile
1645 docs/Makefile
1646 docs/reference/Makefile
1647 docs/reference/gdk-pixbuf/Makefile
1648 docs/reference/gdk-pixbuf/version.xml
1649 docs/reference/gdk/Makefile
1650 docs/reference/gdk/version.xml
1651 docs/reference/gtk/Makefile
1652 docs/reference/gtk/version.xml
1653 docs/faq/Makefile
1654 docs/tools/Makefile
1655 docs/tutorial/Makefile
1656 gdk-pixbuf/Makefile
1657 gdk-pixbuf/gdk_pixbuf.rc
1658 gdk-pixbuf/gdk-pixbuf-features.h
1659 gdk-pixbuf/pixops/Makefile
1660 gdk/Makefile
1661 gdk/x11/Makefile
1662 gdk/win32/Makefile
1663 gdk/win32/rc/Makefile
1664 gdk/win32/rc/gdk.rc
1665 gdk/linux-fb/Makefile
1666 gtk/Makefile
1667 gtk/makefile.msc
1668 gtk/gtkversion.h
1669 gtk/gtk-win32.rc
1670 gtk/stock-icons/Makefile
1671 gtk/theme-bits/Makefile
1672 gtk/xdgmime/Makefile
1673 modules/Makefile
1674 modules/input/Makefile
1675 modules/engines/Makefile
1676 modules/engines/pixbuf/Makefile
1677 modules/engines/ms-windows/Makefile
1678 modules/engines/ms-windows/Theme/Makefile
1679 modules/engines/ms-windows/Theme/gtk-2.0/Makefile
1680 contrib/Makefile
1681 contrib/gdk-pixbuf-xlib/Makefile
1682 contrib/gdk-pixbuf-xlib/gdk-pixbuf-xlib-2.0.pc
1683 ])
1684
1685 AC_OUTPUT