Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(gdk/gdktypes.h)
   3
   4 # In the following, there are a the following variants
   5 # of GLib cflags and libs variables
   6 #
   7 # GLIB_CFLAGS:  cflags for compiling libraries and example progs
   8 # GLIB_LIBS:    libraries for linking example programs
   9 # GLIB_DEPLIBS: libraries for linking libraries against
  10
  11
  12 ## We could have pkg-config uniquify the ldflags and cflags by calling
  13 ## it once with both the GLib and Pango package names, but we don't,
  14 ## someone should fix that.
  15
  16
  17 # Save this value here, since automake will set cflags later
  18 cflags_set=${CFLAGS+set}
  19
  20 dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  21 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  22 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  23 #
  24 # Making releases:
  25 #   GTK_MICRO_VERSION += 1;
  26 #   GTK_INTERFACE_AGE += 1;
  27 #   GTK_BINARY_AGE += 1;
  28 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  29 # if backwards compatibility has been broken,
  30 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  31 #
  32 GTK_MAJOR_VERSION=1
  33 GTK_MINOR_VERSION=3
  34 GTK_MICRO_VERSION=2
  35 GTK_INTERFACE_AGE=0
  36 GTK_BINARY_AGE=0
  37 GTK_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$GTK_MICRO_VERSION
  38 dnl
  39 AC_DIVERT_POP()dnl
  40
  41 AC_SUBST(GTK_MAJOR_VERSION)
  42 AC_SUBST(GTK_MINOR_VERSION)
  43 AC_SUBST(GTK_MICRO_VERSION)
  44 AC_SUBST(GTK_INTERFACE_AGE)
  45 AC_SUBST(GTK_BINARY_AGE)
  46 AC_SUBST(GTK_VERSION)
  47
  48 # libtool versioning
  49 LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  50 LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  51 LT_REVISION=$GTK_INTERFACE_AGE
  52 LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  53 AC_SUBST(LT_RELEASE)
  54 AC_SUBST(LT_CURRENT)
  55 AC_SUBST(LT_REVISION)
  56 AC_SUBST(LT_AGE)
  57
  58 #
  59 # gdk-pixbuf gets versioned separately, and for now, using standard
  60 # libtool versioning, not GTK+-style versioning
  61 #
  62 GDK_PIXBUF_MAJOR=0
  63 GDK_PIXBUF_MINOR=8
  64 GDK_PIXBUF_MICRO=0
  65 GDK_PIXBUF_VERSION="${GDK_PIXBUF_MAJOR}.${GDK_PIXBUF_MINOR}.${GDK_PIXBUF_MICRO}"
  66 AC_SUBST(GDK_PIXBUF_MAJOR)
  67 AC_SUBST(GDK_PIXBUF_MINOR)
  68 AC_SUBST(GDK_PIXBUF_MICRO)
  69 AC_SUBST(GDK_PIXBUF_VERSION)
  70
  71 # For automake.
  72 VERSION=$GTK_VERSION
  73 PACKAGE=gtk+
  74
  75 GETTEXT_PACKAGE=gtk20
  76 AC_SUBST(GETTEXT_PACKAGE)
  77 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
  78
  79 # Save this value here, since automake will set cflags later
  80 cflags_set=${CFLAGS+set}
  81
  82 dnl Initialize automake stuff
  83 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  84
  85 # Specify a configuration file
  86 AM_CONFIG_HEADER(config.h)
  87
  88 dnl Initialize libtool
  89 AM_PROG_LIBTOOL
  90
  91 dnl Initialize maintainer mode
  92 AM_MAINTAINER_MODE
  93
  94 AC_CANONICAL_HOST
  95
  96 dnl figure debugging default, prior to $ac_help setup
  97 dnl
  98 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  99 if test `expr $GTK_MINOR_VERSION \% 2` = 1 ; then
 100         debug_default=yes
 101 else
 102         debug_default=minimum
 103 fi
 104 AC_DIVERT_POP()dnl
 105
 106 dnl declare --enable-* args and collect ac_help strings
 107 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 108 AC_ARG_ENABLE(shm, [  --enable-shm            support shared memory if available [default=yes]],
 109                    echo $enable_shm, enable_shm="yes")
 110 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 111                     , enable_ansi=no)
 112 AC_ARG_WITH(glib, [  --with-glib=DIR         Use uninstalled copy of glib])
 113 AC_ARG_ENABLE(xim, [  --enable-xim            support XIM [default=yes]],
 114                         , enable_xim="yes")
 115 AC_ARG_ENABLE(xim_inst, [  --disable-xim-inst      does not use xim instantiate callback],
 116                         , enable_xim_inst="maybe")
 117 AC_ARG_ENABLE(xkb, [  --enable-xkb            support XKB [default=maybe]],
 118                         , enable_xkb="maybe")
 119 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 120 AC_ARG_WITH(locale, [  --with-locale=LOCALE    locale name you want to use ])
 121
 122 AC_ARG_WITH(xinput, [  --with-xinput=[no/gxi/xfree] support XInput ])
 123
 124 gdktarget=x11
 125 gdktargetlib=libgdk-x11-1.3.la
 126 gtktargetlib=libgtk-x11-1.3.la
 127 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[x11/nanox/linux-fb] select GDK target [default=x11] ],
 128         gdktarget=$with_gdktarget)
 129
 130 AC_SUBST(gdktarget)
 131 case $gdktarget in
 132   x11|nanox|linux-fb) ;;
 133   *) AC_MSG_ERROR([Invalid target for GDK: use x11, nanox or linux-fb.]);;
 134 esac
 135
 136 AC_ARG_ENABLE(shadowfb, [  --disable-shadowfb      disable shadowfb support for linux-fb],,enable_shadowfb=yes)
 137
 138 if test "x$enable_debug" = "xyes"; then
 139   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 140   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 141 else
 142   if test "x$enable_debug" = "xno"; then
 143     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 144   else
 145     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 146   fi
 147 fi
 148
 149 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 150
 151
 152 # Build time sanity check...
 153 AM_SANITY_CHECK
 154
 155 # Checks for programs.
 156 AC_PROG_CC
 157 AC_ISC_POSIX
 158 AM_PROG_CC_STDC
 159 AC_PROG_INSTALL
 160 AC_PROG_MAKE_SET
 161
 162 changequote(,)dnl
 163 if test "x$GCC" = "xyes"; then
 164   case " $CFLAGS " in
 165   *[\ \ ]-Wall[\ \      ]*) ;;
 166   *) CFLAGS="$CFLAGS -Wall" ;;
 167   esac
 168
 169   if test "x$enable_ansi" = "xyes"; then
 170     case " $CFLAGS " in
 171     *[\ \       ]-ansi[\ \      ]*) ;;
 172     *) CFLAGS="$CFLAGS -ansi" ;;
 173     esac
 174
 175     case " $CFLAGS " in
 176     *[\ \       ]-pedantic[\ \  ]*) ;;
 177     *) CFLAGS="$CFLAGS -pedantic" ;;
 178     esac
 179   fi
 180 fi
 181 changequote([,])dnl
 182
 183 # Honor aclocal flags
 184 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 185
 186 # libtool option to control which symbols are exported
 187 # right now, symbols starting with _ are not exported
 188 LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 189 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 190
 191 # define a MAINT-like variable REBUILD which is set if Perl
 192 # and awk are found, so autogenerated sources can be rebuilt
 193
 194 AC_PROG_AWK
 195 AC_CHECK_PROGS(PERL, perl5 perl)
 196
 197 # We would like indent, but don't require it.
 198 AC_CHECK_PROG(INDENT, indent, indent)
 199
 200 REBUILD=\#
 201 if test "x$enable_rebuilds" = "xyes" && \
 202      test -n "$PERL" && \
 203      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 204      test -n "$AWK" ; then
 205   REBUILD=
 206 fi
 207 AC_SUBST(REBUILD)
 208
 209 AC_CHECK_FUNCS(lstat mkstemp sigsetjmp bind_textdomain_codeset)
 210
 211 AC_MSG_CHECKING(whether make is GNU Make)
 212 STRIP_BEGIN=
 213 STRIP_END=
 214 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 215         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 216         STRIP_END=')'
 217         AC_MSG_RESULT(yes)
 218 else
 219         AC_MSG_RESULT(no)
 220 fi
 221 STRIP_DUMMY=
 222 AC_SUBST(STRIP_DUMMY)
 223 AC_SUBST(STRIP_BEGIN)
 224 AC_SUBST(STRIP_END)
 225
 226 # i18n stuff
 227 ALL_LINGUAS="az ca cs da de el en_GB en@IPA es et eu fa fi fr ga gl he hr hu ia it ja ko lt nl no pl pt pt_BR ro ru sk sl sp sr sv tr uk wa zh_TW zh_CN"
 228 AM_GTK_GNU_GETTEXT
 229 LIBS="$LIBS $INTLLIBS"
 230
 231 # AM_GTK_GNU_GETTEXT above substs $DATADIRNAME
 232 # this is the directory where the *.{mo,gmo} files are installed
 233 gtklocaledir='${prefix}/${DATADIRNAME}/locale'
 234 AC_SUBST(gtklocaledir)
 235
 236 dnl The DU4 header files don't provide library prototypes unless
 237 dnl -std1 is given to the native cc.
 238 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 239
 240 gtk_save_LIBS=$LIBS
 241 LIBS="$LIBS -lm"
 242 AC_TRY_RUN([#include <math.h>
 243              int main (void) { return (log(1) != log(1.)); }],
 244      AC_MSG_RESULT(none needed),
 245      gtk_save_CFLAGS="$CFLAGS"
 246      CFLAGS="$CFLAGS -std1"
 247      AC_TRY_RUN([#include <math.h>
 248                  int main (void) { return (log(1) != log(1.)); }],
 249          AC_MSG_RESULT(-std1),
 250          AC_MSG_RESULT()
 251          CFLAGS="$gtk_save_CFLAGS"
 252          AC_MSG_WARN(
 253                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 254          true
 255      ),
 256      AC_MSG_RESULT(none needed)
 257 )
 258 LIBS=$gtk_save_LIBS
 259
 260 MATH_LIB=-lm
 261 GTK_LIBS_EXTRA=
 262 AC_MSG_CHECKING(for the BeOS)
 263 case $host in
 264   *-*-beos*)
 265     AC_MSG_RESULT(yes)
 266     GTK_LIBS_EXTRA="-L\$(top_builddir_full)/gdk/.libs -lgdk"
 267     MATH_LIB=
 268   ;;
 269   *)
 270     AC_MSG_RESULT(no)
 271   ;;
 272 esac
 273 AC_SUBST(MATH_LIB)
 274 AC_SUBST(GTK_LIBS_EXTRA)
 275
 276 dnl NeXTStep cc seems to need this
 277 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 278 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 279   AC_MSG_RESULT(none needed),
 280   gtk_save_CFLAGS="$CFLAGS"
 281   CFLAGS="$CFLAGS -posix"
 282   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 283     AC_MSG_RESULT(-posix),
 284     AC_MSG_RESULT()
 285     CFLAGS="$gtk_save_CFLAGS"
 286     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 287
 288
 289 #
 290 # Find pkg-config
 291 #
 292 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 293 if test x$PKG_CONFIG = xno ; then
 294   AC_MSG_ERROR([*** pkg-config not found. See http://pkgconfig.sourceforge.net])
 295 fi
 296
 297 if ! pkg-config --atleast-pkgconfig-version 0.5 ; then
 298   AC_MSG_ERROR([*** pkg-config too old; version 0.5 or better required.])
 299 fi
 300
 301 if test x$with_glib = xyes ; then
 302   AC_MSG_ERROR([
 303 *** Directory must be specified for --with-glib])
 304 fi
 305
 306 if test x$with_glib = x ; then
 307
 308   # Look for separately installed glib
 309
 310   GLIB_PACKAGES="gobject-2.0 gmodule-2.0 gthread-2.0"
 311   GLIB_REQUIRED_VERSION=1.3.2
 312
 313   AC_MSG_CHECKING(GLib flags)
 314   if $PKG_CONFIG --atleast-version $GLIB_REQUIRED_VERSION glib-2.0 ; then
 315         GLIB_CFLAGS=`$PKG_CONFIG --cflags $GLIB_PACKAGES`
 316         GLIB_LIBS=`$PKG_CONFIG --libs $GLIB_PACKAGES`
 317         GLIB_DEPLIBS=$GLIB_LIBS
 318
 319         AC_MSG_RESULT($GLIB_CFLAGS $GLIB_LIBS)
 320   else
 321         AC_MSG_ERROR([
 322 *** GLIB $GLIB_REQUIRED_VERSION or newer is required. The latest version of GLIB
 323 *** is always available from ftp://ftp.gtk.org/.
 324   ])
 325   fi
 326
 327 else
 328   # Use uninstalled glib (assume they got the version right)
 329
 330   if test -e glib-2.0.pc ; then
 331     :
 332   else
 333     AC_MSG_ERROR([GLIB directory ($with_glib) not present or not configured])
 334   fi
 335
 336   # canonicalize relative paths
 337   case $with_glib in
 338     /*)
 339       glib_dir=$with_glib
 340       ;;
 341     *)
 342       glib_dir="\$(top_builddir)/$with_glib"
 343       ;;
 344   esac
 345
 346   GLIB_CFLAGS="-I$glib_dir -I$glib_dir/gmodule"
 347   GLIB_LIBS="$glib_dir/libglib-1.3.la $glib_dir/gmodule/libgmodule-1.3.la"
 348   GLIB_DEPLIBS=
 349 fi
 350
 351 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 352 AC_SUBST(GLIB_CFLAGS)
 353 AC_SUBST(GLIB_LIBS)
 354 AC_SUBST(GLIB_DEPLIBS)
 355
 356 AC_CHECK_HEADERS(dirent.h, AC_DEFINE(HAVE_DIRENT_H))
 357 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 358 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 359 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 360
 361 saved_cflags="$CFLAGS"
 362 saved_ldflags="$LDFLAGS"
 363
 364 if test "x$gdktarget" = "xx11"; then
 365   # Find the X11 include and library directories
 366   AC_PATH_X
 367   AC_PATH_XTRA
 368
 369   if test "x$x_includes" = "x"; then
 370     x_includes="/usr/include"
 371   fi
 372
 373   CFLAGS="$CFLAGS $X_CFLAGS"
 374   LDFLAGS="$LDFLAGS $X_LDFLAGS $X_LIBS"
 375
 376   if test "x$no_x" = "xyes"; then
 377     AC_MSG_ERROR([
 378 *** X libraries or include files not found. Check 'config.log' for
 379 *** more details.])
 380   fi
 381
 382   # Checks for libraries.
 383   # Check for the X11 library
 384   AC_CHECK_LIB(X11, XOpenDisplay, x_libs="-lX11 $X_EXTRA_LIBS",
 385     AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
 386     $X_EXTRA_LIBS)
 387
 388   if test "x$enable_shm" = "xyes"; then
 389     # Check for the Xext library (needed for XShm extention)
 390     AC_CHECK_LIB(Xext, XShmAttach,
 391         x_libs="-lXext $x_libs",
 392         # On AIX, it is in XextSam instead, but we still need -lXext
 393         AC_CHECK_LIB(XextSam, XShmAttach,
 394             x_libs="-lXextSam -lXext $x_libs",
 395             no_xext_lib=yes, $x_libs),
 396         $x_libs)
 397   fi
 398
 399   # Check for shaped window extension
 400
 401   AC_CHECK_LIB(Xext, XShapeCombineMask,
 402       if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 403            x_libs="-lXext $x_libs"
 404       fi
 405       AC_DEFINE(HAVE_SHAPE_EXT),
 406       ,
 407       $x_libs)
 408
 409   # Check for XConvertCase (X11R6 specific)
 410
 411   AC_CHECK_LIB(X11, XConvertCase,
 412       AC_DEFINE(HAVE_XCONVERTCASE),
 413       ,
 414       $x_libs)
 415
 416   #
 417   # Checks for FreeType
 418   #
 419   FREETYPE_LIBS=
 420   FREETYPE_CFLAGS=
 421   have_freetype=false
 422   AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
 423   if test "x$FREETYPE_CONFIG" != "xno" ; then
 424     FREETYPE_CFLAGS=`freetype-config --cflags`
 425     FREETYPE_LIBS=`freetype-config --libs`
 426
 427     AC_CHECK_LIB(freetype, FT_New_Face, have_freetype=true
 428                  ,:,$FREETYPE_LIBS)
 429   fi
 430   AC_SUBST(FREETYPE_CFLAGS)
 431
 432   #
 433   # Checks for Xft/XRender
 434   #
 435   have_xft=false
 436   XFT_LIBS=""
 437   XFT_CFLAGS=""
 438   if test $have_freetype = true ; then
 439     AC_CHECK_LIB(Xrender, XRenderFindFormat,
 440       AC_CHECK_LIB(Xft, XftFontOpen, have_xft=true, :, -lXrender -lXext $X_LIBS $FREETYPE_LIBS)
 441     ,:,-lXext $X_LIBS)
 442
 443     if $have_xft = 'true' ; then
 444       X_LIBS="-lXft -lXrender -lXext $FREETYPE_LIBS $X_LIBS"
 445       AC_DEFINE(HAVE_XFT)
 446     fi
 447   fi
 448
 449   AC_SUBST(XFT_LIBS)
 450   AM_CONDITIONAL(HAVE_XFT, $have_xft)
 451
 452   # Check for XIM support.
 453
 454   AC_CHECK_LIB(X11, XUnregisterIMInstantiateCallback,
 455             : ,
 456             enable_xim_inst="no",
 457             $x_libs)
 458
 459   # On Solaris, calling XRegisterIMInstantiateCallback seems to
 460   # cause an immediate segfault, so we disable it, unless
 461   # the user specifically forces it to be on.
 462
 463   if test x$enable_xim_inst = xmaybe ; then
 464     case host in
 465           *-*-solaris*)
 466             enable_xim_inst="no"
 467             ;;
 468           *)
 469             enable_xim_inst="yes"
 470             ;;
 471     esac
 472   fi
 473
 474   if test "x$enable_xim" = "xyes"; then
 475     GTK_XIM_FLAGS="-DUSE_XIM"
 476     if test "x$enable_xim_inst" = "xyes"; then
 477       AC_DEFINE(USE_X11R6_XIM)
 478     fi
 479   fi
 480
 481   # Check for XKB support.
 482
 483   if test "x$enable_xkb" = "xyes"; then
 484         AC_MSG_WARN(XKB support explicitly enabled)
 485         AC_DEFINE(HAVE_XKB)
 486   elif test "x$enable_xkb" = "xmaybe"; then
 487         AC_CHECK_LIB(X11, XkbQueryExtension,
 488                      AC_DEFINE(HAVE_XKB),
 489                      ,
 490                      $x_libs)
 491   else
 492         AC_MSG_WARN(XKB support explicitly disabled)
 493   fi
 494
 495   x_cflags="$X_CFLAGS"
 496   x_ldflags="$X_LDFLAGS $X_LIBS"
 497
 498   # set up things for XInput
 499
 500   if test "x$with_xinput" = "xgxi" || test "x$with_xinput" = "xyes"; then
 501     AC_DEFINE(XINPUT_GXI)
 502     xinput_progs=gxid
 503     x_libs="-lXi $x_libs"
 504   elif test "x$with_xinput" = "xxfree"; then
 505     AC_DEFINE(XINPUT_XFREE)
 506     x_libs="-lXi $x_libs"
 507   else
 508     AC_DEFINE(XINPUT_NONE)
 509   fi
 510
 511   AM_CONDITIONAL(XINPUT_GXI, test x$with_xinput = xgxi)
 512   AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree)
 513
 514   if test "x$enable_shm" = "xyes"; then
 515     # Check for shared memory
 516     AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
 517     AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
 518
 519     # Check for the X shared memory extension header file
 520     AC_MSG_CHECKING(X11/extensions/XShm.h)
 521     if test "x$no_xext_lib" = "xyes"; then
 522       AC_MSG_RESULT(no)
 523       no_xshm=yes
 524     else
 525       if test -f "$x_includes/X11/extensions/XShm.h"; then
 526         AC_MSG_RESULT(yes)
 527         AC_DEFINE(HAVE_XSHM_H)
 528       else
 529         AC_MSG_RESULT(no)
 530         no_xshm=yes
 531       fi
 532     fi
 533   fi
 534
 535   more_cflags="$x_cflags"
 536   more_ldflags="$x_ldflags"
 537   more_libs="$x_libs"
 538   more_includes="$x_includes"
 539
 540   # these are already defined above
 541   #gdktargetlib = "libgdk-x11-1.3.la"
 542   #gtktargetlib = "libgtk-x11-1.3.la"
 543
 544   AM_CONDITIONAL(USE_X11, true)
 545 else
 546   AM_CONDITIONAL(USE_X11, false)
 547 fi
 548
 549 if test "x$gdktarget" = "xnanox"; then
 550   AC_CHECK_LIB(nano-X, GrOpen,,AC_MSG_ERROR([nano-X libraries not found.]))
 551   # nano-X may require additional libraries
 552   more_cflags=
 553   more_ldflags=
 554   more_libs="-lnano-X"
 555   more_includes=
 556
 557   gdktargetlib="libgdk-nanox-1.3.la"
 558   gtktargetlib="libgtk-nanox-1.3.la"
 559
 560   with_xinput=no
 561   AC_DEFINE(XINPUT_NONE)
 562   x_cflags=
 563   x_includes=
 564   x_ldflags=
 565   x_libs=
 566   xinput_progs=
 567   AM_CONDITIONAL(USE_NANOX, true)
 568 else
 569   AM_CONDITIONAL(USE_NANOX, false)
 570 fi
 571
 572 if test "x$gdktarget" = "xlinux-fb"; then
 573   more_cflags=
 574   more_ldflags=
 575   more_libs=
 576   more_includes=
 577
 578   gdktargetlib="libgdk-linux-fb-1.3.la"
 579   gtktargetlib="libgtk-linux-fb-1.3.la"
 580
 581   with_xinput=no
 582   AC_DEFINE(XINPUT_NONE)
 583   x_cflags=
 584   x_includes=
 585   x_ldflags=
 586   x_libs=
 587   xinput_progs=
 588
 589   AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
 590   if test x$FREETYPE_CONFIG = xno ; then
 591     AC_MSG_ERROR([*** freetype-config not found])
 592   fi
 593
 594   FREETYPE_CFLAGS="`$FREETYPE_CONFIG --cflags`"
 595   FREETYPE_LIBS="`$FREETYPE_CONFIG --libs`"
 596   CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 597
 598   if test x$enable_shadowfb = xyes ; then
 599     AC_DEFINE(ENABLE_SHADOW_FB)
 600   fi
 601
 602   AM_CONDITIONAL(USE_LINUX_FB, true)
 603 else
 604   AM_CONDITIONAL(USE_LINUX_FB, false)
 605 fi
 606 AC_SUBST(ENABLE_SHADOW_FB)
 607 AC_SUBST(FREETYPE_LIBS)
 608 AC_SUBST(FREETYPE_CFLAGS)
 609
 610 #
 611 # Pick correct Pango packages to use
 612 #
 613
 614 if test "x$gdktarget" = "xx11"; then
 615         if $have_xft = true ; then
 616             PANGO_PACKAGES="pangox pangoxft"
 617         else
 618             PANGO_PACKAGES=pangox
 619         fi
 620 elif test "x$gdktarget" = "xlinux-fb"; then
 621         PANGO_PACKAGES=pangoft2
 622 else
 623         PANGO_PACKAGES=pango
 624 fi
 625
 626 AC_SUBST(PANGO_PACKAGES)
 627
 628 # Check for Pango flags
 629
 630 AC_MSG_CHECKING(Pango flags)
 631 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
 632         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
 633         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
 634
 635         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
 636 else
 637         AC_MSG_ERROR([
 638 *** Pango not found. Pango is required to build GTK+.
 639 *** See http://www.pango.org for Pango information.
 640 *** For the framebuffer target, you will need to build
 641 *** Pango with freetype support.
 642 ])
 643 fi
 644
 645 CFLAGS="$CFLAGS $PANGO_CFLAGS"
 646 AC_SUBST(PANGO_LIBS)
 647 AC_SUBST(PANGO_CFLAGS)
 648
 649 AC_CHECK_LIB(pango, pango_context_new, :, AC_MSG_ERROR([
 650 *** Can't link to Pango. Pango is required to build
 651 *** GTK+. For more information see http://www.pango.org]), $PANGO_LIBS $x_ldflags $x_libs)
 652
 653 CFLAGS="$saved_cflags"
 654 LDFLAGS="$saved_ldflags"
 655
 656 AC_SUBST(x_cflags)
 657 AC_SUBST(x_includes)
 658 AC_SUBST(x_ldflags)
 659 AC_SUBST(x_libs)
 660 AC_SUBST(xinput_progs)
 661
 662 AC_SUBST(more_cflags)
 663 AC_SUBST(more_includes)
 664 AC_SUBST(more_ldflags)
 665 AC_SUBST(more_libs)
 666 AC_SUBST(gdktargetlib)
 667 AC_SUBST(gtktargetlib)
 668
 669
 670 # Check if X_LOCALE definition is necessary
 671
 672 AC_MSG_CHECKING(need -DX_LOCALE)
 673
 674 AC_TRY_RUN([
 675 #include <stdio.h>
 676 #include <locale.h>
 677
 678 int
 679 main ()
 680 {
 681   return setlocale (LC_ALL, "${with_locale}") == NULL;
 682 }],
 683 need_x_locale=no,
 684 need_x_locale=yes,
 685 need_x_locale=no)
 686 AC_MSG_RESULT($need_x_locale)
 687
 688 if test $need_x_locale = yes; then
 689   GTK_LOCALE_FLAGS="-DX_LOCALE"
 690 fi
 691
 692 # Checks for header files.
 693 AC_HEADER_STDC
 694
 695 # Checks for typedefs, structures, and compiler characteristics.
 696 AC_C_CONST
 697
 698 # Checks for library functions.
 699 AC_TYPE_SIGNAL
 700 AC_FUNC_MMAP
 701
 702 AC_CHECK_FUNCS(getresuid)
 703 AC_TYPE_UID_T
 704
 705 # Check if <sys/select.h> needs to be included for fd_set
 706 AC_MSG_CHECKING([for fd_set])
 707 AC_TRY_COMPILE([#include <sys/types.h>],
 708         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 709 if test $gtk_ok = yes; then
 710     AC_MSG_RESULT([yes, found in sys/types.h])
 711 else
 712     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 713     if test $gtk_ok = yes; then
 714         AC_DEFINE(HAVE_SYS_SELECT_H)
 715         AC_MSG_RESULT([yes, found in sys/select.h])
 716     else
 717         AC_DEFINE(NO_FD_SET)
 718         AC_MSG_RESULT(no)
 719     fi
 720 fi
 721
 722 # `widechar' tests for gdki18n.h
 723 AC_MSG_CHECKING(for wchar.h)
 724 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 725 if test $gdk_wchar_h = yes; then
 726    AC_DEFINE(HAVE_WCHAR_H,1,[Have wchar.h include file])
 727 fi
 728 AC_MSG_RESULT($gdk_wchar_h)
 729
 730 # Check for wctype.h (for iswalnum)
 731 AC_MSG_CHECKING(for wctype.h)
 732 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 733 if test $gdk_wctype_h = yes; then
 734    AC_DEFINE(HAVE_WCTYPE_H,1,[Have wctype.h include file])
 735 fi
 736 AC_MSG_RESULT($gdk_wctype_h)
 737
 738 # in Solaris 2.5, `iswalnum' is in -lw
 739 GDK_WLIBS=
 740 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 741
 742 oLIBS="$LIBS"
 743 LIBS="$LIBS $GDK_WLIBS"
 744 # The following is necessary for Linux libc-5.4.38
 745 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 746 AC_TRY_LINK([#include <stdlib.h>],[
 747 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 748 #  ifdef HAVE_WCTYPE_H
 749 #    include <wctype.h>
 750 #  else
 751 #    ifdef HAVE_WCHAR_H
 752 #      include <wchar.h>
 753 #    endif
 754 #  endif
 755 #else
 756 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 757 #endif
 758 iswalnum((wchar_t) 0);
 759 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 760 LIBS="$oLIBS"
 761
 762 if test $gdk_working_wctype = no; then
 763    AC_DEFINE(HAVE_BROKEN_WCTYPE,1,[Is the wctype implementation broken])
 764    GDK_WLIBS=
 765 fi
 766 AC_MSG_RESULT($gdk_working_wctype)
 767 AC_SUBST(GDK_WLIBS)
 768
 769 AC_SUBST(GTK_DEBUG_FLAGS)
 770 AC_SUBST(GTK_XIM_FLAGS)
 771 AC_SUBST(GTK_LOCALE_FLAGS)
 772
 773 ##################################################
 774 # Checks for gdk-pixbuf
 775 ##################################################
 776
 777 AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
 778
 779 AC_ARG_ENABLE(modules, [  --disable-modules       Disables dynamic module loading],[
 780         if test x$withval = xyes; then
 781             with_modules=yes
 782         else
 783             with_modules=no
 784         fi
 785 ])
 786
 787 dynworks=false
 788 deps=
 789 if test x$with_modules = xno; then
 790     AC_MSG_RESULT(no)
 791 else
 792     AC_MSG_RESULT(yes)
 793     AC_MSG_CHECKING(whether dynamic modules work)
 794     oLIBS="$LIBS"
 795     oCFLAGS="$CFLAGS"
 796     CFLAGS="$GLIB_CFLAGS"
 797     LIBS="$GLIB_LIBS"
 798     AC_TRY_RUN([
 799     #include <glib.h>
 800     #include <gmodule.h>
 801     main ()
 802     {
 803         if (g_module_supported ())
 804             exit (0);
 805         else
 806             exit (1);
 807     }
 808     ], dynworks=true)
 809     LIBS="$oLIBS"
 810     CFLAGS="$oCFLAGS"
 811 fi
 812
 813 dnl Now we check to see if our libtool supports shared lib deps
 814 dnl (in a rather ugly way even)
 815 if $dynworks; then
 816    pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} libtool --config"
 817    pixbuf_deplibs_check=`$pixbuf_libtool_config | \
 818       grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 819       sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 820    if test "x$pixbuf_deplibs_check" = "xnone" || \
 821       test "x$pixbuf_deplibs_check" = "xunknown" || \
 822       test "x$pixbuf_deplibs_check" = "x"; then
 823       dynworks=false
 824    fi
 825 fi
 826
 827 if $dynworks; then
 828    AC_DEFINE(USE_GMODULE)
 829    AC_MSG_RESULT(yes)
 830 else
 831    AC_MSG_RESULT(no)
 832 fi
 833
 834 dnl Test for libtiff
 835   if test -z "$LIBTIFF"; then
 836     AC_CHECK_LIB(tiff, TIFFReadScanline,
 837       AC_CHECK_HEADER(tiffio.h,
 838         TIFF='tiff'; LIBTIFF='-ltiff',
 839         AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 840       AC_CHECK_LIB(tiff, TIFFWriteScanline,
 841         AC_CHECK_HEADER(tiffio.h,
 842           TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
 843           AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 844         AC_CHECK_LIB(tiff34, TIFFFlushData,
 845           AC_CHECK_HEADER(tiffio.h,
 846             TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
 847             AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 848         AC_MSG_WARN(*** TIFF plug-in will not be built (TIFF library not found) ***), -ljpeg -lz -lm), -ljpeg -lz -lm), -lm)
 849   fi
 850
 851 dnl Test for libjpeg
 852   if test -z "$LIBJPEG"; then
 853     AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 854       jpeg_ok=yes,
 855       jpeg_ok=no
 856       AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
 857     if test "$jpeg_ok" = yes; then
 858       AC_MSG_CHECKING([for jpeglib.h])
 859       AC_TRY_CPP(
 860 [#include <stdio.h>
 861 #undef PACKAGE
 862 #undef VERSION
 863 #include <jpeglib.h>],
 864         jpeg_ok=yes,
 865         jpeg_ok=no)
 866       AC_MSG_RESULT($jpeg_ok)
 867       if test "$jpeg_ok" = yes; then
 868         LIBJPEG='-ljpeg'
 869         AC_CHECK_LIB(jpeg, jpeg_simple_progression,
 870           AC_DEFINE(HAVE_PROGRESSIVE_JPEG),
 871           AC_MSG_WARN(JPEG library does not support progressive saving.))
 872       else
 873           AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
 874       fi
 875     fi
 876   fi
 877
 878 dnl Test for libpng
 879   if test -z "$LIBPNG"; then
 880     AC_CHECK_LIB(png, png_read_info,
 881       AC_CHECK_HEADER(png.h,
 882         png_ok=yes,
 883         png_ok=no),
 884       AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
 885     if test "$png_ok" = yes; then
 886       AC_MSG_CHECKING([for png_structp in png.h])
 887       AC_TRY_COMPILE([#include <png.h>],
 888         [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 889         png_ok=yes,
 890         png_ok=no)
 891       AC_MSG_RESULT($png_ok)
 892       if test "$png_ok" = yes; then
 893         PNG='png'; LIBPNG='-lpng -lz'
 894       else
 895         AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
 896       fi
 897     else
 898      AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
 899     fi
 900   fi
 901
 902 deps="$LIBTIFF $LIBJPEG $LIBPNG"
 903
 904 AC_SUBST(LIBTIFF)
 905 AC_SUBST(LIBJPEG)
 906 AC_SUBST(LIBPNG)
 907
 908 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 909
 910 #
 911 # Allow building some or all gdk-pixbuf loaders included
 912 #
 913 AC_MSG_CHECKING(pixbuf loaders to build)
 914
 915 AC_ARG_WITH(included_loaders, [  --with-included-loaders=LOADER1,LOADER2,... Build the specified loaders into gdk-pixbuf (only used if module loading disabled)])
 916
 917 all_loaders="png,bmp,wbmp,gif,ico,jpeg,pnm,ras,tiff,xpm"
 918 included_loaders=""
 919 # If no loaders specified, include all
 920 if test "x$with_included_loaders" = xyes ; then
 921   included_loaders="$all_loaders"
 922 else
 923   included_loaders="$with_included_loaders"
 924 fi
 925
 926 AC_MSG_RESULT($included_loaders)
 927
 928 INCLUDED_LOADER_OBJ=
 929 INCLUDED_LOADER_DEFINE=
 930
 931 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 932 for loader in $included_loaders; do
 933  if ! echo "$all_loaders" | grep "\(^\|\,\)$loader\(\$\|\,\)" > /dev/null; then
 934    AC_MSG_ERROR([the specified loader $loader does not exist])
 935  fi
 936
 937  INCLUDED_LOADER_OBJ="$INCLUDED_LOADER_OBJ libpixbufloader-static-$loader.la"
 938  INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_$loader"
 939 done
 940 IFS="$gtk_save_ifs"
 941 AC_SUBST(INCLUDED_LOADER_OBJ)
 942 AC_SUBST(INCLUDED_LOADER_DEFINE)
 943
 944 AC_HEADER_STDC
 945 AC_HEADER_DIRENT
 946 AC_HEADER_SYS_WAIT
 947
 948 AC_TYPE_SIGNAL
 949
 950 AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
 951 AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
 952 AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
 953
 954 GDK_PIXBUF_LIBDIR='-L${libdir}'
 955 GDK_PIXBUF_INCLUDEDIR="-I${includedir} $GTK_CFLAGS"
 956 GDK_PIXBUF_LIBS="$GLIB_LIBS -lgdk_pixbuf $deps $GTK_LIBS"
 957 AC_SUBST(STATIC_LIB_DEPS)
 958 STATIC_LIB_DEPS="$deps"
 959
 960 AC_SUBST(GDK_PIXBUF_LIBDIR)
 961 AC_SUBST(GDK_PIXBUF_INCLUDEDIR)
 962 AC_SUBST(GDK_PIXBUF_LIBS)
 963
 964 GDK_PIXBUF_XLIB_LIBDIR=$GDK_PIXBUF_LIBDIR
 965 GDK_PIXBUF_XLIB_INCLUDEDIR=$GDK_PIXBUF_INCLUDEDIR
 966 GDK_PIXBUF_XLIB_LIBS="$GLIB_LIBS -lgdk_pixbuf_xlib $deps $X11_LIBS"
 967
 968 AC_SUBST(GDK_PIXBUF_XLIB_LIBDIR)
 969 AC_SUBST(GDK_PIXBUF_XLIB_INCLUDEDIR)
 970 AC_SUBST(GDK_PIXBUF_XLIB_LIBS)
 971
 972 # Checks to see if we should compile in MMX support (there will be
 973 # a runtime test when the code is actually run to see if it should
 974 # be used - this just checks if we can compile it.)
 975 #
 976 # This code is partially taken from Mesa
 977 #
 978 AC_MSG_CHECKING(for x86 platform)
 979 case $host_cpu in
 980   i386|i486|i586|i686|i786|k6|k7)
 981         use_x86_asm=yes
 982         ;;
 983    *)
 984         use_x86_asm=no
 985 esac
 986 AC_MSG_RESULT($use_x86_asm)
 987
 988 use_mmx_asm=no
 989 if test $use_x86_asm = yes; then
 990     save_ac_ext=$ac_ext
 991     ac_ext=S
 992
 993     AC_MSG_CHECKING(compiler support for MMX)
 994     cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
 995     if AC_TRY_EVAL(ac_compile); then
 996         use_mmx_asm=yes
 997     fi
 998
 999     rm -rf conftest*
1000
1001     ac_ext=$save_ac_ext
1002     if test $use_mmx_asm = yes; then
1003       AC_DEFINE(USE_MMX)
1004       AC_MSG_RESULT(yes)
1005     else
1006       AC_MSG_RESULT(no)
1007     fi
1008 fi
1009
1010 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
1011
1012
1013 ##################################################
1014 # Checks for gtk-doc and docbook-tools
1015 ##################################################
1016
1017 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
1018
1019 if test "x$with_html_dir" = "x" ; then
1020   HTML_DIR='${datadir}/gtk-doc/html'
1021 else
1022   HTML_DIR=$with_html_dir
1023 fi
1024
1025 AC_SUBST(HTML_DIR)
1026
1027 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1028
1029 gtk_doc_min_version=0.6
1030 if $GTKDOC ; then
1031     gtk_doc_version=`gtkdoc-mkdb --version`
1032     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
1033     if perl <<EOF ; then
1034       exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
1035             ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
1036 EOF
1037       AC_MSG_RESULT(yes)
1038    else
1039       AC_MSG_RESULT(no)
1040       GTKDOC=false
1041    fi
1042 fi
1043
1044 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1045 AC_SUBST(HAVE_GTK_DOC)
1046
1047 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1048 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1049
1050 dnl Let people disable the gtk-doc stuff.
1051 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1052
1053 if test x$enable_gtk_doc = xauto ; then
1054   if test x$GTKDOC = xtrue ; then
1055     enable_gtk_doc=yes
1056   else
1057     enable_gtk_doc=no
1058   fi
1059 fi
1060
1061 dnl NOTE: We need to use a separate automake conditional for this
1062 dnl       to make this work with the tarballs.
1063 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1064
1065 GDK_PIXBUF_DIR=`(cd $srcdir; pwd)`
1066 AC_SUBST(GDK_PIXBUF_DIR)
1067
1068
1069 ##################################################
1070 # Output commands
1071 ##################################################
1072
1073 AC_OUTPUT_COMMANDS([
1074
1075 ## Generate `gdk/gdkconfig.h' in two cases
1076 ## 1. `config.status' is run either explicitly, or via configure.
1077 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1078 ##     config.h
1079 ## 2. CONFIG_OTHER is set explicitly
1080 ##
1081 ## Case 1 is difficult.  We know that `automake' sets one of
1082 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1083 ## only when AM_CONFIG_HEADER is set, however.
1084
1085 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1086   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1087   CONFIG_OTHER=${CONFIG_OTHER:-gdk/gdkconfig.h}
1088 fi
1089 case "$CONFIG_OTHER" in
1090 *gdk/gdkconfig.h*)
1091         echo creating gdk/gdkconfig.h
1092         outfile=gdkconfig.h-tmp
1093         cat > $outfile <<\_______EOF
1094 /* gdkconfig.h
1095  *
1096  * This is a generated file.  Please modify `configure.in'
1097  */
1098
1099 #ifndef GDKCONFIG_H
1100 #define GDKCONFIG_H
1101
1102 #ifdef __cplusplus
1103 extern "C" {
1104 #endif /* __cplusplus */
1105
1106 _______EOF
1107
1108         cat >>$outfile <<_______EOF
1109 $gdk_windowing
1110 $gdk_wc
1111 _______EOF
1112
1113         cat >>$outfile <<_______EOF
1114
1115 #ifdef __cplusplus
1116 }
1117 #endif /* __cplusplus */
1118
1119 #endif /* GDKCONFIG_H */
1120 _______EOF
1121
1122
1123         if cmp -s $outfile gdk/gdkconfig.h; then
1124           echo gdk/gdkconfig.h is unchanged
1125           rm -f $outfile
1126         else
1127           mv $outfile gdk/gdkconfig.h
1128         fi ;;
1129 esac
1130 ],[
1131 if test "x$gdktarget" = "xx11" ; then
1132   gdk_windowing='
1133 #define GDK_WINDOWING_X11'
1134 elif test "x$gdktarget" = "xnanox" ; then
1135   gdk_windowing='
1136 #define GDK_WINDOWING_NANOX'
1137 elif test "x$gdktarget" = "xlinux-fb" ; then
1138   gdk_windowing='
1139 #define GDK_WINDOWING_FB
1140 #define GDK_NATIVE_WINDOW_POINTER'
1141 fi
1142
1143 if test x$gdk_wchar_h = xyes; then
1144   gdk_wc='
1145 #define GDK_HAVE_WCHAR_H 1'
1146 fi
1147 if test x$gdk_wctype_h = xyes; then
1148   gdk_wc="\$gdk_wc
1149 #define GDK_HAVE_WCTYPE_H 1"
1150 fi
1151 if test x$gdk_working_wctype = xno; then
1152   gdk_wc="\$gdk_wc
1153 #define GDK_HAVE_BROKEN_WCTYPE 1"
1154 fi
1155
1156
1157 ])
1158
1159 AC_PATH_PROG(SGML2HTML, sgml2html, no)
1160 AM_CONDITIONAL(HAVE_SGML2HTML, ! test x$SGML2HTML = xno)
1161
1162 AC_OUTPUT([
1163 config.h.win32
1164 gtk+.spec
1165 docs/gtk-config.1
1166 Makefile
1167 gdk-pixbuf-2.0.pc
1168 gdk-2.0.pc
1169 gtk+-2.0.pc
1170 po/Makefile.in
1171 build/Makefile
1172 build/win32/Makefile
1173 demos/Makefile
1174 demos/gtk-demo/Makefile
1175 tests/Makefile
1176 docs/Makefile
1177 docs/reference/Makefile
1178 docs/reference/gdk-pixbuf/Makefile
1179 docs/reference/gdk/Makefile
1180 docs/reference/gtk/Makefile
1181 docs/faq/Makefile
1182 docs/tutorial/Makefile
1183 gdk-pixbuf/Makefile
1184 gdk-pixbuf/makefile.mingw
1185 gdk-pixbuf/gdk-pixbuf-features.h
1186 gdk-pixbuf/pixops/Makefile
1187 gdk-pixbuf/pixops/makefile.mingw
1188 gdk/Makefile
1189 gdk/makefile.mingw
1190 gdk/x11/Makefile
1191 gdk/win32/Makefile
1192 gdk/win32/makefile.mingw
1193 gdk/win32/rc/Makefile
1194 gdk/win32/rc/gdk.rc
1195 gdk/nanox/Makefile
1196 gdk/linux-fb/Makefile
1197 gtk/Makefile
1198 gtk/makefile.mingw
1199 gtk/makefile.msc
1200 gtk/gtkcompat.h
1201 gtk/gtk-win32.rc
1202 gtk/stock-icons/Makefile
1203 modules/Makefile
1204 modules/input/Makefile
1205 contrib/Makefile
1206 contrib/gdk-pixbuf-xlib/Makefile
1207 contrib/gdk-pixbuf-xlib/gdk-pixbuf-xlib-2.0.pc
1208 ])