Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(gdk/gdktypes.h)
   3
   4 # Save this value here, since automake will set cflags later
   5 cflags_set=${CFLAGS+set}
   6
   7 # Making releases:
   8 #   GTK_MICRO_VERSION += 1;
   9 #   GTK_INTERFACE_AGE += 1;
  10 #   GTK_BINARY_AGE += 1;
  11 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  12 # if backwards compatibility has been broken,
  13 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  14 #
  15 GTK_MAJOR_VERSION=1
  16 GTK_MINOR_VERSION=1
  17 GTK_MICRO_VERSION=7
  18 GTK_INTERFACE_AGE=0
  19 GTK_BINARY_AGE=0
  20 GTK_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$GTK_MICRO_VERSION
  21 AC_SUBST(GTK_MAJOR_VERSION)
  22 AC_SUBST(GTK_MINOR_VERSION)
  23 AC_SUBST(GTK_MICRO_VERSION)
  24 AC_SUBST(GTK_INTERFACE_AGE)
  25 AC_SUBST(GTK_BINARY_AGE)
  26 AC_SUBST(GTK_VERSION)
  27
  28 # libtool versioning
  29 LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  30 LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  31 LT_REVISION=$GTK_INTERFACE_AGE
  32 LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  33 AC_SUBST(LT_RELEASE)
  34 AC_SUBST(LT_CURRENT)
  35 AC_SUBST(LT_REVISION)
  36 AC_SUBST(LT_AGE)
  37
  38 # For automake.
  39 VERSION=$GTK_VERSION
  40 PACKAGE=gtk+
  41
  42 # Save this value here, since automake will set cflags later
  43 cflags_set=${CFLAGS+set}
  44
  45 dnl Initialize automake stuff
  46 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  47
  48 # Specify a configuration file
  49 AM_CONFIG_HEADER(config.h)
  50
  51 dnl Initialize libtool
  52 AM_PROG_LIBTOOL
  53
  54 dnl Initialize maintainer mode
  55 AM_MAINTAINER_MODE
  56
  57 AC_CANONICAL_HOST
  58
  59 AC_ARG_ENABLE(shm, [  --enable-shm            support shared memory if available [default=yes]],
  60                    echo $enable_shm, enable_shm="yes")
  61 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=minimum]],,enable_debug=minimum)
  62 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  63                     , enable_ansi=no)
  64 AC_ARG_WITH(glib, [  --with-glib=DIR         Use uninstalled copy of glib])
  65 AC_ARG_ENABLE(xim, [  --enable-xim            support XIM [default=yes]],
  66                         , enable_xim="yes")
  67 AC_ARG_WITH(locale, [  --with-locale=LOCALE    locale name you want to use ])
  68
  69 AC_ARG_WITH(xinput, [  --with-xinput=[no/gxi/xfree] support XInput ])
  70 AC_ARG_WITH(threads, [  --with-threads=[posix] support threading ])
  71
  72 if test "x$enable_debug" = "xyes"; then
  73   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
  74   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
  75 else
  76   if test "x$enable_debug" = "xno"; then
  77     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DGTK_NO_CHECK_CASTS"
  78   else
  79     GTK_DEBUG_FLAGS="-DGTK_NO_CHECK_CASTS"
  80   fi
  81 fi
  82
  83 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
  84
  85 # Build time sanity check...
  86 AM_SANITY_CHECK
  87
  88 # Checks for programs.
  89 AC_PROG_CC
  90 AM_PROG_CC_STDC
  91 AC_PROG_INSTALL
  92 AC_PROG_MAKE_SET
  93
  94 changequote(,)dnl
  95 if test "x$GCC" = "xyes"; then
  96   case " $CFLAGS " in
  97   *[\ \ ]-Wall[\ \      ]*) ;;
  98   *) CFLAGS="$CFLAGS -Wall" ;;
  99   esac
 100
 101   if test "x$enable_ansi" = "xyes"; then
 102     case " $CFLAGS " in
 103     *[\ \       ]-ansi[\ \      ]*) ;;
 104     *) CFLAGS="$CFLAGS -ansi" ;;
 105     esac
 106
 107     case " $CFLAGS " in
 108     *[\ \       ]-pedantic[\ \  ]*) ;;
 109     *) CFLAGS="$CFLAGS -pedantic" ;;
 110     esac
 111   fi
 112 fi
 113 changequote([,])dnl
 114
 115 # define a MAINT-like variable REBUILD which is set if Perl
 116 # and awk are found, so autogenerated sources can be rebuilt
 117
 118 AC_PROG_AWK
 119 AC_CHECK_PROGS(PERL, perl5 perl)
 120
 121 # We would like indent, but don't require it.
 122 AC_CHECK_PROG(INDENT, indent, indent)
 123
 124 REBUILD=\#
 125 if test -n "$PERL" && perl -v | grep 'version 5.' > /dev/null ; then
 126   if test -n "$AWK" ; then
 127     REBUILD=
 128   fi
 129 fi
 130 AC_SUBST(REBUILD)
 131
 132 # i18n stuff
 133 ALL_LINGUAS="de pt"
 134 AM_GNU_GETTEXT
 135 AC_CHECK_FUNC(gettext,
 136         ,
 137         AC_CHECK_LIB(intl, gettext)
 138 )
 139
 140 dnl The DU4 header files don't provide library prototypes unless
 141 dnl -std1 is given to the native cc.
 142 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 143
 144 gtk_save_LIBS=$LIBS
 145 LIBS="$LIBS -lm"
 146 AC_TRY_RUN([#include <math.h>
 147              int main (void) { return (log(1) != log(1.)); }],
 148      AC_MSG_RESULT(none needed),
 149      gtk_save_CFLAGS=$CFLAGS
 150      CFLAGS="$CFLAGS -std1"
 151      AC_TRY_RUN([#include <math.h>
 152                  int main (void) { return (log(1) != log(1.)); }],
 153          AC_MSG_RESULT(-std1),
 154          AC_MSG_RESULT()
 155          CFLAGS=$gtk_save_CFLAGS
 156          AC_MSG_WARN(
 157                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 158      )
 159 )
 160 LIBS=$gtk_save_LIBS
 161
 162 dnl NeXTStep cc seems to need this
 163 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 164 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 165   AC_MSG_RESULT(none needed),
 166   gtk_save_CFLAGS=$CFLAGS
 167   CFLAGS="$CFLAGS -posix"
 168   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 169     AC_MSG_RESULT(-posix),
 170     AC_MSG_RESULT()
 171     CFLAGS=$gtk_save_CFLAGS
 172     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 173
 174 if test x$with_glib = xyes ; then
 175   AC_MSG_ERROR([
 176 *** Directory must be specified for --with-glib])
 177 fi
 178
 179 if test x$with_glib = x ; then
 180   # Look for separately installed glib
 181
 182   AM_PATH_GLIB(1.1.6,,
 183     AC_MSG_ERROR([
 184 *** GLIB 1.1.6 or better is required. The latest version of GLIB
 185 *** is always available from ftp://ftp.gtk.org.]),
 186     gmodule)
 187
 188   glib_cflags=$GLIB_CFLAGS
 189   glib_libs=$GLIB_LIBS
 190 else
 191   # Use uninstalled glib (assume they got the version right)
 192
 193   GLIB_CONFIG=$with_glib/glib-config
 194   if test -x $GLIB_CONFIG ; then
 195     :
 196   else
 197     AC_MSG_ERROR([GLIB directory ($with_glib) not present or not configured])
 198   fi
 199
 200   # For use in gtk-config
 201   glib_cflags=`$GLIB_CONFIG --cflags`
 202   glib_libs=`$GLIB_CONFIG --libs`
 203
 204   glib_release=`$GLIB_CONFIG --version | sed 's%\\.[[0-9]]*$%%'`
 205
 206   # canonicalize relative paths
 207   case $with_glib in
 208     /*)
 209       glib_dir=$with_glib
 210       ;;
 211     *)
 212       glib_dir="\$(top_builddir)/$with_glib"
 213       ;;
 214   esac
 215
 216   GLIB_CFLAGS="-I$glib_dir"
 217   GLIB_LIBS=$glib_dir/libglib-$glib_release.la
 218
 219   AC_SUBST(GLIB_CFLAGS)
 220   AC_SUBST(GLIB_LIBS)
 221 fi
 222
 223 AC_SUBST(glib_cflags)
 224 AC_SUBST(glib_libs)
 225
 226 # Find the X11 include and library directories
 227 AC_PATH_X
 228 AC_PATH_XTRA
 229
 230 if test "x$x_includes" = "x"; then
 231   x_includes="/usr/include"
 232 fi
 233
 234 saved_cflags="$CFLAGS"
 235 saved_ldflags="$LDFLAGS"
 236
 237 CFLAGS="$CFLAGS $X_CFLAGS"
 238 LDFLAGS="$LDFLAGS $X_LDFLAGS $X_LIBS"
 239
 240 if test "x$no_x" = "xyes"; then
 241   AC_MSG_ERROR([
 242 *** X libraries or include files not found. Check 'config.log' for
 243 *** more details.])
 244 fi
 245
 246 # Checks for libraries.
 247 # Check for the X11 library
 248 AC_CHECK_LIB(X11, XOpenDisplay, x_libs="-lX11 $X_EXTRA_LIBS",
 249   AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
 250   $X_EXTRA_LIBS)
 251
 252 if test "x$enable_shm" = "xyes"; then
 253   # Check for the Xext library (needed for XShm extention)
 254   AC_CHECK_LIB(Xext, XShmAttach,
 255       x_libs="-lXext $x_libs",
 256       # On AIX, it is in XextSam instead, but we still need -lXext
 257       AC_CHECK_LIB(XextSam, XShmAttach,
 258           x_libs="-lXextSam -lXext $x_libs",
 259           no_xext_lib=yes, $x_libs),
 260       $x_libs)
 261 fi
 262
 263 # Check for shaped window extension
 264
 265 AC_CHECK_LIB(Xext, XShapeCombineMask,
 266       if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 267            x_libs="-lXext $x_libs"
 268       fi
 269       AC_DEFINE(HAVE_SHAPE_EXT),
 270       ,
 271       $x_libs)
 272
 273 # Check for XConvertCase (X11R6 specific)
 274
 275 AC_CHECK_LIB(X11, XConvertCase,
 276       AC_DEFINE(HAVE_XCONVERTCASE),
 277       ,
 278       $x_libs)
 279
 280 # Check for XIM support.
 281
 282 AC_CHECK_LIB(X11, XUnregisterIMInstantiateCallback,
 283             : ,
 284             enable_xim=no,
 285             $x_libs)
 286
 287 if test "x$enable_xim" = "xyes"; then
 288   GTK_XIM_FLAGS="-DUSE_XIM"
 289 fi
 290
 291 x_cflags="$X_CFLAGS"
 292 x_ldflags="$X_LDFLAGS $X_LIBS"
 293
 294 # set up things for XInput
 295
 296 if test "x$with_xinput" = "xgxi" || test "x$with_xinput" = "xyes"; then
 297   AC_DEFINE(XINPUT_GXI)
 298   xinput_progs=gxid
 299   x_libs="-lXi $x_libs"
 300 elif test "x$with_xinput" = "xxfree"; then
 301   AC_DEFINE(XINPUT_XFREE)
 302   x_libs="-lXi $x_libs"
 303 else
 304   AC_DEFINE(XINPUT_NONE)
 305 fi
 306
 307 # Threads
 308
 309 if test "x$with_threads" = "xposix" || test "x$with_threads" = "xyes"; then
 310   AC_CHECK_LIB(pthread, pthread_attr_init,
 311     [AC_DEFINE(USE_PTHREADS)
 312     x_libs="$x_libs -lpthread"
 313     GTK_THREAD_FLAGS="-D_REENTRANT"],
 314     # AIX has libpthreads, cause they're special. Special friends (TM)
 315     AC_CHECK_LIB(pthreads, pthread_attr_init,
 316       [AC_DEFINE(USE_PTHREADS)
 317       x_libs="$x_libs -lpthreads"
 318       GTK_THREAD_FLAGS="-D_REENTRANT -D_THREAD_SAFE"]))
 319 fi
 320
 321 CFLAGS="$saved_cflags"
 322 LDFLAGS="$saved_ldflags"
 323
 324 AC_SUBST(x_cflags)
 325 AC_SUBST(x_includes)
 326 AC_SUBST(x_ldflags)
 327 AC_SUBST(x_libs)
 328 AC_SUBST(xinput_progs)
 329
 330 if test "x$enable_shm" = "xyes"; then
 331   # Check for shared memory
 332   AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
 333   AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
 334
 335   # Check whether shmctl IPC_RMID allowes subsequent attaches
 336   if test "$ac_cv_header_sys_shm_h" = "yes"; then
 337     AC_MSG_CHECKING(whether shmctl IPC_RMID allowes subsequent attaches)
 338     AC_TRY_RUN([
 339           #include <sys/types.h>
 340           #include <sys/ipc.h>
 341           #include <sys/shm.h>
 342           int main()
 343           {
 344             int id;
 345             char *shmaddr;
 346           id = shmget (IPC_PRIVATE, 4, IPC_CREAT | 0777);
 347           if (id == -1)
 348             exit (2);
 349             shmaddr = shmat (id, 0, 0);
 350             shmctl (id, IPC_RMID, 0);
 351             if ((char*) shmat (id, 0, 0) == (char*) -1)
 352             {
 353               shmdt (shmaddr);
 354               exit (1);
 355             }
 356             shmdt (shmaddr);
 357             shmdt (shmaddr);
 358             exit (0);
 359           }
 360       ],
 361       AC_DEFINE(IPC_RMID_DEFERRED_RELEASE)
 362         AC_MSG_RESULT(yes),
 363       AC_MSG_RESULT(no),
 364       AC_MSG_RESULT(assuming no))
 365   fi
 366
 367   # Check for the X shared memory extension header file
 368   AC_MSG_CHECKING(X11/extensions/XShm.h)
 369   if test "x$no_xext_lib" = "xyes"; then
 370     AC_MSG_RESULT(no)
 371     no_xshm=yes
 372   else
 373     if test -f "$x_includes/X11/extensions/XShm.h"; then
 374       AC_MSG_RESULT(yes)
 375       AC_DEFINE(HAVE_XSHM_H)
 376     else
 377       AC_MSG_RESULT(no)
 378       no_xshm=yes
 379     fi
 380   fi
 381 fi
 382
 383 # Check for private display resource base variable
 384 AC_MSG_CHECKING(resource base field in XDisplay)
 385 AC_CACHE_VAL(gtk_cv_display_resource_base,
 386 [AC_TRY_RUN([
 387 #define XLIB_ILLEGAL_ACCESS
 388 #include <X11/Xlib.h>
 389
 390 int
 391 main ()
 392 {
 393   Display *display;
 394
 395   return 0;
 396
 397   display->resource_base;
 398 }],
 399 gtk_cv_display_resource_base="resource_base",
 400 gtk_cv_display_resource_base="private3")])
 401 AC_MSG_RESULT($gtk_cv_display_resource_base)
 402 AC_DEFINE_UNQUOTED(RESOURCE_BASE, gdk_display->$gtk_cv_display_resource_base)
 403
 404 # Check if X_LOCALE definition is necessary
 405
 406 AC_MSG_CHECKING(need -DX_LOCALE)
 407
 408 AC_TRY_RUN([
 409 #include <stdio.h>
 410 #include <locale.h>
 411
 412 int
 413 main ()
 414 {
 415   return setlocale (LC_ALL, "${with_locale}") == NULL;
 416 }],
 417 need_x_locale=no,
 418 need_x_locale=yes)
 419 AC_MSG_RESULT($need_x_locale)
 420
 421 if test $need_x_locale = yes; then
 422   GTK_LOCALE_CFLAGS="-DX_LOCALE"
 423 fi
 424
 425 # Checks for header files.
 426 AC_HEADER_STDC
 427
 428 # Checks for typedefs, structures, and compiler characteristics.
 429 AC_C_CONST
 430
 431 # Checks for library functions.
 432 AC_TYPE_SIGNAL
 433 AC_FUNC_MMAP
 434
 435 # Check if <sys/select.h> needs to be included for fd_set
 436 AC_MSG_CHECKING([for fd_set])
 437 AC_TRY_COMPILE([#include <sys/types.h>],
 438         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 439 if test $gtk_ok = yes; then
 440     AC_MSG_RESULT([yes, found in sys/types.h])
 441 else
 442     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 443     if test $gtk_ok = yes; then
 444         AC_DEFINE(HAVE_SYS_SELECT_H)
 445         AC_MSG_RESULT([yes, found in sys/select.h])
 446     else
 447         AC_DEFINE(NO_FD_SET)
 448         AC_MSG_RESULT(no)
 449     fi
 450 fi
 451
 452 # Duplicate `widechar' tests from `glib'.
 453 # Check for wchar.h
 454 if test x = y; then
 455   # will not be executed
 456   # hack so as not to update `acconfig.h'
 457   AC_CHECK_HEADERS(wchar.h wctype.h)
 458   AC_CHECK_FUNCS(broken_wctype)
 459 fi
 460
 461 AC_MSG_CHECKING(for wchar.h)
 462 AC_TRY_CPP([#include <wchar.h>], gtk_ok=yes, gtk_ok=no)
 463 if test $gtk_ok = yes; then
 464    ac_kludge=HAVE_WCHAR_H
 465    AC_DEFINE($ac_kludge)
 466 fi
 467 AC_MSG_RESULT($gtk_ok)
 468
 469 # Check for wctype.h (for iswalnum)
 470
 471 AC_MSG_CHECKING(for wctype.h)
 472 AC_TRY_CPP([#include <wctype.h>], gtk_ok=yes, gtk_ok=no)
 473 if test $gtk_ok = yes; then
 474    ac_kludge=HAVE_WCTYPE_H
 475    AC_DEFINE($ac_kludge)
 476 fi
 477 AC_MSG_RESULT($gtk_ok)
 478
 479 # in Solaris 2.5, `iswalnum' is in -lw
 480 GDK_WLIBS=
 481 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 482
 483 # The following is necessary for Linux libc-5.4.38
 484 oLIBS="$LIBS"
 485 LIBS="$LIBS $GDK_WLIBS"
 486 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 487 AC_TRY_LINK([#include <stdlib.h>],[
 488 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 489 #  ifdef HAVE_WCTYPE_H
 490 #    include <wctype.h>
 491 #  else
 492 #    ifdef HAVE_WCHAR_H
 493 #      include <wchar.h>
 494 #    endif
 495 #  endif
 496 #else
 497 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 498 #endif
 499 iswalnum((wchar_t) 0);
 500 ], gtk_ok=yes, gtk_ok=no)
 501 LIBS="$oLIBS"
 502
 503 if test $gtk_ok = no; then
 504    ac_kludge=HAVE_BROKEN_WCTYPE
 505    AC_DEFINE($ac_kludge)
 506    GDK_WLIBS=
 507 fi
 508 AC_MSG_RESULT($gtk_ok)
 509 AC_SUBST(GDK_WLIBS)
 510
 511 AC_SUBST(GTK_DEBUG_FLAGS)
 512 AC_SUBST(GTK_XIM_FLAGS)
 513 AC_SUBST(GTK_LOCALE_FLAGS)
 514 AC_SUBST(GTK_THREAD_FLAGS)
 515
 516 AC_OUTPUT([
 517 Makefile
 518 gtk-config
 519 intl/Makefile
 520 po/Makefile.in
 521 docs/Makefile
 522 gdk/Makefile
 523 gtk/Makefile
 524 gtk/gtkfeatures.h
 525 ], [chmod +x gtk-config])