Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(gdk/gdktypes.h)
   3
   4 # In the following, there are a the following variants
   5 # of GLib cflags and libs variables
   6 #
   7 # GLIB_CFLAGS:  cflags for compiling libraries and example progs
   8 # GLIB_LIBS:    libraries for linking example programs
   9 # GLIB_DEPLIBS: libraries for linking libraries against
  10
  11
  12 ## We could have pkg-config uniquify the ldflags and cflags by calling
  13 ## it once with both the GLib and Pango package names, but we don't,
  14 ## someone should fix that.
  15
  16
  17 # Save this value here, since automake will set cflags later
  18 cflags_set=${CFLAGS+set}
  19
  20 dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  21 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  22 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  23 #
  24 # Making releases:
  25 #   GTK_MICRO_VERSION += 1;
  26 #   GTK_INTERFACE_AGE += 1;
  27 #   GTK_BINARY_AGE += 1;
  28 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  29 # if backwards compatibility has been broken,
  30 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  31 #
  32 GTK_MAJOR_VERSION=1
  33 GTK_MINOR_VERSION=3
  34 GTK_MICRO_VERSION=2
  35 GTK_INTERFACE_AGE=0
  36 GTK_BINARY_AGE=0
  37 GTK_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$GTK_MICRO_VERSION
  38 dnl
  39 AC_DIVERT_POP()dnl
  40
  41 AC_SUBST(GTK_MAJOR_VERSION)
  42 AC_SUBST(GTK_MINOR_VERSION)
  43 AC_SUBST(GTK_MICRO_VERSION)
  44 AC_SUBST(GTK_INTERFACE_AGE)
  45 AC_SUBST(GTK_BINARY_AGE)
  46 AC_SUBST(GTK_VERSION)
  47
  48 # libtool versioning
  49 LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  50 LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  51 LT_REVISION=$GTK_INTERFACE_AGE
  52 LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  53 AC_SUBST(LT_RELEASE)
  54 AC_SUBST(LT_CURRENT)
  55 AC_SUBST(LT_REVISION)
  56 AC_SUBST(LT_AGE)
  57
  58 #
  59 # gdk-pixbuf gets versioned separately, and for now, using standard
  60 # libtool versioning, not GTK+-style versioning
  61 #
  62 GDK_PIXBUF_MAJOR=0
  63 GDK_PIXBUF_MINOR=8
  64 GDK_PIXBUF_MICRO=0
  65 GDK_PIXBUF_VERSION="${GDK_PIXBUF_MAJOR}.${GDK_PIXBUF_MINOR}.${GDK_PIXBUF_MICRO}"
  66 AC_SUBST(GDK_PIXBUF_MAJOR)
  67 AC_SUBST(GDK_PIXBUF_MINOR)
  68 AC_SUBST(GDK_PIXBUF_MICRO)
  69 AC_SUBST(GDK_PIXBUF_VERSION)
  70
  71 # For automake.
  72 VERSION=$GTK_VERSION
  73 PACKAGE=gtk+
  74
  75 GETTEXT_PACKAGE=gtk20
  76 AC_SUBST(GETTEXT_PACKAGE)
  77 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
  78
  79 # Save this value here, since automake will set cflags later
  80 cflags_set=${CFLAGS+set}
  81
  82 dnl Initialize automake stuff
  83 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  84
  85 # Specify a configuration file
  86 AM_CONFIG_HEADER(config.h)
  87
  88 dnl Initialize libtool
  89 AM_PROG_LIBTOOL
  90
  91 dnl Initialize maintainer mode
  92 AM_MAINTAINER_MODE
  93
  94 AC_CANONICAL_HOST
  95
  96 dnl figure debugging default, prior to $ac_help setup
  97 dnl
  98 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  99 if test `expr $GTK_MINOR_VERSION \% 2` = 1 ; then
 100         debug_default=yes
 101 else
 102         debug_default=minimum
 103 fi
 104 AC_DIVERT_POP()dnl
 105
 106 dnl declare --enable-* args and collect ac_help strings
 107 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 108 AC_ARG_ENABLE(shm, [  --enable-shm            support shared memory if available [default=yes]],
 109                    echo $enable_shm, enable_shm="yes")
 110 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 111                     , enable_ansi=no)
 112 AC_ARG_WITH(glib, [  --with-glib=DIR         Use uninstalled copy of glib])
 113 AC_ARG_ENABLE(xim, [  --enable-xim            support XIM [default=yes]],
 114                         , enable_xim="yes")
 115 AC_ARG_ENABLE(xim_inst, [  --disable-xim-inst      does not use xim instantiate callback],
 116                         , enable_xim_inst="maybe")
 117 AC_ARG_ENABLE(xkb, [  --enable-xkb            support XKB [default=maybe]],
 118                         , enable_xkb="maybe")
 119 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 120 AC_ARG_WITH(locale, [  --with-locale=LOCALE    locale name you want to use ])
 121
 122 AC_ARG_WITH(xinput, [  --with-xinput=[no/gxi/xfree] support XInput ])
 123
 124 gdktarget=x11
 125 gdktargetlib=libgdk-x11-1.3.la
 126 gtktargetlib=libgtk-x11-1.3.la
 127 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[x11/nanox/linux-fb] select GDK target [default=x11] ],
 128         gdktarget=$with_gdktarget)
 129
 130 AC_SUBST(gdktarget)
 131 case $gdktarget in
 132   x11|nanox|linux-fb) ;;
 133   *) AC_MSG_ERROR([Invalid target for GDK: use x11, nanox or linux-fb.]);;
 134 esac
 135
 136 AC_ARG_ENABLE(shadowfb, [  --disable-shadowfb      disable shadowfb support for linux-fb],,enable_shadowfb=yes)
 137
 138 if test "x$enable_debug" = "xyes"; then
 139   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 140   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 141 else
 142   if test "x$enable_debug" = "xno"; then
 143     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 144   else
 145     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 146   fi
 147 fi
 148
 149 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 150
 151
 152 # Build time sanity check...
 153 AM_SANITY_CHECK
 154
 155 # Checks for programs.
 156 AC_PROG_CC
 157 AC_ISC_POSIX
 158 AM_PROG_CC_STDC
 159 AC_PROG_INSTALL
 160 AC_PROG_MAKE_SET
 161
 162 changequote(,)dnl
 163 if test "x$GCC" = "xyes"; then
 164   case " $CFLAGS " in
 165   *[\ \ ]-Wall[\ \      ]*) ;;
 166   *) CFLAGS="$CFLAGS -Wall" ;;
 167   esac
 168
 169   if test "x$enable_ansi" = "xyes"; then
 170     case " $CFLAGS " in
 171     *[\ \       ]-ansi[\ \      ]*) ;;
 172     *) CFLAGS="$CFLAGS -ansi" ;;
 173     esac
 174
 175     case " $CFLAGS " in
 176     *[\ \       ]-pedantic[\ \  ]*) ;;
 177     *) CFLAGS="$CFLAGS -pedantic" ;;
 178     esac
 179   fi
 180 fi
 181 changequote([,])dnl
 182
 183 # Honor aclocal flags
 184 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 185
 186 # libtool option to control which symbols are exported
 187 # right now, symbols starting with _ are not exported
 188 LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 189 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 190
 191 # define a MAINT-like variable REBUILD which is set if Perl
 192 # and awk are found, so autogenerated sources can be rebuilt
 193
 194 AC_PROG_AWK
 195 AC_CHECK_PROGS(PERL, perl5 perl)
 196
 197 # We would like indent, but don't require it.
 198 AC_CHECK_PROG(INDENT, indent, indent)
 199
 200 REBUILD=\#
 201 if test "x$enable_rebuilds" = "xyes" && \
 202      test -n "$PERL" && \
 203      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 204      test -n "$AWK" ; then
 205   REBUILD=
 206 fi
 207 AC_SUBST(REBUILD)
 208
 209 AC_CHECK_FUNCS(lstat mkstemp sigsetjmp bind_textdomain_codeset)
 210
 211 AC_MSG_CHECKING(whether make is GNU Make)
 212 STRIP_BEGIN=
 213 STRIP_END=
 214 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 215         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 216         STRIP_END=')'
 217         AC_MSG_RESULT(yes)
 218 else
 219         AC_MSG_RESULT(no)
 220 fi
 221 STRIP_DUMMY=
 222 AC_SUBST(STRIP_DUMMY)
 223 AC_SUBST(STRIP_BEGIN)
 224 AC_SUBST(STRIP_END)
 225
 226 # i18n stuff
 227 ALL_LINGUAS="az ca cs da de el en_GB en@IPA es et eu fa fi fr ga gl he hr hu ia it ja ko lt nl nn no pl pt pt_BR ro ru sk sl sp sr sv tr uk vi wa zh_TW zh_CN"
 228 AM_GTK_GNU_GETTEXT
 229 LIBS="$LIBS $INTLLIBS"
 230
 231 # AM_GTK_GNU_GETTEXT above substs $DATADIRNAME
 232 # this is the directory where the *.{mo,gmo} files are installed
 233 gtklocaledir='${prefix}/${DATADIRNAME}/locale'
 234 AC_SUBST(gtklocaledir)
 235
 236 dnl The DU4 header files don't provide library prototypes unless
 237 dnl -std1 is given to the native cc.
 238 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 239
 240 gtk_save_LIBS=$LIBS
 241 LIBS="$LIBS -lm"
 242 AC_TRY_RUN([#include <math.h>
 243              int main (void) { return (log(1) != log(1.)); }],
 244      AC_MSG_RESULT(none needed),
 245      gtk_save_CFLAGS="$CFLAGS"
 246      CFLAGS="$CFLAGS -std1"
 247      AC_TRY_RUN([#include <math.h>
 248                  int main (void) { return (log(1) != log(1.)); }],
 249          AC_MSG_RESULT(-std1),
 250          AC_MSG_RESULT()
 251          CFLAGS="$gtk_save_CFLAGS"
 252          AC_MSG_WARN(
 253                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 254          true
 255      ),
 256      AC_MSG_RESULT(none needed)
 257 )
 258 LIBS=$gtk_save_LIBS
 259
 260 MATH_LIB=-lm
 261 GTK_LIBS_EXTRA=
 262 AC_MSG_CHECKING(for the BeOS)
 263 case $host in
 264   *-*-beos*)
 265     AC_MSG_RESULT(yes)
 266     GTK_LIBS_EXTRA="-L\$(top_builddir_full)/gdk/.libs -lgdk"
 267     MATH_LIB=
 268   ;;
 269   *)
 270     AC_MSG_RESULT(no)
 271   ;;
 272 esac
 273 AC_SUBST(MATH_LIB)
 274 AC_SUBST(GTK_LIBS_EXTRA)
 275
 276 dnl NeXTStep cc seems to need this
 277 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 278 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 279   AC_MSG_RESULT(none needed),
 280   gtk_save_CFLAGS="$CFLAGS"
 281   CFLAGS="$CFLAGS -posix"
 282   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 283     AC_MSG_RESULT(-posix),
 284     AC_MSG_RESULT()
 285     CFLAGS="$gtk_save_CFLAGS"
 286     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 287
 288
 289 #
 290 # Find pkg-config
 291 #
 292 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 293 if test x$PKG_CONFIG = xno ; then
 294   AC_MSG_ERROR([*** pkg-config not found. See http://pkgconfig.sourceforge.net])
 295 fi
 296
 297 if ! pkg-config --atleast-pkgconfig-version 0.5 ; then
 298   AC_MSG_ERROR([*** pkg-config too old; version 0.5 or better required.])
 299 fi
 300
 301 if test x$with_glib = xyes ; then
 302   AC_MSG_ERROR([
 303 *** Directory must be specified for --with-glib])
 304 fi
 305
 306 if test x$with_glib = x ; then
 307
 308   # Look for separately installed glib
 309
 310   GLIB_PACKAGES="gobject-2.0 gmodule-2.0 gthread-2.0"
 311   GLIB_REQUIRED_VERSION=1.3.2
 312
 313   AC_MSG_CHECKING(GLib flags)
 314   if $PKG_CONFIG --atleast-version $GLIB_REQUIRED_VERSION glib-2.0 ; then
 315         GLIB_CFLAGS=`$PKG_CONFIG --cflags $GLIB_PACKAGES`
 316         GLIB_LIBS=`$PKG_CONFIG --libs $GLIB_PACKAGES`
 317         GLIB_DEPLIBS=$GLIB_LIBS
 318
 319         AC_MSG_RESULT($GLIB_CFLAGS $GLIB_LIBS)
 320   else
 321         AC_MSG_ERROR([
 322 *** GLIB $GLIB_REQUIRED_VERSION or newer is required. The latest version of GLIB
 323 *** is always available from ftp://ftp.gtk.org/.
 324   ])
 325   fi
 326
 327 else
 328   # Use uninstalled glib (assume they got the version right)
 329
 330   if test -e glib-2.0.pc ; then
 331     :
 332   else
 333     AC_MSG_ERROR([GLIB directory ($with_glib) not present or not configured])
 334   fi
 335
 336   # canonicalize relative paths
 337   case $with_glib in
 338     /*)
 339       glib_dir=$with_glib
 340       ;;
 341     *)
 342       glib_dir="\$(top_builddir)/$with_glib"
 343       ;;
 344   esac
 345
 346   GLIB_CFLAGS="-I$glib_dir -I$glib_dir/gmodule"
 347   GLIB_LIBS="$glib_dir/libglib-1.3.la $glib_dir/gmodule/libgmodule-1.3.la"
 348   GLIB_DEPLIBS=
 349 fi
 350
 351 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 352 AC_SUBST(GLIB_CFLAGS)
 353 AC_SUBST(GLIB_LIBS)
 354 AC_SUBST(GLIB_DEPLIBS)
 355
 356 AC_CHECK_HEADERS(dirent.h, AC_DEFINE(HAVE_DIRENT_H))
 357 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 358 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 359 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 360
 361 saved_cflags="$CFLAGS"
 362 saved_ldflags="$LDFLAGS"
 363
 364 if test "x$gdktarget" = "xx11"; then
 365   # Find the X11 include and library directories
 366   AC_PATH_X
 367   AC_PATH_XTRA
 368
 369   if test "x$x_includes" = "x"; then
 370     x_includes="/usr/include"
 371   fi
 372
 373   CFLAGS="$CFLAGS $X_CFLAGS"
 374   LDFLAGS="$LDFLAGS $X_LDFLAGS $X_LIBS"
 375
 376   if test "x$no_x" = "xyes"; then
 377     AC_MSG_ERROR([
 378 *** X libraries or include files not found. Check 'config.log' for
 379 *** more details.])
 380   fi
 381
 382   # Checks for libraries.
 383   # Check for the X11 library
 384   AC_CHECK_LIB(X11, XOpenDisplay, x_libs="-lX11 $X_EXTRA_LIBS",
 385     AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
 386     $X_EXTRA_LIBS)
 387
 388   if test "x$enable_shm" = "xyes"; then
 389     # Check for the Xext library (needed for XShm extention)
 390     AC_CHECK_LIB(Xext, XShmAttach,
 391         x_libs="-lXext $x_libs",
 392         # On AIX, it is in XextSam instead, but we still need -lXext
 393         AC_CHECK_LIB(XextSam, XShmAttach,
 394             x_libs="-lXextSam -lXext $x_libs",
 395             no_xext_lib=yes, $x_libs),
 396         $x_libs)
 397   fi
 398
 399   # Check for shaped window extension
 400
 401   AC_CHECK_LIB(Xext, XShapeCombineMask,
 402       if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 403            x_libs="-lXext $x_libs"
 404       fi
 405       AC_DEFINE(HAVE_SHAPE_EXT),
 406       ,
 407       $x_libs)
 408
 409   # Check for XConvertCase (X11R6 specific)
 410
 411   AC_CHECK_LIB(X11, XConvertCase,
 412       AC_DEFINE(HAVE_XCONVERTCASE),
 413       ,
 414       $x_libs)
 415
 416   #
 417   # Checks for FreeType
 418   #
 419   FREETYPE_LIBS=
 420   FREETYPE_CFLAGS=
 421   have_freetype=false
 422   AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
 423   if test "x$FREETYPE_CONFIG" != "xno" ; then
 424     FREETYPE_CFLAGS=`freetype-config --cflags`
 425     FREETYPE_LIBS=`freetype-config --libs`
 426
 427     AC_CHECK_LIB(freetype, FT_New_Face, have_freetype=true
 428                  ,:,$FREETYPE_LIBS)
 429   fi
 430   AC_SUBST(FREETYPE_CFLAGS)
 431
 432   #
 433   # Checks for Xft/XRender
 434   #
 435   have_xft=false
 436   XFT_LIBS=""
 437   XFT_CFLAGS=""
 438   if test $have_freetype = true ; then
 439     AC_CHECK_LIB(Xrender, XRenderFindFormat,
 440       AC_CHECK_LIB(Xft, XftFontOpen, have_xft=true, :, -lXrender -lXext $X_LIBS $FREETYPE_LIBS)
 441     ,:,-lXext $X_LIBS)
 442
 443     ## be sure we also have Pango built with xft support
 444     if ! $PKG_CONFIG --exists pangoxft ; then
 445         have_xft=false
 446         AC_MSG_WARN([X render extension found, but Pango lacks Xft support])
 447     fi
 448
 449     if $have_xft = 'true' ; then
 450       X_LIBS="-lXft -lXrender -lXext $FREETYPE_LIBS $X_LIBS"
 451       AC_DEFINE(HAVE_XFT)
 452     fi
 453   fi
 454
 455   AC_SUBST(XFT_LIBS)
 456   AM_CONDITIONAL(HAVE_XFT, $have_xft)
 457
 458   # Check for XIM support.
 459
 460   AC_CHECK_LIB(X11, XUnregisterIMInstantiateCallback,
 461             : ,
 462             enable_xim_inst="no",
 463             $x_libs)
 464
 465   # On Solaris, calling XRegisterIMInstantiateCallback seems to
 466   # cause an immediate segfault, so we disable it, unless
 467   # the user specifically forces it to be on.
 468
 469   if test x$enable_xim_inst = xmaybe ; then
 470     case host in
 471           *-*-solaris*)
 472             enable_xim_inst="no"
 473             ;;
 474           *)
 475             enable_xim_inst="yes"
 476             ;;
 477     esac
 478   fi
 479
 480   if test "x$enable_xim" = "xyes"; then
 481     GTK_XIM_FLAGS="-DUSE_XIM"
 482     if test "x$enable_xim_inst" = "xyes"; then
 483       AC_DEFINE(USE_X11R6_XIM)
 484     fi
 485   fi
 486
 487   # Check for XKB support.
 488
 489   if test "x$enable_xkb" = "xyes"; then
 490         AC_MSG_WARN(XKB support explicitly enabled)
 491         AC_DEFINE(HAVE_XKB)
 492   elif test "x$enable_xkb" = "xmaybe"; then
 493         AC_CHECK_LIB(X11, XkbQueryExtension,
 494                      AC_DEFINE(HAVE_XKB),
 495                      ,
 496                      $x_libs)
 497   else
 498         AC_MSG_WARN(XKB support explicitly disabled)
 499   fi
 500
 501   x_cflags="$X_CFLAGS"
 502   x_ldflags="$X_LDFLAGS $X_LIBS"
 503
 504   # set up things for XInput
 505
 506   if test "x$with_xinput" = "xgxi" || test "x$with_xinput" = "xyes"; then
 507     AC_DEFINE(XINPUT_GXI)
 508     xinput_progs=gxid
 509     x_libs="-lXi $x_libs"
 510   elif test "x$with_xinput" = "xxfree"; then
 511     AC_DEFINE(XINPUT_XFREE)
 512     x_libs="-lXi $x_libs"
 513   else
 514     AC_DEFINE(XINPUT_NONE)
 515   fi
 516
 517   AM_CONDITIONAL(XINPUT_GXI, test x$with_xinput = xgxi)
 518   AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree)
 519
 520   if test "x$enable_shm" = "xyes"; then
 521     # Check for shared memory
 522     AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
 523     AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
 524
 525     # Check for the X shared memory extension header file
 526     AC_MSG_CHECKING(X11/extensions/XShm.h)
 527     if test "x$no_xext_lib" = "xyes"; then
 528       AC_MSG_RESULT(no)
 529       no_xshm=yes
 530     else
 531       if test -f "$x_includes/X11/extensions/XShm.h"; then
 532         AC_MSG_RESULT(yes)
 533         AC_DEFINE(HAVE_XSHM_H)
 534       else
 535         AC_MSG_RESULT(no)
 536         no_xshm=yes
 537       fi
 538     fi
 539   fi
 540
 541   more_cflags="$x_cflags"
 542   more_ldflags="$x_ldflags"
 543   more_libs="$x_libs"
 544   more_includes="$x_includes"
 545
 546   # these are already defined above
 547   #gdktargetlib = "libgdk-x11-1.3.la"
 548   #gtktargetlib = "libgtk-x11-1.3.la"
 549
 550   AM_CONDITIONAL(USE_X11, true)
 551 else
 552   AM_CONDITIONAL(USE_X11, false)
 553 fi
 554
 555 if test "x$gdktarget" = "xnanox"; then
 556   AC_CHECK_LIB(nano-X, GrOpen,,AC_MSG_ERROR([nano-X libraries not found.]))
 557   # nano-X may require additional libraries
 558   more_cflags=
 559   more_ldflags=
 560   more_libs="-lnano-X"
 561   more_includes=
 562
 563   gdktargetlib="libgdk-nanox-1.3.la"
 564   gtktargetlib="libgtk-nanox-1.3.la"
 565
 566   with_xinput=no
 567   AC_DEFINE(XINPUT_NONE)
 568   x_cflags=
 569   x_includes=
 570   x_ldflags=
 571   x_libs=
 572   xinput_progs=
 573   AM_CONDITIONAL(USE_NANOX, true)
 574 else
 575   AM_CONDITIONAL(USE_NANOX, false)
 576 fi
 577
 578 if test "x$gdktarget" = "xlinux-fb"; then
 579   more_cflags=
 580   more_ldflags=
 581   more_libs=
 582   more_includes=
 583
 584   gdktargetlib="libgdk-linux-fb-1.3.la"
 585   gtktargetlib="libgtk-linux-fb-1.3.la"
 586
 587   with_xinput=no
 588   AC_DEFINE(XINPUT_NONE)
 589   x_cflags=
 590   x_includes=
 591   x_ldflags=
 592   x_libs=
 593   xinput_progs=
 594
 595   AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
 596   if test x$FREETYPE_CONFIG = xno ; then
 597     AC_MSG_ERROR([*** freetype-config not found])
 598   fi
 599
 600   FREETYPE_CFLAGS="`$FREETYPE_CONFIG --cflags`"
 601   FREETYPE_LIBS="`$FREETYPE_CONFIG --libs`"
 602   CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 603
 604   if test x$enable_shadowfb = xyes ; then
 605     AC_DEFINE(ENABLE_SHADOW_FB)
 606   fi
 607
 608   AM_CONDITIONAL(USE_LINUX_FB, true)
 609 else
 610   AM_CONDITIONAL(USE_LINUX_FB, false)
 611 fi
 612 AC_SUBST(ENABLE_SHADOW_FB)
 613 AC_SUBST(FREETYPE_LIBS)
 614 AC_SUBST(FREETYPE_CFLAGS)
 615
 616 #
 617 # Pick correct Pango packages to use
 618 #
 619
 620 if test "x$gdktarget" = "xx11"; then
 621         if $have_xft = true ; then
 622             PANGO_PACKAGES="pangox pangoxft"
 623         else
 624             PANGO_PACKAGES=pangox
 625         fi
 626 elif test "x$gdktarget" = "xlinux-fb"; then
 627         PANGO_PACKAGES=pangoft2
 628 else
 629         PANGO_PACKAGES=pango
 630 fi
 631
 632 AC_SUBST(PANGO_PACKAGES)
 633
 634 # Check for Pango flags
 635
 636 AC_MSG_CHECKING(Pango flags)
 637 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
 638         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
 639         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
 640
 641         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
 642 else
 643         AC_MSG_ERROR([
 644 *** Pango not found. Pango is required to build GTK+.
 645 *** See http://www.pango.org for Pango information.
 646 *** For the framebuffer target, you will need to build
 647 *** Pango with freetype support.
 648 ])
 649 fi
 650
 651 CFLAGS="$CFLAGS $PANGO_CFLAGS"
 652 AC_SUBST(PANGO_LIBS)
 653 AC_SUBST(PANGO_CFLAGS)
 654
 655 AC_CHECK_LIB(pango, pango_context_new, :, AC_MSG_ERROR([
 656 *** Can't link to Pango. Pango is required to build
 657 *** GTK+. For more information see http://www.pango.org]), $PANGO_LIBS $x_ldflags $x_libs)
 658
 659 CFLAGS="$saved_cflags"
 660 LDFLAGS="$saved_ldflags"
 661
 662 AC_SUBST(x_cflags)
 663 AC_SUBST(x_includes)
 664 AC_SUBST(x_ldflags)
 665 AC_SUBST(x_libs)
 666 AC_SUBST(xinput_progs)
 667
 668 AC_SUBST(more_cflags)
 669 AC_SUBST(more_includes)
 670 AC_SUBST(more_ldflags)
 671 AC_SUBST(more_libs)
 672 AC_SUBST(gdktargetlib)
 673 AC_SUBST(gtktargetlib)
 674
 675
 676 # Check if X_LOCALE definition is necessary
 677
 678 AC_MSG_CHECKING(need -DX_LOCALE)
 679
 680 AC_TRY_RUN([
 681 #include <stdio.h>
 682 #include <locale.h>
 683
 684 int
 685 main ()
 686 {
 687   return setlocale (LC_ALL, "${with_locale}") == NULL;
 688 }],
 689 need_x_locale=no,
 690 need_x_locale=yes,
 691 need_x_locale=no)
 692 AC_MSG_RESULT($need_x_locale)
 693
 694 if test $need_x_locale = yes; then
 695   GTK_LOCALE_FLAGS="-DX_LOCALE"
 696 fi
 697
 698 # Checks for header files.
 699 AC_HEADER_STDC
 700
 701 # Checks for typedefs, structures, and compiler characteristics.
 702 AC_C_CONST
 703
 704 # Checks for library functions.
 705 AC_TYPE_SIGNAL
 706 AC_FUNC_MMAP
 707
 708 AC_CHECK_FUNCS(getresuid)
 709 AC_TYPE_UID_T
 710
 711 # Check if <sys/select.h> needs to be included for fd_set
 712 AC_MSG_CHECKING([for fd_set])
 713 AC_TRY_COMPILE([#include <sys/types.h>],
 714         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 715 if test $gtk_ok = yes; then
 716     AC_MSG_RESULT([yes, found in sys/types.h])
 717 else
 718     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 719     if test $gtk_ok = yes; then
 720         AC_DEFINE(HAVE_SYS_SELECT_H)
 721         AC_MSG_RESULT([yes, found in sys/select.h])
 722     else
 723         AC_DEFINE(NO_FD_SET)
 724         AC_MSG_RESULT(no)
 725     fi
 726 fi
 727
 728 # `widechar' tests for gdki18n.h
 729 AC_MSG_CHECKING(for wchar.h)
 730 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 731 if test $gdk_wchar_h = yes; then
 732    AC_DEFINE(HAVE_WCHAR_H,1,[Have wchar.h include file])
 733 fi
 734 AC_MSG_RESULT($gdk_wchar_h)
 735
 736 # Check for wctype.h (for iswalnum)
 737 AC_MSG_CHECKING(for wctype.h)
 738 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 739 if test $gdk_wctype_h = yes; then
 740    AC_DEFINE(HAVE_WCTYPE_H,1,[Have wctype.h include file])
 741 fi
 742 AC_MSG_RESULT($gdk_wctype_h)
 743
 744 # in Solaris 2.5, `iswalnum' is in -lw
 745 GDK_WLIBS=
 746 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 747
 748 oLIBS="$LIBS"
 749 LIBS="$LIBS $GDK_WLIBS"
 750 # The following is necessary for Linux libc-5.4.38
 751 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 752 AC_TRY_LINK([#include <stdlib.h>],[
 753 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 754 #  ifdef HAVE_WCTYPE_H
 755 #    include <wctype.h>
 756 #  else
 757 #    ifdef HAVE_WCHAR_H
 758 #      include <wchar.h>
 759 #    endif
 760 #  endif
 761 #else
 762 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 763 #endif
 764 iswalnum((wchar_t) 0);
 765 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 766 LIBS="$oLIBS"
 767
 768 if test $gdk_working_wctype = no; then
 769    AC_DEFINE(HAVE_BROKEN_WCTYPE,1,[Is the wctype implementation broken])
 770    GDK_WLIBS=
 771 fi
 772 AC_MSG_RESULT($gdk_working_wctype)
 773 AC_SUBST(GDK_WLIBS)
 774
 775 AC_SUBST(GTK_DEBUG_FLAGS)
 776 AC_SUBST(GTK_XIM_FLAGS)
 777 AC_SUBST(GTK_LOCALE_FLAGS)
 778
 779 ##################################################
 780 # Checks for gdk-pixbuf
 781 ##################################################
 782
 783 AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
 784
 785 AC_ARG_ENABLE(modules, [  --disable-modules       Disables dynamic module loading],[
 786         if test x$withval = xyes; then
 787             with_modules=yes
 788         else
 789             with_modules=no
 790         fi
 791 ])
 792
 793 dynworks=false
 794 deps=
 795 if test x$with_modules = xno; then
 796     AC_MSG_RESULT(no)
 797 else
 798     AC_MSG_RESULT(yes)
 799     AC_MSG_CHECKING(whether dynamic modules work)
 800     oLIBS="$LIBS"
 801     oCFLAGS="$CFLAGS"
 802     CFLAGS="$GLIB_CFLAGS"
 803     LIBS="$GLIB_LIBS"
 804     AC_TRY_RUN([
 805     #include <glib.h>
 806     #include <gmodule.h>
 807     main ()
 808     {
 809         if (g_module_supported ())
 810             exit (0);
 811         else
 812             exit (1);
 813     }
 814     ], dynworks=true)
 815     LIBS="$oLIBS"
 816     CFLAGS="$oCFLAGS"
 817 fi
 818
 819 dnl Now we check to see if our libtool supports shared lib deps
 820 dnl (in a rather ugly way even)
 821 if $dynworks; then
 822    pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} libtool --config"
 823    pixbuf_deplibs_check=`$pixbuf_libtool_config | \
 824       grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 825       sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 826    if test "x$pixbuf_deplibs_check" = "xnone" || \
 827       test "x$pixbuf_deplibs_check" = "xunknown" || \
 828       test "x$pixbuf_deplibs_check" = "x"; then
 829       dynworks=false
 830    fi
 831 fi
 832
 833 if $dynworks; then
 834    AC_DEFINE(USE_GMODULE)
 835    AC_MSG_RESULT(yes)
 836 else
 837    AC_MSG_RESULT(no)
 838 fi
 839
 840 dnl Test for libtiff
 841   if test -z "$LIBTIFF"; then
 842     AC_CHECK_LIB(tiff, TIFFReadScanline,
 843       AC_CHECK_HEADER(tiffio.h,
 844         TIFF='tiff'; LIBTIFF='-ltiff',
 845         AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 846       AC_CHECK_LIB(tiff, TIFFWriteScanline,
 847         AC_CHECK_HEADER(tiffio.h,
 848           TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
 849           AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 850         AC_CHECK_LIB(tiff34, TIFFFlushData,
 851           AC_CHECK_HEADER(tiffio.h,
 852             TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
 853             AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 854         AC_MSG_WARN(*** TIFF plug-in will not be built (TIFF library not found) ***), -ljpeg -lz -lm), -ljpeg -lz -lm), -lm)
 855   fi
 856
 857 dnl Test for libjpeg
 858   if test -z "$LIBJPEG"; then
 859     AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 860       jpeg_ok=yes,
 861       jpeg_ok=no
 862       AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
 863     if test "$jpeg_ok" = yes; then
 864       AC_MSG_CHECKING([for jpeglib.h])
 865       AC_TRY_CPP(
 866 [#include <stdio.h>
 867 #undef PACKAGE
 868 #undef VERSION
 869 #include <jpeglib.h>],
 870         jpeg_ok=yes,
 871         jpeg_ok=no)
 872       AC_MSG_RESULT($jpeg_ok)
 873       if test "$jpeg_ok" = yes; then
 874         LIBJPEG='-ljpeg'
 875         AC_CHECK_LIB(jpeg, jpeg_simple_progression,
 876           AC_DEFINE(HAVE_PROGRESSIVE_JPEG),
 877           AC_MSG_WARN(JPEG library does not support progressive saving.))
 878       else
 879           AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
 880       fi
 881     fi
 882   fi
 883
 884 dnl Test for libpng
 885   if test -z "$LIBPNG"; then
 886     AC_CHECK_LIB(png, png_read_info,
 887       AC_CHECK_HEADER(png.h,
 888         png_ok=yes,
 889         png_ok=no),
 890       AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
 891     if test "$png_ok" = yes; then
 892       AC_MSG_CHECKING([for png_structp in png.h])
 893       AC_TRY_COMPILE([#include <png.h>],
 894         [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 895         png_ok=yes,
 896         png_ok=no)
 897       AC_MSG_RESULT($png_ok)
 898       if test "$png_ok" = yes; then
 899         PNG='png'; LIBPNG='-lpng -lz'
 900       else
 901         AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
 902       fi
 903     else
 904      AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
 905     fi
 906   fi
 907
 908 deps="$LIBTIFF $LIBJPEG $LIBPNG"
 909
 910 AC_SUBST(LIBTIFF)
 911 AC_SUBST(LIBJPEG)
 912 AC_SUBST(LIBPNG)
 913
 914 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 915
 916 #
 917 # Allow building some or all gdk-pixbuf loaders included
 918 #
 919 AC_MSG_CHECKING(pixbuf loaders to build)
 920
 921 AC_ARG_WITH(included_loaders, [  --with-included-loaders=LOADER1,LOADER2,... Build the specified loaders into gdk-pixbuf (only used if module loading disabled)])
 922
 923 all_loaders="png,bmp,wbmp,gif,ico,jpeg,pnm,ras,tiff,xpm"
 924 included_loaders=""
 925 # If no loaders specified, include all
 926 if test "x$with_included_loaders" = xyes ; then
 927   included_loaders="$all_loaders"
 928 else
 929   included_loaders="$with_included_loaders"
 930 fi
 931
 932 AC_MSG_RESULT($included_loaders)
 933
 934 INCLUDED_LOADER_OBJ=
 935 INCLUDED_LOADER_DEFINE=
 936
 937 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 938 for loader in $included_loaders; do
 939  if ! echo "$all_loaders" | grep "\(^\|\,\)$loader\(\$\|\,\)" > /dev/null; then
 940    AC_MSG_ERROR([the specified loader $loader does not exist])
 941  fi
 942
 943  INCLUDED_LOADER_OBJ="$INCLUDED_LOADER_OBJ libpixbufloader-static-$loader.la"
 944  INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_$loader"
 945 done
 946 IFS="$gtk_save_ifs"
 947 AC_SUBST(INCLUDED_LOADER_OBJ)
 948 AC_SUBST(INCLUDED_LOADER_DEFINE)
 949
 950 AC_HEADER_STDC
 951 AC_HEADER_DIRENT
 952 AC_HEADER_SYS_WAIT
 953
 954 AC_TYPE_SIGNAL
 955
 956 AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
 957 AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
 958 AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
 959
 960 GDK_PIXBUF_LIBDIR='-L${libdir}'
 961 GDK_PIXBUF_INCLUDEDIR="-I${includedir} $GTK_CFLAGS"
 962 GDK_PIXBUF_LIBS="$GLIB_LIBS -lgdk_pixbuf $deps $GTK_LIBS"
 963 AC_SUBST(STATIC_LIB_DEPS)
 964 STATIC_LIB_DEPS="$deps"
 965
 966 AC_SUBST(GDK_PIXBUF_LIBDIR)
 967 AC_SUBST(GDK_PIXBUF_INCLUDEDIR)
 968 AC_SUBST(GDK_PIXBUF_LIBS)
 969
 970 GDK_PIXBUF_XLIB_LIBDIR=$GDK_PIXBUF_LIBDIR
 971 GDK_PIXBUF_XLIB_INCLUDEDIR=$GDK_PIXBUF_INCLUDEDIR
 972 GDK_PIXBUF_XLIB_LIBS="$GLIB_LIBS -lgdk_pixbuf_xlib $deps $X11_LIBS"
 973
 974 AC_SUBST(GDK_PIXBUF_XLIB_LIBDIR)
 975 AC_SUBST(GDK_PIXBUF_XLIB_INCLUDEDIR)
 976 AC_SUBST(GDK_PIXBUF_XLIB_LIBS)
 977
 978 # Checks to see if we should compile in MMX support (there will be
 979 # a runtime test when the code is actually run to see if it should
 980 # be used - this just checks if we can compile it.)
 981 #
 982 # This code is partially taken from Mesa
 983 #
 984 AC_MSG_CHECKING(for x86 platform)
 985 case $host_cpu in
 986   i386|i486|i586|i686|i786|k6|k7)
 987         use_x86_asm=yes
 988         ;;
 989    *)
 990         use_x86_asm=no
 991 esac
 992 AC_MSG_RESULT($use_x86_asm)
 993
 994 use_mmx_asm=no
 995 if test $use_x86_asm = yes; then
 996     save_ac_ext=$ac_ext
 997     ac_ext=S
 998
 999     AC_MSG_CHECKING(compiler support for MMX)
1000     cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
1001     if AC_TRY_EVAL(ac_compile); then
1002         use_mmx_asm=yes
1003     fi
1004
1005     rm -rf conftest*
1006
1007     ac_ext=$save_ac_ext
1008     if test $use_mmx_asm = yes; then
1009       AC_DEFINE(USE_MMX)
1010       AC_MSG_RESULT(yes)
1011     else
1012       AC_MSG_RESULT(no)
1013     fi
1014 fi
1015
1016 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
1017
1018
1019 ##################################################
1020 # Checks for gtk-doc and docbook-tools
1021 ##################################################
1022
1023 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
1024
1025 if test "x$with_html_dir" = "x" ; then
1026   HTML_DIR='${datadir}/gtk-doc/html'
1027 else
1028   HTML_DIR=$with_html_dir
1029 fi
1030
1031 AC_SUBST(HTML_DIR)
1032
1033 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1034
1035 gtk_doc_min_version=0.6
1036 if $GTKDOC ; then
1037     gtk_doc_version=`gtkdoc-mkdb --version`
1038     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
1039     if perl <<EOF ; then
1040       exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
1041             ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
1042 EOF
1043       AC_MSG_RESULT(yes)
1044    else
1045       AC_MSG_RESULT(no)
1046       GTKDOC=false
1047    fi
1048 fi
1049
1050 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1051 AC_SUBST(HAVE_GTK_DOC)
1052
1053 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1054 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1055
1056 dnl Let people disable the gtk-doc stuff.
1057 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1058
1059 if test x$enable_gtk_doc = xauto ; then
1060   if test x$GTKDOC = xtrue ; then
1061     enable_gtk_doc=yes
1062   else
1063     enable_gtk_doc=no
1064   fi
1065 fi
1066
1067 dnl NOTE: We need to use a separate automake conditional for this
1068 dnl       to make this work with the tarballs.
1069 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1070
1071 GDK_PIXBUF_DIR=`(cd $srcdir; pwd)`
1072 AC_SUBST(GDK_PIXBUF_DIR)
1073
1074
1075 ##################################################
1076 # Output commands
1077 ##################################################
1078
1079 AC_OUTPUT_COMMANDS([
1080
1081 ## Generate `gdk/gdkconfig.h' in two cases
1082 ## 1. `config.status' is run either explicitly, or via configure.
1083 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1084 ##     config.h
1085 ## 2. CONFIG_OTHER is set explicitly
1086 ##
1087 ## Case 1 is difficult.  We know that `automake' sets one of
1088 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1089 ## only when AM_CONFIG_HEADER is set, however.
1090
1091 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1092   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1093   CONFIG_OTHER=${CONFIG_OTHER:-gdk/gdkconfig.h}
1094 fi
1095 case "$CONFIG_OTHER" in
1096 *gdk/gdkconfig.h*)
1097         echo creating gdk/gdkconfig.h
1098         outfile=gdkconfig.h-tmp
1099         cat > $outfile <<\_______EOF
1100 /* gdkconfig.h
1101  *
1102  * This is a generated file.  Please modify `configure.in'
1103  */
1104
1105 #ifndef GDKCONFIG_H
1106 #define GDKCONFIG_H
1107
1108 #ifdef __cplusplus
1109 extern "C" {
1110 #endif /* __cplusplus */
1111
1112 _______EOF
1113
1114         cat >>$outfile <<_______EOF
1115 $gdk_windowing
1116 $gdk_wc
1117 _______EOF
1118
1119         cat >>$outfile <<_______EOF
1120
1121 #ifdef __cplusplus
1122 }
1123 #endif /* __cplusplus */
1124
1125 #endif /* GDKCONFIG_H */
1126 _______EOF
1127
1128
1129         if cmp -s $outfile gdk/gdkconfig.h; then
1130           echo gdk/gdkconfig.h is unchanged
1131           rm -f $outfile
1132         else
1133           mv $outfile gdk/gdkconfig.h
1134         fi ;;
1135 esac
1136 ],[
1137 if test "x$gdktarget" = "xx11" ; then
1138   gdk_windowing='
1139 #define GDK_WINDOWING_X11'
1140 elif test "x$gdktarget" = "xnanox" ; then
1141   gdk_windowing='
1142 #define GDK_WINDOWING_NANOX'
1143 elif test "x$gdktarget" = "xlinux-fb" ; then
1144   gdk_windowing='
1145 #define GDK_WINDOWING_FB
1146 #define GDK_NATIVE_WINDOW_POINTER'
1147 fi
1148
1149 if test x$gdk_wchar_h = xyes; then
1150   gdk_wc='
1151 #define GDK_HAVE_WCHAR_H 1'
1152 fi
1153 if test x$gdk_wctype_h = xyes; then
1154   gdk_wc="\$gdk_wc
1155 #define GDK_HAVE_WCTYPE_H 1"
1156 fi
1157 if test x$gdk_working_wctype = xno; then
1158   gdk_wc="\$gdk_wc
1159 #define GDK_HAVE_BROKEN_WCTYPE 1"
1160 fi
1161
1162
1163 ])
1164
1165 AC_PATH_PROG(SGML2HTML, sgml2html, no)
1166 AM_CONDITIONAL(HAVE_SGML2HTML, ! test x$SGML2HTML = xno)
1167
1168 AC_OUTPUT([
1169 config.h.win32
1170 gtk+.spec
1171 docs/gtk-config.1
1172 Makefile
1173 gdk-pixbuf-2.0.pc
1174 gdk-2.0.pc
1175 gtk+-2.0.pc
1176 po/Makefile.in
1177 build/Makefile
1178 build/win32/Makefile
1179 demos/Makefile
1180 demos/gtk-demo/Makefile
1181 tests/Makefile
1182 docs/Makefile
1183 docs/reference/Makefile
1184 docs/reference/gdk-pixbuf/Makefile
1185 docs/reference/gdk/Makefile
1186 docs/reference/gtk/Makefile
1187 docs/faq/Makefile
1188 docs/tutorial/Makefile
1189 gdk-pixbuf/Makefile
1190 gdk-pixbuf/makefile.mingw
1191 gdk-pixbuf/gdk-pixbuf-features.h
1192 gdk-pixbuf/pixops/Makefile
1193 gdk-pixbuf/pixops/makefile.mingw
1194 gdk/Makefile
1195 gdk/makefile.mingw
1196 gdk/x11/Makefile
1197 gdk/win32/Makefile
1198 gdk/win32/makefile.mingw
1199 gdk/win32/rc/Makefile
1200 gdk/win32/rc/gdk.rc
1201 gdk/nanox/Makefile
1202 gdk/linux-fb/Makefile
1203 gtk/Makefile
1204 gtk/makefile.mingw
1205 gtk/makefile.msc
1206 gtk/gtkcompat.h
1207 gtk/gtk-win32.rc
1208 gtk/stock-icons/Makefile
1209 modules/Makefile
1210 modules/input/Makefile
1211 contrib/Makefile
1212 contrib/gdk-pixbuf-xlib/Makefile
1213 contrib/gdk-pixbuf-xlib/gdk-pixbuf-xlib-2.0.pc
1214 ])