Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(gdk/gdktypes.h)
   3
   4 #
   5 # For each of the libraries we build, we define the following
   6 # substituted variables:
   7 #
   8 # foo_PACKAGES:     pkg-config packages this library requires
   9 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  10 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  11 # foo_DEP_LIBS:     All libraries this module requires
  12 # foo_DEP_CFLAGS:   All cflags this module requires
  13
  14
  15 ## We could have pkg-config uniquify the ldflags and cflags by calling
  16 ## it once with both the GLib and Pango package names, but we don't,
  17 ## someone should fix that.
  18
  19
  20 # Save this value here, since automake will set cflags later
  21 cflags_set=${CFLAGS+set}
  22
  23 dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  24 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  25 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  26 #
  27 # Making releases:
  28 #   GTK_MICRO_VERSION += 1;
  29 #   GTK_INTERFACE_AGE += 1;
  30 #   GTK_BINARY_AGE += 1;
  31 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  32 # if backwards compatibility has been broken,
  33 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  34 #
  35 GTK_MAJOR_VERSION=1
  36 GTK_MINOR_VERSION=3
  37 GTK_MICRO_VERSION=7
  38 GTK_INTERFACE_AGE=0
  39 GTK_BINARY_AGE=0
  40 GTK_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$GTK_MICRO_VERSION
  41 dnl
  42 AC_DIVERT_POP()dnl
  43
  44 AC_SUBST(GTK_MAJOR_VERSION)
  45 AC_SUBST(GTK_MINOR_VERSION)
  46 AC_SUBST(GTK_MICRO_VERSION)
  47 AC_SUBST(GTK_INTERFACE_AGE)
  48 AC_SUBST(GTK_BINARY_AGE)
  49 AC_SUBST(GTK_VERSION)
  50
  51 # libtool versioning
  52 LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  53 LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  54 LT_REVISION=$GTK_INTERFACE_AGE
  55 LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  56 AC_SUBST(LT_RELEASE)
  57 AC_SUBST(LT_CURRENT)
  58 AC_SUBST(LT_REVISION)
  59 AC_SUBST(LT_AGE)
  60
  61 #
  62 # gdk-pixbuf gets versioned separately, and for now, using standard
  63 # libtool versioning, not GTK+-style versioning
  64 #
  65 GDK_PIXBUF_MAJOR=$GTK_MAJOR_VERSION
  66 GDK_PIXBUF_MINOR=$GTK_MINOR_VERSION
  67 GDK_PIXBUF_MICRO=$GTK_MICRO_VERSION
  68 GDK_PIXBUF_VERSION="${GDK_PIXBUF_MAJOR}.${GDK_PIXBUF_MINOR}.${GDK_PIXBUF_MICRO}"
  69 AC_SUBST(GDK_PIXBUF_MAJOR)
  70 AC_SUBST(GDK_PIXBUF_MINOR)
  71 AC_SUBST(GDK_PIXBUF_MICRO)
  72 AC_SUBST(GDK_PIXBUF_VERSION)
  73
  74 # For automake.
  75 VERSION=$GTK_VERSION
  76 PACKAGE=gtk+
  77
  78 GETTEXT_PACKAGE=gtk20
  79 AC_SUBST(GETTEXT_PACKAGE)
  80 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
  81
  82 # Save this value here, since automake will set cflags later
  83 cflags_set=${CFLAGS+set}
  84
  85 dnl Initialize automake stuff
  86 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  87
  88 # Specify a configuration file
  89 AM_CONFIG_HEADER(config.h)
  90
  91 dnl Initialize libtool
  92 AM_PROG_LIBTOOL
  93
  94 dnl Initialize maintainer mode
  95 AM_MAINTAINER_MODE
  96
  97 AC_CANONICAL_HOST
  98
  99 dnl figure debugging default, prior to $ac_help setup
 100 dnl
 101 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
 102 if test `expr $GTK_MINOR_VERSION \% 2` = 1 ; then
 103         debug_default=yes
 104 else
 105         debug_default=minimum
 106 fi
 107 AC_DIVERT_POP()dnl
 108
 109 dnl declare --enable-* args and collect ac_help strings
 110 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 111 AC_ARG_ENABLE(shm, [  --enable-shm            support shared memory if available [default=yes]],
 112                    echo $enable_shm, enable_shm="yes")
 113 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 114                     , enable_ansi=no)
 115 AC_ARG_ENABLE(xim, [  --enable-xim            support XIM [default=yes]],
 116                         , enable_xim="yes")
 117 AC_ARG_ENABLE(xim_inst, [  --disable-xim-inst      does not use xim instantiate callback],
 118                         , enable_xim_inst="maybe")
 119 AC_ARG_ENABLE(xkb, [  --enable-xkb            support XKB [default=maybe]],
 120                         , enable_xkb="maybe")
 121 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 122
 123 AC_ARG_WITH(xinput, [  --with-xinput=[no/gxi/xfree] support XInput ])
 124
 125 gdktarget=x11
 126 gdktargetlib=libgdk-x11-1.3.la
 127 gtktargetlib=libgtk-x11-1.3.la
 128 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[x11/nanox/linux-fb] select GDK target [default=x11] ],
 129         gdktarget=$with_gdktarget)
 130
 131 AC_SUBST(gdktarget)
 132 case $gdktarget in
 133   x11|nanox|linux-fb) ;;
 134   *) AC_MSG_ERROR([Invalid target for GDK: use x11, nanox or linux-fb.]);;
 135 esac
 136
 137 AC_ARG_ENABLE(shadowfb, [  --disable-shadowfb      disable shadowfb support for linux-fb],,enable_shadowfb=yes)
 138
 139 AC_ARG_ENABLE(fbmanager, [  --enable-fbmanager      enable framebuffer manager support (GtkFB)],enable_fbmanager=yes,enable_fbmanager=no)
 140
 141 if test "x$enable_debug" = "xyes"; then
 142   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 143   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 144 else
 145   if test "x$enable_debug" = "xno"; then
 146     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 147   else
 148     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 149   fi
 150 fi
 151
 152 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 153
 154
 155 # Build time sanity check...
 156 AM_SANITY_CHECK
 157
 158 # Checks for programs.
 159 AC_PROG_CC
 160 AC_ISC_POSIX
 161 AM_PROG_CC_STDC
 162 AC_PROG_INSTALL
 163 AC_PROG_MAKE_SET
 164
 165 changequote(,)dnl
 166 if test "x$GCC" = "xyes"; then
 167   case " $CFLAGS " in
 168   *[\ \ ]-Wall[\ \      ]*) ;;
 169   *) CFLAGS="$CFLAGS -Wall" ;;
 170   esac
 171
 172   if test "x$enable_ansi" = "xyes"; then
 173     case " $CFLAGS " in
 174     *[\ \       ]-ansi[\ \      ]*) ;;
 175     *) CFLAGS="$CFLAGS -ansi" ;;
 176     esac
 177
 178     case " $CFLAGS " in
 179     *[\ \       ]-pedantic[\ \  ]*) ;;
 180     *) CFLAGS="$CFLAGS -pedantic" ;;
 181     esac
 182   fi
 183 fi
 184 changequote([,])dnl
 185
 186 # Honor aclocal flags
 187 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 188
 189 # libtool option to control which symbols are exported
 190 # right now, symbols starting with _ are not exported
 191 LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 192 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 193
 194 # define a MAINT-like variable REBUILD which is set if Perl
 195 # and awk are found, so autogenerated sources can be rebuilt
 196
 197 AC_PROG_AWK
 198 AC_CHECK_PROGS(PERL, perl5 perl)
 199
 200 # We would like indent, but don't require it.
 201 AC_CHECK_PROG(INDENT, indent, indent)
 202
 203 REBUILD=\#
 204 if test "x$enable_rebuilds" = "xyes" && \
 205      test -n "$PERL" && \
 206      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 207      test -n "$AWK" ; then
 208   REBUILD=
 209 fi
 210 AC_SUBST(REBUILD)
 211
 212 AC_CHECK_FUNCS(lstat mkstemp sigsetjmp bind_textdomain_codeset)
 213
 214 AC_MSG_CHECKING(whether make is GNU Make)
 215 STRIP_BEGIN=
 216 STRIP_END=
 217 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 218         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 219         STRIP_END=')'
 220         AC_MSG_RESULT(yes)
 221 else
 222         AC_MSG_RESULT(no)
 223 fi
 224 STRIP_DUMMY=
 225 AC_SUBST(STRIP_DUMMY)
 226 AC_SUBST(STRIP_BEGIN)
 227 AC_SUBST(STRIP_END)
 228
 229 # i18n stuff
 230 ALL_LINGUAS="az ca cs da de el en_GB en@IPA es et eu fa fi fr ga gl he hr hu ia it ja ko lt nl nn no pl pt pt_BR ro ru sk sl sp sr sv tr uk vi wa zh_TW zh_CN"
 231 AM_GLIB_GNU_GETTEXT
 232 LIBS="$LIBS $INTLLIBS"
 233
 234 # AM_GLIB_GNU_GETTEXT above substs $DATADIRNAME
 235 # this is the directory where the *.{mo,gmo} files are installed
 236 gtklocaledir='${prefix}/${DATADIRNAME}/locale'
 237 AC_SUBST(gtklocaledir)
 238
 239 dnl The DU4 header files don't provide library prototypes unless
 240 dnl -std1 is given to the native cc.
 241 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 242
 243 gtk_save_LIBS=$LIBS
 244 LIBS="$LIBS -lm"
 245 AC_TRY_RUN([#include <math.h>
 246              int main (void) { return (log(1) != log(1.)); }],
 247      AC_MSG_RESULT(none needed),
 248      gtk_save_CFLAGS="$CFLAGS"
 249      CFLAGS="$CFLAGS -std1"
 250      AC_TRY_RUN([#include <math.h>
 251                  int main (void) { return (log(1) != log(1.)); }],
 252          AC_MSG_RESULT(-std1),
 253          AC_MSG_RESULT()
 254          CFLAGS="$gtk_save_CFLAGS"
 255          AC_MSG_WARN(
 256                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 257          true
 258      ),
 259      AC_MSG_RESULT(none needed)
 260 )
 261 LIBS=$gtk_save_LIBS
 262
 263 MATH_LIB=-lm
 264 AC_MSG_CHECKING(for the BeOS)
 265 case $host in
 266   *-*-beos*)
 267     AC_MSG_RESULT(yes)
 268     MATH_LIB=
 269   ;;
 270   *)
 271     AC_MSG_RESULT(no)
 272   ;;
 273 esac
 274
 275 dnl NeXTStep cc seems to need this
 276 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 277 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 278   AC_MSG_RESULT(none needed),
 279   gtk_save_CFLAGS="$CFLAGS"
 280   CFLAGS="$CFLAGS -posix"
 281   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 282     AC_MSG_RESULT(-posix),
 283     AC_MSG_RESULT()
 284     CFLAGS="$gtk_save_CFLAGS"
 285     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 286
 287 #
 288 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 289 #
 290
 291 GLIB_PACKAGES="gobject-2.0 gmodule-2.0"
 292 GLIB_REQUIRED_VERSION=1.3.7
 293
 294 AM_PATH_GLIB_2_0($GLIB_REQUIRED_VERSION, :,
 295   AC_MSG_ERROR([
 296 *** GLIB $GLIB_REQUIRED_VERSION or better is required. The latest version of
 297 *** GLIB is always available from ftp://ftp.gtk.org/.]),
 298   gobject gmodule gthread)
 299
 300 AC_CHECK_HEADERS(dirent.h, AC_DEFINE(HAVE_DIRENT_H))
 301 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 302 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 303 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 304
 305 saved_cflags="$CFLAGS"
 306 saved_ldflags="$LDFLAGS"
 307
 308
 309 # Checks for header files.
 310 AC_HEADER_STDC
 311
 312 # Checks for typedefs, structures, and compiler characteristics.
 313 AC_C_CONST
 314
 315 # Checks for library functions.
 316 AC_TYPE_SIGNAL
 317 AC_FUNC_MMAP
 318
 319 AC_CHECK_FUNCS(getresuid)
 320 AC_TYPE_UID_T
 321
 322 # Check if <sys/select.h> needs to be included for fd_set
 323 AC_MSG_CHECKING([for fd_set])
 324 AC_TRY_COMPILE([#include <sys/types.h>],
 325         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 326 if test $gtk_ok = yes; then
 327     AC_MSG_RESULT([yes, found in sys/types.h])
 328 else
 329     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 330     if test $gtk_ok = yes; then
 331         AC_DEFINE(HAVE_SYS_SELECT_H)
 332         AC_MSG_RESULT([yes, found in sys/select.h])
 333     else
 334         AC_DEFINE(NO_FD_SET)
 335         AC_MSG_RESULT(no)
 336     fi
 337 fi
 338
 339 # `widechar' tests for gdki18n.h
 340 AC_MSG_CHECKING(for wchar.h)
 341 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 342 if test $gdk_wchar_h = yes; then
 343    AC_DEFINE(HAVE_WCHAR_H,1,[Have wchar.h include file])
 344 fi
 345 AC_MSG_RESULT($gdk_wchar_h)
 346
 347 # Check for wctype.h (for iswalnum)
 348 AC_MSG_CHECKING(for wctype.h)
 349 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 350 if test $gdk_wctype_h = yes; then
 351    AC_DEFINE(HAVE_WCTYPE_H,1,[Have wctype.h include file])
 352 fi
 353 AC_MSG_RESULT($gdk_wctype_h)
 354
 355 # in Solaris 2.5, `iswalnum' is in -lw
 356 GDK_WLIBS=
 357 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 358
 359 oLIBS="$LIBS"
 360 LIBS="$LIBS $GDK_WLIBS"
 361 # The following is necessary for Linux libc-5.4.38
 362 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 363 AC_TRY_LINK([#include <stdlib.h>],[
 364 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 365 #  ifdef HAVE_WCTYPE_H
 366 #    include <wctype.h>
 367 #  else
 368 #    ifdef HAVE_WCHAR_H
 369 #      include <wchar.h>
 370 #    endif
 371 #  endif
 372 #else
 373 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 374 #endif
 375 iswalnum((wchar_t) 0);
 376 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 377 LIBS="$oLIBS"
 378
 379 if test $gdk_working_wctype = no; then
 380    AC_DEFINE(HAVE_BROKEN_WCTYPE,1,[Is the wctype implementation broken])
 381    GDK_WLIBS=
 382 fi
 383 AC_MSG_RESULT($gdk_working_wctype)
 384 AC_SUBST(GDK_WLIBS)
 385
 386
 387
 388 ##################################################
 389 # Checks for gdk-pixbuf
 390 ##################################################
 391
 392 AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
 393
 394 AC_ARG_ENABLE(modules, [  --disable-modules       Disables dynamic module loading],[
 395         if test x$withval = xyes; then
 396             with_modules=yes
 397         else
 398             with_modules=no
 399         fi
 400 ])
 401
 402 dynworks=false
 403 deps=
 404 if test x$with_modules = xno; then
 405     AC_MSG_RESULT(no)
 406 else
 407     AC_MSG_RESULT(yes)
 408     AC_MSG_CHECKING(whether dynamic modules work)
 409     ## for loop is to strip newline
 410     tmp=`pkg-config --variable=gmodule_supported gmodule-2.0`
 411     for I in $tmp; do
 412         dynworks=$I
 413     done
 414 fi
 415
 416 dnl Now we check to see if our libtool supports shared lib deps
 417 dnl (in a rather ugly way even)
 418 if $dynworks; then
 419    pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} libtool --config"
 420    pixbuf_deplibs_check=`$pixbuf_libtool_config | \
 421       grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 422       sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 423    if test "x$pixbuf_deplibs_check" = "xnone" || \
 424       test "x$pixbuf_deplibs_check" = "xunknown" || \
 425       test "x$pixbuf_deplibs_check" = "x"; then
 426       dynworks=false
 427    fi
 428 fi
 429
 430 if $dynworks; then
 431    AC_DEFINE(USE_GMODULE)
 432    AC_MSG_RESULT(yes)
 433 else
 434    AC_MSG_RESULT(no)
 435 fi
 436
 437 dnl Test for libtiff
 438   if test -z "$LIBTIFF"; then
 439     AC_CHECK_LIB(tiff, TIFFReadScanline,
 440       AC_CHECK_HEADER(tiffio.h,
 441         TIFF='tiff'; LIBTIFF='-ltiff',
 442         AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 443       AC_CHECK_LIB(tiff, TIFFWriteScanline,
 444         AC_CHECK_HEADER(tiffio.h,
 445           TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
 446           AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 447         AC_CHECK_LIB(tiff34, TIFFFlushData,
 448           AC_CHECK_HEADER(tiffio.h,
 449             TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
 450             AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 451         AC_MSG_WARN(*** TIFF plug-in will not be built (TIFF library not found) ***), -ljpeg -lz -lm), -ljpeg -lz -lm), -lm)
 452   fi
 453
 454 dnl Test for libjpeg
 455   if test -z "$LIBJPEG"; then
 456     AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 457       jpeg_ok=yes,
 458       jpeg_ok=no
 459       AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
 460     if test "$jpeg_ok" = yes; then
 461       AC_MSG_CHECKING([for jpeglib.h])
 462       AC_TRY_CPP(
 463 [#include <stdio.h>
 464 #undef PACKAGE
 465 #undef VERSION
 466 #include <jpeglib.h>],
 467         jpeg_ok=yes,
 468         jpeg_ok=no)
 469       AC_MSG_RESULT($jpeg_ok)
 470       if test "$jpeg_ok" = yes; then
 471         LIBJPEG='-ljpeg'
 472         AC_CHECK_LIB(jpeg, jpeg_simple_progression,
 473           AC_DEFINE(HAVE_PROGRESSIVE_JPEG),
 474           AC_MSG_WARN(JPEG library does not support progressive saving.))
 475       else
 476           AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
 477       fi
 478     fi
 479   fi
 480
 481 dnl Test for libpng
 482   if test -z "$LIBPNG"; then
 483     AC_CHECK_LIB(png, png_read_info,
 484       AC_CHECK_HEADER(png.h,
 485         png_ok=yes,
 486         png_ok=no),
 487       AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
 488     if test "$png_ok" = yes; then
 489       AC_MSG_CHECKING([for png_structp in png.h])
 490       AC_TRY_COMPILE([#include <png.h>],
 491         [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 492         png_ok=yes,
 493         png_ok=no)
 494       AC_MSG_RESULT($png_ok)
 495       if test "$png_ok" = yes; then
 496         PNG='png'; LIBPNG='-lpng -lz'
 497       else
 498         AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
 499       fi
 500     else
 501      AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
 502     fi
 503   fi
 504
 505 AC_SUBST(LIBTIFF)
 506 AC_SUBST(LIBJPEG)
 507 AC_SUBST(LIBPNG)
 508
 509 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 510
 511 #
 512 # Allow building some or all gdk-pixbuf loaders included
 513 #
 514 AC_MSG_CHECKING(pixbuf loaders to build)
 515
 516 AC_ARG_WITH(included_loaders, [  --with-included-loaders=LOADER1,LOADER2,... Build the specified loaders into gdk-pixbuf (only used if module loading disabled)])
 517
 518 if $dynworks; then
 519         :
 520 else
 521    ## if the option was specified, leave it; otherwise disable included loaders
 522    if test x$with_included_loaders = xno; then
 523            with_included_loaders=yes
 524    fi
 525 fi
 526
 527 all_loaders="png,bmp,wbmp,gif,ico,jpeg,pnm,ras,tiff,xpm,tga"
 528 included_loaders=""
 529 # If no loaders specified, include all
 530 if test "x$with_included_loaders" = xyes ; then
 531   included_loaders="$all_loaders"
 532 else
 533   included_loaders="$with_included_loaders"
 534 fi
 535
 536 AC_MSG_RESULT($included_loaders)
 537
 538 INCLUDED_LOADER_OBJ=
 539 INCLUDED_LOADER_DEFINE=
 540
 541 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 542 for loader in $included_loaders; do
 543  if echo "$all_loaders" | grep "\(^\|\,\)$loader\(\$\|\,\)" > /dev/null; then
 544    :
 545  else
 546    AC_MSG_ERROR([the specified loader $loader does not exist])
 547  fi
 548
 549  INCLUDED_LOADER_OBJ="$INCLUDED_LOADER_OBJ libpixbufloader-static-$loader.la"
 550  INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_$loader"
 551 done
 552 IFS="$gtk_save_ifs"
 553 AC_SUBST(INCLUDED_LOADER_OBJ)
 554 AC_SUBST(INCLUDED_LOADER_DEFINE)
 555
 556 AC_HEADER_DIRENT
 557 AC_HEADER_SYS_WAIT
 558
 559 AC_TYPE_SIGNAL
 560
 561 AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
 562 AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
 563 AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
 564
 565 if $dynworks ; then
 566   STATIC_LIB_DEPS=
 567   if echo "$included_loaders" | grep "\(^\|\,\)tiff\(\$\|\,\)" > /dev/null; then
 568     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBTIFF"
 569   fi
 570   if echo "$included_loaders" | grep "\(^\|\,\)jpeg\(\$\|\,\)" > /dev/null; then
 571     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBJPEG"
 572   fi
 573   if echo "$included_loaders" | grep "\(^\|\,\)png\(\$\|\,\)" > /dev/null; then
 574     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBPNG"
 575   fi
 576 else
 577   STATIC_LIB_DEPS="$LIBTIFF $LIBJPEG $LIBPNG"
 578 fi
 579
 580 # Checks to see if we should compile in MMX support (there will be
 581 # a runtime test when the code is actually run to see if it should
 582 # be used - this just checks if we can compile it.)
 583 #
 584 # This code is partially taken from Mesa
 585 #
 586 AC_MSG_CHECKING(for x86 platform)
 587 case $host_cpu in
 588   i386|i486|i586|i686|i786|k6|k7)
 589         use_x86_asm=yes
 590         ;;
 591    *)
 592         use_x86_asm=no
 593 esac
 594 AC_MSG_RESULT($use_x86_asm)
 595
 596 use_mmx_asm=no
 597 if test $use_x86_asm = yes; then
 598     save_ac_ext=$ac_ext
 599     ac_ext=S
 600
 601     AC_MSG_CHECKING(compiler support for MMX)
 602     cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
 603     if AC_TRY_EVAL(ac_compile); then
 604         use_mmx_asm=yes
 605     fi
 606
 607     rm -rf conftest*
 608
 609     ac_ext=$save_ac_ext
 610     if test $use_mmx_asm = yes; then
 611       AC_DEFINE(USE_MMX)
 612       AC_MSG_RESULT(yes)
 613     else
 614       AC_MSG_RESULT(no)
 615     fi
 616 fi
 617
 618 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
 619
 620
 621 GDK_PIXBUF_PACKAGES="gmodule-2.0 gobject-2.0"
 622 GDK_PIXBUF_EXTRA_LIBS="$STATIC_LIB_DEPS $MATH_LIB"
 623 GDK_PIXBUF_EXTRA_CFLAGS=
 624 GDK_PIXBUF_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
 625 GDK_PIXBUF_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS"
 626
 627 AC_SUBST(GDK_PIXBUF_PACKAGES)
 628 AC_SUBST(GDK_PIXBUF_EXTRA_LIBS)
 629 AC_SUBST(GDK_PIXBUF_EXTRA_CFLAGS)
 630 AC_SUBST(GDK_PIXBUF_DEP_LIBS)
 631 AC_SUBST(GDK_PIXBUF_DEP_CFLAGS)
 632
 633
 634 ########################################
 635 # Windowing system checks
 636 ########################################
 637
 638 GDK_EXTRA_LIBS=$GDK_WLIBS
 639 GDK_EXTRA_CFLAGS=
 640
 641 if test "x$gdktarget" = "xx11"; then
 642   # We start off with the libraries from Pango
 643
 644   ## be sure we also have Pango built with xft support
 645   if $PKG_CONFIG --exists pangoxft ; then
 646     PANGO_PACKAGES="pangox pangoxft"
 647     have_xft=true
 648     AC_DEFINE(HAVE_XFT)
 649   else
 650     PANGO_PACKAGES="pangox"
 651     have_xft=false
 652   fi
 653
 654   AM_CONDITIONAL(HAVE_XFT, $have_xft)
 655
 656   x_libs="`$PKG_CONFIG --libs $PANGO_PACKAGES`"
 657   x_cflags="`$PKG_CONFIG --cflags $PANGO_PACKAGES`"
 658   x_extra_libs=
 659
 660   ## Strip the .la files
 661
 662   x_libs_for_checks=""
 663   for I in $x_libs ; do
 664     case $I in
 665       *.la) ;;
 666       *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 667     esac
 668   done
 669
 670   # Sanity check for the X11 library
 671   AC_CHECK_LIB(X11, XOpenDisplay, :,
 672             AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
 673             $x_libs_for_checks)
 674
 675   if test "x$enable_shm" = "xyes"; then
 676     # Check for the Xext library (needed for XShm extention)
 677     AC_CHECK_LIB(Xext, XShmAttach,
 678         if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 679           x_extra_libs="-lXext"
 680         fi,
 681         # On AIX, it is in XextSam instead, but we still need -lXext
 682         AC_CHECK_LIB(XextSam, XShmAttach,
 683             if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 684                x_extra_libs="-lXextSam -lXext"
 685             else
 686                x_extra_libs="-lXextSam"
 687             fi, , $x_libs_for_checks),
 688         $x_libs_for_checks)
 689   fi
 690
 691   GDK_PIXBUF_XLIB_EXTRA_CFLAGS="$x_cflags"
 692   # Don't ever pull in the pangoxft libraries for gdk-pixbuf-x11
 693   GDK_PIXBUF_XLIB_EXTRA_LIBS="$x_extra_libs `$PKG_CONFIG --libs pangox`"
 694
 695   # Check for shaped window extension
 696
 697   AC_CHECK_LIB(Xext, XShapeCombineMask,
 698       if test -z "`echo $x_extra_libs $x_libs | grep "\-lXext" 2> /dev/null`"; then
 699            x_extra_libs="-lXext $x_extra_libs"
 700       fi
 701       AC_DEFINE(HAVE_SHAPE_EXT),
 702       ,
 703       $x_libs_for_checks)
 704
 705   # Check for XConvertCase (X11R6 specific)
 706
 707   AC_CHECK_LIB(X11, XConvertCase,
 708       AC_DEFINE(HAVE_XCONVERTCASE),
 709       ,
 710       $x_libs_for_checks)
 711
 712   # Check for XIM support.
 713
 714   AC_CHECK_LIB(X11, XUnregisterIMInstantiateCallback,
 715             : ,
 716             enable_xim_inst="no",
 717             $x_libs_for_checks)
 718
 719   # On Solaris, calling XRegisterIMInstantiateCallback seems to
 720   # cause an immediate segfault, so we disable it, unless
 721   # the user specifically forces it to be on.
 722
 723   if test x$enable_xim_inst = xmaybe ; then
 724     case host in
 725           *-*-solaris*)
 726             enable_xim_inst="no"
 727             ;;
 728           *)
 729             enable_xim_inst="yes"
 730             ;;
 731     esac
 732   fi
 733
 734   if test "x$enable_xim" = "xyes"; then
 735     GTK_XIM_FLAGS="-DUSE_XIM"
 736     if test "x$enable_xim_inst" = "xyes"; then
 737       AC_DEFINE(USE_X11R6_XIM)
 738     fi
 739   fi
 740
 741   # Check for XKB support.
 742
 743   if test "x$enable_xkb" = "xyes"; then
 744         AC_MSG_WARN(XKB support explicitly enabled)
 745         AC_DEFINE(HAVE_XKB)
 746   elif test "x$enable_xkb" = "xmaybe"; then
 747         AC_CHECK_LIB(X11, XkbQueryExtension,
 748                      AC_DEFINE(HAVE_XKB),
 749                      ,
 750                      $x_libs_for_checks)
 751   else
 752         AC_MSG_WARN(XKB support explicitly disabled)
 753   fi
 754
 755   x_cflags="$X_CFLAGS"
 756   x_ldflags="$X_LDFLAGS"
 757
 758   # set up things for XInput
 759
 760   if test "x$with_xinput" = "xgxi" || test "x$with_xinput" = "xyes"; then
 761     AC_DEFINE(XINPUT_GXI)
 762     xinput_progs=gxid
 763     x_extra_libs="-lXi $x_extra_libs"
 764   elif test "x$with_xinput" = "xxfree"; then
 765     AC_DEFINE(XINPUT_XFREE)
 766     x_extra_libs="-lXi $x_extra_libs"
 767   else
 768     AC_DEFINE(XINPUT_NONE)
 769   fi
 770
 771   AM_CONDITIONAL(XINPUT_GXI, test x$with_xinput = xgxi)
 772   AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree)
 773
 774   if test "x$enable_shm" = "xyes"; then
 775     # Check for shared memory
 776     AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
 777     AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
 778
 779     # Check for the X shared memory extension header file
 780     have_xshm=no
 781     AC_MSG_CHECKING(X11/extensions/XShm.h)
 782     if test "x$no_xext_lib" = "xyes"; then
 783       :
 784     else
 785       gtk_save_CFLAGS="$CFLAGS"
 786       CFLAGS="$CFLAGS $x_cflags"
 787       AC_TRY_COMPILE([
 788 #include <stdlib.h>
 789 #include <sys/types.h>
 790 #include <sys/ipc.h>
 791 #include <sys/shm.h>
 792 #include <X11/Xlib.h>
 793 #include <X11/Xutil.h>
 794 #include <X11/extensions/XShm.h>
 795 ], [XShmSegmentInfo *x_shm_info;], have_xshm=yes)
 796       CFLAGS="$gtk_save_CFLAGS"
 797     fi
 798     AC_MSG_RESULT($have_xshm)
 799     if test $have_xshm = yes ; then
 800       AC_DEFINE(HAVE_XSHM_H)
 801     fi
 802   fi
 803
 804   GDK_EXTRA_CFLAGS=
 805   GDK_EXTRA_LIBS="$x_extra_libs"
 806
 807   # these are already defined above
 808   #gdktargetlib = "libgdk-x11-1.3.la"
 809   #gtktargetlib = "libgtk-x11-1.3.la"
 810
 811   AM_CONDITIONAL(USE_X11, true)
 812 else
 813   AM_CONDITIONAL(USE_X11, false)
 814 fi
 815
 816 AC_SUBST(xinput_progs)
 817
 818 GDK_PIXBUF_XLIB_PACKAGES=
 819 GDK_PIXBUF_XLIB_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_XLIB_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
 820 GDK_PIXBUF_XLIB_DEP_CFLAGS="`$PKG_CONFIG --cflags  $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_PIXBUF_XLIB_EXTRA_CFLAGS"
 821
 822 AC_SUBST(GDK_PIXBUF_XLIB_PACKAGES)
 823 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_LIBS)
 824 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_CFLAGS)
 825 AC_SUBST(GDK_PIXBUF_XLIB_DEP_LIBS)
 826 AC_SUBST(GDK_PIXBUF_XLIB_DEP_CFLAGS)
 827
 828 if test "x$gdktarget" = "xnanox"; then
 829   AC_CHECK_LIB(nano-X, GrOpen,,AC_MSG_ERROR([nano-X libraries not found.]))
 830   # nano-X may require additional libraries
 831   GDK_EXTRA_LIBS="-lnano-X $GDK_EXTRA_LIBS"
 832
 833   gdktargetlib="libgdk-nanox-1.3.la"
 834   gtktargetlib="libgtk-nanox-1.3.la"
 835
 836   AM_CONDITIONAL(USE_NANOX, true)
 837 else
 838   AM_CONDITIONAL(USE_NANOX, false)
 839 fi
 840
 841 if test "x$gdktarget" = "xlinux-fb"; then
 842   gdktargetlib="libgdk-linux-fb-1.3.la"
 843   gtktargetlib="libgtk-linux-fb-1.3.la"
 844
 845   AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
 846   if test x$FREETYPE_CONFIG = xno ; then
 847     AC_MSG_ERROR([*** freetype-config not found])
 848   fi
 849
 850   FREETYPE_CFLAGS="`$FREETYPE_CONFIG --cflags`"
 851   FREETYPE_LIBS="`$FREETYPE_CONFIG --libs`"
 852   CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 853
 854   if test x$enable_shadowfb = xyes ; then
 855     AC_DEFINE(ENABLE_SHADOW_FB)
 856   fi
 857
 858   if test x$enable_fbmanager = xyes ; then
 859     AC_DEFINE(ENABLE_FB_MANAGER)
 860     AM_CONDITIONAL(ENABLE_FB_MANAGER, true)
 861   else
 862     AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
 863   fi
 864
 865   GDK_EXTRA_CFLAGS="$FREETYPE_CFLAGS"
 866   GDK_EXTRA_LIBS="$FREETYPE_LIBS $GDK_EXTRA_LIBS"
 867
 868   AM_CONDITIONAL(USE_LINUX_FB, true)
 869 else
 870   AM_CONDITIONAL(USE_LINUX_FB, false)
 871   AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
 872 fi
 873
 874 AC_SUBST(gdktargetlib)
 875 AC_SUBST(gtktargetlib)
 876
 877 #
 878 # Pick correct Pango packages to use
 879 #
 880
 881 if test "x$gdktarget" = "xx11"; then
 882         if $have_xft = true ; then
 883             PANGO_PACKAGES="pangox pangoxft"
 884         else
 885             PANGO_PACKAGES=pangox
 886         fi
 887 elif test "x$gdktarget" = "xlinux-fb"; then
 888         PANGO_PACKAGES=pangoft2
 889 else
 890         PANGO_PACKAGES=pango
 891 fi
 892
 893 # Check for Pango flags
 894
 895 AC_MSG_CHECKING(Pango flags)
 896 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
 897         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
 898         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
 899
 900         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
 901 else
 902         AC_MSG_ERROR([
 903 *** Pango not found. Pango is required to build GTK+.
 904 *** See http://www.pango.org for Pango information.
 905 *** For the framebuffer target, you will need to build
 906 *** Pango with freetype support.
 907 ])
 908 fi
 909
 910 CFLAGS="$CFLAGS $PANGO_CFLAGS"
 911
 912 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
 913         :
 914 else
 915         AC_CHECK_LIB(pango, pango_context_new, :, AC_MSG_ERROR([
 916 *** Can't link to Pango. Pango is required to build
 917 *** GTK+. For more information see http://www.pango.org]), $PANGO_LIBS)
 918 fi
 919
 920 CFLAGS="$saved_cflags"
 921 LDFLAGS="$saved_ldflags"
 922
 923 GDK_PACKAGES=$PANGO_PACKAGES
 924 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
 925 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS"
 926
 927 AC_SUBST(GDK_PACKAGES)
 928 AC_SUBST(GDK_EXTRA_LIBS)
 929 AC_SUBST(GDK_EXTRA_CFLAGS)
 930 AC_SUBST(GDK_DEP_LIBS)
 931 AC_SUBST(GDK_DEP_CFLAGS)
 932
 933
 934 ########################################
 935 # Check for Accessibility Toolkit flags
 936 ########################################
 937
 938 ATK_PACKAGES=atk
 939 AC_MSG_CHECKING(ATK flags)
 940 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
 941         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
 942         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
 943
 944         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
 945 else
 946         AC_MSG_ERROR([
 947 *** Accessibility Toolkit not found. Accessibility Toolkit is required
 948 *** to build GTK+.
 949 ])
 950 fi
 951
 952 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
 953         :
 954 else
 955         AC_CHECK_LIB(atk, atk_object_get_type, : , AC_MSG_ERROR([
 956                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
 957                 *** to build GTK+]), $ATK_LIBS $GLIB_LIBS)
 958 fi
 959
 960 GTK_PACKAGES=atk
 961 GTK_EXTRA_LIBS=
 962 GTK_EXTRA_CFLAGS=
 963 GTK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GTK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GTK_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
 964 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  $GTK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
 965
 966 AC_SUBST(GTK_PACKAGES)
 967 AC_SUBST(GTK_EXTRA_LIBS)
 968 AC_SUBST(GTK_EXTRA_CFLAGS)
 969 AC_SUBST(GTK_DEP_LIBS)
 970 AC_SUBST(GTK_DEP_CFLAGS)
 971
 972
 973 AC_SUBST(GTK_DEBUG_FLAGS)
 974 AC_SUBST(GTK_XIM_FLAGS)
 975
 976 ##################################################
 977 # Checks for gtk-doc and docbook-tools
 978 ##################################################
 979
 980 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
 981
 982 if test "x$with_html_dir" = "x" ; then
 983   HTML_DIR='${datadir}/gtk-doc/html'
 984 else
 985   HTML_DIR=$with_html_dir
 986 fi
 987
 988 AC_SUBST(HTML_DIR)
 989
 990 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
 991
 992 gtk_doc_min_version=0.6
 993 if $GTKDOC ; then
 994     gtk_doc_version=`gtkdoc-mkdb --version`
 995     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
 996     if perl <<EOF ; then
 997       exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
 998             ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
 999 EOF
1000       AC_MSG_RESULT(yes)
1001    else
1002       AC_MSG_RESULT(no)
1003       GTKDOC=false
1004    fi
1005 fi
1006
1007 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1008 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1009
1010 dnl Let people disable the gtk-doc stuff.
1011 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1012
1013 if test x$enable_gtk_doc = xauto ; then
1014   if test x$GTKDOC = xtrue ; then
1015     enable_gtk_doc=yes
1016   else
1017     enable_gtk_doc=no
1018   fi
1019 fi
1020
1021 dnl NOTE: We need to use a separate automake conditional for this
1022 dnl       to make this work with the tarballs.
1023 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1024
1025
1026 ##################################################
1027 # Output commands
1028 ##################################################
1029
1030 AC_OUTPUT_COMMANDS([
1031
1032 ## Generate `gdk/gdkconfig.h' in two cases
1033 ## 1. `config.status' is run either explicitly, or via configure.
1034 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1035 ##     config.h
1036 ## 2. CONFIG_OTHER is set explicitly
1037 ##
1038 ## Case 1 is difficult.  We know that `automake' sets one of
1039 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1040 ## only when AM_CONFIG_HEADER is set, however.
1041
1042 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1043   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1044   CONFIG_OTHER=${CONFIG_OTHER:-gdk/gdkconfig.h}
1045 fi
1046 case "$CONFIG_OTHER" in
1047 *gdk/gdkconfig.h*)
1048         echo creating gdk/gdkconfig.h
1049         outfile=gdkconfig.h-tmp
1050         cat > $outfile <<\_______EOF
1051 /* gdkconfig.h
1052  *
1053  * This is a generated file.  Please modify `configure.in'
1054  */
1055
1056 #ifndef GDKCONFIG_H
1057 #define GDKCONFIG_H
1058
1059 #ifdef __cplusplus
1060 extern "C" {
1061 #endif /* __cplusplus */
1062
1063 _______EOF
1064
1065         cat >>$outfile <<_______EOF
1066 $gdk_windowing
1067 $gdk_wc
1068 _______EOF
1069
1070         cat >>$outfile <<_______EOF
1071
1072 #ifdef __cplusplus
1073 }
1074 #endif /* __cplusplus */
1075
1076 #endif /* GDKCONFIG_H */
1077 _______EOF
1078
1079
1080         if cmp -s $outfile gdk/gdkconfig.h; then
1081           echo gdk/gdkconfig.h is unchanged
1082           rm -f $outfile
1083         else
1084           mv $outfile gdk/gdkconfig.h
1085         fi ;;
1086 esac
1087 ],[
1088 if test "x$gdktarget" = "xx11" ; then
1089   gdk_windowing='
1090 #define GDK_WINDOWING_X11'
1091 elif test "x$gdktarget" = "xnanox" ; then
1092   gdk_windowing='
1093 #define GDK_WINDOWING_NANOX'
1094 elif test "x$gdktarget" = "xlinux-fb" ; then
1095   gdk_windowing='
1096 #define GDK_WINDOWING_FB
1097 #define GDK_NATIVE_WINDOW_POINTER'
1098 fi
1099
1100 if test x$gdk_wchar_h = xyes; then
1101   gdk_wc='
1102 #define GDK_HAVE_WCHAR_H 1'
1103 fi
1104 if test x$gdk_wctype_h = xyes; then
1105   gdk_wc="\$gdk_wc
1106 #define GDK_HAVE_WCTYPE_H 1"
1107 fi
1108 if test x$gdk_working_wctype = xno; then
1109   gdk_wc="\$gdk_wc
1110 #define GDK_HAVE_BROKEN_WCTYPE 1"
1111 fi
1112
1113
1114 ])
1115
1116 AC_PATH_PROG(SGML2HTML, sgml2html, no)
1117 AM_CONDITIONAL(HAVE_SGML2HTML, ! test x$SGML2HTML = xno)
1118
1119 AC_OUTPUT([
1120 config.h.win32
1121 gtk+.spec
1122 docs/gtk-config.1
1123 Makefile
1124 gdk-pixbuf-2.0.pc
1125 gdk-2.0.pc
1126 gtk+-2.0.pc
1127 gdk-pixbuf-2.0-uninstalled.pc
1128 gdk-2.0-uninstalled.pc
1129 gtk+-2.0-uninstalled.pc
1130 m4macros/Makefile
1131 po/Makefile.in
1132 build/Makefile
1133 build/win32/Makefile
1134 demos/Makefile
1135 demos/gtk-demo/Makefile
1136 tests/Makefile
1137 docs/Makefile
1138 docs/reference/Makefile
1139 docs/reference/gdk-pixbuf/Makefile
1140 docs/reference/gdk/Makefile
1141 docs/reference/gtk/Makefile
1142 docs/faq/Makefile
1143 docs/tutorial/Makefile
1144 gdk-pixbuf/Makefile
1145 gdk-pixbuf/makefile.mingw
1146 gdk-pixbuf/gdk-pixbuf-features.h
1147 gdk-pixbuf/pixops/Makefile
1148 gdk-pixbuf/pixops/makefile.mingw
1149 gdk/Makefile
1150 gdk/makefile.mingw
1151 gdk/x11/Makefile
1152 gdk/win32/Makefile
1153 gdk/win32/makefile.mingw
1154 gdk/win32/rc/Makefile
1155 gdk/win32/rc/gdk.rc
1156 gdk/nanox/Makefile
1157 gdk/linux-fb/Makefile
1158 gtk/Makefile
1159 gtk/makefile.mingw
1160 gtk/makefile.msc
1161 gtk/gtkversion.h
1162 gtk/gtk-win32.rc
1163 gtk/stock-icons/Makefile
1164 modules/Makefile
1165 modules/input/Makefile
1166 contrib/Makefile
1167 contrib/gdk-pixbuf-xlib/Makefile
1168 contrib/gdk-pixbuf-xlib/gdk-pixbuf-xlib-2.0.pc
1169 ])