Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 dnl Eric S. Raymond <esr@thyrsus.com>
   3 dnl Matthias Andree <matthias.andree@gmx.de>
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6 dnl
   7
   8 AC_INIT([fetchmail],[6.3.4+svn],[fetchmail-users@lists.berlios.de])
   9 AC_CONFIG_SRCDIR([fetchmail.h])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_LIBOBJ_DIR([.])
  12
  13 AC_CANONICAL_TARGET
  14
  15 dnl automake options are in Makefile.am
  16 AC_PREREQ(2.59)
  17 AM_INIT_AUTOMAKE
  18
  19 dnl autobuild support, see <http://josefsson.org/autobuild/>
  20 (
  21   TZ=GMT
  22   export TZ
  23   AB_INIT
  24 )
  25
  26 dnl python is optional
  27 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  28 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  29
  30 AC_PROG_AWK
  31 AC_PROG_CC
  32 AC_PROG_INSTALL
  33 AC_PROG_CPP                     dnl Later checks need this.
  34 AC_PROG_RANLIB
  35 AM_PROG_CC_C_O
  36 AC_AIX
  37 AC_ISC_POSIX
  38 AC_MINIX
  39 AC_HEADER_STDC
  40 AC_HEADER_TIME
  41 AC_TYPE_SIZE_T
  42 AC_TYPE_PID_T
  43 AC_TYPE_SIGNAL
  44 AC_CHECK_TYPE(u_int32_t,unsigned int)
  45 AC_CHECK_HEADERS([unistd.h termios.h termio.h sgtty.h stdarg.h \
  46         sys/itimer.h fcntl.h sys/fcntl.h memory.h sys/wait.h \
  47         arpa/inet.h arpa/nameser.h netinet/in.h net/socket.h \
  48         sys/select.h sys/socket.h sys/time.h langinfo.h])
  49 AC_CHECK_HEADERS([resolv.h],,,[
  50 #include <sys/types.h>
  51 #ifdef HAVE_NETINET_IN_H
  52 #include <netinet/in.h>
  53 #endif
  54 #ifdef HAVE_ARPA_NAMESER_H
  55 #include <arpa/nameser.h>
  56 #endif
  57 ])
  58
  59 AC_C_CONST                      dnl getopt needs this.
  60
  61 AM_PROG_LEX
  62 AC_PROG_MAKE_SET
  63 AC_PROG_YACC
  64
  65 # Check for OS special cases
  66 case $target_os in
  67 darwin*)
  68     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
  69     CPFLAGS="-DBIND_8_COMPAT"
  70     ;;
  71 # Check for FreeBSD special case: more libs needed
  72 freebsd*)
  73     AC_MSG_NOTICE(found FreeBSD - Adding -lmd -lkvm -lcom_err to standard libraries)
  74     LIBS="$LIBS -lmd -lkvm -lcom_err"
  75     ;;
  76 # Check for LynxOS special case: -lbsd needed (at least on 2.3.0) and -s
  77 # not working.
  78 lynxos*)
  79     AC_MSG_NOTICE(found LynxOS - Adding -lbsd to standard libraries)
  80     LIBS="$LIBS -lbsd"
  81     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
  82     AC_MSG_NOTICE(found LynxOS - Prepending standard include path to gcc flags)
  83     CPFLAGS="-I/usr/include"
  84     ;;
  85 # Check for Rhapsody special case: it doesn't like -s
  86 rhapsody*)
  87     AC_MSG_NOTICE(found Rhapsody - Removing -s load flag)
  88     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
  89     ;;
  90 esac
  91
  92 dnl i18n
  93 AM_GNU_GETTEXT([external], [need-ngettext])
  94 AM_GNU_GETTEXT_VERSION(0.14.3)
  95 dnl end i18n
  96
  97 # Under sysV68, socket and friends are provided by the C library.
  98 # -linet does not provide socket, but causes multiple definition
  99 # errors at link-time.  It is thus better to only use the C library.
 100 # So don't add -linet to the link list unless it's necessary
 101 AC_CHECK_FUNC(socket,
 102     AC_MSG_RESULT(using libc's socket),
 103     AC_CHECK_LIB(socket,socket)
 104     AC_CHECK_LIB(inet,socket))
 105
 106 # The condition in this test copes with the presence of inet_addr in libc6.
 107 AC_CHECK_FUNC(inet_addr,
 108     AC_MSG_RESULT(using libc's inet_addr),
 109     AC_CHECK_LIB(nsl,inet_addr))
 110
 111 dnl Port hack for Interactive UNIX System V/386 Release 3.2
 112 AC_CHECK_LIB(cposix, strchr,
 113                 [DEFS="$DEFS -D_SYSV3"
 114                 LIBS="$LIBS -lcposix"])
 115
 116 dnl Port hack for Sparc/NetBSD-1.5
 117 dnl
 118 dnl NB: this has been disabled as it causes the unconditional
 119 dnl addition of libintl to the build, which is both undesired
 120 dnl and breaks on Solaris/Blastwave.org machines.
 121 dnl
 122 dnl AC_CHECK_LIB(intl, gettext,
 123 dnl             [LIBS="$LIBS -lintl"])
 124
 125 AC_REPLACE_FUNCS([strstr strcasecmp memmove stpcpy strlcpy strlcat])
 126
 127 AC_CHECK_FUNC(MD5Init, [],
 128               [AC_LIBSOURCE(md5c.c)
 129                EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"])
 130
 131 AC_CHECK_FUNC(getopt_long, [],
 132               [AC_LIBSOURCES([getopt.c, getopt1.c])
 133                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 134
 135 AC_FUNC_VPRINTF
 136
 137 AC_SUBST(EXTRAOBJ)
 138
 139 AC_CHECK_FUNCS(tcsetattr stty setsid geteuid seteuid dnl
 140   strerror syslog snprintf vprintf vsnprintf vsyslog dnl
 141   atexit inet_aton strftime setrlimit socketpair sigprocmask dnl
 142   sigaction strdup setlocale)
 143
 144 AC_CHECK_DECLS(strerror)
 145
 146 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 147 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 148 # library.  So don't add -lresolv to the link list unless it's necessary
 149 # (It will be necessary when using GNU libc6).
 150 old_LIBS="$LIBS"
 151 for lib in '' -lresolv; do
 152     if test -z "$lib"; then
 153        AC_MSG_CHECKING([for res_search in libc])
 154     else
 155        AC_MSG_CHECKING([for res_search in $lib])
 156     fi
 157     LIBS="$old_LIBS $lib"
 158     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 159 #include <sys/types.h>
 160 #ifdef HAVE_NETINET_IN_H
 161 #include <netinet/in.h>
 162 #endif
 163 #ifdef HAVE_ARPA_NAMESER_H
 164 #include <arpa/nameser.h>
 165 #endif
 166 #ifdef HAVE_RESOLV_H
 167 #include <resolv.h>
 168 #endif
 169 extern int res_search();
 170 ]], [[res_search(0, 0, 0, 0, 0);]])],
 171     [AC_MSG_RESULT([found])
 172      AC_DEFINE(HAVE_RES_SEARCH, [1],
 173                [Define to 1 if you have the 'res_search' function.])
 174      break], [AC_MSG_RESULT([not found])])
 175      LIBS=$old_LIBS
 176 done
 177
 178 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 179 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 180
 181 dnl Check for RSA refersence library in case we're using SSL
 182 AC_CHECK_LIB(rsaref, RSAPublicDecrypt)
 183
 184 dnl AC_FUNC_SETVBUF_REVERSED
 185
 186 dnl Check for usable void pointer type
 187 AC_MSG_CHECKING(use of void pointer type)
 188 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[char *p;
 189     void *xmalloc();
 190     p = (char *) xmalloc(1);
 191    ]])],[AC_DEFINE(HAVE_VOIDPOINTER,1,[Define if your C compiler allows void * as a function result]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 192
 193 dnl Check for ANSI volatile
 194 AC_C_VOLATILE
 195
 196 dnl Check out the wait reality.  We have to assume sys/wait.h is present.
 197 AC_CHECK_FUNCS(waitpid wait3)
 198 AC_MSG_CHECKING(for union wait);
 199 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 200 #include <sys/wait.h>]], [[union wait status; int pid; pid = wait (&status);
 201 #ifdef WEXITSTATUS
 202 /* Some POSIXoid systems have both the new-style macros and the old
 203    union wait type, and they do not work together.  If union wait
 204    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 205 if (WEXITSTATUS (status) != 0) pid = -1;
 206 #endif
 207 #ifdef HAVE_WAITPID
 208 /* Make sure union wait works with waitpid.  */
 209 pid = waitpid (-1, &status, 0);
 210 #endif
 211 ]])],[AC_DEFINE(HAVE_UNION_WAIT,1,Define if 'union wait' is the type of the first arg to wait functions.) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 212
 213 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 214 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 215 /* NetBSD declares sys_siglist in <unistd.h>.  */
 216 #ifdef HAVE_UNISTD_H
 217 #include <unistd.h>
 218 #endif]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 219
 220 # Find the right directory to put the root-mode PID file in
 221 for dir in "/var/run" "/etc"
 222 do
 223         if test -d $dir
 224         then
 225                 break;
 226         fi
 227 done
 228 AC_MSG_RESULT(root-mode pid file will go in $dir)
 229 AC_DEFINE_UNQUOTED(PID_DIR, "$dir", directory for PID lock files)
 230
 231 # We may have a fallback MDA available in case the socket open to the
 232 # local SMTP listener fails.  Best to use procmail for this, as we know
 233 # it won't try delivering through local SMTP and cause a mail loop.
 234 # Sendmail without the -t option to use the message headers will work too,
 235 # not just for sendmail itself but for workalikes like exim.
 236 #
 237 # Note1: A disadvantage of using procmail is that local alias expansion
 238 # according to /etc/aliases won't get done if we fall back.  This doesn't
 239 # matter in single-drop mode.
 240 #
 241 # Note2: it would be a very bad idea to use any MDA that doesn't return
 242 # a refuse-to-deliver status on disk- or process-table-full
 243 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 244 # like exim that might be lurking under a sendmail alias) do the right
 245 # thing in this circumstance.  Matthias Andree warns that procmail does
 246 # not.
 247 #
 248 # Note3: Defalt value of fallback is now off.  Matthias writes:
 249 #
 250 # 1. there is no way to predict when the fallback is used. With some MTAs
 251 #    (such as those limiting load average), outer circumstances can cause
 252 #    the fallback to kick in.
 253 #
 254 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 255 #    not only about alias expansion, .forwards to special filters won't
 256 #    work, mail may end up in a different place (users claim "mail loss"
 257 #    for that).
 258 #
 259 # 3. The claim procmail did the right thing with its exit codes is plain
 260 #    wrong. I've seen procmail exit with code 1 when it should have exited
 261 #    with code 75, like, configuration errors. Procmail is a dangerous
 262 #    beast and is best replaced by maildrop.
 263 #
 264 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 265 #    cannot tell which one it should choose. Say, your MTA is configured
 266 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 267 #    chooses procmail, this is plain wrong.
 268 #
 269
 270 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 271 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 272 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 273
 274 ###     use option --disable-fallback to disable fallback MDA
 275 ###     use option --enable-fallback=procmail or
 276 ###                --enable-fallback=sendmail to select
 277 AC_ARG_ENABLE(fallback,
 278         [  --enable-fallback=procmail    enable procmail as fallback
 279   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 280   --enable-fallback=maildrop    enable maildrop as fallback
 281   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 282
 283 case "$enable_fallback" in
 284         sendmail)       if test -z "$sendmail" ; then
 285                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 286                                 #not reached
 287                         fi
 288                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 289                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 290                         ;;
 291         procmail)       if test -z "$procmail" ; then
 292                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 293                                 #not reached
 294                         fi
 295                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 296                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 297                         ;;
 298         maildrop)       if test -z "$maildrop" ; then
 299                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 300                                 #not reached
 301                         fi
 302                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 303                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 304                         ;;
 305         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 306                         ;;
 307         auto|yes|set)   if test -n "$sendmail" ; then
 308                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 309                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 310                         else
 311                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 312                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 313                         fi
 314                         ;;
 315         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 316                         #notreached
 317                         ;;
 318 esac
 319
 320 AC_CHECK_SIZEOF(short)
 321 AC_CHECK_SIZEOF(int)
 322 AC_CHECK_SIZEOF(long)
 323
 324 ###     use option --enable-POP2 to compile in the POP2 support
 325 AC_ARG_ENABLE(POP2,
 326         [  --enable-POP2           compile in POP2 protocol support (obsolete)],
 327         [with_POP2=$enableval],
 328         [with_POP2=no])
 329 test "$with_POP2" = "yes" && AC_DEFINE(POP2_ENABLE,1,Define if you want POP2 support compiled in)
 330
 331 ###     use option --disable-POP3 to omit the POP3 support
 332 AC_ARG_ENABLE(POP3,
 333         [  --disable-POP3          don't compile in POP3 protocol support],
 334         [with_POP3=$enableval],
 335         [with_POP3=yes])
 336 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 337
 338 ###     use option --disable-IMAP to omit the IMAP support
 339 AC_ARG_ENABLE(IMAP,
 340         [  --disable-IMAP          don't compile in IMAP protocol support],
 341         [with_IMAP=$enableval],
 342         [with_IMAP=yes])
 343 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,"Define if you want IMAP support compiled in")
 344
 345 ###     use option --disable-ETRN to omit the ETRN support
 346 AC_ARG_ENABLE(ETRN,
 347         [  --disable-ETRN          don't compile in ETRN protocol support],
 348         [with_ETRN=$enableval],
 349         [with_ETRN=yes])
 350 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 351
 352 ###     use option --disable-ODMR to omit the ODMR support
 353 AC_ARG_ENABLE(ODMR,
 354         [  --disable-ODMR          don't compile in ODMR protocol support],
 355         [with_ODMR=$enableval],
 356         [with_ODMR=yes])
 357 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 358
 359 ###     use option --enable-RPA to compile in the RPA support
 360 AC_ARG_ENABLE(RPA,
 361         [  --enable-RPA            compile in RPA protocol support],
 362         [with_RPA=$enableval],
 363         [with_RPA=no])
 364 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 365
 366 ###     use option --enable-NTLM to compile in the NTLM support
 367 AC_ARG_ENABLE(NTLM,
 368         [  --enable-NTLM           compile in NTLM authentication support],
 369         [with_NTLM=$enableval],
 370         [with_NTLM=no])
 371 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 372
 373 ###     use option --enable-SDPS to compile in the SDPS support
 374 AC_ARG_ENABLE(SDPS,
 375         [  --enable-SDPS           compile in SDPS protocol support],
 376         [with_SDPS=$enableval],
 377         [with_SDPS=no])
 378 if test "$with_SDPS" = yes ; then
 379    if test "$with_POP3" != yes ; then
 380        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 381        with_SDPS=no
 382    else
 383        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 384    fi
 385 fi
 386
 387 ###     use option --enable-opie to compile in the OPIE support
 388 AC_ARG_ENABLE(opie,
 389         [  --enable-opie           support OTP through the OPIE library],
 390         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR(cannot find <opie.h>, which is required for OPIE support.)])
 391           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR(cannot find libopie, which is required for OPIE support.)])
 392           with_opie=$enableval],
 393         [with_opie=no])
 394 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 395
 396 AC_SEARCH_LIBS(getaddrinfo, inet6, [AC_DEFINE(HAVE_GETADDRINFO,1,[define to 1 if you have the getaddrinfo function])])
 397 AC_CHECK_FUNCS(getnameinfo)
 398
 399 # This version of the Kerberos 4 and 5 options addresses the follwing issues:
 400 #
 401 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 402 #   OpenSSL support (Debian's is)
 403 # * Build the kerberos.c stuff (KPOP) only for kerberosIV, to avoid breakage.
 404 #   I don't know if this is 100% correct, but now at least IMAP and POP3
 405 #   behave the same way regarding kerberosV.
 406 # * Build without any fuss for both kerberosIV and V at the same time.
 407 # * Move all the kerberos header mess to kerberos.h, and #include that
 408 #   in driver.c and kerberos.c.
 409 #
 410 # Tested using the Heimdal Kerberos V libs, Kungliga Tekniska Högskolan (the
 411 # Royal Institute of Technology in Stockholm, Sweden)'s kerberos IV libs, and
 412 # the MIT reference implementation of KerberosV (all as packaged in Debian).
 413
 414 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 415 ### make sure --with-ssl is run before --with-kerberos* !
 416 AC_ARG_WITH(kerberos5,
 417        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 418 [
 419 if test "$with_kerberos5" != "no"
 420 then
 421 # Check for a OpenBSD special case
 422 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 423 then
 424   AS_MESSAGE(checking kerberosV for OpenBSD...)
 425   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 426   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 427   CEFLAGS="$CEFLAGS -I/usr/include/kerberosV"
 428   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 429 elif krb5-config 2> /dev/null >/dev/null ; then
 430   krb5_prefix=`krb5-config --prefix krb5`
 431   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 432   if test -f ${krb5_prefix}/include/et/com_err.h && \
 433    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 434     CEFLAGS="$CEFLAGS -I${krb5_prefix}/include/et"
 435   fi
 436   unset krb5_prefix
 437   CEFLAGS="$CEFLAGS `krb5-config --cflags krb5`"
 438   LIBS="$LIBS `krb5-config --libs krb5`"
 439   AC_DEFINE(KERBEROS_V5)
 440 else
 441   if test "$with_kerberos5" != "yes"
 442   then
 443       LDEFLAGS="$LDEFLAGS -L${with_kerberos5}/lib"
 444       searchdirs="$with_kerberos5"
 445   else
 446       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 447   fi
 448   with_kerberos5=
 449   for dir in $searchdirs
 450   do AC_MSG_CHECKING([for Kerberos V in $dir])
 451      if test -f "$dir/include/krb5.h"
 452      then
 453         ac_krblibs=
 454         if test -f "$dir/include/roken.h"
 455         then
 456            ac_krblibs="-lasn1 -lroken -lcom_err"
 457            AC_MSG_RESULT([Heimdal found])
 458           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 459           dnl we assume we do if it is available
 460            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 461                 ${LDEFLAGS})
 462            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 463               AC_CHECK_LIB(ssl, MD5_Init, [],
 464                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 465                 ${LDEFLAGS} ${ac_krblibs}),
 466            ${LDEFLAGS} ${ac_krblibs})
 467            AC_DEFINE(HEIMDAL)
 468         else
 469           AC_MSG_RESULT([found])
 470           ac_krblibs="-lcom_err"
 471            AC_CHECK_LIB(crypto,
 472              krb5_des_string_to_key,
 473              libk5crypto=-lcrypto,
 474                 AC_CHECK_LIB(k5crypto,
 475                    krb5_des_string_to_key,
 476                    libk5crypto=-lk5crypto,
 477                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 478                    ${LDEFLAGS} ${ac_krblibs}),
 479                  ${LDEFLAGS} ${ac_krblibs})
 480         fi
 481         AC_CHECK_LIB(krb5, krb5_init_context,[],
 482            continue,
 483            ${LDEFLAGS} ${ac_krblibs})
 484         AC_DEFINE(KERBEROS_V5)
 485         test "$dir" != "/usr" && CEFLAGS="$CEFLAGS -I$dir/include"
 486         LDEFLAGS="$LDEFLAGS -L$dir/lib"
 487        LIBS="$LIBS $ac_krblibs $libk5crypto"
 488         with_kerberos5=$dir
 489         break
 490      else
 491         AC_MSG_RESULT([not found])
 492      fi
 493   done
 494   if test -z "$with_kerberos5" ; then
 495      AC_MSG_ERROR([Kerberos 5 libraries not found])
 496   fi
 497 fi
 498 fi
 499 ]) dnl --with-kerberos5=DIR
 500
 501 ###    use option --with-kerberos=DIR to point at a Kerberos 4 directory
 502 AC_ARG_WITH(kerberos,
 503        [  --with-kerberos=DIR     point fetchmail compilation at a Kerberos 4 directory],
 504 [
 505 if test "$with_kerberos" != "no"
 506 then
 507     AC_MSG_WARN([Kerberos IV support is obsolete. Use --with-kerberos5 if possible.])
 508 # Check for a NetBSD/OpenBSD special case
 509 if test "$with_kerberos" = "yes" && ( test `uname` = "NetBSD" || test `uname` = "OpenBSD" )
 510 then
 511   AS_MESSAGE(checking kerberosIV for `uname`...)
 512   AC_DEFINE(KERBEROS_V4,1,Define if you have Kerberos V4)
 513   CEFLAGS="$CEFLAGS -I/usr/include/kerberosIV"
 514   case `uname` in
 515       NetBSD)  LIBS="$LIBS -lkrb -ldes -lroken -lcom_err" ;;
 516       OpenBSD) LIBS="$LIBS -lkrb -ldes" ;;
 517   esac
 518 elif krb4-config 2> /dev/null >/dev/null ; then
 519   krb4_prefix=`krb4-config --prefix`
 520   AC_MSG_RESULT([krb4-config points to kerberosIV under $krb4_prefix])
 521   unset krb4_prefix
 522   CEFLAGS="$CEFLAGS `krb4-config --cflags`"
 523   LIBS="$LIBS `krb4-config --libs`"
 524   AC_DEFINE(KERBEROS_V4)
 525 elif krb5-config 2> /dev/null >/dev/null ; then
 526   krb4_prefix=`krb5-config --prefix krb4`
 527   AC_MSG_RESULT([krb5-config points to kerberosIV under $krb4_prefix])
 528   if test -f ${krb4_prefix}/include/kerberosIV/krb.h ; then
 529     AC_DEFINE(KERBEROS_V4_V5,1,Define if you have Kerberos V4 headers under a kerberosIV directory)
 530   fi
 531   unset krb4_prefix
 532   CEFLAGS="$CEFLAGS `krb5-config --cflags krb4`"
 533   LIBS="$LIBS `krb5-config --libs krb4`"
 534   AC_DEFINE(KERBEROS_V4)
 535 else
 536   #we need to detect when we're building under a kerberosV compatibility
 537   #layer, btw...
 538   if test "$with_kerberos" != "yes" ; then
 539      searchdirs="$with_kerberos"
 540   else
 541      searchdirs="$with_kerberos5 /usr/kerberos /usr/kerberosIV /usr/athena /usr"
 542   fi
 543   with_kerberos=
 544   ac_saveLDFLAGS="$LDFLAGS"
 545   for dir in $searchdirs
 546   do
 547      AC_MSG_CHECKING([for Kerberos IV in $dir])
 548      if test -f "$dir/include/krb.h" || test -f "$dir/include/krb4.h" \
 549             || test -f "$dir/include/kerberosIV/krb.h"
 550      then
 551         AC_MSG_RESULT([found])
 552      else
 553         AC_MSG_RESULT([not found])
 554        continue
 555      fi
 556      #Find libs
 557      if test -f "$with_kerberos5/roken.h" ; then
 558        AC_CHECK_LIB(45, krb_mk_req)
 559      fi
 560      LDFLAGS="-L$dir/lib $ac_saveLDFLAGS"
 561      if test `uname` = "FreeBSD"; then
 562         AC_SEARCH_LIBS(_ossl_old_des_string_to_key, [des425 des crypto], [], continue)
 563      else
 564         AC_SEARCH_LIBS(des_string_to_key, [crypto], [], continue)
 565      fi
 566      AC_SEARCH_LIBS(krb_realmofhost, [krb4 krb], [], continue)
 567      with_kerberos="$dir"
 568      if test -f "$dir/include/kerberosIV/krb.h" ; then
 569         dir="$dir/include/kerberosIV"
 570      else
 571        dir="$dir/include"
 572      fi
 573      AC_DEFINE(KERBEROS_V4)
 574      test -f "$with_kerberos5/roken.h" && AC_DEFINE(HEIMDAL)
 575      test "$dir" != "/usr/include" && CEFLAGS="$CEFLAGS -I$dir"
 576      LDEFLAGS="$LDEFLAGS -L$with_kerberos/lib"
 577      break
 578   done
 579   if test -z "$with_kerberos" ; then
 580      AC_MSG_ERROR([Kerberos 4 libraries not found])
 581   fi
 582   LDFLAGS="$ac_saveLDFLAGS"
 583 fi
 584 fi
 585 ]) dnl --with-kerberos=DIR
 586
 587 ###     use option --with-ssl to compile in the SSL support
 588 AC_ARG_WITH(ssl,
 589         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 590         [with_ssl=$withval],
 591         [with_ssl=no])
 592 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 593
 594 if test "$with_ssl" = "yes"
 595 then
 596     #   He didn't specify an SSL location.  Let's look at some common
 597     #   directories where SSL has been found in the past and try and auto
 598     #   configure for SSL.  OpenSSL determination will be made later.
 599     #   This will screw up if an OpenSSL install is located in a later
 600     #   directory than an older SSLeay install, but the user should fix that
 601     #   anyways and he can override on the configure line.
 602     #   Just testing for directories is not sufficient, /usr exists on
 603     #   all systems!
 604     for ac_dir in \
 605       /usr/local/ssl \
 606       /usr/local \
 607       /usr/ssl \
 608       /usr \
 609       /local/ssl \
 610       /opt/ssl \
 611       /opt/csw \
 612       ; \
 613     do
 614         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 615             with_ssl=$ac_dir
 616             break;
 617         fi
 618     done
 619 fi
 620
 621 if test -n "$with_ssl" -a "$with_ssl" != "no"
 622 then
 623   # With the autoconfigure above, the only time this is going to be
 624   # true is going to be when we could not find the headers.  If they
 625   # are not in system standard locations, we are going to be broken.
 626   if test "$with_ssl" = "yes"
 627   then
 628     # Let's just define the standard location for the SSLeay root
 629     with_ssl="/usr/local/ssl"
 630   fi
 631   if test -r $with_ssl/include/openssl/ssl.h
 632   then
 633     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 634     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 635     test "$with_ssl" != "/usr" && CEFLAGS="$CEFLAGS -I$with_ssl/include"
 636     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 637     ### force the Kerberos direcory onto the include path so it will build.
 638     CEFLAGS="$CEFLAGS -I/usr/kerberos/include"
 639     ### OpenBSD comes with ssl headers
 640   else
 641     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 642   fi
 643   LDEFLAGS="$LDEFLAGS -L$with_ssl/lib"
 644   LIBS="$LIBS -lssl -lcrypto"
 645   dnl check if -ldl is needed
 646   AC_MSG_CHECKING([for additional library dependencies of SSL])
 647   found=0
 648   save_LIBS="$LIBS"
 649   for i in "" "-ldl" ; do
 650       LIBS="$LDEFLAGS $save_LIBS $i"
 651       AC_LINK_IFELSE([AC_LANG_PROGRAM(,[SSL_library_init()])],[found=1; break])
 652   done
 653   if test $found = 0 ; then
 654       AC_MSG_RESULT([error])
 655       AC_MSG_ERROR([cannot link with SSL - check config.log])
 656   fi
 657   LIBS="$save_LIBS $i"
 658   if test "$i" = "" ; then i="(none)" ; fi
 659   AC_MSG_RESULT($i)
 660   dnl XXX FIXME: use pkg-config if available!
 661   AC_DEFINE(SSL_ENABLE)
 662 else
 663   AC_MSG_NOTICE(Disabling SSL support.)
 664 fi
 665
 666 ###     use option --with-socks=DIR to point at SOCKS library
 667 AC_ARG_WITH(socks,
 668         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 669 [
 670 if test "$with_socks" != no
 671 then
 672     if test "$with_socks" != yes
 673     then
 674         LDEFLAGS="$LDEFLAGS -L$with_socks"
 675     else
 676         AC_CHECK_LIB(socks, Rconnect,,
 677                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 678     fi
 679     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 680     CEFLAGS="$CEFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 681     LIBS="-lsocks $LIBS"
 682 fi])
 683
 684 ###     use option --with-socks5=DIR to point at SOCKS library
 685 AC_ARG_WITH(socks5,
 686         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 687 [
 688 if test "$with_socks5" != no
 689 then
 690   if test "$with_socks5" != yes
 691   then
 692     LDEFLAGS="$LDEFLAGS -L$with_socks5"
 693   fi
 694   ac_savedLDFLAGS="$LDFLAGS"
 695   LDFLAGS="$LDEFLAGS $LDFLAGS"
 696   AC_CHECK_LIB(socks5, SOCKSconnect,,
 697         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 698   AC_DEFINE(HAVE_SOCKS)
 699   CEFLAGS="$CEFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 700   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 701   LDFLAGS="$ac_savedLDFLAGS"
 702 fi])
 703
 704 ACX_WHICH_GETHOSTBYNAME_R
 705
 706 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 707 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 708
 709 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 710 AC_ARG_WITH(gssapi,
 711         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 712 [
 713 if test "$with_gssapi" != "no"
 714 then
 715   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 716   then
 717     with_gssapi=$with_kerberos5
 718   fi
 719   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 720   then
 721     CFLAGS="$CFLAGS -I$with_gssapi/include"
 722     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 723   fi
 724
 725   AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 726   if test -n "$nogss"
 727   then
 728   if test -f "$with_gssapi/include/roken.h"
 729   then
 730      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl"
 731      AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 732                   AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 733      AC_DEFINE(HEIMDAL)
 734   else
 735      AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 736                   AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 737   fi
 738   fi
 739   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 740   save_CPPFLAGS=$CPPFLAGS
 741   CPPFLAGS="-I$with_gssapi/include"
 742   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 743   if test "$ac_cv_header_gssapi_h" = "yes"; then
 744     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 745   else
 746     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 747   fi
 748 fi])
 749
 750 AC_SUBST(CPFLAGS)
 751 AC_SUBST(CEFLAGS)
 752 AC_SUBST(LDEFLAGS)
 753
 754 dnl ,------------------------------------------------------------------
 755 dnl Check if we need TRIO
 756 needtrio=0
 757 if test "$FORCE_TRIO" = "yes" ; then
 758     needtrio=1
 759     ac_cv_func_vsnprintf=no
 760     ac_cv_func_snprintf=no
 761 fi
 762 if test "x$ac_cv_func_snprintf" != "xyes" ; then
 763     AC_DEFINE(snprintf, trio_snprintf,
 764               [Define to trio_snprintf if your system lacks snprintf])
 765     needtrio=1
 766 fi
 767 if test "x$ac_cv_func_vsnprintf" != "xyes" ; then
 768     AC_DEFINE(vsnprintf, trio_vsnprintf,
 769               [Define to trio_vsnprintf if your system lacks vsnprintf])
 770     needtrio=1
 771 fi
 772 AM_CONDITIONAL(NEED_TRIO, test "$needtrio" = 1)
 773
 774 dnl TRIO IEEE compiler option for Alpha
 775 dnl
 776 if test "$needtrio" = 1 ; then
 777     AC_MSG_CHECKING(for IEEE compilation options)
 778     AC_CACHE_VAL(ac_cv_ieee_option, [
 779     AC_TRY_COMPILE(,[
 780     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
 781     # error "Option needed"
 782     #endif
 783     ],ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
 784     AC_TRY_COMPILE(,[
 785     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
 786     # error "Option needed"
 787     #endif
 788     ],ac_cv_ieee_option="-ieee",
 789     AC_TRY_COMPILE(,[
 790     #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
 791     # error "Option needed"
 792     #endif
 793     ],ac_cv_ieee_option="-mieee",
 794     ac_cv_ieee_option="none"
 795     )
 796     )
 797     )
 798     ])
 799     AC_MSG_RESULT($ac_cv_ieee_option)
 800     if test $ac_cv_ieee_option != none; then
 801       CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
 802     fi
 803 fi
 804 dnl ----------------------------------------------------------------'
 805
 806 AC_CONFIG_FILES([Makefile m4/Makefile po/Makefile.in genlsm.sh])
 807 AC_OUTPUT
 808
 809 dnl Local Variables:
 810 dnl comment-start: "dnl "
 811 dnl comment-end: ""
 812 dnl comment-start-skip: "\\bdnl\\b\\s *"
 813 dnl compile-command: "make configure config.h.in"
 814 dnl End: