Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 #
   3 # Fetchmail automatic configuration support
   4 #
   5 # Eric S. Raymond <esr@thyrsus.com>
   6 # 2004 - 2010 Matthias Andree <matthias.andree@gmx.de>
   7 #
   8 dnl Process this file with autoconf to produce a configure script.
   9 dnl
  10
  11 dnl XXX - if bumping version here, check fetchmail.man, too!
  12 AC_INIT([fetchmail],[6.4.0-alpha1],[fetchmail-devel@lists.berlios.de])
  13 AC_CONFIG_SRCDIR([fetchmail.h])
  14 AC_CONFIG_HEADERS([config.h])
  15 AC_CONFIG_LIBOBJ_DIR([.])
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl automake options are in Makefile.am
  20 AC_PREREQ(2.60)
  21 dnl 2.60 required for AC_USE_SYSTEM_EXTENSIONS
  22 AM_INIT_AUTOMAKE
  23
  24 dnl python is optional
  25 #
  26 # you can pass PYTHON=: in environment or on the command line
  27 # to disable python detection and continue without building/installing
  28 # fetchmail.conf -- be sure to check README.packaging, too!
  29 #
  30 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  31 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  32
  33 AC_PROG_AWK
  34 AC_PROG_CC
  35 AM_PROG_CC_C_O
  36 AC_PROG_CPP                     dnl Later checks need this.
  37 AC_PROG_INSTALL
  38 AM_PROG_LEX
  39 AC_PROG_MAKE_SET
  40 AC_PROG_RANLIB
  41 AC_PROG_YACC
  42
  43 AC_USE_SYSTEM_EXTENSIONS
  44
  45 dnl check for b0rked Solaris (and other shells) and find one that works
  46 AC_MSG_CHECKING(for a working shell...)
  47 for i in /usr/xpg6/bin/sh /usr/xpg4/bin/sh /usr/ccs/bin/sh /bin/sh /usr/bin/sh /bin/ksh /bin/bash /usr/local/bin/bash ; do
  48     $i -c 'if ! false ; then echo $(echo ok) ; fi' >config.$$ 2>/dev/null
  49     j=`cat config.$$`
  50     rm -f config.$$
  51     if test "x$j" = "xok" ; then
  52         SHELL=$i
  53         AC_SUBST(SHELL)
  54         break
  55     fi
  56 done
  57 AC_MSG_RESULT($SHELL)
  58 if test "x$SHELL" = "x" ; then
  59     AC_MSG_ERROR(no SUS compliant shell found - on Solaris, install SUNWxcu4)
  60 fi
  61
  62
  63 AC_CHECK_HEADERS([arpa/nameser.h md5.h])
  64
  65 AC_CHECK_HEADERS([resolv.h],,,[
  66 #include <sys/types.h>
  67 #include <netinet/in.h>
  68 #ifdef HAVE_ARPA_NAMESER_H
  69 #include <arpa/nameser.h>
  70 #endif
  71 ])
  72
  73 AC_CHECK_DECLS([h_errno],,,[
  74         AC_INCLUDES_DEFAULT
  75         #include <netdb.h>
  76 ])
  77
  78 AC_C_CONST                      dnl getopt needs this.
  79
  80 # Check for OS special cases
  81 case $host_os in
  82 darwin*)
  83     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
  84     CPPFLAGS="$CPPFLAGS -DBIND_8_COMPAT"
  85     ;;
  86 # Check for FreeBSD special case: more libs needed
  87 freebsd*)
  88     AC_MSG_NOTICE(found FreeBSD - Adding -lkvm -lcom_err to standard libraries)
  89     LIBS="$LIBS -lkvm -lcom_err"
  90     ;;
  91 esac
  92
  93 AC_CACHE_SAVE
  94
  95 dnl i18n
  96 AM_GNU_GETTEXT([external], [need-ngettext])
  97 AM_GNU_GETTEXT_VERSION([0.17])
  98 dnl end i18n
  99
 100 # Under sysV68, socket and friends are provided by the C library.
 101 # -linet does not provide socket, but causes multiple definition
 102 # errors at link-time.  It is thus better to only use the C library.
 103 # So don't add -linet to the link list unless it's necessary
 104 AC_CHECK_FUNC(socket,
 105     AC_MSG_RESULT(using libc's socket),
 106     AC_CHECK_LIB(socket,socket)
 107     AC_CHECK_LIB(inet,socket))
 108
 109 # The condition in this test copes with the presence of inet_addr in libc6.
 110 AC_CHECK_FUNC(inet_addr,
 111     AC_MSG_RESULT(using libc's inet_addr),
 112     AC_CHECK_LIB(nsl,inet_addr))
 113
 114 AC_REPLACE_FUNCS([stpcpy strlcpy strlcat])
 115
 116 have_md5=no
 117 if test "$ac_cv_header_md5_h" != no ; then
 118     AC_SEARCH_LIBS(MD5Init, [md], [have_md5=yes])
 119 fi
 120
 121 if test "$have_md5" != yes ; then
 122     AC_LIBSOURCE(md5c.c)
 123     EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"
 124 fi
 125
 126 AC_CHECK_FUNC(getopt_long, [],
 127               [AC_LIBSOURCES([getopt.c, getopt1.c])
 128                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 129
 130 AC_SUBST(EXTRAOBJ)
 131
 132 AC_CHECK_FUNCS(vsyslog inet_aton)
 133
 134 dnl INET6 is used by KAME/getnameinfo
 135 AC_CACHE_CHECK(for AF_INET6/PF_INET6,ac_cv_inet6,
 136 AC_COMPILE_IFELSE([
 137   AC_LANG_PROGRAM([[
 138     #include <sys/types.h>
 139     #include <sys/socket.h>
 140   ]],[[
 141     int foo = AF_INET6;
 142     int bar = PF_INET6;
 143   ]])],
 144   ac_cv_inet6=yes , ac_cv_inet6=no
 145 ))
 146 if test "x$ac_cv_inet6" = xyes
 147 then
 148     AC_DEFINE(INET6,1,Define to 1 if your system defines AF_INET6 and PF_INET6.)
 149 fi
 150
 151 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 152 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 153 # library.  So don't add -lresolv to the link list unless it's necessary
 154 # (It will be necessary when using GNU libc6).
 155 old_LIBS="$LIBS"
 156 for lib in '' -lresolv; do
 157     if test -z "$lib"; then
 158        AC_MSG_CHECKING([for res_search in libc])
 159     else
 160        AC_MSG_CHECKING([for res_search in $lib])
 161     fi
 162     LIBS="$old_LIBS $lib"
 163     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 164 #include <sys/types.h>
 165 #include <netinet/in.h>
 166 #ifdef HAVE_ARPA_NAMESER_H
 167 #include <arpa/nameser.h>
 168 #endif
 169 #ifdef HAVE_RESOLV_H
 170 #include <resolv.h>
 171 #endif
 172 extern int res_search();
 173 ]], [[res_search(0, 0, 0, 0, 0); dn_skipname(0,0);]])],
 174     [AC_MSG_RESULT([found])
 175      AC_DEFINE(HAVE_RES_SEARCH, [1],
 176                [Define to 1 if you have the 'res_search' and 'dn_skipname' functions.])
 177      break], [AC_MSG_RESULT([not found])])
 178      LIBS=$old_LIBS
 179 done
 180
 181 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 182 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 183
 184 dnl Check for ANSI volatile
 185 AC_C_VOLATILE
 186
 187 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 188 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 189 /* NetBSD declares sys_siglist in <unistd.h>.  */
 190 #include <unistd.h>
 191 ]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 192
 193 AC_DEFINE_UNQUOTED(PID_DIR, "/var/run", directory for PID lock files)
 194
 195 # We may have a fallback MDA available in case the socket open to the
 196 # local SMTP listener fails.  Best to use procmail for this, as we know
 197 # it won't try delivering through local SMTP and cause a mail loop.
 198 # Sendmail without the -t option to use the message headers will work too,
 199 # not just for sendmail itself but for workalikes like exim.
 200 #
 201 # Note1: A disadvantage of using procmail is that local alias expansion
 202 # according to /etc/aliases won't get done if we fall back.  This doesn't
 203 # matter in single-drop mode.
 204 #
 205 # Note2: it would be a very bad idea to use any MDA that doesn't return
 206 # a refuse-to-deliver status on disk- or process-table-full
 207 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 208 # like exim that might be lurking under a sendmail alias) do the right
 209 # thing in this circumstance.  Matthias Andree warns that procmail does
 210 # not.
 211 #
 212 # Note3: Defalt value of fallback is now off.  Matthias writes:
 213 #
 214 # 1. there is no way to predict when the fallback is used. With some MTAs
 215 #    (such as those limiting load average), outer circumstances can cause
 216 #    the fallback to kick in.
 217 #
 218 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 219 #    not only about alias expansion, .forwards to special filters won't
 220 #    work, mail may end up in a different place (users claim "mail loss"
 221 #    for that).
 222 #
 223 # 3. The claim procmail did the right thing with its exit codes is plain
 224 #    wrong. I've seen procmail exit with code 1 when it should have exited
 225 #    with code 75, like, configuration errors. Procmail is a dangerous
 226 #    beast and is best replaced by maildrop.
 227 #
 228 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 229 #    cannot tell which one it should choose. Say, your MTA is configured
 230 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 231 #    chooses procmail, this is plain wrong.
 232 #
 233
 234 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 235 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 236 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 237
 238 ###     use option --disable-fallback to disable fallback MDA
 239 ###     use option --enable-fallback=procmail or
 240 ###                --enable-fallback=sendmail to select
 241 AC_ARG_ENABLE(fallback,
 242         [  --enable-fallback=procmail    enable procmail as fallback
 243   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 244   --enable-fallback=maildrop    enable maildrop as fallback
 245   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 246
 247 case "$enable_fallback" in
 248         sendmail)       if test -z "$sendmail" ; then
 249                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 250                                 #not reached
 251                         fi
 252                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 253                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 254                         ;;
 255         procmail)       if test -z "$procmail" ; then
 256                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 257                                 #not reached
 258                         fi
 259                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 260                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 261                         ;;
 262         maildrop)       if test -z "$maildrop" ; then
 263                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 264                                 #not reached
 265                         fi
 266                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 267                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 268                         ;;
 269         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 270                         ;;
 271         auto|yes|set)   if test -n "$sendmail" ; then
 272                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 273                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 274                         else
 275                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 276                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 277                         fi
 278                         ;;
 279         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 280                         #notreached
 281                         ;;
 282 esac
 283
 284 ###     use option --disable-POP3 to omit the POP3 support
 285 AC_ARG_ENABLE(POP3,
 286         [  --disable-POP3          don't compile in POP3 protocol support],
 287         [with_POP3=$enableval],
 288         [with_POP3=yes])
 289 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 290 AM_CONDITIONAL(POP3_ENABLE, test "$with_POP3" = yes)
 291
 292 ###     use option --disable-IMAP to omit the IMAP support
 293 AC_ARG_ENABLE(IMAP,
 294         [  --disable-IMAP          don't compile in IMAP protocol support],
 295         [with_IMAP=$enableval],
 296         [with_IMAP=yes])
 297 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,Define if you want IMAP support compiled in)
 298 AM_CONDITIONAL(IMAP_ENABLE, test "$with_IMAP" = yes)
 299
 300 ###     use option --disable-ETRN to omit the ETRN support
 301 AC_ARG_ENABLE(ETRN,
 302         [  --disable-ETRN          don't compile in ETRN protocol support],
 303         [with_ETRN=$enableval],
 304         [with_ETRN=yes])
 305 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 306 AM_CONDITIONAL(ETRN_ENABLE, test "$with_ETRN" = yes)
 307
 308 ###     use option --disable-ODMR to omit the ODMR support
 309 AC_ARG_ENABLE(ODMR,
 310         [  --disable-ODMR          don't compile in ODMR protocol support],
 311         [with_ODMR=$enableval],
 312         [with_ODMR=yes])
 313 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 314 AM_CONDITIONAL(ODMR_ENABLE, test "$with_ODMR" = yes)
 315
 316 ###     use option --enable-RPA to compile in the RPA support
 317 AC_ARG_ENABLE(RPA,
 318         [  --enable-RPA            compile in RPA protocol support],
 319         [with_RPA=$enableval],
 320         [with_RPA=no])
 321 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 322 AM_CONDITIONAL(RPA_ENABLE, test "$with_RPA" = yes)
 323
 324 ###     use option --enable-NTLM to compile in the NTLM support
 325 AC_ARG_ENABLE(NTLM,
 326         [  --enable-NTLM           compile in NTLM authentication support],
 327         [with_NTLM=$enableval],
 328         [with_NTLM=no])
 329 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 330 AM_CONDITIONAL(NTLM_ENABLE, test "$with_NTLM" = yes)
 331
 332 ###     use option --enable-SDPS to compile in the SDPS support
 333 AC_ARG_ENABLE(SDPS,
 334         [  --enable-SDPS           compile in SDPS protocol support],
 335         [with_SDPS=$enableval],
 336         [with_SDPS=no])
 337 if test "$with_SDPS" = yes ; then
 338    if test "$with_POP3" != yes ; then
 339        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 340        with_SDPS=no
 341    else
 342        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 343    fi
 344 fi
 345 if test "$with_POP3" != yes && test "$with_IMAP"  != yes ; then
 346     AC_MSG_ERROR([You must enable at least one of POP3 and IMAP.])
 347 fi
 348
 349 AC_CACHE_SAVE
 350
 351 ###     use option --enable-opie to compile in the OPIE support
 352 AC_ARG_ENABLE(opie,
 353         [  --enable-opie           support OTP through the OPIE library],
 354         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR(cannot find <opie.h>, which is required for OPIE support.)])
 355           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR(cannot find libopie, which is required for OPIE support.)])
 356           with_opie=$enableval],
 357         [with_opie=no])
 358 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 359
 360 dnl Mostly stolen from gnulib's getaddrinfo.m4
 361 AC_SEARCH_LIBS(getaddrinfo, [nsl socket])
 362 AC_CACHE_CHECK([for getaddrinfo],[fm_cv_getaddrinfo],[
 363   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 364 #include <sys/types.h>
 365 #include <sys/socket.h>
 366 #include <netdb.h>
 367   ]], [[getaddrinfo(0, 0, 0, 0);]])],[ fm_cv_getaddrinfo=yes],[ fm_cv_getaddrinfo=no ])
 368 ])
 369
 370 if test x"$fm_cv_getaddrinfo" = "xyes"; then
 371      AC_DEFINE(HAVE_GETADDRINFO, 1,
 372       [Define to 1 if you have the getaddrinfo function.])
 373 fi
 374
 375 AC_CACHE_CHECK([for getnameinfo],[fm_cv_getnameinfo],[
 376   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 377 #include <sys/types.h>
 378 #include <sys/socket.h>
 379 #include <netdb.h>
 380 #ifndef NULL
 381 #define NULL 0
 382 #endif
 383   ]], [[getnameinfo(NULL,0, NULL,0, NULL, 0, 0);]])],[ fm_cv_getnameinfo=yes],[ fm_cv_getnameinfo=no ])
 384 ])
 385 if test $fm_cv_getnameinfo = yes ; then
 386     AC_DEFINE(HAVE_GETNAMEINFO,1,[Define to 1 if your system has getnameinfo()])
 387 fi
 388
 389 AM_CONDITIONAL(NEED_GETADDRINFO, test "$fm_cv_getaddrinfo" != yes)
 390 AM_CONDITIONAL(NEED_GETNAMEINFO, test "$fm_cv_getnameinfo"   != yes)
 391
 392 AC_CHECK_FUNCS(inet_ntop)
 393 dnl Check if getaddrinfo is async-signal-safe - most implementations aren't
 394 if test "$fm_cv_getaddrinfo" = yes ; then
 395     AC_MSG_CHECKING(if your getaddrinfo is async-signal-safe)
 396     gai_ts=no
 397     dnl we have getaddrinfo() - check if the OS is known to have a async-signal-safe implementation
 398     case $host_os in
 399         darwin9*)                               gai_ts=yes ;;
 400         linux*)                                 gai_ts=yes ;;
 401         freebsd5.5|freebsd6*|freebsd7*)         gai_ts=yes ;;
 402         solaris2.8|solaris2.9|solaris2.10)      gai_ts=yes ;;
 403     esac
 404     AC_MSG_RESULT($gai_ts)
 405     if test $gai_ts = yes ; then
 406         AC_DEFINE(GETADDRINFO_ASYNCSAFE, 1, [define to 1 if you know your getaddrinfo function is async-signal-safe])
 407     fi
 408 fi
 409
 410 # This version of the Kerberos 5 options addresses the follwing issues:
 411 #
 412 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 413 #   OpenSSL support (Debian's is)
 414
 415 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 416 ### make sure --with-ssl is run before --with-kerberos* !
 417 AC_ARG_WITH(kerberos5,
 418        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 419 [
 420 if test "$with_kerberos5" != "no"
 421 then
 422 # Check for a OpenBSD special case
 423 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 424 then
 425   AS_MESSAGE(checking kerberosV for OpenBSD...)
 426   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 427   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 428   CFLAGS="$CFLAGS -I/usr/include/kerberosV"
 429   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 430 elif krb5-config 2> /dev/null >/dev/null ; then
 431   krb5_prefix=`krb5-config --prefix krb5`
 432   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 433   if test -f ${krb5_prefix}/include/et/com_err.h && \
 434    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 435     CFLAGS="$CFLAGS -I${krb5_prefix}/include/et"
 436   fi
 437   unset krb5_prefix
 438   CFLAGS="$CFLAGS `krb5-config --cflags krb5`"
 439   LIBS="$LIBS `krb5-config --libs krb5`"
 440   AC_DEFINE(KERBEROS_V5)
 441 else
 442   if test "$with_kerberos5" != "yes"
 443   then
 444       LDFLAGS="$LDFLAGS -L${with_kerberos5}/lib"
 445       searchdirs="$with_kerberos5"
 446   else
 447       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 448   fi
 449   with_kerberos5=
 450   for dir in $searchdirs
 451   do AC_MSG_CHECKING([for Kerberos V in $dir])
 452      if test -f "$dir/include/krb5.h" || test -f "$dir/include/krb5/krb5.h"
 453      then
 454         if test -d "$dir/include/krb5" ; then CPPFLAGS="$CPPFLAGS -I$dir/include/krb5" ; fi
 455         ac_krblibs=
 456         if test -f "$dir/include/roken.h" || test -f "$dir/include/krb5/roken.h"
 457         then
 458            ac_krblibs="-lasn1 -lroken -lcom_err"
 459            AC_MSG_RESULT([Heimdal found])
 460           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 461           dnl we assume we do if it is available
 462            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 463                 ${LDFLAGS})
 464            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 465               AC_CHECK_LIB(crypto, MD5_Init, [],
 466                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 467                 ${LDFLAGS} ${ac_krblibs}),
 468            ${LDFLAGS} ${ac_krblibs})
 469            AC_DEFINE(HEIMDAL)
 470         else
 471           AC_MSG_RESULT([found])
 472           ac_krblibs="-lcom_err"
 473            AC_CHECK_LIB(crypto,
 474              krb5_des_string_to_key,
 475              libk5crypto=-lcrypto,
 476                 AC_CHECK_LIB(k5crypto,
 477                    krb5_des_string_to_key,
 478                    libk5crypto=-lk5crypto,
 479                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 480                    ${LDFLAGS} ${ac_krblibs}),
 481                  ${LDFLAGS} ${ac_krblibs})
 482         fi
 483         AC_CHECK_LIB(krb5, krb5_init_context,[],
 484            continue,
 485            ${LDFLAGS} ${ac_krblibs})
 486         AC_DEFINE(KERBEROS_V5)
 487         test "$dir" != "/usr" && CFLAGS="$CFLAGS -I$dir/include"
 488         LDFLAGS="$LDFLAGS -L$dir/lib"
 489        LIBS="$LIBS $ac_krblibs $libk5crypto"
 490         with_kerberos5=$dir
 491         break
 492      else
 493         AC_MSG_RESULT([not found])
 494      fi
 495   done
 496   if test -z "$with_kerberos5" ; then
 497      AC_MSG_ERROR([Kerberos 5 libraries not found])
 498   fi
 499 fi
 500 fi
 501 ]) dnl --with-kerberos5=DIR
 502
 503 ###     use option --with-ssl to compile in the SSL support
 504 AC_ARG_WITH(ssl,
 505         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 506         [with_ssl=$withval],
 507         [with_ssl=no])
 508 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 509
 510 if test "$with_ssl" = "yes"
 511 then
 512     #   User didn't specify an SSL location.  Let's look at some common
 513     #   directories where SSL has been found in the past and try and auto
 514     #   configure for SSL.  OpenSSL determination will be made later.
 515     #   This will screw up if an OpenSSL install is located in a later
 516     #   directory than an older SSLeay install, but the user should fix that
 517     #   anyways and he can override on the configure line.
 518     #   Just testing for directories is not sufficient, /usr exists on
 519     #   all systems!
 520     for ac_dir in \
 521       /usr/local/ssl \
 522       /usr/local \
 523       /usr/ssl \
 524       /usr \
 525       /local/ssl \
 526       /opt/ssl \
 527       /opt/csw \
 528       ; \
 529     do
 530         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 531             with_ssl=$ac_dir
 532             break;
 533         fi
 534     done
 535 fi
 536
 537 if test -n "$with_ssl" -a "$with_ssl" != "no"
 538 then
 539   # With the autoconfigure above, the only time this is going to be
 540   # true is going to be when we could not find the headers.  If they
 541   # are not in system standard locations, we are going to be broken.
 542   if test "$with_ssl" = "yes"
 543   then
 544     # Let's just define the standard location for the SSLeay root
 545     with_ssl="/usr/local/ssl"
 546   fi
 547   if test -r $with_ssl/include/openssl/ssl.h
 548   then
 549     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 550     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 551     test "$with_ssl" != "/usr" && CFLAGS="$CFLAGS -I$with_ssl/include"
 552     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 553     ### force the Kerberos direcory onto the include path so it will build.
 554     CFLAGS="$CFLAGS -I/usr/kerberos/include"
 555     ### OpenBSD comes with ssl headers
 556   else
 557     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 558   fi
 559   LDFLAGS="$LDFLAGS -L$with_ssl/lib"
 560   LIBS="$LIBS -lssl -lcrypto"
 561   dnl check if -ldl is needed
 562   AC_MSG_CHECKING([for additional library dependencies of SSL])
 563   found=0
 564   save_LIBS="$LIBS"
 565   for i in "" "-ldl" ; do
 566       LIBS="$LDFLAGS $save_LIBS $i"
 567       AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <openssl/ssl.h>],[SSL_library_init()])],[found=1; break])
 568   done
 569   if test $found = 0 ; then
 570       AC_MSG_RESULT([error])
 571       AC_MSG_ERROR([cannot link with SSL - check config.log])
 572   fi
 573   LIBS="$save_LIBS $i"
 574   if test "$i" = "" ; then i="(none)" ; fi
 575   AC_MSG_RESULT($i)
 576   dnl XXX FIXME: use pkg-config if available!
 577   AC_DEFINE(SSL_ENABLE)
 578 else
 579   AC_MSG_NOTICE(Disabling SSL support.)
 580 fi
 581
 582 ###     use option --with-socks=DIR to point at SOCKS library
 583 AC_ARG_WITH(socks,
 584         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 585 [
 586 if test "$with_socks" != no
 587 then
 588     if test "$with_socks" != yes
 589     then
 590         LDFLAGS="$LDFLAGS -L$with_socks"
 591     else
 592         AC_CHECK_LIB(socks, Rconnect,,
 593                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 594     fi
 595     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 596     CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 597     LIBS="-lsocks $LIBS"
 598 fi])
 599
 600 ###     use option --with-socks5=DIR to point at SOCKS library
 601 AC_ARG_WITH(socks5,
 602         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 603 [
 604 if test "$with_socks5" != no
 605 then
 606   if test "$with_socks5" != yes
 607   then
 608     LDFLAGS="$LDFLAGS -L$with_socks5"
 609   fi
 610   ac_savedLDFLAGS="$LDFLAGS"
 611   LDFLAGS="$LDFLAGS $LDFLAGS"
 612   AC_CHECK_LIB(socks5, SOCKSconnect,,
 613         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 614   AC_DEFINE(HAVE_SOCKS)
 615   CFLAGS="$CFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 616   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 617   LDFLAGS="$ac_savedLDFLAGS"
 618 fi])
 619
 620 dnl for libesmtp/ modules:
 621 ACX_WHICH_GETHOSTBYNAME_R
 622
 623 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 624 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 625
 626 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 627 AC_ARG_WITH(gssapi,
 628         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 629 [
 630 if test "$with_gssapi" != "no"
 631 then
 632   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 633   then
 634     with_gssapi=$with_kerberos5
 635   fi
 636
 637   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 638   then
 639     CFLAGS="$CFLAGS -I$with_gssapi/include"
 640     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 641   fi
 642
 643   dnl obtain gssapi default libs
 644   if krb5-config --libs gssapi 2>/dev/null >/dev/null ; then
 645       LIBS="$LIBS `krb5-config --libs gssapi`"
 646   else
 647     AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 648     if test -n "$nogss"
 649     then
 650       # -lgss not found
 651       if test "$with_gssapi" = yes ; then
 652           with_gssapi=/usr
 653       fi
 654       if test -f "$with_gssapi/include/roken.h" -o -f "$with_gssapi/include/krb5/roken.h"
 655       then
 656          # have roken.h, assume Heimdal
 657          case `uname` in
 658              NetBSD) LIBS="$LIBS -lkrb5" ;;
 659              *)      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl" ;;
 660          esac
 661          AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 662                       AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 663          AC_DEFINE(HEIMDAL)
 664       else
 665          # no roken.h, assume MIT
 666          AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 667                       AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 668       fi
 669     fi
 670   fi
 671   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 672   if test "$with_gssapi" != yes ; then
 673     CPPFLAGS="$CPPFLAGS -I$with_gssapi/include"
 674   fi
 675   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 676   if test "$ac_cv_header_gssapi_h" = "yes"; then
 677     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 678   else
 679     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 680   fi
 681 fi])
 682
 683 AC_CONFIG_FILES([Makefile po/Makefile.in genlsm.sh])
 684 AC_OUTPUT
 685
 686 dnl Local Variables:
 687 dnl comment-start: "dnl "
 688 dnl comment-end: ""
 689 dnl comment-start-skip: "\\bdnl\\b\\s *"
 690 dnl compile-command: "make configure config.h.in"
 691 dnl End: