Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [0])
  13 m4_define([gtk_micro_version], [1])
  14 m4_define([gtk_interface_age], [1])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Define a string for the earliest version that this release has
  32 # backwards binary compatibility with for all interfaces a module
  33 # might. Unless we add module-only API with lower stability
  34 # guarantees, this should be unchanged until we break binary compat
  35 # for GTK+.
  36 #
  37 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  38 m4_define([gtk_binary_version], [3.0.0])
  39
  40 # required versions of other packages
  41 m4_define([glib_required_version], [2.28.0])
  42 m4_define([pango_required_version], [1.20])
  43 m4_define([atk_required_version], [1.30])
  44 m4_define([cairo_required_version], [1.10.0])
  45 m4_define([gdk_pixbuf_required_version], [2.22.0])
  46 m4_define([introspection_required_version], [0.10.1])
  47 GLIB_REQUIRED_VERSION=glib_required_version
  48 PANGO_REQUIRED_VERSION=pango_required_version
  49 ATK_REQUIRED_VERSION=atk_required_version
  50 CAIRO_REQUIRED_VERSION=cairo_required_version
  51 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  52 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  53
  54 AC_SUBST(GLIB_REQUIRED_VERSION)
  55 AC_SUBST(PANGO_REQUIRED_VERSION)
  56 AC_SUBST(ATK_REQUIRED_VERSION)
  57 AC_SUBST(CAIRO_REQUIRED_VERSION)
  58 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  59 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  60
  61 # Save this value here, since automake will set cflags later
  62 cflags_set=${CFLAGS+set}
  63
  64 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  65 AM_MAINTAINER_MODE([enable])
  66
  67 # Support silent build rules, requires at least automake-1.11. Disable
  68 # by either passing --disable-silent-rules to configure or passing V=1
  69 # to make
  70 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  71
  72 #
  73 # For each of the libraries we build, we define the following
  74 # substituted variables:
  75 #
  76 # foo_PACKAGES:     pkg-config packages this library requires
  77 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  78 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  79 # foo_DEP_LIBS:     All libraries this module requires
  80 # foo_DEP_CFLAGS:   All cflags this module requires
  81
  82
  83 GTK_MAJOR_VERSION=gtk_major_version
  84 GTK_MINOR_VERSION=gtk_minor_version
  85 GTK_MICRO_VERSION=gtk_micro_version
  86 GTK_INTERFACE_AGE=gtk_interface_age
  87 GTK_BINARY_AGE=gtk_binary_age
  88 GTK_VERSION=gtk_version
  89 GTK_API_VERSION=gtk_api_version
  90 GTK_BINARY_VERSION=gtk_binary_version
  91 AC_SUBST(GTK_MAJOR_VERSION)
  92 AC_SUBST(GTK_MINOR_VERSION)
  93 AC_SUBST(GTK_MICRO_VERSION)
  94 AC_SUBST(GTK_INTERFACE_AGE)
  95 AC_SUBST(GTK_BINARY_AGE)
  96 AC_SUBST(GTK_API_VERSION)
  97 AC_SUBST(GTK_VERSION)
  98 AC_SUBST(GTK_BINARY_VERSION)
  99
 100 # libtool versioning
 101 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 102 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 103 #LT_REVISION=$GTK_INTERFACE_AGE
 104 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 105 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 106
 107 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 108 m4_define([lt_revision], [gtk_interface_age])
 109 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 110 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 111 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 112 AC_SUBST(LT_VERSION_INFO)
 113 AC_SUBST(LT_CURRENT_MINUS_AGE)
 114
 115 m4_define([gail_lt_current],[0])
 116 m4_define([gail_lt_revision],[0])
 117 m4_define([gail_lt_age],[0])
 118 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 119 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 120 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 121 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 122
 123 # Checks for programs.
 124 AC_PROG_CC
 125 AC_PROG_CC_C_O
 126 AC_PROG_CC_STDC
 127 AC_PROG_INSTALL
 128 AC_PROG_MAKE_SET
 129
 130
 131 GETTEXT_PACKAGE=gtk30
 132 AC_SUBST(GETTEXT_PACKAGE)
 133 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 134                    [The prefix for our gettext translation domains.])
 135
 136 AC_CANONICAL_HOST
 137
 138 MATH_LIB=-lm
 139 AC_MSG_CHECKING([for native Win32])
 140 LIB_EXE_MACHINE_FLAG=X86
 141 EXE_MANIFEST_ARCHITECTURE=X86
 142 case "$host" in
 143   *-*-mingw*)
 144     os_win32=yes
 145     gio_can_sniff=no
 146     MATH_LIB=
 147     case "$host" in
 148     x86_64-*-*)
 149       LIB_EXE_MACHINE_FLAG=X64
 150       EXE_MANIFEST_ARCHITECTURE=AMD64
 151       ;;
 152     esac
 153     ;;
 154   *)
 155     os_win32=no
 156     ;;
 157 esac
 158 AC_MSG_RESULT([$os_win32])
 159
 160 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 161 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 162
 163 case $host in
 164   *-*-linux*)
 165     os_linux=yes
 166     ;;
 167 esac
 168
 169 dnl
 170 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 171 dnl We use this for an automated test for C++ header correctness.
 172 dnl
 173 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 174 AC_LANG_PUSH([C++])
 175
 176 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 177                                    [[class a { int b; } c;]])],
 178                   [],[CXX=])
 179 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 180
 181 gtk_save_cxxflags="$CXXFLAGS"
 182 CXXFLAGS="$CXXFLAGS -x objective-c++"
 183 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 184                                    [[]])],
 185                   [OBJC=yes],[OBJC=no])
 186 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 187 CXXFLAGS="$gtk_save_cxxflags"
 188 AC_LANG_POP([C++])
 189
 190 if test "$os_win32" = "yes"; then
 191   if test x$enable_static = xyes -o x$enable_static = x; then
 192     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 193     enable_static=no
 194   fi
 195   if test x$enable_shared = xno; then
 196     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 197   fi
 198   enable_shared=yes
 199 fi
 200
 201 dnl Initialize libtool
 202 LT_PREREQ([2.2.6])
 203 LT_INIT([disable-static win32-dll])
 204 # Create libtool early, because it's used in configure
 205 LT_OUTPUT
 206
 207 # Make sure we use 64-bit versions of various file stuff.
 208 AC_SYS_LARGEFILE
 209
 210 AM_PROG_AS
 211 AC_PATH_PROG(NM, nm, nm)
 212
 213 AC_MSG_CHECKING([for some Win32 platform])
 214 case "$host" in
 215   *-*-mingw*|*-*-cygwin*)
 216     platform_win32=yes
 217     ;;
 218   *)
 219     platform_win32=no
 220     ;;
 221 esac
 222 AC_MSG_RESULT([$platform_win32])
 223 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 224
 225 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 226 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 227 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 228
 229 if test "$os_win32" = "yes"; then
 230   AC_CHECK_TOOL(WINDRES, windres, no)
 231   if test "$WINDRES" = no; then
 232     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 233   fi
 234   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 235 fi
 236 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 237
 238 m4_define([debug_default],
 239           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 240
 241 dnl declare --enable-* args and collect ac_help strings
 242 AC_ARG_ENABLE(debug,
 243               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 244                               [turn on debugging @<:@default=debug_default@:>@])],,
 245               [enable_debug=debug_default])
 246
 247 AC_ARG_ENABLE(rebuilds,
 248               [AS_HELP_STRING([--disable-rebuilds],
 249                               [disable all source autogeneration rules])],,
 250               [enable_rebuilds=yes])
 251
 252 AC_ARG_ENABLE(gtk2-dependency,
 253               [AS_HELP_STRING([--enable-gtk2-dependency],
 254                               [Do not build gtk-update-icon-cache and other shared tools])],,
 255               [enable_gtk2_dependency=no])
 256
 257 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 258
 259 AC_ARG_ENABLE(xkb,
 260               [AS_HELP_STRING([--enable-xkb],
 261                               [support XKB extension [default=maybe]])],,
 262               [enable_xkb="maybe"])
 263 AC_ARG_ENABLE(xinerama,
 264               [AS_HELP_STRING([--enable-xinerama],
 265                               [support Xinerama extension if available [default=maybe]])],,
 266               [enable_xinerama="maybe"])
 267 AC_ARG_ENABLE(xinput,
 268               [AS_HELP_STRING([--enable-xinput],
 269                               [support XInput extension if available [default=yes]])],,
 270               [enable_xinput="maybe"])
 271 AC_ARG_ENABLE(xrandr,
 272               [AS_HELP_STRING([--enable-xrandr],
 273                               [support XRandR extension if available [default=maybe]])],,
 274               [enable_xrandr="maybe"])
 275 AC_ARG_ENABLE(xfixes,
 276               [AS_HELP_STRING([--enable-xfixes],
 277                               [support XFixes extension if available [default=maybe]])],,
 278               [enable_xfixes="maybe"])
 279 AC_ARG_ENABLE(xcomposite,
 280               [AS_HELP_STRING([--enable-xcomposite],
 281                               [support X Composite extension if available [default=maybe]])],,
 282               [enable_xcomposite="maybe"])
 283 AC_ARG_ENABLE(xdamage,
 284               [AS_HELP_STRING([--enable-xdamage],
 285                               [support X Damage extension if available [default=maybe]])],,
 286               [enable_xdamage="maybe"])
 287
 288 AC_ARG_ENABLE(x11-backend,
 289               [AS_HELP_STRING([--enable-x11-backend],
 290                               [enable the X11 gdk backend])],
 291                               [backend_set=yes])
 292 AC_ARG_ENABLE(win32-backend,
 293               [AS_HELP_STRING([--enable-win32-backend],
 294                               [enable the Win32 gdk backend])],
 295                               [backend_set=yes])
 296 AC_ARG_ENABLE(quartz-backend,
 297               [AS_HELP_STRING([--enable-quartz-backend],
 298                               [enable the quartz gdk backend])],
 299                               [backend_set=yes])
 300
 301 if test -z "$backend_set"; then
 302   if test "$platform_win32" = yes; then
 303     enable_win32_backend=yes
 304   else
 305     enable_x11_backend=yes
 306   fi
 307 fi
 308
 309 cairo_backends=
 310 backend_immodules=
 311 GDK_BACKENDS=
 312 GDK_EXTRA_LIBS=
 313 GDK_EXTRA_CFLAGS=
 314 GDK_WINDOWING=
 315 GIO_PACKAGE=gio-2.0
 316 PANGO_PACKAGES="pango pangocairo"
 317
 318 if test "x$enable_x11_backend" == xyes; then
 319   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 320   # backend names are identical.
 321   cairo_backends="$cairo_backends cairo-xlib"
 322   GDK_BACKENDS="$GDK_BACKENDS x11"
 323   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 324   # gdkapplaunchcontext-x11.c
 325   GIO_PACKAGE=gio-unix-2.0
 326   backend_immodules="$backend_immodules,xim"
 327   GDK_WINDOWING="$GDK_WINDOWING
 328 #define GDK_WINDOWING_X11"
 329 fi
 330
 331 if test "x$enable_win32_backend" == xyes; then
 332   cairo_backends="$cairo_backends cairo-win32"
 333   GDK_BACKENDS="$GDK_BACKENDS win32"
 334   backend_immodules="$backend_immodules,ime"
 335   GDK_WINDOWING="$GDK_WINDOWING
 336 #define GDK_WINDOWING_WIN32"
 337   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 338   AM_CONDITIONAL(USE_WIN32, true)
 339   PANGO_PACKAGES="pangowin32 pangocairo"
 340 else
 341   AM_CONDITIONAL(USE_WIN32, false)
 342 fi
 343
 344 if test "x$enable_quartz_backend" == xyes; then
 345   cairo_backends="$cairo_backends cairo-quartz"
 346   GDK_BACKENDS="$GDK_BACKENDS quartz"
 347   GDK_WINDOWING="$GDK_WINDOWING
 348 #define GDK_WINDOWING_QUARTZ"
 349   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 350   AM_CONDITIONAL(USE_QUARTZ, true)
 351 else
 352   AM_CONDITIONAL(USE_QUARTZ, false)
 353 fi
 354
 355 # strip leading space
 356 GDK_BACKENDS=${GDK_BACKENDS/# }
 357
 358 AC_SUBST(GDK_BACKENDS)
 359
 360 if test -z "$GDK_BACKENDS"; then
 361   AC_MSG_ERROR([No GDK backends selected.])
 362 fi
 363
 364 if test "x$enable_debug" = "xyes"; then
 365   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 366   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 367 else
 368   if test "x$enable_debug" = "xno"; then
 369     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 370   else
 371     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 372   fi
 373 fi
 374
 375
 376 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 377                    [Define if debugging is enabled])
 378
 379
 380 # Build time sanity check...
 381 AM_SANITY_CHECK
 382
 383 changequote(,)dnl
 384 if test "x$GCC" = "xyes"; then
 385   case " $CFLAGS " in
 386   *[\ \ ]-Wall[\ \      ]*) ;;
 387   *) CFLAGS="$CFLAGS -Wall" ;;
 388   esac
 389
 390   if test "x$enable_ansi" = "xyes"; then
 391     case " $CFLAGS " in
 392     *[\ \       ]-ansi[\ \      ]*) ;;
 393     *) CFLAGS="$CFLAGS -ansi" ;;
 394     esac
 395
 396     case " $CFLAGS " in
 397     *[\ \       ]-pedantic[\ \  ]*) ;;
 398     *) CFLAGS="$CFLAGS -pedantic" ;;
 399     esac
 400   fi
 401 fi
 402 changequote([,])dnl
 403
 404 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 405
 406 # Ensure MSVC-compatible struct packing convention is used when
 407 # compiling for Win32 with gcc.
 408 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 409 # gcc2 uses "-fnative-struct".
 410 if test x"$os_win32" = xyes; then
 411   if test x"$GCC" = xyes; then
 412     msnative_struct=''
 413     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 414     if test -z "$ac_cv_prog_CC"; then
 415       our_gcc="$CC"
 416     else
 417       our_gcc="$ac_cv_prog_CC"
 418     fi
 419     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 420       2.)
 421         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 422           msnative_struct='-fnative-struct'
 423         fi
 424         ;;
 425       *)
 426         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 427           msnative_struct='-mms-bitfields'
 428         fi
 429         ;;
 430     esac
 431     if test x"$msnative_struct" = x ; then
 432       AC_MSG_RESULT([no way])
 433       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 434     else
 435       CFLAGS="$CFLAGS $msnative_struct"
 436       AC_MSG_RESULT([${msnative_struct}])
 437     fi
 438   fi
 439 fi
 440
 441 ## Initial sanity check, done here so that users get told they
 442 ## have the wrong dependencies as early in the process as possible.
 443 ## Later on we actually use the cflags/libs from separate pkg-config
 444 ## calls. Oh, also the later pkg-config calls don't include
 445 ## the version requirements since those make the module lists
 446 ## annoying to construct
 447 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 448   [glib-2.0 >= glib_required_version dnl
 449    atk >= atk_required_version dnl
 450    pango >= pango_required_version dnl
 451    cairo >= cairo_required_version dnl
 452    cairo-gobject >= cairo_required_version dnl
 453    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 454
 455 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 456
 457 if test "$os_win32" != yes; then
 458     # libtool option to control which symbols are exported
 459     # right now, symbols starting with _ are not exported
 460     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 461 else
 462     # We currently use .def files on Windows (for gdk and gtk)
 463     LIBTOOL_EXPORT_OPTIONS=
 464 fi
 465 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 466
 467 dnl ******************************************************
 468 dnl * See whether to include shared library dependencies *
 469 dnl ******************************************************
 470
 471 AC_ARG_ENABLE(explicit-deps,
 472               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 473                               [use explicit dependencies in .pc files [default=auto]])],,
 474               [enable_explicit_deps=auto])
 475
 476 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 477 case $enable_explicit_deps in
 478   auto)
 479     export SED
 480     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 481     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 482       enable_explicit_deps=yes
 483     else
 484       enable_explicit_deps=no
 485     fi
 486   ;;
 487   yes|no)
 488   ;;
 489   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 490   ;;
 491 esac
 492 AC_MSG_RESULT($enable_explicit_deps)
 493
 494 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 495
 496 # define a MAINT-like variable REBUILD which is set if Perl
 497 # and awk are found, so autogenerated sources can be rebuilt
 498
 499 AC_PATH_PROGS(PERL, perl5 perl)
 500
 501 # We would like indent, but don't require it.
 502 AC_CHECK_PROG(INDENT, indent, indent)
 503
 504 REBUILD=\#
 505 if test "x$enable_rebuilds" = "xyes" && \
 506      test -n "$PERL" && \
 507      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 508   REBUILD=
 509 fi
 510 AC_SUBST(REBUILD)
 511
 512 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 513 AC_CHECK_FUNCS(localtime_r)
 514
 515 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 516 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 517 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 518                                 [[char c;
 519                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 520                [gtk_ok=yes], [gtk_ok=no])
 521 AC_MSG_RESULT($gtk_ok)
 522 if test "$gtk_ok" = "yes"; then
 523   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 524             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 525 fi
 526
 527 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 528 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 529 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 530                                 [[char c;
 531                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 532                [gtk_ok=yes], [gtk_ok=no])
 533 AC_MSG_RESULT($gtk_ok)
 534 if test "$gtk_ok" = "yes"; then
 535   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 536             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 537 fi
 538
 539 # _NL_PAPER_HEIGHT is an enum and not a define
 540 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 541 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 542                                 [[char c;
 543                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 544                [gtk_ok=yes], [gtk_ok=no])
 545 AC_MSG_RESULT($gtk_ok)
 546 if test "$gtk_ok" = "yes"; then
 547   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 548             [Define if _NL_PAPER_HEIGHT is available])
 549 fi
 550
 551 # _NL_PAPER_WIDTH is an enum and not a define
 552 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 553 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 554                                 [[char c;
 555                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 556                [gtk_ok=yes], [gtk_ok=no])
 557 AC_MSG_RESULT($gtk_ok)
 558 if test "$gtk_ok" = "yes"; then
 559   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 560             [Define if _NL_PAPER_WIDTH is available])
 561 fi
 562
 563 # i18n stuff
 564 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 565 AM_GLIB_GNU_GETTEXT
 566 LIBS="$LIBS $INTLLIBS"
 567 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 568         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 569       esac])
 570
 571 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 572 dnl po-properties/POTFILES during configure; see GNOME #573515.
 573 dnl
 574 dnl Generate list of files to be processed by xgettext which will
 575 dnl be included in po-properties/Makefile.
 576 test -d po-properties || mkdir po-properties
 577 if test "x$srcdir" != "x."; then
 578   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 579     popropsrcprefix="$srcdir/"
 580   else
 581     popropsrcprefix="../$srcdir/"
 582   fi
 583 else
 584   popropsrcprefix="../"
 585 fi
 586 rm -f po-properties/POTFILES
 587 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 588 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 589 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 590
 591 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 592
 593 dnl The DU4 header files don't provide library prototypes unless
 594 dnl -std1 is given to the native cc.
 595 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 596
 597 gtk_save_LIBS=$LIBS
 598 LIBS="$LIBS -lm"
 599 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 600                                 int main (void) { return (log(1) != log(1.)); }]])],
 601               [AC_MSG_RESULT(none needed)],
 602               [gtk_save_CFLAGS="$CFLAGS"
 603                CFLAGS="$CFLAGS -std1"
 604                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 605                                                int main (void) { return (log(1) != log(1.)); }]])],
 606                              [AC_MSG_RESULT(-std1)],
 607                              [AC_MSG_RESULT()
 608                               CFLAGS="$gtk_save_CFLAGS"
 609                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 610                              [true])],
 611               [AC_MSG_RESULT(none needed)])
 612
 613 LIBS=$gtk_save_LIBS
 614
 615 AC_MSG_CHECKING(for the BeOS)
 616 case $host in
 617   *-*-beos*)
 618     AC_MSG_RESULT(yes)
 619     MATH_LIB=
 620   ;;
 621   *)
 622     AC_MSG_RESULT(no)
 623   ;;
 624 esac
 625
 626 AC_SUBST(MATH_LIB)
 627 #
 628 # see bug 162979
 629 #
 630 AC_MSG_CHECKING(for HP-UX)
 631 case $host_os in
 632   hpux9* | hpux10* | hpux11*)
 633     AC_MSG_RESULT(yes)
 634     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 635   ;;
 636   *)
 637     AC_MSG_RESULT(no)
 638   ;;
 639 esac
 640
 641 #
 642 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 643 #
 644
 645 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 646
 647 AM_PATH_GLIB_2_0(glib_required_version, :,
 648   AC_MSG_ERROR([
 649 *** GLIB glib_required_version or better is required. The latest version of
 650 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 651   gobject gmodule-no-export gthread)
 652
 653 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 654 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 655 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 656 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 657   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 658 fi
 659
 660 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 661
 662
 663 dnl
 664 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 665 dnl
 666 gtk_save_LIBS=$LIBS
 667 LIBS="$LIBS $GLIB_LIBS"
 668 AC_CHECK_FUNCS(bind_textdomain_codeset)
 669 LIBS=$gtk_save_LIBS
 670
 671 AC_CHECK_HEADERS(pwd.h,
 672                  AC_DEFINE(HAVE_PWD_H, 1,
 673                            [Define to 1 if pwd.h is available]))
 674 AC_CHECK_HEADERS(sys/time.h,
 675                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 676                            [Define to 1 if time.h is available]))
 677 AC_CHECK_HEADERS(unistd.h,
 678                  AC_DEFINE(HAVE_UNISTD_H, 1,
 679                            [Define to 1 if unistd.h is available]))
 680 AC_CHECK_HEADERS(ftw.h,
 681                  AC_DEFINE(HAVE_FTW_H, 1,
 682                            [Define to 1 if ftw.h is available]))
 683
 684 AC_MSG_CHECKING([for GNU ftw extensions])
 685 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 686                                      #define _GNU_SOURCE
 687                                      #include <ftw.h>]],
 688                                    [[int flags = FTW_ACTIONRETVAL;]])],
 689                   [gtk_ok=yes],[gtk_ok=no])
 690 if test $gtk_ok = yes; then
 691     AC_MSG_RESULT([yes])
 692     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 693 else
 694     AC_MSG_RESULT([no])
 695 fi
 696
 697 saved_cflags="$CFLAGS"
 698 saved_ldflags="$LDFLAGS"
 699
 700
 701 # Checks for library functions.
 702 AC_FUNC_MMAP
 703
 704 AC_CHECK_FUNCS(mallinfo)
 705 AC_CHECK_FUNCS(getresuid)
 706 AC_TYPE_UID_T
 707
 708 # Check if <sys/select.h> needs to be included for fd_set
 709 AC_MSG_CHECKING([for fd_set])
 710 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 711                                    [[fd_set readMask, writeMask;]])],
 712                   [gtk_ok=yes],[gtk_ok=no])
 713 if test $gtk_ok = yes; then
 714     AC_MSG_RESULT([yes, found in sys/types.h])
 715 else
 716     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 717     if test $gtk_ok = yes; then
 718         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 719                   [Define to 1 if sys/select.h is available])
 720         AC_MSG_RESULT([yes, found in sys/select.h])
 721     else
 722         AC_DEFINE(NO_FD_SET, 1,
 723                   [Define to 1 if fd_set is not available])
 724         AC_MSG_RESULT(no)
 725     fi
 726 fi
 727
 728 # Check for uxtheme.h (for MS-Windows Engine)
 729 AC_MSG_CHECKING(for uxtheme.h)
 730 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 731 if test $gtk_uxtheme_h = yes; then
 732    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 733 fi
 734 AC_MSG_RESULT($gtk_uxtheme_h)
 735
 736 # Checks for gdkspawn
 737 AC_CHECK_HEADERS(crt_externs.h)
 738 AC_CHECK_FUNCS(_NSGetEnviron)
 739
 740 AC_MSG_CHECKING(whether to build dynamic modules)
 741
 742 AC_ARG_ENABLE(modules,
 743               [AS_HELP_STRING([--disable-modules],
 744                               [disable dynamic module loading])])
 745
 746 dynworks=false
 747 build_dynamic_modules=no
 748 deps=
 749 if test x$enable_modules = xno; then
 750     AC_MSG_RESULT(no)
 751 else
 752     AC_MSG_RESULT(yes)
 753     AC_MSG_CHECKING(whether dynamic modules work)
 754     ## for loop is to strip newline
 755     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 756     for I in $tmp; do
 757         dynworks=$I
 758     done
 759
 760     dnl Now we check to see if our libtool supports shared lib deps
 761     dnl (in a rather ugly way even)
 762     if $dynworks; then
 763         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 764         module_deplibs_check=`$module_libtool_config | \
 765             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 766             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 767         if test "x$module_deplibs_check" = "xnone" || \
 768            test "x$module_deplibs_check" = "xunknown" || \
 769            test "x$module_deplibs_check" = "x"; then
 770             dynworks=false
 771         fi
 772     fi
 773
 774     if $dynworks; then
 775         build_dynamic_modules=yes
 776         AC_DEFINE(USE_GMODULE, 1,
 777                   [Define to 1 if gmodule works and should be used])
 778         AC_MSG_RESULT(yes)
 779     else
 780         build_dynamic_modules=no
 781         AC_MSG_RESULT(no)
 782     fi
 783 fi
 784
 785 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 786
 787 #
 788 # Allow building some or all immodules included
 789 #
 790 AC_MSG_CHECKING(immodules to build)
 791
 792 AC_ARG_WITH(included_immodules,
 793             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 794                             [build the specified input methods into gtk])])
 795
 796 if $dynworks; then
 797    :
 798 else
 799    ## if the option was specified, leave it; otherwise disable included immodules
 800    if test x$with_included_immodules = xno; then
 801            with_included_immodules=yes
 802    fi
 803 fi
 804
 805 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 806
 807 included_immodules=""
 808 # If the switch specified without listing any specific ones, include all
 809 if test "x$with_included_immodules" = xyes ; then
 810   included_immodules="$all_immodules"
 811 else
 812   included_immodules="$with_included_immodules"
 813 fi
 814
 815 AC_MSG_RESULT($included_immodules)
 816 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 817
 818 INCLUDED_IMMODULE_OBJ=
 819 INCLUDED_IMMODULE_DEFINE=
 820
 821 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 822 for immodule in $included_immodules; do
 823  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 824  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 825    :
 826  else
 827    AC_MSG_ERROR([the specified input method $immodule does not exist])
 828  fi
 829
 830  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 831  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 832  eval INCLUDE_$immodule_underscores=yes
 833 done
 834 IFS="$gtk_save_ifs"
 835 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 836 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 837
 838 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 839 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 840 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 841 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 842 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 843 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 844 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 845 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 846 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 847 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 848 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 849 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 850
 851 # Checks to see whether we should include mediaLib
 852 # support.
 853 #
 854 AC_CHECK_HEADER(sys/systeminfo.h,
 855                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 856                           [Define to 1 if sys/systeminfo.h is available]))
 857 AC_CHECK_HEADER(sys/sysinfo.h,
 858                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 859                           [Define to 1 if sys/sysinfo.h is available]))
 860
 861 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 862
 863 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 864
 865 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 866   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 867   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 868     REBUILD_PNGS=#
 869   fi
 870 fi
 871
 872 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 873
 874 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 875
 876 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 877    test "x$REBUILD_PNGS" = "x#" ; then
 878      AC_MSG_ERROR([
 879 *** gtkbuiltincache.h is not in the tree, and cannot be built
 880 *** because you don't have libpng, or (when cross-compiling) you
 881 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 882 fi
 883
 884 ########################################
 885 # Windowing system checks
 886 ########################################
 887
 888 # GTK+ uses some X calls, so needs to link against X directly
 889 GTK_DEP_PACKAGES_FOR_X=
 890 GTK_DEP_LIBS_FOR_X=
 891 X_EXTENSIONS=
 892
 893 if test "x$enable_x11_backend" == xyes; then
 894   X_PACKAGES=fontconfig
 895
 896   #
 897   # We use fontconfig very peripherally when decoding the default
 898   # settings.
 899   #
 900   if $PKG_CONFIG --exists fontconfig; then : ; else
 901     AC_MSG_ERROR([
 902 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 903   fi
 904
 905   #
 906   # Check for basic X packages; we use pkg-config if available
 907   #
 908   if $PKG_CONFIG --exists x11 xext; then
 909     have_base_x_pc=true
 910     X_PACKAGES="$X_PACKAGES x11 xext"
 911     x_libs="`$PKG_CONFIG --libs x11 xext`"
 912     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 913
 914     # Strip out any .la files that pkg-config might give us (this happens
 915     # with -uninstalled.pc files)
 916     x_libs_for_checks=
 917     for I in $x_libs ; do
 918       case $I in
 919         *.la) ;;
 920         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 921       esac
 922     done
 923
 924     GTK_PACKAGES_FOR_X="x11"
 925   else
 926     have_base_x_pc=false
 927     AC_PATH_XTRA
 928     if test x$no_x = xyes ; then
 929       AC_MSG_ERROR([X development libraries not found])
 930     fi
 931
 932     x_cflags="$X_CFLAGS"
 933     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 934
 935     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 936   fi
 937
 938   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 939   x_extra_libs=
 940
 941   gtk_save_cppflags="$CPPFLAGS"
 942   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 943
 944   gtk_save_LIBS=$LIBS
 945   LIBS="$x_libs_for_checks $LIBS"
 946
 947   # Sanity check for the X11 and Xext libraries. While everything we need from
 948   # Xext is optional, the chances a system has *none* of these things is so
 949   # small that we just unconditionally require it.
 950   AC_CHECK_FUNC(XOpenDisplay, :,
 951                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 952   AC_CHECK_FUNC(XextFindDisplay, :,
 953                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 954
 955   # Check for xReply
 956
 957   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 958   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 959                                      [[xReply *rep;]])],
 960                     [AC_MSG_RESULT([no])],
 961                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 962                                                           #include <X11/Xlibint.h>]],
 963                                                         [[xReply *rep;]])],
 964                                        [AC_MSG_RESULT([yes])
 965                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 966                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
 967                                        [AC_MSG_RESULT([unknown])
 968                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 969
 970   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 971
 972   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 973
 974   # Generic X11R6 check needed for XIM support; we could
 975   # probably use this to replace the above, but we'll
 976   # leave the separate checks for XConvertCase and XInternAtoms
 977   # for clarity
 978
 979   have_x11r6=false
 980   AC_CHECK_FUNC(XAddConnectionWatch,
 981       have_x11r6=true)
 982
 983   if $have_x11r6; then
 984     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
 985   fi
 986   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
 987
 988   # Check for XKB support.
 989
 990   if test "x$enable_xkb" = "xyes"; then
 991         AC_CHECK_FUNC(XkbQueryExtension,
 992                       X_EXTENSIONS="$X_EXTENSIONS XKB"
 993                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
 994                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
 995   elif test "x$enable_xkb" = "xmaybe"; then
 996         AC_CHECK_FUNC(XkbQueryExtension,
 997                       X_EXTENSIONS="$X_EXTENSIONS XKB"
 998                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
 999   else
1000         AC_MSG_WARN(XKB support explicitly disabled)
1001   fi
1002
1003   # Check for shaped window extension
1004
1005   AC_CHECK_FUNC(XShapeCombineMask, :,
1006      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1007
1008   # X SYNC check
1009   gtk_save_CFLAGS="$CFLAGS"
1010   CFLAGS="$CFLAGS $x_cflags"
1011
1012   AC_CHECK_FUNC(XSyncQueryExtension,
1013       [AC_CHECK_HEADER(X11/extensions/sync.h,
1014           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1015           :, [#include <X11/Xlib.h>])])
1016
1017   CFLAGS="$gtk_save_CFLAGS"
1018
1019   if test "x$enable_xinerama" != "xno"; then
1020     # Check for Xinerama extension (Solaris impl or Xfree impl)
1021     have_xfree_xinerama=false
1022     have_solaris_xinerama=false
1023
1024     gtk_save_cppflags="$CPPFLAGS"
1025     CPPFLAGS="$CPPFLAGS $x_cflags"
1026
1027     # Check for XFree
1028     AC_MSG_CHECKING(for Xinerama packages)
1029
1030     if $PKG_CONFIG --exists xinerama ; then
1031        AC_MSG_RESULT(yes)
1032        have_xfree_xinerama=true
1033        X_PACKAGES="$X_PACKAGES xinerama"
1034     else
1035        AC_MSG_RESULT(no)
1036        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1037            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1038            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1039            have_xfree_xinerama=true], :,
1040            [#include <X11/Xlib.h>])])
1041     fi
1042
1043     if $have_xfree_xinerama ; then
1044       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1045       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1046                 [Define to 1 if XFree Xinerama is available])
1047       AC_DEFINE(HAVE_XINERAMA, 1,
1048                 [Define to 1 is Xinerama is available])
1049     else
1050       case "$host" in
1051         *-*-solaris*)
1052             # Check for solaris
1053             AC_MSG_CHECKING(for Xinerama support on Solaris)
1054
1055             have_solaris_xinerama=false
1056             AC_CHECK_FUNC(XineramaGetInfo,
1057                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1058                     [have_solaris_xinerama=true], :,
1059                     [#include <X11/Xlib.h>])])
1060
1061             if $have_solaris_xinerama ; then
1062               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1063               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1064                         [Define to 1 if solaris xinerama is available])
1065               AC_DEFINE(HAVE_XINERAMA, 1,
1066                         [Define to 1 if xinerama is available])
1067               AC_MSG_RESULT(yes)
1068             else
1069               AC_MSG_RESULT(no)
1070             fi
1071             ;;
1072         *)
1073             ;;
1074       esac
1075     fi
1076   fi
1077   if test "x$enable_xinerama" = "xyes" ; then
1078     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1079       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1080     fi
1081   fi
1082
1083   # set up things for XInput
1084   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1085     have_xinput=yes
1086
1087     AC_DEFINE(XINPUT_XFREE, 1,
1088               [Define to 1 if XFree XInput should be used])
1089
1090     X_PACKAGES="$X_PACKAGES xi"
1091
1092     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1093                     have_xinput2=yes
1094                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1095                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]),
1096                     X_EXTENSIONS="$X_EXTENSIONS XInput")
1097
1098   else
1099     AC_DEFINE(XINPUT_NONE, 1,
1100               [Define to 1 if no XInput should be used])
1101   fi
1102
1103   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1104   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1105
1106   if test "x$enable_xinput" = "xyes" ; then
1107     if test "x$have_xinput" != "xyes" -a "x$have_xinput2" != "xyes" ; then
1108       AC_MSG_ERROR([*** XInput extension not found. Check 'config.log' for more details.])
1109     fi
1110   fi
1111
1112   # Check for the RANDR extension
1113   if test x"$enable_xrandr" != xno; then
1114     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1115       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1116
1117       X_PACKAGES="$X_PACKAGES xrandr"
1118       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1119     elif test x"$enable_xrandr" = xyes; then
1120       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1121     fi
1122   fi
1123
1124   # Checks for Xcursor library
1125
1126   if $PKG_CONFIG --exists xcursor ; then
1127     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1128
1129     X_PACKAGES="$X_PACKAGES xcursor"
1130   fi
1131
1132   # Checks for XFixes extension
1133
1134   if test x"$enable_xfixes" != xno; then
1135     if $PKG_CONFIG --exists xfixes ; then
1136       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1137
1138       X_PACKAGES="$X_PACKAGES xfixes"
1139       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1140       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1141     elif test x"$enable_xfixes" = xyes; then
1142       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1143     fi
1144   fi
1145
1146   # Checks for Xcomposite extension
1147
1148   if test x"$enable_xcomposite" != xno; then
1149     if $PKG_CONFIG --exists xcomposite ; then
1150       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1151
1152       X_PACKAGES="$X_PACKAGES xcomposite"
1153       X_EXTENSIONS="$X_EXTENSIONS Composite"
1154       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1155     elif test x"$enable_xcomposite" = xyes; then
1156       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1157     fi
1158   fi
1159
1160   # Checks for Xdamage extension
1161
1162   if test x"$enable_xdamage" != xno; then
1163     if $PKG_CONFIG --exists xdamage ; then
1164       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1165
1166       X_PACKAGES="$X_PACKAGES xdamage"
1167       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1168       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1169     elif test x"$enable_xdamage" = xyes; then
1170       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1171     fi
1172   fi
1173
1174   if $have_base_x_pc ; then
1175     GDK_EXTRA_LIBS="$x_extra_libs"
1176   else
1177     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1178   fi
1179
1180   CPPFLAGS="$gtk_save_cppflags"
1181   LIBS="$gtk_save_libs"
1182
1183   AM_CONDITIONAL(USE_X11, true)
1184
1185   # strip leading space
1186   X_EXTENSIONS=${X_EXTENSIONS/# }
1187
1188 else
1189   XPACKAGES=
1190
1191   AM_CONDITIONAL(XINPUT_XFREE, false)
1192   AM_CONDITIONAL(XINPUT_2, false)
1193   AM_CONDITIONAL(USE_X11, false)
1194   AM_CONDITIONAL(HAVE_X11R6, false)
1195 fi
1196
1197 # Check for Pango flags
1198
1199 AC_MSG_CHECKING(Pango flags)
1200 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1201         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1202         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1203
1204         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1205 else
1206         AC_MSG_ERROR([
1207 *** Pango not found. Pango built with Cairo support is required
1208 *** to build GTK+. See http://www.pango.org for Pango information.
1209 ])
1210 fi
1211
1212 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1213
1214 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1215         :
1216 else
1217         gtk_save_LIBS="$LIBS"
1218         LIBS="$PANGO_LIBS $LIBS"
1219         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1220 *** Can't link to Pango. Pango is required to build
1221 *** GTK+. For more information see http://www.pango.org]))
1222         LIBS="$gtk_save_LIBS"
1223 fi
1224
1225 CFLAGS="$saved_cflags"
1226 LDFLAGS="$saved_ldflags"
1227
1228 GDK_PACKAGES="$PANGO_PACKAGES $GIO_PACKAGE $X_PACKAGES gdk-pixbuf-2.0 $cairo_backends cairo-gobject"
1229
1230 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1231 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1232 #
1233 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1234 # into the pkg-config files
1235 #
1236 if test $enable_explicit_deps != yes ; then
1237   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo-gobject"
1238   GDK_EXTRA_LIBS=
1239 fi
1240
1241 AC_SUBST(GDK_PACKAGES)
1242 AC_SUBST(GDK_EXTRA_LIBS)
1243 AC_SUBST(GDK_EXTRA_CFLAGS)
1244 AC_SUBST(GDK_DEP_LIBS)
1245 AC_SUBST(GDK_DEP_CFLAGS)
1246
1247
1248 ########################################
1249 # Check for Accessibility Toolkit flags
1250 ########################################
1251
1252 ATK_PACKAGES=atk
1253 AC_MSG_CHECKING(ATK flags)
1254 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1255         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1256         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1257
1258         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1259 else
1260         AC_MSG_ERROR([
1261 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1262 *** to build GTK+.
1263 ])
1264 fi
1265
1266 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1267         :
1268 else
1269         gtk_save_LIBS="$LIBS"
1270         LIBS="$ATK_LIBS $LIBS"
1271         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1272                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1273                 *** to build GTK+]))
1274         LIBS="$gtk_save_LIBS"
1275 fi
1276
1277 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1278 if test "x$enable_x11_backend" == xyes; then
1279   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1280 fi
1281 GTK_EXTRA_LIBS=
1282 GTK_EXTRA_CFLAGS=
1283 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1284 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1285
1286 if test x"$os_win32" = xyes; then
1287   GTK_EXTRA_CFLAGS="$msnative_struct"
1288 fi
1289
1290 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1291 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1292 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1293 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1294
1295 AC_SUBST(GTK_PACKAGES)
1296 AC_SUBST(GTK_EXTRA_LIBS)
1297 AC_SUBST(GTK_EXTRA_CFLAGS)
1298 AC_SUBST(GTK_DEP_LIBS)
1299 AC_SUBST(GTK_DEP_CFLAGS)
1300
1301 AC_SUBST(GLIB_PREFIX)
1302 AC_SUBST(ATK_PREFIX)
1303 AC_SUBST(PANGO_PREFIX)
1304 AC_SUBST(CAIRO_PREFIX)
1305
1306 AC_SUBST(GTK_DEBUG_FLAGS)
1307 AC_SUBST(GTK_XIM_FLAGS)
1308
1309 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1310 AC_SUBST(GDK_PIXBUF_LIBS)
1311
1312 ########################
1313 # Checks needed for gail
1314 ########################
1315
1316 old_LIBS="$LIBS"
1317 dnl Checks for inet libraries:
1318 AC_SEARCH_LIBS(gethostent, nsl)
1319 AC_SEARCH_LIBS(setsockopt, socket)
1320 AC_SEARCH_LIBS(connect, inet)
1321
1322 dnl check for the sockaddr_un.sun_len member
1323 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1324                 [struct_sockaddr_un_sun_len=true],
1325                 [struct_sockaddr_un_suin_len=false],
1326                 [#include <sys/types.h>
1327                  #include <sys/un.h>]
1328                 )
1329 case $struct_sockaddr_un_sun_len in
1330         true)
1331                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1332                                    [Have the sockaddr_un.sun_len member])
1333                 ;;
1334         *)
1335                 ;;
1336 esac
1337
1338 GAIL_INET_LIBS="$LIBS"
1339 AC_SUBST([GAIL_INET_LIBS])
1340
1341 LIBS="$old_LIBS"
1342
1343 ################################################################
1344 # Printing system checks
1345 ################################################################
1346
1347 PRINT_BACKENDS="file lpr"
1348
1349 AC_ARG_ENABLE(cups,
1350               [AS_HELP_STRING([--disable-cups],
1351                               [disable cups print backend])],,
1352               [enable_cups=auto])
1353
1354 if test "x$enable_cups" = "xno"; then
1355   AM_CONDITIONAL(HAVE_CUPS, false)
1356 else
1357   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1358   if test "x$CUPS_CONFIG" = "xno"; then
1359     if test "x$enable_cups" = "xauto"; then
1360       AM_CONDITIONAL(HAVE_CUPS, false)
1361     else
1362       AC_MSG_ERROR([
1363 *** cups not found.
1364 ])
1365     fi
1366   else
1367     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1368     CUPS_LIBS=`$CUPS_CONFIG --libs`
1369
1370     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1371     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1372     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1373
1374     if test $CUPS_API_MAJOR -gt 1 -o \
1375             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1376       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1377                 [Define to 1 if CUPS 1.2 API is available])
1378     fi
1379
1380     AC_SUBST(CUPS_API_MAJOR)
1381     AC_SUBST(CUPS_API_MINOR)
1382     AC_SUBST(CUPS_CFLAGS)
1383     AC_SUBST(CUPS_LIBS)
1384
1385     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1386
1387     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1388     AM_CONDITIONAL(HAVE_CUPS, true)
1389
1390     gtk_save_cflags="$CFLAGS"
1391     CFLAGS="$CUPS_CFLAGS"
1392     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1393                                        [[http_t http; char *s = http.authstring;]])],
1394                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1395                                  [Define if cups http_t authstring field is accessible])],
1396                       [])
1397     CFLAGS="$gtk_save_cflags"
1398
1399     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1400
1401     gtk_save_libs="$LIBS"
1402     LIBS="$CUPS_LIBS"
1403     AC_CHECK_FUNCS(httpGetAuthString)
1404     LIBS="$gtk_save_libs"
1405   fi
1406 fi
1407
1408 # Checks to see if we should compile with PAPI backend for GTK+
1409 #
1410
1411 AC_ARG_ENABLE(papi,
1412               [AS_HELP_STRING([--disable-papi],
1413                               [disable papi print backend])],,
1414               [enable_papi=auto])
1415
1416 if test "x$enable_papi" = "xno"; then
1417   AM_CONDITIONAL(HAVE_PAPI, false)
1418 else
1419   AC_MSG_CHECKING(libpapi)
1420   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1421   if test $have_papi = yes; then
1422     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1423     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1424   fi
1425   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1426   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1427     AC_MSG_ERROR([
1428 *** papi not found.
1429 ])
1430   fi
1431 fi
1432
1433 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1434
1435 gtk_save_cppflags="$CPPFLAGS"
1436 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1437
1438 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1439 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1440 *** backend enabled.]))
1441
1442 if test "$os_win32" != "yes"; then
1443   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1444 *** Can't find cairo-ps.h. You must build Cairo with the
1445 *** postscript backend enabled.]))
1446
1447   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1448 *** Cannot find cairo-svg.h. You must build Cairo with the
1449 *** svg backend enabled.]))
1450 fi
1451
1452 CPPFLAGS="$gtk_save_cppflags"
1453
1454
1455 AC_ARG_ENABLE(test-print-backend,
1456               [AS_HELP_STRING([--enable-test-print-backend],
1457                               [build test print backend])],,
1458               [enable_test_print_backend=no])
1459 if test "x$enable_test_print_backend" != "xno" ; then
1460   PRINT_BACKENDS="$PRINT_BACKENDS test"
1461 fi
1462 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1463
1464
1465 ################################################################
1466 # Strip -export-dynamic from the link lines of various libraries
1467 ################################################################
1468
1469 #
1470 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1471 #  but this flag is only meaningful for executables. For libraries
1472 #  the effect is undefined; what it causes on Linux is that the
1473 #  export list from -export-symbols-regex is ignored and everything
1474 #  is exported
1475 #
1476 # We are using gmodule-no-export now, but I'm leaving the stripping
1477 # code in place for now, since pango and atk still require gmodule.
1478 export SED
1479 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1480 if test -n "$export_dynamic"; then
1481   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1482   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1483 fi
1484
1485 #############
1486 # GSettings #
1487 #############
1488
1489 GLIB_GSETTINGS
1490
1491 ##################################################
1492 # GObject introspection
1493 ##################################################
1494
1495 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1496
1497 ##################################################
1498 # Packagekit module
1499 #################################################
1500
1501 AC_ARG_ENABLE(packagekit,
1502               [AS_HELP_STRING([--disable-packagekit],
1503                               [build packagekit open-with module])])
1504
1505 build_packagekit=no
1506 if test "os_win32" != "yes"; then
1507         if test "x$enable_packagekit" != "xno"; then
1508                 build_packagekit=yes
1509                 AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1510         fi
1511 fi
1512
1513 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1514
1515 ##################################################
1516 # Checks for gtk-doc and docbook-tools
1517 ##################################################
1518
1519 GTK_DOC_CHECK([1.11])
1520
1521 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1522 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1523
1524 AC_ARG_ENABLE(man,
1525               [AS_HELP_STRING([--enable-man],
1526                               [regenerate man pages from Docbook [default=no]])],
1527               [enable_man=yes],
1528               [enable_man=no])
1529
1530 if test "${enable_man}" != no; then
1531   dnl
1532   dnl Check for xsltproc
1533   dnl
1534   AC_PATH_PROG([XSLTPROC], [xsltproc])
1535   if test -z "$XSLTPROC"; then
1536     enable_man=no
1537   fi
1538
1539   dnl check for DocBook DTD and stylesheets in the local catalog.
1540   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1541      [DocBook XML DTD V4.1.2],,enable_man=no)
1542   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1543      [DocBook XSL Stylesheets],,enable_man=no)
1544 fi
1545
1546 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1547
1548
1549 ##################################################
1550 # Output commands
1551 ##################################################
1552
1553 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1554         outfile=gdkconfig.h-tmp
1555         cat > $outfile <<\_______EOF
1556 /* gdkconfig.h
1557  *
1558  * This is a generated file.  Please modify `configure.ac'
1559  */
1560
1561 #ifndef __GDKCONFIG_H__
1562 #define __GDKCONFIG_H__
1563
1564 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1565 #error "Only <gdk/gdk.h> can be included directly."
1566 #endif
1567
1568 #include <glib.h>
1569
1570 G_BEGIN_DECLS
1571
1572 _______EOF
1573
1574         cat >>$outfile <<_______EOF
1575 $gdk_windowing
1576 _______EOF
1577
1578         cat >>$outfile <<_______EOF
1579
1580 G_END_DECLS
1581
1582 #endif  /* __GDKCONFIG_H__ */
1583 _______EOF
1584
1585
1586         if cmp -s $outfile gdk/gdkconfig.h; then
1587           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1588           rm -f $outfile
1589         else
1590           mv $outfile gdk/gdkconfig.h
1591         fi
1592 ],[
1593 gdk_windowing='$GDK_WINDOWING'
1594 ])
1595
1596 dnl
1597 dnl Check for -Bsymbolic-functions linker flag used to avoid
1598 dnl intra-library PLT jumps, if available.
1599 dnl
1600 AC_ARG_ENABLE(Bsymbolic,
1601               [AS_HELP_STRING([--disable-Bsymbolic],
1602                               [avoid linking with -Bsymbolic])],,
1603               [SAVED_LDFLAGS="${LDFLAGS}"
1604                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1605                LDFLAGS=-Wl,-Bsymbolic-functions
1606                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1607                                                [[int main (void) { return 0; }]])],
1608                               [AC_MSG_RESULT(yes)
1609                                enable_Bsymbolic=yes],
1610                               [AC_MSG_RESULT(no)
1611                                enable_Bsymbolic=no])
1612                LDFLAGS="${SAVED_LDFLAGS}"])
1613
1614 if test "x${enable_Bsymbolic}" = "xyes" ; then
1615   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1616 fi
1617 AC_SUBST(GTK_LINK_FLAGS)
1618
1619 AC_CONFIG_FILES([
1620 config.h.win32
1621 gtk-zip.sh
1622 Makefile
1623 gdk-3.0.pc
1624 gtk+-3.0.pc
1625 gtk+-unix-print-3.0.pc
1626 gail-3.0.pc
1627 gtk+-3.0-uninstalled.pc
1628 gail-3.0-uninstalled.pc
1629 m4macros/Makefile
1630 po/Makefile.in
1631 po-properties/Makefile.in
1632 demos/Makefile
1633 demos/gtk-demo/Makefile
1634 demos/gtk-demo/geninclude.pl
1635 examples/Makefile
1636 tests/Makefile
1637 docs/Makefile
1638 docs/reference/Makefile
1639 docs/reference/gdk/Makefile
1640 docs/reference/gdk/version.xml
1641 docs/reference/gtk/Makefile
1642 docs/reference/gtk/version.xml
1643 docs/reference/libgail-util/Makefile
1644 docs/reference/libgail-util/version.xml
1645 docs/tools/Makefile
1646 build/Makefile
1647 build/win32/Makefile
1648 build/win32/vs9/Makefile
1649 gdk/Makefile
1650 gdk/x11/Makefile
1651 gdk/win32/Makefile
1652 gdk/win32/rc/Makefile
1653 gdk/win32/rc/gdk.rc
1654 gdk/quartz/Makefile
1655 gdk/tests/Makefile
1656 gtk/Makefile
1657 gtk/makefile.msc
1658 gtk/gtkversion.h
1659 gtk/gtk-win32.rc
1660 gtk/tests/Makefile
1661 modules/Makefile
1662 modules/other/Makefile
1663 modules/other/gail/Makefile
1664 modules/other/gail/libgail-util/Makefile
1665 modules/other/gail/tests/Makefile
1666 modules/engines/Makefile
1667 modules/engines/pixbuf/Makefile
1668 modules/engines/ms-windows/Makefile
1669 modules/engines/ms-windows/Theme/Makefile
1670 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1671 modules/input/Makefile
1672 modules/printbackends/Makefile
1673 modules/printbackends/cups/Makefile
1674 modules/printbackends/lpr/Makefile
1675 modules/printbackends/file/Makefile
1676 modules/printbackends/papi/Makefile
1677 modules/printbackends/test/Makefile
1678 perf/Makefile
1679 ])
1680
1681 AC_OUTPUT
1682
1683 # beautify the immodule list a bit
1684 included_immodules=${included_immodules//,/ }
1685 included_immodules=${included_immodules:-none}
1686
1687 echo ""
1688 echo "        GTK+ $GTK_VERSION"
1689 echo "        ==========="
1690 echo ""
1691 echo "        GDK backends:         $GDK_BACKENDS"
1692 if test "x$enable_x11_backend" = "xyes"; then
1693 echo "        X11 extensions:       $X_EXTENSIONS"
1694 fi
1695 echo "        Print backends:       $PRINT_BACKENDS"
1696 echo "        Dynamic modules:      $build_dynamic_modules"
1697 echo "        Included immodules:   $included_immodules"
1698 echo "        PackageKit support:   $build_packagekit"
1699 echo "        Introspection:        $found_introspection"
1700 echo "        Debugging:            $enable_debug"
1701 echo "        Documentation:        $enable_gtk_doc"