Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 # Making releases:
   6 #   GTK_MICRO_VERSION += 1;
   7 #   GTK_INTERFACE_AGE += 1;
   8 #   GTK_BINARY_AGE += 1;
   9 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  10 # if backwards compatibility has been broken,
  11 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  12
  13 m4_define([gtk_major_version], [2])
  14 m4_define([gtk_minor_version], [7])
  15 m4_define([gtk_micro_version], [2])
  16 m4_define([gtk_version],
  17           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  18 m4_define([gtk_interface_age], [0])
  19 m4_define([gtk_binary_age],
  20           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  21 # This is the X.Y used in -lgtk-FOO-X.Y
  22 m4_define([gtk_api_version], [2.0])
  23
  24 # Define a string for the earliest version that this release has
  25 # backwards binary compatibility with for all interfaces a module
  26 # might. Unless we add module-only API with lower stability
  27 # guarantees, this should be unchanged until we break binary compat
  28 # for GTK+.
  29 #
  30 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  31 m4_define([gtk_binary_version], [2.4.0])
  32
  33 # required versions of other packages
  34 m4_define([glib_required_version], [2.7.1])
  35 m4_define([pango_required_version], [1.9.0])
  36 m4_define([atk_required_version], [1.0.1])
  37
  38
  39 AC_INIT([gtk+], [gtk_version],
  40         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  41         [gtk+])
  42
  43 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  44
  45 # Save this value here, since automake will set cflags later
  46 cflags_set=${CFLAGS+set}
  47
  48 AM_INIT_AUTOMAKE(no-define)
  49 AM_CONFIG_HEADER(config.h)
  50
  51 #
  52 # For each of the libraries we build, we define the following
  53
  54 # substituted variables:
  55 #
  56 # foo_PACKAGES:     pkg-config packages this library requires
  57 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  58 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  59 # foo_DEP_LIBS:     All libraries this module requires
  60 # foo_DEP_CFLAGS:   All cflags this module requires
  61
  62
  63 GTK_MAJOR_VERSION=gtk_major_version
  64 GTK_MINOR_VERSION=gtk_minor_version
  65 GTK_MICRO_VERSION=gtk_micro_version
  66 GTK_INTERFACE_AGE=gtk_interface_age
  67 GTK_BINARY_AGE=gtk_binary_age
  68 GTK_VERSION=gtk_version
  69 GTK_API_VERSION=gtk_api_version
  70 GTK_BINARY_VERSION=gtk_binary_version
  71 AC_SUBST(GTK_MAJOR_VERSION)
  72 AC_SUBST(GTK_MINOR_VERSION)
  73 AC_SUBST(GTK_MICRO_VERSION)
  74 AC_SUBST(GTK_INTERFACE_AGE)
  75 AC_SUBST(GTK_BINARY_AGE)
  76 AC_SUBST(GTK_API_VERSION)
  77 AC_SUBST(GTK_VERSION)
  78 AC_SUBST(GTK_BINARY_VERSION)
  79
  80 # libtool versioning
  81 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  82 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  83 #LT_REVISION=$GTK_INTERFACE_AGE
  84 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  85 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  86
  87 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
  88 m4_define([lt_revision], [gtk_interface_age])
  89 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
  90 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
  91 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
  92 AC_SUBST(LT_VERSION_INFO)
  93 AC_SUBST(LT_CURRENT_MINUS_AGE)
  94
  95
  96 #
  97 # gdk-pixbuf gets versioned separately, and for now, using standard
  98 # libtool versioning, not GTK+-style versioning
  99 #
 100 GDK_PIXBUF_MAJOR=gtk_major_version
 101 GDK_PIXBUF_MINOR=gtk_minor_version
 102 GDK_PIXBUF_MICRO=gtk_micro_version
 103 GDK_PIXBUF_VERSION="${GDK_PIXBUF_MAJOR}.${GDK_PIXBUF_MINOR}.${GDK_PIXBUF_MICRO}"
 104 AC_SUBST(GDK_PIXBUF_MAJOR)
 105 AC_SUBST(GDK_PIXBUF_MINOR)
 106 AC_SUBST(GDK_PIXBUF_MICRO)
 107 AC_SUBST(GDK_PIXBUF_VERSION)
 108
 109 GETTEXT_PACKAGE=gtk20
 110 AC_SUBST(GETTEXT_PACKAGE)
 111 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
 112
 113 AC_CANONICAL_HOST
 114
 115 MATH_LIB=-lm
 116 AC_MSG_CHECKING([for native Win32])
 117 case "$host" in
 118   *-*-mingw*)
 119     os_win32=yes
 120     MATH_LIB=
 121     ;;
 122   *)
 123     os_win32=no
 124     ;;
 125 esac
 126 AC_MSG_RESULT([$os_win32])
 127
 128 case $host in
 129   *-*-linux*)
 130     os_linux=yes
 131     ;;
 132 esac
 133 dnl Initialize libtool
 134 AC_PROG_CC
 135 AM_DISABLE_STATIC
 136
 137 if test "$os_win32" = "yes"; then
 138   if test x$enable_static = xyes -o x$enable_static = x; then
 139     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 140     enable_static=no
 141   fi
 142   if test x$enable_shared = xno; then
 143     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 144   fi
 145   enable_shared=yes
 146 fi
 147
 148 AC_LIBTOOL_WIN32_DLL
 149 AM_PROG_LIBTOOL
 150
 151 # Make sure we use 64-bit versions of various file stuff.
 152 AC_SYS_LARGEFILE
 153
 154 AM_PROG_AS
 155 AC_PATH_PROG(NM, nm, nm)
 156
 157 dnl Initialize maintainer mode
 158 AM_MAINTAINER_MODE
 159
 160 AC_MSG_CHECKING([for some Win32 platform])
 161 case "$host" in
 162   *-*-mingw*|*-*-cygwin*)
 163     platform_win32=yes
 164     ;;
 165   *)
 166     platform_win32=no
 167     ;;
 168 esac
 169 AC_MSG_RESULT([$platform_win32])
 170 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 171
 172 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 173 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 174 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 175
 176 if test "$os_win32" = "yes"; then
 177   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 178 fi
 179 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 180
 181 m4_define([debug_default],
 182           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 183
 184 dnl declare --enable-* args and collect ac_help strings
 185 AC_ARG_ENABLE(debug,
 186               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 187                              [turn on debugging @<:@default=debug_default@:>@]),,
 188               enable_debug=debug_default)
 189 AC_ARG_ENABLE(shm,
 190               [AC_HELP_STRING([--enable-shm],
 191                               [support shared memory if available [default=yes]])],,
 192               [enable_shm="yes"])
 193 AC_ARG_ENABLE(xkb,
 194               [AC_HELP_STRING([--enable-xkb],
 195                               [support XKB [default=maybe]])],,
 196               [enable_xkb="maybe"])
 197 AC_ARG_ENABLE(rebuilds,
 198               [AC_HELP_STRING([--disable-rebuilds],
 199                               [disable all source autogeneration rules])],,
 200               [enable_rebuilds=yes])
 201 AC_ARG_ENABLE(visibility,
 202               [AC_HELP_STRING([--disable-visibility],
 203                               [don't use ELF visibility attributes])],,
 204               [enable_visibility=yes])
 205
 206 AC_ARG_WITH(xinput,
 207             [AC_HELP_STRING([--with-xinput=@<:@no/yes@:>@], [support XInput])])
 208
 209 AC_ARG_WITH(wintab,
 210             [AC_HELP_STRING([--with-wintab=DIRECTORY],
 211                             [use Wintab API with win32 backend])])
 212 AC_ARG_WITH(ie55,
 213             [AC_HELP_STRING([--with-ie55=DIRECTORY],
 214                             [IE5.5 libs and headers (for Active IMM)])])
 215
 216 if test "$platform_win32" = yes; then
 217   gdktarget=win32
 218 else
 219   gdktarget=x11
 220 fi
 221
 222 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/linux-fb/win32]] select non-default GDK target],
 223         gdktarget=$with_gdktarget)
 224
 225 AC_SUBST(gdktarget)
 226 case $gdktarget in
 227   x11|linux-fb|win32) ;;
 228   *) AC_MSG_ERROR([Invalid target for GDK: use x11, linux-fb or win32.]);;
 229 esac
 230
 231 gdktargetlib=libgdk-$gdktarget-$GTK_API_VERSION.la
 232 gtktargetlib=libgtk-$gdktarget-$GTK_API_VERSION.la
 233
 234 AC_SUBST(gdktargetlib)
 235 AC_SUBST(gtktargetlib)
 236
 237 AC_ARG_ENABLE(shadowfb,
 238               [AC_HELP_STRING([--disable-shadowfb],
 239                               [disable shadowfb support for linux-fb])],,
 240               [enable_shadowfb=yes])
 241
 242 AC_ARG_ENABLE(fbmanager,
 243               [AC_HELP_STRING([--enable-fbmanager],
 244                               [enable framebuffer manager support (GtkFB)])],,
 245               enable_fbmanager=no)
 246
 247 if test "x$enable_debug" = "xyes"; then
 248   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 249   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 250 else
 251   if test "x$enable_debug" = "xno"; then
 252     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 253   else
 254     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 255   fi
 256 fi
 257
 258 if test "x$enable_visibility" = "xno"; then
 259   GTK_DEBUG_FLAGS="$GTK_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 260 fi
 261
 262
 263 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 264
 265
 266 # Build time sanity check...
 267 AM_SANITY_CHECK
 268
 269 # Checks for programs.
 270 AC_ISC_POSIX
 271 AM_PROG_CC_STDC
 272 AC_PROG_INSTALL
 273 AC_PROG_MAKE_SET
 274
 275 changequote(,)dnl
 276 if test "x$GCC" = "xyes"; then
 277   case " $CFLAGS " in
 278   *[\ \ ]-Wall[\ \      ]*) ;;
 279   *) CFLAGS="$CFLAGS -Wall" ;;
 280   esac
 281
 282   if test "x$enable_ansi" = "xyes"; then
 283     case " $CFLAGS " in
 284     *[\ \       ]-ansi[\ \      ]*) ;;
 285     *) CFLAGS="$CFLAGS -ansi" ;;
 286     esac
 287
 288     case " $CFLAGS " in
 289     *[\ \       ]-pedantic[\ \  ]*) ;;
 290     *) CFLAGS="$CFLAGS -pedantic" ;;
 291     esac
 292   fi
 293 fi
 294 changequote([,])dnl
 295
 296 # Ensure MSVC-compatible struct packing convention is used when
 297 # compiling for Win32 with gcc.
 298 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 299 # gcc2 uses "-fnative-struct".
 300 if test x"$os_win32" = xyes; then
 301   if test x"$GCC" = xyes; then
 302     msnative_struct=''
 303     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 304     if test -z "$ac_cv_prog_CC"; then
 305       our_gcc="$CC"
 306     else
 307       our_gcc="$ac_cv_prog_CC"
 308     fi
 309     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 310       2.)
 311         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 312           msnative_struct='-fnative-struct'
 313         fi
 314         ;;
 315       *)
 316         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 317           msnative_struct='-mms-bitfields'
 318         fi
 319         ;;
 320     esac
 321     if test x"$msnative_struct" = x ; then
 322       AC_MSG_RESULT([no way])
 323       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 324     else
 325       CFLAGS="$CFLAGS $msnative_struct"
 326       AC_MSG_RESULT([${msnative_struct}])
 327     fi
 328   fi
 329 fi
 330
 331 # Honor aclocal flags
 332 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 333
 334 ## Initial sanity check, done here so that users get told they
 335 ## have the wrong dependencies as early in the process as possible.
 336 ## Later on we actually use the cflags/libs from separate pkg-config
 337 ## calls. Oh, also the later pkg-config calls don't include
 338 ## the version requirements since those make the module lists
 339 ## annoying to construct
 340 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 341   [glib-2.0 >= glib_required_version dnl
 342    atk >= atk_required_version dnl
 343    pango >= pango_required_version])
 344
 345 if test "$os_win32" != yes; then
 346     # libtool option to control which symbols are exported
 347     # right now, symbols starting with _ are not exported
 348     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 349 else
 350     # We currently use .def files on Windows (for gdk-pixbuf, gdk and gtk)
 351     LIBTOOL_EXPORT_OPTIONS=
 352 fi
 353 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 354
 355 dnl ******************************************************
 356 dnl * See whether to include shared library dependencies *
 357 dnl ******************************************************
 358
 359 AC_ARG_ENABLE(explicit-deps,
 360               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 361                               [use explicit dependencies in .pc files [default=auto]])],,
 362               [enable_explicit_deps=auto])
 363
 364 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 365 case $enable_explicit_deps in
 366   auto)
 367     deplib_check_method=`(./libtool --config; echo eval echo \\$deplib_check_method) | sh`
 368     if test "X$deplib_check_method" = Xnone || test "x$enable_static" = xyes ; then
 369       enable_explicit_deps=yes
 370     else
 371       enable_explicit_deps=no
 372     fi
 373   ;;
 374   yes|no)
 375   ;;
 376   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 377   ;;
 378 esac
 379 AC_MSG_RESULT($enable_explicit_deps)
 380
 381 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 382
 383 # define a MAINT-like variable REBUILD which is set if Perl
 384 # and awk are found, so autogenerated sources can be rebuilt
 385
 386 AC_PATH_PROGS(PERL, perl5 perl)
 387
 388 # We would like indent, but don't require it.
 389 AC_CHECK_PROG(INDENT, indent, indent)
 390
 391 REBUILD=\#
 392 if test "x$enable_rebuilds" = "xyes" && \
 393      test -n "$PERL" && \
 394      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 395   REBUILD=
 396 fi
 397 AC_SUBST(REBUILD)
 398
 399 AC_CHECK_FUNCS(lstat mkstemp flockfile)
 400
 401 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 402 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 403 AC_TRY_LINK([#include <langinfo.h>], [
 404 char c;
 405 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 406 ], gtk_ok=yes, gtk_ok=no)
 407 AC_MSG_RESULT($gtk_ok)
 408 if test "$gtk_ok" = "yes"; then
 409   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 410             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 411 fi
 412
 413 # sigsetjmp is a macro on some platforms, so AC_CHECK_FUNCS is not reliable
 414 AC_MSG_CHECKING(for sigsetjmp)
 415 AC_TRY_LINK([#include <setjmp.h>], [
 416 sigjmp_buf env;
 417 sigsetjmp(env, 0);
 418 ], gtk_ok=yes, gtk_ok=no)
 419 AC_MSG_RESULT($gtk_ok)
 420 if test "$gtk_ok" = "yes"; then
 421   AC_DEFINE(HAVE_SIGSETJMP)
 422 fi
 423
 424 # i18n stuff
 425 # TRANSLATORS:  Please note that gtk+ has both po/ and po-properties/
 426 # directories.  If you add a new language to ALL_LINGUAS, please make
 427 # sure that both po/ and po-properties/ have .po files that correspond
 428 # to your language.  If you only add one to po/, the build will break
 429 # in po-properties/.
 430 ALL_LINGUAS="af am ar az az_IR be bg bn br bs ca cs cy da de el en_CA en_GB es et eu fa fi fr ga gl gu he hi hr hu ia id is it ja ko li lt lv mi mk ml mn mr ms nb ne nl nn no nso pa pl pt pt_BR ro ru rw sk sl sq sr sr@ije sr@Latn sv ta th tk tr uk uz uz@Latn vi wa xh yi zh_CN zh_TW"
 431 AM_GLIB_GNU_GETTEXT
 432 LIBS="$LIBS $INTLLIBS"
 433 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 434         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 435       esac])
 436
 437 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 438
 439 dnl The DU4 header files don't provide library prototypes unless
 440 dnl -std1 is given to the native cc.
 441 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 442
 443 gtk_save_LIBS=$LIBS
 444 LIBS="$LIBS -lm"
 445 AC_TRY_RUN([#include <math.h>
 446              int main (void) { return (log(1) != log(1.)); }],
 447      AC_MSG_RESULT(none needed),
 448      gtk_save_CFLAGS="$CFLAGS"
 449      CFLAGS="$CFLAGS -std1"
 450      AC_TRY_RUN([#include <math.h>
 451                  int main (void) { return (log(1) != log(1.)); }],
 452          AC_MSG_RESULT(-std1),
 453          AC_MSG_RESULT()
 454          CFLAGS="$gtk_save_CFLAGS"
 455          AC_MSG_WARN(
 456                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 457          true
 458      ),
 459      AC_MSG_RESULT(none needed)
 460 )
 461 LIBS=$gtk_save_LIBS
 462
 463 AC_MSG_CHECKING(for the BeOS)
 464 case $host in
 465   *-*-beos*)
 466     AC_MSG_RESULT(yes)
 467     MATH_LIB=
 468   ;;
 469   *)
 470     AC_MSG_RESULT(no)
 471   ;;
 472 esac
 473
 474 #
 475 # see bug 162979
 476 #
 477 AC_MSG_CHECKING(for HP-UX)
 478 case $host_os in
 479   hpux9* | hpux10* | hpux11*)
 480     AC_MSG_RESULT(yes)
 481     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 482   ;;
 483   *)
 484     AC_MSG_RESULT(no)
 485   ;;
 486 esac
 487
 488 dnl NeXTStep cc seems to need this
 489 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 490 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 491   AC_MSG_RESULT(none needed),
 492   gtk_save_CFLAGS="$CFLAGS"
 493   CFLAGS="$CFLAGS -posix"
 494   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 495     AC_MSG_RESULT(-posix),
 496     AC_MSG_RESULT()
 497     CFLAGS="$gtk_save_CFLAGS"
 498     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 499
 500 #
 501 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 502 #
 503
 504 GLIB_PACKAGES="gobject-2.0 gmodule-no-export-2.0"
 505
 506 AM_PATH_GLIB_2_0(glib_required_version, :,
 507   AC_MSG_ERROR([
 508 *** GLIB glib_required_version or better is required. The latest version of
 509 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 510   gobject gmodule-no-export gthread)
 511
 512 dnl
 513 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 514 dnl
 515 gtk_save_LIBS=$LIBS
 516 LIBS="$LIBS $GLIB_LIBS"
 517 AC_CHECK_FUNCS(bind_textdomain_codeset)
 518 LIBS=$gtk_save_LIBS
 519
 520 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 521 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 522 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 523
 524 if test "${with_ie55+set}" = set && test $with_ie55 != no; then
 525   AC_MSG_CHECKING([for dimm.h])
 526   saved_CFLAGS="$CFLAGS"
 527   CFLAGS="$CFLAGS -idirafter $with_ie55/Include"
 528   AC_TRY_COMPILE([/* The w32api imm.h clashes a bit with the IE5.5 dimm.h */
 529 #ifdef __GNUC__
 530 #define IMEMENUITEMINFOA hidden_IMEMENUITEMINFOA
 531 #define IMEMENUITEMINFOW hidden_IMEMENUITEMINFOW
 532 #endif
 533 #include <windows.h>
 534 #include <objbase.h>
 535 #include <imm.h>
 536 #ifdef __GNUC__
 537 #undef IMEMENUITEMINFOA
 538 #undef IMEMENUITEMINFOW
 539 #endif
 540 #include <dimm.h>
 541 ],
 542    [],
 543    [AC_MSG_RESULT(yes)
 544     AC_MSG_CHECKING([for IE55 uuid.lib])
 545     if test -f $with_ie55/Lib/uuid.lib ; then
 546       AC_MSG_RESULT(yes)
 547       have_ie55=yes
 548       AC_DEFINE(HAVE_DIMM_H)
 549       IE55_UUID_LIB="$with_ie55/Lib/uuid.lib"
 550       AC_SUBST(IE55_UUID_LIB)
 551     else
 552       AC_MSG_RESULT(no)
 553       CFLAGS="$saved_CFLAGS"
 554       have_ie55=no
 555     fi
 556     ],
 557    [AC_MSG_RESULT(no)
 558     CFLAGS="$saved_CFLAGS"
 559     have_ie55=no])
 560 fi
 561 AM_CONDITIONAL(HAVE_IE55, test x$have_ie55 = xyes)
 562
 563 if test "${with_wintab+set}" = set && test $with_wintab != no; then
 564   AC_MSG_CHECKING([for wintab.h])
 565   saved_CFLAGS="$CFLAGS"
 566   CFLAGS="$CFLAGS -I$with_wintab/include"
 567   AC_TRY_COMPILE([#include <windows.h>
 568 #include <wintab.h>],
 569    [],
 570    [AC_MSG_RESULT(yes)
 571     AC_MSG_CHECKING([for wntab32x.lib])
 572     if test -f $with_wintab/lib/i386/wntab32x.lib ; then
 573       AC_MSG_RESULT(yes)
 574       have_wintab=yes
 575       AC_DEFINE(HAVE_WINTAB)
 576       WINTAB_LIB="$with_wintab/lib/i386/wntab32x.lib"
 577       AC_SUBST(WINTAB_LIB)
 578     else
 579       AC_MSG_RESULT(no)
 580       CFLAGS="$saved_cflags"
 581       have_wintab=no
 582     fi
 583     ],
 584    [AC_MSG_RESULT(no)
 585     CFLAGS="$saved_cflags"
 586     have_wintab=no])
 587 fi
 588 AM_CONDITIONAL(HAVE_WINTAB, test x$have_wintab = xyes)
 589
 590 saved_cflags="$CFLAGS"
 591 saved_ldflags="$LDFLAGS"
 592
 593
 594 # Checks for header files.
 595 AC_HEADER_STDC
 596
 597 # Checks for typedefs, structures, and compiler characteristics.
 598 AC_C_CONST
 599
 600 # Checks for library functions.
 601 AC_TYPE_SIGNAL
 602 AC_FUNC_MMAP
 603
 604 AC_CHECK_FUNCS(mallinfo)
 605 AC_CHECK_FUNCS(getresuid)
 606 AC_TYPE_UID_T
 607
 608 # Check if <sys/select.h> needs to be included for fd_set
 609 AC_MSG_CHECKING([for fd_set])
 610 AC_TRY_COMPILE([#include <sys/types.h>],
 611         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 612 if test $gtk_ok = yes; then
 613     AC_MSG_RESULT([yes, found in sys/types.h])
 614 else
 615     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 616     if test $gtk_ok = yes; then
 617         AC_DEFINE(HAVE_SYS_SELECT_H)
 618         AC_MSG_RESULT([yes, found in sys/select.h])
 619     else
 620         AC_DEFINE(NO_FD_SET)
 621         AC_MSG_RESULT(no)
 622     fi
 623 fi
 624
 625 # `widechar' tests for gdki18n.h
 626 AC_MSG_CHECKING(for wchar.h)
 627 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 628 if test $gdk_wchar_h = yes; then
 629    AC_DEFINE(HAVE_WCHAR_H,1,[Have wchar.h include file])
 630 fi
 631 AC_MSG_RESULT($gdk_wchar_h)
 632
 633 # Check for wctype.h (for iswalnum)
 634 AC_MSG_CHECKING(for wctype.h)
 635 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 636 if test $gdk_wctype_h = yes; then
 637    AC_DEFINE(HAVE_WCTYPE_H,1,[Have wctype.h include file])
 638 fi
 639 AC_MSG_RESULT($gdk_wctype_h)
 640
 641 # in Solaris 2.5, `iswalnum' is in -lw
 642 GDK_WLIBS=
 643 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 644
 645 oLIBS="$LIBS"
 646 LIBS="$LIBS $GDK_WLIBS"
 647 # The following is necessary for Linux libc-5.4.38
 648 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 649 AC_TRY_LINK([#include <stdlib.h>],[
 650 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 651 #  ifdef HAVE_WCTYPE_H
 652 #    include <wctype.h>
 653 #  else
 654 #    ifdef HAVE_WCHAR_H
 655 #      include <wchar.h>
 656 #    endif
 657 #  endif
 658 #else
 659 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 660 #endif
 661 iswalnum((wchar_t) 0);
 662 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 663 LIBS="$oLIBS"
 664
 665 if test $gdk_working_wctype = no; then
 666    AC_DEFINE(HAVE_BROKEN_WCTYPE,1,[Is the wctype implementation broken])
 667    GDK_WLIBS=
 668 fi
 669 AC_MSG_RESULT($gdk_working_wctype)
 670 AC_SUBST(GDK_WLIBS)
 671
 672 # Check for uxtheme.h (for MS-Windows Engine)
 673 AC_MSG_CHECKING(for uxtheme.h)
 674 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 675 if test $gtk_uxtheme_h = yes; then
 676    AC_DEFINE(HAVE_UXTHEME_H,1,[Have uxtheme.h include file])
 677 fi
 678 AC_MSG_RESULT($gtk_uxtheme_h)
 679
 680
 681 ##################################################
 682 # Checks for gdk-pixbuf
 683 ##################################################
 684
 685 dnl ********************************************************
 686 dnl * See whether we need to load our modules as .la files *
 687 dnl ********************************************************
 688
 689 use_la_modules=false
 690 case $host in
 691   *-aix*) use_la_modules=true
 692 esac
 693
 694 if $use_la_modules ; then
 695    AC_DEFINE(USE_LA_MODULES, 1, [Whether to load modules via .la files rather than directly])
 696 fi
 697
 698
 699 AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
 700
 701 AC_ARG_ENABLE(modules,
 702               [AC_HELP_STRING([--disable-modules],
 703                               [disable dynamic module loading])])
 704
 705 dynworks=false
 706 deps=
 707 if test x$enable_modules = xno; then
 708     AC_MSG_RESULT(no)
 709 else
 710     AC_MSG_RESULT(yes)
 711     AC_MSG_CHECKING(whether dynamic modules work)
 712     ## for loop is to strip newline
 713     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 714     for I in $tmp; do
 715         dynworks=$I
 716     done
 717
 718     dnl Now we check to see if our libtool supports shared lib deps
 719     dnl (in a rather ugly way even)
 720     if $dynworks; then
 721         pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 722         pixbuf_deplibs_check=`$pixbuf_libtool_config | \
 723             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 724             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 725         if test "x$pixbuf_deplibs_check" = "xnone" || \
 726            test "x$pixbuf_deplibs_check" = "xunknown" || \
 727            test "x$pixbuf_deplibs_check" = "x"; then
 728             dynworks=false
 729         fi
 730     fi
 731
 732     if $dynworks; then
 733         AC_DEFINE(USE_GMODULE)
 734         AC_MSG_RESULT(yes)
 735     else
 736         AC_MSG_RESULT(no)
 737     fi
 738 fi
 739
 740 dnl We allow people to disable image loaders explicitely, but if they don't we error
 741 dnl out so that people don't accidentally build without them.
 742
 743 AC_ARG_WITH(libpng,
 744             [AC_HELP_STRING([--without-libpng],
 745                             [disable PNG loader for gdk-pixbuf])])
 746 AC_ARG_WITH(libjpeg,
 747             [AC_HELP_STRING([--without-libjpeg],
 748                             [disable JPEG loader for gdk-pixbuf])])
 749 AC_ARG_WITH(libtiff,
 750             [AC_HELP_STRING([--without-libtiff],
 751                             [disable TIFF loader for gdk-pixbuf])])
 752
 753 dnl Test for libtiff
 754   if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
 755     AC_CHECK_LIB(tiff, TIFFReadScanline,
 756       [AC_CHECK_HEADER(tiffio.h,
 757         TIFF='tiff'; LIBTIFF='-ltiff',
 758         AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 759       [AC_CHECK_LIB(tiff, TIFFWriteScanline,
 760         [AC_CHECK_HEADER(tiffio.h,
 761           TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
 762           AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 763         [AC_CHECK_LIB(tiff34, TIFFFlushData,
 764           [AC_CHECK_HEADER(tiffio.h,
 765             TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
 766             AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 767         AC_MSG_WARN(*** TIFF loader will not be built (TIFF library not found) ***), -ljpeg -lz -lm)], -ljpeg -lz -lm)], -lm)
 768   fi
 769
 770   if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
 771      AC_MSG_ERROR([
 772 *** Checks for TIFF loader failed. You can build without it by passing
 773 *** --without-libtiff to configure but some programs using GTK+ may
 774 *** not work properly])
 775   fi
 776
 777 dnl Test for libjpeg
 778   if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
 779     AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 780       jpeg_ok=yes,
 781       jpeg_ok=no
 782       AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
 783     if test "$jpeg_ok" = yes; then
 784       AC_MSG_CHECKING([for jpeglib.h])
 785       AC_TRY_CPP(
 786 [#include <stdio.h>
 787 #undef PACKAGE
 788 #undef VERSION
 789 #undef HAVE_STDLIB_H
 790 #include <jpeglib.h>],
 791         jpeg_ok=yes,
 792         jpeg_ok=no)
 793       AC_MSG_RESULT($jpeg_ok)
 794       if test "$jpeg_ok" = yes; then
 795         LIBJPEG='-ljpeg'
 796         AC_CHECK_LIB(jpeg, jpeg_simple_progression,
 797           AC_DEFINE(HAVE_PROGRESSIVE_JPEG),
 798           AC_MSG_WARN(JPEG library does not support progressive saving.))
 799       else
 800           AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
 801       fi
 802     fi
 803   fi
 804
 805   if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
 806      AC_MSG_ERROR([
 807 *** Checks for JPEG loader failed. You can build without it by passing
 808 *** --without-libjpeg to configure but some programs using GTK+ may
 809 *** not work properly])
 810   fi
 811
 812 dnl Test for libpng
 813   if test x$with_libpng != xno && test -z "$LIBPNG"; then
 814     AC_MSG_CHECKING(for libpng12)
 815     if $PKG_CONFIG --exists libpng12 ; then
 816         AC_MSG_RESULT(yes)
 817         PNG='png'
 818         PNG_DEP_CFLAGS_PACKAGES=libpng12
 819         LIBPNG=`$PKG_CONFIG --libs libpng12`
 820     else
 821       AC_MSG_RESULT(no)
 822       AC_CHECK_LIB(png, png_read_info,
 823         [AC_CHECK_HEADER(png.h,
 824           png_ok=yes,
 825           png_ok=no)],
 826         AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
 827       if test "$png_ok" = yes; then
 828         AC_MSG_CHECKING([for png_structp in png.h])
 829         AC_TRY_COMPILE([#include <png.h>],
 830           [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 831           png_ok=yes,
 832           png_ok=no)
 833         AC_MSG_RESULT($png_ok)
 834         if test "$png_ok" = yes; then
 835           PNG='png'; LIBPNG='-lpng -lz'
 836         else
 837           AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
 838         fi
 839       else
 840        AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
 841       fi
 842     fi
 843   fi
 844
 845   if test x$with_libpng != xno && test -z "$LIBPNG"; then
 846      AC_MSG_ERROR([
 847 *** Checks for PNG loader failed. You can build without it by passing
 848 *** --without-libpng to configure but many programs using GTK+ will
 849 *** not work properly. The PNG loader is also needed if you are compiling
 850 *** from CVS.])
 851   fi
 852
 853 AC_SUBST(LIBTIFF)
 854 AC_SUBST(LIBJPEG)
 855 AC_SUBST(LIBPNG)
 856
 857 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 858
 859 #
 860 # Allow building some or all gdk-pixbuf loaders included
 861 #
 862 AC_MSG_CHECKING(pixbuf loaders to build)
 863
 864 dnl due to an autoconf bug, commas in the first arg to
 865 dnl AC_HELP_STRING cause problems.
 866 dnl AC_HELP_STRING([--with-included-loaders=LOADER1 LOADER2 ...],
 867 dnl                [build the specified loaders into gdk-pixbuf (only used if module loading disabled)])
 868 AC_ARG_WITH(included_loaders,
 869 [  --with-included-loaders=LOADER1,LOADER2,...
 870                           build the specified loaders into gdk-pixbuf (only
 871                           used if module loading disabled)])
 872
 873 if $dynworks; then
 874         :
 875 else
 876    ## if the option was specified, leave it; otherwise disable included loaders
 877    if test x$with_included_loaders = xno; then
 878            with_included_loaders=yes
 879    fi
 880 fi
 881
 882 all_loaders="png,bmp,wbmp,gif,ico,ani,jpeg,pnm,ras,tiff,xpm,tga,pcx"
 883 included_loaders=""
 884 # If no loaders specified, include all
 885 if test "x$with_included_loaders" = xyes ; then
 886   included_loaders="$all_loaders"
 887 else
 888   included_loaders="$with_included_loaders"
 889 fi
 890
 891 AC_MSG_RESULT($included_loaders)
 892
 893 INCLUDED_LOADER_OBJ=
 894 INCLUDED_LOADER_DEFINE=
 895
 896 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 897 for loader in $included_loaders; do
 898  if echo "$all_loaders" | egrep "(^|,)$loader(\$|,)" > /dev/null; then
 899    :
 900  else
 901    AC_MSG_ERROR([the specified loader $loader does not exist])
 902  fi
 903
 904  INCLUDED_LOADER_OBJ="$INCLUDED_LOADER_OBJ libpixbufloader-static-$loader.la"
 905  INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_$loader"
 906 done
 907 IFS="$gtk_save_ifs"
 908 AC_SUBST(INCLUDED_LOADER_OBJ)
 909 AC_SUBST(INCLUDED_LOADER_DEFINE)
 910
 911 AC_HEADER_SYS_WAIT
 912
 913 AC_TYPE_SIGNAL
 914
 915 AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
 916 AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
 917 AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
 918
 919 if $dynworks ; then
 920   STATIC_LIB_DEPS=
 921   if echo "$included_loaders" | egrep '(^|,)tiff($|,)' > /dev/null; then
 922     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBTIFF"
 923   fi
 924   if echo "$included_loaders" | egrep '(^|,)jpeg($|,)' > /dev/null; then
 925     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBJPEG"
 926   fi
 927   if echo "$included_loaders" | egrep '(^|,)png($|,)' > /dev/null; then
 928     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBPNG"
 929   fi
 930 else
 931   STATIC_LIB_DEPS="$LIBTIFF $LIBJPEG $LIBPNG"
 932 fi
 933
 934 # Checks to see if we should compile in MMX support (there will be
 935 # a runtime test when the code is actually run to see if it should
 936 # be used - this just checks if we can compile it.)
 937 #
 938 # This code is partially taken from Mesa
 939 #
 940 AC_MSG_CHECKING(for x86 platform)
 941 case $host_cpu in
 942   i386|i486|i586|i686|i786|k6|k7)
 943         use_x86_asm=yes
 944         ;;
 945    *)
 946         use_x86_asm=no
 947 esac
 948 AC_MSG_RESULT($use_x86_asm)
 949
 950 use_mmx_asm=no
 951 if test $use_x86_asm = yes; then
 952     save_ac_ext=$ac_ext
 953     ac_ext=S
 954
 955     AC_MSG_CHECKING(compiler support for MMX)
 956     cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
 957     if AC_TRY_EVAL(ac_compile); then
 958         use_mmx_asm=yes
 959     fi
 960
 961     rm -rf conftest*
 962
 963     ac_ext=$save_ac_ext
 964     if test $use_mmx_asm = yes; then
 965       AC_DEFINE(USE_MMX)
 966       AC_MSG_RESULT(yes)
 967     else
 968       AC_MSG_RESULT(no)
 969     fi
 970 fi
 971
 972 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
 973
 974 REBUILD_PNGS=
 975 if test -z "$LIBPNG"; then
 976   REBUILD_PNGS=#
 977 fi
 978
 979 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 980
 981 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 982
 983 if test $cross_compiling = yes; then
 984   AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 985   if test x$GDK_PIXBUF_CSOURCE = xno; then
 986     REBUILD_PNGS=#
 987   fi
 988 fi
 989
 990 if test ! -f $srcdir/gtk/stock-icons/gtkstockpixbufs.h &&
 991    test "x$REBUILD_PNGS" = "x#" ; then
 992      AC_MSG_ERROR([
 993 *** gtkstockpixbufs.h is not in the tree, and cannot be built
 994 *** because you don't have libpng, or (when cross-compiling) you
 995 *** don't have a prebuilt gdk-pixbuf-csource on the host system.])
 996 fi
 997
 998 AC_SUBST(REBUILD_PNGS)
 999
1000 GDK_PIXBUF_PACKAGES="gmodule-no-export-2.0 gobject-2.0"
1001 GDK_PIXBUF_EXTRA_LIBS="$STATIC_LIB_DEPS $MATH_LIB"
1002 GDK_PIXBUF_EXTRA_CFLAGS=
1003 GDK_PIXBUF_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
1004 GDK_PIXBUF_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $PNG_DEP_CFLAGS_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS"
1005
1006 AC_SUBST(GDK_PIXBUF_PACKAGES)
1007 AC_SUBST(GDK_PIXBUF_EXTRA_LIBS)
1008 AC_SUBST(GDK_PIXBUF_EXTRA_CFLAGS)
1009 AC_SUBST(GDK_PIXBUF_DEP_LIBS)
1010 AC_SUBST(GDK_PIXBUF_DEP_CFLAGS)
1011
1012
1013 ########################################
1014 # Windowing system checks
1015 ########################################
1016
1017 GDK_EXTRA_LIBS=$GDK_WLIBS
1018 GDK_EXTRA_CFLAGS=
1019 GTK_DEP_LIBS_FOR_X=
1020
1021 FREETYPE_LIBS=
1022 FREETYPE_CFLAGS=
1023 if test "x$gdktarget" = "xlinux-fb" || test "x$gdktarget" = "xx11" ; then
1024   #
1025   # Checks for FreeType
1026   #
1027   have_freetype=false
1028   AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
1029   if test "x$FREETYPE_CONFIG" != "xno" ; then
1030     FREETYPE_CFLAGS=`$FREETYPE_CONFIG --cflags`
1031     FREETYPE_LIBS=`$FREETYPE_CONFIG --libs`
1032
1033     gtk_save_LIBS="$LIBS"
1034     LIBS="$FREETYPE_LIBS $LIBS"
1035     AC_TRY_LINK_FUNC(FT_New_Face, have_freetype=true,:)
1036     LIBS="$gtk_save_LIBS"
1037
1038     if $have_freetype ; then
1039       gtk_save_cppflags="$CPPFLAGS"
1040       CPPFLAGS="$CPPFLAGS $FREETYPE_CFLAGS"
1041
1042       AC_MSG_CHECKING([For sufficiently new FreeType (at least 2.0.1)])
1043       AC_TRY_COMPILE([
1044 #include <ft2build.h>
1045 #include FT_FREETYPE_H
1046 #include FT_ERRORS_H
1047     ],
1048                      [(void)1;],:,have_freetype=false)
1049       if $have_freetype ; then
1050         AC_MSG_RESULT(yes)
1051       else
1052         AC_MSG_RESULT(no)
1053       fi
1054
1055       CPPFLAGS="$gtk_save_cppflags"
1056     fi
1057   fi
1058   AC_SUBST(FREETYPE_LIBS)
1059   AC_SUBST(FREETYPE_CFLAGS)
1060 fi
1061
1062 if test "x$gdktarget" = "xx11"; then
1063   # We start off with the libraries from Pango
1064
1065   ## be sure we also have Pango built with Xft2 support
1066   if $PKG_CONFIG --exists 'pangoxft >= 1.2.0' ; then
1067     if $have_freetype ; then
1068       :
1069     else
1070       AC_MSG_ERROR([Xft Pango backend found but did not find freetype libraries])
1071     fi
1072   else
1073     AC_MSG_ERROR([Xft Pango backend is required for x11 target])
1074   fi
1075
1076   if $PKG_CONFIG --exists xft ; then : ; else
1077     AC_MSG_ERROR([Xft version 2 is required for x11 target])
1078   fi
1079
1080   #
1081   # If Pango included the shared library dependencies from X11 in
1082   # the pkg-config output, then we use that (to avoid duplicates).
1083   # but if they were omitted to avoid binary compatibility problems,
1084   # then we need to repeat the checks.
1085   #
1086   x_libs="`$PKG_CONFIG --libs pangoxft`"
1087   case "$x_libs" in
1088     *-lX11*) pango_omitted_x_deps=no ;;
1089     *)       pango_omitted_x_deps=yes ;;
1090   esac
1091
1092   x_cflags="`$PKG_CONFIG --cflags pangoxft`"
1093   x_extra_libs=
1094
1095   AC_PATH_XTRA
1096   if test x$no_x = xyes ; then
1097     AC_MSG_ERROR([X development libraries not found])
1098   fi
1099
1100   if test $pango_omitted_x_deps = yes ; then
1101     # Old versions of Xft didn't necessarily include -lX11 in the output
1102     x_libs="`$PKG_CONFIG --libs xft` -lX11 $X_EXTRA_LIBS"
1103   fi
1104
1105   ## Strip the .la files
1106
1107   x_libs_for_checks=""
1108   for I in $x_libs ; do
1109     case $I in
1110       *.la) ;;
1111       *) x_libs_for_checks="$x_libs_for_checks $I" ;;
1112     esac
1113   done
1114
1115   # Sanity check for the X11 library
1116   AC_CHECK_LIB(X11, XOpenDisplay, :,
1117             AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
1118             $x_libs_for_checks)
1119
1120   if test "x$enable_shm" = "xyes"; then
1121     # Check for the Xext library (needed for XShm extention)
1122     AC_CHECK_LIB(Xext, XShmAttach,
1123         [GTK_ADD_LIB(x_extra_libs,Xext)],
1124         # On AIX, it is in XextSam instead, but we still need -lXext
1125         [AC_CHECK_LIB(XextSam, XShmAttach,
1126             [GTK_ADD_LIB(x_extra_libs,Xext)
1127              GTK_ADD_LIB(x_extra_libs,XextSam)
1128             ], , -lXext $x_libs_for_checks)],
1129         $x_libs_for_checks)
1130   fi
1131
1132   GDK_PIXBUF_XLIB_EXTRA_CFLAGS="$x_cflags"
1133   # Don't ever pull in the pangoxft libraries for gdk-pixbuf-x11
1134   GDK_PIXBUF_XLIB_EXTRA_LIBS="$X_LIBS -lX11 $x_extra_libs $X_EXTRA_LIBS"
1135
1136   # GTK+ uses some X calls, so needs to link against X directly
1137   if test $enable_explicit_deps != yes ; then
1138     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
1139   fi
1140
1141   # Check for Xinerama extension (Solaris impl or Xfree impl)
1142
1143   gtk_save_cppflags="$CPPFLAGS"
1144   CPPFLAGS="$CPPFLAGS $x_cflags"
1145
1146   case "$host" in
1147       *-*-solaris*)
1148           # Check for solaris
1149           use_solaris_xinerama=yes
1150           AC_CHECK_LIB(Xext, XineramaGetInfo,
1151                         use_solaris_xinerama=yes,
1152                         use_solaris_xinerama=no,
1153                         -lXext $x_libs_for_checks)
1154           if test "x$use_solaris_xinerama" = "xyes"; then
1155               AC_CHECK_HEADER(X11/extensions/xinerama.h,
1156                 [GTK_ADD_LIB(x_extra_libs,Xext)
1157                 AC_DEFINE(HAVE_SOLARIS_XINERAMA)
1158                 AC_DEFINE(HAVE_XINERAMA)],
1159                 use_solaris_xinerama=no,[#include <X11/Xlib.h>])
1160           fi
1161           AC_MSG_CHECKING(for Xinerama support on Solaris)
1162           AC_MSG_RESULT($use_solaris_xinerama);
1163           ;;
1164       *)
1165           # Check for XFree
1166           use_xfree_xinerama=yes
1167           AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1168               [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1169                   [GTK_ADD_LIB(x_extra_libs,Xext)
1170                   GTK_ADD_LIB(x_extra_libs,Xinerama)
1171                   AC_DEFINE(HAVE_XFREE_XINERAMA)
1172                   AC_DEFINE(HAVE_XINERAMA)],
1173                   use_xfree_xinerama=no,
1174                   [#include <X11/Xlib.h>])],
1175               use_xfree_xinerama=no, -lXext $x_libs_for_checks)
1176           AC_MSG_CHECKING(for Xinerama support on XFree86)
1177           AC_MSG_RESULT($use_xfree_xinerama);
1178           ;;
1179   esac
1180
1181   CPPFLAGS="$gtk_save_cppflags"
1182
1183   # Check for xReply
1184
1185   gtk_save_cppflags="$CPPFLAGS"
1186   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1187
1188   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
1189   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
1190       [xReply *rep;],
1191       [AC_MSG_RESULT([no])],
1192       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
1193 #include <X11/Xlibint.h>],
1194            [xReply *rep;],
1195            [AC_MSG_RESULT([yes])
1196             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
1197                 [Define if <X11/extensions/XIproto.h> needed for xReply])],
1198            [AC_MSG_RESULT([unknown])
1199             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1200
1201   CPPFLAGS="$gtk_save_cppflags"
1202
1203   # Check for shaped window extension
1204
1205   AC_CHECK_LIB(Xext, XShapeCombineMask,
1206       [GTK_ADD_LIB(x_extra_libs,Xext)
1207        AC_DEFINE(HAVE_SHAPE_EXT)],
1208       ,
1209       $x_libs_for_checks)
1210
1211   # Check for XConvertCase (X11R6 specific)
1212
1213   AC_CHECK_LIB(X11, XConvertCase,
1214       AC_DEFINE(HAVE_XCONVERTCASE),
1215       ,
1216       $x_libs_for_checks)
1217
1218   # Check for XInternAtoms (X11R6 specific)
1219
1220   AC_CHECK_LIB(X11, XInternAtoms,
1221       AC_DEFINE([HAVE_XINTERNATOMS], 1,
1222           [Define to 1 if you have the `XInternAtoms' function.]),
1223       ,
1224       $x_libs_for_checks)
1225
1226   # Generic X11R6 check needed for XIM support; we could
1227   # probably use this to replace the above, but we'll
1228   # leave the separate checks for XConvertCase and XInternAtoms
1229   # for clarity
1230   have_x11r6=false
1231   AC_CHECK_LIB(X11, XAddConnectionWatch,
1232       have_x11r6=true,
1233       ,
1234       $x_libs_for_checks)
1235
1236   if $have_x11r6; then
1237     AC_DEFINE(HAVE_X11R6,1,[Define if we have X11R6])
1238   fi
1239   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1240
1241   # Check for XKB support.
1242
1243   if test "x$enable_xkb" = "xyes"; then
1244         AC_MSG_WARN(XKB support explicitly enabled)
1245         AC_DEFINE(HAVE_XKB)
1246   elif test "x$enable_xkb" = "xmaybe"; then
1247         AC_CHECK_LIB(X11, XkbQueryExtension,
1248                      AC_DEFINE(HAVE_XKB),
1249                      ,
1250                      $x_libs_for_checks)
1251   else
1252         AC_MSG_WARN(XKB support explicitly disabled)
1253   fi
1254
1255   x_cflags="$X_CFLAGS"
1256   x_ldflags="$X_LDFLAGS"
1257
1258   # set up things for XInput
1259
1260   if test "x$with_xinput" = "xxfree" || test "x$with_xinput" = "xyes"; then
1261     AC_DEFINE(XINPUT_XFREE)
1262     GTK_ADD_LIB(x_extra_libs, Xi)
1263   else
1264     AC_DEFINE(XINPUT_NONE)
1265   fi
1266
1267   AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree || test x$with_xinput = xyes)
1268
1269   # Check for the RANDR extension
1270
1271   AC_CHECK_LIB(Xrandr, XRRUpdateConfiguration,
1272       [AC_CHECK_HEADER(X11/extensions/Xrandr.h,
1273           # RANDR requires RENDER
1274           [GTK_ADD_LIB(x_extra_libs, Xrender)
1275           GTK_ADD_LIB(x_extra_libs, Xrandr)
1276           AC_DEFINE(HAVE_RANDR, 1, Have the Xrandr extension library)],
1277           :, [#include <X11/Xlib.h>])], : ,
1278        $X_LIBS -lXrandr -lXrender -lX11 $X_EXTRA_LIBS)
1279
1280   # Checks for Xcursor library
1281
1282   have_xcursor=false
1283   PKG_CHECK_MODULES(XCURSOR, xcursor, have_xcursor=true, :)
1284
1285   if $have_xcursor ; then
1286     AC_DEFINE(HAVE_XCURSOR, 1, Have the Xcursor library)
1287     GDK_EXTRA_CFLAGS="`$PKG_CONFIG --cflags xcursor` $GDK_EXTRA_CFLAGS"
1288     GDK_EXTRA_LIBS="`$PKG_CONFIG --libs xcursor` $GDK_EXTRA_LIBS"
1289   fi
1290
1291   # X SYNC check
1292   AC_CHECK_LIB(Xext, XSyncQueryExtension,
1293       [AC_CHECK_HEADER(X11/extensions/sync.h,
1294           [GTK_ADD_LIB(x_extra_libs, Xext)
1295           AC_DEFINE(HAVE_XSYNC, 1, Have the SYNC extension library)],
1296           :, [#include <X11/Xlib.h>])], : ,
1297        $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
1298
1299   # Checks for XFixes extension
1300
1301   have_xfixes=false
1302   PKG_CHECK_MODULES(XFIXES, xfixes, have_xfixes=true, :)
1303
1304   if $have_xfixes ; then
1305     AC_DEFINE(HAVE_XFIXES, 1, Have the XFIXES X extension)
1306     GDK_EXTRA_CFLAGS="`$PKG_CONFIG --cflags xfixes` $GDK_EXTRA_CFLAGS"
1307     GDK_EXTRA_LIBS="`$PKG_CONFIG --libs xfixes` $GDK_EXTRA_LIBS"
1308   fi
1309
1310   # Xshm checks
1311
1312   if test "x$enable_shm" = "xyes"; then
1313     # Check for shared memory
1314     AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
1315     AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
1316
1317     # Check for the X shared memory extension header file
1318     have_xshm=no
1319     AC_MSG_CHECKING(X11/extensions/XShm.h)
1320     if test "x$no_xext_lib" = "xyes"; then
1321       :
1322     else
1323       gtk_save_CFLAGS="$CFLAGS"
1324       CFLAGS="$CFLAGS $x_cflags"
1325       AC_TRY_COMPILE([
1326 #include <stdlib.h>
1327 #include <sys/types.h>
1328 #include <sys/ipc.h>
1329 #include <sys/shm.h>
1330 #include <X11/Xlib.h>
1331 #include <X11/Xutil.h>
1332 #include <X11/extensions/XShm.h>
1333 ], [XShmSegmentInfo *x_shm_info;], have_xshm=yes)
1334       CFLAGS="$gtk_save_CFLAGS"
1335     fi
1336     AC_MSG_RESULT($have_xshm)
1337     if test $have_xshm = yes ; then
1338       AC_DEFINE(HAVE_XSHM_H)
1339     fi
1340   fi
1341
1342   if test $pango_omitted_x_deps = yes ; then
1343     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs $x_libs $GDK_EXTRA_LIBS"
1344   else
1345     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs $GDK_EXTRA_LIBS"
1346   fi
1347
1348   AM_CONDITIONAL(USE_X11, true)
1349 else
1350   AM_CONDITIONAL(XINPUT_XFREE, false)
1351   AM_CONDITIONAL(USE_X11, false)
1352   AM_CONDITIONAL(HAVE_X11R6, false)
1353 fi
1354
1355 if test "x$gdktarget" = "xwin32"; then
1356   # We start off with the libraries from Pango
1357
1358   if test x$have_wintab = xyes; then
1359     GDK_WIN32_EXTRA_CFLAGS="-I $with_wintab/include"
1360     AC_SUBST(GDK_WIN32_EXTRA_CFLAGS)
1361   fi
1362
1363   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -user32 -limm32 -lshell32 -lole32 -luuid"
1364   AM_CONDITIONAL(USE_WIN32, true)
1365 else
1366   AM_CONDITIONAL(USE_WIN32, false)
1367 fi
1368
1369 GDK_PIXBUF_XLIB_PACKAGES=
1370 GDK_PIXBUF_XLIB_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_XLIB_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
1371 GDK_PIXBUF_XLIB_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_PIXBUF_XLIB_EXTRA_CFLAGS"
1372
1373 AC_SUBST(GDK_PIXBUF_XLIB_PACKAGES)
1374 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_LIBS)
1375 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_CFLAGS)
1376 AC_SUBST(GDK_PIXBUF_XLIB_DEP_LIBS)
1377 AC_SUBST(GDK_PIXBUF_XLIB_DEP_CFLAGS)
1378
1379 if test "x$gdktarget" = "xlinux-fb"; then
1380   if $have_freetype ; then
1381     :
1382   else
1383     AC_MSG_ERROR([Using linux-fb backend but freetype was not found])
1384   fi
1385
1386   ft2_libs="`$PKG_CONFIG --libs pangoft2`"
1387   case "$ft2_libs" in
1388     *-lfreetype*) pango_omitted_ft2_deps=no ;;
1389     *)            pango_omitted_ft2_deps=yes ;;
1390   esac
1391
1392   CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
1393
1394   if test x$enable_shadowfb = xyes ; then
1395     AC_DEFINE(ENABLE_SHADOW_FB)
1396   fi
1397
1398   if test x$enable_fbmanager = xyes ; then
1399     AC_DEFINE(ENABLE_FB_MANAGER)
1400     AM_CONDITIONAL(ENABLE_FB_MANAGER, true)
1401   else
1402     AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
1403   fi
1404
1405   if test $pango_omitted_ft2_deps = yes ; then
1406     GDK_EXTRA_LIBS="$FREETYPE_LIBS $GDK_EXTRA_LIBS"
1407   fi
1408
1409   AM_CONDITIONAL(USE_LINUX_FB, true)
1410 else
1411   AM_CONDITIONAL(USE_LINUX_FB, false)
1412   AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
1413 fi
1414
1415 #
1416 # Pick correct Pango packages to use
1417 #
1418
1419 if test "x$gdktarget" = "xx11"; then
1420         PANGO_PACKAGES="pangoxft pangocairo"
1421
1422         # We no longer use pangox, but if we find it, we link to it
1423         # for binary compatibility.
1424         if $PKG_CONFIG --exists pangox ; then
1425                 PANGO_PACKAGES="$PANGO_PACKAGES pangox"
1426         fi
1427 elif test "x$gdktarget" = "xwin32"; then
1428         PANGO_PACKAGES="pangowin32 pangocairo"
1429 elif test "x$gdktarget" = "xlinux-fb"; then
1430         PANGO_PACKAGES="pangoft2 pangocairo"
1431 else
1432         PANGO_PACKAGES="pango pangocairo"
1433 fi
1434
1435 # Check for Pango flags
1436
1437 AC_MSG_CHECKING(Pango flags)
1438 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1439         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1440         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1441
1442         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1443 else
1444         AC_MSG_ERROR([
1445 *** Pango not found. Pango built with Cairo support is required
1446 *** to build GTK+. See http://www.pango.org for Pango information.
1447 ])
1448 fi
1449
1450 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1451
1452 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1453         :
1454 else
1455         gtk_save_LIBS="$LIBS"
1456         LIBS="$PANGO_LIBS $LIBS"
1457         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1458 *** Can't link to Pango. Pango is required to build
1459 *** GTK+. For more information see http://www.pango.org]))
1460         LIBS="$gtk_save_LIBS"
1461 fi
1462
1463 CFLAGS="$saved_cflags"
1464 LDFLAGS="$saved_ldflags"
1465
1466 GDK_PACKAGES="$PANGO_PACKAGES"
1467 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
1468 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS"
1469
1470 #
1471 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1472 # into the pkg-config files
1473 #
1474 if test $enable_explicit_deps != yes ; then
1475   GDK_EXTRA_LIBS=
1476 fi
1477
1478 AC_SUBST(GDK_PACKAGES)
1479 AC_SUBST(GDK_EXTRA_LIBS)
1480 AC_SUBST(GDK_EXTRA_CFLAGS)
1481 AC_SUBST(GDK_DEP_LIBS)
1482 AC_SUBST(GDK_DEP_CFLAGS)
1483
1484
1485 ########################################
1486 # Check for Accessibility Toolkit flags
1487 ########################################
1488
1489 ATK_PACKAGES=atk
1490 AC_MSG_CHECKING(ATK flags)
1491 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1492         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1493         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1494
1495         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1496 else
1497         AC_MSG_ERROR([
1498 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1499 *** to build GTK+.
1500 ])
1501 fi
1502
1503 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1504         :
1505 else
1506         gtk_save_LIBS="$LIBS"
1507         LIBS="$ATK_LIBS $LIBS"
1508         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1509                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1510                 *** to build GTK+]))
1511         LIBS="$gtk_save_LIBS"
1512 fi
1513
1514 GTK_PACKAGES="atk cairo"
1515 GTK_EXTRA_LIBS=
1516 GTK_EXTRA_CFLAGS=
1517 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GTK_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
1518 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1519
1520 if test x"$os_win32" = xyes; then
1521   GTK_EXTRA_CFLAGS="$msnative_struct"
1522 fi
1523
1524 AC_SUBST(GTK_PACKAGES)
1525 AC_SUBST(GTK_EXTRA_LIBS)
1526 AC_SUBST(GTK_EXTRA_CFLAGS)
1527 AC_SUBST(GTK_DEP_LIBS)
1528 AC_SUBST(GTK_DEP_CFLAGS)
1529
1530
1531 AC_SUBST(GTK_DEBUG_FLAGS)
1532 AC_SUBST(GTK_XIM_FLAGS)
1533
1534 ################################################################
1535 # Strip -export-dynamic from the link lines of various libraries
1536 ################################################################
1537
1538 #
1539 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1540 #  but this flag is only meaningful for executables. For libraries
1541 #  the effect is undefined; what it causes on Linux is that the
1542 #  export list from -export-symbols-regex is ignored and everything
1543 #  is exported
1544 #
1545 # We are using gmodule-no-export now, but I'm leaving the stripping
1546 # code in place for now, since pango and atk still require gmodule.
1547 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1548 if test -n "$export_dynamic"; then
1549   GDK_PIXBUF_DEP_LIBS=`echo $GDK_PIXBUF_DEP_LIBS | sed -e "s/$export_dynamic//"`
1550   GDK_PIXBUF_XLIB_DEP_LIBS=`echo $GDK_PIXBUF_XLIB_DEP_LIBS | sed -e "s/$export_dynamic//"`
1551   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1552   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1553 fi
1554
1555
1556 ##################################################
1557 # Checks for gtk-doc and docbook-tools
1558 ##################################################
1559
1560 GTK_DOC_CHECK([1.4])
1561
1562 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1563 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1564
1565 AC_ARG_ENABLE(man,
1566               [AC_HELP_STRING([--enable-man],
1567                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1568               enable_man=no)
1569
1570 if test "${enable_man}" != no; then
1571   dnl
1572   dnl Check for xsltproc
1573   dnl
1574   AC_PATH_PROG([XSLTPROC], [xsltproc])
1575   if test -z "$XSLTPROC"; then
1576     enable_man=no
1577   fi
1578
1579   dnl check for DocBook DTD and stylesheets in the local catalog.
1580   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1581      [DocBook XML DTD V4.1.2],,enable_man=no)
1582   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1583      [DocBook XSL Stylesheets],,enable_man=no)
1584 fi
1585
1586 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1587
1588
1589 ##################################################
1590 # Output commands
1591 ##################################################
1592
1593 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1594         outfile=gdkconfig.h-tmp
1595         cat > $outfile <<\_______EOF
1596 /* gdkconfig.h
1597  *
1598  * This is a generated file.  Please modify `configure.in'
1599  */
1600
1601 #ifndef GDKCONFIG_H
1602 #define GDKCONFIG_H
1603
1604 #ifdef __cplusplus
1605 extern "C" {
1606 #endif /* __cplusplus */
1607
1608 _______EOF
1609
1610         cat >>$outfile <<_______EOF
1611 $gdk_windowing
1612 $gdk_wc
1613 _______EOF
1614
1615         cat >>$outfile <<_______EOF
1616
1617 #ifdef __cplusplus
1618 }
1619 #endif /* __cplusplus */
1620
1621 #endif /* GDKCONFIG_H */
1622 _______EOF
1623
1624
1625         if cmp -s $outfile gdk/gdkconfig.h; then
1626           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1627           rm -f $outfile
1628         else
1629           mv $outfile gdk/gdkconfig.h
1630         fi
1631 ],[
1632 if test "x$gdktarget" = "xx11" ; then
1633   gdk_windowing='
1634 #define GDK_WINDOWING_X11'
1635 elif test "x$gdktarget" = "xwin32" ; then
1636   gdk_windowing='
1637 #define GDK_WINDOWING_WIN32'
1638 elif test "x$gdktarget" = "xlinux-fb" ; then
1639   gdk_windowing='
1640 #define GDK_WINDOWING_FB
1641 #define GDK_NATIVE_WINDOW_POINTER'
1642 fi
1643
1644 if test x$gdk_wchar_h = xyes; then
1645   gdk_wc='
1646 #define GDK_HAVE_WCHAR_H 1'
1647 fi
1648 if test x$gdk_wctype_h = xyes; then
1649   gdk_wc="\$gdk_wc
1650 #define GDK_HAVE_WCTYPE_H 1"
1651 fi
1652 if test x$gdk_working_wctype = xno; then
1653   gdk_wc="\$gdk_wc
1654 #define GDK_HAVE_BROKEN_WCTYPE 1"
1655 fi
1656
1657
1658 ])
1659
1660 AC_CONFIG_FILES([
1661 config.h.win32
1662 gtk-zip.sh
1663 Makefile
1664 gdk-pixbuf-2.0.pc
1665 gdk-2.0.pc
1666 gtk+-2.0.pc
1667 gdk-pixbuf-2.0-uninstalled.pc
1668 gdk-2.0-uninstalled.pc
1669 gtk+-2.0-uninstalled.pc
1670 m4macros/Makefile
1671 po/Makefile.in
1672 po-properties/Makefile.in
1673 build/Makefile
1674 build/win32/Makefile
1675 build/win32/dirent/Makefile
1676 demos/Makefile
1677 demos/gtk-demo/Makefile
1678 demos/gtk-demo/geninclude.pl
1679 tests/Makefile
1680 docs/Makefile
1681 docs/reference/Makefile
1682 docs/reference/gdk-pixbuf/Makefile
1683 docs/reference/gdk-pixbuf/version.xml
1684 docs/reference/gdk/Makefile
1685 docs/reference/gdk/version.xml
1686 docs/reference/gtk/Makefile
1687 docs/reference/gtk/version.xml
1688 docs/faq/Makefile
1689 docs/tools/Makefile
1690 docs/tutorial/Makefile
1691 gdk-pixbuf/Makefile
1692 gdk-pixbuf/gdk_pixbuf.rc
1693 gdk-pixbuf/gdk-pixbuf-features.h
1694 gdk-pixbuf/pixops/Makefile
1695 gdk/Makefile
1696 gdk/x11/Makefile
1697 gdk/win32/Makefile
1698 gdk/win32/rc/Makefile
1699 gdk/win32/rc/gdk.rc
1700 gdk/linux-fb/Makefile
1701 gtk/Makefile
1702 gtk/makefile.msc
1703 gtk/gtkversion.h
1704 gtk/gtk-win32.rc
1705 gtk/stock-icons/Makefile
1706 gtk/theme-bits/Makefile
1707 gtk/xdgmime/Makefile
1708 modules/Makefile
1709 modules/input/Makefile
1710 modules/engines/Makefile
1711 modules/engines/pixbuf/Makefile
1712 modules/engines/ms-windows/Makefile
1713 modules/engines/ms-windows/Theme/Makefile
1714 modules/engines/ms-windows/Theme/gtk-2.0/Makefile
1715 contrib/Makefile
1716 contrib/gdk-pixbuf-xlib/Makefile
1717 contrib/gdk-pixbuf-xlib/gdk-pixbuf-xlib-2.0.pc
1718 ])
1719
1720 AC_OUTPUT
1721
1722 echo "configuration:
1723         target: $gdktarget"
1724
1725 if test "x$gdktarget" = "xlinux-fb"; then
1726   echo "Warning: The linux-fb GDK target is unmaintained"
1727   echo "         and may not work or even compile"
1728 fi
1729