Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 # Making releases:
   6 #   GTK_MICRO_VERSION += 1;
   7 #   GTK_INTERFACE_AGE += 1;
   8 #   GTK_BINARY_AGE += 1;
   9 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  10 # if backwards compatibility has been broken,
  11 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  12
  13 m4_define([gtk_major_version], [2])
  14 m4_define([gtk_minor_version], [11])
  15 m4_define([gtk_micro_version], [0])
  16 m4_define([gtk_version],
  17           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  18 m4_define([gtk_interface_age], [0])
  19 m4_define([gtk_binary_age],
  20           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  21 # This is the X.Y used in -lgtk-FOO-X.Y
  22 m4_define([gtk_api_version], [2.0])
  23
  24 # Define a string for the earliest version that this release has
  25 # backwards binary compatibility with for all interfaces a module
  26 # might. Unless we add module-only API with lower stability
  27 # guarantees, this should be unchanged until we break binary compat
  28 # for GTK+.
  29 #
  30 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  31 m4_define([gtk_binary_version], [2.10.0])
  32
  33 # required versions of other packages
  34 m4_define([glib_required_version], [2.12.0])
  35 m4_define([pango_required_version], [1.12.0])
  36 m4_define([atk_required_version], [1.9.0])
  37 m4_define([cairo_required_version], [1.2.0])
  38
  39
  40 AC_INIT([gtk+], [gtk_version],
  41         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  42         [gtk+])
  43
  44 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  45
  46 # Save this value here, since automake will set cflags later
  47 cflags_set=${CFLAGS+set}
  48
  49 AM_INIT_AUTOMAKE(no-define)
  50 AM_CONFIG_HEADER(config.h)
  51
  52 #
  53 # For each of the libraries we build, we define the following
  54
  55 # substituted variables:
  56 #
  57 # foo_PACKAGES:     pkg-config packages this library requires
  58 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  59 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  60 # foo_DEP_LIBS:     All libraries this module requires
  61 # foo_DEP_CFLAGS:   All cflags this module requires
  62
  63
  64 GTK_MAJOR_VERSION=gtk_major_version
  65 GTK_MINOR_VERSION=gtk_minor_version
  66 GTK_MICRO_VERSION=gtk_micro_version
  67 GTK_INTERFACE_AGE=gtk_interface_age
  68 GTK_BINARY_AGE=gtk_binary_age
  69 GTK_VERSION=gtk_version
  70 GTK_API_VERSION=gtk_api_version
  71 GTK_BINARY_VERSION=gtk_binary_version
  72 AC_SUBST(GTK_MAJOR_VERSION)
  73 AC_SUBST(GTK_MINOR_VERSION)
  74 AC_SUBST(GTK_MICRO_VERSION)
  75 AC_SUBST(GTK_INTERFACE_AGE)
  76 AC_SUBST(GTK_BINARY_AGE)
  77 AC_SUBST(GTK_API_VERSION)
  78 AC_SUBST(GTK_VERSION)
  79 AC_SUBST(GTK_BINARY_VERSION)
  80
  81 # libtool versioning
  82 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  83 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  84 #LT_REVISION=$GTK_INTERFACE_AGE
  85 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  86 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  87
  88 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
  89 m4_define([lt_revision], [gtk_interface_age])
  90 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
  91 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
  92 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
  93 AC_SUBST(LT_VERSION_INFO)
  94 AC_SUBST(LT_CURRENT_MINUS_AGE)
  95
  96
  97 #
  98 # gdk-pixbuf gets versioned separately, and for now, using standard
  99 # libtool versioning, not GTK+-style versioning
 100 #
 101 GDK_PIXBUF_MAJOR=gtk_major_version
 102 GDK_PIXBUF_MINOR=gtk_minor_version
 103 GDK_PIXBUF_MICRO=gtk_micro_version
 104 GDK_PIXBUF_VERSION="${GDK_PIXBUF_MAJOR}.${GDK_PIXBUF_MINOR}.${GDK_PIXBUF_MICRO}"
 105 AC_SUBST(GDK_PIXBUF_MAJOR)
 106 AC_SUBST(GDK_PIXBUF_MINOR)
 107 AC_SUBST(GDK_PIXBUF_MICRO)
 108 AC_SUBST(GDK_PIXBUF_VERSION)
 109
 110 GETTEXT_PACKAGE=gtk20
 111 AC_SUBST(GETTEXT_PACKAGE)
 112 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
 113
 114 AC_CANONICAL_HOST
 115
 116 MATH_LIB=-lm
 117 AC_MSG_CHECKING([for native Win32])
 118 case "$host" in
 119   *-*-mingw*)
 120     os_win32=yes
 121     MATH_LIB=
 122     ;;
 123   *)
 124     os_win32=no
 125     ;;
 126 esac
 127 AC_MSG_RESULT([$os_win32])
 128
 129 case $host in
 130   *-*-linux*)
 131     os_linux=yes
 132     ;;
 133 esac
 134 dnl Initialize libtool
 135 AC_PROG_CC
 136 AM_DISABLE_STATIC
 137
 138 if test "$os_win32" = "yes"; then
 139   if test x$enable_static = xyes -o x$enable_static = x; then
 140     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 141     enable_static=no
 142   fi
 143   if test x$enable_shared = xno; then
 144     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 145   fi
 146   enable_shared=yes
 147 fi
 148
 149 AC_LIBTOOL_WIN32_DLL
 150 AM_PROG_LIBTOOL
 151
 152 # Make sure we use 64-bit versions of various file stuff.
 153 AC_SYS_LARGEFILE
 154
 155 AM_PROG_AS
 156 AC_PATH_PROG(NM, nm, nm)
 157
 158 dnl Initialize maintainer mode
 159 AM_MAINTAINER_MODE
 160
 161 AC_MSG_CHECKING([for some Win32 platform])
 162 case "$host" in
 163   *-*-mingw*|*-*-cygwin*)
 164     platform_win32=yes
 165     ;;
 166   *)
 167     platform_win32=no
 168     ;;
 169 esac
 170 AC_MSG_RESULT([$platform_win32])
 171 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 172
 173 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 174 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 175 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 176
 177 if test "$os_win32" = "yes"; then
 178   AC_CHECK_TOOL(WINDRES, windres, no)
 179   if test "$WINDRES" = no; then
 180     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 181   fi
 182   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 183 fi
 184 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 185
 186 m4_define([debug_default],
 187           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 188
 189 dnl declare --enable-* args and collect ac_help strings
 190 AC_ARG_ENABLE(debug,
 191               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 192                              [turn on debugging @<:@default=debug_default@:>@]),,
 193               enable_debug=debug_default)
 194 AC_ARG_ENABLE(shm,
 195               [AC_HELP_STRING([--enable-shm],
 196                               [support shared memory if available [default=yes]])],,
 197               [enable_shm="yes"])
 198 AC_ARG_ENABLE(xkb,
 199               [AC_HELP_STRING([--enable-xkb],
 200                               [support XKB [default=maybe]])],,
 201               [enable_xkb="maybe"])
 202 AC_ARG_ENABLE(rebuilds,
 203               [AC_HELP_STRING([--disable-rebuilds],
 204                               [disable all source autogeneration rules])],,
 205               [enable_rebuilds=yes])
 206 AC_ARG_ENABLE(visibility,
 207               [AC_HELP_STRING([--disable-visibility],
 208                               [don't use ELF visibility attributes])],,
 209               [enable_visibility=yes])
 210
 211 AC_ARG_WITH(xinput,
 212             [AC_HELP_STRING([--with-xinput=@<:@no/yes@:>@], [support XInput])])
 213
 214 AC_ARG_WITH(wintab,
 215             [AC_HELP_STRING([--with-wintab=DIRECTORY],
 216                             [use Wintab API with win32 backend])])
 217 if test "$platform_win32" = yes; then
 218   gdktarget=win32
 219 else
 220   gdktarget=x11
 221 fi
 222
 223 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/linux-fb/win32/quartz/directfb]] select non-default GDK target],
 224         gdktarget=$with_gdktarget)
 225
 226 AC_SUBST(gdktarget)
 227 case $gdktarget in
 228   x11|linux-fb|win32|quartz|directfb) ;;
 229   *) AC_MSG_ERROR([Invalid target for GDK: use x11, linux-fb, quartz, directfb or win32.]);;
 230 esac
 231
 232 gdktargetlib=libgdk-$gdktarget-$GTK_API_VERSION.la
 233 gtktargetlib=libgtk-$gdktarget-$GTK_API_VERSION.la
 234
 235 AC_SUBST(gdktargetlib)
 236 AC_SUBST(gtktargetlib)
 237
 238 AC_ARG_ENABLE(shadowfb,
 239               [AC_HELP_STRING([--disable-shadowfb],
 240                               [disable shadowfb support for linux-fb])],,
 241               [enable_shadowfb=yes])
 242
 243 AC_ARG_ENABLE(fbmanager,
 244               [AC_HELP_STRING([--enable-fbmanager],
 245                               [enable framebuffer manager support (GtkFB)])],,
 246               enable_fbmanager=no)
 247
 248 if test "x$enable_debug" = "xyes"; then
 249   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 250   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 251 else
 252   if test "x$enable_debug" = "xno"; then
 253     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 254   else
 255     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 256   fi
 257 fi
 258
 259 if test "x$enable_visibility" = "xno"; then
 260   GTK_DEBUG_FLAGS="$GTK_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 261 fi
 262
 263
 264 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 265
 266
 267 # Build time sanity check...
 268 AM_SANITY_CHECK
 269
 270 # Checks for programs.
 271 AC_ISC_POSIX
 272 AM_PROG_CC_STDC
 273 AC_PROG_INSTALL
 274 AC_PROG_MAKE_SET
 275
 276 changequote(,)dnl
 277 if test "x$GCC" = "xyes"; then
 278   case " $CFLAGS " in
 279   *[\ \ ]-Wall[\ \      ]*) ;;
 280   *) CFLAGS="$CFLAGS -Wall" ;;
 281   esac
 282
 283   if test "x$enable_ansi" = "xyes"; then
 284     case " $CFLAGS " in
 285     *[\ \       ]-ansi[\ \      ]*) ;;
 286     *) CFLAGS="$CFLAGS -ansi" ;;
 287     esac
 288
 289     case " $CFLAGS " in
 290     *[\ \       ]-pedantic[\ \  ]*) ;;
 291     *) CFLAGS="$CFLAGS -pedantic" ;;
 292     esac
 293   fi
 294 fi
 295 changequote([,])dnl
 296
 297 # Ensure MSVC-compatible struct packing convention is used when
 298 # compiling for Win32 with gcc.
 299 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 300 # gcc2 uses "-fnative-struct".
 301 if test x"$os_win32" = xyes; then
 302   if test x"$GCC" = xyes; then
 303     msnative_struct=''
 304     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 305     if test -z "$ac_cv_prog_CC"; then
 306       our_gcc="$CC"
 307     else
 308       our_gcc="$ac_cv_prog_CC"
 309     fi
 310     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 311       2.)
 312         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 313           msnative_struct='-fnative-struct'
 314         fi
 315         ;;
 316       *)
 317         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 318           msnative_struct='-mms-bitfields'
 319         fi
 320         ;;
 321     esac
 322     if test x"$msnative_struct" = x ; then
 323       AC_MSG_RESULT([no way])
 324       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 325     else
 326       CFLAGS="$CFLAGS $msnative_struct"
 327       AC_MSG_RESULT([${msnative_struct}])
 328     fi
 329   fi
 330 fi
 331
 332 # Honor aclocal flags
 333 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 334
 335 ## Initial sanity check, done here so that users get told they
 336 ## have the wrong dependencies as early in the process as possible.
 337 ## Later on we actually use the cflags/libs from separate pkg-config
 338 ## calls. Oh, also the later pkg-config calls don't include
 339 ## the version requirements since those make the module lists
 340 ## annoying to construct
 341 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 342   [glib-2.0 >= glib_required_version dnl
 343    atk >= atk_required_version dnl
 344    pango >= pango_required_version dnl
 345    cairo >= cairo_required_version])
 346
 347 if test "$os_win32" != yes; then
 348     # libtool option to control which symbols are exported
 349     # right now, symbols starting with _ are not exported
 350     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 351 else
 352     # We currently use .def files on Windows (for gdk-pixbuf, gdk and gtk)
 353     LIBTOOL_EXPORT_OPTIONS=
 354 fi
 355 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 356
 357 dnl ******************************************************
 358 dnl * See whether to include shared library dependencies *
 359 dnl ******************************************************
 360
 361 AC_ARG_ENABLE(explicit-deps,
 362               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 363                               [use explicit dependencies in .pc files [default=auto]])],,
 364               [enable_explicit_deps=auto])
 365
 366 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 367 case $enable_explicit_deps in
 368   auto)
 369     deplibs_check_method=`(./libtool --config; echo eval echo \\$deplibs_check_method) | sh`
 370     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 371       enable_explicit_deps=yes
 372     else
 373       enable_explicit_deps=no
 374     fi
 375   ;;
 376   yes|no)
 377   ;;
 378   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 379   ;;
 380 esac
 381 AC_MSG_RESULT($enable_explicit_deps)
 382
 383 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 384
 385 # define a MAINT-like variable REBUILD which is set if Perl
 386 # and awk are found, so autogenerated sources can be rebuilt
 387
 388 AC_PATH_PROGS(PERL, perl5 perl)
 389
 390 # We would like indent, but don't require it.
 391 AC_CHECK_PROG(INDENT, indent, indent)
 392
 393 REBUILD=\#
 394 if test "x$enable_rebuilds" = "xyes" && \
 395      test -n "$PERL" && \
 396      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 397   REBUILD=
 398 fi
 399 AC_SUBST(REBUILD)
 400
 401 AC_CHECK_FUNCS(lstat mkstemp flockfile)
 402
 403 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 404 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 405 AC_TRY_LINK([#include <langinfo.h>], [
 406 char c;
 407 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 408 ], gtk_ok=yes, gtk_ok=no)
 409 AC_MSG_RESULT($gtk_ok)
 410 if test "$gtk_ok" = "yes"; then
 411   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 412             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 413 fi
 414
 415 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 416 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 417 AC_TRY_LINK([#include <langinfo.h>], [
 418 char c;
 419 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 420 ], gtk_ok=yes, gtk_ok=no)
 421 AC_MSG_RESULT($gtk_ok)
 422 if test "$gtk_ok" = "yes"; then
 423   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 424             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 425 fi
 426
 427 # _NL_PAPER_HEIGHT is an enum and not a define
 428 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 429 AC_TRY_LINK([#include <langinfo.h>], [
 430 char c;
 431 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 432 ], gtk_ok=yes, gtk_ok=no)
 433 AC_MSG_RESULT($gtk_ok)
 434 if test "$gtk_ok" = "yes"; then
 435   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 436             [Define if _NL_PAPER_HEIGHT is available])
 437 fi
 438
 439 # _NL_PAPER_WIDTH is an enum and not a define
 440 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 441 AC_TRY_LINK([#include <langinfo.h>], [
 442 char c;
 443 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 444 ], gtk_ok=yes, gtk_ok=no)
 445 AC_MSG_RESULT($gtk_ok)
 446 if test "$gtk_ok" = "yes"; then
 447   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 448             [Define if _NL_PAPER_WIDTH is available])
 449 fi
 450
 451 # sigsetjmp is a macro on some platforms, so AC_CHECK_FUNCS is not reliable
 452 AC_MSG_CHECKING(for sigsetjmp)
 453 AC_TRY_LINK([#include <setjmp.h>], [
 454 sigjmp_buf env;
 455 sigsetjmp(env, 0);
 456 ], gtk_ok=yes, gtk_ok=no)
 457 AC_MSG_RESULT($gtk_ok)
 458 if test "$gtk_ok" = "yes"; then
 459   AC_DEFINE(HAVE_SIGSETJMP)
 460 fi
 461
 462 # i18n stuff
 463 # TRANSLATORS:  Please note that gtk+ has both po/ and po-properties/
 464 # directories.  If you add a new language to ALL_LINGUAS, please make
 465 # sure that both po/ and po-properties/ have .po files that correspond
 466 # to your language.  If you only add one to po/, the build will break
 467 # in po-properties/.
 468 ALL_LINGUAS="af am ang ar az az_IR be bg bn bn_IN br bs ca cs cy da de dz el en_CA en_GB es et eu fa fi fr ga gl gu he hi hr hu hy ia id is it ja ka ko ku li lt lv mi mk ml mn mr ms nb ne nl nn nso or pa pl pt pt_BR ro ru rw sk sl sq sr sr@Latn sr@ije sv ta te th tk tr tt uk ur uz uz@Latn vi wa xh yi zh_CN zh_HK zh_TW"
 469 AM_GLIB_GNU_GETTEXT
 470 LIBS="$LIBS $INTLLIBS"
 471 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 472         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 473       esac])
 474
 475 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 476
 477 dnl The DU4 header files don't provide library prototypes unless
 478 dnl -std1 is given to the native cc.
 479 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 480
 481 gtk_save_LIBS=$LIBS
 482 LIBS="$LIBS -lm"
 483 AC_TRY_RUN([#include <math.h>
 484              int main (void) { return (log(1) != log(1.)); }],
 485      AC_MSG_RESULT(none needed),
 486      gtk_save_CFLAGS="$CFLAGS"
 487      CFLAGS="$CFLAGS -std1"
 488      AC_TRY_RUN([#include <math.h>
 489                  int main (void) { return (log(1) != log(1.)); }],
 490          AC_MSG_RESULT(-std1),
 491          AC_MSG_RESULT()
 492          CFLAGS="$gtk_save_CFLAGS"
 493          AC_MSG_WARN(
 494                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 495          true
 496      ),
 497      AC_MSG_RESULT(none needed)
 498 )
 499 LIBS=$gtk_save_LIBS
 500
 501 AC_MSG_CHECKING(for the BeOS)
 502 case $host in
 503   *-*-beos*)
 504     AC_MSG_RESULT(yes)
 505     MATH_LIB=
 506   ;;
 507   *)
 508     AC_MSG_RESULT(no)
 509   ;;
 510 esac
 511
 512 #
 513 # see bug 162979
 514 #
 515 AC_MSG_CHECKING(for HP-UX)
 516 case $host_os in
 517   hpux9* | hpux10* | hpux11*)
 518     AC_MSG_RESULT(yes)
 519     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 520   ;;
 521   *)
 522     AC_MSG_RESULT(no)
 523   ;;
 524 esac
 525
 526 dnl NeXTStep cc seems to need this
 527 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 528 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 529   AC_MSG_RESULT(none needed),
 530   gtk_save_CFLAGS="$CFLAGS"
 531   CFLAGS="$CFLAGS -posix"
 532   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 533     AC_MSG_RESULT(-posix),
 534     AC_MSG_RESULT()
 535     CFLAGS="$gtk_save_CFLAGS"
 536     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 537
 538 #
 539 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 540 #
 541
 542 GLIB_PACKAGES="gobject-2.0 gmodule-no-export-2.0"
 543
 544 AM_PATH_GLIB_2_0(glib_required_version, :,
 545   AC_MSG_ERROR([
 546 *** GLIB glib_required_version or better is required. The latest version of
 547 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 548   gobject gmodule-no-export gthread)
 549
 550 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 551 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 552 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 553 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 554   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 555 fi
 556
 557
 558 dnl
 559 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 560 dnl
 561 gtk_save_LIBS=$LIBS
 562 LIBS="$LIBS $GLIB_LIBS"
 563 AC_CHECK_FUNCS(bind_textdomain_codeset)
 564 LIBS=$gtk_save_LIBS
 565
 566 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 567 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 568 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 569
 570 if test "${with_wintab+set}" = set && test $with_wintab != no; then
 571   AC_MSG_CHECKING([for wintab.h])
 572   saved_CFLAGS="$CFLAGS"
 573   CFLAGS="$CFLAGS -I$with_wintab/include"
 574   AC_TRY_COMPILE([#include <windows.h>
 575 #include <wintab.h>],
 576    [],
 577    [AC_MSG_RESULT(yes)
 578     AC_MSG_CHECKING([for wntab32x.lib])
 579     if test -f $with_wintab/lib/i386/wntab32x.lib ; then
 580       AC_MSG_RESULT(yes)
 581       have_wintab=yes
 582       AC_DEFINE(HAVE_WINTAB)
 583       WINTAB_LIB="$with_wintab/lib/i386/wntab32x.lib"
 584       AC_SUBST(WINTAB_LIB)
 585     else
 586       AC_MSG_RESULT(no)
 587       CFLAGS="$saved_cflags"
 588       have_wintab=no
 589     fi
 590     ],
 591    [AC_MSG_RESULT(no)
 592     CFLAGS="$saved_cflags"
 593     have_wintab=no])
 594 fi
 595 AM_CONDITIONAL(HAVE_WINTAB, test x$have_wintab = xyes)
 596
 597 saved_cflags="$CFLAGS"
 598 saved_ldflags="$LDFLAGS"
 599
 600
 601 # Checks for header files.
 602 AC_HEADER_STDC
 603
 604 # Checks for typedefs, structures, and compiler characteristics.
 605 AC_C_CONST
 606
 607 # Checks for library functions.
 608 AC_TYPE_SIGNAL
 609 AC_FUNC_MMAP
 610
 611 AC_CHECK_FUNCS(mallinfo)
 612 AC_CHECK_FUNCS(getresuid)
 613 AC_TYPE_UID_T
 614
 615 # Check if <sys/select.h> needs to be included for fd_set
 616 AC_MSG_CHECKING([for fd_set])
 617 AC_TRY_COMPILE([#include <sys/types.h>],
 618         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 619 if test $gtk_ok = yes; then
 620     AC_MSG_RESULT([yes, found in sys/types.h])
 621 else
 622     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 623     if test $gtk_ok = yes; then
 624         AC_DEFINE(HAVE_SYS_SELECT_H)
 625         AC_MSG_RESULT([yes, found in sys/select.h])
 626     else
 627         AC_DEFINE(NO_FD_SET)
 628         AC_MSG_RESULT(no)
 629     fi
 630 fi
 631
 632 # `widechar' tests for gdki18n.h
 633 AC_MSG_CHECKING(for wchar.h)
 634 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 635 if test $gdk_wchar_h = yes; then
 636    AC_DEFINE(HAVE_WCHAR_H,1,[Have wchar.h include file])
 637 fi
 638 AC_MSG_RESULT($gdk_wchar_h)
 639
 640 # Check for wctype.h (for iswalnum)
 641 AC_MSG_CHECKING(for wctype.h)
 642 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 643 if test $gdk_wctype_h = yes; then
 644    AC_DEFINE(HAVE_WCTYPE_H,1,[Have wctype.h include file])
 645 fi
 646 AC_MSG_RESULT($gdk_wctype_h)
 647
 648 # in Solaris 2.5, `iswalnum' is in -lw
 649 GDK_WLIBS=
 650 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 651
 652 oLIBS="$LIBS"
 653 LIBS="$LIBS $GDK_WLIBS"
 654 # The following is necessary for Linux libc-5.4.38
 655 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 656 AC_TRY_LINK([#include <stdlib.h>],[
 657 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 658 #  ifdef HAVE_WCTYPE_H
 659 #    include <wctype.h>
 660 #  else
 661 #    ifdef HAVE_WCHAR_H
 662 #      include <wchar.h>
 663 #    endif
 664 #  endif
 665 #else
 666 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 667 #endif
 668 iswalnum((wchar_t) 0);
 669 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 670 LIBS="$oLIBS"
 671
 672 if test $gdk_working_wctype = no; then
 673    AC_DEFINE(HAVE_BROKEN_WCTYPE,1,[Is the wctype implementation broken])
 674    GDK_WLIBS=
 675 fi
 676 AC_MSG_RESULT($gdk_working_wctype)
 677 AC_SUBST(GDK_WLIBS)
 678
 679 # Check for uxtheme.h (for MS-Windows Engine)
 680 AC_MSG_CHECKING(for uxtheme.h)
 681 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 682 if test $gtk_uxtheme_h = yes; then
 683    AC_DEFINE(HAVE_UXTHEME_H,1,[Have uxtheme.h include file])
 684 fi
 685 AC_MSG_RESULT($gtk_uxtheme_h)
 686
 687
 688 ##################################################
 689 # Checks for gdk-pixbuf
 690 ##################################################
 691
 692 dnl ********************************************************
 693 dnl * See whether we need to load our modules as .la files *
 694 dnl ********************************************************
 695
 696 use_la_modules=false
 697 case $host in
 698   *-aix*) use_la_modules=true
 699 esac
 700
 701 if $use_la_modules ; then
 702    AC_DEFINE(USE_LA_MODULES, 1, [Whether to load modules via .la files rather than directly])
 703 fi
 704
 705
 706 AC_MSG_CHECKING(whether to build gmodulized gdk-pixbuf)
 707
 708 AC_ARG_ENABLE(modules,
 709               [AC_HELP_STRING([--disable-modules],
 710                               [disable dynamic module loading])])
 711
 712 dynworks=false
 713 deps=
 714 if test x$enable_modules = xno; then
 715     AC_MSG_RESULT(no)
 716 else
 717     AC_MSG_RESULT(yes)
 718     AC_MSG_CHECKING(whether dynamic modules work)
 719     ## for loop is to strip newline
 720     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 721     for I in $tmp; do
 722         dynworks=$I
 723     done
 724
 725     dnl Now we check to see if our libtool supports shared lib deps
 726     dnl (in a rather ugly way even)
 727     if $dynworks; then
 728         pixbuf_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 729         pixbuf_deplibs_check=`$pixbuf_libtool_config | \
 730             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 731             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 732         if test "x$pixbuf_deplibs_check" = "xnone" || \
 733            test "x$pixbuf_deplibs_check" = "xunknown" || \
 734            test "x$pixbuf_deplibs_check" = "x"; then
 735             dynworks=false
 736         fi
 737     fi
 738
 739     if $dynworks; then
 740         AC_DEFINE(USE_GMODULE)
 741         AC_MSG_RESULT(yes)
 742     else
 743         AC_MSG_RESULT(no)
 744     fi
 745 fi
 746
 747 dnl We allow people to disable image loaders explicitely, but if they don't we error
 748 dnl out so that people don't accidentally build without them.
 749
 750 AC_ARG_WITH(libpng,
 751             [AC_HELP_STRING([--without-libpng],
 752                             [disable PNG loader for gdk-pixbuf])])
 753 AC_ARG_WITH(libjpeg,
 754             [AC_HELP_STRING([--without-libjpeg],
 755                             [disable JPEG loader for gdk-pixbuf])])
 756 AC_ARG_WITH(libtiff,
 757             [AC_HELP_STRING([--without-libtiff],
 758                             [disable TIFF loader for gdk-pixbuf])])
 759
 760 dnl Test for libtiff
 761   if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
 762     AC_CHECK_LIB(tiff, TIFFReadScanline,
 763       [AC_CHECK_HEADER(tiffio.h,
 764         TIFF='tiff'; LIBTIFF='-ltiff',
 765         AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 766       [AC_CHECK_LIB(tiff, TIFFWriteScanline,
 767         [AC_CHECK_HEADER(tiffio.h,
 768           TIFF='tiff'; LIBTIFF='-ltiff -ljpeg -lz',
 769           AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 770         [AC_CHECK_LIB(tiff34, TIFFFlushData,
 771           [AC_CHECK_HEADER(tiffio.h,
 772             TIFF='tiff'; LIBTIFF='-ltiff34 -ljpeg -lz',
 773             AC_MSG_WARN(*** TIFF loader will not be built (TIFF header files not found) ***))],
 774         AC_MSG_WARN(*** TIFF loader will not be built (TIFF library not found) ***), -ljpeg -lz -lm)], -ljpeg -lz -lm)], -lm)
 775   fi
 776
 777   if test x$with_libtiff != xno && test -z "$LIBTIFF"; then
 778      AC_MSG_ERROR([
 779 *** Checks for TIFF loader failed. You can build without it by passing
 780 *** --without-libtiff to configure but some programs using GTK+ may
 781 *** not work properly])
 782   fi
 783
 784 dnl Test for libjpeg
 785   if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
 786     AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,
 787       jpeg_ok=yes,
 788       jpeg_ok=no
 789       AC_MSG_WARN(*** JPEG loader will not be built (JPEG library not found) ***))
 790     if test "$jpeg_ok" = yes; then
 791       AC_MSG_CHECKING([for jpeglib.h])
 792       AC_TRY_CPP(
 793 [#include <stdio.h>
 794 #undef PACKAGE
 795 #undef VERSION
 796 #undef HAVE_STDLIB_H
 797 #include <jpeglib.h>],
 798         jpeg_ok=yes,
 799         jpeg_ok=no)
 800       AC_MSG_RESULT($jpeg_ok)
 801       if test "$jpeg_ok" = yes; then
 802         LIBJPEG='-ljpeg'
 803         AC_CHECK_LIB(jpeg, jpeg_simple_progression,
 804           AC_DEFINE(HAVE_PROGRESSIVE_JPEG),
 805           AC_MSG_WARN(JPEG library does not support progressive saving.))
 806       else
 807           AC_MSG_WARN(*** JPEG loader will not be built (JPEG header file not found) ***)
 808       fi
 809     fi
 810   fi
 811
 812   if test x$with_libjpeg != xno && test -z "$LIBJPEG"; then
 813      AC_MSG_ERROR([
 814 *** Checks for JPEG loader failed. You can build without it by passing
 815 *** --without-libjpeg to configure but some programs using GTK+ may
 816 *** not work properly])
 817   fi
 818
 819 dnl Test for libpng
 820   if test x$with_libpng != xno && test -z "$LIBPNG"; then
 821     AC_MSG_CHECKING(for libpng12)
 822     if $PKG_CONFIG --exists libpng12 ; then
 823         AC_MSG_RESULT(yes)
 824         PNG='png'
 825         PNG_DEP_CFLAGS_PACKAGES=libpng12
 826         LIBPNG=`$PKG_CONFIG --libs libpng12`
 827     else
 828       AC_MSG_RESULT(no)
 829       AC_CHECK_LIB(png, png_read_info,
 830         [AC_CHECK_HEADER(png.h,
 831           png_ok=yes,
 832           png_ok=no)],
 833         AC_MSG_WARN(*** PNG loader will not be built (PNG library not found) ***), -lz -lm)
 834       if test "$png_ok" = yes; then
 835         AC_MSG_CHECKING([for png_structp in png.h])
 836         AC_TRY_COMPILE([#include <png.h>],
 837           [png_structp pp; png_infop info; png_colorp cmap; png_create_read_struct;],
 838           png_ok=yes,
 839           png_ok=no)
 840         AC_MSG_RESULT($png_ok)
 841         if test "$png_ok" = yes; then
 842           PNG='png'; LIBPNG='-lpng -lz'
 843         else
 844           AC_MSG_WARN(*** PNG loader will not be built (PNG library is too old) ***)
 845         fi
 846       else
 847        AC_MSG_WARN(*** PNG loader will not be built (PNG header file not found) ***)
 848       fi
 849     fi
 850   fi
 851
 852   if test x$with_libpng != xno && test -z "$LIBPNG"; then
 853      AC_MSG_ERROR([
 854 *** Checks for PNG loader failed. You can build without it by passing
 855 *** --without-libpng to configure but many programs using GTK+ will
 856 *** not work properly. The PNG loader is also needed if you are compiling
 857 *** from CVS.])
 858   fi
 859
 860 AC_SUBST(LIBTIFF)
 861 AC_SUBST(LIBJPEG)
 862 AC_SUBST(LIBPNG)
 863
 864 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 865
 866 #
 867 # Allow building some or all gdk-pixbuf loaders included
 868 #
 869 AC_MSG_CHECKING(pixbuf loaders to build)
 870
 871 dnl due to an autoconf bug, commas in the first arg to
 872 dnl AC_HELP_STRING cause problems.
 873 dnl AC_HELP_STRING([--with-included-loaders=LOADER1 LOADER2 ...],
 874 dnl                [build the specified loaders into gdk-pixbuf (only used if module loading disabled)])
 875 AC_ARG_WITH(included_loaders,
 876 [  --with-included-loaders=LOADER1,LOADER2,...
 877                           build the specified loaders into gdk-pixbuf (only
 878                           used if module loading disabled)])
 879
 880 if $dynworks; then
 881         :
 882 else
 883    ## if the option was specified, leave it; otherwise disable included loaders
 884    if test x$with_included_loaders = xno; then
 885            with_included_loaders=yes
 886    fi
 887 fi
 888
 889 all_loaders="png,bmp,wbmp,gif,ico,ani,jpeg,pnm,ras,tiff,xpm,tga,pcx"
 890 included_loaders=""
 891 # If no loaders specified, include all
 892 if test "x$with_included_loaders" = xyes ; then
 893   included_loaders="$all_loaders"
 894 else
 895   included_loaders="$with_included_loaders"
 896 fi
 897
 898 AC_MSG_RESULT($included_loaders)
 899
 900 INCLUDED_LOADER_OBJ=
 901 INCLUDED_LOADER_DEFINE=
 902
 903 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 904 for loader in $included_loaders; do
 905  if echo "$all_loaders" | egrep "(^|,)$loader(\$|,)" > /dev/null; then
 906    :
 907  else
 908    AC_MSG_ERROR([the specified loader $loader does not exist])
 909  fi
 910
 911  INCLUDED_LOADER_OBJ="$INCLUDED_LOADER_OBJ libpixbufloader-static-$loader.la"
 912  INCLUDED_LOADER_DEFINE="$INCLUDED_LOADER_DEFINE -DINCLUDE_$loader"
 913 done
 914 IFS="$gtk_save_ifs"
 915 AC_SUBST(INCLUDED_LOADER_OBJ)
 916 AC_SUBST(INCLUDED_LOADER_DEFINE)
 917
 918 AC_HEADER_SYS_WAIT
 919
 920 AC_TYPE_SIGNAL
 921
 922 AM_CONDITIONAL(HAVE_TIFF, test "x$LIBTIFF" != x)
 923 AM_CONDITIONAL(HAVE_PNG, test "x$LIBPNG" != x)
 924 AM_CONDITIONAL(HAVE_JPEG, test "x$LIBJPEG" != x)
 925
 926 if $dynworks ; then
 927   STATIC_LIB_DEPS=
 928   if echo "$included_loaders" | egrep '(^|,)tiff($|,)' > /dev/null; then
 929     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBTIFF"
 930   fi
 931   if echo "$included_loaders" | egrep '(^|,)jpeg($|,)' > /dev/null; then
 932     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBJPEG"
 933   fi
 934   if echo "$included_loaders" | egrep '(^|,)png($|,)' > /dev/null; then
 935     STATIC_LIB_DEPS="$STATIC_LIB_DEPS $LIBPNG"
 936   fi
 937 else
 938   STATIC_LIB_DEPS="$LIBTIFF $LIBJPEG $LIBPNG"
 939 fi
 940
 941 # Checks to see if we should compile in MMX support (there will be
 942 # a runtime test when the code is actually run to see if it should
 943 # be used - this just checks if we can compile it.)
 944 #
 945 # This code is partially taken from Mesa
 946 #
 947 AC_MSG_CHECKING(for x86 platform)
 948 case $host_cpu in
 949   i386|i486|i586|i686|i786|k6|k7)
 950         use_x86_asm=yes
 951         ;;
 952    *)
 953         use_x86_asm=no
 954 esac
 955 AC_MSG_RESULT($use_x86_asm)
 956
 957 use_mmx_asm=no
 958 if test $use_x86_asm = yes; then
 959     save_ac_ext=$ac_ext
 960     ac_ext=S
 961
 962     AC_MSG_CHECKING(compiler support for MMX)
 963     cp $srcdir/gdk-pixbuf/pixops/scale_line_22_33_mmx.S conftest.S
 964     if AC_TRY_EVAL(ac_compile); then
 965         use_mmx_asm=yes
 966     fi
 967
 968     rm -rf conftest*
 969
 970     ac_ext=$save_ac_ext
 971     if test $use_mmx_asm = yes; then
 972       AC_DEFINE(USE_MMX)
 973       AC_MSG_RESULT(yes)
 974     else
 975       AC_MSG_RESULT(no)
 976     fi
 977 fi
 978
 979 AM_CONDITIONAL(USE_MMX, test x$use_mmx_asm = xyes)
 980
 981 REBUILD_PNGS=
 982 if test -z "$LIBPNG"; then
 983   REBUILD_PNGS=#
 984 fi
 985
 986 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 987
 988 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 989
 990 if test $cross_compiling = yes; then
 991   AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 992   if test x$GDK_PIXBUF_CSOURCE = xno; then
 993     REBUILD_PNGS=#
 994   fi
 995 fi
 996
 997 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 998    test "x$REBUILD_PNGS" = "x#" ; then
 999      AC_MSG_ERROR([
1000 *** gtkbuiltincache.h is not in the tree, and cannot be built
1001 *** because you don't have libpng, or (when cross-compiling) you
1002 *** don't have a prebuilt gdk-pixbuf-csource on the host system.])
1003 fi
1004
1005 AC_SUBST(REBUILD_PNGS)
1006
1007 GDK_PIXBUF_PACKAGES="gmodule-no-export-2.0 gobject-2.0"
1008 GDK_PIXBUF_EXTRA_LIBS="$STATIC_LIB_DEPS $MATH_LIB"
1009 GDK_PIXBUF_EXTRA_CFLAGS=
1010 GDK_PIXBUF_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
1011 GDK_PIXBUF_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $PNG_DEP_CFLAGS_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS"
1012
1013 AC_SUBST(GDK_PIXBUF_PACKAGES)
1014 AC_SUBST(GDK_PIXBUF_EXTRA_LIBS)
1015 AC_SUBST(GDK_PIXBUF_EXTRA_CFLAGS)
1016 AC_SUBST(GDK_PIXBUF_DEP_LIBS)
1017 AC_SUBST(GDK_PIXBUF_DEP_CFLAGS)
1018
1019
1020 ########################################
1021 # Windowing system checks
1022 ########################################
1023
1024 GDK_PIXBUF_XLIB_PACKAGES=
1025 GDK_PIXBUF_XLIB_EXTRA_CFLAGS=
1026 GDK_PIXBUF_XLIB_EXTRA_LIBS=
1027
1028 X_PACKAGES=fontconfig
1029 GDK_EXTRA_LIBS="$GDK_WLIBS"
1030 GDK_EXTRA_CFLAGS=
1031
1032 # GTK+ uses some X calls, so needs to link against X directly
1033 GTK_DEP_PACKAGES_FOR_X=
1034 GTK_DEP_LIBS_FOR_X=
1035
1036 if test "x$gdktarget" = "xx11"; then
1037   #
1038   # We use fontconfig very peripherally when decoding the default
1039   # settings.
1040   #
1041   if $PKG_CONFIG --exists fontconfig; then : ; else
1042     AC_MSG_ERROR([
1043 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
1044   fi
1045
1046   #
1047   # Check for basic X packages; we use pkg-config if available
1048   #
1049   if $PKG_CONFIG --exists x11 xext xrender; then
1050     have_base_x_pc=true
1051     X_PACKAGES="$X_PACKAGES x11 xext xrender"
1052     x_libs="`$PKG_CONFIG --libs x11 xext xrender`"
1053     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext xrender`"
1054
1055     # Strip out any .la files that pkg-config might give us (this happens
1056     # with -uninstalled.pc files)
1057     x_libs_for_checks=
1058     for I in $x_libs ; do
1059       case $I in
1060         *.la) ;;
1061         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
1062       esac
1063     done
1064
1065     GDK_PIXBUF_XLIB_PACKAGES="x11"
1066     GTK_PACKAGES_FOR_X="x11"
1067   else
1068     have_base_x_pc=false
1069     AC_PATH_XTRA
1070     if test x$no_x = xyes ; then
1071       AC_MSG_ERROR([X development libraries not found])
1072     fi
1073
1074     x_cflags="$X_CFLAGS"
1075     x_libs_for_checks="$X_LIBS -lXext -lXrender -lX11 $X_EXTRA_LIBS"
1076
1077     GDK_PIXBUF_XLIB_EXTRA_CFLAGS="$x_cflags"
1078     GDK_PIXBUF_XLIB_EXTRA_LIBS="$X_LIBS -lX11 $X_EXTRA_LIBS"
1079     GTK_DEP_LIBS_FOR_X="$X_LIBS -lXrender -lX11 $X_EXTRA_LIBS"
1080   fi
1081
1082   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
1083   x_extra_libs=
1084
1085   gtk_save_cppflags="$CPPFLAGS"
1086   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1087
1088   gtk_save_LIBS=$LIBS
1089   LIBS="$x_libs_for_checks $LIBS"
1090
1091   # Sanity check for the X11 and Xext libraries. While everything we need from
1092   # Xext is optional, the chances a system has *none* of these things is so
1093   # small that we just unconditionally require it.
1094   AC_CHECK_FUNC(XOpenDisplay, :,
1095                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
1096   AC_CHECK_FUNC(XextFindDisplay, :,
1097                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
1098   AC_CHECK_FUNC(XRenderQueryExtension, :,
1099                 AC_MSG_ERROR([*** libXrender not found. Check 'config.log' for more details.]))
1100
1101   # Check for xReply
1102
1103   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
1104   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
1105       [xReply *rep;],
1106       [AC_MSG_RESULT([no])],
1107       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
1108 #include <X11/Xlibint.h>],
1109            [xReply *rep;],
1110            [AC_MSG_RESULT([yes])
1111             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
1112                 [Define if <X11/extensions/XIproto.h> needed for xReply])],
1113            [AC_MSG_RESULT([unknown])
1114             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1115
1116   # Check for XConvertCase, XInternAtoms (X11R6 specific)
1117
1118   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
1119
1120   # Generic X11R6 check needed for XIM support; we could
1121   # probably use this to replace the above, but we'll
1122   # leave the separate checks for XConvertCase and XInternAtoms
1123   # for clarity
1124
1125   have_x11r6=false
1126   AC_CHECK_FUNC(XAddConnectionWatch,
1127       have_x11r6=true)
1128
1129   if $have_x11r6; then
1130     AC_DEFINE(HAVE_X11R6,1,[Define if we have X11R6])
1131   fi
1132   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1133
1134   # Check for XKB support.
1135
1136   if test "x$enable_xkb" = "xyes"; then
1137         AC_MSG_WARN(XKB support explicitly enabled)
1138         AC_DEFINE(HAVE_XKB)
1139   elif test "x$enable_xkb" = "xmaybe"; then
1140         AC_CHECK_FUNC(XkbQueryExtension,
1141                       AC_DEFINE(HAVE_XKB))
1142   else
1143         AC_MSG_WARN(XKB support explicitly disabled)
1144   fi
1145
1146   # Check for shaped window extension
1147
1148   AC_CHECK_FUNC(XShapeCombineMask,
1149       AC_DEFINE(HAVE_SHAPE_EXT))
1150
1151   # X SYNC check
1152   gtk_save_CFLAGS="$CFLAGS"
1153   CFLAGS="$CFLAGS $x_cflags"
1154
1155   AC_CHECK_FUNC(XSyncQueryExtension,
1156       [AC_CHECK_HEADER(X11/extensions/sync.h,
1157           AC_DEFINE(HAVE_XSYNC, 1, Have the SYNC extension library),
1158           :, [#include <X11/Xlib.h>])])
1159
1160   CFLAGS="$gtk_save_CFLAGS"
1161
1162   # Xshm checks
1163
1164   if test "x$enable_shm" = "xyes"; then
1165      # Check for the XShm extension, normally in Xext
1166      AC_CHECK_FUNC(XShmAttach,
1167         :,
1168         # On AIX, it is in XextSam instead
1169         [AC_CHECK_LIB(XextSam, XShmAttach,
1170             [GTK_ADD_LIB(x_extra_libs,XextSam)])])
1171   fi
1172
1173   if test "x$enable_shm" = "xyes"; then
1174     # Check for shared memory
1175     AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
1176     AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
1177
1178     # Check for the X shared memory extension header file
1179     have_xshm=no
1180     AC_MSG_CHECKING(X11/extensions/XShm.h)
1181     if test "x$no_xext_lib" = "xyes"; then
1182       :
1183     else
1184       gtk_save_CFLAGS="$CFLAGS"
1185       CFLAGS="$CFLAGS $x_cflags"
1186       AC_TRY_COMPILE([
1187 #include <stdlib.h>
1188 #include <sys/types.h>
1189 #include <sys/ipc.h>
1190 #include <sys/shm.h>
1191 #include <X11/Xlib.h>
1192 #include <X11/Xutil.h>
1193 #include <X11/extensions/XShm.h>
1194 ], [XShmSegmentInfo *x_shm_info;], have_xshm=yes)
1195       CFLAGS="$gtk_save_CFLAGS"
1196     fi
1197     AC_MSG_RESULT($have_xshm)
1198     if test $have_xshm = yes ; then
1199       AC_DEFINE(HAVE_XSHM_H)
1200     fi
1201   fi
1202
1203   # Check for Xinerama extension (Solaris impl or Xfree impl)
1204
1205   gtk_save_cppflags="$CPPFLAGS"
1206   CPPFLAGS="$CPPFLAGS $x_cflags"
1207
1208   case "$host" in
1209       *-*-solaris*)
1210           # Check for solaris
1211           AC_MSG_CHECKING(for Xinerama support on Solaris)
1212
1213           have_solaris_xinerama=false
1214           AC_CHECK_FUNC(XineramaGetInfo,
1215               [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1216                   [have_solaris_xinerama=true], :,
1217                   [#include <X11/Xlib.h>])])
1218
1219           if $have_solaris_xinerama ; then
1220             AC_DEFINE(HAVE_SOLARIS_XINERAMA)
1221             AC_DEFINE(HAVE_XINERAMA)
1222             AC_MSG_RESULT(yes)
1223           else
1224             AC_MSG_RESULT(no)
1225           fi
1226           ;;
1227       *)
1228           # Check for XFree
1229           AC_MSG_CHECKING(for Xinerama support on XFree86)
1230
1231           have_xfree_xinerama=false
1232           if $PKG_CONFIG --exists xinerama ; then
1233              have_xfree_xinerama=true
1234              X_PACKAGES="$X_PACKAGES xinerama"
1235           else
1236               AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1237                   [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1238                       [GTK_ADD_LIB(x_extra_libs,Xinerama)
1239                       have_xfree_xinerama=true], :,
1240                       [#include <X11/Xlib.h>])])
1241           fi
1242
1243           if $have_xfree_xinerama ; then
1244             AC_DEFINE(HAVE_XFREE_XINERAMA)
1245             AC_DEFINE(HAVE_XINERAMA)
1246             AC_MSG_RESULT(yes)
1247          else
1248             AC_MSG_RESULT(no)
1249          fi
1250          ;;
1251   esac
1252
1253   # set up things for XInput
1254
1255   if test "x$with_xinput" = "xxfree" || test "x$with_xinput" = "xyes"; then
1256     AC_DEFINE(XINPUT_XFREE)
1257
1258     if $PKG_CONFIG --exists xi ; then
1259       X_PACKAGES="$X_PACKAGES xi"
1260     else
1261       GTK_ADD_LIB(x_extra_libs, Xi)
1262     fi
1263   else
1264     AC_DEFINE(XINPUT_NONE)
1265   fi
1266
1267   AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree || test x$with_xinput = xyes)
1268
1269   # Check for the RANDR extension
1270
1271   have_randr=false
1272   if $PKG_CONFIG --exists xrandr ; then
1273     have_randr=true
1274     X_PACKAGES="$X_PACKAGES xrandr"
1275   else
1276     AC_CHECK_LIB(Xrandr, XRRUpdateConfiguration,
1277        [AC_CHECK_HEADER(X11/extensions/Xrandr.h,
1278           # RANDR requires RENDER
1279           [have_randr=true
1280           GTK_ADD_LIB(x_extra_libs, Xrender)
1281           GTK_ADD_LIB(x_extra_libs, Xrandr)],
1282           :, [#include <X11/Xlib.h>])])
1283   fi
1284
1285   if $have_randr ; then
1286      AC_DEFINE(HAVE_RANDR, 1, Have the Xrandr extension library)
1287   fi
1288
1289   # Checks for Xcursor library
1290
1291   if $PKG_CONFIG --exists xcursor ; then
1292     AC_DEFINE(HAVE_XCURSOR, 1, Have the Xcursor library)
1293
1294     X_PACKAGES="$X_PACKAGES xcursor"
1295   fi
1296
1297   # Checks for XFixes extension
1298
1299   if $PKG_CONFIG --exists xfixes ; then
1300     AC_DEFINE(HAVE_XFIXES, 1, Have the XFIXES X extension)
1301
1302     X_PACKAGES="$X_PACKAGES xfixes"
1303   fi
1304
1305   if $have_base_x_pc ; then
1306     GDK_EXTRA_LIBS="$x_extra_libs"
1307   else
1308     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1309   fi
1310
1311   CPPFLAGS="$gtk_save_cppflags"
1312   LIBS="$gtk_save_libs"
1313
1314   AM_CONDITIONAL(USE_X11, true)
1315 else
1316   AM_CONDITIONAL(XINPUT_XFREE, false)
1317   AM_CONDITIONAL(USE_X11, false)
1318   AM_CONDITIONAL(HAVE_X11R6, false)
1319 fi
1320
1321 if test "x$gdktarget" = "xwin32"; then
1322   # We start off with the libraries from Pango
1323
1324   if test x$have_wintab = xyes; then
1325     GDK_WIN32_EXTRA_CFLAGS="-I $with_wintab/include"
1326     AC_SUBST(GDK_WIN32_EXTRA_CFLAGS)
1327   fi
1328
1329   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -user32 -limm32 -lshell32 -lole32 -Wl,-luuid"
1330   AM_CONDITIONAL(USE_WIN32, true)
1331 else
1332   AM_CONDITIONAL(USE_WIN32, false)
1333 fi
1334
1335 if test "x$gdktarget" = "xquartz"; then
1336   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
1337   AM_CONDITIONAL(USE_QUARTZ, true)
1338 else
1339   AM_CONDITIONAL(USE_QUARTZ, false)
1340 fi
1341
1342 GDK_PIXBUF_XLIB_DEP_LIBS="`$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_XLIB_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
1343 GDK_PIXBUF_XLIB_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PIXBUF_XLIB_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_PIXBUF_XLIB_EXTRA_CFLAGS"
1344
1345 AC_SUBST(GDK_PIXBUF_XLIB_PACKAGES)
1346 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_LIBS)
1347 AC_SUBST(GDK_PIXBUF_XLIB_EXTRA_CFLAGS)
1348 AC_SUBST(GDK_PIXBUF_XLIB_DEP_LIBS)
1349 AC_SUBST(GDK_PIXBUF_XLIB_DEP_CFLAGS)
1350
1351 if test "x$gdktarget" = "xlinux-fb"; then
1352   if test x$enable_shadowfb = xyes ; then
1353     AC_DEFINE(ENABLE_SHADOW_FB)
1354   fi
1355
1356   if test x$enable_fbmanager = xyes ; then
1357     AC_DEFINE(ENABLE_FB_MANAGER)
1358     AM_CONDITIONAL(ENABLE_FB_MANAGER, true)
1359   else
1360     AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
1361   fi
1362
1363   AM_CONDITIONAL(USE_LINUX_FB, true)
1364 else
1365   AM_CONDITIONAL(USE_LINUX_FB, false)
1366   AM_CONDITIONAL(ENABLE_FB_MANAGER, false)
1367 fi
1368
1369 if test "x$gdktarget" = "xdirectfb"; then
1370   DIRECTFB_REQUIRED_VERSION=0.9.24
1371   AC_MSG_CHECKING(for DirectFB)
1372
1373   if $PKG_CONFIG --atleast-version $DIRECTFB_REQUIRED_VERSION directfb ; then
1374       AC_MSG_RESULT(found)
1375       GDK_EXTRA_CFLAGS="`$PKG_CONFIG --cflags cairo-directfb` $GDK_EXTRA_CFLAGS"
1376       GDK_EXTRA_LIBS="`$PKG_CONFIG --libs cairo-directfb` $GDK_EXTRA_LIBS"
1377   else
1378       AC_MSG_ERROR([
1379 *** DirectFB $DIRECTFB_REQUIRED_VERSION or newer is required. The latest
1380 *** version of DirectFB is always available from http://www.directfb.org/.
1381   ])
1382   fi
1383
1384   AM_CONDITIONAL(USE_DIRECTFB, true)
1385 else
1386   AM_CONDITIONAL(USE_DIRECTFB, false)
1387 fi
1388
1389
1390 # Check for Pango flags
1391
1392 if test "x$gdktarget" = "xwin32"; then
1393         PANGO_PACKAGES="pangowin32 pangocairo"
1394 else
1395         PANGO_PACKAGES="pango pangocairo"
1396 fi
1397
1398 AC_MSG_CHECKING(Pango flags)
1399 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1400         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1401         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1402
1403         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1404 else
1405         AC_MSG_ERROR([
1406 *** Pango not found. Pango built with Cairo support is required
1407 *** to build GTK+. See http://www.pango.org for Pango information.
1408 ])
1409 fi
1410
1411 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1412
1413 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1414         :
1415 else
1416         gtk_save_LIBS="$LIBS"
1417         LIBS="$PANGO_LIBS $LIBS"
1418         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1419 *** Can't link to Pango. Pango is required to build
1420 *** GTK+. For more information see http://www.pango.org]))
1421         LIBS="$gtk_save_LIBS"
1422 fi
1423
1424 CFLAGS="$saved_cflags"
1425 LDFLAGS="$saved_ldflags"
1426
1427 GDK_PACKAGES="$PANGO_PACKAGES"
1428 if test "x$gdktarget" = "xx11"; then
1429   GDK_PACKAGES="$GDK_PACKAGES $X_PACKAGES"
1430 fi
1431 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_LIBS"
1432 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS"
1433
1434 #
1435 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1436 # into the pkg-config files
1437 #
1438 if test $enable_explicit_deps != yes ; then
1439   GDK_PACKAGES="$PANGO_PACKAGES"
1440   GDK_EXTRA_LIBS=
1441 fi
1442
1443 AC_SUBST(GDK_PACKAGES)
1444 AC_SUBST(GDK_EXTRA_LIBS)
1445 AC_SUBST(GDK_EXTRA_CFLAGS)
1446 AC_SUBST(GDK_DEP_LIBS)
1447 AC_SUBST(GDK_DEP_CFLAGS)
1448
1449
1450 ########################################
1451 # Check for Accessibility Toolkit flags
1452 ########################################
1453
1454 ATK_PACKAGES=atk
1455 AC_MSG_CHECKING(ATK flags)
1456 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1457         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1458         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1459
1460         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1461 else
1462         AC_MSG_ERROR([
1463 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1464 *** to build GTK+.
1465 ])
1466 fi
1467
1468 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1469         :
1470 else
1471         gtk_save_LIBS="$LIBS"
1472         LIBS="$ATK_LIBS $LIBS"
1473         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1474                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1475                 *** to build GTK+]))
1476         LIBS="$gtk_save_LIBS"
1477 fi
1478
1479 GTK_PACKAGES="atk cairo"
1480 GTK_EXTRA_LIBS=
1481 GTK_EXTRA_CFLAGS=
1482 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $GDK_PIXBUF_PACKAGES $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS $GDK_PIXBUF_EXTRA_LIBS"
1483 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PIXBUF_PACKAGES $GDK_PACKAGES $GTK_PACKAGES` $GDK_PIXBUF_EXTRA_CFLAGS $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1484
1485 if test x"$os_win32" = xyes; then
1486   GTK_EXTRA_CFLAGS="$msnative_struct"
1487 fi
1488
1489 AC_SUBST(GTK_PACKAGES)
1490 AC_SUBST(GTK_EXTRA_LIBS)
1491 AC_SUBST(GTK_EXTRA_CFLAGS)
1492 AC_SUBST(GTK_DEP_LIBS)
1493 AC_SUBST(GTK_DEP_CFLAGS)
1494
1495
1496 AC_SUBST(GTK_DEBUG_FLAGS)
1497 AC_SUBST(GTK_XIM_FLAGS)
1498
1499 ################################################################
1500 # Printing system checks
1501 ################################################################
1502
1503 AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1504 if test "x$CUPS_CONFIG" != "xno"; then
1505   CUPS_CFLAGS=`cups-config --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1506   CUPS_LIBS=`cups-config --libs`
1507
1508   CUPS_API_VERSION=`cups-config --api-version`
1509   CUPS_API_MAJOR=`echo -n $CUPS_API_VERSION | awk -F. '{print $1}'`
1510   CUPS_API_MINOR=`echo -n $CUPS_API_VERSION | awk -F. '{print $2}'`
1511
1512   if test $CUPS_API_MAJOR -gt 1 -o \
1513           $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1514     AC_DEFINE(HAVE_CUPS_API_1_2)
1515   fi
1516
1517   AC_SUBST(CUPS_API_MAJOR)
1518   AC_SUBST(CUPS_API_MINOR)
1519   AC_SUBST(CUPS_CFLAGS)
1520   AC_SUBST(CUPS_LIBS)
1521 fi
1522 AM_CONDITIONAL(HAVE_CUPS, test "x$CUPS_CONFIG" != "xno")
1523
1524 gtk_save_cppflags="$CPPFLAGS"
1525 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS"
1526
1527 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1528 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1529 *** backend enabled.]))
1530
1531 if test "$os_win32" != "yes"; then
1532   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1533 *** Can't find cairo-ps.h. You must build Cairo with the
1534 *** postscript backend enabled.]))
1535 fi
1536
1537 CPPFLAGS="$gtk_save_cppflags"
1538
1539
1540 ################################################################
1541 # Strip -export-dynamic from the link lines of various libraries
1542 ################################################################
1543
1544 #
1545 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1546 #  but this flag is only meaningful for executables. For libraries
1547 #  the effect is undefined; what it causes on Linux is that the
1548 #  export list from -export-symbols-regex is ignored and everything
1549 #  is exported
1550 #
1551 # We are using gmodule-no-export now, but I'm leaving the stripping
1552 # code in place for now, since pango and atk still require gmodule.
1553 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1554 if test -n "$export_dynamic"; then
1555   GDK_PIXBUF_DEP_LIBS=`echo $GDK_PIXBUF_DEP_LIBS | sed -e "s/$export_dynamic//"`
1556   GDK_PIXBUF_XLIB_DEP_LIBS=`echo $GDK_PIXBUF_XLIB_DEP_LIBS | sed -e "s/$export_dynamic//"`
1557   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1558   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1559 fi
1560
1561
1562 ##################################################
1563 # Checks for gtk-doc and docbook-tools
1564 ##################################################
1565
1566 GTK_DOC_CHECK([1.4])
1567
1568 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1569 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1570
1571 AC_ARG_ENABLE(man,
1572               [AC_HELP_STRING([--enable-man],
1573                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1574               enable_man=no)
1575
1576 if test "${enable_man}" != no; then
1577   dnl
1578   dnl Check for xsltproc
1579   dnl
1580   AC_PATH_PROG([XSLTPROC], [xsltproc])
1581   if test -z "$XSLTPROC"; then
1582     enable_man=no
1583   fi
1584
1585   dnl check for DocBook DTD and stylesheets in the local catalog.
1586   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1587      [DocBook XML DTD V4.1.2],,enable_man=no)
1588   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1589      [DocBook XSL Stylesheets],,enable_man=no)
1590 fi
1591
1592 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1593
1594
1595 ##################################################
1596 # Output commands
1597 ##################################################
1598
1599 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1600         outfile=gdkconfig.h-tmp
1601         cat > $outfile <<\_______EOF
1602 /* gdkconfig.h
1603  *
1604  * This is a generated file.  Please modify `configure.in'
1605  */
1606
1607 #ifndef GDKCONFIG_H
1608 #define GDKCONFIG_H
1609
1610 #ifdef __cplusplus
1611 extern "C" {
1612 #endif /* __cplusplus */
1613
1614 _______EOF
1615
1616         cat >>$outfile <<_______EOF
1617 $gdk_windowing
1618 $gdk_wc
1619 _______EOF
1620
1621         cat >>$outfile <<_______EOF
1622
1623 #ifdef __cplusplus
1624 }
1625 #endif /* __cplusplus */
1626
1627 #endif /* GDKCONFIG_H */
1628 _______EOF
1629
1630
1631         if cmp -s $outfile gdk/gdkconfig.h; then
1632           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1633           rm -f $outfile
1634         else
1635           mv $outfile gdk/gdkconfig.h
1636         fi
1637 ],[
1638 if test "x$gdktarget" = "xx11" ; then
1639   gdk_windowing='
1640 #define GDK_WINDOWING_X11'
1641 elif test "x$gdktarget" = "xwin32" ; then
1642   gdk_windowing='
1643 #define GDK_WINDOWING_WIN32'
1644 elif test "x$gdktarget" = "xlinux-fb" ; then
1645   gdk_windowing='
1646 #define GDK_WINDOWING_FB
1647 #define GDK_NATIVE_WINDOW_POINTER'
1648 elif test "x$gdktarget" = "xquartz" ; then
1649   gdk_windowing='
1650 #define GDK_WINDOWING_QUARTZ'
1651 elif test "x$gdktarget" = "xdirectfb" ; then
1652   gdk_windowing='
1653 #define GDK_WINDOWING_DIRECTFB'
1654 fi
1655
1656 if test x$gdk_wchar_h = xyes; then
1657   gdk_wc='
1658 #define GDK_HAVE_WCHAR_H 1'
1659 fi
1660 if test x$gdk_wctype_h = xyes; then
1661   gdk_wc="\$gdk_wc
1662 #define GDK_HAVE_WCTYPE_H 1"
1663 fi
1664 if test x$gdk_working_wctype = xno; then
1665   gdk_wc="\$gdk_wc
1666 #define GDK_HAVE_BROKEN_WCTYPE 1"
1667 fi
1668
1669
1670 ])
1671
1672 AC_CONFIG_FILES([
1673 config.h.win32
1674 gtk-zip.sh
1675 Makefile
1676 gdk-pixbuf-2.0.pc
1677 gdk-2.0.pc
1678 gtk+-2.0.pc
1679 gtk+-unix-print-2.0.pc
1680 gdk-pixbuf-2.0-uninstalled.pc
1681 gdk-2.0-uninstalled.pc
1682 gtk+-2.0-uninstalled.pc
1683 m4macros/Makefile
1684 po/Makefile.in
1685 po-properties/Makefile.in
1686 demos/Makefile
1687 demos/gtk-demo/Makefile
1688 demos/gtk-demo/geninclude.pl
1689 tests/Makefile
1690 docs/Makefile
1691 docs/reference/Makefile
1692 docs/reference/gdk-pixbuf/Makefile
1693 docs/reference/gdk-pixbuf/version.xml
1694 docs/reference/gdk/Makefile
1695 docs/reference/gdk/version.xml
1696 docs/reference/gtk/Makefile
1697 docs/reference/gtk/version.xml
1698 docs/faq/Makefile
1699 docs/tools/Makefile
1700 docs/tutorial/Makefile
1701 gdk-pixbuf/Makefile
1702 gdk-pixbuf/gdk_pixbuf.rc
1703 gdk-pixbuf/gdk-pixbuf-features.h
1704 gdk-pixbuf/pixops/Makefile
1705 gdk/Makefile
1706 gdk/x11/Makefile
1707 gdk/win32/Makefile
1708 gdk/win32/rc/Makefile
1709 gdk/win32/rc/gdk.rc
1710 gdk/linux-fb/Makefile
1711 gdk/quartz/Makefile
1712 gdk/directfb/Makefile
1713 gtk/Makefile
1714 gtk/makefile.msc
1715 gtk/gtkversion.h
1716 gtk/gtk-win32.rc
1717 gtk/theme-bits/Makefile
1718 gtk/xdgmime/Makefile
1719 modules/Makefile
1720 modules/input/Makefile
1721 modules/engines/Makefile
1722 modules/engines/pixbuf/Makefile
1723 modules/engines/ms-windows/Makefile
1724 modules/engines/ms-windows/Theme/Makefile
1725 modules/engines/ms-windows/Theme/gtk-2.0/Makefile
1726 modules/printbackends/Makefile
1727 modules/printbackends/cups/Makefile
1728 modules/printbackends/lpr/Makefile
1729 modules/printbackends/file/Makefile
1730 perf/Makefile
1731 contrib/Makefile
1732 contrib/gdk-pixbuf-xlib/Makefile
1733 contrib/gdk-pixbuf-xlib/gdk-pixbuf-xlib-2.0.pc
1734 ])
1735
1736 AC_OUTPUT
1737
1738 echo "configuration:
1739         target: $gdktarget"
1740
1741 if test "x$gdktarget" = "xlinux-fb"; then
1742   echo "Warning: The linux-fb GDK target is unmaintained"
1743   echo "         and may not work or even compile"
1744 fi
1745