Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 # Making releases:
   6 #   GTK_MICRO_VERSION += 1;
   7 #   GTK_INTERFACE_AGE += 1;
   8 #   GTK_BINARY_AGE += 1;
   9 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  10 # if backwards compatibility has been broken,
  11 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  12
  13 m4_define([gtk_major_version], [2])
  14 m4_define([gtk_minor_version], [6])
  15 m4_define([gtk_micro_version], [2])
  16 m4_define([gtk_version],
  17           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  18 m4_define([gtk_interface_age], [2])
  19 m4_define([gtk_binary_age],
  20           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  21 # This is the X.Y used in -lgtk-FOO-X.Y
  22 m4_define([gtk_api_version], [2.0])
  23
  24 # Define a string for the earliest version that this release has
  25 # forward/backwards binary compatibility with. This is used for module
  26 # locations. (Should this be backwards-compat instead?)
  27 #
  28 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  29 m4_define([gtk_binary_version], [2.4.0])
  30
  31 # required versions of other packages
  32 m4_define([glib_required_version], [2.6.0])
  33 m4_define([pango_required_version], [1.8.0])
  34 m4_define([atk_required_version], [1.0.1])
  35
  36
  37 AC_INIT([gtk+], [gtk_version],
  38         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk+],
  39         [gtk+])
  40
  41 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  42
  43 # Save this value here, since automake will set cflags later
  44 cflags_set=${CFLAGS+set}
  45
  46 AM_INIT_AUTOMAKE(no-define)
  47 AM_CONFIG_HEADER(config.h)
  48
  49 #
  50 # For each of the libraries we build, we define the following
  51
  52 # substituted variables:
  53 #
  54 # foo_PACKAGES:     pkg-config packages this library requires
  55 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  56 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  57 # foo_DEP_LIBS:     All libraries this module requires
  58 # foo_DEP_CFLAGS:   All cflags this module requires
  59
  60
  61 GTK_MAJOR_VERSION=gtk_major_version
  62 GTK_MINOR_VERSION=gtk_minor_version
  63 GTK_MICRO_VERSION=gtk_micro_version
  64 GTK_INTERFACE_AGE=gtk_interface_age
  65 GTK_BINARY_AGE=gtk_binary_age
  66 GTK_VERSION=gtk_version
  67 GTK_API_VERSION=gtk_api_version
  68 GTK_BINARY_VERSION=gtk_binary_version
  69 AC_SUBST(GTK_MAJOR_VERSION)
  70 AC_SUBST(GTK_MINOR_VERSION)
  71 AC_SUBST(GTK_MICRO_VERSION)
  72 AC_SUBST(GTK_INTERFACE_AGE)
  73 AC_SUBST(GTK_BINARY_AGE)
  74 AC_SUBST(GTK_API_VERSION)
  75 AC_SUBST(GTK_VERSION)
  76 AC_SUBST(GTK_BINARY_VERSION)
  77
  78 # libtool versioning
  79 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  80 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  81 #LT_REVISION=$GTK_INTERFACE_AGE
  82 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  83 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  84
  85 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
  86 m4_define([lt_revision], [gtk_interface_age])
  87 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
  88 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
  89 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
  90 AC_SUBST(LT_VERSION_INFO)
  91 AC_SUBST(LT_CURRENT_MINUS_AGE)
  92
  93
  94 #
  95 # gdk-pixbuf gets versioned separately, and for now, using standard
  96 # libtool versioning, not GTK+-style versioning
  97 #
  98 GDK_PIXBUF_MAJOR=gtk_major_version
  99 GDK_PIXBUF_MINOR=gtk_minor_version
 100 GDK_PIXBUF_MICRO=gtk_micro_version
 101 GDK_PIXBUF_VERSION="${GDK_PIXBUF_MAJOR}.${GDK_PIXBUF_MINOR}.${GDK_PIXBUF_MICRO}"
 102 AC_SUBST(GDK_PIXBUF_MAJOR)
 103 AC_SUBST(GDK_PIXBUF_MINOR)
 104 AC_SUBST(GDK_PIXBUF_MICRO)
 105 AC_SUBST(GDK_PIXBUF_VERSION)
 106
 107 GETTEXT_PACKAGE=gtk20
 108 AC_SUBST(GETTEXT_PACKAGE)
 109 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
 110
 111 AC_CANONICAL_HOST
 112
 113 MATH_LIB=-lm
 114 AC_MSG_CHECKING([for native Win32])
 115 case "$host" in
 116   *-*-mingw*)
 117     os_win32=yes
 118     MATH_LIB=
 119     ;;
 120   *)
 121     os_win32=no
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$os_win32])
 125
 126 case $host in
 127   *-*-linux*)
 128     os_linux=yes
 129     ;;
 130 esac
 131 dnl Initialize libtool
 132 AC_PROG_CC
 133 AM_DISABLE_STATIC
 134
 135 if test "$os_win32" = "yes"; then
 136   if test x$enable_static = xyes -o x$enable_static = x; then
 137     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 138     enable_static=no
 139   fi
 140   if test x$enable_shared = xno; then
 141     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 142   fi
 143   enable_shared=yes
 144 fi
 145
 146 AM_PROG_LIBTOOL
 147
 148 # Make sure we use 64-bit versions of various file stuff.
 149 AC_SYS_LARGEFILE
 150
 151 AM_PROG_AS
 152
 153 dnl Initialize maintainer mode
 154 AM_MAINTAINER_MODE
 155
 156 AC_MSG_CHECKING([for some Win32 platform])
 157 case "$host" in
 158   *-*-mingw*|*-*-cygwin*)
 159     platform_win32=yes
 160     ;;
 161   *)
 162     platform_win32=no
 163     ;;
 164 esac
 165 AC_MSG_RESULT([$platform_win32])
 166 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 167
 168 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 169 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 170 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 171
 172 if test "$os_win32" = "yes"; then
 173   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 174 fi
 175 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 176
 177 m4_define([debug_default],
 178           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 179
 180 dnl declare --enable-* args and collect ac_help strings
 181 AC_ARG_ENABLE(debug,
 182               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 183                              [turn on debugging @<:@default=debug_default@:>@]),,
 184               enable_debug=debug_default)
 185 AC_ARG_ENABLE(shm,
 186               [AC_HELP_STRING([--enable-shm],
 187                               [support shared memory if available [default=yes]])],,
 188               [enable_shm="yes"])
 189 AC_ARG_ENABLE(ansi,
 190               [AC_HELP_STRING([--enable-ansi],
 191                               [turn on strict ansi [default=no]])],,
 192               [enable_ansi=no])
 193 AC_ARG_ENABLE(xkb,
 194               [AC_HELP_STRING([--enable-xkb],
 195                               [support XKB [default=maybe]])],,
 196               [enable_xkb="maybe"])
 197 AC_ARG_ENABLE(rebuilds,
 198               [AC_HELP_STRING([--disable-rebuilds],
 199                               [disable all source autogeneration rules])],,
 200               [enable_rebuilds=yes])
 201 AC_ARG_ENABLE(visibility,
 202               [AC_HELP_STRING([--disable-visibility],
 203                               [don't use ELF visibility attributes])],,
 204               [enable_visibility=yes])
 205
 206 AC_ARG_WITH(xinput,
 207             [AC_HELP_STRING([--with-xinput=@<:@no/yes@:>@], [support XInput])])
 208
 209 AC_ARG_WITH(wintab,
 210             [AC_HELP_STRING([--with-wintab=DIRECTORY],
 211                             [use Wintab API with win32 backend])])
 212 AC_ARG_WITH(ie55,
 213             [AC_HELP_STRING([--with-ie55=DIRECTORY],
 214                             [IE5.5 libs and headers (for Active IMM)])])
 215
 216 if test "$platform_win32" = yes; then
 217   gdktarget=win32
 218 else
 219   gdktarget=x11
 220 fi
 221
 222 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/linux-fb/win32]] select non-default GDK target],
 223         gdktarget=$with_gdktarget)
 224
 225 AC_SUBST(gdktarget)
 226 case $gdktarget in
 227   x11|linux-fb|win32) ;;
 228   *) AC_MSG_ERROR([Invalid target for GDK: use x11, linux-fb or win32.]);;
 229 esac
 230
 231 gdktargetlib=libgdk-$gdktarget-$GTK_API_VERSION.la
 232 gtktargetlib=libgtk-$gdktarget-$GTK_API_VERSION.la
 233
 234 AC_SUBST(gdktargetlib)
 235 AC_SUBST(gtktargetlib)
 236
 237 AC_ARG_ENABLE(shadowfb,
 238               [AC_HELP_STRING([--disable-shadowfb],
 239                               [disable shadowfb support for linux-fb])],,
 240               [enable_shadowfb=yes])
 241
 242 AC_ARG_ENABLE(fbmanager,
 243               [AC_HELP_STRING([--enable-fbmanager],
 244                               [enable framebuffer manager support (GtkFB)])],,
 245               enable_fbmanager=no)
 246
 247 if test "x$enable_debug" = "xyes"; then
 248   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 249   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 250 else
 251   if test "x$enable_debug" = "xno"; then
 252     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 253   else
 254     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 255   fi
 256 fi
 257
 258 if test "x$enable_visibility" = "xno"; then
 259   GTK_DEBUG_FLAGS="$GTK_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 260 fi
 261
 262
 263 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 264
 265
 266 # Build time sanity check...
 267 AM_SANITY_CHECK
 268
 269 # Checks for programs.
 270 AC_ISC_POSIX
 271 AM_PROG_CC_STDC
 272 AC_PROG_INSTALL
 273 AC_PROG_MAKE_SET
 274
 275 changequote(,)dnl
 276 if test "x$GCC" = "xyes"; then
 277   case " $CFLAGS " in
 278   *[\ \ ]-Wall[\ \      ]*) ;;
 279   *) CFLAGS="$CFLAGS -Wall" ;;
 280   esac
 281
 282   if test "x$enable_ansi" = "xyes"; then
 283     case " $CFLAGS " in
 284     *[\ \       ]-ansi[\ \      ]*) ;;
 285     *) CFLAGS="$CFLAGS -ansi" ;;
 286     esac
 287
 288     case " $CFLAGS " in
 289     *[\ \       ]-pedantic[\ \  ]*) ;;
 290     *) CFLAGS="$CFLAGS -pedantic" ;;
 291     esac
 292   fi
 293 fi
 294 changequote([,])dnl
 295
 296 # Ensure MSVC-compatible struct packing convention is used when
 297 # compiling for Win32 with gcc.
 298 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 299 # gcc2 uses "-fnative-struct".
 300 if test x"$os_win32" = xyes; then
 301   if test x"$GCC" = xyes; then
 302     msnative_struct=''
 303     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 304     if test -z "$ac_cv_prog_CC"; then
 305       our_gcc="$CC"
 306     else
 307       our_gcc="$ac_cv_prog_CC"
 308     fi
 309     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 310       2.)
 311         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 312           msnative_struct='-fnative-struct'
 313         fi
 314         ;;
 315       *)
 316         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 317           msnative_struct='-mms-bitfields'
 318         fi
 319         ;;
 320     esac
 321     if test x"$msnative_struct" = x ; then
 322       AC_MSG_RESULT([no way])
 323       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 324     else
 325       CFLAGS="$CFLAGS $msnative_struct"
 326       AC_MSG_RESULT([${msnative_struct}])
 327     fi
 328   fi
 329 fi
 330
 331 # Honor aclocal flags
 332 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 333
 334 ## Initial sanity check, done here so that users get told they
 335 ## have the wrong dependencies as early in the process as possible.
 336 ## Later on we actually use the cflags/libs from separate pkg-config
 337 ## calls. Oh, also the later pkg-config calls don't include
 338 ## the version requirements since those make the module lists
 339 ## annoying to construct
 340 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 341   [glib-2.0 >= glib_required_version dnl
 342    atk >= atk_required_version dnl
 343    pango >= pango_required_version])
 344
 345 if test "$os_win32" != yes; then
 346     # libtool option to control which symbols are exported
 347     # right now, symbols starting with _ are not exported
 348     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 349 else
 350     # We currently use .def files on Windows (for gdk-pixbuf, gdk and gtk)
 351     LIBTOOL_EXPORT_OPTIONS=
 352 fi
 353 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 354
 355 dnl ******************************************************
 356 dnl * See whether to include shared library dependencies *
 357 dnl ******************************************************
 358
 359 AC_ARG_ENABLE(explicit-deps,
 360               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 361                               [use explicit dependencies in .pc files [default=auto]])],,
 362               [enable_explicit_deps=auto])
 363
 364 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 365 case $enable_explicit_deps in
 366   auto)
 367     deplib_check_method=`(./libtool --config; echo eval echo \\$deplib_check_method) | sh`
 368     if test "X$deplib_check_method" = Xnone || test "x$enable_static" = xyes ; then
 369       enable_explicit_deps=yes
 370     else
 371       enable_explicit_deps=no
 372     fi
 373   ;;
 374   yes|no)
 375   ;;
 376   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 377   ;;
 378 esac
 379 AC_MSG_RESULT($enable_explicit_deps)
 380
 381 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 382
 383 # define a MAINT-like variable REBUILD which is set if Perl
 384 # and awk are found, so autogenerated sources can be rebuilt
 385
 386 AC_PATH_PROGS(PERL, perl5 perl)
 387
 388 # We would like indent, but don't require it.
 389 AC_CHECK_PROG(INDENT, indent, indent)
 390
 391 REBUILD=\#
 392 if test "x$enable_rebuilds" = "xyes" && \
 393      test -n "$PERL" && \
 394      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 395   REBUILD=
 396 fi
 397 AC_SUBST(REBUILD)
 398
 399 AC_CHECK_FUNCS(lstat mkstemp flockfile)
 400
 401 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 402 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 403 AC_TRY_LINK([#include <langinfo.h>], [
 404 char c;
 405 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 406 ], gtk_ok=yes, gtk_ok=no)
 407 AC_MSG_RESULT($gtk_ok)
 408 if test "$gtk_ok" = "yes"; then
 409   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 410             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 411 fi
 412
 413 # sigsetjmp is a macro on some platforms, so AC_CHECK_FUNCS is not reliable
 414 AC_MSG_CHECKING(for sigsetjmp)
 415 AC_TRY_LINK([#include <setjmp.h>], [
 416 sigjmp_buf env;
 417 sigsetjmp(env, 0);
 418 ], gtk_ok=yes, gtk_ok=no)
 419 AC_MSG_RESULT($gtk_ok)
 420 if test "$gtk_ok" = "yes"; then
 421   AC_DEFINE(HAVE_SIGSETJMP)
 422 fi
 423
 424 # i18n stuff
 425 # TRANSLATORS:  Please note that gtk+ has both po/ and po-properties/
 426 # directories.  If you add a new language to ALL_LINGUAS, please make
 427 # sure that both po/ and po-properties/ have .po files that correspond
 428 # to your language.  If you only add one to po/, the build will break
 429 # in po-properties/.
 430 ALL_LINGUAS="af am ar az az_IR be bg bn br bs ca cs cy da de el en_CA en_GB es et eu fa fi fr ga gl gu he hi hr hu ia id is it ja ko li lt lv mi mk ml mn mr ms nb ne nl nn no nso pa pl pt pt_BR ro ru rw sk sl sq sr sr@ije sr@Latn sv ta th tk tr uk uz uz@Latn vi wa yi zh_CN zh_TW"
 431 AM_GLIB_GNU_GETTEXT
 432 LIBS="$LIBS $INTLLIBS"
 433 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 434         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 435       esac])
 436
 437 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 438
 439 dnl The DU4 header files don't provide library prototypes unless
 440 dnl -std1 is given to the native cc.
 441 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 442
 443 gtk_save_LIBS=$LIBS
 444 LIBS="$LIBS -lm"
 445 AC_TRY_RUN([#include <math.h>
 446              int main (void) { return (log(1) != log(1.)); }],
 447      AC_MSG_RESULT(none needed),
 448      gtk_save_CFLAGS="$CFLAGS"
 449      CFLAGS="$CFLAGS -std1"
 450      AC_TRY_RUN([#include <math.h>
 451                  int main (void) { return (log(1) != log(1.)); }],
 452          AC_MSG_RESULT(-std1),
 453          AC_MSG_RESULT()
 454          CFLAGS="$gtk_save_CFLAGS"
 455          AC_MSG_WARN(
 456                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 457          true
 458      ),
 459      AC_MSG_RESULT(none needed)
 460 )
 461 LIBS=$gtk_save_LIBS
 462
 463 AC_MSG_CHECKING(for the BeOS)
 464 case $host in
 465   *-*-beos*)
 466     AC_MSG_RESULT(yes)
 467     MATH_LIB=
 468   ;;
 469   *)
 470     AC_MSG_RESULT(no)
 471   ;;
 472 esac
 473
 474 dnl NeXTStep cc seems to need this
 475 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 476 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 477   AC_MSG_RESULT(none needed),
 478   gtk_save_CFLAGS="$CFLAGS"
 479   CFLAGS="$CFLAGS -posix"
 480   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 481     AC_MSG_RESULT(-posix),
 482     AC_MSG_RESULT()
 483     CFLAGS="$gtk_save_CFLAGS"
 484     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 485
 486 #
 487 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 488 #
 489
 490 GLIB_PACKAGES="gobject-2.0 gmodule-no-export-2.0"
 491
 492 AM_PATH_GLIB_2_0(glib_required_version, :,
 493   AC_MSG_ERROR([
 494 *** GLIB glib_required_version or better is required. The latest version of
 495 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 496   gobject gmodule-no-export gthread)
 497
 498 dnl
 499 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 500 dnl
 501 gtk_save_LIBS=$LIBS
 502 LIBS="$LIBS $GLIB_LIBS"
 503 AC_CHECK_FUNCS(bind_textdomain_codeset)
 504 LIBS=$gtk_save_LIBS
 505
 506 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 507 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 508 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 509
 510 if test "${with_ie55+set}" = set && test $with_ie55 != no; then
 511   AC_MSG_CHECKING([for dimm.h])
 512   saved_CFLAGS="$CFLAGS"
 513   CFLAGS="$CFLAGS -idirafter $with_ie55/Include"
 514   AC_TRY_COMPILE([/* The w32api imm.h clashes a bit with the IE5.5 dimm.h */
 515 #ifdef __GNUC__
 516 #define IMEMENUITEMINFOA hidden_IMEMENUITEMINFOA
 517 #define IMEMENUITEMINFOW hidden_IMEMENUITEMINFOW
 518 #endif
 519 #include <windows.h>
 520 #include <objbase.h>
 521 #include <imm.h>
 522 #ifdef __GNUC__
 523 #undef IMEMENUITEMINFOA
 524 #undef IMEMENUITEMINFOW
 525 #endif
 526 #include <dimm.h>
 527 ],
 528    [],
 529    [AC_MSG_RESULT(yes)
 530     AC_MSG_CHECKING([for IE55 uuid.lib])
 531     if test -f $with_ie55/Lib/uuid.lib ; then
 532       AC_MSG_RESULT(yes)
 533       have_ie55=yes
 534       AC_DEFINE(HAVE_DIMM_H)
 535       IE55_UUID_LIB="$with_ie55/Lib/uuid.lib"
 536       AC_SUBST(IE55_UUID_LIB)
 537     else
 538       AC_MSG_RESULT(no)
 539       CFLAGS="$saved_CFLAGS"
 540       have_ie55=no
 541     fi
 542     ],
 543    [AC_MSG_RESULT(no)
 544     CFLAGS="$saved_CFLAGS"
 545     have_ie55=no])
 546 fi
 547 AM_CONDITIONAL(HAVE_IE55, test x$have_ie55 = xyes)
 548
 549 if test "${with_wintab+set}" = set && test $with_wintab != no; then
 550   AC_MSG_CHECKING([for wintab.h])
 551   saved_CFLAGS="$CFLAGS"
 552   CFLAGS="$CFLAGS -I$with_wintab/include"
 553   AC_TRY_COMPILE([#include <windows.h>
 554 #include <wintab.h>],
 555    [],
 556    [AC_MSG_RESULT(yes)
 557     AC_MSG_CHECKING([for wntab32x.lib])
 558     if test -f $with_wintab/lib/i386/wntab32x.lib ; then
 559       AC_MSG_RESULT(yes)
 560       have_wintab=yes
 561       AC_DEFINE(HAVE_WINTAB)
 562       WINTAB_LIB="$with_wintab/lib/i386/wntab32x.lib"
 563       AC_SUBST(WINTAB_LIB)
 564     else
 565       AC_MSG_RESULT(no)
 566       CFLAGS="$saved_cflags"
 567       have_wintab=no
 568     fi
 569     ],
 570    [AC_MSG_RESULT(no)
 571     CFLAGS="$saved_cflags"
 572     have_wintab=no])
 573 fi
 574 AM_CONDITIONAL(HAVE_WINTAB, test x$have_wintab = xyes)
 575
 576 saved_cflags="$CFLAGS"
 577 saved_ldflags="$LDFLAGS"
 578
 579
 580 # Checks for header files.
 581 AC_HEADER_STDC
 582
 583 # Checks for typedefs, structures, and compiler characteristics.
 584 AC_C_CONST
 585
 586 # Checks for library functions.
 587 AC_TYPE_SIGNAL
 588 AC_FUNC_MMAP
 589
 590 AC_CHECK_FUNCS(mallinfo)
 591 AC_CHECK_FUNCS(getresuid)
 592 AC_TYPE_UID_T
 593
 594 # Check if <sys/select.h> needs to be included for fd_set
 595 AC_MSG_CHECKING([for fd_set])
 596 AC_TRY_COMPILE([#include <sys/types.h>],
 597         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 598 if test $gtk_ok = yes; then
 599     AC_MSG_RESULT([yes, found in sys/types.h])
 600 else
 601     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 602     if test $gtk_ok = yes; then
 603         AC_DEFINE(HAVE_SYS_SELECT_H)
 604         AC_MSG_RESULT([yes, found in sys/select.h])
 605     else
 606         AC_DEFINE(NO_FD_SET)
 607         AC_MSG_RESULT(no)
 608     fi
 609 fi
 610
 611 # `widechar' tests for gdki18n.h
 612 AC_MSG_CHECKING(for wchar.h)
 613 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 614 if test $gdk_wchar_h = yes; then
 615    AC_DEFINE(HAVE_WCHAR_H,1,[Have wchar.h include file])
 616 fi
 617 AC_MSG_RESULT($gdk_wchar_h)
 618
 619 # Check for wctype.h (for iswalnum)
 620 AC_MSG_CHECKING(for wctype.h)
 621 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 622 if test $gdk_wctype_h = yes; then
 623    AC_DEFINE(HAVE_WCTYPE_H,1,[Have wctype.h include file])
 624 fi
 625 AC_MSG_RESULT($gdk_wctype_h)
 626
 627 # in Solaris 2.5, `iswalnum' is in -lw
 628 GDK_WLIBS=
 629 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 630
 631 oLIBS="$LIBS"
 632 LIBS="$LIBS $GDK_WLIBS"
 633 # The following is necessary for Linux libc-5.4.38
 634 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 635 AC_TRY_LINK([#include <stdlib.h>],[
 636 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 637 #  ifdef HAVE_WCTYPE_H
 638 #    include <wctype.h>
 639 #  else
 640 #    ifdef HAVE_WCHAR_H
 641 #      include <wchar.h>
 642 #    endif
 643 #  endif
 644 #else
 645 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 646 #endif
 647 iswalnum((wchar_t) 0);
 648 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 649 LIBS="$oLIBS"
 650
 651 if test $gdk_working_wctype = no; then
 652    AC_DEFINE(HAVE_BROKEN_WCTYPE,1,[Is the wctype implementation broken])
 653    GDK_WLIBS=
 654 fi
 655 AC_MSG_RESULT($gdk_working_wctype)
 656 AC_SUBST(GDK_WLIBS)
 657
 658 # Check for uxtheme.h (for MS-Windows Engine)
 659 AC_MSG_CHECKING(for uxtheme.h)
 660 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 661 if test $gtk_uxtheme_h = yes; then
 662    AC_DEFINE(HAVE_UXTHEME_H,1,[Have uxtheme.h include file])
 663 fi
 664 AC_MSG_RESULT($gtk_uxtheme_h)
 665
 666
 667 ##################################################
 668 # Checks for gdk-pixbuf
 669 ##################################################
 670
 671 dnl ********************************************************
 672 dnl * See whether we need to load our modules as .la files *
 673 dnl ********************************************************
 674
 675 use_la_modules=false
 676 case $host in
 677   *-aix*) use_la_modules=true
 678 esac
 679
 680 if $use_la_modules ; then
 681    AC_DEFINE(USE_LA_MODULES, 1, [Whether to load modules via .la files rather than directly])
 682 fi
 683
 684
 685 AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
 686
 687 AC_ARG_ENABLE(modules,
 688               [AC_HELP_STRING([--disable-modules],
 689                               [disable dynamic module loading])])
 690
 691 dynworks=false
 692 deps=
 693 if test x$enable_modules = xno; then
 694     AC_MSG_RESULT(no)
 695 else
 696     AC_MSG_RESULT(yes)
 697     AC_MSG_CHECKING(whether dynamic modules work)
 698     ## for loop is to strip newline
 699     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 700     for I in $tmp; do
 701         dynworks=$I
 702     done
 703
 704     dnl Now we check to see if our libtool supports shared lib deps
 705     dnl (in a rather ugly way even)
 706     if $dynworks; then
 707         pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 708         pixbuf_deplibs_check=`$pixbuf_libtool_config | \
 709             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 710             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 711         if test "x$pixbuf_deplibs_check" = "xnone" || \
 712            test "x$pixbuf_deplibs_check" = "xunknown" || \
 713            test "x$pixbuf_deplibs_check" = "x"; then
 714             dynworks=false
 715         fi
 716     fi
 717
 718     if $dynworks; then
 719         AC_DEFINE(USE_GMODULE)
 720         AC_MSG_RESULT(yes)
 721     else
 722         AC_MSG_RESULT(no)
 723     fi
 724 fi
 725
 726 dnl We allow people to disable image loaders explicitely, but if they don't we error
 727 dnl out so that people don't accidentally build without them.
 728
 729 AC_ARG_WITH(libpng,
 730             [AC_HELP_STRING([--without-libpng],
 731                             [disable PNG loader for gdk-pixbuf])])
 732 AC_ARG_WITH(libjpeg,
 733             [AC_HELP_STRING([--without-libjpeg],
 734                             [disable JPEG loader for gdk-pixbuf])])
 735 AC_ARG_WITH(libtiff,
 736             [AC_HELP_STRING([--without-libtiff],
 737                             [disable TIFF loader for gdk-pixbuf])])
 738
 739 dnl Test for libtiff
 740   if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
 741     AC_CHECK_LIB(tiff, TIFFReadScanline,
 742       [AC_CHECK_HEADER(tiffio.h,
 743         TIFF='tiff'; LIBTIFF='-ltiff',
 744         AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 745       [AC_CHECK_LIB(tiff, TIFFWriteScanline,
 746         [AC_CHECK_HEADER(tiffio.h,
 747           TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
 748           AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 749         [AC_CHECK_LIB(tiff34, TIFFFlushData,
 750           [AC_CHECK_HEADER(tiffio.h,
 751             TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
 752             AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 753         AC_MSG_WARN(*** TIFF loader will not be built (TIFF library not found) ***), -ljpeg -lz -lm)], -ljpeg -lz -lm)], -lm)
 754   fi
 755
 756   if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
 757      AC_MSG_ERROR([
 758 *** Checks for TIFF loader failed. You can build without it by passing
 759 *** --without-libtiff to configure but some programs using GTK+ may
 760 *** not work properly])
 761   fi
 762
 763 dnl Test for libjpeg
 764   if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
 765     AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 766       jpeg_ok=yes,
 767       jpeg_ok=no
 768       AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
 769     if test "$jpeg_ok" = yes; then
 770       AC_MSG_CHECKING([for jpeglib.h])
 771       AC_TRY_CPP(
 772 [#include <stdio.h>
 773 #undef PACKAGE
 774 #undef VERSION
 775 #undef HAVE_STDLIB_H
 776 #include <jpeglib.h>],
 777         jpeg_ok=yes,
 778         jpeg_ok=no)
 779       AC_MSG_RESULT($jpeg_ok)
 780       if test "$jpeg_ok" = yes; then
 781         LIBJPEG='-ljpeg'
 782         AC_CHECK_LIB(jpeg, jpeg_simple_progression,
 783           AC_DEFINE(HAVE_PROGRESSIVE_JPEG),
 784           AC_MSG_WARN(JPEG library does not support progressive saving.))
 785       else
 786           AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
 787       fi
 788     fi
 789   fi
 790
 791   if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
 792      AC_MSG_ERROR([
 793 *** Checks for JPEG loader failed. You can build without it by passing
 794 *** --without-libjpeg to configure but some programs using GTK+ may
 795 *** not work properly])
 796   fi
 797
 798 dnl Test for libpng
 799   if test x$with_libpng != xno && test -z "$LIBPNG"; then
 800     AC_MSG_CHECKING(for libpng12)
 801     if $PKG_CONFIG --exists libpng12 ; then
 802         AC_MSG_RESULT(yes)
 803         PNG='png'
 804         PNG_DEP_CFLAGS_PACKAGES=libpng12
 805         LIBPNG=`$PKG_CONFIG --libs libpng12`
 806     else
 807       AC_MSG_RESULT(no)
 808       AC_CHECK_LIB(png, png_read_info,
 809         [AC_CHECK_HEADER(png.h,
 810           png_ok=yes,
 811           png_ok=no)],
 812         AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
 813       if test "$png_ok" = yes; then
 814         AC_MSG_CHECKING([for png_structp in png.h])
 815         AC_TRY_COMPILE([#include <png.h>],
 816           [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 817           png_ok=yes,
 818           png_ok=no)
 819         AC_MSG_RESULT($png_ok)
 820         if test "$png_ok" = yes; then
 821           PNG='png'; LIBPNG='-lpng -lz'
 822         else
 823           AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
 824         fi
 825       else
 826        AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
 827       fi
 828     fi
 829   fi
 830
 831   if test x$with_libpng != xno && test -z "$LIBPNG"; then
 832      AC_MSG_ERROR([
 833 *** Checks for PNG loader failed. You can build without it by passing
 834 *** --without-libpng to configure but many programs using GTK+ will
 835 *** not work properly. The PNG loader is also needed if you are compiling
 836 *** from CVS.])
 837   fi
 838
 839 AC_SUBST(LIBTIFF)
 840 AC_SUBST(LIBJPEG)
 841 AC_SUBST(LIBPNG)
 842
 843 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 844
 845 #
 846 # Allow building some or all gdk-pixbuf loaders included
 847 #
 848 AC_MSG_CHECKING(pixbuf loaders to build)
 849
 850 dnl due to an autoconf bug, commas in the first arg to
 851 dnl AC_HELP_STRING cause problems.
 852 dnl AC_HELP_STRING([--with-included-loaders=LOADER1 LOADER2 ...],
 853 dnl                [build the specified loaders into gdk-pixbuf (only used if module loading disabled)])
 854 AC_ARG_WITH(included_loaders,
 855 [  --with-included-loaders=LOADER1,LOADER2,...
 856                           build the specified loaders into gdk-pixbuf (only
 857                           used if module loading disabled)])
 858
 859 if $dynworks; then
 860         :
 861 else
 862    ## if the option was specified, leave it; otherwise disable included loaders
 863    if test x$with_included_loaders = xno; then
 864            with_included_loaders=yes
 865    fi
 866 fi
 867
 868 all_loaders="png,bmp,wbmp,gif,ico,ani,jpeg,pnm,ras,tiff,xpm,tga,pcx"
 869 included_loaders=""
 870 # If no loaders specified, include all
 871 if test "x$with_included_loaders" = xyes ; then
 872   included_loaders="$all_loaders"
 873 else
 874   included_loaders="$with_included_loaders"
 875 fi
 876
 877 AC_MSG_RESULT($included_loaders)
 878
 879 INCLUDED_LOADER_OBJ=
 880 INCLUDED_LOADER_DEFINE=
 881
 882 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 883 for loader in $included_loaders; do
 884  if echo "$all_loaders" | egrep "(^|,)$loader(\$|,)" > /dev/null; then
 885    :
 886  else
 887    AC_MSG_ERROR([the specified loader $loader does not exist])
 888  fi
 889
 890  INCLUDED_LOADER_OBJ="$INCLUDED_LOADER_OBJ libpixbufloader-static-$loader.la"
 891  INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_$loader"
 892 done
 893 IFS="$gtk_save_ifs"
 894 AC_SUBST(INCLUDED_LOADER_OBJ)
 895 AC_SUBST(INCLUDED_LOADER_DEFINE)
 896
 897 AC_HEADER_SYS_WAIT
 898
 899 AC_TYPE_SIGNAL
 900
 901 AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
 902 AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
 903 AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
 904
 905 if $dynworks ; then
 906   STATIC_LIB_DEPS=
 907   if echo "$included_loaders" | egrep '(^|,)tiff($|,)' > /dev/null; then
 908     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBTIFF"
 909   fi
 910   if echo "$included_loaders" | egrep '(^|,)jpeg($|,)' > /dev/null; then
 911     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBJPEG"
 912   fi
 913   if echo "$included_loaders" | egrep '(^|,)png($|,)' > /dev/null; then
 914     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBPNG"
 915   fi
 916 else
 917   STATIC_LIB_DEPS="$LIBTIFF $LIBJPEG $LIBPNG"
 918 fi
 919
 920 # Checks to see if we should compile in MMX support (there will be
 921 # a runtime test when the code is actually run to see if it should
 922 # be used - this just checks if we can compile it.)
 923 #
 924 # This code is partially taken from Mesa
 925 #
 926 AC_MSG_CHECKING(for x86 platform)
 927 case $host_cpu in
 928   i386|i486|i586|i686|i786|k6|k7)
 929         use_x86_asm=yes
 930         ;;
 931    *)
 932         use_x86_asm=no
 933 esac
 934 AC_MSG_RESULT($use_x86_asm)
 935
 936 use_mmx_asm=no
 937 if test $use_x86_asm = yes; then
 938     save_ac_ext=$ac_ext
 939     ac_ext=S
 940
 941     AC_MSG_CHECKING(compiler support for MMX)
 942     cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
 943     if AC_TRY_EVAL(ac_compile); then
 944         use_mmx_asm=yes
 945     fi
 946
 947     rm -rf conftest*
 948
 949     ac_ext=$save_ac_ext
 950     if test $use_mmx_asm = yes; then
 951       AC_DEFINE(USE_MMX)
 952       AC_MSG_RESULT(yes)
 953     else
 954       AC_MSG_RESULT(no)
 955     fi
 956 fi
 957
 958 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
 959
 960 REBUILD_PNGS=
 961 if test -z "$LIBPNG"; then
 962   REBUILD_PNGS=#
 963 fi
 964
 965 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 966
 967 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 968
 969 if test $cross_compiling = yes; then
 970   AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 971   if test x$GDK_PIXBUF_CSOURCE = xno; then
 972     REBUILD_PNGS=#
 973   fi
 974 fi
 975
 976 if test ! -f $srcdir/gtk/stock-icons/gtkstockpixbufs.h &&
 977    test "x$REBUILD_PNGS" = "x#" ; then
 978      AC_MSG_ERROR([
 979 *** gtkstockpixbufs.h is not in the tree, and cannot be built
 980 *** because you don't have libpng, or (when cross-compiling) you
 981 *** don't have a prebuilt gdk-pixbuf-csource on the host system.])
 982 fi
 983
 984 AC_SUBST(REBUILD_PNGS)
 985
 986 GDK_PIXBUF_PACKAGES="gmodule-no-export-2.0 gobject-2.0"
 987 GDK_PIXBUF_EXTRA_LIBS="$STATIC_LIB_DEPS $MATH_LIB"
 988 GDK_PIXBUF_EXTRA_CFLAGS=
 989 GDK_PIXBUF_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
 990 GDK_PIXBUF_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $PNG_DEP_CFLAGS_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS"
 991
 992 AC_SUBST(GDK_PIXBUF_PACKAGES)
 993 AC_SUBST(GDK_PIXBUF_EXTRA_LIBS)
 994 AC_SUBST(GDK_PIXBUF_EXTRA_CFLAGS)
 995 AC_SUBST(GDK_PIXBUF_DEP_LIBS)
 996 AC_SUBST(GDK_PIXBUF_DEP_CFLAGS)
 997
 998
 999 ########################################
1000 # Windowing system checks
1001 ########################################
1002
1003 GDK_EXTRA_LIBS=$GDK_WLIBS
1004 GDK_EXTRA_CFLAGS=
1005 GTK_DEP_LIBS_FOR_X=
1006
1007 FREETYPE_LIBS=
1008 FREETYPE_CFLAGS=
1009 if test "x$gdktarget" = "xlinux-fb" || test "x$gdktarget" = "xx11" ; then
1010   #
1011   # Checks for FreeType
1012   #
1013   have_freetype=false
1014   AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
1015   if test "x$FREETYPE_CONFIG" != "xno" ; then
1016     FREETYPE_CFLAGS=`$FREETYPE_CONFIG --cflags`
1017     FREETYPE_LIBS=`$FREETYPE_CONFIG --libs`
1018
1019     gtk_save_LIBS="$LIBS"
1020     LIBS="$FREETYPE_LIBS $LIBS"
1021     AC_TRY_LINK_FUNC(FT_New_Face, have_freetype=true,:)
1022     LIBS="$gtk_save_LIBS"
1023
1024     if $have_freetype ; then
1025       gtk_save_cppflags="$CPPFLAGS"
1026       CPPFLAGS="$CPPFLAGS $FREETYPE_CFLAGS"
1027
1028       AC_MSG_CHECKING([For sufficiently new FreeType (at least 2.0.1)])
1029       AC_TRY_COMPILE([
1030 #include <ft2build.h>
1031 #include FT_FREETYPE_H
1032 #include FT_ERRORS_H
1033     ],
1034                      [(void)1;],:,have_freetype=false)
1035       if $have_freetype ; then
1036         AC_MSG_RESULT(yes)
1037       else
1038         AC_MSG_RESULT(no)
1039       fi
1040
1041       CPPFLAGS="$gtk_save_cppflags"
1042     fi
1043   fi
1044   AC_SUBST(FREETYPE_LIBS)
1045   AC_SUBST(FREETYPE_CFLAGS)
1046 fi
1047
1048 if test "x$gdktarget" = "xx11"; then
1049   # We start off with the libraries from Pango
1050
1051   ## be sure we also have Pango built with Xft2 support
1052   if $PKG_CONFIG --exists 'pangoxft >= 1.2.0' ; then
1053     if $have_freetype ; then
1054       :
1055     else
1056       AC_MSG_ERROR([Xft Pango backend found but did not find freetype libraries])
1057     fi
1058   else
1059     AC_MSG_ERROR([Xft Pango backend is required for x11 target])
1060   fi
1061
1062   if $PKG_CONFIG --exists xft ; then : ; else
1063     AC_MSG_ERROR([Xft version 2 is required for x11 target])
1064   fi
1065
1066   #
1067   # If Pango included the shared library dependencies from X11 in
1068   # the pkg-config output, then we use that (to avoid duplicates).
1069   # but if they were omitted to avoid binary compatibility problems,
1070   # then we need to repeat the checks.
1071   #
1072   x_libs="`$PKG_CONFIG --libs pangoxft`"
1073   case "$x_libs" in
1074     *-lX11*) pango_omitted_x_deps=no ;;
1075     *)       pango_omitted_x_deps=yes ;;
1076   esac
1077
1078   x_cflags="`$PKG_CONFIG --cflags pangoxft`"
1079   x_extra_libs=
1080
1081   AC_PATH_XTRA
1082   if test x$no_x = xyes ; then
1083     AC_MSG_ERROR([X development libraries not found])
1084   fi
1085
1086   if test $pango_omitted_x_deps = yes ; then
1087     # Old versions of Xft didn't necessarily include -lX11 in the output
1088     x_libs="`pkg-config --libs xft` -lX11 $X_EXTRA_LIBS"
1089   fi
1090
1091   ## Strip the .la files
1092
1093   x_libs_for_checks=""
1094   for I in $x_libs ; do
1095     case $I in
1096       *.la) ;;
1097       *) x_libs_for_checks="$x_libs_for_checks $I" ;;
1098     esac
1099   done
1100
1101   # Sanity check for the X11 library
1102   AC_CHECK_LIB(X11, XOpenDisplay, :,
1103             AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
1104             $x_libs_for_checks)
1105
1106   if test "x$enable_shm" = "xyes"; then
1107     # Check for the Xext library (needed for XShm extention)
1108     AC_CHECK_LIB(Xext, XShmAttach,
1109         [GTK_ADD_LIB(x_extra_libs,Xext)],
1110         # On AIX, it is in XextSam instead, but we still need -lXext
1111         [AC_CHECK_LIB(XextSam, XShmAttach,
1112             [GTK_ADD_LIB(x_extra_libs,Xext)
1113              GTK_ADD_LIB(x_extra_libs,XextSam)
1114             ], , -lXext $x_libs_for_checks)],
1115         $x_libs_for_checks)
1116   fi
1117
1118   GDK_PIXBUF_XLIB_EXTRA_CFLAGS="$x_cflags"
1119   # Don't ever pull in the pangoxft libraries for gdk-pixbuf-x11
1120   GDK_PIXBUF_XLIB_EXTRA_LIBS="$X_LIBS -lX11 $x_extra_libs $X_EXTRA_LIBS"
1121
1122   # GTK+ uses some X calls, so needs to link against X directly
1123   if test $enable_explicit_deps != yes ; then
1124     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
1125   fi
1126
1127   # Check for Xinerama extension (Solaris impl or Xfree impl)
1128
1129   gtk_save_cppflags="$CPPFLAGS"
1130   CPPFLAGS="$CPPFLAGS $x_cflags"
1131
1132   case "$host" in
1133       *-*-solaris*)
1134           # Check for solaris
1135           use_solaris_xinerama=yes
1136           AC_CHECK_LIB(Xext, XineramaGetInfo,
1137                         use_solaris_xinerama=yes,
1138                         use_solaris_xinerama=no,
1139                         -lXext $x_libs_for_checks)
1140           if test "x$use_solaris_xinerama" = "xyes"; then
1141               AC_CHECK_HEADER(X11/extensions/xinerama.h,
1142                 [GTK_ADD_LIB(x_extra_libs,Xext)
1143                 AC_DEFINE(HAVE_SOLARIS_XINERAMA)
1144                 AC_DEFINE(HAVE_XINERAMA)],
1145                 use_solaris_xinerama=no,[#include <X11/Xlib.h>])
1146           fi
1147           AC_MSG_CHECKING(for Xinerama support on Solaris)
1148           AC_MSG_RESULT($use_solaris_xinerama);
1149           ;;
1150       *)
1151           # Check for XFree
1152           use_xfree_xinerama=yes
1153           AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1154               [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1155                   [GTK_ADD_LIB(x_extra_libs,Xext)
1156                   GTK_ADD_LIB(x_extra_libs,Xinerama)
1157                   AC_DEFINE(HAVE_XFREE_XINERAMA)
1158                   AC_DEFINE(HAVE_XINERAMA)],
1159                   use_xfree_xinerama=no,
1160                   [#include <X11/Xlib.h>])],
1161               use_xfree_xinerama=no, -lXext $x_libs_for_checks)
1162           AC_MSG_CHECKING(for Xinerama support on XFree86)
1163           AC_MSG_RESULT($use_xfree_xinerama);
1164           ;;
1165   esac
1166
1167   CPPFLAGS="$gtk_save_cppflags"
1168
1169   # Check for xReply
1170
1171   gtk_save_cppflags="$CPPFLAGS"
1172   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1173
1174   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
1175   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
1176       [xReply *rep;],
1177       [AC_MSG_RESULT([no])],
1178       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
1179 #include <X11/Xlibint.h>],
1180            [xReply *rep;],
1181            [AC_MSG_RESULT([yes])
1182             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
1183                 [Define if <X11/extensions/XIproto.h> needed for xReply])],
1184            [AC_MSG_RESULT([unknown])
1185             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1186
1187   CPPFLAGS="$gtk_save_cppflags"
1188
1189   # Check for shaped window extension
1190
1191   AC_CHECK_LIB(Xext, XShapeCombineMask,
1192       [GTK_ADD_LIB(x_extra_libs,Xext)
1193        AC_DEFINE(HAVE_SHAPE_EXT)],
1194       ,
1195       $x_libs_for_checks)
1196
1197   # Check for XConvertCase (X11R6 specific)
1198
1199   AC_CHECK_LIB(X11, XConvertCase,
1200       AC_DEFINE(HAVE_XCONVERTCASE),
1201       ,
1202       $x_libs_for_checks)
1203
1204   # Check for XInternAtoms (X11R6 specific)
1205
1206   AC_CHECK_LIB(X11, XInternAtoms,
1207       AC_DEFINE([HAVE_XINTERNATOMS], 1,
1208           [Define to 1 if you have the `XInternAtoms' function.]),
1209       ,
1210       $x_libs_for_checks)
1211
1212   # Generic X11R6 check needed for XIM support; we could
1213   # probably use this to replace the above, but we'll
1214   # leave the separate checks for XConvertCase and XInternAtoms
1215   # for clarity
1216   have_x11r6=false
1217   AC_CHECK_LIB(X11, XAddConnectionWatch,
1218       have_x11r6=true,
1219       ,
1220       $x_libs_for_checks)
1221
1222   if $have_x11r6; then
1223     AC_DEFINE(HAVE_X11R6,1,[Define if we have X11R6])
1224   fi
1225   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1226
1227   # Check for XKB support.
1228
1229   if test "x$enable_xkb" = "xyes"; then
1230         AC_MSG_WARN(XKB support explicitly enabled)
1231         AC_DEFINE(HAVE_XKB)
1232   elif test "x$enable_xkb" = "xmaybe"; then
1233         AC_CHECK_LIB(X11, XkbQueryExtension,
1234                      AC_DEFINE(HAVE_XKB),
1235                      ,
1236                      $x_libs_for_checks)
1237   else
1238         AC_MSG_WARN(XKB support explicitly disabled)
1239   fi
1240
1241   x_cflags="$X_CFLAGS"
1242   x_ldflags="$X_LDFLAGS"
1243
1244   # set up things for XInput
1245
1246   if test "x$with_xinput" = "xxfree" || test "x$with_xinput" = "xyes"; then
1247     AC_DEFINE(XINPUT_XFREE)
1248     GTK_ADD_LIB(x_extra_libs, Xi)
1249   else
1250     AC_DEFINE(XINPUT_NONE)
1251   fi
1252
1253   AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree || test x$with_xinput = xyes)
1254
1255   # Check for the RANDR extension
1256
1257   AC_CHECK_LIB(Xrandr, XRRUpdateConfiguration,
1258       [AC_CHECK_HEADER(X11/extensions/Xrandr.h,
1259           # RANDR requires RENDER
1260           [GTK_ADD_LIB(x_extra_libs, Xrender)
1261           GTK_ADD_LIB(x_extra_libs, Xrandr)
1262           AC_DEFINE(HAVE_RANDR, 1, Have the Xrandr extension library)],
1263           :, [#include <X11/Xlib.h>])], : ,
1264        $X_LIBS -lXrandr -lXrender -lX11 $X_EXTRA_LIBS)
1265
1266   # Checks for Xcursor library
1267
1268   have_xcursor=false
1269   PKG_CHECK_MODULES(XCURSOR, xcursor, have_xcursor=true, :)
1270
1271   if $have_xcursor ; then
1272     AC_DEFINE(HAVE_XCURSOR, 1, Have the Xcursor library)
1273     GDK_EXTRA_CFLAGS="`$PKG_CONFIG --cflags xcursor` $GDK_EXTRA_CFLAGS"
1274     GDK_EXTRA_LIBS="`$PKG_CONFIG --libs xcursor` $GDK_EXTRA_LIBS"
1275   fi
1276
1277   # X SYNC check
1278   AC_CHECK_LIB(Xext, XSyncQueryExtension,
1279       [AC_CHECK_HEADER(X11/extensions/sync.h,
1280           [GTK_ADD_LIB(x_extra_libs, Xext)
1281           AC_DEFINE(HAVE_XSYNC, 1, Have the SYNC extension library)],
1282           :, [#include <X11/Xlib.h>])], : ,
1283        $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
1284
1285   # Checks for XFixes extension
1286
1287   have_xfixes=false
1288   PKG_CHECK_MODULES(XFIXES, xfixes, have_xfixes=true, :)
1289
1290   if $have_xfixes ; then
1291     AC_DEFINE(HAVE_XFIXES, 1, Have the XFIXES X extension)
1292     GDK_EXTRA_CFLAGS="`$PKG_CONFIG --cflags xfixes` $GDK_EXTRA_CFLAGS"
1293     GDK_EXTRA_LIBS="`$PKG_CONFIG --libs xfixes` $GDK_EXTRA_LIBS"
1294   fi
1295
1296   # Xshm checks
1297
1298   if test "x$enable_shm" = "xyes"; then
1299     # Check for shared memory
1300     AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
1301     AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
1302
1303     # Check for the X shared memory extension header file
1304     have_xshm=no
1305     AC_MSG_CHECKING(X11/extensions/XShm.h)
1306     if test "x$no_xext_lib" = "xyes"; then
1307       :
1308     else
1309       gtk_save_CFLAGS="$CFLAGS"
1310       CFLAGS="$CFLAGS $x_cflags"
1311       AC_TRY_COMPILE([
1312 #include <stdlib.h>
1313 #include <sys/types.h>
1314 #include <sys/ipc.h>
1315 #include <sys/shm.h>
1316 #include <X11/Xlib.h>
1317 #include <X11/Xutil.h>
1318 #include <X11/extensions/XShm.h>
1319 ], [XShmSegmentInfo *x_shm_info;], have_xshm=yes)
1320       CFLAGS="$gtk_save_CFLAGS"
1321     fi
1322     AC_MSG_RESULT($have_xshm)
1323     if test $have_xshm = yes ; then
1324       AC_DEFINE(HAVE_XSHM_H)
1325     fi
1326   fi
1327
1328   if test $pango_omitted_x_deps = yes ; then
1329     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs $x_libs $GDK_EXTRA_LIBS"
1330   else
1331     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs $GDK_EXTRA_LIBS"
1332   fi
1333
1334   AM_CONDITIONAL(USE_X11, true)
1335 else
1336   AM_CONDITIONAL(XINPUT_XFREE, false)
1337   AM_CONDITIONAL(USE_X11, false)
1338   AM_CONDITIONAL(HAVE_X11R6, false)
1339 fi
1340
1341 if test "x$gdktarget" = "xwin32"; then
1342   # We start off with the libraries from Pango
1343
1344   if test x$have_wintab = xyes; then
1345     GDK_WIN32_EXTRA_CFLAGS="-I $with_wintab/include"
1346     AC_SUBST(GDK_WIN32_EXTRA_CFLAGS)
1347   fi
1348
1349   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -user32 -limm32 -lshell32 -lole32 -luuid"
1350   AM_CONDITIONAL(USE_WIN32, true)
1351 else
1352   AM_CONDITIONAL(USE_WIN32, false)
1353 fi
1354
1355 GDK_PIXBUF_XLIB_PACKAGES=
1356 GDK_PIXBUF_XLIB_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_XLIB_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
1357 GDK_PIXBUF_XLIB_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_PIXBUF_XLIB_EXTRA_CFLAGS"
1358
1359 AC_SUBST(GDK_PIXBUF_XLIB_PACKAGES)
1360 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_LIBS)
1361 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_CFLAGS)
1362 AC_SUBST(GDK_PIXBUF_XLIB_DEP_LIBS)
1363 AC_SUBST(GDK_PIXBUF_XLIB_DEP_CFLAGS)
1364
1365 if test "x$gdktarget" = "xlinux-fb"; then
1366   if $have_freetype ; then
1367     :
1368   else
1369     AC_MSG_ERROR([Using linux-fb backend but freetype was not found])
1370   fi
1371
1372   ft2_libs="`$PKG_CONFIG --libs pangoft2`"
1373   case "$ft2_libs" in
1374     *-lfreetype*) pango_omitted_ft2_deps=no ;;
1375     *)            pango_omitted_ft2_deps=yes ;;
1376   esac
1377
1378   CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
1379
1380   if test x$enable_shadowfb = xyes ; then
1381     AC_DEFINE(ENABLE_SHADOW_FB)
1382   fi
1383
1384   if test x$enable_fbmanager = xyes ; then
1385     AC_DEFINE(ENABLE_FB_MANAGER)
1386     AM_CONDITIONAL(ENABLE_FB_MANAGER, true)
1387   else
1388     AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
1389   fi
1390
1391   if test $pango_omitted_ft2_deps = yes ; then
1392     GDK_EXTRA_LIBS="$FREETYPE_LIBS $GDK_EXTRA_LIBS"
1393   fi
1394
1395   AM_CONDITIONAL(USE_LINUX_FB, true)
1396 else
1397   AM_CONDITIONAL(USE_LINUX_FB, false)
1398   AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
1399 fi
1400
1401 #
1402 # Pick correct Pango packages to use
1403 #
1404
1405 if test "x$gdktarget" = "xx11"; then
1406         PANGO_PACKAGES=pangoxft
1407
1408         # We no longer use pangox, but if we find it, we link to it
1409         # for binary compatibility.
1410         if $PKG_CONFIG --exists pangox ; then
1411                 PANGO_PACKAGES="$PANGO_PACKAGES pangox"
1412         fi
1413 elif test "x$gdktarget" = "xwin32"; then
1414         PANGO_PACKAGES=pangowin32
1415 elif test "x$gdktarget" = "xlinux-fb"; then
1416         PANGO_PACKAGES=pangoft2
1417 else
1418         PANGO_PACKAGES=pango
1419 fi
1420
1421 # Check for Pango flags
1422
1423 AC_MSG_CHECKING(Pango flags)
1424 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1425         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1426         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1427
1428         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1429 else
1430         AC_MSG_ERROR([
1431 *** Pango not found. Pango is required to build GTK+.
1432 *** See http://www.pango.org for Pango information.
1433 *** For the framebuffer target, you will need to build
1434 *** Pango with freetype support.
1435 ])
1436 fi
1437
1438 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1439
1440 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1441         :
1442 else
1443         gtk_save_LIBS="$LIBS"
1444         LIBS="$PANGO_LIBS $LIBS"
1445         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1446 *** Can't link to Pango. Pango is required to build
1447 *** GTK+. For more information see http://www.pango.org]))
1448         LIBS="$gtk_save_LIBS"
1449 fi
1450
1451 CFLAGS="$saved_cflags"
1452 LDFLAGS="$saved_ldflags"
1453
1454 GDK_PACKAGES="$PANGO_PACKAGES"
1455 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
1456 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS"
1457
1458 #
1459 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1460 # into the pkg-config files
1461 #
1462 if test $enable_explicit_deps != yes ; then
1463   GDK_EXTRA_LIBS=
1464 fi
1465
1466 AC_SUBST(GDK_PACKAGES)
1467 AC_SUBST(GDK_EXTRA_LIBS)
1468 AC_SUBST(GDK_EXTRA_CFLAGS)
1469 AC_SUBST(GDK_DEP_LIBS)
1470 AC_SUBST(GDK_DEP_CFLAGS)
1471
1472
1473 ########################################
1474 # Check for Accessibility Toolkit flags
1475 ########################################
1476
1477 ATK_PACKAGES=atk
1478 AC_MSG_CHECKING(ATK flags)
1479 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1480         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1481         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1482
1483         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1484 else
1485         AC_MSG_ERROR([
1486 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1487 *** to build GTK+.
1488 ])
1489 fi
1490
1491 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1492         :
1493 else
1494         gtk_save_LIBS="$LIBS"
1495         LIBS="$ATK_LIBS $LIBS"
1496         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1497                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1498                 *** to build GTK+]))
1499         LIBS="$gtk_save_LIBS"
1500 fi
1501
1502 GTK_PACKAGES=atk
1503 GTK_EXTRA_LIBS=
1504 GTK_EXTRA_CFLAGS=
1505 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GTK_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
1506 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1507
1508 AC_SUBST(GTK_PACKAGES)
1509 AC_SUBST(GTK_EXTRA_LIBS)
1510 AC_SUBST(GTK_EXTRA_CFLAGS)
1511 AC_SUBST(GTK_DEP_LIBS)
1512 AC_SUBST(GTK_DEP_CFLAGS)
1513
1514
1515 AC_SUBST(GTK_DEBUG_FLAGS)
1516 AC_SUBST(GTK_XIM_FLAGS)
1517
1518 ################################################################
1519 # Strip -export-dynamic from the link lines of various libraries
1520 ################################################################
1521
1522 #
1523 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1524 #  but this flag is only meaningful for executables. For libraries
1525 #  the effect is undefined; what it causes on Linux is that the
1526 #  export list from -export-symbols-regex is ignored and everything
1527 #  is exported
1528 #
1529 # We are using gmodule-no-export now, but I'm leaving the stripping
1530 # code in place for now, since pango and atk still require gmodule.
1531 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1532 if test -n "$export_dynamic"; then
1533   GDK_PIXBUF_DEP_LIBS=`echo $GDK_PIXBUF_DEP_LIBS | sed -e "s/$export_dynamic//"`
1534   GDK_PIXBUF_XLIB_DEP_LIBS=`echo $GDK_PIXBUF_XLIB_DEP_LIBS | sed -e "s/$export_dynamic//"`
1535   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1536   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1537 fi
1538
1539
1540 ##################################################
1541 # Checks for gtk-doc and docbook-tools
1542 ##################################################
1543
1544 GTK_DOC_CHECK([1.0])
1545
1546 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1547 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1548
1549 AC_ARG_ENABLE(man,
1550               [AC_HELP_STRING([--enable-man],
1551                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1552               enable_man=no)
1553
1554 if test "${enable_man}" != no; then
1555   dnl
1556   dnl Check for xsltproc
1557   dnl
1558   AC_PATH_PROG([XSLTPROC], [xsltproc])
1559   if test -z "$XSLTPROC"; then
1560     enable_man=no
1561   fi
1562
1563   dnl check for DocBook DTD and stylesheets in the local catalog.
1564   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1565      [DocBook XML DTD V4.1.2],,enable_man=no)
1566   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1567      [DocBook XSL Stylesheets],,enable_man=no)
1568 fi
1569
1570 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1571
1572
1573 ##################################################
1574 # Output commands
1575 ##################################################
1576
1577 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1578         outfile=gdkconfig.h-tmp
1579         cat > $outfile <<\_______EOF
1580 /* gdkconfig.h
1581  *
1582  * This is a generated file.  Please modify `configure.in'
1583  */
1584
1585 #ifndef GDKCONFIG_H
1586 #define GDKCONFIG_H
1587
1588 #ifdef __cplusplus
1589 extern "C" {
1590 #endif /* __cplusplus */
1591
1592 _______EOF
1593
1594         cat >>$outfile <<_______EOF
1595 $gdk_windowing
1596 $gdk_wc
1597 _______EOF
1598
1599         cat >>$outfile <<_______EOF
1600
1601 #ifdef __cplusplus
1602 }
1603 #endif /* __cplusplus */
1604
1605 #endif /* GDKCONFIG_H */
1606 _______EOF
1607
1608
1609         if cmp -s $outfile gdk/gdkconfig.h; then
1610           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1611           rm -f $outfile
1612         else
1613           mv $outfile gdk/gdkconfig.h
1614         fi
1615 ],[
1616 if test "x$gdktarget" = "xx11" ; then
1617   gdk_windowing='
1618 #define GDK_WINDOWING_X11'
1619 elif test "x$gdktarget" = "xwin32" ; then
1620   gdk_windowing='
1621 #define GDK_WINDOWING_WIN32'
1622 elif test "x$gdktarget" = "xlinux-fb" ; then
1623   gdk_windowing='
1624 #define GDK_WINDOWING_FB
1625 #define GDK_NATIVE_WINDOW_POINTER'
1626 fi
1627
1628 if test x$gdk_wchar_h = xyes; then
1629   gdk_wc='
1630 #define GDK_HAVE_WCHAR_H 1'
1631 fi
1632 if test x$gdk_wctype_h = xyes; then
1633   gdk_wc="\$gdk_wc
1634 #define GDK_HAVE_WCTYPE_H 1"
1635 fi
1636 if test x$gdk_working_wctype = xno; then
1637   gdk_wc="\$gdk_wc
1638 #define GDK_HAVE_BROKEN_WCTYPE 1"
1639 fi
1640
1641
1642 ])
1643
1644 AC_CONFIG_FILES([
1645 config.h.win32
1646 gtk-zip.sh
1647 Makefile
1648 gdk-pixbuf-2.0.pc
1649 gdk-2.0.pc
1650 gtk+-2.0.pc
1651 gdk-pixbuf-2.0-uninstalled.pc
1652 gdk-2.0-uninstalled.pc
1653 gtk+-2.0-uninstalled.pc
1654 m4macros/Makefile
1655 po/Makefile.in
1656 po-properties/Makefile.in
1657 build/Makefile
1658 build/win32/Makefile
1659 build/win32/dirent/Makefile
1660 demos/Makefile
1661 demos/gtk-demo/Makefile
1662 demos/gtk-demo/geninclude.pl
1663 tests/Makefile
1664 docs/Makefile
1665 docs/reference/Makefile
1666 docs/reference/gdk-pixbuf/Makefile
1667 docs/reference/gdk-pixbuf/version.xml
1668 docs/reference/gdk/Makefile
1669 docs/reference/gdk/version.xml
1670 docs/reference/gtk/Makefile
1671 docs/reference/gtk/version.xml
1672 docs/faq/Makefile
1673 docs/tools/Makefile
1674 docs/tutorial/Makefile
1675 gdk-pixbuf/Makefile
1676 gdk-pixbuf/gdk_pixbuf.rc
1677 gdk-pixbuf/gdk-pixbuf-features.h
1678 gdk-pixbuf/pixops/Makefile
1679 gdk/Makefile
1680 gdk/x11/Makefile
1681 gdk/win32/Makefile
1682 gdk/win32/rc/Makefile
1683 gdk/win32/rc/gdk.rc
1684 gdk/linux-fb/Makefile
1685 gtk/Makefile
1686 gtk/makefile.msc
1687 gtk/gtkversion.h
1688 gtk/gtk-win32.rc
1689 gtk/stock-icons/Makefile
1690 gtk/theme-bits/Makefile
1691 gtk/xdgmime/Makefile
1692 modules/Makefile
1693 modules/input/Makefile
1694 modules/engines/Makefile
1695 modules/engines/pixbuf/Makefile
1696 modules/engines/ms-windows/Makefile
1697 modules/engines/ms-windows/Theme/Makefile
1698 modules/engines/ms-windows/Theme/gtk-2.0/Makefile
1699 contrib/Makefile
1700 contrib/gdk-pixbuf-xlib/Makefile
1701 contrib/gdk-pixbuf-xlib/gdk-pixbuf-xlib-2.0.pc
1702 ])
1703
1704 AC_OUTPUT
1705
1706 echo "configuration:
1707         target: $gdktarget"
1708
1709 if test "x$gdktarget" = "xlinux-fb"; then
1710   echo "Warning: The linux-fb GDK target is unmaintained"
1711   echo "         and may not work or even compile"
1712 fi
1713