Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [2])
  12 m4_define([gtk_minor_version], [99])
  13 m4_define([gtk_micro_version], [4])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Define a string for the earliest version that this release has
  32 # backwards binary compatibility with for all interfaces a module
  33 # might. Unless we add module-only API with lower stability
  34 # guarantees, this should be unchanged until we break binary compat
  35 # for GTK+.
  36 #
  37 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  38 m4_define([gtk_binary_version], [3.0.0])
  39
  40 # required versions of other packages
  41 m4_define([glib_required_version], [2.28.0])
  42 m4_define([pango_required_version], [1.20])
  43 m4_define([atk_required_version], [1.30])
  44 m4_define([cairo_required_version], [1.10.0])
  45 m4_define([gdk_pixbuf_required_version], [2.22.0])
  46 m4_define([introspection_required_version], [0.10.1])
  47 GLIB_REQUIRED_VERSION=glib_required_version
  48 PANGO_REQUIRED_VERSION=pango_required_version
  49 ATK_REQUIRED_VERSION=atk_required_version
  50 CAIRO_REQUIRED_VERSION=cairo_required_version
  51 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  52 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  53
  54 AC_SUBST(GLIB_REQUIRED_VERSION)
  55 AC_SUBST(PANGO_REQUIRED_VERSION)
  56 AC_SUBST(ATK_REQUIRED_VERSION)
  57 AC_SUBST(CAIRO_REQUIRED_VERSION)
  58 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  59 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  60
  61 # Save this value here, since automake will set cflags later
  62 cflags_set=${CFLAGS+set}
  63
  64 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  65 AM_MAINTAINER_MODE([enable])
  66
  67 # Support silent build rules, requires at least automake-1.11. Disable
  68 # by either passing --disable-silent-rules to configure or passing V=1
  69 # to make
  70 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  71
  72 #
  73 # For each of the libraries we build, we define the following
  74 # substituted variables:
  75 #
  76 # foo_PACKAGES:     pkg-config packages this library requires
  77 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  78 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  79 # foo_DEP_LIBS:     All libraries this module requires
  80 # foo_DEP_CFLAGS:   All cflags this module requires
  81
  82
  83 GTK_MAJOR_VERSION=gtk_major_version
  84 GTK_MINOR_VERSION=gtk_minor_version
  85 GTK_MICRO_VERSION=gtk_micro_version
  86 GTK_INTERFACE_AGE=gtk_interface_age
  87 GTK_BINARY_AGE=gtk_binary_age
  88 GTK_VERSION=gtk_version
  89 GTK_API_VERSION=gtk_api_version
  90 GTK_BINARY_VERSION=gtk_binary_version
  91 AC_SUBST(GTK_MAJOR_VERSION)
  92 AC_SUBST(GTK_MINOR_VERSION)
  93 AC_SUBST(GTK_MICRO_VERSION)
  94 AC_SUBST(GTK_INTERFACE_AGE)
  95 AC_SUBST(GTK_BINARY_AGE)
  96 AC_SUBST(GTK_API_VERSION)
  97 AC_SUBST(GTK_VERSION)
  98 AC_SUBST(GTK_BINARY_VERSION)
  99
 100 # libtool versioning
 101 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 102 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 103 #LT_REVISION=$GTK_INTERFACE_AGE
 104 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 105 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 106
 107 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 108 m4_define([lt_revision], [gtk_interface_age])
 109 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 110 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 111 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 112 AC_SUBST(LT_VERSION_INFO)
 113 AC_SUBST(LT_CURRENT_MINUS_AGE)
 114
 115 m4_define([gail_lt_current],[0])
 116 m4_define([gail_lt_revision],[0])
 117 m4_define([gail_lt_age],[0])
 118 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 119 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 120 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 121 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 122
 123 # Checks for programs.
 124 AC_PROG_CC
 125 AC_PROG_CC_C_O
 126 AC_PROG_CC_STDC
 127 AC_PROG_INSTALL
 128 AC_PROG_MAKE_SET
 129
 130
 131 GETTEXT_PACKAGE=gtk30
 132 AC_SUBST(GETTEXT_PACKAGE)
 133 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 134                    [The prefix for our gettext translation domains.])
 135
 136 AC_CANONICAL_HOST
 137
 138 MATH_LIB=-lm
 139 AC_MSG_CHECKING([for native Win32])
 140 LIB_EXE_MACHINE_FLAG=X86
 141 EXE_MANIFEST_ARCHITECTURE=X86
 142 case "$host" in
 143   *-*-mingw*)
 144     os_win32=yes
 145     gio_can_sniff=no
 146     MATH_LIB=
 147     case "$host" in
 148     x86_64-*-*)
 149       LIB_EXE_MACHINE_FLAG=X64
 150       EXE_MANIFEST_ARCHITECTURE=AMD64
 151       ;;
 152     esac
 153     ;;
 154   *)
 155     os_win32=no
 156     ;;
 157 esac
 158 AC_MSG_RESULT([$os_win32])
 159
 160 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 161 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 162
 163 case $host in
 164   *-*-linux*)
 165     os_linux=yes
 166     ;;
 167 esac
 168
 169 dnl
 170 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 171 dnl We use this for an automated test for C++ header correctness.
 172 dnl
 173 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 174 AC_LANG_PUSH([C++])
 175
 176 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 177                                    [[class a { int b; } c;]])],
 178                   [],[CXX=])
 179 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 180
 181 gtk_save_cxxflags="$CXXFLAGS"
 182 CXXFLAGS="$CXXFLAGS -x objective-c++"
 183 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 184                                    [[]])],
 185                   [OBJC=yes],[OBJC=no])
 186 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 187 CXXFLAGS="$gtk_save_cxxflags"
 188 AC_LANG_POP([C++])
 189
 190 if test "$os_win32" = "yes"; then
 191   if test x$enable_static = xyes -o x$enable_static = x; then
 192     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 193     enable_static=no
 194   fi
 195   if test x$enable_shared = xno; then
 196     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 197   fi
 198   enable_shared=yes
 199 fi
 200
 201 dnl Initialize libtool
 202 LT_PREREQ([2.2.6])
 203 LT_INIT([disable-static win32-dll])
 204 # Create libtool early, because it's used in configure
 205 LT_OUTPUT
 206
 207 # Make sure we use 64-bit versions of various file stuff.
 208 AC_SYS_LARGEFILE
 209
 210 AM_PROG_AS
 211 AC_PATH_PROG(NM, nm, nm)
 212
 213 AC_MSG_CHECKING([for some Win32 platform])
 214 case "$host" in
 215   *-*-mingw*|*-*-cygwin*)
 216     platform_win32=yes
 217     ;;
 218   *)
 219     platform_win32=no
 220     ;;
 221 esac
 222 AC_MSG_RESULT([$platform_win32])
 223 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 224
 225 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 226 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 227 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 228
 229 if test "$os_win32" = "yes"; then
 230   AC_CHECK_TOOL(WINDRES, windres, no)
 231   if test "$WINDRES" = no; then
 232     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 233   fi
 234   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 235 fi
 236 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 237
 238 m4_define([debug_default],
 239           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 240
 241 dnl declare --enable-* args and collect ac_help strings
 242 AC_ARG_ENABLE(debug,
 243               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 244                               [turn on debugging @<:@default=debug_default@:>@])],,
 245               [enable_debug=debug_default])
 246
 247 AC_ARG_ENABLE(rebuilds,
 248               [AS_HELP_STRING([--disable-rebuilds],
 249                               [disable all source autogeneration rules])],,
 250               [enable_rebuilds=yes])
 251
 252 AC_ARG_ENABLE(gtk2-dependency,
 253               [AS_HELP_STRING([--enable-gtk2-dependency],
 254                               [Do not build gtk-update-icon-cache and other shared tools])],,
 255               [enable_gtk2_dependency=no])
 256
 257 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 258
 259 AC_ARG_ENABLE(xkb,
 260               [AS_HELP_STRING([--enable-xkb],
 261                               [support XKB extension [default=maybe]])],,
 262               [enable_xkb="maybe"])
 263 AC_ARG_ENABLE(xinerama,
 264               [AS_HELP_STRING([--enable-xinerama],
 265                               [support Xinerama extension if available [default=maybe]])],,
 266               [enable_xinerama="maybe"])
 267 AC_ARG_ENABLE(xinput,
 268               [AS_HELP_STRING([--enable-xinput],
 269                               [support XInput extension if available [default=yes]])],,
 270               [enable_xinput="maybe"])
 271 AC_ARG_ENABLE(xrandr,
 272               [AS_HELP_STRING([--enable-xrandr],
 273                               [support XRandR extension if available [default=maybe]])],,
 274               [enable_xrandr="maybe"])
 275 AC_ARG_ENABLE(xfixes,
 276               [AS_HELP_STRING([--enable-xfixes],
 277                               [support XFixes extension if available [default=maybe]])],,
 278               [enable_xfixes="maybe"])
 279 AC_ARG_ENABLE(xcomposite,
 280               [AS_HELP_STRING([--enable-xcomposite],
 281                               [support X Composite extension if available [default=maybe]])],,
 282               [enable_xcomposite="maybe"])
 283 AC_ARG_ENABLE(xdamage,
 284               [AS_HELP_STRING([--enable-xdamage],
 285                               [support X Damage extension if available [default=maybe]])],,
 286               [enable_xdamage="maybe"])
 287
 288 AC_ARG_ENABLE(x11-backend,
 289               [AS_HELP_STRING([--enable-x11-backend],
 290                               [enable the X11 gdk backend])],
 291                               [backend_set=yes])
 292 AC_ARG_ENABLE(win32-backend,
 293               [AS_HELP_STRING([--enable-win32-backend],
 294                               [enable the Win32 gdk backend])],
 295                               [backend_set=yes])
 296 AC_ARG_ENABLE(quartz-backend,
 297               [AS_HELP_STRING([--enable-quartz-backend],
 298                               [enable the quartz gdk backend])],
 299                               [backend_set=yes])
 300
 301 if test -z "$backend_set"; then
 302   if test "$platform_win32" = yes; then
 303     enable_win32_backend=yes
 304   else
 305     enable_x11_backend=yes
 306   fi
 307 fi
 308
 309 cairo_backends=
 310 backend_immodules=
 311 GDK_BACKENDS=
 312 GDK_EXTRA_LIBS=
 313 GDK_EXTRA_CFLAGS=
 314 GDK_WINDOWING=
 315 GIO_PACKAGE=gio-2.0
 316 PANGO_PACKAGES="pango pangocairo"
 317
 318 if test "x$enable_x11_backend" == xyes; then
 319   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 320   # backend names are identical.
 321   cairo_backends="$cairo_backends cairo-xlib"
 322   GDK_BACKENDS="$GDK_BACKENDS x11"
 323   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 324   # gdkapplaunchcontext-x11.c
 325   GIO_PACKAGE=gio-unix-2.0
 326   backend_immodules="$backend_immodules,xim"
 327   GDK_WINDOWING="$GDK_WINDOWING
 328 #define GDK_WINDOWING_X11"
 329 fi
 330
 331 if test "x$enable_win32_backend" == xyes; then
 332   cairo_backends="$cairo_backends cairo-win32"
 333   GDK_BACKENDS="$GDK_BACKENDS win32"
 334   backend_immodules="$backend_immodules,ime"
 335   GDK_WINDOWING="$GDK_WINDOWING
 336 #define GDK_WINDOWING_WIN32"
 337   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 338   AM_CONDITIONAL(USE_WIN32, true)
 339   PANGO_PACKAGES="pangowin32 pangocairo"
 340 else
 341   AM_CONDITIONAL(USE_WIN32, false)
 342 fi
 343
 344 if test "x$enable_quartz_backend" == xyes; then
 345   cairo_backends="$cairo_backends cairo-quartz"
 346   GDK_BACKENDS="$GDK_BACKENDS quartz"
 347   GDK_WINDOWING="$GDK_WINDOWING
 348 #define GDK_WINDOWING_QUARTZ"
 349   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 350   AM_CONDITIONAL(USE_QUARTZ, true)
 351 else
 352   AM_CONDITIONAL(USE_QUARTZ, false)
 353 fi
 354
 355 # strip leading space
 356 GDK_BACKENDS=${GDK_BACKENDS/# }
 357
 358 AC_SUBST(GDK_BACKENDS)
 359
 360 if test -z "$GDK_BACKENDS"; then
 361   AC_MSG_ERROR([No GDK backends selected.])
 362 fi
 363
 364 if test "x$enable_debug" = "xyes"; then
 365   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 366   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 367 else
 368   if test "x$enable_debug" = "xno"; then
 369     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 370   else
 371     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 372   fi
 373 fi
 374
 375
 376 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 377                    [Define if debugging is enabled])
 378
 379
 380 # Build time sanity check...
 381 AM_SANITY_CHECK
 382
 383 changequote(,)dnl
 384 if test "x$GCC" = "xyes"; then
 385   case " $CFLAGS " in
 386   *[\ \ ]-Wall[\ \      ]*) ;;
 387   *) CFLAGS="$CFLAGS -Wall" ;;
 388   esac
 389
 390   if test "x$enable_ansi" = "xyes"; then
 391     case " $CFLAGS " in
 392     *[\ \       ]-ansi[\ \      ]*) ;;
 393     *) CFLAGS="$CFLAGS -ansi" ;;
 394     esac
 395
 396     case " $CFLAGS " in
 397     *[\ \       ]-pedantic[\ \  ]*) ;;
 398     *) CFLAGS="$CFLAGS -pedantic" ;;
 399     esac
 400   fi
 401 fi
 402 changequote([,])dnl
 403
 404 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 405
 406 # Ensure MSVC-compatible struct packing convention is used when
 407 # compiling for Win32 with gcc.
 408 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 409 # gcc2 uses "-fnative-struct".
 410 if test x"$os_win32" = xyes; then
 411   if test x"$GCC" = xyes; then
 412     msnative_struct=''
 413     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 414     if test -z "$ac_cv_prog_CC"; then
 415       our_gcc="$CC"
 416     else
 417       our_gcc="$ac_cv_prog_CC"
 418     fi
 419     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 420       2.)
 421         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 422           msnative_struct='-fnative-struct'
 423         fi
 424         ;;
 425       *)
 426         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 427           msnative_struct='-mms-bitfields'
 428         fi
 429         ;;
 430     esac
 431     if test x"$msnative_struct" = x ; then
 432       AC_MSG_RESULT([no way])
 433       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 434     else
 435       CFLAGS="$CFLAGS $msnative_struct"
 436       AC_MSG_RESULT([${msnative_struct}])
 437     fi
 438   fi
 439 fi
 440
 441 ## Initial sanity check, done here so that users get told they
 442 ## have the wrong dependencies as early in the process as possible.
 443 ## Later on we actually use the cflags/libs from separate pkg-config
 444 ## calls. Oh, also the later pkg-config calls don't include
 445 ## the version requirements since those make the module lists
 446 ## annoying to construct
 447 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 448   [glib-2.0 >= glib_required_version dnl
 449    atk >= atk_required_version dnl
 450    pango >= pango_required_version dnl
 451    cairo >= cairo_required_version dnl
 452    cairo-gobject >= cairo_required_version dnl
 453    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 454
 455 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 456
 457 if test "$os_win32" != yes; then
 458     # libtool option to control which symbols are exported
 459     # right now, symbols starting with _ are not exported
 460     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 461 else
 462     # We currently use .def files on Windows (for gdk and gtk)
 463     LIBTOOL_EXPORT_OPTIONS=
 464 fi
 465 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 466
 467 dnl ******************************************************
 468 dnl * See whether to include shared library dependencies *
 469 dnl ******************************************************
 470
 471 AC_ARG_ENABLE(explicit-deps,
 472               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 473                               [use explicit dependencies in .pc files [default=auto]])],,
 474               [enable_explicit_deps=auto])
 475
 476 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 477 case $enable_explicit_deps in
 478   auto)
 479     export SED
 480     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 481     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 482       enable_explicit_deps=yes
 483     else
 484       enable_explicit_deps=no
 485     fi
 486   ;;
 487   yes|no)
 488   ;;
 489   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 490   ;;
 491 esac
 492 AC_MSG_RESULT($enable_explicit_deps)
 493
 494 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 495
 496 # define a MAINT-like variable REBUILD which is set if Perl
 497 # and awk are found, so autogenerated sources can be rebuilt
 498
 499 AC_PATH_PROGS(PERL, perl5 perl)
 500
 501 # We would like indent, but don't require it.
 502 AC_CHECK_PROG(INDENT, indent, indent)
 503
 504 REBUILD=\#
 505 if test "x$enable_rebuilds" = "xyes" && \
 506      test -n "$PERL" && \
 507      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 508   REBUILD=
 509 fi
 510 AC_SUBST(REBUILD)
 511
 512 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 513 AC_CHECK_FUNCS(localtime_r)
 514
 515 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 516 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 517 AC_TRY_LINK([#include <langinfo.h>], [
 518 char c;
 519 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 520 ], gtk_ok=yes, gtk_ok=no)
 521 AC_MSG_RESULT($gtk_ok)
 522 if test "$gtk_ok" = "yes"; then
 523   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 524             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 525 fi
 526
 527 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 528 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 529 AC_TRY_LINK([#include <langinfo.h>], [
 530 char c;
 531 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 532 ], gtk_ok=yes, gtk_ok=no)
 533 AC_MSG_RESULT($gtk_ok)
 534 if test "$gtk_ok" = "yes"; then
 535   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 536             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 537 fi
 538
 539 # _NL_PAPER_HEIGHT is an enum and not a define
 540 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 541 AC_TRY_LINK([#include <langinfo.h>], [
 542 char c;
 543 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 544 ], gtk_ok=yes, gtk_ok=no)
 545 AC_MSG_RESULT($gtk_ok)
 546 if test "$gtk_ok" = "yes"; then
 547   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 548             [Define if _NL_PAPER_HEIGHT is available])
 549 fi
 550
 551 # _NL_PAPER_WIDTH is an enum and not a define
 552 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 553 AC_TRY_LINK([#include <langinfo.h>], [
 554 char c;
 555 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 556 ], gtk_ok=yes, gtk_ok=no)
 557 AC_MSG_RESULT($gtk_ok)
 558 if test "$gtk_ok" = "yes"; then
 559   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 560             [Define if _NL_PAPER_WIDTH is available])
 561 fi
 562
 563 # i18n stuff
 564 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 565 AM_GLIB_GNU_GETTEXT
 566 LIBS="$LIBS $INTLLIBS"
 567 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 568         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 569       esac])
 570
 571 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 572 dnl po-properties/POTFILES during configure; see GNOME #573515.
 573 dnl
 574 dnl Generate list of files to be processed by xgettext which will
 575 dnl be included in po-properties/Makefile.
 576 test -d po-properties || mkdir po-properties
 577 if test "x$srcdir" != "x."; then
 578   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 579     popropsrcprefix="$srcdir/"
 580   else
 581     popropsrcprefix="../$srcdir/"
 582   fi
 583 else
 584   popropsrcprefix="../"
 585 fi
 586 rm -f po-properties/POTFILES
 587 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 588 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 589 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 590
 591 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 592
 593 dnl The DU4 header files don't provide library prototypes unless
 594 dnl -std1 is given to the native cc.
 595 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 596
 597 gtk_save_LIBS=$LIBS
 598 LIBS="$LIBS -lm"
 599 AC_TRY_RUN([#include <math.h>
 600              int main (void) { return (log(1) != log(1.)); }],
 601      AC_MSG_RESULT(none needed),
 602      gtk_save_CFLAGS="$CFLAGS"
 603      CFLAGS="$CFLAGS -std1"
 604      AC_TRY_RUN([#include <math.h>
 605                  int main (void) { return (log(1) != log(1.)); }],
 606          AC_MSG_RESULT(-std1),
 607          AC_MSG_RESULT()
 608          CFLAGS="$gtk_save_CFLAGS"
 609          AC_MSG_WARN(
 610                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 611          true
 612      ),
 613      AC_MSG_RESULT(none needed)
 614 )
 615 LIBS=$gtk_save_LIBS
 616
 617 AC_MSG_CHECKING(for the BeOS)
 618 case $host in
 619   *-*-beos*)
 620     AC_MSG_RESULT(yes)
 621     MATH_LIB=
 622   ;;
 623   *)
 624     AC_MSG_RESULT(no)
 625   ;;
 626 esac
 627
 628 AC_SUBST(MATH_LIB)
 629 #
 630 # see bug 162979
 631 #
 632 AC_MSG_CHECKING(for HP-UX)
 633 case $host_os in
 634   hpux9* | hpux10* | hpux11*)
 635     AC_MSG_RESULT(yes)
 636     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 637   ;;
 638   *)
 639     AC_MSG_RESULT(no)
 640   ;;
 641 esac
 642
 643 #
 644 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 645 #
 646
 647 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 648
 649 AM_PATH_GLIB_2_0(glib_required_version, :,
 650   AC_MSG_ERROR([
 651 *** GLIB glib_required_version or better is required. The latest version of
 652 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 653   gobject gmodule-no-export gthread)
 654
 655 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 656 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 657 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 658 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 659   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 660 fi
 661
 662 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 663
 664
 665 dnl
 666 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 667 dnl
 668 gtk_save_LIBS=$LIBS
 669 LIBS="$LIBS $GLIB_LIBS"
 670 AC_CHECK_FUNCS(bind_textdomain_codeset)
 671 LIBS=$gtk_save_LIBS
 672
 673 AC_CHECK_HEADERS(pwd.h,
 674                  AC_DEFINE(HAVE_PWD_H, 1,
 675                            [Define to 1 if pwd.h is available]))
 676 AC_CHECK_HEADERS(sys/time.h,
 677                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 678                            [Define to 1 if time.h is available]))
 679 AC_CHECK_HEADERS(unistd.h,
 680                  AC_DEFINE(HAVE_UNISTD_H, 1,
 681                            [Define to 1 if unistd.h is available]))
 682 AC_CHECK_HEADERS(ftw.h,
 683                  AC_DEFINE(HAVE_FTW_H, 1,
 684                            [Define to 1 if ftw.h is available]))
 685
 686 AC_MSG_CHECKING([for GNU ftw extensions])
 687 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 688                                      #define _GNU_SOURCE
 689                                      #include <ftw.h>]],
 690                                    [[int flags = FTW_ACTIONRETVAL;]])],
 691                   [gtk_ok=yes],[gtk_ok=no])
 692 if test $gtk_ok = yes; then
 693     AC_MSG_RESULT([yes])
 694     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 695 else
 696     AC_MSG_RESULT([no])
 697 fi
 698
 699 saved_cflags="$CFLAGS"
 700 saved_ldflags="$LDFLAGS"
 701
 702
 703 # Checks for library functions.
 704 AC_FUNC_MMAP
 705
 706 AC_CHECK_FUNCS(mallinfo)
 707 AC_CHECK_FUNCS(getresuid)
 708 AC_TYPE_UID_T
 709
 710 # Check if <sys/select.h> needs to be included for fd_set
 711 AC_MSG_CHECKING([for fd_set])
 712 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 713                                    [[fd_set readMask, writeMask;]])],
 714                   [gtk_ok=yes],[gtk_ok=no])
 715 if test $gtk_ok = yes; then
 716     AC_MSG_RESULT([yes, found in sys/types.h])
 717 else
 718     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 719     if test $gtk_ok = yes; then
 720         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 721                   [Define to 1 if sys/select.h is available])
 722         AC_MSG_RESULT([yes, found in sys/select.h])
 723     else
 724         AC_DEFINE(NO_FD_SET, 1,
 725                   [Define to 1 if fd_set is not available])
 726         AC_MSG_RESULT(no)
 727     fi
 728 fi
 729
 730 # Check for uxtheme.h (for MS-Windows Engine)
 731 AC_MSG_CHECKING(for uxtheme.h)
 732 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 733 if test $gtk_uxtheme_h = yes; then
 734    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 735 fi
 736 AC_MSG_RESULT($gtk_uxtheme_h)
 737
 738 # Checks for gdkspawn
 739 AC_CHECK_HEADERS(crt_externs.h)
 740 AC_CHECK_FUNCS(_NSGetEnviron)
 741
 742 AC_MSG_CHECKING(whether to build dynamic modules)
 743
 744 AC_ARG_ENABLE(modules,
 745               [AS_HELP_STRING([--disable-modules],
 746                               [disable dynamic module loading])])
 747
 748 dynworks=false
 749 build_dynamic_modules=no
 750 deps=
 751 if test x$enable_modules = xno; then
 752     AC_MSG_RESULT(no)
 753 else
 754     AC_MSG_RESULT(yes)
 755     AC_MSG_CHECKING(whether dynamic modules work)
 756     ## for loop is to strip newline
 757     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 758     for I in $tmp; do
 759         dynworks=$I
 760     done
 761
 762     dnl Now we check to see if our libtool supports shared lib deps
 763     dnl (in a rather ugly way even)
 764     if $dynworks; then
 765         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 766         module_deplibs_check=`$module_libtool_config | \
 767             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 768             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 769         if test "x$module_deplibs_check" = "xnone" || \
 770            test "x$module_deplibs_check" = "xunknown" || \
 771            test "x$module_deplibs_check" = "x"; then
 772             dynworks=false
 773         fi
 774     fi
 775
 776     if $dynworks; then
 777         build_dynamic_modules=yes
 778         AC_DEFINE(USE_GMODULE, 1,
 779                   [Define to 1 if gmodule works and should be used])
 780         AC_MSG_RESULT(yes)
 781     else
 782         build_dynamic_modules=no
 783         AC_MSG_RESULT(no)
 784     fi
 785 fi
 786
 787 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 788
 789 #
 790 # Allow building some or all immodules included
 791 #
 792 AC_MSG_CHECKING(immodules to build)
 793
 794 AC_ARG_WITH(included_immodules,
 795             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 796                             [build the specified input methods into gtk])])
 797
 798 if $dynworks; then
 799    :
 800 else
 801    ## if the option was specified, leave it; otherwise disable included immodules
 802    if test x$with_included_immodules = xno; then
 803            with_included_immodules=yes
 804    fi
 805 fi
 806
 807 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 808
 809 included_immodules=""
 810 # If the switch specified without listing any specific ones, include all
 811 if test "x$with_included_immodules" = xyes ; then
 812   included_immodules="$all_immodules"
 813 else
 814   included_immodules="$with_included_immodules"
 815 fi
 816
 817 AC_MSG_RESULT($included_immodules)
 818 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 819
 820 INCLUDED_IMMODULE_OBJ=
 821 INCLUDED_IMMODULE_DEFINE=
 822
 823 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 824 for immodule in $included_immodules; do
 825  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 826  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 827    :
 828  else
 829    AC_MSG_ERROR([the specified input method $immodule does not exist])
 830  fi
 831
 832  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 833  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 834  eval INCLUDE_$immodule_underscores=yes
 835 done
 836 IFS="$gtk_save_ifs"
 837 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 838 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 839
 840 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 841 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 842 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 843 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 844 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 845 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 846 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 847 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 848 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 849 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 850 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 851 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 852
 853 # Checks to see whether we should include mediaLib
 854 # support.
 855 #
 856 AC_CHECK_HEADER(sys/systeminfo.h,
 857                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 858                           [Define to 1 if sys/systeminfo.h is available]))
 859 AC_CHECK_HEADER(sys/sysinfo.h,
 860                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 861                           [Define to 1 if sys/sysinfo.h is available]))
 862
 863 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 864
 865 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 866
 867 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 868   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 869   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 870     REBUILD_PNGS=#
 871   fi
 872 fi
 873
 874 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 875
 876 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 877
 878 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 879    test "x$REBUILD_PNGS" = "x#" ; then
 880      AC_MSG_ERROR([
 881 *** gtkbuiltincache.h is not in the tree, and cannot be built
 882 *** because you don't have libpng, or (when cross-compiling) you
 883 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 884 fi
 885
 886 ########################################
 887 # Windowing system checks
 888 ########################################
 889
 890 # GTK+ uses some X calls, so needs to link against X directly
 891 GTK_DEP_PACKAGES_FOR_X=
 892 GTK_DEP_LIBS_FOR_X=
 893 X_EXTENSIONS=
 894
 895 if test "x$enable_x11_backend" == xyes; then
 896   X_PACKAGES=fontconfig
 897
 898   #
 899   # We use fontconfig very peripherally when decoding the default
 900   # settings.
 901   #
 902   if $PKG_CONFIG --exists fontconfig; then : ; else
 903     AC_MSG_ERROR([
 904 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 905   fi
 906
 907   #
 908   # Check for basic X packages; we use pkg-config if available
 909   #
 910   if $PKG_CONFIG --exists x11 xext; then
 911     have_base_x_pc=true
 912     X_PACKAGES="$X_PACKAGES x11 xext"
 913     x_libs="`$PKG_CONFIG --libs x11 xext`"
 914     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 915
 916     # Strip out any .la files that pkg-config might give us (this happens
 917     # with -uninstalled.pc files)
 918     x_libs_for_checks=
 919     for I in $x_libs ; do
 920       case $I in
 921         *.la) ;;
 922         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 923       esac
 924     done
 925
 926     GTK_PACKAGES_FOR_X="x11"
 927   else
 928     have_base_x_pc=false
 929     AC_PATH_XTRA
 930     if test x$no_x = xyes ; then
 931       AC_MSG_ERROR([X development libraries not found])
 932     fi
 933
 934     x_cflags="$X_CFLAGS"
 935     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 936
 937     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 938   fi
 939
 940   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 941   x_extra_libs=
 942
 943   gtk_save_cppflags="$CPPFLAGS"
 944   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 945
 946   gtk_save_LIBS=$LIBS
 947   LIBS="$x_libs_for_checks $LIBS"
 948
 949   # Sanity check for the X11 and Xext libraries. While everything we need from
 950   # Xext is optional, the chances a system has *none* of these things is so
 951   # small that we just unconditionally require it.
 952   AC_CHECK_FUNC(XOpenDisplay, :,
 953                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 954   AC_CHECK_FUNC(XextFindDisplay, :,
 955                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 956
 957   # Check for xReply
 958
 959   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 960   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 961                                      [[xReply *rep;]])],
 962                     [AC_MSG_RESULT([no])],
 963                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 964                                                           #include <X11/Xlibint.h>]],
 965                                                         [[xReply *rep;]])],
 966                                        [AC_MSG_RESULT([yes])
 967                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 968                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
 969                                        [AC_MSG_RESULT([unknown])
 970                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 971
 972   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 973
 974   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 975
 976   # Generic X11R6 check needed for XIM support; we could
 977   # probably use this to replace the above, but we'll
 978   # leave the separate checks for XConvertCase and XInternAtoms
 979   # for clarity
 980
 981   have_x11r6=false
 982   AC_CHECK_FUNC(XAddConnectionWatch,
 983       have_x11r6=true)
 984
 985   if $have_x11r6; then
 986     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
 987   fi
 988   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
 989
 990   # Check for XKB support.
 991
 992   if test "x$enable_xkb" = "xyes"; then
 993         AC_CHECK_FUNC(XkbQueryExtension,
 994                       X_EXTENSIONS="$X_EXTENSIONS XKB"
 995                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
 996                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
 997   elif test "x$enable_xkb" = "xmaybe"; then
 998         AC_CHECK_FUNC(XkbQueryExtension,
 999                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1000                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1001   else
1002         AC_MSG_WARN(XKB support explicitly disabled)
1003   fi
1004
1005   # Check for shaped window extension
1006
1007   AC_CHECK_FUNC(XShapeCombineMask, :,
1008      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1009
1010   # X SYNC check
1011   gtk_save_CFLAGS="$CFLAGS"
1012   CFLAGS="$CFLAGS $x_cflags"
1013
1014   AC_CHECK_FUNC(XSyncQueryExtension,
1015       [AC_CHECK_HEADER(X11/extensions/sync.h,
1016           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1017           :, [#include <X11/Xlib.h>])])
1018
1019   CFLAGS="$gtk_save_CFLAGS"
1020
1021   if test "x$enable_xinerama" != "xno"; then
1022     # Check for Xinerama extension (Solaris impl or Xfree impl)
1023     have_xfree_xinerama=false
1024     have_solaris_xinerama=false
1025
1026     gtk_save_cppflags="$CPPFLAGS"
1027     CPPFLAGS="$CPPFLAGS $x_cflags"
1028
1029     # Check for XFree
1030     AC_MSG_CHECKING(for Xinerama packages)
1031
1032     if $PKG_CONFIG --exists xinerama ; then
1033        AC_MSG_RESULT(yes)
1034        have_xfree_xinerama=true
1035        X_PACKAGES="$X_PACKAGES xinerama"
1036     else
1037        AC_MSG_RESULT(no)
1038        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1039            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1040            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1041            have_xfree_xinerama=true], :,
1042            [#include <X11/Xlib.h>])])
1043     fi
1044
1045     if $have_xfree_xinerama ; then
1046       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1047       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1048                 [Define to 1 if XFree Xinerama is available])
1049       AC_DEFINE(HAVE_XINERAMA, 1,
1050                 [Define to 1 is Xinerama is available])
1051     else
1052       case "$host" in
1053         *-*-solaris*)
1054             # Check for solaris
1055             AC_MSG_CHECKING(for Xinerama support on Solaris)
1056
1057             have_solaris_xinerama=false
1058             AC_CHECK_FUNC(XineramaGetInfo,
1059                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1060                     [have_solaris_xinerama=true], :,
1061                     [#include <X11/Xlib.h>])])
1062
1063             if $have_solaris_xinerama ; then
1064               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1065               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1066                         [Define to 1 if solaris xinerama is available])
1067               AC_DEFINE(HAVE_XINERAMA, 1,
1068                         [Define to 1 if xinerama is available])
1069               AC_MSG_RESULT(yes)
1070             else
1071               AC_MSG_RESULT(no)
1072             fi
1073             ;;
1074         *)
1075             ;;
1076       esac
1077     fi
1078   fi
1079   if test "x$enable_xinerama" = "xyes" ; then
1080     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1081       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1082     fi
1083   fi
1084
1085   # set up things for XInput
1086   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1087     have_xinput=yes
1088
1089     AC_DEFINE(XINPUT_XFREE, 1,
1090               [Define to 1 if XFree XInput should be used])
1091
1092     X_PACKAGES="$X_PACKAGES xi"
1093
1094     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1095                     have_xinput2=yes
1096                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1097                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]),
1098                     X_EXTENSIONS="$X_EXTENSIONS XInput")
1099
1100   else
1101     AC_DEFINE(XINPUT_NONE, 1,
1102               [Define to 1 if no XInput should be used])
1103   fi
1104
1105   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1106   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1107
1108   if test "x$enable_xinput" = "xyes" ; then
1109     if test "x$have_xinput" != "xyes" -a "x$have_xinput2" != "xyes" ; then
1110       AC_MSG_ERROR([*** XInput extension not found. Check 'config.log' for more details.])
1111     fi
1112   fi
1113
1114   # Check for the RANDR extension
1115   if test x"$enable_xrandr" != xno; then
1116     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1117       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1118
1119       X_PACKAGES="$X_PACKAGES xrandr"
1120       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1121     elif test x"$enable_xrandr" = xyes; then
1122       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1123     fi
1124   fi
1125
1126   # Checks for Xcursor library
1127
1128   if $PKG_CONFIG --exists xcursor ; then
1129     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1130
1131     X_PACKAGES="$X_PACKAGES xcursor"
1132   fi
1133
1134   # Checks for XFixes extension
1135
1136   if test x"$enable_xfixes" != xno; then
1137     if $PKG_CONFIG --exists xfixes ; then
1138       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1139
1140       X_PACKAGES="$X_PACKAGES xfixes"
1141       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1142       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1143     elif test x"$enable_xfixes" = xyes; then
1144       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1145     fi
1146   fi
1147
1148   # Checks for Xcomposite extension
1149
1150   if test x"$enable_xcomposite" != xno; then
1151     if $PKG_CONFIG --exists xcomposite ; then
1152       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1153
1154       X_PACKAGES="$X_PACKAGES xcomposite"
1155       X_EXTENSIONS="$X_EXTENSIONS Composite"
1156       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1157     elif test x"$enable_xcomposite" = xyes; then
1158       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1159     fi
1160   fi
1161
1162   # Checks for Xdamage extension
1163
1164   if test x"$enable_xdamage" != xno; then
1165     if $PKG_CONFIG --exists xdamage ; then
1166       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1167
1168       X_PACKAGES="$X_PACKAGES xdamage"
1169       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1170       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1171     elif test x"$enable_xdamage" = xyes; then
1172       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1173     fi
1174   fi
1175
1176   if $have_base_x_pc ; then
1177     GDK_EXTRA_LIBS="$x_extra_libs"
1178   else
1179     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1180   fi
1181
1182   CPPFLAGS="$gtk_save_cppflags"
1183   LIBS="$gtk_save_libs"
1184
1185   AM_CONDITIONAL(USE_X11, true)
1186
1187   # strip leading space
1188   X_EXTENSIONS=${X_EXTENSIONS/# }
1189
1190 else
1191   XPACKAGES=
1192
1193   AM_CONDITIONAL(XINPUT_XFREE, false)
1194   AM_CONDITIONAL(XINPUT_2, false)
1195   AM_CONDITIONAL(USE_X11, false)
1196   AM_CONDITIONAL(HAVE_X11R6, false)
1197 fi
1198
1199 # Check for Pango flags
1200
1201 AC_MSG_CHECKING(Pango flags)
1202 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1203         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1204         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1205
1206         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1207 else
1208         AC_MSG_ERROR([
1209 *** Pango not found. Pango built with Cairo support is required
1210 *** to build GTK+. See http://www.pango.org for Pango information.
1211 ])
1212 fi
1213
1214 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1215
1216 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1217         :
1218 else
1219         gtk_save_LIBS="$LIBS"
1220         LIBS="$PANGO_LIBS $LIBS"
1221         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1222 *** Can't link to Pango. Pango is required to build
1223 *** GTK+. For more information see http://www.pango.org]))
1224         LIBS="$gtk_save_LIBS"
1225 fi
1226
1227 CFLAGS="$saved_cflags"
1228 LDFLAGS="$saved_ldflags"
1229
1230 GDK_PACKAGES="$PANGO_PACKAGES $GIO_PACKAGE $X_PACKAGES gdk-pixbuf-2.0 $cairo_backends cairo-gobject"
1231
1232 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1233 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1234 #
1235 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1236 # into the pkg-config files
1237 #
1238 if test $enable_explicit_deps != yes ; then
1239   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo-gobject"
1240   GDK_EXTRA_LIBS=
1241 fi
1242
1243 AC_SUBST(GDK_PACKAGES)
1244 AC_SUBST(GDK_EXTRA_LIBS)
1245 AC_SUBST(GDK_EXTRA_CFLAGS)
1246 AC_SUBST(GDK_DEP_LIBS)
1247 AC_SUBST(GDK_DEP_CFLAGS)
1248
1249
1250 ########################################
1251 # Check for Accessibility Toolkit flags
1252 ########################################
1253
1254 ATK_PACKAGES=atk
1255 AC_MSG_CHECKING(ATK flags)
1256 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1257         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1258         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1259
1260         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1261 else
1262         AC_MSG_ERROR([
1263 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1264 *** to build GTK+.
1265 ])
1266 fi
1267
1268 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1269         :
1270 else
1271         gtk_save_LIBS="$LIBS"
1272         LIBS="$ATK_LIBS $LIBS"
1273         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1274                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1275                 *** to build GTK+]))
1276         LIBS="$gtk_save_LIBS"
1277 fi
1278
1279 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1280 if test "x$enable_x11_backend" == xyes; then
1281   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1282 fi
1283 GTK_EXTRA_LIBS=
1284 GTK_EXTRA_CFLAGS=
1285 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1286 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1287
1288 if test x"$os_win32" = xyes; then
1289   GTK_EXTRA_CFLAGS="$msnative_struct"
1290 fi
1291
1292 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1293 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1294 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1295 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1296
1297 AC_SUBST(GTK_PACKAGES)
1298 AC_SUBST(GTK_EXTRA_LIBS)
1299 AC_SUBST(GTK_EXTRA_CFLAGS)
1300 AC_SUBST(GTK_DEP_LIBS)
1301 AC_SUBST(GTK_DEP_CFLAGS)
1302
1303 AC_SUBST(GLIB_PREFIX)
1304 AC_SUBST(ATK_PREFIX)
1305 AC_SUBST(PANGO_PREFIX)
1306 AC_SUBST(CAIRO_PREFIX)
1307
1308 AC_SUBST(GTK_DEBUG_FLAGS)
1309 AC_SUBST(GTK_XIM_FLAGS)
1310
1311 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1312 AC_SUBST(GDK_PIXBUF_LIBS)
1313
1314 ########################
1315 # Checks needed for gail
1316 ########################
1317
1318 old_LIBS="$LIBS"
1319 dnl Checks for inet libraries:
1320 AC_SEARCH_LIBS(gethostent, nsl)
1321 AC_SEARCH_LIBS(setsockopt, socket)
1322 AC_SEARCH_LIBS(connect, inet)
1323
1324 dnl check for the sockaddr_un.sun_len member
1325 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1326                 [struct_sockaddr_un_sun_len=true],
1327                 [struct_sockaddr_un_suin_len=false],
1328                 [#include <sys/types.h>
1329                  #include <sys/un.h>]
1330                 )
1331 case $struct_sockaddr_un_sun_len in
1332         true)
1333                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1334                                    [Have the sockaddr_un.sun_len member])
1335                 ;;
1336         *)
1337                 ;;
1338 esac
1339
1340 GAIL_INET_LIBS="$LIBS"
1341 AC_SUBST([GAIL_INET_LIBS])
1342
1343 LIBS="$old_LIBS"
1344
1345 ################################################################
1346 # Printing system checks
1347 ################################################################
1348
1349 PRINT_BACKENDS="file lpr"
1350
1351 AC_ARG_ENABLE(cups,
1352               [AS_HELP_STRING([--disable-cups],
1353                               [disable cups print backend])],,
1354               [enable_cups=auto])
1355
1356 if test "x$enable_cups" = "xno"; then
1357   AM_CONDITIONAL(HAVE_CUPS, false)
1358 else
1359   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1360   if test "x$CUPS_CONFIG" = "xno"; then
1361     if test "x$enable_cups" = "xauto"; then
1362       AM_CONDITIONAL(HAVE_CUPS, false)
1363     else
1364       AC_MSG_ERROR([
1365 *** cups not found.
1366 ])
1367     fi
1368   else
1369     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1370     CUPS_LIBS=`$CUPS_CONFIG --libs`
1371
1372     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1373     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1374     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1375
1376     if test $CUPS_API_MAJOR -gt 1 -o \
1377             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1378       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1379                 [Define to 1 if CUPS 1.2 API is available])
1380     fi
1381
1382     AC_SUBST(CUPS_API_MAJOR)
1383     AC_SUBST(CUPS_API_MINOR)
1384     AC_SUBST(CUPS_CFLAGS)
1385     AC_SUBST(CUPS_LIBS)
1386
1387     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1388
1389     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1390     AM_CONDITIONAL(HAVE_CUPS, true)
1391
1392     gtk_save_cflags="$CFLAGS"
1393     CFLAGS="$CUPS_CFLAGS"
1394     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1395                                        [[http_t http; char *s = http.authstring;]])],
1396                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1397                                  [Define if cups http_t authstring field is accessible])],
1398                       [])
1399     CFLAGS="$gtk_save_cflags"
1400
1401     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1402
1403     gtk_save_libs="$LIBS"
1404     LIBS="$CUPS_LIBS"
1405     AC_CHECK_FUNCS(httpGetAuthString)
1406     LIBS="$gtk_save_libs"
1407   fi
1408 fi
1409
1410 # Checks to see if we should compile with PAPI backend for GTK+
1411 #
1412
1413 AC_ARG_ENABLE(papi,
1414               [AS_HELP_STRING([--disable-papi],
1415                               [disable papi print backend])],,
1416               [enable_papi=auto])
1417
1418 if test "x$enable_papi" = "xno"; then
1419   AM_CONDITIONAL(HAVE_PAPI, false)
1420 else
1421   AC_MSG_CHECKING(libpapi)
1422   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1423   if test $have_papi = yes; then
1424     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1425     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1426   fi
1427   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1428   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1429     AC_MSG_ERROR([
1430 *** papi not found.
1431 ])
1432   fi
1433 fi
1434
1435 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1436
1437 gtk_save_cppflags="$CPPFLAGS"
1438 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1439
1440 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1441 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1442 *** backend enabled.]))
1443
1444 if test "$os_win32" != "yes"; then
1445   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1446 *** Can't find cairo-ps.h. You must build Cairo with the
1447 *** postscript backend enabled.]))
1448
1449   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1450 *** Cannot find cairo-svg.h. You must build Cairo with the
1451 *** svg backend enabled.]))
1452 fi
1453
1454 CPPFLAGS="$gtk_save_cppflags"
1455
1456
1457 AC_ARG_ENABLE(test-print-backend,
1458               [AS_HELP_STRING([--enable-test-print-backend],
1459                               [build test print backend])],,
1460               [enable_test_print_backend=no])
1461 if test "x$enable_test_print_backend" != "xno" ; then
1462   PRINT_BACKENDS="$PRINT_BACKENDS test"
1463 fi
1464 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1465
1466
1467 ################################################################
1468 # Strip -export-dynamic from the link lines of various libraries
1469 ################################################################
1470
1471 #
1472 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1473 #  but this flag is only meaningful for executables. For libraries
1474 #  the effect is undefined; what it causes on Linux is that the
1475 #  export list from -export-symbols-regex is ignored and everything
1476 #  is exported
1477 #
1478 # We are using gmodule-no-export now, but I'm leaving the stripping
1479 # code in place for now, since pango and atk still require gmodule.
1480 export SED
1481 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1482 if test -n "$export_dynamic"; then
1483   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1484   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1485 fi
1486
1487 #############
1488 # GSettings #
1489 #############
1490
1491 GLIB_GSETTINGS
1492
1493 ##################################################
1494 # GObject introspection
1495 ##################################################
1496
1497 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1498
1499 ##################################################
1500 # Packagekit module
1501 #################################################
1502
1503 AC_ARG_ENABLE(packagekit,
1504               [AS_HELP_STRING([--disable-packagekit],
1505                               [build packagekit open-with module])])
1506
1507 build_packagekit=no
1508 if test "os_win32" != "yes"; then
1509         if test "x$enable_packagekit" != "xno"; then
1510                 build_packagekit=yes
1511                 AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1512         fi
1513 fi
1514
1515 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1516
1517 ##################################################
1518 # Checks for gtk-doc and docbook-tools
1519 ##################################################
1520
1521 GTK_DOC_CHECK([1.11])
1522
1523 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1524 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1525
1526 AC_ARG_ENABLE(man,
1527               [AS_HELP_STRING([--enable-man],
1528                               [regenerate man pages from Docbook [default=no]])],
1529               [enable_man=yes],
1530               [enable_man=no])
1531
1532 if test "${enable_man}" != no; then
1533   dnl
1534   dnl Check for xsltproc
1535   dnl
1536   AC_PATH_PROG([XSLTPROC], [xsltproc])
1537   if test -z "$XSLTPROC"; then
1538     enable_man=no
1539   fi
1540
1541   dnl check for DocBook DTD and stylesheets in the local catalog.
1542   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1543      [DocBook XML DTD V4.1.2],,enable_man=no)
1544   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1545      [DocBook XSL Stylesheets],,enable_man=no)
1546 fi
1547
1548 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1549
1550
1551 ##################################################
1552 # Output commands
1553 ##################################################
1554
1555 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1556         outfile=gdkconfig.h-tmp
1557         cat > $outfile <<\_______EOF
1558 /* gdkconfig.h
1559  *
1560  * This is a generated file.  Please modify `configure.ac'
1561  */
1562
1563 #ifndef __GDKCONFIG_H__
1564 #define __GDKCONFIG_H__
1565
1566 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1567 #error "Only <gdk/gdk.h> can be included directly."
1568 #endif
1569
1570 #include <glib.h>
1571
1572 G_BEGIN_DECLS
1573
1574 _______EOF
1575
1576         cat >>$outfile <<_______EOF
1577 $gdk_windowing
1578 _______EOF
1579
1580         cat >>$outfile <<_______EOF
1581
1582 G_END_DECLS
1583
1584 #endif  /* __GDKCONFIG_H__ */
1585 _______EOF
1586
1587
1588         if cmp -s $outfile gdk/gdkconfig.h; then
1589           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1590           rm -f $outfile
1591         else
1592           mv $outfile gdk/gdkconfig.h
1593         fi
1594 ],[
1595 gdk_windowing='$GDK_WINDOWING'
1596 ])
1597
1598 dnl
1599 dnl Check for -Bsymbolic-functions linker flag used to avoid
1600 dnl intra-library PLT jumps, if available.
1601 dnl
1602 AC_ARG_ENABLE(Bsymbolic,
1603               [AS_HELP_STRING([--disable-Bsymbolic],
1604                               [avoid linking with -Bsymbolic])],,
1605               [SAVED_LDFLAGS="${LDFLAGS}"
1606                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1607                LDFLAGS=-Wl,-Bsymbolic-functions
1608                AC_TRY_LINK([], [int main (void) { return 0; }],
1609                            AC_MSG_RESULT(yes)
1610                            enable_Bsymbolic=yes,
1611                            AC_MSG_RESULT(no)
1612                            enable_Bsymbolic=no)
1613                LDFLAGS="${SAVED_LDFLAGS}"])
1614
1615 if test "x${enable_Bsymbolic}" = "xyes" ; then
1616   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1617 fi
1618 AC_SUBST(GTK_LINK_FLAGS)
1619
1620 AC_CONFIG_FILES([
1621 config.h.win32
1622 gtk-zip.sh
1623 Makefile
1624 gdk-3.0.pc
1625 gtk+-3.0.pc
1626 gtk+-unix-print-3.0.pc
1627 gail-3.0.pc
1628 gtk+-3.0-uninstalled.pc
1629 gail-3.0-uninstalled.pc
1630 m4macros/Makefile
1631 po/Makefile.in
1632 po-properties/Makefile.in
1633 demos/Makefile
1634 demos/gtk-demo/Makefile
1635 demos/gtk-demo/geninclude.pl
1636 examples/Makefile
1637 tests/Makefile
1638 docs/Makefile
1639 docs/reference/Makefile
1640 docs/reference/gdk/Makefile
1641 docs/reference/gdk/version.xml
1642 docs/reference/gtk/Makefile
1643 docs/reference/gtk/version.xml
1644 docs/reference/libgail-util/Makefile
1645 docs/reference/libgail-util/version.xml
1646 docs/tools/Makefile
1647 build/Makefile
1648 build/win32/Makefile
1649 build/win32/vs9/Makefile
1650 gdk/Makefile
1651 gdk/x11/Makefile
1652 gdk/win32/Makefile
1653 gdk/win32/rc/Makefile
1654 gdk/win32/rc/gdk.rc
1655 gdk/quartz/Makefile
1656 gdk/tests/Makefile
1657 gtk/Makefile
1658 gtk/makefile.msc
1659 gtk/gtkversion.h
1660 gtk/gtk-win32.rc
1661 gtk/tests/Makefile
1662 modules/Makefile
1663 modules/other/Makefile
1664 modules/other/gail/Makefile
1665 modules/other/gail/libgail-util/Makefile
1666 modules/other/gail/tests/Makefile
1667 modules/engines/Makefile
1668 modules/engines/pixbuf/Makefile
1669 modules/engines/ms-windows/Makefile
1670 modules/engines/ms-windows/Theme/Makefile
1671 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1672 modules/input/Makefile
1673 modules/printbackends/Makefile
1674 modules/printbackends/cups/Makefile
1675 modules/printbackends/lpr/Makefile
1676 modules/printbackends/file/Makefile
1677 modules/printbackends/papi/Makefile
1678 modules/printbackends/test/Makefile
1679 perf/Makefile
1680 ])
1681
1682 AC_OUTPUT
1683
1684 # beautify the immodule list a bit
1685 included_immodules=${included_immodules//,/ }
1686 included_immodules=${included_immodules:-none}
1687
1688 echo ""
1689 echo "        GTK+ $GTK_VERSION"
1690 echo "        ==========="
1691 echo ""
1692 echo "        GDK backends:         $GDK_BACKENDS"
1693 if test "x$enable_x11_backend" = "xyes"; then
1694 echo "        X11 extensions:       $X_EXTENSIONS"
1695 fi
1696 echo "        Print backends:       $PRINT_BACKENDS"
1697 echo "        Dynamic modules:      $build_dynamic_modules"
1698 echo "        Included immodules:   $included_immodules"
1699 echo "        PackageKit support:   $build_packagekit"
1700 echo "        Introspection:        $found_introspection"
1701 echo "        Debugging:            $enable_debug"
1702 echo "        Documentation:        $enable_gtk_doc"