Pileus Git - ~andy/gtk/blob - configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(gdk/gdktypes.h)
   3
   4 # In the following, there are a the following variants
   5 # of GLib cflags and libs variables
   6 #
   7 # GLIB_CFLAGS:  cflags for compiling libraries and example progs
   8 # GLIB_LIBS:    libraries for linking example programs
   9 # GLIB_DEPLIBS: libraries for linking libraries against
  10 # glib_cflags:  cflags to store in gtk-config
  11 # glib_libs:    libs to store in gtk-config
  12 # glib_thread_cflags: cflags to store in gtk-config for gtk-config gthread
  13 # glib_thread_libs:   libs to store in gtk-config for gtk-config gthread
  14
  15 # Save this value here, since automake will set cflags later
  16 cflags_set=${CFLAGS+set}
  17
  18 dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  19 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  20 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  21 #
  22 # Making releases:
  23 #   GTK_MICRO_VERSION += 1;
  24 #   GTK_INTERFACE_AGE += 1;
  25 #   GTK_BINARY_AGE += 1;
  26 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  27 # if backwards compatibility has been broken,
  28 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  29 #
  30 GTK_MAJOR_VERSION=1
  31 GTK_MINOR_VERSION=3
  32 GTK_MICRO_VERSION=0
  33 GTK_INTERFACE_AGE=0
  34 GTK_BINARY_AGE=0
  35 GTK_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$GTK_MICRO_VERSION
  36 dnl
  37 AC_DIVERT_POP()dnl
  38
  39 AC_SUBST(GTK_MAJOR_VERSION)
  40 AC_SUBST(GTK_MINOR_VERSION)
  41 AC_SUBST(GTK_MICRO_VERSION)
  42 AC_SUBST(GTK_INTERFACE_AGE)
  43 AC_SUBST(GTK_BINARY_AGE)
  44 AC_SUBST(GTK_VERSION)
  45
  46 # libtool versioning
  47 LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  48 LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  49 LT_REVISION=$GTK_INTERFACE_AGE
  50 LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  51 AC_SUBST(LT_RELEASE)
  52 AC_SUBST(LT_CURRENT)
  53 AC_SUBST(LT_REVISION)
  54 AC_SUBST(LT_AGE)
  55
  56 # For automake.
  57 VERSION=$GTK_VERSION
  58 PACKAGE=gtk+
  59
  60 # Save this value here, since automake will set cflags later
  61 cflags_set=${CFLAGS+set}
  62
  63 dnl Initialize automake stuff
  64 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  65
  66 # Specify a configuration file
  67 AM_CONFIG_HEADER(config.h)
  68
  69 dnl Initialize libtool
  70 AM_PROG_LIBTOOL
  71
  72 dnl Initialize maintainer mode
  73 AM_MAINTAINER_MODE
  74
  75 AC_CANONICAL_HOST
  76
  77 dnl figure debugging default, prior to $ac_help setup
  78 dnl
  79 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  80 if test `expr $GTK_MINOR_VERSION \% 2` = 1 ; then
  81         debug_default=yes
  82 else
  83         debug_default=minimum
  84 fi
  85 AC_DIVERT_POP()dnl
  86
  87 dnl declare --enable-* args and collect ac_help strings
  88 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
  89 AC_ARG_ENABLE(shm, [  --enable-shm            support shared memory if available [default=yes]],
  90                    echo $enable_shm, enable_shm="yes")
  91 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  92                     , enable_ansi=no)
  93 AC_ARG_WITH(glib, [  --with-glib=DIR         Use uninstalled copy of glib])
  94 AC_ARG_ENABLE(xim, [  --enable-xim            support XIM [default=yes]],
  95                         , enable_xim="yes")
  96 AC_ARG_ENABLE(xim_inst, [  --disable-xim-inst      does not use xim instantiate callback],
  97                         , enable_xim_inst="maybe")
  98 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
  99 AC_ARG_WITH(locale, [  --with-locale=LOCALE    locale name you want to use ])
 100
 101 AC_ARG_WITH(xinput, [  --with-xinput=[no/gxi/xfree] support XInput ])
 102
 103 if test "x$enable_debug" = "xyes"; then
 104   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 105   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 106 else
 107   if test "x$enable_debug" = "xno"; then
 108     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DGTK_NO_CHECK_CASTS"
 109   else
 110     GTK_DEBUG_FLAGS="-DGTK_NO_CHECK_CASTS"
 111   fi
 112 fi
 113
 114 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 115
 116 # Build time sanity check...
 117 AM_SANITY_CHECK
 118
 119 # Checks for programs.
 120 AC_PROG_CC
 121 AC_ISC_POSIX
 122 AM_PROG_CC_STDC
 123 AC_PROG_INSTALL
 124 AC_PROG_MAKE_SET
 125
 126 changequote(,)dnl
 127 if test "x$GCC" = "xyes"; then
 128   case " $CFLAGS " in
 129   *[\ \ ]-Wall[\ \      ]*) ;;
 130   *) CFLAGS="$CFLAGS -Wall" ;;
 131   esac
 132
 133   if test "x$enable_ansi" = "xyes"; then
 134     case " $CFLAGS " in
 135     *[\ \       ]-ansi[\ \      ]*) ;;
 136     *) CFLAGS="$CFLAGS -ansi" ;;
 137     esac
 138
 139     case " $CFLAGS " in
 140     *[\ \       ]-pedantic[\ \  ]*) ;;
 141     *) CFLAGS="$CFLAGS -pedantic" ;;
 142     esac
 143   fi
 144 fi
 145 changequote([,])dnl
 146
 147 # Honor aclocal flags
 148 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
 149
 150  # define a MAINT-like variable REBUILD which is set if Perl
 151 # and awk are found, so autogenerated sources can be rebuilt
 152
 153 AC_PROG_AWK
 154 AC_CHECK_PROGS(PERL, perl5 perl)
 155
 156 # We would like indent, but don't require it.
 157 AC_CHECK_PROG(INDENT, indent, indent)
 158
 159 REBUILD=\#
 160 if test "x$enable_rebuilds" = "xyes" && \
 161      test -n "$PERL" && \
 162      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 163      test -n "$AWK" ; then
 164   REBUILD=
 165 fi
 166 AC_SUBST(REBUILD)
 167
 168 AC_CHECK_FUNCS(lstat)
 169
 170 AC_MSG_CHECKING(whether make is GNU Make)
 171 STRIP_BEGIN=
 172 STRIP_END=
 173 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 174         STRIP_BEGIN='$(strip'
 175         STRIP_END=')'
 176         AC_MSG_RESULT(yes)
 177 else
 178         AC_MSG_RESULT(no)
 179 fi
 180 AC_SUBST(STRIP_BEGIN)
 181 AC_SUBST(STRIP_END)
 182
 183 # i18n stuff
 184 ALL_LINGUAS="ca cs da de el es et eu fi fr ga gl hr hu it ja ko nl no pl pt pt_BR ru sk sl sv uk wa zh_TW.Big5"
 185 AM_GTK_GNU_GETTEXT
 186 LIBS="$LIBS $INTLLIBS"
 187
 188 # AM_GTK_GNU_GETTEXT above substs $DATADIRNAME
 189 # this is the directory where the *.{mo,gmo} files are installed
 190 gtklocaledir='${prefix}/${DATADIRNAME}/locale'
 191 AC_SUBST(gtklocaledir)
 192
 193 dnl The DU4 header files don't provide library prototypes unless
 194 dnl -std1 is given to the native cc.
 195 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 196
 197 gtk_save_LIBS=$LIBS
 198 LIBS="$LIBS -lm"
 199 AC_TRY_RUN([#include <math.h>
 200              int main (void) { return (log(1) != log(1.)); }],
 201      AC_MSG_RESULT(none needed),
 202      gtk_save_CFLAGS=$CFLAGS
 203      CFLAGS="$CFLAGS -std1"
 204      AC_TRY_RUN([#include <math.h>
 205                  int main (void) { return (log(1) != log(1.)); }],
 206          AC_MSG_RESULT(-std1),
 207          AC_MSG_RESULT()
 208          CFLAGS=$gtk_save_CFLAGS
 209          AC_MSG_WARN(
 210                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 211      )
 212 )
 213 LIBS=$gtk_save_LIBS
 214
 215 MATH_LIB=-lm
 216 GTK_LIBS_EXTRA=
 217 AC_MSG_CHECKING(for the BeOS)
 218 case $host in
 219   *-*-beos*)
 220     AC_MSG_RESULT(yes)
 221     GTK_LIBS_EXTRA="-L\$(top_builddir_full)/gdk/.libs -lgdk"
 222     MATH_LIB=
 223   ;;
 224   *)
 225     AC_MSG_RESULT(no)
 226   ;;
 227 esac
 228 AC_SUBST(MATH_LIB)
 229 AC_SUBST(GTK_LIBS_EXTRA)
 230
 231 dnl NeXTStep cc seems to need this
 232 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 233 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 234   AC_MSG_RESULT(none needed),
 235   gtk_save_CFLAGS=$CFLAGS
 236   CFLAGS="$CFLAGS -posix"
 237   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 238     AC_MSG_RESULT(-posix),
 239     AC_MSG_RESULT()
 240     CFLAGS=$gtk_save_CFLAGS
 241     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 242
 243 if test x$with_glib = xyes ; then
 244   AC_MSG_ERROR([
 245 *** Directory must be specified for --with-glib])
 246 fi
 247
 248 if test x$with_glib = x ; then
 249   # Look for separately installed glib
 250
 251   AM_PATH_GLIB(1.3.0,,
 252     AC_MSG_ERROR([
 253 *** GLIB 1.3.0 or better is required. The latest version of GLIB
 254 *** is always available from ftp://ftp.gtk.org/.]),
 255     gmodule gthread)
 256
 257   # we do not want to make all gtk progs to link to thread libraries.
 258   glib_cflags=`$GLIB_CONFIG glib gmodule --cflags`
 259   glib_thread_cflags="$GLIB_CFLAGS"
 260   glib_libs=`$GLIB_CONFIG glib gmodule --libs`
 261   glib_thread_libs="$GLIB_LIBS"
 262   GLIB_LIBS="$glib_libs"
 263   GLIB_DEPLIBS="$glib_libs"
 264 else
 265   # Use uninstalled glib (assume they got the version right)
 266
 267   GLIB_CONFIG=$with_glib/glib-config
 268   if test -x $GLIB_CONFIG ; then
 269     :
 270   else
 271     AC_MSG_ERROR([GLIB directory ($with_glib) not present or not configured])
 272   fi
 273
 274   # For use in gtk-config
 275   glib_cflags=`$GLIB_CONFIG --cflags gmodule`
 276   glib_thread_cflags=`$GLIB_CONFIG --cflags gmodule gthread`
 277   glib_libs=`$GLIB_CONFIG --libs gmodule`
 278   glib_thread_libs=`$GLIB_CONFIG --libs gmodule gthread`
 279
 280   glib_release=`$GLIB_CONFIG --version | sed 's%\\.[[0-9]]*$%%'`
 281
 282   # canonicalize relative paths
 283   case $with_glib in
 284     /*)
 285       glib_dir=$with_glib
 286       ;;
 287     *)
 288       glib_dir="\$(top_builddir)/$with_glib"
 289       ;;
 290   esac
 291
 292   GLIB_CFLAGS="-I$glib_dir -I$glib_dir/gmodule"
 293   GLIB_LIBS="$glib_dir/libglib.la $glib_dir/gmodule/libgmodule.la"
 294   GLIB_DEPLIBS=
 295
 296   AC_SUBST(GLIB_CFLAGS)
 297   AC_SUBST(GLIB_LIBS)
 298 fi
 299
 300 AC_SUBST(glib_cflags)
 301 AC_SUBST(glib_libs)
 302 AC_SUBST(glib_thread_cflags)
 303 AC_SUBST(glib_thread_libs)
 304 AC_SUBST(GLIB_DEPLIBS)
 305
 306 AC_CHECK_HEADERS(dirent.h, AC_DEFINE(HAVE_DIRENT_H))
 307 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 308 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 309
 310 # Find the X11 include and library directories
 311 AC_PATH_X
 312 AC_PATH_XTRA
 313
 314 if test "x$x_includes" = "x"; then
 315   x_includes="/usr/include"
 316 fi
 317
 318 saved_cflags="$CFLAGS"
 319 saved_ldflags="$LDFLAGS"
 320
 321 CFLAGS="$CFLAGS $X_CFLAGS"
 322 LDFLAGS="$LDFLAGS $X_LDFLAGS $X_LIBS"
 323
 324 if test "x$no_x" = "xyes"; then
 325   AC_MSG_ERROR([
 326 *** X libraries or include files not found. Check 'config.log' for
 327 *** more details.])
 328 fi
 329
 330 # Checks for libraries.
 331 # Check for the X11 library
 332 AC_CHECK_LIB(X11, XOpenDisplay, x_libs="-lX11 $X_EXTRA_LIBS",
 333   AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]),
 334   $X_EXTRA_LIBS)
 335
 336 if test "x$enable_shm" = "xyes"; then
 337   # Check for the Xext library (needed for XShm extention)
 338   AC_CHECK_LIB(Xext, XShmAttach,
 339       x_libs="-lXext $x_libs",
 340       # On AIX, it is in XextSam instead, but we still need -lXext
 341       AC_CHECK_LIB(XextSam, XShmAttach,
 342           x_libs="-lXextSam -lXext $x_libs",
 343           no_xext_lib=yes, $x_libs),
 344       $x_libs)
 345 fi
 346
 347 # Check for shaped window extension
 348
 349 AC_CHECK_LIB(Xext, XShapeCombineMask,
 350       if test -z "`echo $x_libs | grep "\-lXext" 2> /dev/null`"; then
 351            x_libs="-lXext $x_libs"
 352       fi
 353       AC_DEFINE(HAVE_SHAPE_EXT),
 354       ,
 355       $x_libs)
 356
 357 # Check for XConvertCase (X11R6 specific)
 358
 359 AC_CHECK_LIB(X11, XConvertCase,
 360       AC_DEFINE(HAVE_XCONVERTCASE),
 361       ,
 362       $x_libs)
 363
 364 # Check for XIM support.
 365
 366 AC_CHECK_LIB(X11, XUnregisterIMInstantiateCallback,
 367             : ,
 368             enable_xim_inst="no",
 369             $x_libs)
 370
 371 # On Solaris, calling XRegisterIMInstantiateCallback seems to
 372 # cause an immediate segfault, so we disable it, unless
 373 # the user specifically forces it to be on.
 374
 375 if test x$enable_xim_inst = xmaybe ; then
 376   case host in
 377         *-*-solaris*)
 378             enable_xim_inst="no"
 379             ;;
 380         *)
 381             enable_xim_inst="yes"
 382             ;;
 383   esac
 384 fi
 385
 386 if test "x$enable_xim" = "xyes"; then
 387   GTK_XIM_FLAGS="-DUSE_XIM"
 388   if test "x$enable_xim_inst" = "xyes"; then
 389     AC_DEFINE(USE_X11R6_XIM)
 390   fi
 391 fi
 392
 393 x_cflags="$X_CFLAGS"
 394 x_ldflags="$X_LDFLAGS $X_LIBS"
 395
 396 # set up things for XInput
 397
 398 if test "x$with_xinput" = "xgxi" || test "x$with_xinput" = "xyes"; then
 399   AC_DEFINE(XINPUT_GXI)
 400   xinput_progs=gxid
 401   x_libs="-lXi $x_libs"
 402 elif test "x$with_xinput" = "xxfree"; then
 403   AC_DEFINE(XINPUT_XFREE)
 404   x_libs="-lXi $x_libs"
 405 else
 406   AC_DEFINE(XINPUT_NONE)
 407 fi
 408
 409 AM_CONDITIONAL(XINPUT_GXI, test x$with_xinput = xgxi)
 410 AM_CONDITIONAL(XINPUT_XFREE, test x$with_xinput = xxfree)
 411
 412 CFLAGS="$saved_cflags"
 413 LDFLAGS="$saved_ldflags"
 414
 415 AC_SUBST(x_cflags)
 416 AC_SUBST(x_includes)
 417 AC_SUBST(x_ldflags)
 418 AC_SUBST(x_libs)
 419 AC_SUBST(xinput_progs)
 420
 421 if test "x$enable_shm" = "xyes"; then
 422   # Check for shared memory
 423   AC_CHECK_HEADER(sys/ipc.h, AC_DEFINE(HAVE_IPC_H), no_sys_ipc=yes)
 424   AC_CHECK_HEADER(sys/shm.h, AC_DEFINE(HAVE_SHM_H), no_sys_shm=yes)
 425
 426   # Check for the X shared memory extension header file
 427   AC_MSG_CHECKING(X11/extensions/XShm.h)
 428   if test "x$no_xext_lib" = "xyes"; then
 429     AC_MSG_RESULT(no)
 430     no_xshm=yes
 431   else
 432     if test -f "$x_includes/X11/extensions/XShm.h"; then
 433       AC_MSG_RESULT(yes)
 434       AC_DEFINE(HAVE_XSHM_H)
 435     else
 436       AC_MSG_RESULT(no)
 437       no_xshm=yes
 438     fi
 439   fi
 440 fi
 441
 442 # Check if X_LOCALE definition is necessary
 443
 444 AC_MSG_CHECKING(need -DX_LOCALE)
 445
 446 AC_TRY_RUN([
 447 #include <stdio.h>
 448 #include <locale.h>
 449
 450 int
 451 main ()
 452 {
 453   return setlocale (LC_ALL, "${with_locale}") == NULL;
 454 }],
 455 need_x_locale=no,
 456 need_x_locale=yes)
 457 AC_MSG_RESULT($need_x_locale)
 458
 459 if test $need_x_locale = yes; then
 460   GTK_LOCALE_CFLAGS="-DX_LOCALE"
 461 fi
 462
 463 # Checks for header files.
 464 AC_HEADER_STDC
 465
 466 # Checks for typedefs, structures, and compiler characteristics.
 467 AC_C_CONST
 468
 469 # Checks for library functions.
 470 AC_TYPE_SIGNAL
 471 AC_FUNC_MMAP
 472
 473 # Check if <sys/select.h> needs to be included for fd_set
 474 AC_MSG_CHECKING([for fd_set])
 475 AC_TRY_COMPILE([#include <sys/types.h>],
 476         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 477 if test $gtk_ok = yes; then
 478     AC_MSG_RESULT([yes, found in sys/types.h])
 479 else
 480     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 481     if test $gtk_ok = yes; then
 482         AC_DEFINE(HAVE_SYS_SELECT_H)
 483         AC_MSG_RESULT([yes, found in sys/select.h])
 484     else
 485         AC_DEFINE(NO_FD_SET)
 486         AC_MSG_RESULT(no)
 487     fi
 488 fi
 489
 490 # `widechar' tests for gdki18n.h
 491 AC_MSG_CHECKING(for wchar.h)
 492 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 493 if test $gdk_wchar_h = yes; then
 494    AC_DEFINE(HAVE_WCHAR_H,1,[Have wchar.h include file])
 495 fi
 496 AC_MSG_RESULT($gdk_wchar_h)
 497
 498 # Check for wctype.h (for iswalnum)
 499 AC_MSG_CHECKING(for wctype.h)
 500 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 501 if test $gdk_wctype_h = yes; then
 502    AC_DEFINE(HAVE_WCTYPE_H,1,[Have wctype.h include file])
 503 fi
 504 AC_MSG_RESULT($gdk_wctype_h)
 505
 506 # in Solaris 2.5, `iswalnum' is in -lw
 507 GDK_WLIBS=
 508 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 509
 510 oLIBS="$LIBS"
 511 LIBS="$LIBS $GDK_WLIBS"
 512 # The following is necessary for Linux libc-5.4.38
 513 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 514 AC_TRY_LINK([#include <stdlib.h>],[
 515 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 516 #  ifdef HAVE_WCTYPE_H
 517 #    include <wctype.h>
 518 #  else
 519 #    ifdef HAVE_WCHAR_H
 520 #      include <wchar.h>
 521 #    endif
 522 #  endif
 523 #else
 524 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 525 #endif
 526 iswalnum((wchar_t) 0);
 527 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 528 LIBS="$oLIBS"
 529
 530 if test $gdk_working_wctype = no; then
 531    AC_DEFINE(HAVE_BROKEN_WCTYPE,1,[Is the wctype implementation broken])
 532    GDK_WLIBS=
 533 fi
 534 AC_MSG_RESULT($gdk_working_wctype)
 535 AC_SUBST(GDK_WLIBS)
 536
 537 AC_SUBST(GTK_DEBUG_FLAGS)
 538 AC_SUBST(GTK_XIM_FLAGS)
 539 AC_SUBST(GTK_LOCALE_FLAGS)
 540
 541 AC_OUTPUT_COMMANDS([
 542
 543 ## Generate `gdk/gdkconfig.h' in two cases
 544 ## 1. `config.status' is run either explicitly, or via configure.
 545 ##     Esp. not when it is run in `Makefile' to generate makefiles and
 546 ##     config.h
 547 ## 2. CONFIG_OTHER is set explicitly
 548 ##
 549 ## Case 1 is difficult.  We know that `automake' sets one of
 550 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
 551 ## only when AM_CONFIG_HEADER is set, however.
 552
 553 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
 554   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
 555   CONFIG_OTHER=${CONFIG_OTHER:-gdk/gdkconfig.h}
 556 fi
 557 case "$CONFIG_OTHER" in
 558 *gdk/gdkconfig.h*)
 559         echo creating gdk/gdkconfig.h
 560         outfile=gdkconfig.h-tmp
 561         cat > $outfile <<\_______EOF
 562 /* gdkconfig.h
 563  *
 564  * This is a generated file.  Please modify `configure.in'
 565  */
 566
 567 #ifndef GDKCONFIG_H
 568 #define GDKCONFIG_H
 569
 570 #ifdef __cplusplus
 571 extern "C" {
 572 #endif /* __cplusplus */
 573
 574 _______EOF
 575
 576         cat >>$outfile <<_______EOF
 577 $gdk_windowing
 578 $gdk_wc
 579 _______EOF
 580
 581         cat >>$outfile <<_______EOF
 582
 583 #ifdef __cplusplus
 584 }
 585 #endif /* __cplusplus */
 586
 587 #endif /* GDKCONFIG_H */
 588 _______EOF
 589
 590
 591         if cmp -s $outfile gdk/gdkconfig.h; then
 592           echo gdk/gdkconfig.h is unchanged
 593           rm -f $outfile
 594         else
 595           mv $outfile gdk/gdkconfig.h
 596         fi ;;
 597 esac
 598 ],[
 599 # Currently we always use X11 on those systems where we run configure...
 600 gdk_windowing='
 601 #define GDK_WINDOWING_X11'
 602 if test x$gdk_wchar_h = xyes; then
 603   gdk_wc='
 604 #define GDK_HAVE_WCHAR_H 1'
 605 fi
 606 if test x$gdk_wctype_h = xyes; then
 607   gdk_wc="\$gdk_wc
 608 #define GDK_HAVE_WCTYPE_H 1"
 609 fi
 610 if test x$gdk_working_wctype = xno; then
 611   gdk_wc="\$gdk_wc
 612 #define GDK_HAVE_BROKEN_WCTYPE 1"
 613 fi
 614
 615
 616 ])
 617
 618 AC_OUTPUT([
 619 gtk+.spec
 620 docs/gtk-config.1
 621 Makefile
 622 gtk-config
 623 po/Makefile.in
 624 docs/Makefile
 625 gdk/Makefile
 626 gdk/x11/Makefile
 627 gtk/Makefile
 628 gtk/gtkfeatures.h
 629 gtk/gtkcompat.h
 630 ], [chmod +x gtk-config])