Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(gdk/gdktypes.h)
   3
   4 #
   5 # For each of the libraries we build, we define the following
   6 # substituted variables:
   7 #
   8 # foo_PACKAGES:     pkg-config packages this library requires
   9 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  10 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  11 # foo_DEP_LIBS:     All libraries this module requires
  12 # foo_DEP_CFLAGS:   All cflags this module requires
  13
  14
  15 ## We could have pkg-config uniquify the ldflags and cflags by calling
  16 ## it once with both the GLib and Pango package names, but we don't,
  17 ## someone should fix that.
  18
  19
  20 # Save this value here, since automake will set cflags later
  21 cflags_set=${CFLAGS+set}
  22
  23 dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  24 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  25 GLIB_AC_DIVERT_BEFORE_HELP([
  26 #
  27 # Making releases:
  28 #   GTK_MICRO_VERSION += 1;
  29 #   GTK_INTERFACE_AGE += 1;
  30 #   GTK_BINARY_AGE += 1;
  31 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  32 # if backwards compatibility has been broken,
  33 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  34 #
  35 GTK_MAJOR_VERSION=1
  36 GTK_MINOR_VERSION=3
  37 GTK_MICRO_VERSION=9
  38 GTK_INTERFACE_AGE=0
  39 GTK_BINARY_AGE=0
  40 GTK_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$GTK_MICRO_VERSION
  41 dnl
  42 ])dnl
  43
  44 AC_SUBST(GTK_MAJOR_VERSION)
  45 AC_SUBST(GTK_MINOR_VERSION)
  46 AC_SUBST(GTK_MICRO_VERSION)
  47 AC_SUBST(GTK_INTERFACE_AGE)
  48 AC_SUBST(GTK_BINARY_AGE)
  49 AC_SUBST(GTK_VERSION)
  50
  51 # libtool versioning
  52 LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  53 LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  54 LT_REVISION=$GTK_INTERFACE_AGE
  55 LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  56 AC_SUBST(LT_RELEASE)
  57 AC_SUBST(LT_CURRENT)
  58 AC_SUBST(LT_REVISION)
  59 AC_SUBST(LT_AGE)
  60
  61 # Define a string for the earliest version that this release has
  62 # binary compatibility with. This is used for module locations.
  63 #
  64 GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  65 AC_SUBST(GTK_BINARY_VERSION)
  66
  67 #
  68 # gdk-pixbuf gets versioned separately, and for now, using standard
  69 # libtool versioning, not GTK+-style versioning
  70 #
  71 GDK_PIXBUF_MAJOR=$GTK_MAJOR_VERSION
  72 GDK_PIXBUF_MINOR=$GTK_MINOR_VERSION
  73 GDK_PIXBUF_MICRO=$GTK_MICRO_VERSION
  74 GDK_PIXBUF_VERSION="${GDK_PIXBUF_MAJOR}.${GDK_PIXBUF_MINOR}.${GDK_PIXBUF_MICRO}"
  75 AC_SUBST(GDK_PIXBUF_MAJOR)
  76 AC_SUBST(GDK_PIXBUF_MINOR)
  77 AC_SUBST(GDK_PIXBUF_MICRO)
  78 AC_SUBST(GDK_PIXBUF_VERSION)
  79
  80 ## Versions of dependencies
  81 GLIB_REQUIRED_VERSION=1.3.9
  82 PANGO_REQUIRED_VERSION=0.20
  83 ATK_REQUIRED_VERSION=0.5
  84
  85 # For automake.
  86 VERSION=$GTK_VERSION
  87 PACKAGE=gtk+
  88
  89 GETTEXT_PACKAGE=gtk20
  90 AC_SUBST(GETTEXT_PACKAGE)
  91 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
  92
  93 # Save this value here, since automake will set cflags later
  94 cflags_set=${CFLAGS+set}
  95
  96 dnl Initialize automake stuff
  97 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  98
  99 # Specify a configuration file
 100 AM_CONFIG_HEADER(config.h)
 101
 102 dnl Initialize libtool
 103 AM_PROG_LIBTOOL
 104
 105 dnl Initialize maintainer mode
 106 AM_MAINTAINER_MODE
 107
 108 AC_CANONICAL_HOST
 109
 110 dnl figure debugging default, prior to $ac_help setup
 111 dnl
 112 GLIB_AC_DIVERT_BEFORE_HELP([
 113 if test `expr $GTK_MINOR_VERSION \% 2` = 1 ; then
 114         debug_default=yes
 115 else
 116         debug_default=minimum
 117 fi
 118 ])dnl
 119
 120 dnl declare --enable-* args and collect ac_help strings
 121 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 122 AC_ARG_ENABLE(shm, [  --enable-shm            support shared memory if available [default=yes]],
 123                    echo $enable_shm, enable_shm="yes")
 124 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 125                     , enable_ansi=no)
 126 AC_ARG_ENABLE(xim, [  --enable-xim            support XIM [default=yes]],
 127                         , enable_xim="yes")
 128 AC_ARG_ENABLE(xim_inst, [  --disable-xim-inst      does not use xim instantiate callback],
 129                         , enable_xim_inst="maybe")
 130 AC_ARG_ENABLE(xkb, [  --enable-xkb            support XKB [default=maybe]],
 131                         , enable_xkb="maybe")
 132 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 133
 134 AC_ARG_WITH(xinput, [  --with-xinput=[no/gxi/xfree] support XInput ])
 135
 136 gdktarget=x11
 137 gdktargetlib=libgdk-x11-1.3.la
 138 gtktargetlib=libgtk-x11-1.3.la
 139 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[x11/linux-fb] select GDK target [default=x11] ],
 140         gdktarget=$with_gdktarget)
 141
 142 AC_SUBST(gdktarget)
 143 case $gdktarget in
 144   x11|linux-fb) ;;
 145   *) AC_MSG_ERROR([Invalid target for GDK: use x11 or linux-fb.]);;
 146 esac
 147
 148 AC_ARG_ENABLE(shadowfb, [  --disable-shadowfb      disable shadowfb support for linux-fb],,enable_shadowfb=yes)
 149
 150 AC_ARG_ENABLE(fbmanager, [  --enable-fbmanager      enable framebuffer manager support (GtkFB)],enable_fbmanager=yes,enable_fbmanager=no)
 151
 152 if test "x$enable_debug" = "xyes"; then
 153   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 154   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 155 else
 156   if test "x$enable_debug" = "xno"; then
 157     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 158   else
 159     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 160   fi
 161 fi
 162
 163 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 164
 165
 166 # Build time sanity check...
 167 AM_SANITY_CHECK
 168
 169 # Checks for programs.
 170 AC_PROG_CC
 171 AC_ISC_POSIX
 172 AM_PROG_CC_STDC
 173 AC_PROG_INSTALL
 174 AC_PROG_MAKE_SET
 175
 176 changequote(,)dnl
 177 if test "x$GCC" = "xyes"; then
 178   case " $CFLAGS " in
 179   *[\ \ ]-Wall[\ \      ]*) ;;
 180   *) CFLAGS="$CFLAGS -Wall" ;;
 181   esac
 182
 183   if test "x$enable_ansi" = "xyes"; then
 184     case " $CFLAGS " in
 185     *[\ \       ]-ansi[\ \      ]*) ;;
 186     *) CFLAGS="$CFLAGS -ansi" ;;
 187     esac
 188
 189     case " $CFLAGS " in
 190     *[\ \       ]-pedantic[\ \  ]*) ;;
 191     *) CFLAGS="$CFLAGS -pedantic" ;;
 192     esac
 193   fi
 194 fi
 195 changequote([,])dnl
 196
 197 # Honor aclocal flags
 198 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 199
 200 ## Initial sanity check, done here so that users get told they
 201 ## have the wrong dependencies as early in the process as possible.
 202 ## Later on we actually use the cflags/libs from separate pkg-config
 203 ## calls. Oh, also the later pkg-config calls don't include
 204 ## the version requirements since those make the module lists
 205 ## annoying to construct
 206 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION atk >= $ATK_REQUIRED_VERSION pango >= $PANGO_REQUIRED_VERSION)
 207
 208 # libtool option to control which symbols are exported
 209 # right now, symbols starting with _ are not exported
 210 LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 211 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 212
 213 # define a MAINT-like variable REBUILD which is set if Perl
 214 # and awk are found, so autogenerated sources can be rebuilt
 215
 216 AC_PROG_AWK
 217 AC_CHECK_PROGS(PERL, perl5 perl)
 218
 219 # We would like indent, but don't require it.
 220 AC_CHECK_PROG(INDENT, indent, indent)
 221
 222 REBUILD=\#
 223 if test "x$enable_rebuilds" = "xyes" && \
 224      test -n "$PERL" && \
 225      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 226      test -n "$AWK" ; then
 227   REBUILD=
 228 fi
 229 AC_SUBST(REBUILD)
 230
 231 AC_CHECK_FUNCS(lstat mkstemp sigsetjmp bind_textdomain_codeset)
 232
 233 AC_MSG_CHECKING(whether make is GNU Make)
 234 STRIP_BEGIN=
 235 STRIP_END=
 236 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 237         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 238         STRIP_END=')'
 239         AC_MSG_RESULT(yes)
 240 else
 241         AC_MSG_RESULT(no)
 242 fi
 243 STRIP_DUMMY=
 244 AC_SUBST(STRIP_DUMMY)
 245 AC_SUBST(STRIP_BEGIN)
 246 AC_SUBST(STRIP_END)
 247
 248 # i18n stuff
 249 ALL_LINGUAS="az ca cs da de el en_GB en@IPA es et eu fa fi fr ga gl he hr hu ia it ja ko lt nl nn no pl pt pt_BR ro ru sk sl sp sr sv tr uk vi wa zh_TW zh_CN"
 250 AM_GLIB_GNU_GETTEXT
 251 LIBS="$LIBS $INTLLIBS"
 252
 253 # AM_GLIB_GNU_GETTEXT above substs $DATADIRNAME
 254 # this is the directory where the *.{mo,gmo} files are installed
 255 gtklocaledir='${prefix}/${DATADIRNAME}/locale'
 256 AC_SUBST(gtklocaledir)
 257
 258 dnl The DU4 header files don't provide library prototypes unless
 259 dnl -std1 is given to the native cc.
 260 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 261
 262 gtk_save_LIBS=$LIBS
 263 LIBS="$LIBS -lm"
 264 AC_TRY_RUN([#include <math.h>
 265              int main (void) { return (log(1) != log(1.)); }],
 266      AC_MSG_RESULT(none needed),
 267      gtk_save_CFLAGS="$CFLAGS"
 268      CFLAGS="$CFLAGS -std1"
 269      AC_TRY_RUN([#include <math.h>
 270                  int main (void) { return (log(1) != log(1.)); }],
 271          AC_MSG_RESULT(-std1),
 272          AC_MSG_RESULT()
 273          CFLAGS="$gtk_save_CFLAGS"
 274          AC_MSG_WARN(
 275                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 276          true
 277      ),
 278      AC_MSG_RESULT(none needed)
 279 )
 280 LIBS=$gtk_save_LIBS
 281
 282 MATH_LIB=-lm
 283 AC_MSG_CHECKING(for the BeOS)
 284 case $host in
 285   *-*-beos*)
 286     AC_MSG_RESULT(yes)
 287     MATH_LIB=
 288   ;;
 289   *)
 290     AC_MSG_RESULT(no)
 291   ;;
 292 esac
 293
 294 dnl NeXTStep cc seems to need this
 295 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 296 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 297   AC_MSG_RESULT(none needed),
 298   gtk_save_CFLAGS="$CFLAGS"
 299   CFLAGS="$CFLAGS -posix"
 300   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 301     AC_MSG_RESULT(-posix),
 302     AC_MSG_RESULT()
 303     CFLAGS="$gtk_save_CFLAGS"
 304     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 305
 306 #
 307 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 308 #
 309
 310 GLIB_PACKAGES="gobject-2.0 gmodule-2.0"
 311
 312 AM_PATH_GLIB_2_0($GLIB_REQUIRED_VERSION, :,
 313   AC_MSG_ERROR([
 314 *** GLIB $GLIB_REQUIRED_VERSION or better is required. The latest version of
 315 *** GLIB is always available from ftp://ftp.gtk.org/.]),
 316   gobject gmodule gthread)
 317
 318 AC_CHECK_HEADERS(dirent.h, AC_DEFINE(HAVE_DIRENT_H))
 319 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 320 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 321 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 322
 323 saved_cflags="$CFLAGS"
 324 saved_ldflags="$LDFLAGS"
 325
 326
 327 # Checks for header files.
 328 AC_HEADER_STDC
 329
 330 # Checks for typedefs, structures, and compiler characteristics.
 331 AC_C_CONST
 332
 333 # Checks for library functions.
 334 AC_TYPE_SIGNAL
 335 AC_FUNC_MMAP
 336
 337 AC_CHECK_FUNCS(getresuid)
 338 AC_TYPE_UID_T
 339
 340 # Check if <sys/select.h> needs to be included for fd_set
 341 AC_MSG_CHECKING([for fd_set])
 342 AC_TRY_COMPILE([#include <sys/types.h>],
 343         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 344 if test $gtk_ok = yes; then
 345     AC_MSG_RESULT([yes, found in sys/types.h])
 346 else
 347     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 348     if test $gtk_ok = yes; then
 349         AC_DEFINE(HAVE_SYS_SELECT_H)
 350         AC_MSG_RESULT([yes, found in sys/select.h])
 351     else
 352         AC_DEFINE(NO_FD_SET)
 353         AC_MSG_RESULT(no)
 354     fi
 355 fi
 356
 357 # `widechar' tests for gdki18n.h
 358 AC_MSG_CHECKING(for wchar.h)
 359 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 360 if test $gdk_wchar_h = yes; then
 361    AC_DEFINE(HAVE_WCHAR_H,1,[Have wchar.h include file])
 362 fi
 363 AC_MSG_RESULT($gdk_wchar_h)
 364
 365 # Check for wctype.h (for iswalnum)
 366 AC_MSG_CHECKING(for wctype.h)
 367 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 368 if test $gdk_wctype_h = yes; then
 369    AC_DEFINE(HAVE_WCTYPE_H,1,[Have wctype.h include file])
 370 fi
 371 AC_MSG_RESULT($gdk_wctype_h)
 372
 373 # in Solaris 2.5, `iswalnum' is in -lw
 374 GDK_WLIBS=
 375 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 376
 377 oLIBS="$LIBS"
 378 LIBS="$LIBS $GDK_WLIBS"
 379 # The following is necessary for Linux libc-5.4.38
 380 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 381 AC_TRY_LINK([#include <stdlib.h>],[
 382 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 383 #  ifdef HAVE_WCTYPE_H
 384 #    include <wctype.h>
 385 #  else
 386 #    ifdef HAVE_WCHAR_H
 387 #      include <wchar.h>
 388 #    endif
 389 #  endif
 390 #else
 391 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 392 #endif
 393 iswalnum((wchar_t) 0);
 394 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 395 LIBS="$oLIBS"
 396
 397 if test $gdk_working_wctype = no; then
 398    AC_DEFINE(HAVE_BROKEN_WCTYPE,1,[Is the wctype implementation broken])
 399    GDK_WLIBS=
 400 fi
 401 AC_MSG_RESULT($gdk_working_wctype)
 402 AC_SUBST(GDK_WLIBS)
 403
 404
 405
 406 ##################################################
 407 # Checks for gdk-pixbuf
 408 ##################################################
 409
 410 AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
 411
 412 AC_ARG_ENABLE(modules, [  --disable-modules       Disables dynamic module loading],[
 413         if test x$withval = xyes; then
 414             with_modules=yes
 415         else
 416             with_modules=no
 417         fi
 418 ])
 419
 420 dynworks=false
 421 deps=
 422 if test x$with_modules = xno; then
 423     AC_MSG_RESULT(no)
 424 else
 425     AC_MSG_RESULT(yes)
 426     AC_MSG_CHECKING(whether dynamic modules work)
 427     ## for loop is to strip newline
 428     tmp=`pkg-config --variable=gmodule_supported gmodule-2.0`
 429     for I in $tmp; do
 430         dynworks=$I
 431     done
 432 fi
 433
 434 dnl Now we check to see if our libtool supports shared lib deps
 435 dnl (in a rather ugly way even)
 436 if $dynworks; then
 437    pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} libtool --config"
 438    pixbuf_deplibs_check=`$pixbuf_libtool_config | \
 439       grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 440       sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 441    if test "x$pixbuf_deplibs_check" = "xnone" || \
 442       test "x$pixbuf_deplibs_check" = "xunknown" || \
 443       test "x$pixbuf_deplibs_check" = "x"; then
 444       dynworks=false
 445    fi
 446 fi
 447
 448 if $dynworks; then
 449    AC_DEFINE(USE_GMODULE)
 450    AC_MSG_RESULT(yes)
 451 else
 452    AC_MSG_RESULT(no)
 453 fi
 454
 455 dnl Test for libtiff
 456   if test -z "$LIBTIFF"; then
 457     AC_CHECK_LIB(tiff, TIFFReadScanline,
 458       AC_CHECK_HEADER(tiffio.h,
 459         TIFF='tiff'; LIBTIFF='-ltiff',
 460         AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 461       AC_CHECK_LIB(tiff, TIFFWriteScanline,
 462         AC_CHECK_HEADER(tiffio.h,
 463           TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
 464           AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 465         AC_CHECK_LIB(tiff34, TIFFFlushData,
 466           AC_CHECK_HEADER(tiffio.h,
 467             TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
 468             AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***)),
 469         AC_MSG_WARN(*** TIFF plug-in will not be built (TIFF library not found) ***), -ljpeg -lz -lm), -ljpeg -lz -lm), -lm)
 470   fi
 471
 472 dnl Test for libjpeg
 473   if test -z "$LIBJPEG"; then
 474     AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 475       jpeg_ok=yes,
 476       jpeg_ok=no
 477       AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
 478     if test "$jpeg_ok" = yes; then
 479       AC_MSG_CHECKING([for jpeglib.h])
 480       AC_TRY_CPP(
 481 [#include <stdio.h>
 482 #undef PACKAGE
 483 #undef VERSION
 484 #include <jpeglib.h>],
 485         jpeg_ok=yes,
 486         jpeg_ok=no)
 487       AC_MSG_RESULT($jpeg_ok)
 488       if test "$jpeg_ok" = yes; then
 489         LIBJPEG='-ljpeg'
 490         AC_CHECK_LIB(jpeg, jpeg_simple_progression,
 491           AC_DEFINE(HAVE_PROGRESSIVE_JPEG),
 492           AC_MSG_WARN(JPEG library does not support progressive saving.))
 493       else
 494           AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
 495       fi
 496     fi
 497   fi
 498
 499 dnl Test for libpng
 500   if test -z "$LIBPNG"; then
 501     AC_CHECK_LIB(png, png_read_info,
 502       AC_CHECK_HEADER(png.h,
 503         png_ok=yes,
 504         png_ok=no),
 505       AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
 506     if test "$png_ok" = yes; then
 507       AC_MSG_CHECKING([for png_structp in png.h])
 508       AC_TRY_COMPILE([#include <png.h>],
 509         [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 510         png_ok=yes,
 511         png_ok=no)
 512       AC_MSG_RESULT($png_ok)
 513       if test "$png_ok" = yes; then
 514         PNG='png'; LIBPNG='-lpng -lz'
 515       else
 516         AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
 517       fi
 518     else
 519      AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
 520     fi
 521   fi
 522
 523 AC_SUBST(LIBTIFF)
 524 AC_SUBST(LIBJPEG)
 525 AC_SUBST(LIBPNG)
 526
 527 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 528
 529 #
 530 # Allow building some or all gdk-pixbuf loaders included
 531 #
 532 AC_MSG_CHECKING(pixbuf loaders to build)
 533
 534 AC_ARG_WITH(included_loaders, [  --with-included-loaders=LOADER1,LOADER2,... Build the specified loaders into gdk-pixbuf (only used if module loading disabled)])
 535
 536 if $dynworks; then
 537         :
 538 else
 539    ## if the option was specified, leave it; otherwise disable included loaders
 540    if test x$with_included_loaders = xno; then
 541            with_included_loaders=yes
 542    fi
 543 fi
 544
 545 all_loaders="png,bmp,wbmp,gif,ico,jpeg,pnm,ras,tiff,xpm,tga"
 546 included_loaders=""
 547 # If no loaders specified, include all
 548 if test "x$with_included_loaders" = xyes ; then
 549   included_loaders="$all_loaders"
 550 else
 551   included_loaders="$with_included_loaders"
 552 fi
 553
 554 AC_MSG_RESULT($included_loaders)
 555
 556 INCLUDED_LOADER_OBJ=
 557 INCLUDED_LOADER_DEFINE=
 558
 559 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 560 for loader in $included_loaders; do
 561  if echo "$all_loaders" | grep "\(^\|\,\)$loader\(\$\|\,\)" > /dev/null; then
 562    :
 563  else
 564    AC_MSG_ERROR([the specified loader $loader does not exist])
 565  fi
 566
 567  INCLUDED_LOADER_OBJ="$INCLUDED_LOADER_OBJ libpixbufloader-static-$loader.la"
 568  INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_$loader"
 569 done
 570 IFS="$gtk_save_ifs"
 571 AC_SUBST(INCLUDED_LOADER_OBJ)
 572 AC_SUBST(INCLUDED_LOADER_DEFINE)
 573
 574 AC_HEADER_DIRENT
 575 AC_HEADER_SYS_WAIT
 576
 577 AC_TYPE_SIGNAL
 578
 579 AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
 580 AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
 581 AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
 582
 583 if $dynworks ; then
 584   STATIC_LIB_DEPS=
 585   if echo "$included_loaders" | grep "\(^\|\,\)tiff\(\$\|\,\)" > /dev/null; then
 586     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBTIFF"
 587   fi
 588   if echo "$included_loaders" | grep "\(^\|\,\)jpeg\(\$\|\,\)" > /dev/null; then
 589     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBJPEG"
 590   fi
 591   if echo "$included_loaders" | grep "\(^\|\,\)png\(\$\|\,\)" > /dev/null; then
 592     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBPNG"
 593   fi
 594 else
 595   STATIC_LIB_DEPS="$LIBTIFF $LIBJPEG $LIBPNG"
 596 fi
 597
 598 # Checks to see if we should compile in MMX support (there will be
 599 # a runtime test when the code is actually run to see if it should
 600 # be used - this just checks if we can compile it.)
 601 #
 602 # This code is partially taken from Mesa
 603 #
 604 AC_MSG_CHECKING(for x86 platform)
 605 case $host_cpu in
 606   i386|i486|i586|i686|i786|k6|k7)
 607         use_x86_asm=yes
 608         ;;
 609    *)
 610         use_x86_asm=no
 611 esac
 612 AC_MSG_RESULT($use_x86_asm)
 613
 614 use_mmx_asm=no
 615 if test $use_x86_asm = yes; then
 616     save_ac_ext=$ac_ext
 617     ac_ext=S
 618
 619     AC_MSG_CHECKING(compiler support for MMX)
 620     cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
 621     if AC_TRY_EVAL(ac_compile); then
 622         use_mmx_asm=yes
 623     fi
 624
 625     rm -rf conftest*
 626
 627     ac_ext=$save_ac_ext
 628     if test $use_mmx_asm = yes; then
 629       AC_DEFINE(USE_MMX)
 630       AC_MSG_RESULT(yes)
 631     else
 632       AC_MSG_RESULT(no)
 633     fi
 634 fi
 635
 636 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
 637
 638
 639 GDK_PIXBUF_PACKAGES="gmodule-2.0 gobject-2.0"
 640 GDK_PIXBUF_EXTRA_LIBS="$STATIC_LIB_DEPS $MATH_LIB"
 641 GDK_PIXBUF_EXTRA_CFLAGS=
 642 GDK_PIXBUF_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
 643 GDK_PIXBUF_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS"
 644
 645 AC_SUBST(GDK_PIXBUF_PACKAGES)
 646 AC_SUBST(GDK_PIXBUF_EXTRA_LIBS)
 647 AC_SUBST(GDK_PIXBUF_EXTRA_CFLAGS)
 648 AC_SUBST(GDK_PIXBUF_DEP_LIBS)
 649 AC_SUBST(GDK_PIXBUF_DEP_CFLAGS)
 650
 651
 652 ########################################
 653 # Windowing system checks
 654 ########################################
 655
 656 GDK_EXTRA_LIBS=$GDK_WLIBS
 657 GDK_EXTRA_CFLAGS=
 658
 659 if test "x$gdktarget" = "xx11"; then
 660   # We start off with the libraries from Pango
 661
 662   ## be sure we also have Pango built with xft support
 663   if $PKG_CONFIG --exists pangoxft ; then
 664     PANGO_PACKAGES="pangox pangoxft"
 665     have_xft=true
 666     AC_DEFINE(HAVE_XFT)
 667   else
 668     PANGO_PACKAGES="pangox"
 669     have_xft=false
 670   fi
 671
 672   AM_CONDITIONAL(HAVE_XFT, $have_xft)
 673
 674   x_libs="`$PKG_CONFIG --libs $PANGO_PACKAGES`"
 675   x_cflags="`$PKG_CONFIG --cflags $PANGO_PACKAGES`"
 676   x_extra_libs=
 677
 678   ## Strip the .la files
 679
 680   x_libs_for_checks=""
 681   for I in $x_libs ; do
 682     case $I in
 683       *.la) ;;
 684       *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 685     esac
 686   done
 687
 688   # Sanity check for the X11 library
 689   AC_CHECK_LIB(X11, XOpenDisplay, :,
 690             AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
 691             $x_libs_for_checks)
 692
 693   if test "x$enable_shm" = "xyes"; then
 694     # Check for the Xext library (needed for XShm extention)
 695     AC_CHECK_LIB(Xext, XShmAttach,
 696         if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 697           x_extra_libs="-lXext"
 698         fi,
 699         # On AIX, it is in XextSam instead, but we still need -lXext
 700         AC_CHECK_LIB(XextSam, XShmAttach,
 701             if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 702                x_extra_libs="-lXextSam -lXext"
 703             else
 704                x_extra_libs="-lXextSam"
 705             fi, , $x_libs_for_checks),
 706         $x_libs_for_checks)
 707   fi
 708
 709   GDK_PIXBUF_XLIB_EXTRA_CFLAGS="$x_cflags"
 710   # Don't ever pull in the pangoxft libraries for gdk-pixbuf-x11
 711   GDK_PIXBUF_XLIB_EXTRA_LIBS="$x_extra_libs `$PKG_CONFIG --libs pangox`"
 712
 713   # Check for shaped window extension
 714
 715   AC_CHECK_LIB(Xext, XShapeCombineMask,
 716       if test -z "`echo $x_extra_libs $x_libs | grep "\-lXext" 2> /dev/null`"; then
 717            x_extra_libs="-lXext $x_extra_libs"
 718       fi
 719       AC_DEFINE(HAVE_SHAPE_EXT),
 720       ,
 721       $x_libs_for_checks)
 722
 723   # Check for XConvertCase (X11R6 specific)
 724
 725   AC_CHECK_LIB(X11, XConvertCase,
 726       AC_DEFINE(HAVE_XCONVERTCASE),
 727       ,
 728       $x_libs_for_checks)
 729
 730   # Check for XIM support.
 731
 732   AC_CHECK_LIB(X11, XUnregisterIMInstantiateCallback,
 733             : ,
 734             enable_xim_inst="no",
 735             $x_libs_for_checks)
 736
 737   # On Solaris, calling XRegisterIMInstantiateCallback seems to
 738   # cause an immediate segfault, so we disable it, unless
 739   # the user specifically forces it to be on.
 740
 741   if test x$enable_xim_inst = xmaybe ; then
 742     case host in
 743           *-*-solaris*)
 744             enable_xim_inst="no"
 745             ;;
 746           *)
 747             enable_xim_inst="yes"
 748             ;;
 749     esac
 750   fi
 751
 752   if test "x$enable_xim" = "xyes"; then
 753     GTK_XIM_FLAGS="-DUSE_XIM"
 754     if test "x$enable_xim_inst" = "xyes"; then
 755       AC_DEFINE(USE_X11R6_XIM)
 756     fi
 757   fi
 758
 759   # Check for XKB support.
 760
 761   if test "x$enable_xkb" = "xyes"; then
 762         AC_MSG_WARN(XKB support explicitly enabled)
 763         AC_DEFINE(HAVE_XKB)
 764   elif test "x$enable_xkb" = "xmaybe"; then
 765         AC_CHECK_LIB(X11, XkbQueryExtension,
 766                      AC_DEFINE(HAVE_XKB),
 767                      ,
 768                      $x_libs_for_checks)
 769   else
 770         AC_MSG_WARN(XKB support explicitly disabled)
 771   fi
 772
 773   x_cflags="$X_CFLAGS"
 774   x_ldflags="$X_LDFLAGS"
 775
 776   # set up things for XInput
 777
 778   if test "x$with_xinput" = "xgxi" || test "x$with_xinput" = "xyes"; then
 779     AC_DEFINE(XINPUT_GXI)
 780     xinput_progs=gxid
 781     x_extra_libs="-lXi $x_extra_libs"
 782   elif test "x$with_xinput" = "xxfree"; then
 783     AC_DEFINE(XINPUT_XFREE)
 784     x_extra_libs="-lXi $x_extra_libs"
 785   else
 786     AC_DEFINE(XINPUT_NONE)
 787   fi
 788
 789   AM_CONDITIONAL(XINPUT_GXI, test x$with_xinput = xgxi)
 790   AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree)
 791
 792   if test "x$enable_shm" = "xyes"; then
 793     # Check for shared memory
 794     AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
 795     AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
 796
 797     # Check for the X shared memory extension header file
 798     have_xshm=no
 799     AC_MSG_CHECKING(X11/extensions/XShm.h)
 800     if test "x$no_xext_lib" = "xyes"; then
 801       :
 802     else
 803       gtk_save_CFLAGS="$CFLAGS"
 804       CFLAGS="$CFLAGS $x_cflags"
 805       AC_TRY_COMPILE([
 806 #include <stdlib.h>
 807 #include <sys/types.h>
 808 #include <sys/ipc.h>
 809 #include <sys/shm.h>
 810 #include <X11/Xlib.h>
 811 #include <X11/Xutil.h>
 812 #include <X11/extensions/XShm.h>
 813 ], [XShmSegmentInfo *x_shm_info;], have_xshm=yes)
 814       CFLAGS="$gtk_save_CFLAGS"
 815     fi
 816     AC_MSG_RESULT($have_xshm)
 817     if test $have_xshm = yes ; then
 818       AC_DEFINE(HAVE_XSHM_H)
 819     fi
 820   fi
 821
 822   GDK_EXTRA_CFLAGS=
 823   GDK_EXTRA_LIBS="$x_extra_libs"
 824
 825   # these are already defined above
 826   #gdktargetlib = "libgdk-x11-1.3.la"
 827   #gtktargetlib = "libgtk-x11-1.3.la"
 828
 829   AM_CONDITIONAL(USE_X11, true)
 830 else
 831   AM_CONDITIONAL(USE_X11, false)
 832 fi
 833
 834 AC_SUBST(xinput_progs)
 835
 836 GDK_PIXBUF_XLIB_PACKAGES=
 837 GDK_PIXBUF_XLIB_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_XLIB_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
 838 GDK_PIXBUF_XLIB_DEP_CFLAGS="`$PKG_CONFIG --cflags  $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_PIXBUF_XLIB_EXTRA_CFLAGS"
 839
 840 AC_SUBST(GDK_PIXBUF_XLIB_PACKAGES)
 841 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_LIBS)
 842 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_CFLAGS)
 843 AC_SUBST(GDK_PIXBUF_XLIB_DEP_LIBS)
 844 AC_SUBST(GDK_PIXBUF_XLIB_DEP_CFLAGS)
 845
 846 if test "x$gdktarget" = "xlinux-fb"; then
 847   gdktargetlib="libgdk-linux-fb-1.3.la"
 848   gtktargetlib="libgtk-linux-fb-1.3.la"
 849
 850   AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
 851   if test x$FREETYPE_CONFIG = xno ; then
 852     AC_MSG_ERROR([*** freetype-config not found])
 853   fi
 854
 855   FREETYPE_CFLAGS="`$FREETYPE_CONFIG --cflags`"
 856   FREETYPE_LIBS="`$FREETYPE_CONFIG --libs`"
 857   CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 858
 859   if test x$enable_shadowfb = xyes ; then
 860     AC_DEFINE(ENABLE_SHADOW_FB)
 861   fi
 862
 863   if test x$enable_fbmanager = xyes ; then
 864     AC_DEFINE(ENABLE_FB_MANAGER)
 865     AM_CONDITIONAL(ENABLE_FB_MANAGER, true)
 866   else
 867     AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
 868   fi
 869
 870   GDK_EXTRA_CFLAGS="$FREETYPE_CFLAGS"
 871   GDK_EXTRA_LIBS="$FREETYPE_LIBS $GDK_EXTRA_LIBS"
 872
 873   AM_CONDITIONAL(USE_LINUX_FB, true)
 874 else
 875   AM_CONDITIONAL(USE_LINUX_FB, false)
 876   AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
 877 fi
 878
 879 AC_SUBST(gdktargetlib)
 880 AC_SUBST(gtktargetlib)
 881
 882 #
 883 # Pick correct Pango packages to use
 884 #
 885
 886 if test "x$gdktarget" = "xx11"; then
 887         if $have_xft = true ; then
 888             PANGO_PACKAGES="pangox pangoxft"
 889         else
 890             PANGO_PACKAGES=pangox
 891         fi
 892 elif test "x$gdktarget" = "xlinux-fb"; then
 893         PANGO_PACKAGES=pangoft2
 894 else
 895         PANGO_PACKAGES=pango
 896 fi
 897
 898 # Check for Pango flags
 899
 900 AC_MSG_CHECKING(Pango flags)
 901 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
 902         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
 903         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
 904
 905         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
 906 else
 907         AC_MSG_ERROR([
 908 *** Pango not found. Pango is required to build GTK+.
 909 *** See http://www.pango.org for Pango information.
 910 *** For the framebuffer target, you will need to build
 911 *** Pango with freetype support.
 912 ])
 913 fi
 914
 915 CFLAGS="$CFLAGS $PANGO_CFLAGS"
 916
 917 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
 918         :
 919 else
 920         AC_CHECK_LIB(pango, pango_context_new, :, AC_MSG_ERROR([
 921 *** Can't link to Pango. Pango is required to build
 922 *** GTK+. For more information see http://www.pango.org]), $PANGO_LIBS)
 923 fi
 924
 925 CFLAGS="$saved_cflags"
 926 LDFLAGS="$saved_ldflags"
 927
 928 GDK_PACKAGES=$PANGO_PACKAGES
 929 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
 930 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS"
 931
 932 AC_SUBST(GDK_PACKAGES)
 933 AC_SUBST(GDK_EXTRA_LIBS)
 934 AC_SUBST(GDK_EXTRA_CFLAGS)
 935 AC_SUBST(GDK_DEP_LIBS)
 936 AC_SUBST(GDK_DEP_CFLAGS)
 937
 938
 939 ########################################
 940 # Check for Accessibility Toolkit flags
 941 ########################################
 942
 943 ATK_PACKAGES=atk
 944 AC_MSG_CHECKING(ATK flags)
 945 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
 946         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
 947         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
 948
 949         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
 950 else
 951         AC_MSG_ERROR([
 952 *** Accessibility Toolkit not found. Accessibility Toolkit is required
 953 *** to build GTK+.
 954 ])
 955 fi
 956
 957 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
 958         :
 959 else
 960         AC_CHECK_LIB(atk, atk_object_get_type, : , AC_MSG_ERROR([
 961                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
 962                 *** to build GTK+]), $ATK_LIBS $GLIB_LIBS)
 963 fi
 964
 965 GTK_PACKAGES=atk
 966 GTK_EXTRA_LIBS=
 967 GTK_EXTRA_CFLAGS=
 968 GTK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GTK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GTK_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
 969 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  $GTK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
 970
 971 AC_SUBST(GTK_PACKAGES)
 972 AC_SUBST(GTK_EXTRA_LIBS)
 973 AC_SUBST(GTK_EXTRA_CFLAGS)
 974 AC_SUBST(GTK_DEP_LIBS)
 975 AC_SUBST(GTK_DEP_CFLAGS)
 976
 977
 978 AC_SUBST(GTK_DEBUG_FLAGS)
 979 AC_SUBST(GTK_XIM_FLAGS)
 980
 981 ##################################################
 982 # Checks for gtk-doc and docbook-tools
 983 ##################################################
 984
 985 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH    path to installed docs ])
 986
 987 if test "x$with_html_dir" = "x" ; then
 988   HTML_DIR='${datadir}/gtk-doc/html'
 989 else
 990   HTML_DIR=$with_html_dir
 991 fi
 992
 993 AC_SUBST(HTML_DIR)
 994
 995 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
 996
 997 gtk_doc_min_version=0.6
 998 if $GTKDOC ; then
 999     gtk_doc_version=`gtkdoc-mkdb --version`
1000     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
1001     if perl <<EOF ; then
1002       exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
1003             ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
1004 EOF
1005       AC_MSG_RESULT(yes)
1006    else
1007       AC_MSG_RESULT(no)
1008       GTKDOC=false
1009    fi
1010 fi
1011
1012 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1013 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1014
1015 dnl Let people disable the gtk-doc stuff.
1016 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc        Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1017
1018 if test x$enable_gtk_doc = xauto ; then
1019   if test x$GTKDOC = xtrue ; then
1020     enable_gtk_doc=yes
1021   else
1022     enable_gtk_doc=no
1023   fi
1024 fi
1025
1026 dnl NOTE: We need to use a separate automake conditional for this
1027 dnl       to make this work with the tarballs.
1028 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1029
1030
1031 ##################################################
1032 # Output commands
1033 ##################################################
1034
1035 AC_OUTPUT_COMMANDS([
1036
1037 ## Generate `gdk/gdkconfig.h' in two cases
1038 ## 1. `config.status' is run either explicitly, or via configure.
1039 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1040 ##     config.h
1041 ## 2. CONFIG_OTHER is set explicitly
1042 ##
1043 ## Case 1 is difficult.  We know that `automake' sets one of
1044 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1045 ## only when AM_CONFIG_HEADER is set, however.
1046
1047 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1048   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1049   CONFIG_OTHER=${CONFIG_OTHER:-gdk/gdkconfig.h}
1050 fi
1051 case "$CONFIG_OTHER" in
1052 *gdk/gdkconfig.h*)
1053         echo creating gdk/gdkconfig.h
1054         outfile=gdkconfig.h-tmp
1055         cat > $outfile <<\_______EOF
1056 /* gdkconfig.h
1057  *
1058  * This is a generated file.  Please modify `configure.in'
1059  */
1060
1061 #ifndef GDKCONFIG_H
1062 #define GDKCONFIG_H
1063
1064 #ifdef __cplusplus
1065 extern "C" {
1066 #endif /* __cplusplus */
1067
1068 _______EOF
1069
1070         cat >>$outfile <<_______EOF
1071 $gdk_windowing
1072 $gdk_wc
1073 _______EOF
1074
1075         cat >>$outfile <<_______EOF
1076
1077 #ifdef __cplusplus
1078 }
1079 #endif /* __cplusplus */
1080
1081 #endif /* GDKCONFIG_H */
1082 _______EOF
1083
1084
1085         if cmp -s $outfile gdk/gdkconfig.h; then
1086           echo gdk/gdkconfig.h is unchanged
1087           rm -f $outfile
1088         else
1089           mv $outfile gdk/gdkconfig.h
1090         fi ;;
1091 esac
1092 ],[
1093 if test "x$gdktarget" = "xx11" ; then
1094   gdk_windowing='
1095 #define GDK_WINDOWING_X11'
1096 elif test "x$gdktarget" = "xlinux-fb" ; then
1097   gdk_windowing='
1098 #define GDK_WINDOWING_FB
1099 #define GDK_NATIVE_WINDOW_POINTER'
1100 fi
1101
1102 if test x$gdk_wchar_h = xyes; then
1103   gdk_wc='
1104 #define GDK_HAVE_WCHAR_H 1'
1105 fi
1106 if test x$gdk_wctype_h = xyes; then
1107   gdk_wc="\$gdk_wc
1108 #define GDK_HAVE_WCTYPE_H 1"
1109 fi
1110 if test x$gdk_working_wctype = xno; then
1111   gdk_wc="\$gdk_wc
1112 #define GDK_HAVE_BROKEN_WCTYPE 1"
1113 fi
1114
1115
1116 ])
1117
1118 AC_PATH_PROG(SGML2HTML, sgml2html, no)
1119 AM_CONDITIONAL(HAVE_SGML2HTML, ! test x$SGML2HTML = xno)
1120
1121 AC_OUTPUT([
1122 config.h.win32
1123 gtk+.spec
1124 Makefile
1125 gdk-pixbuf-2.0.pc
1126 gdk-2.0.pc
1127 gtk+-2.0.pc
1128 gdk-pixbuf-2.0-uninstalled.pc
1129 gdk-2.0-uninstalled.pc
1130 gtk+-2.0-uninstalled.pc
1131 m4macros/Makefile
1132 po/Makefile.in
1133 build/Makefile
1134 build/win32/Makefile
1135 build/win32/dirent/Makefile
1136 demos/Makefile
1137 demos/gtk-demo/Makefile
1138 tests/Makefile
1139 docs/Makefile
1140 docs/reference/Makefile
1141 docs/reference/gdk-pixbuf/Makefile
1142 docs/reference/gdk/Makefile
1143 docs/reference/gtk/Makefile
1144 docs/faq/Makefile
1145 docs/tutorial/Makefile
1146 gdk-pixbuf/Makefile
1147 gdk-pixbuf/makefile.mingw
1148 gdk-pixbuf/gdk-pixbuf-features.h
1149 gdk-pixbuf/pixops/Makefile
1150 gdk-pixbuf/pixops/makefile.mingw
1151 gdk/Makefile
1152 gdk/makefile.mingw
1153 gdk/x11/Makefile
1154 gdk/win32/Makefile
1155 gdk/win32/makefile.mingw
1156 gdk/win32/rc/Makefile
1157 gdk/win32/rc/gdk.rc
1158 gdk/linux-fb/Makefile
1159 gtk/Makefile
1160 gtk/makefile.mingw
1161 gtk/makefile.msc
1162 gtk/gtkversion.h
1163 gtk/gtk-win32.rc
1164 gtk/stock-icons/Makefile
1165 modules/Makefile
1166 modules/input/Makefile
1167 contrib/Makefile
1168 contrib/gdk-pixbuf-xlib/Makefile
1169 contrib/gdk-pixbuf-xlib/gdk-pixbuf-xlib-2.0.pc
1170 ])