Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 # Making releases:
   6 #   GTK_MICRO_VERSION += 1;
   7 #   GTK_INTERFACE_AGE += 1;
   8 #   GTK_BINARY_AGE += 1;
   9 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  10 # if backwards compatibility has been broken,
  11 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  12
  13 m4_define([gtk_major_version], [2])
  14 m4_define([gtk_minor_version], [18])
  15 m4_define([gtk_micro_version], [1])
  16 m4_define([gtk_interface_age], [1])
  17 m4_define([gtk_binary_age],
  18           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  19 m4_define([gtk_version],
  20           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  21 # This is the X.Y used in -lgtk-FOO-X.Y
  22 m4_define([gtk_api_version], [2.0])
  23
  24 # Define a string for the earliest version that this release has
  25 # backwards binary compatibility with for all interfaces a module
  26 # might. Unless we add module-only API with lower stability
  27 # guarantees, this should be unchanged until we break binary compat
  28 # for GTK+.
  29 #
  30 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  31 m4_define([gtk_binary_version], [2.10.0])
  32
  33 # required versions of other packages
  34 m4_define([glib_required_version], [2.21.3])
  35 m4_define([pango_required_version], [1.20])
  36 m4_define([atk_required_version], [1.13.0])
  37 m4_define([cairo_required_version], [1.6])
  38
  39
  40 AC_INIT([gtk+], [gtk_version],
  41         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  42         [gtk+])
  43
  44 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  45
  46 # Save this value here, since automake will set cflags later
  47 cflags_set=${CFLAGS+set}
  48
  49 AM_INIT_AUTOMAKE(no-define)
  50 AM_CONFIG_HEADER(config.h)
  51
  52 # Support silent build rules, requires at least automake-1.11. Enable
  53 # by either passing --enable-silent-rules to configure or passing V=0
  54 # to make
  55 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([no])])
  56
  57 #
  58 # For each of the libraries we build, we define the following
  59
  60 # substituted variables:
  61 #
  62 # foo_PACKAGES:     pkg-config packages this library requires
  63 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  64 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  65 # foo_DEP_LIBS:     All libraries this module requires
  66 # foo_DEP_CFLAGS:   All cflags this module requires
  67
  68
  69 GTK_MAJOR_VERSION=gtk_major_version
  70 GTK_MINOR_VERSION=gtk_minor_version
  71 GTK_MICRO_VERSION=gtk_micro_version
  72 GTK_INTERFACE_AGE=gtk_interface_age
  73 GTK_BINARY_AGE=gtk_binary_age
  74 GTK_VERSION=gtk_version
  75 GTK_API_VERSION=gtk_api_version
  76 GTK_BINARY_VERSION=gtk_binary_version
  77 AC_SUBST(GTK_MAJOR_VERSION)
  78 AC_SUBST(GTK_MINOR_VERSION)
  79 AC_SUBST(GTK_MICRO_VERSION)
  80 AC_SUBST(GTK_INTERFACE_AGE)
  81 AC_SUBST(GTK_BINARY_AGE)
  82 AC_SUBST(GTK_API_VERSION)
  83 AC_SUBST(GTK_VERSION)
  84 AC_SUBST(GTK_BINARY_VERSION)
  85
  86 # libtool versioning
  87 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  88 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  89 #LT_REVISION=$GTK_INTERFACE_AGE
  90 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  91 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  92
  93 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
  94 m4_define([lt_revision], [gtk_interface_age])
  95 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
  96 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
  97 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
  98 AC_SUBST(LT_VERSION_INFO)
  99 AC_SUBST(LT_CURRENT_MINUS_AGE)
 100
 101 m4_define([gail_lt_current],[18])
 102 m4_define([gail_lt_revision],[1])
 103 m4_define([gail_lt_age],[0])
 104 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 105 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 106 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 107 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 108
 109 #
 110 # gdk-pixbuf gets versioned separately, and for now, using standard
 111 # libtool versioning, not GTK+-style versioning
 112 #
 113 GDK_PIXBUF_MAJOR=gtk_major_version
 114 GDK_PIXBUF_MINOR=gtk_minor_version
 115 GDK_PIXBUF_MICRO=gtk_micro_version
 116 GDK_PIXBUF_VERSION="${GDK_PIXBUF_MAJOR}.${GDK_PIXBUF_MINOR}.${GDK_PIXBUF_MICRO}"
 117 AC_SUBST(GDK_PIXBUF_MAJOR)
 118 AC_SUBST(GDK_PIXBUF_MINOR)
 119 AC_SUBST(GDK_PIXBUF_MICRO)
 120 AC_SUBST(GDK_PIXBUF_VERSION)
 121
 122 GETTEXT_PACKAGE=gtk20
 123 AC_SUBST(GETTEXT_PACKAGE)
 124 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 125                    [The prefix for our gettext translation domains.])
 126
 127 AC_CANONICAL_HOST
 128
 129 MATH_LIB=-lm
 130 AC_MSG_CHECKING([for native Win32])
 131 LIB_EXE_MACHINE_FLAG=X86
 132 case "$host" in
 133   *-*-mingw*)
 134     os_win32=yes
 135     gio_can_sniff=no
 136     MATH_LIB=
 137     case "$host" in
 138     x86_64-*-*)
 139       LIB_EXE_MACHINE_FLAG=X64
 140       ;;
 141     esac
 142     ;;
 143   *)
 144     os_win32=no
 145     ;;
 146 esac
 147 AC_MSG_RESULT([$os_win32])
 148
 149 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 150
 151 case $host in
 152   *-*-linux*)
 153     os_linux=yes
 154     ;;
 155 esac
 156
 157 dnl Initialize libtool
 158 AC_PROG_CC
 159 AM_DISABLE_STATIC
 160
 161 dnl
 162 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 163 dnl We use this for an automated test for C++ header correctness.
 164 dnl
 165 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 166 AC_LANG_SAVE
 167 AC_LANG_CPLUSPLUS
 168
 169 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 170 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 171
 172 gtk_save_cxxflags="$CXXFLAGS"
 173 CXXFLAGS="$CXXFLAGS -x objective-c++"
 174 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 175 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 176 CXXFLAGS="$gtk_save_cxxflags"
 177 AC_LANG_RESTORE
 178
 179 if test "$os_win32" = "yes"; then
 180   if test x$enable_static = xyes -o x$enable_static = x; then
 181     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 182     enable_static=no
 183   fi
 184   if test x$enable_shared = xno; then
 185     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 186   fi
 187   enable_shared=yes
 188 fi
 189
 190 AC_LIBTOOL_WIN32_DLL
 191 AM_PROG_LIBTOOL
 192 dnl when using libtool 2.x create libtool early, because it's used in configure
 193 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 194
 195
 196 # Make sure we use 64-bit versions of various file stuff.
 197 AC_SYS_LARGEFILE
 198
 199 AM_PROG_AS
 200 AC_PATH_PROG(NM, nm, nm)
 201
 202 dnl Initialize maintainer mode
 203 AM_MAINTAINER_MODE
 204
 205 AC_MSG_CHECKING([for some Win32 platform])
 206 case "$host" in
 207   *-*-mingw*|*-*-cygwin*)
 208     platform_win32=yes
 209     ;;
 210   *)
 211     platform_win32=no
 212     ;;
 213 esac
 214 AC_MSG_RESULT([$platform_win32])
 215 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 216
 217 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 218 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 219 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 220
 221 if test "$os_win32" = "yes"; then
 222   AC_CHECK_TOOL(WINDRES, windres, no)
 223   if test "$WINDRES" = no; then
 224     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 225   fi
 226   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 227 fi
 228 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 229
 230 m4_define([debug_default],
 231           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 232
 233 dnl declare --enable-* args and collect ac_help strings
 234 AC_ARG_ENABLE(debug,
 235               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 236                              [turn on debugging @<:@default=debug_default@:>@]),,
 237               enable_debug=debug_default)
 238 AC_ARG_ENABLE(shm,
 239               [AC_HELP_STRING([--enable-shm],
 240                               [support shared memory if available [default=yes]])],,
 241               [enable_shm="yes"])
 242 AC_ARG_ENABLE(xkb,
 243               [AC_HELP_STRING([--enable-xkb],
 244                               [support XKB [default=maybe]])],,
 245               [enable_xkb="maybe"])
 246 AC_ARG_ENABLE(xinerama,
 247               [AC_HELP_STRING([--enable-xinerama],
 248                               [support xinerama extension if available [default=yes]])],,
 249               [enable_xinerama="yes"])
 250 AC_ARG_ENABLE(rebuilds,
 251               [AC_HELP_STRING([--disable-rebuilds],
 252                               [disable all source autogeneration rules])],,
 253               [enable_rebuilds=yes])
 254 AC_ARG_ENABLE(visibility,
 255               [AC_HELP_STRING([--disable-visibility],
 256                               [don't use ELF visibility attributes])],,
 257               [enable_visibility=yes])
 258
 259 AC_ARG_WITH(xinput,
 260             [AC_HELP_STRING([--with-xinput=@<:@no/yes@:>@], [support XInput])])
 261
 262 if test "$platform_win32" = yes; then
 263   gdktarget=win32
 264 else
 265   gdktarget=x11
 266 fi
 267
 268 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/win32/quartz/directfb]] select non-default GDK target],
 269         gdktarget=$with_gdktarget)
 270
 271 AC_SUBST(gdktarget)
 272 case $gdktarget in
 273   x11|win32|quartz|directfb) ;;
 274   *) AC_MSG_ERROR([Invalid target for GDK: use x11, quartz, directfb or win32.]);;
 275 esac
 276
 277 gdktargetlib=libgdk-$gdktarget-$GTK_API_VERSION.la
 278 gtktargetlib=libgtk-$gdktarget-$GTK_API_VERSION.la
 279
 280 AC_SUBST(gdktargetlib)
 281 AC_SUBST(gtktargetlib)
 282
 283 if test "x$enable_debug" = "xyes"; then
 284   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 285   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 286 else
 287   if test "x$enable_debug" = "xno"; then
 288     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 289   else
 290     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 291   fi
 292 fi
 293
 294
 295 if test "x$enable_visibility" = "xno"; then
 296   GTK_DEBUG_FLAGS="$GTK_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 297 fi
 298
 299
 300 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 301                    [Define if debugging is enabled])
 302
 303
 304 # Build time sanity check...
 305 AM_SANITY_CHECK
 306
 307 # Checks for programs.
 308 AC_ISC_POSIX
 309 AM_PROG_CC_STDC
 310 AM_PROG_CC_C_O
 311 AC_PROG_INSTALL
 312 AC_PROG_MAKE_SET
 313
 314 changequote(,)dnl
 315 if test "x$GCC" = "xyes"; then
 316   case " $CFLAGS " in
 317   *[\ \ ]-Wall[\ \      ]*) ;;
 318   *) CFLAGS="$CFLAGS -Wall" ;;
 319   esac
 320
 321   if test "x$enable_ansi" = "xyes"; then
 322     case " $CFLAGS " in
 323     *[\ \       ]-ansi[\ \      ]*) ;;
 324     *) CFLAGS="$CFLAGS -ansi" ;;
 325     esac
 326
 327     case " $CFLAGS " in
 328     *[\ \       ]-pedantic[\ \  ]*) ;;
 329     *) CFLAGS="$CFLAGS -pedantic" ;;
 330     esac
 331   fi
 332 fi
 333 changequote([,])dnl
 334
 335 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES -DGDK_PIXBUF_DISABLE_SINGLE_INCLUDES -DGTK_DISABLE_SINGLE_INCLUDES"
 336
 337 # Ensure MSVC-compatible struct packing convention is used when
 338 # compiling for Win32 with gcc.
 339 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 340 # gcc2 uses "-fnative-struct".
 341 if test x"$os_win32" = xyes; then
 342   if test x"$GCC" = xyes; then
 343     msnative_struct=''
 344     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 345     if test -z "$ac_cv_prog_CC"; then
 346       our_gcc="$CC"
 347     else
 348       our_gcc="$ac_cv_prog_CC"
 349     fi
 350     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 351       2.)
 352         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 353           msnative_struct='-fnative-struct'
 354         fi
 355         ;;
 356       *)
 357         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 358           msnative_struct='-mms-bitfields'
 359         fi
 360         ;;
 361     esac
 362     if test x"$msnative_struct" = x ; then
 363       AC_MSG_RESULT([no way])
 364       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 365     else
 366       CFLAGS="$CFLAGS $msnative_struct"
 367       AC_MSG_RESULT([${msnative_struct}])
 368     fi
 369   fi
 370 fi
 371
 372 # Honor aclocal flags
 373 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 374
 375 ## Initial sanity check, done here so that users get told they
 376 ## have the wrong dependencies as early in the process as possible.
 377 ## Later on we actually use the cflags/libs from separate pkg-config
 378 ## calls. Oh, also the later pkg-config calls don't include
 379 ## the version requirements since those make the module lists
 380 ## annoying to construct
 381 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 382   [glib-2.0 >= glib_required_version dnl
 383    atk >= atk_required_version dnl
 384    pango >= pango_required_version dnl
 385    cairo >= cairo_required_version])
 386
 387 ## In addition to checking that cairo is present, we also need to
 388 ## check that the correct cairo backend is there. E.g. if the GDK
 389 ## target is win32 we need the cairo-win32 backend and so on.
 390 cairo_backend=$gdktarget
 391
 392 # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 393 # backend names are identical.
 394 if test "x$cairo_backend" = "xx11"; then
 395    cairo_backend=xlib
 396 fi
 397 PKG_CHECK_MODULES(CAIRO_BACKEND,
 398   [cairo-$cairo_backend >= cairo_required_version])
 399
 400 if test "$os_win32" != yes; then
 401     # libtool option to control which symbols are exported
 402     # right now, symbols starting with _ are not exported
 403     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 404 else
 405     # We currently use .def files on Windows (for gdk-pixbuf, gdk and gtk)
 406     LIBTOOL_EXPORT_OPTIONS=
 407 fi
 408 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 409
 410 dnl ******************************************************
 411 dnl * See whether to include shared library dependencies *
 412 dnl ******************************************************
 413
 414 AC_ARG_ENABLE(explicit-deps,
 415               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 416                               [use explicit dependencies in .pc files [default=auto]])],,
 417               [enable_explicit_deps=auto])
 418
 419 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 420 case $enable_explicit_deps in
 421   auto)
 422     export SED
 423     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 424     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 425       enable_explicit_deps=yes
 426     else
 427       enable_explicit_deps=no
 428     fi
 429   ;;
 430   yes|no)
 431   ;;
 432   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 433   ;;
 434 esac
 435 AC_MSG_RESULT($enable_explicit_deps)
 436
 437 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 438
 439 # define a MAINT-like variable REBUILD which is set if Perl
 440 # and awk are found, so autogenerated sources can be rebuilt
 441
 442 AC_PATH_PROGS(PERL, perl5 perl)
 443
 444 # We would like indent, but don't require it.
 445 AC_CHECK_PROG(INDENT, indent, indent)
 446
 447 REBUILD=\#
 448 if test "x$enable_rebuilds" = "xyes" && \
 449      test -n "$PERL" && \
 450      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 451   REBUILD=
 452 fi
 453 AC_SUBST(REBUILD)
 454
 455 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 456 AC_CHECK_FUNCS(localtime_r)
 457
 458 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 459 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 460 AC_TRY_LINK([#include <langinfo.h>], [
 461 char c;
 462 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 463 ], gtk_ok=yes, gtk_ok=no)
 464 AC_MSG_RESULT($gtk_ok)
 465 if test "$gtk_ok" = "yes"; then
 466   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 467             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 468 fi
 469
 470 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 471 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 472 AC_TRY_LINK([#include <langinfo.h>], [
 473 char c;
 474 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 475 ], gtk_ok=yes, gtk_ok=no)
 476 AC_MSG_RESULT($gtk_ok)
 477 if test "$gtk_ok" = "yes"; then
 478   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 479             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 480 fi
 481
 482 # _NL_PAPER_HEIGHT is an enum and not a define
 483 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 484 AC_TRY_LINK([#include <langinfo.h>], [
 485 char c;
 486 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 487 ], gtk_ok=yes, gtk_ok=no)
 488 AC_MSG_RESULT($gtk_ok)
 489 if test "$gtk_ok" = "yes"; then
 490   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 491             [Define if _NL_PAPER_HEIGHT is available])
 492 fi
 493
 494 # _NL_PAPER_WIDTH is an enum and not a define
 495 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 496 AC_TRY_LINK([#include <langinfo.h>], [
 497 char c;
 498 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 499 ], gtk_ok=yes, gtk_ok=no)
 500 AC_MSG_RESULT($gtk_ok)
 501 if test "$gtk_ok" = "yes"; then
 502   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 503             [Define if _NL_PAPER_WIDTH is available])
 504 fi
 505
 506 # sigsetjmp is a macro on some platforms, so AC_CHECK_FUNCS is not reliable
 507 AC_MSG_CHECKING(for sigsetjmp)
 508 AC_TRY_LINK([#include <setjmp.h>], [
 509 sigjmp_buf env;
 510 sigsetjmp(env, 0);
 511 ], gtk_ok=yes, gtk_ok=no)
 512 AC_MSG_RESULT($gtk_ok)
 513 if test "$gtk_ok" = "yes"; then
 514   AC_DEFINE(HAVE_SIGSETJMP, 1,
 515             [Define to 1 if sigsetjmp is available])
 516 fi
 517
 518 # i18n stuff
 519 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 520 AM_GLIB_GNU_GETTEXT
 521 LIBS="$LIBS $INTLLIBS"
 522 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 523         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 524       esac])
 525
 526 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 527 dnl po-properties/POTFILES during configure; see GNOME #573515.
 528 dnl
 529 dnl Generate list of files to be processed by xgettext which will
 530 dnl be included in po-properties/Makefile.
 531 test -d po-properties || mkdir po-properties
 532 if test "x$srcdir" != "x."; then
 533   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 534     popropsrcprefix="$srcdir/"
 535   else
 536     popropsrcprefix="../$srcdir/"
 537   fi
 538 else
 539   popropsrcprefix="../"
 540 fi
 541 rm -f po-properties/POTFILES
 542 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 543 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 544 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 545
 546 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 547
 548 dnl The DU4 header files don't provide library prototypes unless
 549 dnl -std1 is given to the native cc.
 550 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 551
 552 gtk_save_LIBS=$LIBS
 553 LIBS="$LIBS -lm"
 554 AC_TRY_RUN([#include <math.h>
 555              int main (void) { return (log(1) != log(1.)); }],
 556      AC_MSG_RESULT(none needed),
 557      gtk_save_CFLAGS="$CFLAGS"
 558      CFLAGS="$CFLAGS -std1"
 559      AC_TRY_RUN([#include <math.h>
 560                  int main (void) { return (log(1) != log(1.)); }],
 561          AC_MSG_RESULT(-std1),
 562          AC_MSG_RESULT()
 563          CFLAGS="$gtk_save_CFLAGS"
 564          AC_MSG_WARN(
 565                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 566          true
 567      ),
 568      AC_MSG_RESULT(none needed)
 569 )
 570 LIBS=$gtk_save_LIBS
 571
 572 AC_MSG_CHECKING(for the BeOS)
 573 case $host in
 574   *-*-beos*)
 575     AC_MSG_RESULT(yes)
 576     MATH_LIB=
 577   ;;
 578   *)
 579     AC_MSG_RESULT(no)
 580   ;;
 581 esac
 582
 583 #
 584 # see bug 162979
 585 #
 586 AC_MSG_CHECKING(for HP-UX)
 587 case $host_os in
 588   hpux9* | hpux10* | hpux11*)
 589     AC_MSG_RESULT(yes)
 590     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 591   ;;
 592   *)
 593     AC_MSG_RESULT(no)
 594   ;;
 595 esac
 596
 597 dnl NeXTStep cc seems to need this
 598 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 599 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 600   AC_MSG_RESULT(none needed),
 601   gtk_save_CFLAGS="$CFLAGS"
 602   CFLAGS="$CFLAGS -posix"
 603   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 604     AC_MSG_RESULT(-posix),
 605     AC_MSG_RESULT()
 606     CFLAGS="$gtk_save_CFLAGS"
 607     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 608
 609 #
 610 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 611 #
 612
 613 GLIB_PACKAGES="gobject-2.0 gmodule-no-export-2.0"
 614
 615 AM_PATH_GLIB_2_0(glib_required_version, :,
 616   AC_MSG_ERROR([
 617 *** GLIB glib_required_version or better is required. The latest version of
 618 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 619   gobject gmodule-no-export gthread)
 620
 621 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 622 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 623 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 624 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 625   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 626 fi
 627
 628 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 629
 630
 631 dnl
 632 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 633 dnl
 634 gtk_save_LIBS=$LIBS
 635 LIBS="$LIBS $GLIB_LIBS"
 636 AC_CHECK_FUNCS(bind_textdomain_codeset)
 637 LIBS=$gtk_save_LIBS
 638
 639 AC_CHECK_HEADERS(pwd.h,
 640                  AC_DEFINE(HAVE_PWD_H, 1,
 641                            [Define to 1 if pwd.h is available]))
 642 AC_CHECK_HEADERS(sys/time.h,
 643                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 644                            [Define to 1 if time.h is available]))
 645 AC_CHECK_HEADERS(unistd.h,
 646                  AC_DEFINE(HAVE_UNISTD_H, 1,
 647                            [Define to 1 if unistd.h is available]))
 648 AC_CHECK_HEADERS(ftw.h,
 649                  AC_DEFINE(HAVE_FTW_H, 1,
 650                            [Define to 1 if ftw.h is available]))
 651
 652 AC_MSG_CHECKING([for GNU ftw extensions])
 653 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 654 #define _GNU_SOURCE
 655 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 656 if test $gtk_ok = yes; then
 657     AC_MSG_RESULT([yes])
 658     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 659 else
 660     AC_MSG_RESULT([no])
 661 fi
 662
 663 saved_cflags="$CFLAGS"
 664 saved_ldflags="$LDFLAGS"
 665
 666
 667 # Checks for header files.
 668 AC_HEADER_STDC
 669
 670 # Checks for typedefs, structures, and compiler characteristics.
 671 AC_C_CONST
 672
 673 # Checks for library functions.
 674 AC_TYPE_SIGNAL
 675 AC_FUNC_MMAP
 676
 677 AC_CHECK_FUNCS(mallinfo)
 678 AC_CHECK_FUNCS(getresuid)
 679 AC_TYPE_UID_T
 680
 681 # Check if <sys/select.h> needs to be included for fd_set
 682 AC_MSG_CHECKING([for fd_set])
 683 AC_TRY_COMPILE([#include <sys/types.h>],
 684         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 685 if test $gtk_ok = yes; then
 686     AC_MSG_RESULT([yes, found in sys/types.h])
 687 else
 688     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 689     if test $gtk_ok = yes; then
 690         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 691                   [Define to 1 if sys/select.h is available])
 692         AC_MSG_RESULT([yes, found in sys/select.h])
 693     else
 694         AC_DEFINE(NO_FD_SET, 1,
 695                   [Define to 1 if fd_set is not available])
 696         AC_MSG_RESULT(no)
 697     fi
 698 fi
 699
 700 # `widechar' tests for gdki18n.h
 701 AC_MSG_CHECKING(for wchar.h)
 702 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 703 if test $gdk_wchar_h = yes; then
 704    AC_DEFINE(HAVE_WCHAR_H, 1, [Have wchar.h include file])
 705 fi
 706 AC_MSG_RESULT($gdk_wchar_h)
 707
 708 # Check for wctype.h (for iswalnum)
 709 AC_MSG_CHECKING(for wctype.h)
 710 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 711 if test $gdk_wctype_h = yes; then
 712    AC_DEFINE(HAVE_WCTYPE_H, 1, [Have wctype.h include file])
 713 fi
 714 AC_MSG_RESULT($gdk_wctype_h)
 715
 716 # in Solaris 2.5, `iswalnum' is in -lw
 717 GDK_WLIBS=
 718 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 719
 720 oLIBS="$LIBS"
 721 LIBS="$LIBS $GDK_WLIBS"
 722 # The following is necessary for Linux libc-5.4.38
 723 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 724 AC_TRY_LINK([#include <stdlib.h>],[
 725 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 726 #  ifdef HAVE_WCTYPE_H
 727 #    include <wctype.h>
 728 #  else
 729 #    ifdef HAVE_WCHAR_H
 730 #      include <wchar.h>
 731 #    endif
 732 #  endif
 733 #else
 734 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 735 #endif
 736 iswalnum((wchar_t) 0);
 737 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 738 LIBS="$oLIBS"
 739
 740 if test $gdk_working_wctype = no; then
 741    AC_DEFINE(HAVE_BROKEN_WCTYPE, 1, [Is the wctype implementation broken])
 742    GDK_WLIBS=
 743 fi
 744 AC_MSG_RESULT($gdk_working_wctype)
 745 AC_SUBST(GDK_WLIBS)
 746
 747 # Check for uxtheme.h (for MS-Windows Engine)
 748 AC_MSG_CHECKING(for uxtheme.h)
 749 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 750 if test $gtk_uxtheme_h = yes; then
 751    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 752 fi
 753 AC_MSG_RESULT($gtk_uxtheme_h)
 754
 755 # Checks for gdkspawn
 756 AC_CHECK_HEADERS(crt_externs.h)
 757 AC_CHECK_FUNCS(_NSGetEnviron)
 758
 759
 760 ##################################################
 761 # Checks for gdk-pixbuf
 762 ##################################################
 763
 764 dnl ********************************************************
 765 dnl * See whether we need to load our modules as .la files *
 766 dnl ********************************************************
 767
 768 use_la_modules=false
 769 case $host in
 770   *-aix*) use_la_modules=true
 771 esac
 772
 773 if $use_la_modules ; then
 774    AC_DEFINE(USE_LA_MODULES, 1,
 775              [Whether to load modules via .la files rather than directly])
 776 fi
 777
 778
 779 AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
 780
 781 AC_ARG_ENABLE(modules,
 782               [AC_HELP_STRING([--disable-modules],
 783                               [disable dynamic module loading])])
 784
 785 dynworks=false
 786 deps=
 787 if test x$enable_modules = xno; then
 788     AC_MSG_RESULT(no)
 789 else
 790     AC_MSG_RESULT(yes)
 791     AC_MSG_CHECKING(whether dynamic modules work)
 792     ## for loop is to strip newline
 793     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 794     for I in $tmp; do
 795         dynworks=$I
 796     done
 797
 798     dnl Now we check to see if our libtool supports shared lib deps
 799     dnl (in a rather ugly way even)
 800     if $dynworks; then
 801         pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 802         pixbuf_deplibs_check=`$pixbuf_libtool_config | \
 803             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 804             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 805         if test "x$pixbuf_deplibs_check" = "xnone" || \
 806            test "x$pixbuf_deplibs_check" = "xunknown" || \
 807            test "x$pixbuf_deplibs_check" = "x"; then
 808             dynworks=false
 809         fi
 810     fi
 811
 812     if $dynworks; then
 813         AC_DEFINE(USE_GMODULE, 1,
 814                   [Define to 1 if gmodule works and should be used])
 815         AC_MSG_RESULT(yes)
 816     else
 817         AC_MSG_RESULT(no)
 818     fi
 819 fi
 820
 821 dnl We allow people to disable image loaders explicitely, but if they don't we error
 822 dnl out so that people don't accidentally build without them.
 823
 824 AC_ARG_WITH(libpng,
 825             [AC_HELP_STRING([--without-libpng],
 826                             [disable PNG loader for gdk-pixbuf])])
 827 AC_ARG_WITH(libjpeg,
 828             [AC_HELP_STRING([--without-libjpeg],
 829                             [disable JPEG loader for gdk-pixbuf])])
 830 AC_ARG_WITH(libtiff,
 831             [AC_HELP_STRING([--without-libtiff],
 832                             [disable TIFF loader for gdk-pixbuf])])
 833 AC_ARG_WITH(libjasper,
 834             [AC_HELP_STRING([--with-libjasper],
 835                             [enable JPEG2000 loader for gdk-pixbuf])])
 836
 837 AC_ARG_ENABLE(gdiplus,
 838             [AC_HELP_STRING([--enable-gdiplus],
 839                             [enble GDI+ loaders for gdk-pixbuf (currently known to be broken)])],,
 840             [enable_gdiplus=no])
 841
 842 AM_CONDITIONAL(BUILD_GDIPLUS_LOADERS, [ test x$os_win32 = xyes && test x$enable_gdiplus != xno ])
 843
 844 dnl Test for libtiff
 845 if test x$os_win32 = xno || test x$enable_gdiplus = xno; then
 846   if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
 847     AC_CHECK_LIB(tiff, TIFFReadRGBAImageOriented,
 848       [AC_CHECK_HEADER(tiffio.h,
 849         TIFF='tiff'; LIBTIFF='-ltiff',
 850         AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 851       [AC_CHECK_LIB(tiff, TIFFWriteScanline,
 852         [AC_CHECK_HEADER(tiffio.h,
 853           TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
 854           AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 855         [AC_CHECK_LIB(tiff34, TIFFFlushData,
 856           [AC_CHECK_HEADER(tiffio.h,
 857             TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
 858             AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 859         AC_MSG_WARN(*** TIFF loader will not be built (TIFF library not found) ***), -ljpeg -lz -lm)], -ljpeg -lz -lm)], -lm)
 860   fi
 861
 862   if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
 863      AC_MSG_ERROR([
 864 *** Checks for TIFF loader failed. You can build without it by passing
 865 *** --without-libtiff to configure but some programs using GTK+ may
 866 *** not work properly])
 867   fi
 868 fi
 869
 870 dnl Test for libjpeg
 871 if test x$os_win32 = xno || test x$enable_gdiplus = xno; then
 872   if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
 873     AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 874       jpeg_ok=yes,
 875       jpeg_ok=no
 876       AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
 877     if test "$jpeg_ok" = yes; then
 878       AC_MSG_CHECKING([for jpeglib.h])
 879       AC_TRY_CPP(
 880 [#include <stdio.h>
 881 #undef PACKAGE
 882 #undef VERSION
 883 #undef HAVE_STDLIB_H
 884 #include <jpeglib.h>],
 885         jpeg_ok=yes,
 886         jpeg_ok=no)
 887       AC_MSG_RESULT($jpeg_ok)
 888       if test "$jpeg_ok" = yes; then
 889         LIBJPEG='-ljpeg'
 890         AC_CHECK_LIB(jpeg, jpeg_simple_progression,
 891           AC_DEFINE(HAVE_PROGRESSIVE_JPEG, 1,
 892                     [Define to 1 is libjpeg supports progressive JPEG]),
 893           AC_MSG_WARN(JPEG library does not support progressive saving.))
 894       else
 895           AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
 896       fi
 897     fi
 898   fi
 899
 900   if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
 901      AC_MSG_ERROR([
 902 *** Checks for JPEG loader failed. You can build without it by passing
 903 *** --without-libjpeg to configure but some programs using GTK+ may
 904 *** not work properly])
 905   fi
 906 fi
 907
 908 dnl Test for libpng
 909   if test x$with_libpng != xno && test -z "$LIBPNG"; then
 910     AC_MSG_CHECKING(for libpng12)
 911     if $PKG_CONFIG --exists libpng12 ; then
 912         AC_MSG_RESULT(yes)
 913         PNG='png'
 914         PNG_DEP_CFLAGS_PACKAGES=libpng12
 915         LIBPNG=`$PKG_CONFIG --libs libpng12`
 916     else
 917       AC_MSG_RESULT(no)
 918       AC_CHECK_LIB(png, png_read_info,
 919         [AC_CHECK_HEADER(png.h,
 920           png_ok=yes,
 921           png_ok=no)],
 922         AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
 923       if test "$png_ok" = yes; then
 924         AC_MSG_CHECKING([for png_structp in png.h])
 925         AC_TRY_COMPILE([#include <png.h>],
 926           [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 927           png_ok=yes,
 928           png_ok=no)
 929         AC_MSG_RESULT($png_ok)
 930         if test "$png_ok" = yes; then
 931           PNG='png'; LIBPNG='-lpng -lz'
 932         else
 933           AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
 934         fi
 935       else
 936        AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
 937       fi
 938     fi
 939   fi
 940
 941   if test x$with_libpng != xno && test -z "$LIBPNG"; then
 942      AC_MSG_ERROR([
 943 *** Checks for PNG loader failed. You can build without it by passing
 944 *** --without-libpng to configure but many programs using GTK+ will
 945 *** not work properly. The PNG loader is also needed if you are compiling
 946 *** from CVS.])
 947   fi
 948
 949 dnl Test for libjasper
 950   if test x$with_libjasper = xyes && test -z "$LIBJASPER"; then
 951     AC_CHECK_LIB(jasper, jas_init, LIBJASPER=-ljasper, [], -ljpeg)
 952   fi
 953
 954   if test x$with_libjasper = xyes && test -z "$LIBJASPER"; then
 955      AC_MSG_ERROR([
 956 *** Checks for JPEG2000 loader failed. You can build without it by passing
 957 *** --without-libjasper to configure])
 958   fi
 959
 960 AC_SUBST(LIBTIFF)
 961 AC_SUBST(LIBJPEG)
 962 AC_SUBST(LIBPNG)
 963 AC_SUBST(LIBJASPER)
 964
 965 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 966
 967 #
 968 # Allow building some or all gdk-pixbuf loaders included
 969 #
 970 AC_MSG_CHECKING(pixbuf loaders to build)
 971
 972 dnl due to an autoconf bug, commas in the first arg to
 973 dnl AC_HELP_STRING cause problems.
 974 dnl AC_HELP_STRING([--with-included-loaders=LOADER1 LOADER2 ...],
 975 dnl                [build the specified loaders into gdk-pixbuf])
 976 AC_ARG_WITH(included_loaders,
 977 [  --with-included-loaders=LOADER1,LOADER2,...
 978                           build the specified loaders into gdk-pixbuf])
 979
 980 if $dynworks; then
 981    :
 982 else
 983    ## if the option was specified, leave it; otherwise disable included loaders
 984    if test x$with_included_loaders = xno; then
 985            with_included_loaders=yes
 986    fi
 987 fi
 988
 989 # Use the traditional png loader instead of the GDI+ one on Windows,
 990 # because some important apps like GIMP need to read and write
 991 # arbitrary tEXt chunks which doesn't seem to be possible through GDI+
 992
 993 all_loaders="ani,icns,pcx,ras,tga,png,pnm,wbmp,xbm,xpm"
 994 if test x$with_libjasper != xno; then
 995   all_loaders="$all_loaders,jasper"
 996 fi
 997 if test x$os_win32 = xyes && test x$enable_gdiplus != xno; then
 998   # Skip PNG, see comment above
 999   gdip_formats="bmp emf gif ico jpeg tiff wmf"
1000   for f in $gdip_formats; do
1001     all_loaders="$all_loaders,gdip-$f"
1002   done
1003 else
1004   all_loaders="$all_loaders,bmp,gif,ico,jpeg,tiff"
1005 fi
1006 included_loaders=""
1007 # If no loaders specified, include all
1008 if test "x$with_included_loaders" = xyes ; then
1009   included_loaders="$all_loaders"
1010 else
1011   included_loaders="$with_included_loaders"
1012 fi
1013
1014 AC_MSG_RESULT($included_loaders)
1015
1016 INCLUDED_LOADER_OBJ=
1017 INCLUDED_LOADER_DEFINE=
1018
1019 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
1020 for loader in $included_loaders; do
1021  if echo "$all_loaders" | egrep "(^|,)$loader(\$|,)" > /dev/null; then
1022    :
1023  else
1024    AC_MSG_ERROR([the specified loader $loader does not exist])
1025  fi
1026
1027  loader_underscores=`echo $loader | sed -e 's/-/_/g'`
1028  INCLUDED_LOADER_OBJ="$INCLUDED_LOADER_OBJ libstatic-pixbufloader-$loader.la"
1029
1030  # Don't bother defining separate -DINCLUDE_gdip_foo for each gdip-foo loader
1031  case $loader in
1032    gdip-*) ;;
1033    *) INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_$loader_underscores";;
1034  esac
1035  eval INCLUDE_$loader_underscores=yes
1036 done
1037
1038 # Just define one -DINCLUDE_gdiplus for all the gdip-foo loaders
1039 # (except gdip-png, which isn't built at all)
1040 if test x"$INCLUDE_gdip_ico" = xyes; then
1041   INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_gdiplus"
1042 fi
1043
1044 IFS="$gtk_save_ifs"
1045 AC_SUBST(INCLUDED_LOADER_OBJ)
1046 AC_SUBST(INCLUDED_LOADER_DEFINE)
1047
1048 AM_CONDITIONAL(INCLUDE_PNG, [test x"$INCLUDE_png" = xyes])
1049 AM_CONDITIONAL(INCLUDE_BMP, [test x"$INCLUDE_bmp" = xyes])
1050 AM_CONDITIONAL(INCLUDE_WBMP, [test x"$INCLUDE_wbmp" = xyes])
1051 AM_CONDITIONAL(INCLUDE_GIF, [test x"$INCLUDE_gif" = xyes])
1052 AM_CONDITIONAL(INCLUDE_ICO, [test x"$INCLUDE_ico" = xyes])
1053 AM_CONDITIONAL(INCLUDE_ANI, [test x"$INCLUDE_ani" = xyes])
1054 AM_CONDITIONAL(INCLUDE_JPEG, [test x"$INCLUDE_jpeg" = xyes])
1055 AM_CONDITIONAL(INCLUDE_PNM, [test x"$INCLUDE_pnm" = xyes])
1056 AM_CONDITIONAL(INCLUDE_RAS, [test x"$INCLUDE_ras" = xyes])
1057 AM_CONDITIONAL(INCLUDE_TIFF, [test x"$INCLUDE_tiff" = xyes])
1058 AM_CONDITIONAL(INCLUDE_XPM, [test x"$INCLUDE_xpm" = xyes])
1059 AM_CONDITIONAL(INCLUDE_XBM, [test x"$INCLUDE_xbm" = xyes])
1060 AM_CONDITIONAL(INCLUDE_TGA, [test x"$INCLUDE_tga" = xyes])
1061 AM_CONDITIONAL(INCLUDE_PCX, [test x"$INCLUDE_pcx" = xyes])
1062 AM_CONDITIONAL(INCLUDE_ICNS, [test x"$INCLUDE_icns" = xyes])
1063 AM_CONDITIONAL(INCLUDE_JASPER, [test x"$INCLUDE_jasper" = xyes])
1064 # As all GDI+ loaders are either built-in or not, arbitrarily just
1065 # check one of the variables here
1066 AM_CONDITIONAL(INCLUDE_GDIPLUS, [test x"$INCLUDE_gdip_ico" = xyes])
1067
1068 if test x$gio_can_sniff = x; then
1069   AC_MSG_CHECKING([if gio can sniff png])
1070   gtk_save_LIBS="$LIBS"
1071   gtk_save_CFLAGS="$CFLAGS"
1072   LIBS="`$PKG_CONFIG --libs gio-2.0`"
1073   CFLAGS="`$PKG_CONFIG --cflags gio-2.0`"
1074   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1075   #include <gio/gio.h>
1076   static const gsize data_size = 159;
1077   static const guint8 data[] =
1078   {
1079     0x89, 0x50, 0x4e, 0x47, 0x0d, 0x0a, 0x1a, 0x0a, 0x00, 0x00, 0x00, 0x0d,
1080     0x49, 0x48, 0x44, 0x52, 0x00, 0x00, 0x00, 0x01, 0x00, 0x00, 0x00, 0x01,
1081     0x08, 0x02, 0x00, 0x00, 0x00, 0x90, 0x77, 0x53, 0xde, 0x00, 0x00, 0x00,
1082     0x01, 0x73, 0x52, 0x47, 0x42, 0x00, 0xae, 0xce, 0x1c, 0xe9, 0x00, 0x00,
1083     0x00, 0x09, 0x70, 0x48, 0x59, 0x73, 0x00, 0x00, 0x0b, 0x13, 0x00, 0x00,
1084     0x0b, 0x13, 0x01, 0x00, 0x9a, 0x9c, 0x18, 0x00, 0x00, 0x00, 0x07, 0x74,
1085     0x49, 0x4d, 0x45, 0x07, 0xd8, 0x07, 0x0f, 0x10, 0x08, 0x15, 0x61, 0xd8,
1086     0x35, 0x37, 0x00, 0x00, 0x00, 0x19, 0x74, 0x45, 0x58, 0x74, 0x43, 0x6f,
1087     0x6d, 0x6d, 0x65, 0x6e, 0x74, 0x00, 0x43, 0x72, 0x65, 0x61, 0x74, 0x65,
1088     0x64, 0x20, 0x77, 0x69, 0x74, 0x68, 0x20, 0x47, 0x49, 0x4d, 0x50, 0x57,
1089     0x81, 0x0e, 0x17, 0x00, 0x00, 0x00, 0x0c, 0x49, 0x44, 0x41, 0x54, 0x08,
1090     0xd7, 0x63, 0xf8, 0xff, 0xff, 0x3f, 0x00, 0x05, 0xfe, 0x02, 0xfe, 0xdc,
1091     0xcc, 0x59, 0xe7, 0x00, 0x00, 0x00, 0x00, 0x49, 0x45, 0x4e, 0x44, 0xae,
1092     0x42, 0x60, 0x82
1093   };
1094   int
1095   main (int argc, char **argv)
1096   {
1097     char *content_type;
1098     char *image_png;
1099     content_type = g_content_type_guess (NULL, data, data_size, NULL);
1100     image_png = g_content_type_from_mime_type ("image/png");
1101     return !!strcmp (content_type, image_png);
1102   }]])],
1103     [gio_can_sniff=yes
1104      AC_DEFINE(GDK_PIXBUF_USE_GIO_MIME, 1, [Define if gio can sniff image data])],
1105     [gio_can_sniff=no])
1106   AC_MSG_RESULT($gio_can_sniff)
1107   LIBS="$gtk_save_LIBS"
1108   CFLAGS="$gtk_save_CFLAGS"
1109 fi
1110
1111 #
1112 # Allow building some or all immodules included
1113 #
1114 AC_MSG_CHECKING(immodules to build)
1115
1116 dnl due to an autoconf bug, commas in the first arg to
1117 dnl AC_HELP_STRING cause problems.
1118 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
1119 dnl                [build the specified input method modules into gtk])
1120 AC_ARG_WITH(included_immodules,
1121 [  --with-included-immodules=MODULE1,MODULE2,...
1122                           build the specified input methods into gtk])
1123
1124 if $dynworks; then
1125    :
1126 else
1127    ## if the option was specified, leave it; otherwise disable included immodules
1128    if test x$with_included_immodules = xno; then
1129            with_included_immodules=yes
1130    fi
1131 fi
1132
1133 all_immodules="am-et,cedilla,cyrillic-translit"
1134 if test "$gdktarget" = "win32"; then
1135    all_immodules="${all_immodules},ime"
1136 fi
1137 all_immodules="${all_immodules},inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr"
1138 if test "$gdktarget" = "x11"; then
1139    all_immodules="${all_immodules},xim"
1140 fi
1141
1142 included_immodules=""
1143 # If the switch specified without listing any specific ones, include all
1144 if test "x$with_included_immodules" = xyes ; then
1145   included_immodules="$all_immodules"
1146 else
1147   included_immodules="$with_included_immodules"
1148 fi
1149
1150 AC_MSG_RESULT($included_immodules)
1151 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
1152
1153 INCLUDED_IMMODULE_OBJ=
1154 INCLUDED_IMMODULE_DEFINE=
1155
1156 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
1157 for immodule in $included_immodules; do
1158  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
1159  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
1160    :
1161  else
1162    AC_MSG_ERROR([the specified input method $immodule does not exist])
1163  fi
1164
1165  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
1166  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
1167  eval INCLUDE_$immodule_underscores=yes
1168 done
1169 IFS="$gtk_save_ifs"
1170 AC_SUBST(INCLUDED_IMMODULE_OBJ)
1171 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
1172
1173 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
1174 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
1175 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
1176 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
1177 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
1178 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
1179 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
1180 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
1181 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
1182 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
1183 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
1184 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
1185
1186 AC_HEADER_SYS_WAIT
1187
1188 AC_TYPE_SIGNAL
1189
1190 AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
1191 AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
1192 AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
1193 AM_CONDITIONAL(HAVE_JASPER, test "x$LIBJASPER" != x)
1194
1195 if $dynworks ; then
1196   STATIC_LIB_DEPS=
1197   if echo "$included_loaders" | egrep '(^|,)tiff($|,)' > /dev/null; then
1198     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBTIFF"
1199   fi
1200   if echo "$included_loaders" | egrep '(^|,)jpeg($|,)' > /dev/null; then
1201     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBJPEG"
1202   fi
1203   if echo "$included_loaders" | egrep '(^|,)png($|,)' > /dev/null; then
1204     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBPNG"
1205   fi
1206   if echo "$included_loaders" | egrep '(^|,)jasper($|,)' > /dev/null; then
1207     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBJASPER"
1208   fi
1209 else
1210   STATIC_LIB_DEPS="$LIBTIFF $LIBJPEG $LIBPNG $LIBJASPER"
1211 fi
1212
1213 # Checks to see whether we should include mediaLib
1214 # support.
1215 #
1216 AC_CHECK_HEADER(sys/systeminfo.h,
1217                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
1218                           [Define to 1 if sys/systeminfo.h is available]))
1219 AC_CHECK_HEADER(sys/sysinfo.h,
1220                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
1221                           [Define to 1 if sys/sysinfo.h is available]))
1222
1223 AC_MSG_CHECKING(for mediaLib 2.3)
1224 use_mlib25=no
1225 # Check for a mediaLib 2.3 function since that is what the GTK+ mediaLib
1226 # patch requires.
1227 AC_CHECK_LIB(mlib, mlib_ImageSetStruct, use_mlib=yes, use_mlib=no)
1228 if test $use_mlib = yes; then
1229     AC_DEFINE(USE_MEDIALIB, 1,
1230               [Define to 1 if medialib is available and should be used])
1231     MEDIA_LIB=-lmlib
1232
1233     AC_MSG_CHECKING(for mediaLib 2.5)
1234     # Check for a mediaLib 2.5 function since that is what is needed for
1235     # gdk_rgb_convert integration.
1236     AC_CHECK_LIB(mlib, mlib_VideoColorRGBint_to_BGRAint, use_mlib25=yes, use_mlib25=no)
1237     if test $use_mlib25 = yes; then
1238         AC_DEFINE(USE_MEDIALIB25, 1,
1239                   [Define to 1 if medialib 2.5 is available])
1240     fi
1241 fi
1242 AM_CONDITIONAL(USE_MEDIALIB, test $use_mlib = yes)
1243 AM_CONDITIONAL(USE_MEDIALIB25, test $use_mlib25 = yes)
1244
1245 # Checks to see if we should compile in MMX support (there will be
1246 # a runtime test when the code is actually run to see if it should
1247 # be used - this just checks if we can compile it.)
1248 #
1249 # This code is partially taken from Mesa
1250 #
1251 AC_MSG_CHECKING(for x86 platform)
1252 case $host_cpu in
1253   i386|i486|i586|i686|i786|k6|k7)
1254         use_x86_asm=yes
1255         ;;
1256    *)
1257         use_x86_asm=no
1258 esac
1259 AC_MSG_RESULT($use_x86_asm)
1260
1261 use_mmx_asm=no
1262 if test $use_x86_asm = yes; then
1263     save_ac_ext=$ac_ext
1264     ac_ext=S
1265
1266     AC_MSG_CHECKING(compiler support for MMX)
1267     cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
1268     if AC_TRY_EVAL(ac_compile); then
1269         use_mmx_asm=yes
1270     fi
1271
1272     rm -rf conftest*
1273
1274     ac_ext=$save_ac_ext
1275     if test $use_mmx_asm = yes; then
1276       AC_DEFINE(USE_MMX, 1,
1277                 [Define to 1 if XXM is available and should be used])
1278       AC_MSG_RESULT(yes)
1279     else
1280       AC_MSG_RESULT(no)
1281     fi
1282 fi
1283
1284 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
1285
1286 REBUILD_PNGS=
1287 if test -z "$LIBPNG" && test x"$os_win32" = xno -o x$enable_gdiplus = xno; then
1288   REBUILD_PNGS=#
1289 fi
1290
1291 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
1292
1293 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
1294
1295 if test $cross_compiling = yes; then
1296   AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
1297   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
1298   if test x$GTK_UPDATE_ICON_CACHE = xno; then
1299     REBUILD_PNGS=#
1300   fi
1301 fi
1302
1303 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
1304    test "x$REBUILD_PNGS" = "x#" ; then
1305      AC_MSG_ERROR([
1306 *** gtkbuiltincache.h is not in the tree, and cannot be built
1307 *** because you don't have libpng, or (when cross-compiling) you
1308 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
1309 fi
1310
1311 AC_SUBST(REBUILD_PNGS)
1312
1313 GDK_PIXBUF_PACKAGES="gmodule-no-export-2.0 gobject-2.0 gio-2.0"
1314 GDK_PIXBUF_EXTRA_LIBS="$STATIC_LIB_DEPS $MATH_LIB $MEDIA_LIB"
1315 GDK_PIXBUF_EXTRA_CFLAGS=
1316 GDK_PIXBUF_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
1317 GDK_PIXBUF_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $PNG_DEP_CFLAGS_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS"
1318
1319 ########################################
1320 # Windowing system checks
1321 ########################################
1322
1323 GDK_PIXBUF_XLIB_PACKAGES=
1324 GDK_PIXBUF_XLIB_EXTRA_CFLAGS=
1325 GDK_PIXBUF_XLIB_EXTRA_LIBS=
1326
1327 GDK_EXTRA_LIBS="$GDK_WLIBS"
1328 GDK_EXTRA_CFLAGS=
1329
1330 # GTK+ uses some X calls, so needs to link against X directly
1331 GTK_DEP_PACKAGES_FOR_X=
1332 GTK_DEP_LIBS_FOR_X=
1333
1334 if test "x$gdktarget" = "xx11"; then
1335   X_PACKAGES=fontconfig
1336
1337   #
1338   # We use fontconfig very peripherally when decoding the default
1339   # settings.
1340   #
1341   if $PKG_CONFIG --exists fontconfig; then : ; else
1342     AC_MSG_ERROR([
1343 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
1344   fi
1345
1346   #
1347   # Check for basic X packages; we use pkg-config if available
1348   #
1349   if $PKG_CONFIG --exists x11 xext xrender; then
1350     have_base_x_pc=true
1351     X_PACKAGES="$X_PACKAGES x11 xext xrender"
1352     x_libs="`$PKG_CONFIG --libs x11 xext xrender`"
1353     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext xrender`"
1354
1355     # Strip out any .la files that pkg-config might give us (this happens
1356     # with -uninstalled.pc files)
1357     x_libs_for_checks=
1358     for I in $x_libs ; do
1359       case $I in
1360         *.la) ;;
1361         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
1362       esac
1363     done
1364
1365     GDK_PIXBUF_XLIB_PACKAGES="x11"
1366     GTK_PACKAGES_FOR_X="x11"
1367   else
1368     have_base_x_pc=false
1369     AC_PATH_XTRA
1370     if test x$no_x = xyes ; then
1371       AC_MSG_ERROR([X development libraries not found])
1372     fi
1373
1374     x_cflags="$X_CFLAGS"
1375     x_libs_for_checks="$X_LIBS -lXext -lXrender -lX11 $X_EXTRA_LIBS"
1376
1377     GDK_PIXBUF_XLIB_EXTRA_CFLAGS="$x_cflags"
1378     GDK_PIXBUF_XLIB_EXTRA_LIBS="$X_LIBS -lX11 $X_EXTRA_LIBS"
1379     GTK_DEP_LIBS_FOR_X="$X_LIBS -lXrender -lX11 $X_EXTRA_LIBS"
1380   fi
1381
1382   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
1383   x_extra_libs=
1384
1385   gtk_save_cppflags="$CPPFLAGS"
1386   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1387
1388   gtk_save_LIBS=$LIBS
1389   LIBS="$x_libs_for_checks $LIBS"
1390
1391   # Sanity check for the X11 and Xext libraries. While everything we need from
1392   # Xext is optional, the chances a system has *none* of these things is so
1393   # small that we just unconditionally require it.
1394   AC_CHECK_FUNC(XOpenDisplay, :,
1395                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
1396   AC_CHECK_FUNC(XextFindDisplay, :,
1397                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
1398   AC_CHECK_FUNC(XRenderQueryExtension, :,
1399                 AC_MSG_ERROR([*** libXrender not found. Check 'config.log' for more details.]))
1400
1401   # Check for xReply
1402
1403   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
1404   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
1405       [xReply *rep;],
1406       [AC_MSG_RESULT([no])],
1407       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
1408 #include <X11/Xlibint.h>],
1409            [xReply *rep;],
1410            [AC_MSG_RESULT([yes])
1411             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
1412                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
1413            [AC_MSG_RESULT([unknown])
1414             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1415
1416   # Check for XConvertCase, XInternAtoms (X11R6 specific)
1417
1418   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
1419
1420   # Generic X11R6 check needed for XIM support; we could
1421   # probably use this to replace the above, but we'll
1422   # leave the separate checks for XConvertCase and XInternAtoms
1423   # for clarity
1424
1425   have_x11r6=false
1426   AC_CHECK_FUNC(XAddConnectionWatch,
1427       have_x11r6=true)
1428
1429   if $have_x11r6; then
1430     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1431   fi
1432   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1433
1434   # Check for XKB support.
1435
1436   if test "x$enable_xkb" = "xyes"; then
1437         AC_MSG_WARN(XKB support explicitly enabled)
1438         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
1439   elif test "x$enable_xkb" = "xmaybe"; then
1440         AC_CHECK_FUNC(XkbQueryExtension,
1441                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1442   else
1443         AC_MSG_WARN(XKB support explicitly disabled)
1444   fi
1445
1446   # Check for shaped window extension
1447
1448   AC_CHECK_FUNC(XShapeCombineMask, :,
1449      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1450
1451   # X SYNC check
1452   gtk_save_CFLAGS="$CFLAGS"
1453   CFLAGS="$CFLAGS $x_cflags"
1454
1455   AC_CHECK_FUNC(XSyncQueryExtension,
1456       [AC_CHECK_HEADER(X11/extensions/sync.h,
1457           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1458           :, [#include <X11/Xlib.h>])])
1459
1460   CFLAGS="$gtk_save_CFLAGS"
1461
1462   # Xshm checks
1463
1464   if test "x$enable_shm" = "xyes"; then
1465      # Check for the XShm extension, normally in Xext
1466      AC_CHECK_FUNC(XShmAttach,
1467         :,
1468         # On AIX, it is in XextSam instead
1469         [AC_CHECK_LIB(XextSam, XShmAttach,
1470             [GTK_ADD_LIB(x_extra_libs,XextSam)])])
1471   fi
1472
1473   if test "x$enable_shm" = "xyes"; then
1474     # Check for shared memory
1475     AC_CHECK_HEADER(sys/ipc.h,
1476                     AC_DEFINE(HAVE_IPC_H, 1,
1477                               [Define to 1 if ipc.h is available]),
1478                     no_sys_ipc=yes)
1479     AC_CHECK_HEADER(sys/shm.h,
1480                     AC_DEFINE(HAVE_SHM_H, 1,
1481                               [Define to 1 if shm.h is available]),
1482                     no_sys_shm=yes)
1483
1484     # Check for the X shared memory extension header file
1485     have_xshm=no
1486     AC_MSG_CHECKING(X11/extensions/XShm.h)
1487     if test "x$no_xext_lib" = "xyes"; then
1488       :
1489     else
1490       gtk_save_CFLAGS="$CFLAGS"
1491       CFLAGS="$CFLAGS $x_cflags"
1492       AC_TRY_COMPILE([
1493 #include <stdlib.h>
1494 #include <sys/types.h>
1495 #include <sys/ipc.h>
1496 #include <sys/shm.h>
1497 #include <X11/Xlib.h>
1498 #include <X11/Xutil.h>
1499 #include <X11/extensions/XShm.h>
1500 ], [XShmSegmentInfo *x_shm_info;], have_xshm=yes)
1501       CFLAGS="$gtk_save_CFLAGS"
1502     fi
1503     AC_MSG_RESULT($have_xshm)
1504     if test $have_xshm = yes ; then
1505       AC_DEFINE(HAVE_XSHM_H, 1,
1506                 [Define to 1 if xshm.h is available])
1507     fi
1508   fi
1509
1510   if test "x$enable_xinerama" = "xyes"; then
1511     # Check for Xinerama extension (Solaris impl or Xfree impl)
1512     gtk_save_cppflags="$CPPFLAGS"
1513     CPPFLAGS="$CPPFLAGS $x_cflags"
1514
1515     # Check for XFree
1516     AC_MSG_CHECKING(for Xinerama support on XFree86)
1517
1518     have_xfree_xinerama=false
1519     if $PKG_CONFIG --exists xinerama ; then
1520        have_xfree_xinerama=true
1521        X_PACKAGES="$X_PACKAGES xinerama"
1522     else
1523        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1524            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1525            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1526            have_xfree_xinerama=true], :,
1527            [#include <X11/Xlib.h>])])
1528     fi
1529
1530     if $have_xfree_xinerama ; then
1531       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1532                 [Define to 1 if XFree Xinerama is available])
1533       AC_DEFINE(HAVE_XINERAMA, 1,
1534                 [Define to 1 is Xinerama is available])
1535       AC_MSG_RESULT(yes)
1536     else
1537       AC_MSG_RESULT(no)
1538
1539       case "$host" in
1540         *-*-solaris*)
1541             # Check for solaris
1542             AC_MSG_CHECKING(for Xinerama support on Solaris)
1543
1544             have_solaris_xinerama=false
1545             AC_CHECK_FUNC(XineramaGetInfo,
1546                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1547                     [have_solaris_xinerama=true], :,
1548                     [#include <X11/Xlib.h>])])
1549
1550             if $have_solaris_xinerama ; then
1551               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1552                         [Define to 1 if solaris xinerama is available])
1553               AC_DEFINE(HAVE_XINERAMA, 1,
1554                         [Define to 1 if xinerama is available])
1555               AC_MSG_RESULT(yes)
1556             else
1557               AC_MSG_RESULT(no)
1558             fi
1559             ;;
1560         *)
1561             ;;
1562       esac
1563     fi
1564   fi
1565
1566   # set up things for XInput
1567
1568   if test "x$with_xinput" = "xxfree" || test "x$with_xinput" = "xyes"; then
1569     AC_DEFINE(XINPUT_XFREE, 1,
1570               [Define to 1 if XFree XInput should be used])
1571
1572     if $PKG_CONFIG --exists xi ; then
1573       X_PACKAGES="$X_PACKAGES xi"
1574     else
1575       GTK_ADD_LIB(x_extra_libs, Xi)
1576     fi
1577   else
1578     AC_DEFINE(XINPUT_NONE, 1,
1579               [Define to 1 if no XInput should be used])
1580   fi
1581
1582   AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree || test x$with_xinput = xyes)
1583
1584   # Check for the RANDR extension
1585   if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1586      AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1587
1588      X_PACKAGES="$X_PACKAGES xrandr"
1589   fi
1590
1591   # Checks for Xcursor library
1592
1593   if $PKG_CONFIG --exists xcursor ; then
1594     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1595
1596     X_PACKAGES="$X_PACKAGES xcursor"
1597   fi
1598
1599   # Checks for XFixes extension
1600
1601   if $PKG_CONFIG --exists xfixes ; then
1602     AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1603
1604     X_PACKAGES="$X_PACKAGES xfixes"
1605     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1606   fi
1607
1608   # Checks for Xcomposite extension
1609
1610   if $PKG_CONFIG --exists xcomposite ; then
1611     AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1612
1613     X_PACKAGES="$X_PACKAGES xcomposite"
1614     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1615   fi
1616
1617   # Checks for Xdamage extension
1618
1619   if $PKG_CONFIG --exists xdamage ; then
1620     AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1621
1622     X_PACKAGES="$X_PACKAGES xdamage"
1623     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1624   fi
1625
1626   if $have_base_x_pc ; then
1627     GDK_EXTRA_LIBS="$x_extra_libs"
1628   else
1629     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1630   fi
1631
1632   CPPFLAGS="$gtk_save_cppflags"
1633   LIBS="$gtk_save_libs"
1634
1635   AM_CONDITIONAL(USE_X11, true)
1636 else
1637   XPACKAGES=
1638
1639   AM_CONDITIONAL(XINPUT_XFREE, false)
1640   AM_CONDITIONAL(USE_X11, false)
1641   AM_CONDITIONAL(HAVE_X11R6, false)
1642 fi
1643
1644 if test "x$gdktarget" = "xwin32"; then
1645   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
1646   AM_CONDITIONAL(USE_WIN32, true)
1647 else
1648   AM_CONDITIONAL(USE_WIN32, false)
1649 fi
1650
1651 if test "x$gdktarget" = "xquartz"; then
1652   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
1653   AM_CONDITIONAL(USE_QUARTZ, true)
1654 else
1655   AM_CONDITIONAL(USE_QUARTZ, false)
1656 fi
1657
1658 GDK_PIXBUF_XLIB_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_XLIB_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
1659 GDK_PIXBUF_XLIB_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_PIXBUF_XLIB_EXTRA_CFLAGS"
1660
1661 AC_SUBST(GDK_PIXBUF_XLIB_PACKAGES)
1662 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_LIBS)
1663 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_CFLAGS)
1664 AC_SUBST(GDK_PIXBUF_XLIB_DEP_LIBS)
1665 AC_SUBST(GDK_PIXBUF_XLIB_DEP_CFLAGS)
1666
1667 if test "x$gdktarget" = "xdirectfb"; then
1668   DIRECTFB_REQUIRED_VERSION=1.0.0
1669   AC_MSG_CHECKING(for DirectFB)
1670
1671   PKG_CHECK_MODULES(DIRECTFB, [directfb >= $DIRECTFB_REQUIRED_VERSION])
1672   AM_CONDITIONAL(USE_DIRECTFB, true)
1673 else
1674   AM_CONDITIONAL(USE_DIRECTFB, false)
1675 fi
1676
1677
1678 # Check for Pango flags
1679
1680 if test "x$gdktarget" = "xwin32"; then
1681         PANGO_PACKAGES="pangowin32 pangocairo"
1682 else
1683         PANGO_PACKAGES="pango pangocairo"
1684 fi
1685
1686 AC_MSG_CHECKING(Pango flags)
1687 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1688         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1689         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1690
1691         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1692 else
1693         AC_MSG_ERROR([
1694 *** Pango not found. Pango built with Cairo support is required
1695 *** to build GTK+. See http://www.pango.org for Pango information.
1696 ])
1697 fi
1698
1699 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1700
1701 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1702         :
1703 else
1704         gtk_save_LIBS="$LIBS"
1705         LIBS="$PANGO_LIBS $LIBS"
1706         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1707 *** Can't link to Pango. Pango is required to build
1708 *** GTK+. For more information see http://www.pango.org]))
1709         LIBS="$gtk_save_LIBS"
1710 fi
1711
1712 CFLAGS="$saved_cflags"
1713 LDFLAGS="$saved_ldflags"
1714
1715 GDK_PACKAGES="$PANGO_PACKAGES gio-2.0 $X_PACKAGES cairo-$cairo_backend"
1716 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
1717 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS"
1718 #
1719 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1720 # into the pkg-config files
1721 #
1722 if test $enable_explicit_deps != yes ; then
1723   GDK_PACKAGES="$PANGO_PACKAGES"
1724   GDK_EXTRA_LIBS=
1725 fi
1726
1727 AC_SUBST(GDK_PACKAGES)
1728 AC_SUBST(GDK_EXTRA_LIBS)
1729 AC_SUBST(GDK_EXTRA_CFLAGS)
1730 AC_SUBST(GDK_DEP_LIBS)
1731 AC_SUBST(GDK_DEP_CFLAGS)
1732
1733
1734 ########################################
1735 # Check for Accessibility Toolkit flags
1736 ########################################
1737
1738 ATK_PACKAGES=atk
1739 AC_MSG_CHECKING(ATK flags)
1740 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1741         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1742         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1743
1744         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1745 else
1746         AC_MSG_ERROR([
1747 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1748 *** to build GTK+.
1749 ])
1750 fi
1751
1752 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1753         :
1754 else
1755         gtk_save_LIBS="$LIBS"
1756         LIBS="$ATK_LIBS $LIBS"
1757         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1758                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1759                 *** to build GTK+]))
1760         LIBS="$gtk_save_LIBS"
1761 fi
1762
1763 GTK_PACKAGES="atk cairo gio-2.0"
1764 if test "x$gdktarget" = "xx11"; then
1765   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1766 fi
1767 GTK_EXTRA_LIBS=
1768 GTK_EXTRA_CFLAGS=
1769 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
1770 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1771
1772 if test x"$os_win32" = xyes; then
1773   GTK_EXTRA_CFLAGS="$msnative_struct"
1774 fi
1775
1776 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1777 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1778 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1779 CAIRO_PREFIX="`pkg-config --variable=prefix cairo`"
1780
1781 if test $enable_explicit_deps != yes ; then
1782   GDK_PIXBUF_EXTRA_LIBS=
1783 fi
1784
1785 AC_SUBST(GDK_PIXBUF_PACKAGES)
1786 AC_SUBST(GDK_PIXBUF_EXTRA_LIBS)
1787 AC_SUBST(GDK_PIXBUF_EXTRA_CFLAGS)
1788 AC_SUBST(GDK_PIXBUF_DEP_LIBS)
1789 AC_SUBST(GDK_PIXBUF_DEP_CFLAGS)
1790
1791 AC_SUBST(GTK_PACKAGES)
1792 AC_SUBST(GTK_EXTRA_LIBS)
1793 AC_SUBST(GTK_EXTRA_CFLAGS)
1794 AC_SUBST(GTK_DEP_LIBS)
1795 AC_SUBST(GTK_DEP_CFLAGS)
1796
1797 AC_SUBST(GLIB_PREFIX)
1798 AC_SUBST(ATK_PREFIX)
1799 AC_SUBST(PANGO_PREFIX)
1800 AC_SUBST(CAIRO_PREFIX)
1801
1802 AC_SUBST(GTK_DEBUG_FLAGS)
1803 AC_SUBST(GTK_XIM_FLAGS)
1804
1805 ########################
1806 # Checks needed for gail
1807 ########################
1808
1809 old_LIBS="$LIBS"
1810 dnl Checks for inet libraries:
1811 AC_SEARCH_LIBS(gethostent, nsl)
1812 AC_SEARCH_LIBS(setsockopt, socket)
1813 AC_SEARCH_LIBS(connect, inet)
1814
1815 dnl check for the sockaddr_un.sun_len member
1816 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1817                 [struct_sockaddr_un_sun_len=true],
1818                 [struct_sockaddr_un_suin_len=false],
1819                 [#include <sys/types.h>
1820                  #include <sys/un.h>]
1821                 )
1822 case $struct_sockaddr_un_sun_len in
1823         true)
1824                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1825                                    [Have the sockaddr_un.sun_len member])
1826                 ;;
1827         *)
1828                 ;;
1829 esac
1830
1831 GAIL_INET_LIBS="$LIBS"
1832 AC_SUBST([GAIL_INET_LIBS])
1833
1834 LIBS="$old_LIBS"
1835
1836 ################################################################
1837 # Printing system checks
1838 ################################################################
1839
1840 AC_ARG_ENABLE(cups,
1841               [AC_HELP_STRING([--disable-cups]
1842                               [disable cups print backend])],,
1843               [enable_cups=auto])
1844
1845 if test "x$enable_cups" = "xno"; then
1846   AM_CONDITIONAL(HAVE_CUPS, false)
1847 else
1848   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1849   if test "x$CUPS_CONFIG" = "xno"; then
1850     if test "x$enable_cups" = "xauto"; then
1851       AM_CONDITIONAL(HAVE_CUPS, false)
1852     else
1853       AC_MSG_ERROR([
1854 *** cups not found.
1855 ])
1856     fi
1857   else
1858     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1859     CUPS_LIBS=`$CUPS_CONFIG --libs`
1860
1861     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1862     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1863     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1864
1865     if test $CUPS_API_MAJOR -gt 1 -o \
1866             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1867       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1868                 [Define to 1 if CUPS 1.2 API is available])
1869     fi
1870
1871     AC_SUBST(CUPS_API_MAJOR)
1872     AC_SUBST(CUPS_API_MINOR)
1873     AC_SUBST(CUPS_CFLAGS)
1874     AC_SUBST(CUPS_LIBS)
1875
1876     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1877
1878     AM_CONDITIONAL(HAVE_CUPS, true)
1879
1880     gtk_save_cflags="$CFLAGS"
1881     CFLAGS="$CUPS_CFLAGS"
1882     AC_TRY_COMPILE([#include <cups/http.h>],
1883                    [http_t http; char *s = http.authstring;],
1884                    [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1885                               [Define if cups http_t authstring field is accessible])],)
1886     CFLAGS="$gtk_save_cflags"
1887
1888     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1889
1890     gtk_save_libs="$LIBS"
1891     LIBS="$CUPS_LIBS"
1892     AC_CHECK_FUNCS(httpGetAuthString)
1893     LIBS="$gtk_save_libs"
1894   fi
1895 fi
1896
1897 # Checks to see if we should compile with PAPI backend for GTK+
1898 #
1899
1900 AC_ARG_ENABLE(papi,
1901               [AC_HELP_STRING([--disable-papi]
1902                               [disable papi print backend])],,
1903              [enable_papi=auto])
1904
1905 if test "x$enable_papi" = "xno"; then
1906   AM_CONDITIONAL(HAVE_PAPI, false)
1907 else
1908   AC_MSG_CHECKING(libpapi)
1909   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1910   if test $have_papi = yes; then
1911     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1912   fi
1913   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1914   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1915     AC_MSG_ERROR([
1916 *** papi not found.
1917 ])
1918   fi
1919 fi
1920
1921 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1922
1923 gtk_save_cppflags="$CPPFLAGS"
1924 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1925
1926 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1927 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1928 *** backend enabled.]))
1929
1930 if test "$os_win32" != "yes"; then
1931   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1932 *** Can't find cairo-ps.h. You must build Cairo with the
1933 *** postscript backend enabled.]))
1934 fi
1935
1936 CPPFLAGS="$gtk_save_cppflags"
1937
1938
1939 AC_ARG_ENABLE(test-print-backend,
1940               [AC_HELP_STRING([--enable-test-print-backend],
1941                               [build test print backend])],,
1942               [enable_test_print_backend=no])
1943 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1944
1945
1946 ################################################################
1947 # Strip -export-dynamic from the link lines of various libraries
1948 ################################################################
1949
1950 #
1951 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1952 #  but this flag is only meaningful for executables. For libraries
1953 #  the effect is undefined; what it causes on Linux is that the
1954 #  export list from -export-symbols-regex is ignored and everything
1955 #  is exported
1956 #
1957 # We are using gmodule-no-export now, but I'm leaving the stripping
1958 # code in place for now, since pango and atk still require gmodule.
1959 export SED
1960 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1961 if test -n "$export_dynamic"; then
1962   GDK_PIXBUF_DEP_LIBS=`echo $GDK_PIXBUF_DEP_LIBS | sed -e "s/$export_dynamic//"`
1963   GDK_PIXBUF_XLIB_DEP_LIBS=`echo $GDK_PIXBUF_XLIB_DEP_LIBS | sed -e "s/$export_dynamic//"`
1964   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1965   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1966 fi
1967
1968
1969 ##################################################
1970 # Checks for gtk-doc and docbook-tools
1971 ##################################################
1972
1973 GTK_DOC_CHECK([1.11])
1974
1975 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1976 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1977
1978 AC_ARG_ENABLE(man,
1979               [AC_HELP_STRING([--enable-man],
1980                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1981               enable_man=no)
1982
1983 if test "${enable_man}" != no; then
1984   dnl
1985   dnl Check for xsltproc
1986   dnl
1987   AC_PATH_PROG([XSLTPROC], [xsltproc])
1988   if test -z "$XSLTPROC"; then
1989     enable_man=no
1990   fi
1991
1992   dnl check for DocBook DTD and stylesheets in the local catalog.
1993   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1994      [DocBook XML DTD V4.1.2],,enable_man=no)
1995   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1996      [DocBook XSL Stylesheets],,enable_man=no)
1997 fi
1998
1999 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2000
2001
2002 ##################################################
2003 # Output commands
2004 ##################################################
2005
2006 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
2007         outfile=gdkconfig.h-tmp
2008         cat > $outfile <<\_______EOF
2009 /* gdkconfig.h
2010  *
2011  * This is a generated file.  Please modify `configure.in'
2012  */
2013
2014 #ifndef GDKCONFIG_H
2015 #define GDKCONFIG_H
2016
2017 #ifdef __cplusplus
2018 extern "C" {
2019 #endif /* __cplusplus */
2020
2021 #ifndef GSEAL
2022 /* introduce GSEAL() here for all of Gdk and Gtk+ without the need to modify GLib */
2023 #  ifdef GSEAL_ENABLE
2024 #    define GSEAL(ident)      _g_sealed__ ## ident
2025 #  else
2026 #    define GSEAL(ident)      ident
2027 #  endif
2028 #endif /* !GSEAL */
2029
2030 _______EOF
2031
2032         cat >>$outfile <<_______EOF
2033 $gdk_windowing
2034 $gdk_wc
2035 _______EOF
2036
2037         cat >>$outfile <<_______EOF
2038
2039 #ifdef __cplusplus
2040 }
2041 #endif /* __cplusplus */
2042
2043 #endif /* GDKCONFIG_H */
2044 _______EOF
2045
2046
2047         if cmp -s $outfile gdk/gdkconfig.h; then
2048           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
2049           rm -f $outfile
2050         else
2051           mv $outfile gdk/gdkconfig.h
2052         fi
2053 ],[
2054 if test "x$gdktarget" = "xx11" ; then
2055   gdk_windowing='
2056 #define GDK_WINDOWING_X11'
2057 elif test "x$gdktarget" = "xwin32" ; then
2058   gdk_windowing='
2059 #define GDK_NATIVE_WINDOW_POINTER
2060
2061 #define GDK_WINDOWING_WIN32'
2062 elif test "x$gdktarget" = "xquartz" ; then
2063   gdk_windowing='
2064 #define GDK_WINDOWING_QUARTZ'
2065 elif test "x$gdktarget" = "xdirectfb" ; then
2066   gdk_windowing='
2067 #define GDK_WINDOWING_DIRECTFB'
2068 fi
2069
2070 if test x$gdk_wchar_h = xyes; then
2071   gdk_wc='
2072 #define GDK_HAVE_WCHAR_H 1'
2073 fi
2074 if test x$gdk_wctype_h = xyes; then
2075   gdk_wc="\$gdk_wc
2076 #define GDK_HAVE_WCTYPE_H 1"
2077 fi
2078 if test x$gdk_working_wctype = xno; then
2079   gdk_wc="\$gdk_wc
2080 #define GDK_HAVE_BROKEN_WCTYPE 1"
2081 fi
2082
2083
2084 ])
2085
2086 AC_CONFIG_FILES([
2087 config.h.win32
2088 gtk-zip.sh
2089 Makefile
2090 gdk-pixbuf-2.0.pc
2091 gdk-2.0.pc
2092 gtk+-2.0.pc
2093 gtk+-unix-print-2.0.pc
2094 gail.pc
2095 gdk-pixbuf-2.0-uninstalled.pc
2096 gdk-2.0-uninstalled.pc
2097 gtk+-2.0-uninstalled.pc
2098 gail-uninstalled.pc
2099 m4macros/Makefile
2100 po/Makefile.in
2101 po-properties/Makefile.in
2102 demos/Makefile
2103 demos/gtk-demo/Makefile
2104 demos/gtk-demo/geninclude.pl
2105 tests/Makefile
2106 docs/Makefile
2107 docs/reference/Makefile
2108 docs/reference/gdk-pixbuf/Makefile
2109 docs/reference/gdk-pixbuf/version.xml
2110 docs/reference/gdk/Makefile
2111 docs/reference/gdk/version.xml
2112 docs/reference/gtk/Makefile
2113 docs/reference/gtk/version.xml
2114 docs/reference/libgail-util/Makefile
2115 docs/faq/Makefile
2116 docs/tools/Makefile
2117 docs/tutorial/Makefile
2118 gdk-pixbuf/Makefile
2119 gdk-pixbuf/gdk_pixbuf.rc
2120 gdk-pixbuf/gdk-pixbuf-features.h
2121 gdk-pixbuf/pixops/Makefile
2122 gdk/Makefile
2123 gdk/x11/Makefile
2124 gdk/win32/Makefile
2125 gdk/win32/rc/Makefile
2126 gdk/win32/rc/gdk.rc
2127 gdk/quartz/Makefile
2128 gdk/directfb/Makefile
2129 gdk/tests/Makefile
2130 gtk/Makefile
2131 gtk/makefile.msc
2132 gtk/gtkversion.h
2133 gtk/gtk-win32.rc
2134 gtk/theme-bits/Makefile
2135 gtk/tests/Makefile
2136 modules/Makefile
2137 modules/other/Makefile
2138 modules/other/gail/Makefile
2139 modules/other/gail/libgail-util/Makefile
2140 modules/other/gail/tests/Makefile
2141 modules/engines/Makefile
2142 modules/engines/pixbuf/Makefile
2143 modules/engines/ms-windows/Makefile
2144 modules/engines/ms-windows/Theme/Makefile
2145 modules/engines/ms-windows/Theme/gtk-2.0/Makefile
2146 modules/input/Makefile
2147 modules/printbackends/Makefile
2148 modules/printbackends/cups/Makefile
2149 modules/printbackends/lpr/Makefile
2150 modules/printbackends/file/Makefile
2151 modules/printbackends/papi/Makefile
2152 modules/printbackends/test/Makefile
2153 perf/Makefile
2154 contrib/Makefile
2155 contrib/gdk-pixbuf-xlib/Makefile
2156 contrib/gdk-pixbuf-xlib/gdk-pixbuf-xlib-2.0.pc
2157 ])
2158
2159 AC_OUTPUT
2160
2161 echo "configuration:
2162         target: $gdktarget"