Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(gdk/gdktypes.h)
   3
   4 #
   5 # For each of the libraries we build, we define the following
   6 # substituted variables:
   7 #
   8 # foo_PACKAGES:     pkg-config packages this library requires
   9 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  10 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  11 # foo_DEP_LIBS:     All libraries this module requires
  12 # foo_DEP_CFLAGS:   All cflags this module requires
  13
  14
  15 ## We could have pkg-config uniquify the ldflags and cflags by calling
  16 ## it once with both the GLib and Pango package names, but we don't,
  17 ## someone should fix that.
  18
  19
  20 # Save this value here, since automake will set cflags later
  21 cflags_set=${CFLAGS+set}
  22
  23 dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  24 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  25 GLIB_AC_DIVERT_BEFORE_HELP([
  26 #
  27 # Making releases:
  28 #   GTK_MICRO_VERSION += 1;
  29 #   GTK_INTERFACE_AGE += 1;
  30 #   GTK_BINARY_AGE += 1;
  31 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  32 # if backwards compatibility has been broken,
  33 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  34 #
  35 GTK_MAJOR_VERSION=1
  36 GTK_MINOR_VERSION=3
  37 GTK_MICRO_VERSION=7
  38 GTK_INTERFACE_AGE=0
  39 GTK_BINARY_AGE=0
  40 GTK_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$GTK_MICRO_VERSION
  41 dnl
  42 ])dnl
  43
  44 AC_SUBST(GTK_MAJOR_VERSION)
  45 AC_SUBST(GTK_MINOR_VERSION)
  46 AC_SUBST(GTK_MICRO_VERSION)
  47 AC_SUBST(GTK_INTERFACE_AGE)
  48 AC_SUBST(GTK_BINARY_AGE)
  49 AC_SUBST(GTK_VERSION)
  50
  51 # libtool versioning
  52 LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  53 LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  54 LT_REVISION=$GTK_INTERFACE_AGE
  55 LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  56 AC_SUBST(LT_RELEASE)
  57 AC_SUBST(LT_CURRENT)
  58 AC_SUBST(LT_REVISION)
  59 AC_SUBST(LT_AGE)
  60
  61 # Define a string for the earliest version that this release has
  62 # binary compatibility with. This is used for module locations.
  63 #
  64 GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  65 AC_SUBST(GTK_BINARY_VERSION)
  66
  67 #
  68 # gdk-pixbuf gets versioned separately, and for now, using standard
  69 # libtool versioning, not GTK+-style versioning
  70 #
  71 GDK_PIXBUF_MAJOR=$GTK_MAJOR_VERSION
  72 GDK_PIXBUF_MINOR=$GTK_MINOR_VERSION
  73 GDK_PIXBUF_MICRO=$GTK_MICRO_VERSION
  74 GDK_PIXBUF_VERSION="${GDK_PIXBUF_MAJOR}.${GDK_PIXBUF_MINOR}.${GDK_PIXBUF_MICRO}"
  75 AC_SUBST(GDK_PIXBUF_MAJOR)
  76 AC_SUBST(GDK_PIXBUF_MINOR)
  77 AC_SUBST(GDK_PIXBUF_MICRO)
  78 AC_SUBST(GDK_PIXBUF_VERSION)
  79
  80 # For automake.
  81 VERSION=$GTK_VERSION
  82 PACKAGE=gtk+
  83
  84 GETTEXT_PACKAGE=gtk20
  85 AC_SUBST(GETTEXT_PACKAGE)
  86 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
  87
  88 # Save this value here, since automake will set cflags later
  89 cflags_set=${CFLAGS+set}
  90
  91 dnl Initialize automake stuff
  92 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  93
  94 # Specify a configuration file
  95 AM_CONFIG_HEADER(config.h)
  96
  97 dnl Initialize libtool
  98 AM_PROG_LIBTOOL
  99
 100 dnl Initialize maintainer mode
 101 AM_MAINTAINER_MODE
 102
 103 AC_CANONICAL_HOST
 104
 105 dnl figure debugging default, prior to $ac_help setup
 106 dnl
 107 GLIB_AC_DIVERT_BEFORE_HELP([
 108 if test `expr $GTK_MINOR_VERSION \% 2` = 1 ; then
 109         debug_default=yes
 110 else
 111         debug_default=minimum
 112 fi
 113 ])dnl
 114
 115 dnl declare --enable-* args and collect ac_help strings
 116 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 117 AC_ARG_ENABLE(shm, [  --enable-shm            support shared memory if available [default=yes]],
 118                    echo $enable_shm, enable_shm="yes")
 119 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 120                     , enable_ansi=no)
 121 AC_ARG_ENABLE(xim, [  --enable-xim            support XIM [default=yes]],
 122                         , enable_xim="yes")
 123 AC_ARG_ENABLE(xim_inst, [  --disable-xim-inst      does not use xim instantiate callback],
 124                         , enable_xim_inst="maybe")
 125 AC_ARG_ENABLE(xkb, [  --enable-xkb            support XKB [default=maybe]],
 126                         , enable_xkb="maybe")
 127 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 128
 129 AC_ARG_WITH(xinput, [  --with-xinput=[no/gxi/xfree] support XInput ])
 130
 131 gdktarget=x11
 132 gdktargetlib=libgdk-x11-1.3.la
 133 gtktargetlib=libgtk-x11-1.3.la
 134 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[x11/nanox/linux-fb] select GDK target [default=x11] ],
 135         gdktarget=$with_gdktarget)
 136
 137 AC_SUBST(gdktarget)
 138 case $gdktarget in
 139   x11|nanox|linux-fb) ;;
 140   *) AC_MSG_ERROR([Invalid target for GDK: use x11, nanox or linux-fb.]);;
 141 esac
 142
 143 AC_ARG_ENABLE(shadowfb, [  --disable-shadowfb      disable shadowfb support for linux-fb],,enable_shadowfb=yes)
 144
 145 AC_ARG_ENABLE(fbmanager, [  --enable-fbmanager      enable framebuffer manager support (GtkFB)],enable_fbmanager=yes,enable_fbmanager=no)
 146
 147 if test "x$enable_debug" = "xyes"; then
 148   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 149   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 150 else
 151   if test "x$enable_debug" = "xno"; then
 152     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 153   else
 154     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 155   fi
 156 fi
 157
 158 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 159
 160
 161 # Build time sanity check...
 162 AM_SANITY_CHECK
 163
 164 # Checks for programs.
 165 AC_PROG_CC
 166 AC_ISC_POSIX
 167 AM_PROG_CC_STDC
 168 AC_PROG_INSTALL
 169 AC_PROG_MAKE_SET
 170
 171 changequote(,)dnl
 172 if test "x$GCC" = "xyes"; then
 173   case " $CFLAGS " in
 174   *[\ \ ]-Wall[\ \      ]*) ;;
 175   *) CFLAGS="$CFLAGS -Wall" ;;
 176   esac
 177
 178   if test "x$enable_ansi" = "xyes"; then
 179     case " $CFLAGS " in
 180     *[\ \       ]-ansi[\ \      ]*) ;;
 181     *) CFLAGS="$CFLAGS -ansi" ;;
 182     esac
 183
 184     case " $CFLAGS " in
 185     *[\ \       ]-pedantic[\ \  ]*) ;;
 186     *) CFLAGS="$CFLAGS -pedantic" ;;
 187     esac
 188   fi
 189 fi
 190 changequote([,])dnl
 191
 192 # Honor aclocal flags
 193 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 194
 195 # libtool option to control which symbols are exported
 196 # right now, symbols starting with _ are not exported
 197 LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 198 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 199
 200 # define a MAINT-like variable REBUILD which is set if Perl
 201 # and awk are found, so autogenerated sources can be rebuilt
 202
 203 AC_PROG_AWK
 204 AC_CHECK_PROGS(PERL, perl5 perl)
 205
 206 # We would like indent, but don't require it.
 207 AC_CHECK_PROG(INDENT, indent, indent)
 208
 209 REBUILD=\#
 210 if test "x$enable_rebuilds" = "xyes" && \
 211      test -n "$PERL" && \
 212      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 213      test -n "$AWK" ; then
 214   REBUILD=
 215 fi
 216 AC_SUBST(REBUILD)
 217
 218 AC_CHECK_FUNCS(lstat mkstemp sigsetjmp bind_textdomain_codeset)
 219
 220 AC_MSG_CHECKING(whether make is GNU Make)
 221 STRIP_BEGIN=
 222 STRIP_END=
 223 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 224         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 225         STRIP_END=')'
 226         AC_MSG_RESULT(yes)
 227 else
 228         AC_MSG_RESULT(no)
 229 fi
 230 STRIP_DUMMY=
 231 AC_SUBST(STRIP_DUMMY)
 232 AC_SUBST(STRIP_BEGIN)
 233 AC_SUBST(STRIP_END)
 234
 235 # i18n stuff
 236 ALL_LINGUAS="az ca cs da de el en_GB en@IPA es et eu fa fi fr ga gl he hr hu ia it ja ko lt nl nn no pl pt pt_BR ro ru sk sl sp sr sv tr uk vi wa zh_TW zh_CN"
 237 AM_GLIB_GNU_GETTEXT
 238 LIBS="$LIBS $INTLLIBS"
 239
 240 # AM_GLIB_GNU_GETTEXT above substs $DATADIRNAME
 241 # this is the directory where the *.{mo,gmo} files are installed
 242 gtklocaledir='${prefix}/${DATADIRNAME}/locale'
 243 AC_SUBST(gtklocaledir)
 244
 245 dnl The DU4 header files don't provide library prototypes unless
 246 dnl -std1 is given to the native cc.
 247 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 248
 249 gtk_save_LIBS=$LIBS
 250 LIBS="$LIBS -lm"
 251 AC_TRY_RUN([#include <math.h>
 252              int main (void) { return (log(1) != log(1.)); }],
 253      AC_MSG_RESULT(none needed),
 254      gtk_save_CFLAGS="$CFLAGS"
 255      CFLAGS="$CFLAGS -std1"
 256      AC_TRY_RUN([#include <math.h>
 257                  int main (void) { return (log(1) != log(1.)); }],
 258          AC_MSG_RESULT(-std1),
 259          AC_MSG_RESULT()
 260          CFLAGS="$gtk_save_CFLAGS"
 261          AC_MSG_WARN(
 262                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 263          true
 264      ),
 265      AC_MSG_RESULT(none needed)
 266 )
 267 LIBS=$gtk_save_LIBS
 268
 269 MATH_LIB=-lm
 270 AC_MSG_CHECKING(for the BeOS)
 271 case $host in
 272   *-*-beos*)
 273     AC_MSG_RESULT(yes)
 274     MATH_LIB=
 275   ;;
 276   *)
 277     AC_MSG_RESULT(no)
 278   ;;
 279 esac
 280
 281 dnl NeXTStep cc seems to need this
 282 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 283 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 284   AC_MSG_RESULT(none needed),
 285   gtk_save_CFLAGS="$CFLAGS"
 286   CFLAGS="$CFLAGS -posix"
 287   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 288     AC_MSG_RESULT(-posix),
 289     AC_MSG_RESULT()
 290     CFLAGS="$gtk_save_CFLAGS"
 291     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 292
 293 #
 294 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 295 #
 296
 297 GLIB_PACKAGES="gobject-2.0 gmodule-2.0"
 298 GLIB_REQUIRED_VERSION=1.3.7
 299
 300 AM_PATH_GLIB_2_0($GLIB_REQUIRED_VERSION, :,
 301   AC_MSG_ERROR([
 302 *** GLIB $GLIB_REQUIRED_VERSION or better is required. The latest version of
 303 *** GLIB is always available from ftp://ftp.gtk.org/.]),
 304   gobject gmodule gthread)
 305
 306 AC_CHECK_HEADERS(dirent.h, AC_DEFINE(HAVE_DIRENT_H))
 307 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 308 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 309 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 310
 311 saved_cflags="$CFLAGS"
 312 saved_ldflags="$LDFLAGS"
 313
 314
 315 # Checks for header files.
 316 AC_HEADER_STDC
 317
 318 # Checks for typedefs, structures, and compiler characteristics.
 319 AC_C_CONST
 320
 321 # Checks for library functions.
 322 AC_TYPE_SIGNAL
 323 AC_FUNC_MMAP
 324
 325 AC_CHECK_FUNCS(getresuid)
 326 AC_TYPE_UID_T
 327
 328 # Check if <sys/select.h> needs to be included for fd_set
 329 AC_MSG_CHECKING([for fd_set])
 330 AC_TRY_COMPILE([#include <sys/types.h>],
 331         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 332 if test $gtk_ok = yes; then
 333     AC_MSG_RESULT([yes, found in sys/types.h])
 334 else
 335     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 336     if test $gtk_ok = yes; then
 337         AC_DEFINE(HAVE_SYS_SELECT_H)
 338         AC_MSG_RESULT([yes, found in sys/select.h])
 339     else
 340         AC_DEFINE(NO_FD_SET)
 341         AC_MSG_RESULT(no)
 342     fi
 343 fi
 344
 345 # `widechar' tests for gdki18n.h
 346 AC_MSG_CHECKING(for wchar.h)
 347 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 348 if test $gdk_wchar_h = yes; then
 349    AC_DEFINE(HAVE_WCHAR_H,1,[Have wchar.h include file])
 350 fi
 351 AC_MSG_RESULT($gdk_wchar_h)
 352
 353 # Check for wctype.h (for iswalnum)
 354 AC_MSG_CHECKING(for wctype.h)
 355 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 356 if test $gdk_wctype_h = yes; then
 357    AC_DEFINE(HAVE_WCTYPE_H,1,[Have wctype.h include file])
 358 fi
 359 AC_MSG_RESULT($gdk_wctype_h)
 360
 361 # in Solaris 2.5, `iswalnum' is in -lw
 362 GDK_WLIBS=
 363 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 364
 365 oLIBS="$LIBS"
 366 LIBS="$LIBS $GDK_WLIBS"
 367 # The following is necessary for Linux libc-5.4.38
 368 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 369 AC_TRY_LINK([#include <stdlib.h>],[
 370 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 371 #  ifdef HAVE_WCTYPE_H
 372 #    include <wctype.h>
 373 #  else
 374 #    ifdef HAVE_WCHAR_H
 375 #      include <wchar.h>
 376 #    endif
 377 #  endif
 378 #else
 379 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 380 #endif
 381 iswalnum((wchar_t) 0);
 382 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 383 LIBS="$oLIBS"
 384
 385 if test $gdk_working_wctype = no; then
 386    AC_DEFINE(HAVE_BROKEN_WCTYPE,1,[Is the wctype implementation broken])
 387    GDK_WLIBS=
 388 fi
 389 AC_MSG_RESULT($gdk_working_wctype)
 390 AC_SUBST(GDK_WLIBS)
 391
 392
 393
 394 ##################################################
 395 # Checks for gdk-pixbuf
 396 ##################################################
 397
 398 AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
 399
 400 AC_ARG_ENABLE(modules, [  --disable-modules       Disables dynamic module loading],[
 401         if test x$withval = xyes; then
 402             with_modules=yes
 403         else
 404             with_modules=no
 405         fi
 406 ])
 407
 408 dynworks=false
 409 deps=
 410 if test x$with_modules = xno; then
 411     AC_MSG_RESULT(no)
 412 else
 413     AC_MSG_RESULT(yes)
 414     AC_MSG_CHECKING(whether dynamic modules work)
 415     ## for loop is to strip newline
 416     tmp=`pkg-config --variable=gmodule_supported gmodule-2.0`
 417     for I in $tmp; do
 418         dynworks=$I
 419     done
 420 fi
 421
 422 dnl Now we check to see if our libtool supports shared lib deps
 423 dnl (in a rather ugly way even)
 424 if $dynworks; then
 425    pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} libtool --config"
 426    pixbuf_deplibs_check=`$pixbuf_libtool_config | \
 427       grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 428       sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 429    if test "x$pixbuf_deplibs_check" = "xnone" || \
 430       test "x$pixbuf_deplibs_check" = "xunknown" || \
 431       test "x$pixbuf_deplibs_check" = "x"; then
 432       dynworks=false
 433    fi
 434 fi
 435
 436 if $dynworks; then
 437    AC_DEFINE(USE_GMODULE)
 438    AC_MSG_RESULT(yes)
 439 else
 440    AC_MSG_RESULT(no)
 441 fi
 442
 443 dnl Test for libtiff
 444   if test -z "$LIBTIFF"; then
 445     AC_CHECK_LIB(tiff, TIFFReadScanline,
 446       AC_CHECK_HEADER(tiffio.h,
 447         TIFF='tiff'; LIBTIFF='-ltiff',
 448         AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 449       AC_CHECK_LIB(tiff, TIFFWriteScanline,
 450         AC_CHECK_HEADER(tiffio.h,
 451           TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
 452           AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 453         AC_CHECK_LIB(tiff34, TIFFFlushData,
 454           AC_CHECK_HEADER(tiffio.h,
 455             TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
 456             AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 457         AC_MSG_WARN(*** TIFF plug-in will not be built (TIFF library not found) ***), -ljpeg -lz -lm), -ljpeg -lz -lm), -lm)
 458   fi
 459
 460 dnl Test for libjpeg
 461   if test -z "$LIBJPEG"; then
 462     AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 463       jpeg_ok=yes,
 464       jpeg_ok=no
 465       AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
 466     if test "$jpeg_ok" = yes; then
 467       AC_MSG_CHECKING([for jpeglib.h])
 468       AC_TRY_CPP(
 469 [#include <stdio.h>
 470 #undef PACKAGE
 471 #undef VERSION
 472 #include <jpeglib.h>],
 473         jpeg_ok=yes,
 474         jpeg_ok=no)
 475       AC_MSG_RESULT($jpeg_ok)
 476       if test "$jpeg_ok" = yes; then
 477         LIBJPEG='-ljpeg'
 478         AC_CHECK_LIB(jpeg, jpeg_simple_progression,
 479           AC_DEFINE(HAVE_PROGRESSIVE_JPEG),
 480           AC_MSG_WARN(JPEG library does not support progressive saving.))
 481       else
 482           AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
 483       fi
 484     fi
 485   fi
 486
 487 dnl Test for libpng
 488   if test -z "$LIBPNG"; then
 489     AC_CHECK_LIB(png, png_read_info,
 490       AC_CHECK_HEADER(png.h,
 491         png_ok=yes,
 492         png_ok=no),
 493       AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
 494     if test "$png_ok" = yes; then
 495       AC_MSG_CHECKING([for png_structp in png.h])
 496       AC_TRY_COMPILE([#include <png.h>],
 497         [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 498         png_ok=yes,
 499         png_ok=no)
 500       AC_MSG_RESULT($png_ok)
 501       if test "$png_ok" = yes; then
 502         PNG='png'; LIBPNG='-lpng -lz'
 503       else
 504         AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
 505       fi
 506     else
 507      AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
 508     fi
 509   fi
 510
 511 AC_SUBST(LIBTIFF)
 512 AC_SUBST(LIBJPEG)
 513 AC_SUBST(LIBPNG)
 514
 515 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 516
 517 #
 518 # Allow building some or all gdk-pixbuf loaders included
 519 #
 520 AC_MSG_CHECKING(pixbuf loaders to build)
 521
 522 AC_ARG_WITH(included_loaders, [  --with-included-loaders=LOADER1,LOADER2,... Build the specified loaders into gdk-pixbuf (only used if module loading disabled)])
 523
 524 if $dynworks; then
 525         :
 526 else
 527    ## if the option was specified, leave it; otherwise disable included loaders
 528    if test x$with_included_loaders = xno; then
 529            with_included_loaders=yes
 530    fi
 531 fi
 532
 533 all_loaders="png,bmp,wbmp,gif,ico,jpeg,pnm,ras,tiff,xpm,tga"
 534 included_loaders=""
 535 # If no loaders specified, include all
 536 if test "x$with_included_loaders" = xyes ; then
 537   included_loaders="$all_loaders"
 538 else
 539   included_loaders="$with_included_loaders"
 540 fi
 541
 542 AC_MSG_RESULT($included_loaders)
 543
 544 INCLUDED_LOADER_OBJ=
 545 INCLUDED_LOADER_DEFINE=
 546
 547 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 548 for loader in $included_loaders; do
 549  if echo "$all_loaders" | grep "\(^\|\,\)$loader\(\$\|\,\)" > /dev/null; then
 550    :
 551  else
 552    AC_MSG_ERROR([the specified loader $loader does not exist])
 553  fi
 554
 555  INCLUDED_LOADER_OBJ="$INCLUDED_LOADER_OBJ libpixbufloader-static-$loader.la"
 556  INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_$loader"
 557 done
 558 IFS="$gtk_save_ifs"
 559 AC_SUBST(INCLUDED_LOADER_OBJ)
 560 AC_SUBST(INCLUDED_LOADER_DEFINE)
 561
 562 AC_HEADER_DIRENT
 563 AC_HEADER_SYS_WAIT
 564
 565 AC_TYPE_SIGNAL
 566
 567 AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
 568 AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
 569 AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
 570
 571 if $dynworks ; then
 572   STATIC_LIB_DEPS=
 573   if echo "$included_loaders" | grep "\(^\|\,\)tiff\(\$\|\,\)" > /dev/null; then
 574     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBTIFF"
 575   fi
 576   if echo "$included_loaders" | grep "\(^\|\,\)jpeg\(\$\|\,\)" > /dev/null; then
 577     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBJPEG"
 578   fi
 579   if echo "$included_loaders" | grep "\(^\|\,\)png\(\$\|\,\)" > /dev/null; then
 580     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBPNG"
 581   fi
 582 else
 583   STATIC_LIB_DEPS="$LIBTIFF $LIBJPEG $LIBPNG"
 584 fi
 585
 586 # Checks to see if we should compile in MMX support (there will be
 587 # a runtime test when the code is actually run to see if it should
 588 # be used - this just checks if we can compile it.)
 589 #
 590 # This code is partially taken from Mesa
 591 #
 592 AC_MSG_CHECKING(for x86 platform)
 593 case $host_cpu in
 594   i386|i486|i586|i686|i786|k6|k7)
 595         use_x86_asm=yes
 596         ;;
 597    *)
 598         use_x86_asm=no
 599 esac
 600 AC_MSG_RESULT($use_x86_asm)
 601
 602 use_mmx_asm=no
 603 if test $use_x86_asm = yes; then
 604     save_ac_ext=$ac_ext
 605     ac_ext=S
 606
 607     AC_MSG_CHECKING(compiler support for MMX)
 608     cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
 609     if AC_TRY_EVAL(ac_compile); then
 610         use_mmx_asm=yes
 611     fi
 612
 613     rm -rf conftest*
 614
 615     ac_ext=$save_ac_ext
 616     if test $use_mmx_asm = yes; then
 617       AC_DEFINE(USE_MMX)
 618       AC_MSG_RESULT(yes)
 619     else
 620       AC_MSG_RESULT(no)
 621     fi
 622 fi
 623
 624 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
 625
 626
 627 GDK_PIXBUF_PACKAGES="gmodule-2.0 gobject-2.0"
 628 GDK_PIXBUF_EXTRA_LIBS="$STATIC_LIB_DEPS $MATH_LIB"
 629 GDK_PIXBUF_EXTRA_CFLAGS=
 630 GDK_PIXBUF_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
 631 GDK_PIXBUF_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS"
 632
 633 AC_SUBST(GDK_PIXBUF_PACKAGES)
 634 AC_SUBST(GDK_PIXBUF_EXTRA_LIBS)
 635 AC_SUBST(GDK_PIXBUF_EXTRA_CFLAGS)
 636 AC_SUBST(GDK_PIXBUF_DEP_LIBS)
 637 AC_SUBST(GDK_PIXBUF_DEP_CFLAGS)
 638
 639
 640 ########################################
 641 # Windowing system checks
 642 ########################################
 643
 644 GDK_EXTRA_LIBS=$GDK_WLIBS
 645 GDK_EXTRA_CFLAGS=
 646
 647 if test "x$gdktarget" = "xx11"; then
 648   # We start off with the libraries from Pango
 649
 650   ## be sure we also have Pango built with xft support
 651   if $PKG_CONFIG --exists pangoxft ; then
 652     PANGO_PACKAGES="pangox pangoxft"
 653     have_xft=true
 654     AC_DEFINE(HAVE_XFT)
 655   else
 656     PANGO_PACKAGES="pangox"
 657     have_xft=false
 658   fi
 659
 660   AM_CONDITIONAL(HAVE_XFT, $have_xft)
 661
 662   x_libs="`$PKG_CONFIG --libs $PANGO_PACKAGES`"
 663   x_cflags="`$PKG_CONFIG --cflags $PANGO_PACKAGES`"
 664   x_extra_libs=
 665
 666   ## Strip the .la files
 667
 668   x_libs_for_checks=""
 669   for I in $x_libs ; do
 670     case $I in
 671       *.la) ;;
 672       *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 673     esac
 674   done
 675
 676   # Sanity check for the X11 library
 677   AC_CHECK_LIB(X11, XOpenDisplay, :,
 678             AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
 679             $x_libs_for_checks)
 680
 681   if test "x$enable_shm" = "xyes"; then
 682     # Check for the Xext library (needed for XShm extention)
 683     AC_CHECK_LIB(Xext, XShmAttach,
 684         if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 685           x_extra_libs="-lXext"
 686         fi,
 687         # On AIX, it is in XextSam instead, but we still need -lXext
 688         AC_CHECK_LIB(XextSam, XShmAttach,
 689             if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 690                x_extra_libs="-lXextSam -lXext"
 691             else
 692                x_extra_libs="-lXextSam"
 693             fi, , $x_libs_for_checks),
 694         $x_libs_for_checks)
 695   fi
 696
 697   GDK_PIXBUF_XLIB_EXTRA_CFLAGS="$x_cflags"
 698   # Don't ever pull in the pangoxft libraries for gdk-pixbuf-x11
 699   GDK_PIXBUF_XLIB_EXTRA_LIBS="$x_extra_libs `$PKG_CONFIG --libs pangox`"
 700
 701   # Check for shaped window extension
 702
 703   AC_CHECK_LIB(Xext, XShapeCombineMask,
 704       if test -z "`echo $x_extra_libs $x_libs | grep "\-lXext" 2> /dev/null`"; then
 705            x_extra_libs="-lXext $x_extra_libs"
 706       fi
 707       AC_DEFINE(HAVE_SHAPE_EXT),
 708       ,
 709       $x_libs_for_checks)
 710
 711   # Check for XConvertCase (X11R6 specific)
 712
 713   AC_CHECK_LIB(X11, XConvertCase,
 714       AC_DEFINE(HAVE_XCONVERTCASE),
 715       ,
 716       $x_libs_for_checks)
 717
 718   # Check for XIM support.
 719
 720   AC_CHECK_LIB(X11, XUnregisterIMInstantiateCallback,
 721             : ,
 722             enable_xim_inst="no",
 723             $x_libs_for_checks)
 724
 725   # On Solaris, calling XRegisterIMInstantiateCallback seems to
 726   # cause an immediate segfault, so we disable it, unless
 727   # the user specifically forces it to be on.
 728
 729   if test x$enable_xim_inst = xmaybe ; then
 730     case host in
 731           *-*-solaris*)
 732             enable_xim_inst="no"
 733             ;;
 734           *)
 735             enable_xim_inst="yes"
 736             ;;
 737     esac
 738   fi
 739
 740   if test "x$enable_xim" = "xyes"; then
 741     GTK_XIM_FLAGS="-DUSE_XIM"
 742     if test "x$enable_xim_inst" = "xyes"; then
 743       AC_DEFINE(USE_X11R6_XIM)
 744     fi
 745   fi
 746
 747   # Check for XKB support.
 748
 749   if test "x$enable_xkb" = "xyes"; then
 750         AC_MSG_WARN(XKB support explicitly enabled)
 751         AC_DEFINE(HAVE_XKB)
 752   elif test "x$enable_xkb" = "xmaybe"; then
 753         AC_CHECK_LIB(X11, XkbQueryExtension,
 754                      AC_DEFINE(HAVE_XKB),
 755                      ,
 756                      $x_libs_for_checks)
 757   else
 758         AC_MSG_WARN(XKB support explicitly disabled)
 759   fi
 760
 761   x_cflags="$X_CFLAGS"
 762   x_ldflags="$X_LDFLAGS"
 763
 764   # set up things for XInput
 765
 766   if test "x$with_xinput" = "xgxi" || test "x$with_xinput" = "xyes"; then
 767     AC_DEFINE(XINPUT_GXI)
 768     xinput_progs=gxid
 769     x_extra_libs="-lXi $x_extra_libs"
 770   elif test "x$with_xinput" = "xxfree"; then
 771     AC_DEFINE(XINPUT_XFREE)
 772     x_extra_libs="-lXi $x_extra_libs"
 773   else
 774     AC_DEFINE(XINPUT_NONE)
 775   fi
 776
 777   AM_CONDITIONAL(XINPUT_GXI, test x$with_xinput = xgxi)
 778   AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree)
 779
 780   if test "x$enable_shm" = "xyes"; then
 781     # Check for shared memory
 782     AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
 783     AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
 784
 785     # Check for the X shared memory extension header file
 786     have_xshm=no
 787     AC_MSG_CHECKING(X11/extensions/XShm.h)
 788     if test "x$no_xext_lib" = "xyes"; then
 789       :
 790     else
 791       gtk_save_CFLAGS="$CFLAGS"
 792       CFLAGS="$CFLAGS $x_cflags"
 793       AC_TRY_COMPILE([
 794 #include <stdlib.h>
 795 #include <sys/types.h>
 796 #include <sys/ipc.h>
 797 #include <sys/shm.h>
 798 #include <X11/Xlib.h>
 799 #include <X11/Xutil.h>
 800 #include <X11/extensions/XShm.h>
 801 ], [XShmSegmentInfo *x_shm_info;], have_xshm=yes)
 802       CFLAGS="$gtk_save_CFLAGS"
 803     fi
 804     AC_MSG_RESULT($have_xshm)
 805     if test $have_xshm = yes ; then
 806       AC_DEFINE(HAVE_XSHM_H)
 807     fi
 808   fi
 809
 810   GDK_EXTRA_CFLAGS=
 811   GDK_EXTRA_LIBS="$x_extra_libs"
 812
 813   # these are already defined above
 814   #gdktargetlib = "libgdk-x11-1.3.la"
 815   #gtktargetlib = "libgtk-x11-1.3.la"
 816
 817   AM_CONDITIONAL(USE_X11, true)
 818 else
 819   AM_CONDITIONAL(USE_X11, false)
 820 fi
 821
 822 AC_SUBST(xinput_progs)
 823
 824 GDK_PIXBUF_XLIB_PACKAGES=
 825 GDK_PIXBUF_XLIB_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_XLIB_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
 826 GDK_PIXBUF_XLIB_DEP_CFLAGS="`$PKG_CONFIG --cflags  $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_PIXBUF_XLIB_EXTRA_CFLAGS"
 827
 828 AC_SUBST(GDK_PIXBUF_XLIB_PACKAGES)
 829 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_LIBS)
 830 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_CFLAGS)
 831 AC_SUBST(GDK_PIXBUF_XLIB_DEP_LIBS)
 832 AC_SUBST(GDK_PIXBUF_XLIB_DEP_CFLAGS)
 833
 834 if test "x$gdktarget" = "xnanox"; then
 835   AC_CHECK_LIB(nano-X, GrOpen,,AC_MSG_ERROR([nano-X libraries not found.]))
 836   # nano-X may require additional libraries
 837   GDK_EXTRA_LIBS="-lnano-X $GDK_EXTRA_LIBS"
 838
 839   gdktargetlib="libgdk-nanox-1.3.la"
 840   gtktargetlib="libgtk-nanox-1.3.la"
 841
 842   AM_CONDITIONAL(USE_NANOX, true)
 843 else
 844   AM_CONDITIONAL(USE_NANOX, false)
 845 fi
 846
 847 if test "x$gdktarget" = "xlinux-fb"; then
 848   gdktargetlib="libgdk-linux-fb-1.3.la"
 849   gtktargetlib="libgtk-linux-fb-1.3.la"
 850
 851   AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
 852   if test x$FREETYPE_CONFIG = xno ; then
 853     AC_MSG_ERROR([*** freetype-config not found])
 854   fi
 855
 856   FREETYPE_CFLAGS="`$FREETYPE_CONFIG --cflags`"
 857   FREETYPE_LIBS="`$FREETYPE_CONFIG --libs`"
 858   CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 859
 860   if test x$enable_shadowfb = xyes ; then
 861     AC_DEFINE(ENABLE_SHADOW_FB)
 862   fi
 863
 864   if test x$enable_fbmanager = xyes ; then
 865     AC_DEFINE(ENABLE_FB_MANAGER)
 866     AM_CONDITIONAL(ENABLE_FB_MANAGER, true)
 867   else
 868     AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
 869   fi
 870
 871   GDK_EXTRA_CFLAGS="$FREETYPE_CFLAGS"
 872   GDK_EXTRA_LIBS="$FREETYPE_LIBS $GDK_EXTRA_LIBS"
 873
 874   AM_CONDITIONAL(USE_LINUX_FB, true)
 875 else
 876   AM_CONDITIONAL(USE_LINUX_FB, false)
 877   AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
 878 fi
 879
 880 AC_SUBST(gdktargetlib)
 881 AC_SUBST(gtktargetlib)
 882
 883 #
 884 # Pick correct Pango packages to use
 885 #
 886
 887 if test "x$gdktarget" = "xx11"; then
 888         if $have_xft = true ; then
 889             PANGO_PACKAGES="pangox pangoxft"
 890         else
 891             PANGO_PACKAGES=pangox
 892         fi
 893 elif test "x$gdktarget" = "xlinux-fb"; then
 894         PANGO_PACKAGES=pangoft2
 895 else
 896         PANGO_PACKAGES=pango
 897 fi
 898
 899 # Check for Pango flags
 900
 901 AC_MSG_CHECKING(Pango flags)
 902 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
 903         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
 904         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
 905
 906         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
 907 else
 908         AC_MSG_ERROR([
 909 *** Pango not found. Pango is required to build GTK+.
 910 *** See http://www.pango.org for Pango information.
 911 *** For the framebuffer target, you will need to build
 912 *** Pango with freetype support.
 913 ])
 914 fi
 915
 916 CFLAGS="$CFLAGS $PANGO_CFLAGS"
 917
 918 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
 919         :
 920 else
 921         AC_CHECK_LIB(pango, pango_context_new, :, AC_MSG_ERROR([
 922 *** Can't link to Pango. Pango is required to build
 923 *** GTK+. For more information see http://www.pango.org]), $PANGO_LIBS)
 924 fi
 925
 926 CFLAGS="$saved_cflags"
 927 LDFLAGS="$saved_ldflags"
 928
 929 GDK_PACKAGES=$PANGO_PACKAGES
 930 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
 931 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS"
 932
 933 AC_SUBST(GDK_PACKAGES)
 934 AC_SUBST(GDK_EXTRA_LIBS)
 935 AC_SUBST(GDK_EXTRA_CFLAGS)
 936 AC_SUBST(GDK_DEP_LIBS)
 937 AC_SUBST(GDK_DEP_CFLAGS)
 938
 939
 940 ########################################
 941 # Check for Accessibility Toolkit flags
 942 ########################################
 943
 944 ATK_PACKAGES=atk
 945 AC_MSG_CHECKING(ATK flags)
 946 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
 947         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
 948         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
 949
 950         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
 951 else
 952         AC_MSG_ERROR([
 953 *** Accessibility Toolkit not found. Accessibility Toolkit is required
 954 *** to build GTK+.
 955 ])
 956 fi
 957
 958 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
 959         :
 960 else
 961         AC_CHECK_LIB(atk, atk_object_get_type, : , AC_MSG_ERROR([
 962                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
 963                 *** to build GTK+]), $ATK_LIBS $GLIB_LIBS)
 964 fi
 965
 966 GTK_PACKAGES=atk
 967 GTK_EXTRA_LIBS=
 968 GTK_EXTRA_CFLAGS=
 969 GTK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GTK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GTK_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
 970 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  $GTK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
 971
 972 AC_SUBST(GTK_PACKAGES)
 973 AC_SUBST(GTK_EXTRA_LIBS)
 974 AC_SUBST(GTK_EXTRA_CFLAGS)
 975 AC_SUBST(GTK_DEP_LIBS)
 976 AC_SUBST(GTK_DEP_CFLAGS)
 977
 978
 979 AC_SUBST(GTK_DEBUG_FLAGS)
 980 AC_SUBST(GTK_XIM_FLAGS)
 981
 982 ##################################################
 983 # Checks for gtk-doc and docbook-tools
 984 ##################################################
 985
 986 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
 987
 988 if test "x$with_html_dir" = "x" ; then
 989   HTML_DIR='${datadir}/gtk-doc/html'
 990 else
 991   HTML_DIR=$with_html_dir
 992 fi
 993
 994 AC_SUBST(HTML_DIR)
 995
 996 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
 997
 998 gtk_doc_min_version=0.6
 999 if $GTKDOC ; then
1000     gtk_doc_version=`gtkdoc-mkdb --version`
1001     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
1002     if perl <<EOF ; then
1003       exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
1004             ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
1005 EOF
1006       AC_MSG_RESULT(yes)
1007    else
1008       AC_MSG_RESULT(no)
1009       GTKDOC=false
1010    fi
1011 fi
1012
1013 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1014 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1015
1016 dnl Let people disable the gtk-doc stuff.
1017 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1018
1019 if test x$enable_gtk_doc = xauto ; then
1020   if test x$GTKDOC = xtrue ; then
1021     enable_gtk_doc=yes
1022   else
1023     enable_gtk_doc=no
1024   fi
1025 fi
1026
1027 dnl NOTE: We need to use a separate automake conditional for this
1028 dnl       to make this work with the tarballs.
1029 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1030
1031
1032 ##################################################
1033 # Output commands
1034 ##################################################
1035
1036 AC_OUTPUT_COMMANDS([
1037
1038 ## Generate `gdk/gdkconfig.h' in two cases
1039 ## 1. `config.status' is run either explicitly, or via configure.
1040 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1041 ##     config.h
1042 ## 2. CONFIG_OTHER is set explicitly
1043 ##
1044 ## Case 1 is difficult.  We know that `automake' sets one of
1045 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1046 ## only when AM_CONFIG_HEADER is set, however.
1047
1048 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1049   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1050   CONFIG_OTHER=${CONFIG_OTHER:-gdk/gdkconfig.h}
1051 fi
1052 case "$CONFIG_OTHER" in
1053 *gdk/gdkconfig.h*)
1054         echo creating gdk/gdkconfig.h
1055         outfile=gdkconfig.h-tmp
1056         cat > $outfile <<\_______EOF
1057 /* gdkconfig.h
1058  *
1059  * This is a generated file.  Please modify `configure.in'
1060  */
1061
1062 #ifndef GDKCONFIG_H
1063 #define GDKCONFIG_H
1064
1065 #ifdef __cplusplus
1066 extern "C" {
1067 #endif /* __cplusplus */
1068
1069 _______EOF
1070
1071         cat >>$outfile <<_______EOF
1072 $gdk_windowing
1073 $gdk_wc
1074 _______EOF
1075
1076         cat >>$outfile <<_______EOF
1077
1078 #ifdef __cplusplus
1079 }
1080 #endif /* __cplusplus */
1081
1082 #endif /* GDKCONFIG_H */
1083 _______EOF
1084
1085
1086         if cmp -s $outfile gdk/gdkconfig.h; then
1087           echo gdk/gdkconfig.h is unchanged
1088           rm -f $outfile
1089         else
1090           mv $outfile gdk/gdkconfig.h
1091         fi ;;
1092 esac
1093 ],[
1094 if test "x$gdktarget" = "xx11" ; then
1095   gdk_windowing='
1096 #define GDK_WINDOWING_X11'
1097 elif test "x$gdktarget" = "xnanox" ; then
1098   gdk_windowing='
1099 #define GDK_WINDOWING_NANOX'
1100 elif test "x$gdktarget" = "xlinux-fb" ; then
1101   gdk_windowing='
1102 #define GDK_WINDOWING_FB
1103 #define GDK_NATIVE_WINDOW_POINTER'
1104 fi
1105
1106 if test x$gdk_wchar_h = xyes; then
1107   gdk_wc='
1108 #define GDK_HAVE_WCHAR_H 1'
1109 fi
1110 if test x$gdk_wctype_h = xyes; then
1111   gdk_wc="\$gdk_wc
1112 #define GDK_HAVE_WCTYPE_H 1"
1113 fi
1114 if test x$gdk_working_wctype = xno; then
1115   gdk_wc="\$gdk_wc
1116 #define GDK_HAVE_BROKEN_WCTYPE 1"
1117 fi
1118
1119
1120 ])
1121
1122 AC_PATH_PROG(SGML2HTML, sgml2html, no)
1123 AM_CONDITIONAL(HAVE_SGML2HTML, ! test x$SGML2HTML = xno)
1124
1125 AC_OUTPUT([
1126 config.h.win32
1127 gtk+.spec
1128 Makefile
1129 gdk-pixbuf-2.0.pc
1130 gdk-2.0.pc
1131 gtk+-2.0.pc
1132 gdk-pixbuf-2.0-uninstalled.pc
1133 gdk-2.0-uninstalled.pc
1134 gtk+-2.0-uninstalled.pc
1135 m4macros/Makefile
1136 po/Makefile.in
1137 build/Makefile
1138 build/win32/Makefile
1139 demos/Makefile
1140 demos/gtk-demo/Makefile
1141 tests/Makefile
1142 docs/Makefile
1143 docs/reference/Makefile
1144 docs/reference/gdk-pixbuf/Makefile
1145 docs/reference/gdk/Makefile
1146 docs/reference/gtk/Makefile
1147 docs/faq/Makefile
1148 docs/tutorial/Makefile
1149 gdk-pixbuf/Makefile
1150 gdk-pixbuf/makefile.mingw
1151 gdk-pixbuf/gdk-pixbuf-features.h
1152 gdk-pixbuf/pixops/Makefile
1153 gdk-pixbuf/pixops/makefile.mingw
1154 gdk/Makefile
1155 gdk/makefile.mingw
1156 gdk/x11/Makefile
1157 gdk/win32/Makefile
1158 gdk/win32/makefile.mingw
1159 gdk/win32/rc/Makefile
1160 gdk/win32/rc/gdk.rc
1161 gdk/linux-fb/Makefile
1162 gtk/Makefile
1163 gtk/makefile.mingw
1164 gtk/makefile.msc
1165 gtk/gtkversion.h
1166 gtk/gtk-win32.rc
1167 gtk/stock-icons/Makefile
1168 modules/Makefile
1169 modules/input/Makefile
1170 contrib/Makefile
1171 contrib/gdk-pixbuf-xlib/Makefile
1172 contrib/gdk-pixbuf-xlib/gdk-pixbuf-xlib-2.0.pc
1173 ])