Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(gdk/gdktypes.h)
   3
   4 # Save this value here, since automake will set cflags later
   5 cflags_set=${CFLAGS+set}
   6
   7 # Making releases:
   8 #   GTK_MICRO_VERSION += 1;
   9 #   GTK_INTERFACE_AGE += 1;
  10 #   GTK_BINARY_AGE += 1;
  11 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  12 # if backwards compatibility has been broken,
  13 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  14 #
  15 GTK_MAJOR_VERSION=1
  16 GTK_MINOR_VERSION=1
  17 GTK_MICRO_VERSION=6
  18 GTK_INTERFACE_AGE=0
  19 GTK_BINARY_AGE=0
  20 GTK_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$GTK_MICRO_VERSION
  21 AC_SUBST(GTK_MAJOR_VERSION)
  22 AC_SUBST(GTK_MINOR_VERSION)
  23 AC_SUBST(GTK_MICRO_VERSION)
  24 AC_SUBST(GTK_INTERFACE_AGE)
  25 AC_SUBST(GTK_BINARY_AGE)
  26 AC_SUBST(GTK_VERSION)
  27
  28 # libtool versioning
  29 LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  30 LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  31 LT_REVISION=$GTK_INTERFACE_AGE
  32 LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  33 AC_SUBST(LT_RELEASE)
  34 AC_SUBST(LT_CURRENT)
  35 AC_SUBST(LT_REVISION)
  36 AC_SUBST(LT_AGE)
  37
  38 # For automake.
  39 VERSION=$GTK_VERSION
  40 PACKAGE=gtk+
  41
  42 # Save this value here, since automake will set cflags later
  43 cflags_set=${CFLAGS+set}
  44
  45 dnl Initialize automake stuff
  46 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  47
  48 # Specify a configuration file
  49 AM_CONFIG_HEADER(config.h)
  50
  51 dnl Initialize libtool
  52 AM_PROG_LIBTOOL
  53
  54 dnl Initialize maintainer mode
  55 AM_MAINTAINER_MODE
  56
  57 AC_CANONICAL_HOST
  58
  59 AC_ARG_ENABLE(shm, [  --enable-shm            support shared memory if available [default=yes]],
  60                    echo $enable_shm, enable_shm="yes")
  61 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=minimum]],,enable_debug=minimum)
  62 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  63                     , enable_ansi=no)
  64 AC_ARG_WITH(glib, [  --with-glib=DIR         Use uninstalled copy of glib])
  65 AC_ARG_ENABLE(xim, [  --enable-xim            support XIM [default=yes]],
  66                         , enable_xim="yes")
  67 AC_ARG_WITH(locale, [  --with-locale=LOCALE    locale name you want to use ])
  68
  69 AC_ARG_WITH(xinput, [  --with-xinput=[no/gxi/xfree] support XInput ])
  70 AC_ARG_WITH(threads, [  --with-threads=[posix] support threading ])
  71
  72 if test "x$enable_debug" = "xyes"; then
  73   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
  74   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
  75 else
  76   if test "x$enable_debug" = "xno"; then
  77     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DGTK_NO_CHECK_CASTS"
  78   else
  79     GTK_DEBUG_FLAGS="-DGTK_NO_CHECK_CASTS"
  80   fi
  81 fi
  82
  83 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
  84
  85 # Build time sanity check...
  86 AM_SANITY_CHECK
  87
  88 # Checks for programs.
  89 AC_PROG_CC
  90 AM_PROG_CC_STDC
  91 AC_PROG_INSTALL
  92 AC_PROG_MAKE_SET
  93
  94 changequote(,)dnl
  95 if test "x$GCC" = "xyes"; then
  96   case " $CFLAGS " in
  97   *[\ \ ]-Wall[\ \      ]*) ;;
  98   *) CFLAGS="$CFLAGS -Wall" ;;
  99   esac
 100
 101   if test "x$enable_ansi" = "xyes"; then
 102     case " $CFLAGS " in
 103     *[\ \       ]-ansi[\ \      ]*) ;;
 104     *) CFLAGS="$CFLAGS -ansi" ;;
 105     esac
 106
 107     case " $CFLAGS " in
 108     *[\ \       ]-pedantic[\ \  ]*) ;;
 109     *) CFLAGS="$CFLAGS -pedantic" ;;
 110     esac
 111   fi
 112 fi
 113 changequote([,])dnl
 114
 115 # define a MAINT-like variable REBUILD which is set if Perl
 116 # and awk are found, so autogenerated sources can be rebuilt
 117
 118 AC_PROG_AWK
 119 AC_CHECK_PROGS(PERL, perl5 perl)
 120
 121 # We would like indent, but don't require it.
 122 AC_CHECK_PROG(INDENT, indent, indent)
 123
 124 REBUILD=\#
 125 if test -n "$PERL" && perl -v | grep 'version 5.' > /dev/null ; then
 126   if test -n "$AWK" ; then
 127     REBUILD=
 128   fi
 129 fi
 130 AC_SUBST(REBUILD)
 131
 132 dnl The DU4 header files don't provide library prototypes unless
 133 dnl -std1 is given to the native cc.
 134 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 135
 136 gtk_save_LIBS=$LIBS
 137 LIBS="$LIBS -lm"
 138 AC_TRY_RUN([#include <math.h>
 139              int main (void) { return (log(1) != log(1.)); }],
 140      AC_MSG_RESULT(none needed),
 141      gtk_save_CFLAGS=$CFLAGS
 142      CFLAGS="$CFLAGS -std1"
 143      AC_TRY_RUN([#include <math.h>
 144                  int main (void) { return (log(1) != log(1.)); }],
 145          AC_MSG_RESULT(-std1),
 146          AC_MSG_RESULT()
 147          CFLAGS=$gtk_save_CFLAGS
 148          AC_MSG_WARN(
 149                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 150      )
 151 )
 152 LIBS=$gtk_save_LIBS
 153
 154 dnl NeXTStep cc seems to need this
 155 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 156 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 157   AC_MSG_RESULT(none needed),
 158   gtk_save_CFLAGS=$CFLAGS
 159   CFLAGS="$CFLAGS -posix"
 160   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 161     AC_MSG_RESULT(-posix),
 162     AC_MSG_RESULT()
 163     CFLAGS=$gtk_save_CFLAGS
 164     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 165
 166 if test x$with_glib = xyes ; then
 167   AC_MSG_ERROR([
 168 *** Directory must be specified for --with-glib])
 169 fi
 170
 171 if test x$with_glib = x ; then
 172   # Look for separately installed glib
 173
 174   AM_PATH_GLIB(1.1.6,,
 175     AC_MSG_ERROR([
 176 *** GLIB 1.1.6 or better is required. The latest version of GLIB
 177 *** is always available from ftp://ftp.gtk.org.]),
 178     gmodule)
 179
 180   glib_cflags=$GLIB_CFLAGS
 181   glib_libs=$GLIB_LIBS
 182 else
 183   # Use uninstalled glib (assume they got the version right)
 184
 185   GLIB_CONFIG=$with_glib/glib-config
 186   if test -x $GLIB_CONFIG ; then
 187     :
 188   else
 189     AC_MSG_ERROR([GLIB directory ($with_glib) not present or not configured])
 190   fi
 191
 192   # For use in gtk-config
 193   glib_cflags=`$GLIB_CONFIG --cflags`
 194   glib_libs=`$GLIB_CONFIG --libs`
 195
 196   glib_release=`$GLIB_CONFIG --version | sed 's%\\.[[0-9]]*$%%'`
 197
 198   # canonicalize relative paths
 199   case $with_glib in
 200     /*)
 201       glib_dir=$with_glib
 202       ;;
 203     *)
 204       glib_dir="\$(top_builddir)/$with_glib"
 205       ;;
 206   esac
 207
 208   GLIB_CFLAGS="-I$glib_dir"
 209   GLIB_LIBS=$glib_dir/libglib-$glib_release.la
 210
 211   AC_SUBST(GLIB_CFLAGS)
 212   AC_SUBST(GLIB_LIBS)
 213 fi
 214
 215 AC_SUBST(glib_cflags)
 216 AC_SUBST(glib_libs)
 217
 218 # Find the X11 include and library directories
 219 AC_PATH_X
 220 AC_PATH_XTRA
 221
 222 if test "x$x_includes" = "x"; then
 223   x_includes="/usr/include"
 224 fi
 225
 226 saved_cflags="$CFLAGS"
 227 saved_ldflags="$LDFLAGS"
 228
 229 CFLAGS="$CFLAGS $X_CFLAGS"
 230 LDFLAGS="$LDFLAGS $X_LDFLAGS $X_LIBS"
 231
 232 if test "x$no_x" = "xyes"; then
 233   AC_MSG_ERROR([
 234 *** X libraries or include files not found. Check 'config.log' for
 235 *** more details.])
 236 fi
 237
 238 # Checks for libraries.
 239 # Check for the X11 library
 240 AC_CHECK_LIB(X11, XOpenDisplay, x_libs="-lX11 $X_EXTRA_LIBS",
 241   AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
 242   $X_EXTRA_LIBS)
 243
 244 if test "x$enable_shm" = "xyes"; then
 245   # Check for the Xext library (needed for XShm extention)
 246   AC_CHECK_LIB(Xext, XShmAttach,
 247       x_libs="-lXext $x_libs",
 248       # On AIX, it is in XextSam instead, but we still need -lXext
 249       AC_CHECK_LIB(XextSam, XShmAttach,
 250           x_libs="-lXextSam -lXext $x_libs",
 251           no_xext_lib=yes, $x_libs),
 252       $x_libs)
 253 fi
 254
 255 # Check for shaped window extension
 256
 257 AC_CHECK_LIB(Xext, XShapeCombineMask,
 258       if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 259            x_libs="-lXext $x_libs"
 260       fi
 261       AC_DEFINE(HAVE_SHAPE_EXT),
 262       ,
 263       $x_libs)
 264
 265 # Check for XConvertCase (X11R6 specific)
 266
 267 AC_CHECK_LIB(X11, XConvertCase,
 268       AC_DEFINE(HAVE_XCONVERTCASE),
 269       ,
 270       $x_libs)
 271
 272 # Check for XIM support.
 273
 274 AC_CHECK_LIB(X11, XUnregisterIMInstantiateCallback,
 275             : ,
 276             enable_xim=no,
 277             $x_libs)
 278
 279 if test "x$enable_xim" = "xyes"; then
 280   GTK_XIM_FLAGS="-DUSE_XIM"
 281 fi
 282
 283 x_cflags="$X_CFLAGS"
 284 x_ldflags="$X_LDFLAGS $X_LIBS"
 285
 286 # set up things for XInput
 287
 288 if test "x$with_xinput" = "xgxi" || test "x$with_xinput" = "xyes"; then
 289   AC_DEFINE(XINPUT_GXI)
 290   xinput_progs=gxid
 291   x_libs="-lXi $x_libs"
 292 elif test "x$with_xinput" = "xxfree"; then
 293   AC_DEFINE(XINPUT_XFREE)
 294   x_libs="-lXi $x_libs"
 295 else
 296   AC_DEFINE(XINPUT_NONE)
 297 fi
 298
 299 # Threads
 300
 301 if test "x$with_threads" = "xposix" || test "x$with_threads" = "xyes"; then
 302   AC_CHECK_LIB(pthread, pthread_attr_init,
 303     [AC_DEFINE(USE_PTHREADS)
 304     x_libs="$x_libs -lpthread"
 305     GTK_THREAD_FLAGS="-D_REENTRANT"],
 306     # AIX has libpthreads, cause they're special. Special friends (TM)
 307     AC_CHECK_LIB(pthreads, pthread_attr_init,
 308       [AC_DEFINE(USE_PTHREADS)
 309       x_libs="$x_libs -lpthreads"
 310       GTK_THREAD_FLAGS="-D_REENTRANT -D_THREAD_SAFE"]))
 311 fi
 312
 313 CFLAGS="$saved_cflags"
 314 LDFLAGS="$saved_ldflags"
 315
 316 AC_SUBST(x_cflags)
 317 AC_SUBST(x_includes)
 318 AC_SUBST(x_ldflags)
 319 AC_SUBST(x_libs)
 320 AC_SUBST(xinput_progs)
 321
 322 if test "x$enable_shm" = "xyes"; then
 323   # Check for shared memory
 324   AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
 325   AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
 326
 327   # Check whether shmctl IPC_RMID allowes subsequent attaches
 328   if test "$ac_cv_header_sys_shm_h" = "yes"; then
 329     AC_MSG_CHECKING(whether shmctl IPC_RMID allowes subsequent attaches)
 330     AC_TRY_RUN([
 331           #include <sys/types.h>
 332           #include <sys/ipc.h>
 333           #include <sys/shm.h>
 334           int main()
 335           {
 336             int id;
 337             char *shmaddr;
 338           id = shmget (IPC_PRIVATE, 4, IPC_CREAT | 0777);
 339           if (id == -1)
 340             exit (2);
 341             shmaddr = shmat (id, 0, 0);
 342             shmctl (id, IPC_RMID, 0);
 343             if ((char*) shmat (id, 0, 0) == (char*) -1)
 344             {
 345               shmdt (shmaddr);
 346               exit (1);
 347             }
 348             shmdt (shmaddr);
 349             shmdt (shmaddr);
 350             exit (0);
 351           }
 352       ],
 353       AC_DEFINE(IPC_RMID_DEFERRED_RELEASE)
 354         AC_MSG_RESULT(yes),
 355       AC_MSG_RESULT(no),
 356       AC_MSG_RESULT(assuming no))
 357   fi
 358
 359   # Check for the X shared memory extension header file
 360   AC_MSG_CHECKING(X11/extensions/XShm.h)
 361   if test "x$no_xext_lib" = "xyes"; then
 362     AC_MSG_RESULT(no)
 363     no_xshm=yes
 364   else
 365     if test -f "$x_includes/X11/extensions/XShm.h"; then
 366       AC_MSG_RESULT(yes)
 367       AC_DEFINE(HAVE_XSHM_H)
 368     else
 369       AC_MSG_RESULT(no)
 370       no_xshm=yes
 371     fi
 372   fi
 373 fi
 374
 375 # Check for private display resource base variable
 376 AC_MSG_CHECKING(resource base field in XDisplay)
 377 AC_CACHE_VAL(gtk_cv_display_resource_base,
 378 [AC_TRY_RUN([
 379 #define XLIB_ILLEGAL_ACCESS
 380 #include <X11/Xlib.h>
 381
 382 int
 383 main ()
 384 {
 385   Display *display;
 386
 387   return 0;
 388
 389   display->resource_base;
 390 }],
 391 gtk_cv_display_resource_base="resource_base",
 392 gtk_cv_display_resource_base="private3")])
 393 AC_MSG_RESULT($gtk_cv_display_resource_base)
 394 AC_DEFINE_UNQUOTED(RESOURCE_BASE, gdk_display->$gtk_cv_display_resource_base)
 395
 396 # Check if X_LOCALE definition is necessary
 397
 398 AC_MSG_CHECKING(need -DX_LOCALE)
 399
 400 AC_TRY_RUN([
 401 #include <stdio.h>
 402 #include <locale.h>
 403
 404 int
 405 main ()
 406 {
 407   return setlocale (LC_ALL, "${with_locale}") == NULL;
 408 }],
 409 need_x_locale=no,
 410 need_x_locale=yes)
 411 AC_MSG_RESULT($need_x_locale)
 412
 413 if test $need_x_locale = yes; then
 414   GTK_LOCALE_CFLAGS="-DX_LOCALE"
 415 fi
 416
 417 # Checks for header files.
 418 AC_HEADER_STDC
 419
 420 # Checks for typedefs, structures, and compiler characteristics.
 421 AC_C_CONST
 422
 423 # Checks for library functions.
 424 AC_TYPE_SIGNAL
 425 AC_FUNC_MMAP
 426
 427 # Check if <sys/select.h> needs to be included for fd_set
 428 AC_MSG_CHECKING([for fd_set])
 429 AC_TRY_COMPILE([#include <sys/types.h>],
 430         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 431 if test $gtk_ok = yes; then
 432     AC_MSG_RESULT([yes, found in sys/types.h])
 433 else
 434     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 435     if test $gtk_ok = yes; then
 436         AC_DEFINE(HAVE_SYS_SELECT_H)
 437         AC_MSG_RESULT([yes, found in sys/select.h])
 438     else
 439         AC_DEFINE(NO_FD_SET)
 440         AC_MSG_RESULT(no)
 441     fi
 442 fi
 443
 444 # Duplicate `widechar' tests from `glib'.
 445 # Check for wchar.h
 446 if test x = y; then
 447   # will not be executed
 448   # hack so as not to update `acconfig.h'
 449   AC_CHECK_HEADERS(wchar.h wctype.h)
 450   AC_CHECK_FUNCS(broken_wctype)
 451 fi
 452
 453 AC_MSG_CHECKING(for wchar.h)
 454 AC_TRY_CPP([#include <wchar.h>], gtk_ok=yes, gtk_ok=no)
 455 if test $gtk_ok = yes; then
 456    ac_kludge=HAVE_WCHAR_H
 457    AC_DEFINE($ac_kludge)
 458 fi
 459 AC_MSG_RESULT($gtk_ok)
 460
 461 # Check for wctype.h (for iswalnum)
 462
 463 AC_MSG_CHECKING(for wctype.h)
 464 AC_TRY_CPP([#include <wctype.h>], gtk_ok=yes, gtk_ok=no)
 465 if test $gtk_ok = yes; then
 466    ac_kludge=HAVE_WCTYPE_H
 467    AC_DEFINE($ac_kludge)
 468 fi
 469 AC_MSG_RESULT($gtk_ok)
 470
 471 # in Solaris 2.5, `iswalnum' is in -lw
 472 GDK_WLIBS=
 473 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 474
 475 # The following is necessary for Linux libc-5.4.38
 476 oLIBS="$LIBS"
 477 LIBS="$LIBS $GDK_WLIBS"
 478 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 479 AC_TRY_LINK([#include <stdlib.h>],[
 480 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 481 #  ifdef HAVE_WCTYPE_H
 482 #    include <wctype.h>
 483 #  else
 484 #    ifdef HAVE_WCHAR_H
 485 #      include <wchar.h>
 486 #    endif
 487 #  endif
 488 #else
 489 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 490 #endif
 491 iswalnum((wchar_t) 0);
 492 ], gtk_ok=yes, gtk_ok=no)
 493 LIBS="$oLIBS"
 494
 495 if test $gtk_ok = no; then
 496    ac_kludge=HAVE_BROKEN_WCTYPE
 497    AC_DEFINE($ac_kludge)
 498    GDK_WLIBS=
 499 fi
 500 AC_MSG_RESULT($gtk_ok)
 501 AC_SUBST(GDK_WLIBS)
 502
 503 AC_SUBST(GTK_DEBUG_FLAGS)
 504 AC_SUBST(GTK_XIM_FLAGS)
 505 AC_SUBST(GTK_LOCALE_FLAGS)
 506 AC_SUBST(GTK_THREAD_FLAGS)
 507
 508 AC_OUTPUT([
 509 Makefile
 510 gtk-config
 511 docs/Makefile
 512 gdk/Makefile
 513 gtk/Makefile
 514 gtk/gtkfeatures.h
 515 ], [chmod +x gtk-config])