Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 # Making releases:
   6 #   GTK_MICRO_VERSION += 1;
   7 #   GTK_INTERFACE_AGE += 1;
   8 #   GTK_BINARY_AGE += 1;
   9 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  10 # if backwards compatibility has been broken,
  11 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  12
  13 m4_define([gtk_major_version], [2])
  14 m4_define([gtk_minor_version], [13])
  15 m4_define([gtk_micro_version], [5])
  16 m4_define([gtk_interface_age], [0])
  17 m4_define([gtk_binary_age],
  18           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  19 m4_define([gtk_version],
  20           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  21 # This is the X.Y used in -lgtk-FOO-X.Y
  22 m4_define([gtk_api_version], [2.0])
  23
  24 # Define a string for the earliest version that this release has
  25 # backwards binary compatibility with for all interfaces a module
  26 # might. Unless we add module-only API with lower stability
  27 # guarantees, this should be unchanged until we break binary compat
  28 # for GTK+.
  29 #
  30 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  31 m4_define([gtk_binary_version], [2.10.0])
  32
  33 # required versions of other packages
  34 m4_define([glib_required_version], [2.17.3])
  35 m4_define([pango_required_version], [1.20])
  36 m4_define([atk_required_version], [1.13.0])
  37 m4_define([cairo_required_version], [1.6])
  38
  39
  40 AC_INIT([gtk+], [gtk_version],
  41         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  42         [gtk+])
  43
  44 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  45
  46 # Save this value here, since automake will set cflags later
  47 cflags_set=${CFLAGS+set}
  48
  49 AM_INIT_AUTOMAKE(no-define)
  50 AM_CONFIG_HEADER(config.h)
  51
  52 #
  53 # For each of the libraries we build, we define the following
  54
  55 # substituted variables:
  56 #
  57 # foo_PACKAGES:     pkg-config packages this library requires
  58 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  59 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  60 # foo_DEP_LIBS:     All libraries this module requires
  61 # foo_DEP_CFLAGS:   All cflags this module requires
  62
  63
  64 GTK_MAJOR_VERSION=gtk_major_version
  65 GTK_MINOR_VERSION=gtk_minor_version
  66 GTK_MICRO_VERSION=gtk_micro_version
  67 GTK_INTERFACE_AGE=gtk_interface_age
  68 GTK_BINARY_AGE=gtk_binary_age
  69 GTK_VERSION=gtk_version
  70 GTK_API_VERSION=gtk_api_version
  71 GTK_BINARY_VERSION=gtk_binary_version
  72 AC_SUBST(GTK_MAJOR_VERSION)
  73 AC_SUBST(GTK_MINOR_VERSION)
  74 AC_SUBST(GTK_MICRO_VERSION)
  75 AC_SUBST(GTK_INTERFACE_AGE)
  76 AC_SUBST(GTK_BINARY_AGE)
  77 AC_SUBST(GTK_API_VERSION)
  78 AC_SUBST(GTK_VERSION)
  79 AC_SUBST(GTK_BINARY_VERSION)
  80
  81 # libtool versioning
  82 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  83 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  84 #LT_REVISION=$GTK_INTERFACE_AGE
  85 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  86 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  87
  88 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
  89 m4_define([lt_revision], [gtk_interface_age])
  90 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
  91 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
  92 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
  93 AC_SUBST(LT_VERSION_INFO)
  94 AC_SUBST(LT_CURRENT_MINUS_AGE)
  95
  96 m4_define([gail_lt_current],[18])
  97 m4_define([gail_lt_revision],[1])
  98 m4_define([gail_lt_age],[0])
  99 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 100 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 101 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 102 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 103
 104 #
 105 # gdk-pixbuf gets versioned separately, and for now, using standard
 106 # libtool versioning, not GTK+-style versioning
 107 #
 108 GDK_PIXBUF_MAJOR=gtk_major_version
 109 GDK_PIXBUF_MINOR=gtk_minor_version
 110 GDK_PIXBUF_MICRO=gtk_micro_version
 111 GDK_PIXBUF_VERSION="${GDK_PIXBUF_MAJOR}.${GDK_PIXBUF_MINOR}.${GDK_PIXBUF_MICRO}"
 112 AC_SUBST(GDK_PIXBUF_MAJOR)
 113 AC_SUBST(GDK_PIXBUF_MINOR)
 114 AC_SUBST(GDK_PIXBUF_MICRO)
 115 AC_SUBST(GDK_PIXBUF_VERSION)
 116
 117 GETTEXT_PACKAGE=gtk20
 118 AC_SUBST(GETTEXT_PACKAGE)
 119 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 120                    [The prefix for our gettext translation domains.])
 121
 122 AC_CANONICAL_HOST
 123
 124 MATH_LIB=-lm
 125 AC_MSG_CHECKING([for native Win32])
 126 case "$host" in
 127   *-*-mingw*)
 128     os_win32=yes
 129     MATH_LIB=
 130     ;;
 131   *)
 132     os_win32=no
 133     ;;
 134 esac
 135 AC_MSG_RESULT([$os_win32])
 136
 137 case $host in
 138   *-*-linux*)
 139     os_linux=yes
 140     ;;
 141 esac
 142 dnl Initialize libtool
 143 AC_PROG_CC
 144 AM_DISABLE_STATIC
 145
 146 dnl
 147 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 148 dnl We use this for an automated test for C++ header correctness.
 149 dnl
 150 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 151 AC_LANG_SAVE
 152 AC_LANG_CPLUSPLUS
 153
 154 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 155 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 156
 157 gtk_save_cxxflags="$CXXFLAGS"
 158 CXXFLAGS="$CXXFLAGS -x objective-c++"
 159 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 160 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 161 CXXFLAGS="$gtk_save_cxxflags"
 162 AC_LANG_RESTORE
 163
 164 if test "$os_win32" = "yes"; then
 165   if test x$enable_static = xyes -o x$enable_static = x; then
 166     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 167     enable_static=no
 168   fi
 169   if test x$enable_shared = xno; then
 170     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 171   fi
 172   enable_shared=yes
 173 fi
 174
 175 AC_LIBTOOL_WIN32_DLL
 176 AM_PROG_LIBTOOL
 177
 178 # Make sure we use 64-bit versions of various file stuff.
 179 AC_SYS_LARGEFILE
 180
 181 AM_PROG_AS
 182 AC_PATH_PROG(NM, nm, nm)
 183
 184 dnl Initialize maintainer mode
 185 AM_MAINTAINER_MODE
 186
 187 AC_MSG_CHECKING([for some Win32 platform])
 188 case "$host" in
 189   *-*-mingw*|*-*-cygwin*)
 190     platform_win32=yes
 191     ;;
 192   *)
 193     platform_win32=no
 194     ;;
 195 esac
 196 AC_MSG_RESULT([$platform_win32])
 197 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 198
 199 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 200 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 201 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 202
 203 if test "$os_win32" = "yes"; then
 204   AC_CHECK_TOOL(WINDRES, windres, no)
 205   if test "$WINDRES" = no; then
 206     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 207   fi
 208   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 209 fi
 210 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 211
 212 m4_define([debug_default],
 213           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 214
 215 dnl declare --enable-* args and collect ac_help strings
 216 AC_ARG_ENABLE(debug,
 217               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 218                              [turn on debugging @<:@default=debug_default@:>@]),,
 219               enable_debug=debug_default)
 220 AC_ARG_ENABLE(shm,
 221               [AC_HELP_STRING([--enable-shm],
 222                               [support shared memory if available [default=yes]])],,
 223               [enable_shm="yes"])
 224 AC_ARG_ENABLE(xkb,
 225               [AC_HELP_STRING([--enable-xkb],
 226                               [support XKB [default=maybe]])],,
 227               [enable_xkb="maybe"])
 228 AC_ARG_ENABLE(xinerama,
 229               [AC_HELP_STRING([--enable-xinerama],
 230                               [support xinerama extension if available [default=yes]])],,
 231               [enable_xinerama="no"])
 232 AC_ARG_ENABLE(rebuilds,
 233               [AC_HELP_STRING([--disable-rebuilds],
 234                               [disable all source autogeneration rules])],,
 235               [enable_rebuilds=yes])
 236 AC_ARG_ENABLE(visibility,
 237               [AC_HELP_STRING([--disable-visibility],
 238                               [don't use ELF visibility attributes])],,
 239               [enable_visibility=yes])
 240
 241 AC_ARG_WITH(xinput,
 242             [AC_HELP_STRING([--with-xinput=@<:@no/yes@:>@], [support XInput])])
 243
 244 if test "$platform_win32" = yes; then
 245   gdktarget=win32
 246 else
 247   gdktarget=x11
 248 fi
 249
 250 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/win32/quartz/directfb]] select non-default GDK target],
 251         gdktarget=$with_gdktarget)
 252
 253 AC_SUBST(gdktarget)
 254 case $gdktarget in
 255   x11|win32|quartz|directfb) ;;
 256   *) AC_MSG_ERROR([Invalid target for GDK: use x11, quartz, directfb or win32.]);;
 257 esac
 258
 259 gdktargetlib=libgdk-$gdktarget-$GTK_API_VERSION.la
 260 gtktargetlib=libgtk-$gdktarget-$GTK_API_VERSION.la
 261
 262 AC_SUBST(gdktargetlib)
 263 AC_SUBST(gtktargetlib)
 264
 265 if test "x$enable_debug" = "xyes"; then
 266   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 267   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 268 else
 269   if test "x$enable_debug" = "xno"; then
 270     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 271   else
 272     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 273   fi
 274 fi
 275
 276
 277 if test "x$enable_visibility" = "xno"; then
 278   GTK_DEBUG_FLAGS="$GTK_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 279 fi
 280
 281
 282 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 283                    [Define if debugging is enabled])
 284
 285
 286 # Build time sanity check...
 287 AM_SANITY_CHECK
 288
 289 # Checks for programs.
 290 AC_ISC_POSIX
 291 AM_PROG_CC_STDC
 292 AC_PROG_INSTALL
 293 AC_PROG_MAKE_SET
 294
 295 changequote(,)dnl
 296 if test "x$GCC" = "xyes"; then
 297   case " $CFLAGS " in
 298   *[\ \ ]-Wall[\ \      ]*) ;;
 299   *) CFLAGS="$CFLAGS -Wall" ;;
 300   esac
 301
 302   if test "x$enable_ansi" = "xyes"; then
 303     case " $CFLAGS " in
 304     *[\ \       ]-ansi[\ \      ]*) ;;
 305     *) CFLAGS="$CFLAGS -ansi" ;;
 306     esac
 307
 308     case " $CFLAGS " in
 309     *[\ \       ]-pedantic[\ \  ]*) ;;
 310     *) CFLAGS="$CFLAGS -pedantic" ;;
 311     esac
 312   fi
 313 fi
 314 changequote([,])dnl
 315
 316 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES -DPANGO_DISABLE_SINGLE_INCLUDES -DGDK_PIXBUF_DISABLE_SINGLE_INCLUDES -DGTK_DISABLE_SINGLE_INCLUDES"
 317
 318 # Ensure MSVC-compatible struct packing convention is used when
 319 # compiling for Win32 with gcc.
 320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 321 # gcc2 uses "-fnative-struct".
 322 if test x"$os_win32" = xyes; then
 323   if test x"$GCC" = xyes; then
 324     msnative_struct=''
 325     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 326     if test -z "$ac_cv_prog_CC"; then
 327       our_gcc="$CC"
 328     else
 329       our_gcc="$ac_cv_prog_CC"
 330     fi
 331     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 332       2.)
 333         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 334           msnative_struct='-fnative-struct'
 335         fi
 336         ;;
 337       *)
 338         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 339           msnative_struct='-mms-bitfields'
 340         fi
 341         ;;
 342     esac
 343     if test x"$msnative_struct" = x ; then
 344       AC_MSG_RESULT([no way])
 345       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 346     else
 347       CFLAGS="$CFLAGS $msnative_struct"
 348       AC_MSG_RESULT([${msnative_struct}])
 349     fi
 350   fi
 351 fi
 352
 353 # Honor aclocal flags
 354 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 355
 356 ## Initial sanity check, done here so that users get told they
 357 ## have the wrong dependencies as early in the process as possible.
 358 ## Later on we actually use the cflags/libs from separate pkg-config
 359 ## calls. Oh, also the later pkg-config calls don't include
 360 ## the version requirements since those make the module lists
 361 ## annoying to construct
 362 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 363   [glib-2.0 >= glib_required_version dnl
 364    atk >= atk_required_version dnl
 365    pango >= pango_required_version dnl
 366    cairo >= cairo_required_version])
 367
 368 if test "$os_win32" != yes; then
 369     # libtool option to control which symbols are exported
 370     # right now, symbols starting with _ are not exported
 371     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 372 else
 373     # We currently use .def files on Windows (for gdk-pixbuf, gdk and gtk)
 374     LIBTOOL_EXPORT_OPTIONS=
 375 fi
 376 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 377
 378 dnl ******************************************************
 379 dnl * See whether to include shared library dependencies *
 380 dnl ******************************************************
 381
 382 AC_ARG_ENABLE(explicit-deps,
 383               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 384                               [use explicit dependencies in .pc files [default=auto]])],,
 385               [enable_explicit_deps=auto])
 386
 387 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 388 case $enable_explicit_deps in
 389   auto)
 390     export SED
 391     deplibs_check_method=`(./libtool --config; echo 'eval echo $deplibs_check_method') | sh`
 392     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 393       enable_explicit_deps=yes
 394     else
 395       enable_explicit_deps=no
 396     fi
 397   ;;
 398   yes|no)
 399   ;;
 400   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 401   ;;
 402 esac
 403 AC_MSG_RESULT($enable_explicit_deps)
 404
 405 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 406
 407 # define a MAINT-like variable REBUILD which is set if Perl
 408 # and awk are found, so autogenerated sources can be rebuilt
 409
 410 AC_PATH_PROGS(PERL, perl5 perl)
 411
 412 # We would like indent, but don't require it.
 413 AC_CHECK_PROG(INDENT, indent, indent)
 414
 415 REBUILD=\#
 416 if test "x$enable_rebuilds" = "xyes" && \
 417      test -n "$PERL" && \
 418      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 419   REBUILD=
 420 fi
 421 AC_SUBST(REBUILD)
 422
 423 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 424 AC_CHECK_FUNCS(localtime_r)
 425
 426 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 427 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 428 AC_TRY_LINK([#include <langinfo.h>], [
 429 char c;
 430 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 431 ], gtk_ok=yes, gtk_ok=no)
 432 AC_MSG_RESULT($gtk_ok)
 433 if test "$gtk_ok" = "yes"; then
 434   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 435             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 436 fi
 437
 438 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 439 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 440 AC_TRY_LINK([#include <langinfo.h>], [
 441 char c;
 442 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 443 ], gtk_ok=yes, gtk_ok=no)
 444 AC_MSG_RESULT($gtk_ok)
 445 if test "$gtk_ok" = "yes"; then
 446   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 447             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 448 fi
 449
 450 # _NL_PAPER_HEIGHT is an enum and not a define
 451 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 452 AC_TRY_LINK([#include <langinfo.h>], [
 453 char c;
 454 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 455 ], gtk_ok=yes, gtk_ok=no)
 456 AC_MSG_RESULT($gtk_ok)
 457 if test "$gtk_ok" = "yes"; then
 458   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 459             [Define if _NL_PAPER_HEIGHT is available])
 460 fi
 461
 462 # _NL_PAPER_WIDTH is an enum and not a define
 463 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 464 AC_TRY_LINK([#include <langinfo.h>], [
 465 char c;
 466 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 467 ], gtk_ok=yes, gtk_ok=no)
 468 AC_MSG_RESULT($gtk_ok)
 469 if test "$gtk_ok" = "yes"; then
 470   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 471             [Define if _NL_PAPER_WIDTH is available])
 472 fi
 473
 474 # sigsetjmp is a macro on some platforms, so AC_CHECK_FUNCS is not reliable
 475 AC_MSG_CHECKING(for sigsetjmp)
 476 AC_TRY_LINK([#include <setjmp.h>], [
 477 sigjmp_buf env;
 478 sigsetjmp(env, 0);
 479 ], gtk_ok=yes, gtk_ok=no)
 480 AC_MSG_RESULT($gtk_ok)
 481 if test "$gtk_ok" = "yes"; then
 482   AC_DEFINE(HAVE_SIGSETJMP, 1,
 483             [Define to 1 if sigsetjmp is available])
 484 fi
 485
 486 # i18n stuff
 487 # TRANSLATORS:  Please note that gtk+ has both po/ and po-properties/
 488 # directories.  If you add a new language to ALL_LINGUAS, please make
 489 # sure that both po/ and po-properties/ have .po files that correspond
 490 # to your language.  If you only add one to po/, the build will break
 491 # in po-properties/.
 492 ALL_LINGUAS="af am ang ar as az az_IR be be@latin bg bn bn_IN br bs ca ca@valencia cs cy da de dz el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu hy ia id io is it ja ka kn ko ku li lt lv mi mk ml mn mr ms nb ne nl nn nso oc or pa pl ps pt pt_BR ro ru rw si sk sl sq sr sr@Latn sr@ije sv ta te th tk tr tt uk ur uz uz@cyrillic vi wa xh yi zh_CN zh_HK zh_TW"
 493 AM_GLIB_GNU_GETTEXT
 494 LIBS="$LIBS $INTLLIBS"
 495 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 496         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 497       esac])
 498
 499 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 500
 501 dnl The DU4 header files don't provide library prototypes unless
 502 dnl -std1 is given to the native cc.
 503 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 504
 505 gtk_save_LIBS=$LIBS
 506 LIBS="$LIBS -lm"
 507 AC_TRY_RUN([#include <math.h>
 508              int main (void) { return (log(1) != log(1.)); }],
 509      AC_MSG_RESULT(none needed),
 510      gtk_save_CFLAGS="$CFLAGS"
 511      CFLAGS="$CFLAGS -std1"
 512      AC_TRY_RUN([#include <math.h>
 513                  int main (void) { return (log(1) != log(1.)); }],
 514          AC_MSG_RESULT(-std1),
 515          AC_MSG_RESULT()
 516          CFLAGS="$gtk_save_CFLAGS"
 517          AC_MSG_WARN(
 518                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 519          true
 520      ),
 521      AC_MSG_RESULT(none needed)
 522 )
 523 LIBS=$gtk_save_LIBS
 524
 525 AC_MSG_CHECKING(for the BeOS)
 526 case $host in
 527   *-*-beos*)
 528     AC_MSG_RESULT(yes)
 529     MATH_LIB=
 530   ;;
 531   *)
 532     AC_MSG_RESULT(no)
 533   ;;
 534 esac
 535
 536 #
 537 # see bug 162979
 538 #
 539 AC_MSG_CHECKING(for HP-UX)
 540 case $host_os in
 541   hpux9* | hpux10* | hpux11*)
 542     AC_MSG_RESULT(yes)
 543     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 544   ;;
 545   *)
 546     AC_MSG_RESULT(no)
 547   ;;
 548 esac
 549
 550 dnl NeXTStep cc seems to need this
 551 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 552 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 553   AC_MSG_RESULT(none needed),
 554   gtk_save_CFLAGS="$CFLAGS"
 555   CFLAGS="$CFLAGS -posix"
 556   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 557     AC_MSG_RESULT(-posix),
 558     AC_MSG_RESULT()
 559     CFLAGS="$gtk_save_CFLAGS"
 560     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 561
 562 #
 563 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 564 #
 565
 566 GLIB_PACKAGES="gobject-2.0 gmodule-no-export-2.0"
 567
 568 AM_PATH_GLIB_2_0(glib_required_version, :,
 569   AC_MSG_ERROR([
 570 *** GLIB glib_required_version or better is required. The latest version of
 571 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 572   gobject gmodule-no-export gthread)
 573
 574 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 575 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 576 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 577 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 578   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 579 fi
 580
 581
 582 dnl
 583 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 584 dnl
 585 gtk_save_LIBS=$LIBS
 586 LIBS="$LIBS $GLIB_LIBS"
 587 AC_CHECK_FUNCS(bind_textdomain_codeset)
 588 LIBS=$gtk_save_LIBS
 589
 590 AC_CHECK_HEADERS(pwd.h,
 591                  AC_DEFINE(HAVE_PWD_H, 1,
 592                            [Define to 1 if pwd.h is available]))
 593 AC_CHECK_HEADERS(sys/time.h,
 594                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 595                            [Define to 1 if time.h is available]))
 596 AC_CHECK_HEADERS(unistd.h,
 597                  AC_DEFINE(HAVE_UNISTD_H, 1,
 598                            [Define to 1 if unistd.h is available]))
 599 AC_CHECK_HEADERS(ftw.h,
 600                  AC_DEFINE(HAVE_FTW_H, 1,
 601                            [Define to 1 if ftw.h is available]))
 602
 603 AC_MSG_CHECKING([for GNU ftw extensions])
 604 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 605 #define _GNU_SOURCE
 606 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 607 if test $gtk_ok = yes; then
 608     AC_MSG_RESULT([yes])
 609     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 610 else
 611     AC_MSG_RESULT([no])
 612 fi
 613
 614 saved_cflags="$CFLAGS"
 615 saved_ldflags="$LDFLAGS"
 616
 617
 618 # Checks for header files.
 619 AC_HEADER_STDC
 620
 621 # Checks for typedefs, structures, and compiler characteristics.
 622 AC_C_CONST
 623
 624 # Checks for library functions.
 625 AC_TYPE_SIGNAL
 626 AC_FUNC_MMAP
 627
 628 AC_CHECK_FUNCS(mallinfo)
 629 AC_CHECK_FUNCS(getresuid)
 630 AC_TYPE_UID_T
 631
 632 # Check if <sys/select.h> needs to be included for fd_set
 633 AC_MSG_CHECKING([for fd_set])
 634 AC_TRY_COMPILE([#include <sys/types.h>],
 635         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 636 if test $gtk_ok = yes; then
 637     AC_MSG_RESULT([yes, found in sys/types.h])
 638 else
 639     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 640     if test $gtk_ok = yes; then
 641         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 642                   [Define to 1 if sys/select.h is available])
 643         AC_MSG_RESULT([yes, found in sys/select.h])
 644     else
 645         AC_DEFINE(NO_FD_SET, 1,
 646                   [Define to 1 if fd_set is not available])
 647         AC_MSG_RESULT(no)
 648     fi
 649 fi
 650
 651 # `widechar' tests for gdki18n.h
 652 AC_MSG_CHECKING(for wchar.h)
 653 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 654 if test $gdk_wchar_h = yes; then
 655    AC_DEFINE(HAVE_WCHAR_H, 1, [Have wchar.h include file])
 656 fi
 657 AC_MSG_RESULT($gdk_wchar_h)
 658
 659 # Check for wctype.h (for iswalnum)
 660 AC_MSG_CHECKING(for wctype.h)
 661 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 662 if test $gdk_wctype_h = yes; then
 663    AC_DEFINE(HAVE_WCTYPE_H, 1, [Have wctype.h include file])
 664 fi
 665 AC_MSG_RESULT($gdk_wctype_h)
 666
 667 # in Solaris 2.5, `iswalnum' is in -lw
 668 GDK_WLIBS=
 669 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 670
 671 oLIBS="$LIBS"
 672 LIBS="$LIBS $GDK_WLIBS"
 673 # The following is necessary for Linux libc-5.4.38
 674 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 675 AC_TRY_LINK([#include <stdlib.h>],[
 676 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 677 #  ifdef HAVE_WCTYPE_H
 678 #    include <wctype.h>
 679 #  else
 680 #    ifdef HAVE_WCHAR_H
 681 #      include <wchar.h>
 682 #    endif
 683 #  endif
 684 #else
 685 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 686 #endif
 687 iswalnum((wchar_t) 0);
 688 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 689 LIBS="$oLIBS"
 690
 691 if test $gdk_working_wctype = no; then
 692    AC_DEFINE(HAVE_BROKEN_WCTYPE, 1, [Is the wctype implementation broken])
 693    GDK_WLIBS=
 694 fi
 695 AC_MSG_RESULT($gdk_working_wctype)
 696 AC_SUBST(GDK_WLIBS)
 697
 698 # Check for uxtheme.h (for MS-Windows Engine)
 699 AC_MSG_CHECKING(for uxtheme.h)
 700 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 701 if test $gtk_uxtheme_h = yes; then
 702    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 703 fi
 704 AC_MSG_RESULT($gtk_uxtheme_h)
 705
 706 # Checks for gdkspawn
 707 AC_CHECK_HEADERS(crt_externs.h)
 708 AC_CHECK_FUNCS(_NSGetEnviron)
 709
 710
 711 ##################################################
 712 # Checks for gdk-pixbuf
 713 ##################################################
 714
 715 dnl ********************************************************
 716 dnl * See whether we need to load our modules as .la files *
 717 dnl ********************************************************
 718
 719 use_la_modules=false
 720 case $host in
 721   *-aix*) use_la_modules=true
 722 esac
 723
 724 if $use_la_modules ; then
 725    AC_DEFINE(USE_LA_MODULES, 1,
 726              [Whether to load modules via .la files rather than directly])
 727 fi
 728
 729
 730 AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
 731
 732 AC_ARG_ENABLE(modules,
 733               [AC_HELP_STRING([--disable-modules],
 734                               [disable dynamic module loading])])
 735
 736 dynworks=false
 737 deps=
 738 if test x$enable_modules = xno; then
 739     AC_MSG_RESULT(no)
 740 else
 741     AC_MSG_RESULT(yes)
 742     AC_MSG_CHECKING(whether dynamic modules work)
 743     ## for loop is to strip newline
 744     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 745     for I in $tmp; do
 746         dynworks=$I
 747     done
 748
 749     dnl Now we check to see if our libtool supports shared lib deps
 750     dnl (in a rather ugly way even)
 751     if $dynworks; then
 752         pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 753         pixbuf_deplibs_check=`$pixbuf_libtool_config | \
 754             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 755             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 756         if test "x$pixbuf_deplibs_check" = "xnone" || \
 757            test "x$pixbuf_deplibs_check" = "xunknown" || \
 758            test "x$pixbuf_deplibs_check" = "x"; then
 759             dynworks=false
 760         fi
 761     fi
 762
 763     if $dynworks; then
 764         AC_DEFINE(USE_GMODULE, 1,
 765                   [Define to 1 if gmodule works and should be used])
 766         AC_MSG_RESULT(yes)
 767     else
 768         AC_MSG_RESULT(no)
 769     fi
 770 fi
 771
 772 dnl We allow people to disable image loaders explicitely, but if they don't we error
 773 dnl out so that people don't accidentally build without them.
 774
 775 AC_ARG_WITH(libpng,
 776             [AC_HELP_STRING([--without-libpng],
 777                             [disable PNG loader for gdk-pixbuf])])
 778 AC_ARG_WITH(libjpeg,
 779             [AC_HELP_STRING([--without-libjpeg],
 780                             [disable JPEG loader for gdk-pixbuf])])
 781 AC_ARG_WITH(libtiff,
 782             [AC_HELP_STRING([--without-libtiff],
 783                             [disable TIFF loader for gdk-pixbuf])])
 784 AC_ARG_WITH(libjasper,
 785             [AC_HELP_STRING([--without-libjasper],
 786                             [disable JPEG2000 loader for gdk-pixbuf])])
 787
 788 AC_ARG_ENABLE(gdiplus,
 789             [AC_HELP_STRING([--disable-gdiplus-loaders],
 790                             [disable GDI+ loaders for gdk-pixbuf])])
 791
 792 AM_CONDITIONAL(BUILD_GDIPLUS_LOADERS, [ test x$os_win32 = xyes && test x$enable_gdiplus != xno ])
 793
 794 dnl Test for libtiff
 795 if test x$os_win32 = xno || test x$enable_gdiplus = xno; then
 796   if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
 797     AC_CHECK_LIB(tiff, TIFFReadRGBAImageOriented,
 798       [AC_CHECK_HEADER(tiffio.h,
 799         TIFF='tiff'; LIBTIFF='-ltiff',
 800         AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 801       [AC_CHECK_LIB(tiff, TIFFWriteScanline,
 802         [AC_CHECK_HEADER(tiffio.h,
 803           TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
 804           AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 805         [AC_CHECK_LIB(tiff34, TIFFFlushData,
 806           [AC_CHECK_HEADER(tiffio.h,
 807             TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
 808             AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 809         AC_MSG_WARN(*** TIFF loader will not be built (TIFF library not found) ***), -ljpeg -lz -lm)], -ljpeg -lz -lm)], -lm)
 810   fi
 811
 812   if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
 813      AC_MSG_ERROR([
 814 *** Checks for TIFF loader failed. You can build without it by passing
 815 *** --without-libtiff to configure but some programs using GTK+ may
 816 *** not work properly])
 817   fi
 818 fi
 819
 820 dnl Test for libjpeg
 821 if test x$os_win32 = xno || test x$enable_gdiplus = xno; then
 822   if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
 823     AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 824       jpeg_ok=yes,
 825       jpeg_ok=no
 826       AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
 827     if test "$jpeg_ok" = yes; then
 828       AC_MSG_CHECKING([for jpeglib.h])
 829       AC_TRY_CPP(
 830 [#include <stdio.h>
 831 #undef PACKAGE
 832 #undef VERSION
 833 #undef HAVE_STDLIB_H
 834 #include <jpeglib.h>],
 835         jpeg_ok=yes,
 836         jpeg_ok=no)
 837       AC_MSG_RESULT($jpeg_ok)
 838       if test "$jpeg_ok" = yes; then
 839         LIBJPEG='-ljpeg'
 840         AC_CHECK_LIB(jpeg, jpeg_simple_progression,
 841           AC_DEFINE(HAVE_PROGRESSIVE_JPEG, 1,
 842                     [Define to 1 is libjpeg supports progressive JPEG]),
 843           AC_MSG_WARN(JPEG library does not support progressive saving.))
 844       else
 845           AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
 846       fi
 847     fi
 848   fi
 849
 850   if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
 851      AC_MSG_ERROR([
 852 *** Checks for JPEG loader failed. You can build without it by passing
 853 *** --without-libjpeg to configure but some programs using GTK+ may
 854 *** not work properly])
 855   fi
 856 fi
 857
 858 dnl Test for libpng
 859   if test x$with_libpng != xno && test -z "$LIBPNG"; then
 860     AC_MSG_CHECKING(for libpng12)
 861     if $PKG_CONFIG --exists libpng12 ; then
 862         AC_MSG_RESULT(yes)
 863         PNG='png'
 864         PNG_DEP_CFLAGS_PACKAGES=libpng12
 865         LIBPNG=`$PKG_CONFIG --libs libpng12`
 866     else
 867       AC_MSG_RESULT(no)
 868       AC_CHECK_LIB(png, png_read_info,
 869         [AC_CHECK_HEADER(png.h,
 870           png_ok=yes,
 871           png_ok=no)],
 872         AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
 873       if test "$png_ok" = yes; then
 874         AC_MSG_CHECKING([for png_structp in png.h])
 875         AC_TRY_COMPILE([#include <png.h>],
 876           [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 877           png_ok=yes,
 878           png_ok=no)
 879         AC_MSG_RESULT($png_ok)
 880         if test "$png_ok" = yes; then
 881           PNG='png'; LIBPNG='-lpng -lz'
 882         else
 883           AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
 884         fi
 885       else
 886        AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
 887       fi
 888     fi
 889   fi
 890
 891   if test x$with_libpng != xno && test -z "$LIBPNG"; then
 892      AC_MSG_ERROR([
 893 *** Checks for PNG loader failed. You can build without it by passing
 894 *** --without-libpng to configure but many programs using GTK+ will
 895 *** not work properly. The PNG loader is also needed if you are compiling
 896 *** from CVS.])
 897   fi
 898
 899 dnl Test for libjasper
 900   if test x$with_libjasper != xno && test -z "$LIBJASPER"; then
 901     AC_CHECK_LIB(jasper, jas_init, LIBJASPER=-ljasper, [], -ljpeg)
 902   fi
 903
 904   if test x$with_libjasper != xno && test -z "$LIBJASPER"; then
 905      AC_MSG_ERROR([
 906 *** Checks for JPEG2000 loader failed. You can build without it by passing
 907 *** --without-libjasper to configure])
 908   fi
 909
 910 AC_SUBST(LIBTIFF)
 911 AC_SUBST(LIBJPEG)
 912 AC_SUBST(LIBPNG)
 913 AC_SUBST(LIBJASPER)
 914
 915 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 916
 917 #
 918 # Allow building some or all gdk-pixbuf loaders included
 919 #
 920 AC_MSG_CHECKING(pixbuf loaders to build)
 921
 922 dnl due to an autoconf bug, commas in the first arg to
 923 dnl AC_HELP_STRING cause problems.
 924 dnl AC_HELP_STRING([--with-included-loaders=LOADER1 LOADER2 ...],
 925 dnl                [build the specified loaders into gdk-pixbuf])
 926 AC_ARG_WITH(included_loaders,
 927 [  --with-included-loaders=LOADER1,LOADER2,...
 928                           build the specified loaders into gdk-pixbuf])
 929
 930 if $dynworks; then
 931    :
 932 else
 933    ## if the option was specified, leave it; otherwise disable included loaders
 934    if test x$with_included_loaders = xno; then
 935            with_included_loaders=yes
 936    fi
 937 fi
 938
 939 # Use the traditional png loader instead of the GDI+ one on Windows,
 940 # because some important apps like GIMP need to read and write
 941 # arbitrary tEXt chunks which doesn't seem to be possible through GDI+
 942
 943 all_loaders="ani,icns,pcx,ras,tga,png,pnm,wbmp,xbm,xpm"
 944 if test x$with_libjasper != xno; then
 945   all_loaders="$all_loaders,jasper"
 946 fi
 947 if test x$os_win32 = xyes && test x$enable_gdiplus != xno; then
 948   # Skip PNG, see comment above
 949   gdip_formats="bmp emf gif ico jpeg tiff wmf"
 950   for f in $gdip_formats; do
 951     all_loaders="$all_loaders,gdip-$f"
 952   done
 953 else
 954   all_loaders="$all_loaders,bmp,gif,ico,jpeg,tiff"
 955 fi
 956 included_loaders=""
 957 # If no loaders specified, include all
 958 if test "x$with_included_loaders" = xyes ; then
 959   included_loaders="$all_loaders"
 960 else
 961   included_loaders="$with_included_loaders"
 962 fi
 963
 964 AC_MSG_RESULT($included_loaders)
 965
 966 INCLUDED_LOADER_OBJ=
 967 INCLUDED_LOADER_DEFINE=
 968
 969 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 970 for loader in $included_loaders; do
 971  if echo "$all_loaders" | egrep "(^|,)$loader(\$|,)" > /dev/null; then
 972    :
 973  else
 974    AC_MSG_ERROR([the specified loader $loader does not exist])
 975  fi
 976
 977  loader_underscores=`echo $loader | sed -e 's/-/_/g'`
 978  INCLUDED_LOADER_OBJ="$INCLUDED_LOADER_OBJ libstatic-pixbufloader-$loader.la"
 979
 980  # Don't bother defining separate -DINCLUDE_gdip_foo for each gdip-foo loader
 981  case $loader in
 982    gdip-*) ;;
 983    *) INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_$loader_underscores";;
 984  esac
 985  eval INCLUDE_$loader_underscores=yes
 986 done
 987
 988 # Just define one -DINCLUDE_gdiplus for all the gdip-foo loaders
 989 # (except gdip-png, which isn't built at all)
 990 if test x"$INCLUDE_gdip_ico" = xyes; then
 991   INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_gdiplus"
 992 fi
 993
 994 IFS="$gtk_save_ifs"
 995 AC_SUBST(INCLUDED_LOADER_OBJ)
 996 AC_SUBST(INCLUDED_LOADER_DEFINE)
 997
 998 AM_CONDITIONAL(INCLUDE_PNG, [test x"$INCLUDE_png" = xyes])
 999 AM_CONDITIONAL(INCLUDE_BMP, [test x"$INCLUDE_bmp" = xyes])
1000 AM_CONDITIONAL(INCLUDE_WBMP, [test x"$INCLUDE_wbmp" = xyes])
1001 AM_CONDITIONAL(INCLUDE_GIF, [test x"$INCLUDE_gif" = xyes])
1002 AM_CONDITIONAL(INCLUDE_ICO, [test x"$INCLUDE_ico" = xyes])
1003 AM_CONDITIONAL(INCLUDE_ANI, [test x"$INCLUDE_ani" = xyes])
1004 AM_CONDITIONAL(INCLUDE_JPEG, [test x"$INCLUDE_jpeg" = xyes])
1005 AM_CONDITIONAL(INCLUDE_PNM, [test x"$INCLUDE_pnm" = xyes])
1006 AM_CONDITIONAL(INCLUDE_RAS, [test x"$INCLUDE_ras" = xyes])
1007 AM_CONDITIONAL(INCLUDE_TIFF, [test x"$INCLUDE_tiff" = xyes])
1008 AM_CONDITIONAL(INCLUDE_XPM, [test x"$INCLUDE_xpm" = xyes])
1009 AM_CONDITIONAL(INCLUDE_XBM, [test x"$INCLUDE_xbm" = xyes])
1010 AM_CONDITIONAL(INCLUDE_TGA, [test x"$INCLUDE_tga" = xyes])
1011 AM_CONDITIONAL(INCLUDE_PCX, [test x"$INCLUDE_pcx" = xyes])
1012 AM_CONDITIONAL(INCLUDE_ICNS, [test x"$INCLUDE_icns" = xyes])
1013 AM_CONDITIONAL(INCLUDE_JASPER, [test x"$INCLUDE_jasper" = xyes])
1014 # As all GDI+ loaders are either built-in or not, arbitrarily just
1015 # check one of the variables here
1016 AM_CONDITIONAL(INCLUDE_GDIPLUS, [test x"$INCLUDE_gdip_ico" = xyes])
1017
1018 AC_MSG_CHECKING([if gio can sniff png])
1019 gtk_save_LIBS="$LIBS"
1020 gtk_save_CFLAGS="$CFLAGS"
1021 LIBS="`$PKG_CONFIG --libs gio-2.0`"
1022 CFLAGS="`$PKG_CONFIG --cflags gio-2.0`"
1023 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1024 #include <gio/gio.h>
1025 static const gsize data_size = 159;
1026 static const guint8 data[] =
1027 {
1028   0x89, 0x50, 0x4e, 0x47, 0x0d, 0x0a, 0x1a, 0x0a, 0x00, 0x00, 0x00, 0x0d,
1029   0x49, 0x48, 0x44, 0x52, 0x00, 0x00, 0x00, 0x01, 0x00, 0x00, 0x00, 0x01,
1030   0x08, 0x02, 0x00, 0x00, 0x00, 0x90, 0x77, 0x53, 0xde, 0x00, 0x00, 0x00,
1031   0x01, 0x73, 0x52, 0x47, 0x42, 0x00, 0xae, 0xce, 0x1c, 0xe9, 0x00, 0x00,
1032   0x00, 0x09, 0x70, 0x48, 0x59, 0x73, 0x00, 0x00, 0x0b, 0x13, 0x00, 0x00,
1033   0x0b, 0x13, 0x01, 0x00, 0x9a, 0x9c, 0x18, 0x00, 0x00, 0x00, 0x07, 0x74,
1034   0x49, 0x4d, 0x45, 0x07, 0xd8, 0x07, 0x0f, 0x10, 0x08, 0x15, 0x61, 0xd8,
1035   0x35, 0x37, 0x00, 0x00, 0x00, 0x19, 0x74, 0x45, 0x58, 0x74, 0x43, 0x6f,
1036   0x6d, 0x6d, 0x65, 0x6e, 0x74, 0x00, 0x43, 0x72, 0x65, 0x61, 0x74, 0x65,
1037   0x64, 0x20, 0x77, 0x69, 0x74, 0x68, 0x20, 0x47, 0x49, 0x4d, 0x50, 0x57,
1038   0x81, 0x0e, 0x17, 0x00, 0x00, 0x00, 0x0c, 0x49, 0x44, 0x41, 0x54, 0x08,
1039   0xd7, 0x63, 0xf8, 0xff, 0xff, 0x3f, 0x00, 0x05, 0xfe, 0x02, 0xfe, 0xdc,
1040   0xcc, 0x59, 0xe7, 0x00, 0x00, 0x00, 0x00, 0x49, 0x45, 0x4e, 0x44, 0xae,
1041   0x42, 0x60, 0x82
1042 };
1043 int
1044 main (int argc, char **argv)
1045 {
1046   char *content_type;
1047   content_type = g_content_type_guess (NULL, data, data_size, NULL);
1048   return strcmp (content_type, "image/png");
1049 }]])],
1050   [gio_can_sniff=yes
1051    AC_DEFINE(GDK_PIXBUF_USE_GIO_MIME, 1, [Define if gio can sniff image data])],
1052   [gio_can_sniff=no])
1053 AC_MSG_RESULT($gio_can_sniff)
1054 LIBS="$gtk_save_LIBS"
1055 CFLAGS="$gtk_save_CFLAGS"
1056
1057 #
1058 # Allow building some or all immodules included
1059 #
1060 AC_MSG_CHECKING(immodules to build)
1061
1062 dnl due to an autoconf bug, commas in the first arg to
1063 dnl AC_HELP_STRING cause problems.
1064 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
1065 dnl                [build the specified input method modules into gtk])
1066 AC_ARG_WITH(included_immodules,
1067 [  --with-included-immodules=MODULE1,MODULE2,...
1068                           build the specified input methods into gtk])
1069
1070 if $dynworks; then
1071    :
1072 else
1073    ## if the option was specified, leave it; otherwise disable included immodules
1074    if test x$with_included_immodules = xno; then
1075            with_included_immodules=yes
1076    fi
1077 fi
1078
1079 all_immodules="am-et,cedilla,cyrillic-translit"
1080 if test "$gdktarget" = "win32"; then
1081    all_immodules="${all_immodules},ime"
1082 fi
1083 all_immodules="${all_immodules},inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr"
1084 if test "$gdktarget" = "x11"; then
1085    all_immodules="${all_immodules},xim"
1086 fi
1087
1088 included_immodules=""
1089 # If the switch specified without listing any specific ones, include all
1090 if test "x$with_included_immodules" = xyes ; then
1091   included_immodules="$all_immodules"
1092 else
1093   included_immodules="$with_included_immodules"
1094 fi
1095
1096 AC_MSG_RESULT($included_immodules)
1097 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
1098
1099 INCLUDED_IMMODULE_OBJ=
1100 INCLUDED_IMMODULE_DEFINE=
1101
1102 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
1103 for immodule in $included_immodules; do
1104  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
1105  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
1106    :
1107  else
1108    AC_MSG_ERROR([the specified input method $immodule does not exist])
1109  fi
1110
1111  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
1112  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
1113  eval INCLUDE_$immodule_underscores=yes
1114 done
1115 IFS="$gtk_save_ifs"
1116 AC_SUBST(INCLUDED_IMMODULE_OBJ)
1117 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
1118
1119 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
1120 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
1121 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
1122 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
1123 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
1124 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
1125 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
1126 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
1127 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
1128 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
1129 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
1130 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
1131
1132 AC_HEADER_SYS_WAIT
1133
1134 AC_TYPE_SIGNAL
1135
1136 AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
1137 AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
1138 AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
1139 AM_CONDITIONAL(HAVE_JASPER, test "x$LIBJASPER" != x)
1140
1141 if $dynworks ; then
1142   STATIC_LIB_DEPS=
1143   if echo "$included_loaders" | egrep '(^|,)tiff($|,)' > /dev/null; then
1144     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBTIFF"
1145   fi
1146   if echo "$included_loaders" | egrep '(^|,)jpeg($|,)' > /dev/null; then
1147     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBJPEG"
1148   fi
1149   if echo "$included_loaders" | egrep '(^|,)png($|,)' > /dev/null; then
1150     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBPNG"
1151   fi
1152 else
1153   STATIC_LIB_DEPS="$LIBTIFF $LIBJPEG $LIBPNG"
1154 fi
1155
1156 # Checks to see whether we should include mediaLib
1157 # support.
1158 #
1159 AC_CHECK_HEADER(sys/systeminfo.h,
1160                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
1161                           [Define to 1 if sys/systeminfo.h is available]))
1162 AC_CHECK_HEADER(sys/sysinfo.h,
1163                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
1164                           [Define to 1 if sys/sysinfo.h is available]))
1165
1166 AC_MSG_CHECKING(for mediaLib 2.3)
1167 use_mlib25=no
1168 # Check for a mediaLib 2.3 function since that is what the GTK+ mediaLib
1169 # patch requires.
1170 AC_CHECK_LIB(mlib, mlib_ImageSetStruct, use_mlib=yes, use_mlib=no)
1171 if test $use_mlib = yes; then
1172     AC_DEFINE(USE_MEDIALIB, 1,
1173               [Define to 1 if medialib is available and should be used])
1174     MEDIA_LIB=-lmlib
1175
1176     AC_MSG_CHECKING(for mediaLib 2.5)
1177     # Check for a mediaLib 2.5 function since that is what is needed for
1178     # gdk_rgb_convert integration.
1179     AC_CHECK_LIB(mlib, mlib_VideoColorRGBint_to_BGRAint, use_mlib25=yes, use_mlib25=no)
1180     if test $use_mlib25 = yes; then
1181         AC_DEFINE(USE_MEDIALIB25, 1,
1182                   [Define to 1 if medialib 2.5 is available])
1183     fi
1184 fi
1185 AM_CONDITIONAL(USE_MEDIALIB, test $use_mlib = yes)
1186 AM_CONDITIONAL(USE_MEDIALIB25, test $use_mlib25 = yes)
1187
1188 # Checks to see if we should compile in MMX support (there will be
1189 # a runtime test when the code is actually run to see if it should
1190 # be used - this just checks if we can compile it.)
1191 #
1192 # This code is partially taken from Mesa
1193 #
1194 AC_MSG_CHECKING(for x86 platform)
1195 case $host_cpu in
1196   i386|i486|i586|i686|i786|k6|k7)
1197         use_x86_asm=yes
1198         ;;
1199    *)
1200         use_x86_asm=no
1201 esac
1202 AC_MSG_RESULT($use_x86_asm)
1203
1204 use_mmx_asm=no
1205 if test $use_x86_asm = yes; then
1206     save_ac_ext=$ac_ext
1207     ac_ext=S
1208
1209     AC_MSG_CHECKING(compiler support for MMX)
1210     cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
1211     if AC_TRY_EVAL(ac_compile); then
1212         use_mmx_asm=yes
1213     fi
1214
1215     rm -rf conftest*
1216
1217     ac_ext=$save_ac_ext
1218     if test $use_mmx_asm = yes; then
1219       AC_DEFINE(USE_MMX, 1,
1220                 [Define to 1 if XXM is available and should be used])
1221       AC_MSG_RESULT(yes)
1222     else
1223       AC_MSG_RESULT(no)
1224     fi
1225 fi
1226
1227 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
1228
1229 REBUILD_PNGS=
1230 if test -z "$LIBPNG" && test x"$os_win32" = xno -o x$enable_gdiplus = xno; then
1231   REBUILD_PNGS=#
1232 fi
1233
1234 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
1235
1236 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
1237
1238 if test $cross_compiling = yes; then
1239   AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
1240   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
1241   if test x$GTK_UPDATE_ICON_CACHE = xno; then
1242     REBUILD_PNGS=#
1243   fi
1244 fi
1245
1246 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
1247    test "x$REBUILD_PNGS" = "x#" ; then
1248      AC_MSG_ERROR([
1249 *** gtkbuiltincache.h is not in the tree, and cannot be built
1250 *** because you don't have libpng, or (when cross-compiling) you
1251 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
1252 fi
1253
1254 AC_SUBST(REBUILD_PNGS)
1255
1256 GDK_PIXBUF_PACKAGES="gmodule-no-export-2.0 gobject-2.0 gio-2.0"
1257 GDK_PIXBUF_EXTRA_LIBS="$STATIC_LIB_DEPS $MATH_LIB $MEDIA_LIB"
1258 GDK_PIXBUF_EXTRA_CFLAGS=
1259 GDK_PIXBUF_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
1260 GDK_PIXBUF_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $PNG_DEP_CFLAGS_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS"
1261
1262 ########################################
1263 # Windowing system checks
1264 ########################################
1265
1266 GDK_PIXBUF_XLIB_PACKAGES=
1267 GDK_PIXBUF_XLIB_EXTRA_CFLAGS=
1268 GDK_PIXBUF_XLIB_EXTRA_LIBS=
1269
1270 X_PACKAGES=fontconfig
1271 GDK_EXTRA_LIBS="$GDK_WLIBS"
1272 GDK_EXTRA_CFLAGS=
1273
1274 # GTK+ uses some X calls, so needs to link against X directly
1275 GTK_DEP_PACKAGES_FOR_X=
1276 GTK_DEP_LIBS_FOR_X=
1277
1278 if test "x$gdktarget" = "xx11"; then
1279   #
1280   # We use fontconfig very peripherally when decoding the default
1281   # settings.
1282   #
1283   if $PKG_CONFIG --exists fontconfig; then : ; else
1284     AC_MSG_ERROR([
1285 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
1286   fi
1287
1288   #
1289   # Check for basic X packages; we use pkg-config if available
1290   #
1291   if $PKG_CONFIG --exists x11 xext xrender; then
1292     have_base_x_pc=true
1293     X_PACKAGES="$X_PACKAGES x11 xext xrender"
1294     x_libs="`$PKG_CONFIG --libs x11 xext xrender`"
1295     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext xrender`"
1296
1297     # Strip out any .la files that pkg-config might give us (this happens
1298     # with -uninstalled.pc files)
1299     x_libs_for_checks=
1300     for I in $x_libs ; do
1301       case $I in
1302         *.la) ;;
1303         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
1304       esac
1305     done
1306
1307     GDK_PIXBUF_XLIB_PACKAGES="x11"
1308     GTK_PACKAGES_FOR_X="x11"
1309   else
1310     have_base_x_pc=false
1311     AC_PATH_XTRA
1312     if test x$no_x = xyes ; then
1313       AC_MSG_ERROR([X development libraries not found])
1314     fi
1315
1316     x_cflags="$X_CFLAGS"
1317     x_libs_for_checks="$X_LIBS -lXext -lXrender -lX11 $X_EXTRA_LIBS"
1318
1319     GDK_PIXBUF_XLIB_EXTRA_CFLAGS="$x_cflags"
1320     GDK_PIXBUF_XLIB_EXTRA_LIBS="$X_LIBS -lX11 $X_EXTRA_LIBS"
1321     GTK_DEP_LIBS_FOR_X="$X_LIBS -lXrender -lX11 $X_EXTRA_LIBS"
1322   fi
1323
1324   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
1325   x_extra_libs=
1326
1327   gtk_save_cppflags="$CPPFLAGS"
1328   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1329
1330   gtk_save_LIBS=$LIBS
1331   LIBS="$x_libs_for_checks $LIBS"
1332
1333   # Sanity check for the X11 and Xext libraries. While everything we need from
1334   # Xext is optional, the chances a system has *none* of these things is so
1335   # small that we just unconditionally require it.
1336   AC_CHECK_FUNC(XOpenDisplay, :,
1337                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
1338   AC_CHECK_FUNC(XextFindDisplay, :,
1339                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
1340   AC_CHECK_FUNC(XRenderQueryExtension, :,
1341                 AC_MSG_ERROR([*** libXrender not found. Check 'config.log' for more details.]))
1342
1343   # Check for xReply
1344
1345   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
1346   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
1347       [xReply *rep;],
1348       [AC_MSG_RESULT([no])],
1349       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
1350 #include <X11/Xlibint.h>],
1351            [xReply *rep;],
1352            [AC_MSG_RESULT([yes])
1353             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
1354                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
1355            [AC_MSG_RESULT([unknown])
1356             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1357
1358   # Check for XConvertCase, XInternAtoms (X11R6 specific)
1359
1360   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
1361
1362   # Generic X11R6 check needed for XIM support; we could
1363   # probably use this to replace the above, but we'll
1364   # leave the separate checks for XConvertCase and XInternAtoms
1365   # for clarity
1366
1367   have_x11r6=false
1368   AC_CHECK_FUNC(XAddConnectionWatch,
1369       have_x11r6=true)
1370
1371   if $have_x11r6; then
1372     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1373   fi
1374   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1375
1376   # Check for XKB support.
1377
1378   if test "x$enable_xkb" = "xyes"; then
1379         AC_MSG_WARN(XKB support explicitly enabled)
1380         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
1381   elif test "x$enable_xkb" = "xmaybe"; then
1382         AC_CHECK_FUNC(XkbQueryExtension,
1383                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1384   else
1385         AC_MSG_WARN(XKB support explicitly disabled)
1386   fi
1387
1388   # Check for shaped window extension
1389
1390   AC_CHECK_FUNC(XShapeCombineMask,
1391       AC_DEFINE(HAVE_SHAPE_EXT, 1,
1392                 [Define to 1 if the XShape extension is available]))
1393
1394   # X SYNC check
1395   gtk_save_CFLAGS="$CFLAGS"
1396   CFLAGS="$CFLAGS $x_cflags"
1397
1398   AC_CHECK_FUNC(XSyncQueryExtension,
1399       [AC_CHECK_HEADER(X11/extensions/sync.h,
1400           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1401           :, [#include <X11/Xlib.h>])])
1402
1403   CFLAGS="$gtk_save_CFLAGS"
1404
1405   # Xshm checks
1406
1407   if test "x$enable_shm" = "xyes"; then
1408      # Check for the XShm extension, normally in Xext
1409      AC_CHECK_FUNC(XShmAttach,
1410         :,
1411         # On AIX, it is in XextSam instead
1412         [AC_CHECK_LIB(XextSam, XShmAttach,
1413             [GTK_ADD_LIB(x_extra_libs,XextSam)])])
1414   fi
1415
1416   if test "x$enable_shm" = "xyes"; then
1417     # Check for shared memory
1418     AC_CHECK_HEADER(sys/ipc.h,
1419                     AC_DEFINE(HAVE_IPC_H, 1,
1420                               [Define to 1 if ipc.h is available]),
1421                     no_sys_ipc=yes)
1422     AC_CHECK_HEADER(sys/shm.h,
1423                     AC_DEFINE(HAVE_SHM_H, 1,
1424                               [Define to 1 if shm.h is available]),
1425                     no_sys_shm=yes)
1426
1427     # Check for the X shared memory extension header file
1428     have_xshm=no
1429     AC_MSG_CHECKING(X11/extensions/XShm.h)
1430     if test "x$no_xext_lib" = "xyes"; then
1431       :
1432     else
1433       gtk_save_CFLAGS="$CFLAGS"
1434       CFLAGS="$CFLAGS $x_cflags"
1435       AC_TRY_COMPILE([
1436 #include <stdlib.h>
1437 #include <sys/types.h>
1438 #include <sys/ipc.h>
1439 #include <sys/shm.h>
1440 #include <X11/Xlib.h>
1441 #include <X11/Xutil.h>
1442 #include <X11/extensions/XShm.h>
1443 ], [XShmSegmentInfo *x_shm_info;], have_xshm=yes)
1444       CFLAGS="$gtk_save_CFLAGS"
1445     fi
1446     AC_MSG_RESULT($have_xshm)
1447     if test $have_xshm = yes ; then
1448       AC_DEFINE(HAVE_XSHM_H, 1,
1449                 [Define to 1 if xshm.h is available])
1450     fi
1451   fi
1452
1453   if test "x$enable_xinerama" = "xyes"; then
1454     # Check for Xinerama extension (Solaris impl or Xfree impl)
1455     gtk_save_cppflags="$CPPFLAGS"
1456     CPPFLAGS="$CPPFLAGS $x_cflags"
1457
1458     case "$host" in
1459       *-*-solaris*)
1460           # Check for solaris
1461           AC_MSG_CHECKING(for Xinerama support on Solaris)
1462
1463           have_solaris_xinerama=false
1464           AC_CHECK_FUNC(XineramaGetInfo,
1465               [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1466                   [have_solaris_xinerama=true], :,
1467                   [#include <X11/Xlib.h>])])
1468
1469           if $have_solaris_xinerama ; then
1470             AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1471                       [Define to 1 if solaris xinerama is available])
1472             AC_DEFINE(HAVE_XINERAMA, 1,
1473                       [Define to 1 if xinerama is available])
1474             AC_MSG_RESULT(yes)
1475           else
1476             AC_MSG_RESULT(no)
1477           fi
1478           ;;
1479       *)
1480           # Check for XFree
1481           AC_MSG_CHECKING(for Xinerama support on XFree86)
1482
1483           have_xfree_xinerama=false
1484           if $PKG_CONFIG --exists xinerama ; then
1485              have_xfree_xinerama=true
1486              X_PACKAGES="$X_PACKAGES xinerama"
1487           else
1488               AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1489                   [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1490                       [GTK_ADD_LIB(x_extra_libs,Xinerama)
1491                       have_xfree_xinerama=true], :,
1492                       [#include <X11/Xlib.h>])])
1493           fi
1494
1495           if $have_xfree_xinerama ; then
1496             AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1497                       [Define to 1 if XFree Xinerama is available])
1498             AC_DEFINE(HAVE_XINERAMA, 1,
1499                       [Define to 1 is Xinerama is available])
1500             AC_MSG_RESULT(yes)
1501          else
1502             AC_MSG_RESULT(no)
1503          fi
1504          ;;
1505     esac
1506   fi
1507
1508   # set up things for XInput
1509
1510   if test "x$with_xinput" = "xxfree" || test "x$with_xinput" = "xyes"; then
1511     AC_DEFINE(XINPUT_XFREE, 1,
1512               [Define to 1 if XFree XInput should be used])
1513
1514     if $PKG_CONFIG --exists xi ; then
1515       X_PACKAGES="$X_PACKAGES xi"
1516     else
1517       GTK_ADD_LIB(x_extra_libs, Xi)
1518     fi
1519   else
1520     AC_DEFINE(XINPUT_NONE, 1,
1521               [Define to 1 if no XInput should be used])
1522   fi
1523
1524   AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree || test x$with_xinput = xyes)
1525
1526   # Check for the RANDR extension
1527   if $PKG_CONFIG --exists "xrandr >= 1.2" ; then
1528      AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1529
1530      X_PACKAGES="$X_PACKAGES xrandr"
1531   fi
1532
1533   # Checks for Xcursor library
1534
1535   if $PKG_CONFIG --exists xcursor ; then
1536     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1537
1538     X_PACKAGES="$X_PACKAGES xcursor"
1539   fi
1540
1541   # Checks for XFixes extension
1542
1543   if $PKG_CONFIG --exists xfixes ; then
1544     AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1545
1546     X_PACKAGES="$X_PACKAGES xfixes"
1547     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1548   fi
1549
1550   # Checks for Xcomposite extension
1551
1552   if $PKG_CONFIG --exists xcomposite ; then
1553     AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1554
1555     X_PACKAGES="$X_PACKAGES xcomposite"
1556     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1557   fi
1558
1559   # Checks for Xdamage extension
1560
1561   if $PKG_CONFIG --exists xdamage ; then
1562     AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1563
1564     X_PACKAGES="$X_PACKAGES xdamage"
1565     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1566   fi
1567
1568   if $have_base_x_pc ; then
1569     GDK_EXTRA_LIBS="$x_extra_libs"
1570   else
1571     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1572   fi
1573
1574   CPPFLAGS="$gtk_save_cppflags"
1575   LIBS="$gtk_save_libs"
1576
1577   AM_CONDITIONAL(USE_X11, true)
1578 else
1579   AM_CONDITIONAL(XINPUT_XFREE, false)
1580   AM_CONDITIONAL(USE_X11, false)
1581   AM_CONDITIONAL(HAVE_X11R6, false)
1582 fi
1583
1584 if test "x$gdktarget" = "xwin32"; then
1585   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
1586   AM_CONDITIONAL(USE_WIN32, true)
1587 else
1588   AM_CONDITIONAL(USE_WIN32, false)
1589 fi
1590
1591 if test "x$gdktarget" = "xquartz"; then
1592   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
1593   AM_CONDITIONAL(USE_QUARTZ, true)
1594 else
1595   AM_CONDITIONAL(USE_QUARTZ, false)
1596 fi
1597
1598 GDK_PIXBUF_XLIB_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_XLIB_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
1599 GDK_PIXBUF_XLIB_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_PIXBUF_XLIB_EXTRA_CFLAGS"
1600
1601 AC_SUBST(GDK_PIXBUF_XLIB_PACKAGES)
1602 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_LIBS)
1603 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_CFLAGS)
1604 AC_SUBST(GDK_PIXBUF_XLIB_DEP_LIBS)
1605 AC_SUBST(GDK_PIXBUF_XLIB_DEP_CFLAGS)
1606
1607 if test "x$gdktarget" = "xdirectfb"; then
1608   DIRECTFB_REQUIRED_VERSION=0.9.24
1609   AC_MSG_CHECKING(for DirectFB)
1610
1611   if $PKG_CONFIG --atleast-version $DIRECTFB_REQUIRED_VERSION directfb && $PKG_CONFIG --exists cairo-directfb ; then
1612       AC_MSG_RESULT(found)
1613       GDK_EXTRA_CFLAGS="`$PKG_CONFIG --cflags cairo-directfb` $GDK_EXTRA_CFLAGS"
1614       GDK_EXTRA_LIBS="`$PKG_CONFIG --libs cairo-directfb` $GDK_EXTRA_LIBS"
1615   else
1616       AC_MSG_ERROR([
1617 *** DirectFB $DIRECTFB_REQUIRED_VERSION or newer and the cairo backend
1618 *** are required. The latest version of DirectFB is always available
1619 *** from http://www.directfb.org/.
1620   ])
1621   fi
1622
1623   AM_CONDITIONAL(USE_DIRECTFB, true)
1624 else
1625   AM_CONDITIONAL(USE_DIRECTFB, false)
1626 fi
1627
1628
1629 # Check for Pango flags
1630
1631 if test "x$gdktarget" = "xwin32"; then
1632         PANGO_PACKAGES="pangowin32 pangocairo"
1633 else
1634         PANGO_PACKAGES="pango pangocairo"
1635 fi
1636
1637 AC_MSG_CHECKING(Pango flags)
1638 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1639         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1640         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1641
1642         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1643 else
1644         AC_MSG_ERROR([
1645 *** Pango not found. Pango built with Cairo support is required
1646 *** to build GTK+. See http://www.pango.org for Pango information.
1647 ])
1648 fi
1649
1650 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1651
1652 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1653         :
1654 else
1655         gtk_save_LIBS="$LIBS"
1656         LIBS="$PANGO_LIBS $LIBS"
1657         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1658 *** Can't link to Pango. Pango is required to build
1659 *** GTK+. For more information see http://www.pango.org]))
1660         LIBS="$gtk_save_LIBS"
1661 fi
1662
1663 CFLAGS="$saved_cflags"
1664 LDFLAGS="$saved_ldflags"
1665
1666 GDK_PACKAGES="$PANGO_PACKAGES gio-2.0"
1667 if test "x$gdktarget" = "xx11"; then
1668   GDK_PACKAGES="$GDK_PACKAGES $X_PACKAGES"
1669 fi
1670 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
1671 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS"
1672
1673 #
1674 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1675 # into the pkg-config files
1676 #
1677 if test $enable_explicit_deps != yes ; then
1678   GDK_PACKAGES="$PANGO_PACKAGES"
1679   GDK_EXTRA_LIBS=
1680 fi
1681
1682 AC_SUBST(GDK_PACKAGES)
1683 AC_SUBST(GDK_EXTRA_LIBS)
1684 AC_SUBST(GDK_EXTRA_CFLAGS)
1685 AC_SUBST(GDK_DEP_LIBS)
1686 AC_SUBST(GDK_DEP_CFLAGS)
1687
1688
1689 ########################################
1690 # Check for Accessibility Toolkit flags
1691 ########################################
1692
1693 ATK_PACKAGES=atk
1694 AC_MSG_CHECKING(ATK flags)
1695 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1696         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1697         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1698
1699         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1700 else
1701         AC_MSG_ERROR([
1702 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1703 *** to build GTK+.
1704 ])
1705 fi
1706
1707 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1708         :
1709 else
1710         gtk_save_LIBS="$LIBS"
1711         LIBS="$ATK_LIBS $LIBS"
1712         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1713                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1714                 *** to build GTK+]))
1715         LIBS="$gtk_save_LIBS"
1716 fi
1717
1718 GTK_PACKAGES="atk cairo gio-2.0"
1719 if test "x$gdktarget" = "xx11"; then
1720   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1721 fi
1722 GTK_EXTRA_LIBS=
1723 GTK_EXTRA_CFLAGS=
1724 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
1725 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1726
1727 if test x"$os_win32" = xyes; then
1728   GTK_EXTRA_CFLAGS="$msnative_struct"
1729 fi
1730
1731 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1732 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1733 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1734 CAIRO_PREFIX="`pkg-config --variable=prefix cairo`"
1735
1736 if test $enable_explicit_deps != yes ; then
1737   GDK_PIXBUF_EXTRA_LIBS=
1738 fi
1739
1740 AC_SUBST(GDK_PIXBUF_PACKAGES)
1741 AC_SUBST(GDK_PIXBUF_EXTRA_LIBS)
1742 AC_SUBST(GDK_PIXBUF_EXTRA_CFLAGS)
1743 AC_SUBST(GDK_PIXBUF_DEP_LIBS)
1744 AC_SUBST(GDK_PIXBUF_DEP_CFLAGS)
1745
1746 AC_SUBST(GTK_PACKAGES)
1747 AC_SUBST(GTK_EXTRA_LIBS)
1748 AC_SUBST(GTK_EXTRA_CFLAGS)
1749 AC_SUBST(GTK_DEP_LIBS)
1750 AC_SUBST(GTK_DEP_CFLAGS)
1751
1752 AC_SUBST(GLIB_PREFIX)
1753 AC_SUBST(ATK_PREFIX)
1754 AC_SUBST(PANGO_PREFIX)
1755 AC_SUBST(CAIRO_PREFIX)
1756
1757 AC_SUBST(GTK_DEBUG_FLAGS)
1758 AC_SUBST(GTK_XIM_FLAGS)
1759
1760 ########################
1761 # Checks needed for gail
1762 ########################
1763
1764 old_LIBS="$LIBS"
1765 dnl Checks for inet libraries:
1766 AC_SEARCH_LIBS(gethostent, nsl)
1767 AC_SEARCH_LIBS(setsockopt, socket)
1768 AC_SEARCH_LIBS(connect, inet)
1769
1770 dnl check for the sockaddr_un.sun_len member
1771 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1772                 [struct_sockaddr_un_sun_len=true],
1773                 [struct_sockaddr_un_suin_len=false],
1774                 [#include <sys/types.h>
1775                  #include <sys/un.h>]
1776                 )
1777 case $struct_sockaddr_un_sun_len in
1778         true)
1779                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1780                                    [Have the sockaddr_un.sun_len member])
1781                 ;;
1782         *)
1783                 ;;
1784 esac
1785
1786 GAIL_INET_LIBS="$LIBS"
1787 AC_SUBST([GAIL_INET_LIBS])
1788
1789 LIBS="$old_LIBS"
1790
1791 ################################################################
1792 # Printing system checks
1793 ################################################################
1794
1795 AC_ARG_ENABLE(cups,
1796               [AC_HELP_STRING([--disable-cups]
1797                               [disable cups print backend])],,
1798               [enable_cups=auto])
1799
1800 if test "x$enable_cups" = "xauto"
1801 then
1802   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1803   if test "x$CUPS_CONFIG" != "xno"; then
1804     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1805     CUPS_LIBS=`$CUPS_CONFIG --libs`
1806
1807     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1808     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1809     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1810
1811     if test $CUPS_API_MAJOR -gt 1 -o \
1812             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1813       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1814                 [Define to 1 if CUPS 1.2 API is available])
1815     fi
1816
1817     AC_SUBST(CUPS_API_MAJOR)
1818     AC_SUBST(CUPS_API_MINOR)
1819     AC_SUBST(CUPS_CFLAGS)
1820     AC_SUBST(CUPS_LIBS)
1821
1822     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1823   fi
1824   AM_CONDITIONAL(HAVE_CUPS, test "x$CUPS_CONFIG" != "xno")
1825
1826   gtk_save_cflags="$CFLAGS"
1827   CFLAGS="$CUPS_CFLAGS"
1828   AC_TRY_COMPILE([#include <cups/http.h>],
1829                  [http_t http; char *s = http.authstring;],
1830                  [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1831                             [Define if cups http_t authstring field is accessible])],)
1832   CFLAGS="$gtk_save_cflags"
1833
1834   AC_SUBST(HAVE_HTTP_AUTHSTRING)
1835
1836   gtk_save_libs="$LIBS"
1837   LIBS="$CUPS_LIBS"
1838   AC_CHECK_FUNCS(httpGetAuthString)
1839   LIBS="$gtk_save_libs"
1840
1841 else
1842   AM_CONDITIONAL(HAVE_CUPS, false)
1843 fi
1844
1845 gtk_save_cppflags="$CPPFLAGS"
1846 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS"
1847
1848 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1849 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1850 *** backend enabled.]))
1851
1852 if test "$os_win32" != "yes"; then
1853   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1854 *** Can't find cairo-ps.h. You must build Cairo with the
1855 *** postscript backend enabled.]))
1856 fi
1857
1858 CPPFLAGS="$gtk_save_cppflags"
1859
1860
1861 AC_ARG_ENABLE(test-print-backend,
1862               [AC_HELP_STRING([--enable-test-print-backend],
1863                               [build test print backend])],,
1864               [enable_test_print_backend=no])
1865 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1866
1867
1868 ################################################################
1869 # Strip -export-dynamic from the link lines of various libraries
1870 ################################################################
1871
1872 #
1873 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1874 #  but this flag is only meaningful for executables. For libraries
1875 #  the effect is undefined; what it causes on Linux is that the
1876 #  export list from -export-symbols-regex is ignored and everything
1877 #  is exported
1878 #
1879 # We are using gmodule-no-export now, but I'm leaving the stripping
1880 # code in place for now, since pango and atk still require gmodule.
1881 export SED
1882 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1883 if test -n "$export_dynamic"; then
1884   GDK_PIXBUF_DEP_LIBS=`echo $GDK_PIXBUF_DEP_LIBS | sed -e "s/$export_dynamic//"`
1885   GDK_PIXBUF_XLIB_DEP_LIBS=`echo $GDK_PIXBUF_XLIB_DEP_LIBS | sed -e "s/$export_dynamic//"`
1886   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1887   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1888 fi
1889
1890
1891 ##################################################
1892 # Checks for gtk-doc and docbook-tools
1893 ##################################################
1894
1895 GTK_DOC_CHECK([1.8])
1896
1897 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1898 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1899
1900 AC_ARG_ENABLE(man,
1901               [AC_HELP_STRING([--enable-man],
1902                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1903               enable_man=no)
1904
1905 if test "${enable_man}" != no; then
1906   dnl
1907   dnl Check for xsltproc
1908   dnl
1909   AC_PATH_PROG([XSLTPROC], [xsltproc])
1910   if test -z "$XSLTPROC"; then
1911     enable_man=no
1912   fi
1913
1914   dnl check for DocBook DTD and stylesheets in the local catalog.
1915   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1916      [DocBook XML DTD V4.1.2],,enable_man=no)
1917   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1918      [DocBook XSL Stylesheets],,enable_man=no)
1919 fi
1920
1921 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1922
1923
1924 ##################################################
1925 # Output commands
1926 ##################################################
1927
1928 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1929         outfile=gdkconfig.h-tmp
1930         cat > $outfile <<\_______EOF
1931 /* gdkconfig.h
1932  *
1933  * This is a generated file.  Please modify `configure.in'
1934  */
1935
1936 #ifndef GDKCONFIG_H
1937 #define GDKCONFIG_H
1938
1939 #ifdef __cplusplus
1940 extern "C" {
1941 #endif /* __cplusplus */
1942
1943 #ifndef GSEAL
1944 /* introduce GSEAL() here for all of Gdk and Gtk+ without the need to modify GLib */
1945 #  ifdef GSEAL_ENABLE
1946 #    define GSEAL(ident)      _g_sealed__ ## ident
1947 #  else
1948 #    define GSEAL(ident)      ident
1949 #  endif
1950 #endif /* !GSEAL */
1951
1952 _______EOF
1953
1954         cat >>$outfile <<_______EOF
1955 $gdk_windowing
1956 $gdk_wc
1957 _______EOF
1958
1959         cat >>$outfile <<_______EOF
1960
1961 #ifdef __cplusplus
1962 }
1963 #endif /* __cplusplus */
1964
1965 #endif /* GDKCONFIG_H */
1966 _______EOF
1967
1968
1969         if cmp -s $outfile gdk/gdkconfig.h; then
1970           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1971           rm -f $outfile
1972         else
1973           mv $outfile gdk/gdkconfig.h
1974         fi
1975 ],[
1976 if test "x$gdktarget" = "xx11" ; then
1977   gdk_windowing='
1978 #define GDK_WINDOWING_X11'
1979 elif test "x$gdktarget" = "xwin32" ; then
1980   gdk_windowing='
1981 #define GDK_WINDOWING_WIN32'
1982 elif test "x$gdktarget" = "xquartz" ; then
1983   gdk_windowing='
1984 #define GDK_WINDOWING_QUARTZ'
1985 elif test "x$gdktarget" = "xdirectfb" ; then
1986   gdk_windowing='
1987 #define GDK_WINDOWING_DIRECTFB'
1988 fi
1989
1990 if test x$gdk_wchar_h = xyes; then
1991   gdk_wc='
1992 #define GDK_HAVE_WCHAR_H 1'
1993 fi
1994 if test x$gdk_wctype_h = xyes; then
1995   gdk_wc="\$gdk_wc
1996 #define GDK_HAVE_WCTYPE_H 1"
1997 fi
1998 if test x$gdk_working_wctype = xno; then
1999   gdk_wc="\$gdk_wc
2000 #define GDK_HAVE_BROKEN_WCTYPE 1"
2001 fi
2002
2003
2004 ])
2005
2006 AC_CONFIG_FILES([
2007 config.h.win32
2008 gtk-zip.sh
2009 Makefile
2010 gdk-pixbuf-2.0.pc
2011 gdk-2.0.pc
2012 gtk+-2.0.pc
2013 gtk+-unix-print-2.0.pc
2014 gail.pc
2015 gdk-pixbuf-2.0-uninstalled.pc
2016 gdk-2.0-uninstalled.pc
2017 gtk+-2.0-uninstalled.pc
2018 gail-uninstalled.pc
2019 m4macros/Makefile
2020 po/Makefile.in
2021 po-properties/Makefile.in
2022 demos/Makefile
2023 demos/gtk-demo/Makefile
2024 demos/gtk-demo/geninclude.pl
2025 tests/Makefile
2026 docs/Makefile
2027 docs/reference/Makefile
2028 docs/reference/gdk-pixbuf/Makefile
2029 docs/reference/gdk-pixbuf/version.xml
2030 docs/reference/gdk/Makefile
2031 docs/reference/gdk/version.xml
2032 docs/reference/gtk/Makefile
2033 docs/reference/gtk/version.xml
2034 docs/reference/libgail-util/Makefile
2035 docs/faq/Makefile
2036 docs/tools/Makefile
2037 docs/tutorial/Makefile
2038 gdk-pixbuf/Makefile
2039 gdk-pixbuf/gdk_pixbuf.rc
2040 gdk-pixbuf/gdk-pixbuf-features.h
2041 gdk-pixbuf/pixops/Makefile
2042 gdk/Makefile
2043 gdk/x11/Makefile
2044 gdk/win32/Makefile
2045 gdk/win32/rc/Makefile
2046 gdk/win32/rc/gdk.rc
2047 gdk/quartz/Makefile
2048 gdk/directfb/Makefile
2049 gtk/Makefile
2050 gtk/makefile.msc
2051 gtk/gtkversion.h
2052 gtk/gtk-win32.rc
2053 gtk/theme-bits/Makefile
2054 gtk/tests/Makefile
2055 modules/Makefile
2056 modules/other/Makefile
2057 modules/other/gail/Makefile
2058 modules/other/gail/libgail-util/Makefile
2059 modules/other/gail/tests/Makefile
2060 modules/engines/Makefile
2061 modules/engines/pixbuf/Makefile
2062 modules/engines/ms-windows/Makefile
2063 modules/engines/ms-windows/Theme/Makefile
2064 modules/engines/ms-windows/Theme/gtk-2.0/Makefile
2065 modules/input/Makefile
2066 modules/printbackends/Makefile
2067 modules/printbackends/cups/Makefile
2068 modules/printbackends/lpr/Makefile
2069 modules/printbackends/file/Makefile
2070 modules/printbackends/test/Makefile
2071 perf/Makefile
2072 contrib/Makefile
2073 contrib/gdk-pixbuf-xlib/Makefile
2074 contrib/gdk-pixbuf-xlib/gdk-pixbuf-xlib-2.0.pc
2075 ])
2076
2077 AC_OUTPUT
2078
2079 echo "configuration:
2080         target: $gdktarget"