Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [2])
  12 m4_define([gtk_minor_version], [99])
  13 m4_define([gtk_micro_version], [3])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Define a string for the earliest version that this release has
  32 # backwards binary compatibility with for all interfaces a module
  33 # might. Unless we add module-only API with lower stability
  34 # guarantees, this should be unchanged until we break binary compat
  35 # for GTK+.
  36 #
  37 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  38 m4_define([gtk_binary_version], [3.0.0])
  39
  40 # required versions of other packages
  41 m4_define([glib_required_version], [2.27.5])
  42 m4_define([pango_required_version], [1.20])
  43 m4_define([atk_required_version], [1.29.2])
  44 m4_define([cairo_required_version], [1.10.0])
  45 m4_define([gdk_pixbuf_required_version], [2.21.0])
  46 GLIB_REQUIRED_VERSION=glib_required_version
  47 PANGO_REQUIRED_VERSION=pango_required_version
  48 ATK_REQUIRED_VERSION=atk_required_version
  49 CAIRO_REQUIRED_VERSION=cairo_required_version
  50 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  51 AC_SUBST(GLIB_REQUIRED_VERSION)
  52 AC_SUBST(PANGO_REQUIRED_VERSION)
  53 AC_SUBST(ATK_REQUIRED_VERSION)
  54 AC_SUBST(CAIRO_REQUIRED_VERSION)
  55 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  56
  57
  58 # Save this value here, since automake will set cflags later
  59 cflags_set=${CFLAGS+set}
  60
  61 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  62 AM_MAINTAINER_MODE([enable])
  63
  64 # Support silent build rules, requires at least automake-1.11. Disable
  65 # by either passing --disable-silent-rules to configure or passing V=1
  66 # to make
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69 #
  70 # For each of the libraries we build, we define the following
  71 # substituted variables:
  72 #
  73 # foo_PACKAGES:     pkg-config packages this library requires
  74 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  75 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  76 # foo_DEP_LIBS:     All libraries this module requires
  77 # foo_DEP_CFLAGS:   All cflags this module requires
  78
  79
  80 GTK_MAJOR_VERSION=gtk_major_version
  81 GTK_MINOR_VERSION=gtk_minor_version
  82 GTK_MICRO_VERSION=gtk_micro_version
  83 GTK_INTERFACE_AGE=gtk_interface_age
  84 GTK_BINARY_AGE=gtk_binary_age
  85 GTK_VERSION=gtk_version
  86 GTK_API_VERSION=gtk_api_version
  87 GTK_BINARY_VERSION=gtk_binary_version
  88 AC_SUBST(GTK_MAJOR_VERSION)
  89 AC_SUBST(GTK_MINOR_VERSION)
  90 AC_SUBST(GTK_MICRO_VERSION)
  91 AC_SUBST(GTK_INTERFACE_AGE)
  92 AC_SUBST(GTK_BINARY_AGE)
  93 AC_SUBST(GTK_API_VERSION)
  94 AC_SUBST(GTK_VERSION)
  95 AC_SUBST(GTK_BINARY_VERSION)
  96
  97 # libtool versioning
  98 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  99 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 100 #LT_REVISION=$GTK_INTERFACE_AGE
 101 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 102 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 103
 104 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 105 m4_define([lt_revision], [gtk_interface_age])
 106 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 107 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 108 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 109 AC_SUBST(LT_VERSION_INFO)
 110 AC_SUBST(LT_CURRENT_MINUS_AGE)
 111
 112 m4_define([gail_lt_current],[0])
 113 m4_define([gail_lt_revision],[0])
 114 m4_define([gail_lt_age],[0])
 115 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 116 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 117 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 118 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 119
 120 # Checks for programs.
 121 AC_PROG_CC
 122 AC_PROG_CC_C_O
 123 AC_PROG_CC_STDC
 124 AC_PROG_INSTALL
 125 AC_PROG_MAKE_SET
 126
 127
 128 GETTEXT_PACKAGE=gtk30
 129 AC_SUBST(GETTEXT_PACKAGE)
 130 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 131                    [The prefix for our gettext translation domains.])
 132
 133 AC_CANONICAL_HOST
 134
 135 MATH_LIB=-lm
 136 AC_MSG_CHECKING([for native Win32])
 137 LIB_EXE_MACHINE_FLAG=X86
 138 EXE_MANIFEST_ARCHITECTURE=X86
 139 case "$host" in
 140   *-*-mingw*)
 141     os_win32=yes
 142     gio_can_sniff=no
 143     MATH_LIB=
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       EXE_MANIFEST_ARCHITECTURE=AMD64
 148       ;;
 149     esac
 150     ;;
 151   *)
 152     os_win32=no
 153     ;;
 154 esac
 155 AC_MSG_RESULT([$os_win32])
 156
 157 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 158 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 159
 160 case $host in
 161   *-*-linux*)
 162     os_linux=yes
 163     ;;
 164 esac
 165
 166 dnl
 167 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 168 dnl We use this for an automated test for C++ header correctness.
 169 dnl
 170 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 171 AC_LANG_PUSH([C++])
 172
 173 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 174 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 175
 176 gtk_save_cxxflags="$CXXFLAGS"
 177 CXXFLAGS="$CXXFLAGS -x objective-c++"
 178 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 179 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 180 CXXFLAGS="$gtk_save_cxxflags"
 181 AC_LANG_POP([C++])
 182
 183 if test "$os_win32" = "yes"; then
 184   if test x$enable_static = xyes -o x$enable_static = x; then
 185     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 186     enable_static=no
 187   fi
 188   if test x$enable_shared = xno; then
 189     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 190   fi
 191   enable_shared=yes
 192 fi
 193
 194 dnl Initialize libtool
 195 LT_PREREQ([2.2.6])
 196 LT_INIT([disable-static win32-dll])
 197 # Create libtool early, because it's used in configure
 198 LT_OUTPUT
 199
 200 # Make sure we use 64-bit versions of various file stuff.
 201 AC_SYS_LARGEFILE
 202
 203 AM_PROG_AS
 204 AC_PATH_PROG(NM, nm, nm)
 205
 206 AC_MSG_CHECKING([for some Win32 platform])
 207 case "$host" in
 208   *-*-mingw*|*-*-cygwin*)
 209     platform_win32=yes
 210     ;;
 211   *)
 212     platform_win32=no
 213     ;;
 214 esac
 215 AC_MSG_RESULT([$platform_win32])
 216 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 217
 218 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 219 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 220 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 221
 222 if test "$os_win32" = "yes"; then
 223   AC_CHECK_TOOL(WINDRES, windres, no)
 224   if test "$WINDRES" = no; then
 225     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 226   fi
 227   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 228 fi
 229 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 230
 231 m4_define([debug_default],
 232           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 233
 234 dnl declare --enable-* args and collect ac_help strings
 235 AC_ARG_ENABLE(debug,
 236               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 237                              [turn on debugging @<:@default=debug_default@:>@]),,
 238               enable_debug=debug_default)
 239
 240 AC_ARG_ENABLE(rebuilds,
 241               [AC_HELP_STRING([--disable-rebuilds],
 242                               [disable all source autogeneration rules])],,
 243               [enable_rebuilds=yes])
 244
 245 AC_ARG_ENABLE(gtk2-dependency,
 246               AC_HELP_STRING([--enable-gtk2-dependency],
 247                              [Do not build gtk-update-icon-cache and other shared tools]),,
 248               [enable_gtk2_dependency=no])
 249
 250 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 251
 252 AC_ARG_ENABLE(xkb,
 253               [AC_HELP_STRING([--enable-xkb],
 254                               [support XKB extension [default=maybe]])],,
 255               [enable_xkb="maybe"])
 256 AC_ARG_ENABLE(xinerama,
 257               [AC_HELP_STRING([--enable-xinerama],
 258                               [support Xinerama extension if available [default=maybe]])],,
 259               [enable_xinerama="maybe"])
 260 AC_ARG_ENABLE(xinput,
 261               [AC_HELP_STRING([--enable-xinput],
 262                               [support XInput extension if available [default=yes]])],,
 263               [enable_xinput="maybe"])
 264 AC_ARG_ENABLE(xrandr,
 265               [AC_HELP_STRING([--enable-xrandr],
 266                               [support XRandR extension if available [default=maybe]])],,
 267               [enable_xrandr="maybe"])
 268 AC_ARG_ENABLE(xfixes,
 269               [AC_HELP_STRING([--enable-xfixes],
 270                               [support XFixes extension if available [default=maybe]])],,
 271               [enable_xfixes="maybe"])
 272 AC_ARG_ENABLE(xcomposite,
 273               [AC_HELP_STRING([--enable-xcomposite],
 274                               [support X Composite extension if available [default=maybe]])],,
 275               [enable_xcomposite="maybe"])
 276 AC_ARG_ENABLE(xdamage,
 277               [AC_HELP_STRING([--enable-xdamage],
 278                               [support X Damage extension if available [default=maybe]])],,
 279               [enable_xdamage="maybe"])
 280
 281 AC_ARG_ENABLE(x11-backend,
 282               [AC_HELP_STRING([--enable-x11-backend],
 283                               [enable the X11 gdk backend])],
 284                               [backend_set=yes])
 285 AC_ARG_ENABLE(win32-backend,
 286               [AC_HELP_STRING([--enable-win32-backend],
 287                               [enable the Win32 gdk backend])],
 288                               [backend_set=yes])
 289 AC_ARG_ENABLE(quartz-backend,
 290               [AC_HELP_STRING([--enable-quartz-backend],
 291                               [enable the quartz gdk backend])],
 292                               [backend_set=yes])
 293 AC_ARG_ENABLE(broadway-backend,
 294               [AC_HELP_STRING([--enable-broadway-backend],
 295                               [enable the broadway (HTML5) gdk backend])],
 296                               [backend_set=yes])
 297
 298 if test -z "$backend_set"; then
 299   if test "$platform_win32" = yes; then
 300     enable_win32_backend=yes
 301   else
 302     enable_x11_backend=yes
 303   fi
 304 fi
 305
 306 cairo_backends=
 307 backend_immodules=
 308 GDK_BACKENDS=
 309 GDK_EXTRA_LIBS=
 310 GDK_EXTRA_CFLAGS=
 311 GDK_WINDOWING=
 312 GIO_PACKAGE=gio-2.0
 313 PANGO_PACKAGES="pango pangocairo"
 314
 315 if test "x$enable_x11_backend" == xyes; then
 316   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 317   # backend names are identical.
 318   cairo_backends="$cairo_backends cairo-xlib"
 319   GDK_BACKENDS="$GDK_BACKENDS x11"
 320   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 321   # gdkapplaunchcontext-x11.c
 322   GIO_PACKAGE=gio-unix-2.0
 323   backend_immodules="$backend_immodules,xim"
 324   GDK_WINDOWING="$GDK_WINDOWING
 325 #define GDK_WINDOWING_X11"
 326 fi
 327
 328 if test "x$enable_win32_backend" == xyes; then
 329   cairo_backends="$cairo_backends cairo-win32"
 330   GDK_BACKENDS="$GDK_BACKENDS win32"
 331   backend_immodules="$backend_immodules,ime"
 332   GDK_WINDOWING="$GDK_WINDOWING
 333 #define GDK_NATIVE_WINDOW_POINTER
 334 #define GDK_WINDOWING_WIN32"
 335   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 336   AM_CONDITIONAL(USE_WIN32, true)
 337   PANGO_PACKAGES="pangowin32 pangocairo"
 338 else
 339   AM_CONDITIONAL(USE_WIN32, false)
 340 fi
 341
 342 if test "x$enable_quartz_backend" == xyes; then
 343   cairo_backends="$cairo_backends cairo-quartz"
 344   GDK_BACKENDS="$GDK_BACKENDS quartz"
 345   GDK_WINDOWING="$GDK_WINDOWING
 346 #define GDK_WINDOWING_QUARTZ"
 347   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 348   AM_CONDITIONAL(USE_QUARTZ, true)
 349 else
 350   AM_CONDITIONAL(USE_QUARTZ, false)
 351 fi
 352
 353 if test "x$enable_broadway_backend" == xyes; then
 354   GDK_BACKENDS="$GDK_BACKENDS broadway"
 355   GDK_WINDOWING="$GDK_WINDOWING
 356 #define GDK_WINDOWING_BROADWAY"
 357   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 358   AM_CONDITIONAL(USE_BROADWAY, true)
 359 else
 360   AM_CONDITIONAL(USE_BROADWAY, false)
 361 fi
 362
 363 # strip leading space
 364 GDK_BACKENDS=${GDK_BACKENDS/# }
 365
 366 AC_SUBST(GDK_BACKENDS)
 367
 368 if test -z "$GDK_BACKENDS"; then
 369   AC_MSG_ERROR([No GDK backends selected.])
 370 fi
 371
 372 if test "x$enable_debug" = "xyes"; then
 373   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 374   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 375 else
 376   if test "x$enable_debug" = "xno"; then
 377     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 378   else
 379     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 380   fi
 381 fi
 382
 383
 384 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 385                    [Define if debugging is enabled])
 386
 387
 388 # Build time sanity check...
 389 AM_SANITY_CHECK
 390
 391 changequote(,)dnl
 392 if test "x$GCC" = "xyes"; then
 393   case " $CFLAGS " in
 394   *[\ \ ]-Wall[\ \      ]*) ;;
 395   *) CFLAGS="$CFLAGS -Wall" ;;
 396   esac
 397
 398   if test "x$enable_ansi" = "xyes"; then
 399     case " $CFLAGS " in
 400     *[\ \       ]-ansi[\ \      ]*) ;;
 401     *) CFLAGS="$CFLAGS -ansi" ;;
 402     esac
 403
 404     case " $CFLAGS " in
 405     *[\ \       ]-pedantic[\ \  ]*) ;;
 406     *) CFLAGS="$CFLAGS -pedantic" ;;
 407     esac
 408   fi
 409 fi
 410 changequote([,])dnl
 411
 412 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 413
 414 # Ensure MSVC-compatible struct packing convention is used when
 415 # compiling for Win32 with gcc.
 416 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 417 # gcc2 uses "-fnative-struct".
 418 if test x"$os_win32" = xyes; then
 419   if test x"$GCC" = xyes; then
 420     msnative_struct=''
 421     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 422     if test -z "$ac_cv_prog_CC"; then
 423       our_gcc="$CC"
 424     else
 425       our_gcc="$ac_cv_prog_CC"
 426     fi
 427     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 428       2.)
 429         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 430           msnative_struct='-fnative-struct'
 431         fi
 432         ;;
 433       *)
 434         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 435           msnative_struct='-mms-bitfields'
 436         fi
 437         ;;
 438     esac
 439     if test x"$msnative_struct" = x ; then
 440       AC_MSG_RESULT([no way])
 441       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 442     else
 443       CFLAGS="$CFLAGS $msnative_struct"
 444       AC_MSG_RESULT([${msnative_struct}])
 445     fi
 446   fi
 447 fi
 448
 449 ## Initial sanity check, done here so that users get told they
 450 ## have the wrong dependencies as early in the process as possible.
 451 ## Later on we actually use the cflags/libs from separate pkg-config
 452 ## calls. Oh, also the later pkg-config calls don't include
 453 ## the version requirements since those make the module lists
 454 ## annoying to construct
 455 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 456   [glib-2.0 >= glib_required_version dnl
 457    atk >= atk_required_version dnl
 458    pango >= pango_required_version dnl
 459    cairo >= cairo_required_version dnl
 460    cairo-gobject >= cairo_required_version dnl
 461    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 462
 463 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 464
 465 if test "$os_win32" != yes; then
 466     # libtool option to control which symbols are exported
 467     # right now, symbols starting with _ are not exported
 468     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 469 else
 470     # We currently use .def files on Windows (for gdk and gtk)
 471     LIBTOOL_EXPORT_OPTIONS=
 472 fi
 473 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 474
 475 dnl ******************************************************
 476 dnl * See whether to include shared library dependencies *
 477 dnl ******************************************************
 478
 479 AC_ARG_ENABLE(explicit-deps,
 480               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 481                               [use explicit dependencies in .pc files [default=auto]])],,
 482               [enable_explicit_deps=auto])
 483
 484 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 485 case $enable_explicit_deps in
 486   auto)
 487     export SED
 488     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 489     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 490       enable_explicit_deps=yes
 491     else
 492       enable_explicit_deps=no
 493     fi
 494   ;;
 495   yes|no)
 496   ;;
 497   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 498   ;;
 499 esac
 500 AC_MSG_RESULT($enable_explicit_deps)
 501
 502 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 503
 504 # define a MAINT-like variable REBUILD which is set if Perl
 505 # and awk are found, so autogenerated sources can be rebuilt
 506
 507 AC_PATH_PROGS(PERL, perl5 perl)
 508
 509 # We would like indent, but don't require it.
 510 AC_CHECK_PROG(INDENT, indent, indent)
 511
 512 REBUILD=\#
 513 if test "x$enable_rebuilds" = "xyes" && \
 514      test -n "$PERL" && \
 515      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 516   REBUILD=
 517 fi
 518 AC_SUBST(REBUILD)
 519
 520 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 521 AC_CHECK_FUNCS(localtime_r)
 522
 523 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 524 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 525 AC_TRY_LINK([#include <langinfo.h>], [
 526 char c;
 527 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 528 ], gtk_ok=yes, gtk_ok=no)
 529 AC_MSG_RESULT($gtk_ok)
 530 if test "$gtk_ok" = "yes"; then
 531   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 532             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 533 fi
 534
 535 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 536 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 537 AC_TRY_LINK([#include <langinfo.h>], [
 538 char c;
 539 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 540 ], gtk_ok=yes, gtk_ok=no)
 541 AC_MSG_RESULT($gtk_ok)
 542 if test "$gtk_ok" = "yes"; then
 543   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 544             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 545 fi
 546
 547 # _NL_PAPER_HEIGHT is an enum and not a define
 548 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 549 AC_TRY_LINK([#include <langinfo.h>], [
 550 char c;
 551 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 552 ], gtk_ok=yes, gtk_ok=no)
 553 AC_MSG_RESULT($gtk_ok)
 554 if test "$gtk_ok" = "yes"; then
 555   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 556             [Define if _NL_PAPER_HEIGHT is available])
 557 fi
 558
 559 # _NL_PAPER_WIDTH is an enum and not a define
 560 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 561 AC_TRY_LINK([#include <langinfo.h>], [
 562 char c;
 563 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 564 ], gtk_ok=yes, gtk_ok=no)
 565 AC_MSG_RESULT($gtk_ok)
 566 if test "$gtk_ok" = "yes"; then
 567   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 568             [Define if _NL_PAPER_WIDTH is available])
 569 fi
 570
 571 # i18n stuff
 572 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 573 AM_GLIB_GNU_GETTEXT
 574 LIBS="$LIBS $INTLLIBS"
 575 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 576         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 577       esac])
 578
 579 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 580 dnl po-properties/POTFILES during configure; see GNOME #573515.
 581 dnl
 582 dnl Generate list of files to be processed by xgettext which will
 583 dnl be included in po-properties/Makefile.
 584 test -d po-properties || mkdir po-properties
 585 if test "x$srcdir" != "x."; then
 586   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 587     popropsrcprefix="$srcdir/"
 588   else
 589     popropsrcprefix="../$srcdir/"
 590   fi
 591 else
 592   popropsrcprefix="../"
 593 fi
 594 rm -f po-properties/POTFILES
 595 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 596 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 597 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 598
 599 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 600
 601 dnl The DU4 header files don't provide library prototypes unless
 602 dnl -std1 is given to the native cc.
 603 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 604
 605 gtk_save_LIBS=$LIBS
 606 LIBS="$LIBS -lm"
 607 AC_TRY_RUN([#include <math.h>
 608              int main (void) { return (log(1) != log(1.)); }],
 609      AC_MSG_RESULT(none needed),
 610      gtk_save_CFLAGS="$CFLAGS"
 611      CFLAGS="$CFLAGS -std1"
 612      AC_TRY_RUN([#include <math.h>
 613                  int main (void) { return (log(1) != log(1.)); }],
 614          AC_MSG_RESULT(-std1),
 615          AC_MSG_RESULT()
 616          CFLAGS="$gtk_save_CFLAGS"
 617          AC_MSG_WARN(
 618                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 619          true
 620      ),
 621      AC_MSG_RESULT(none needed)
 622 )
 623 LIBS=$gtk_save_LIBS
 624
 625 AC_MSG_CHECKING(for the BeOS)
 626 case $host in
 627   *-*-beos*)
 628     AC_MSG_RESULT(yes)
 629     MATH_LIB=
 630   ;;
 631   *)
 632     AC_MSG_RESULT(no)
 633   ;;
 634 esac
 635
 636 AC_SUBST(MATH_LIB)
 637 #
 638 # see bug 162979
 639 #
 640 AC_MSG_CHECKING(for HP-UX)
 641 case $host_os in
 642   hpux9* | hpux10* | hpux11*)
 643     AC_MSG_RESULT(yes)
 644     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 645   ;;
 646   *)
 647     AC_MSG_RESULT(no)
 648   ;;
 649 esac
 650
 651 dnl NeXTStep cc seems to need this
 652 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 653 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 654   AC_MSG_RESULT(none needed),
 655   gtk_save_CFLAGS="$CFLAGS"
 656   CFLAGS="$CFLAGS -posix"
 657   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 658     AC_MSG_RESULT(-posix),
 659     AC_MSG_RESULT()
 660     CFLAGS="$gtk_save_CFLAGS"
 661     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 662
 663 #
 664 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 665 #
 666
 667 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 668
 669 AM_PATH_GLIB_2_0(glib_required_version, :,
 670   AC_MSG_ERROR([
 671 *** GLIB glib_required_version or better is required. The latest version of
 672 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 673   gobject gmodule-no-export gthread)
 674
 675 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 676 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 677 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 678 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 679   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 680 fi
 681
 682 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 683
 684
 685 dnl
 686 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 687 dnl
 688 gtk_save_LIBS=$LIBS
 689 LIBS="$LIBS $GLIB_LIBS"
 690 AC_CHECK_FUNCS(bind_textdomain_codeset)
 691 LIBS=$gtk_save_LIBS
 692
 693 AC_CHECK_HEADERS(pwd.h,
 694                  AC_DEFINE(HAVE_PWD_H, 1,
 695                            [Define to 1 if pwd.h is available]))
 696 AC_CHECK_HEADERS(sys/time.h,
 697                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 698                            [Define to 1 if time.h is available]))
 699 AC_CHECK_HEADERS(unistd.h,
 700                  AC_DEFINE(HAVE_UNISTD_H, 1,
 701                            [Define to 1 if unistd.h is available]))
 702 AC_CHECK_HEADERS(ftw.h,
 703                  AC_DEFINE(HAVE_FTW_H, 1,
 704                            [Define to 1 if ftw.h is available]))
 705
 706 AC_MSG_CHECKING([for GNU ftw extensions])
 707 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 708 #define _GNU_SOURCE
 709 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 710 if test $gtk_ok = yes; then
 711     AC_MSG_RESULT([yes])
 712     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 713 else
 714     AC_MSG_RESULT([no])
 715 fi
 716
 717 saved_cflags="$CFLAGS"
 718 saved_ldflags="$LDFLAGS"
 719
 720
 721 # Checks for header files.
 722 AC_HEADER_STDC
 723
 724 # Checks for typedefs, structures, and compiler characteristics.
 725 AC_C_CONST
 726
 727 # Checks for library functions.
 728 AC_TYPE_SIGNAL
 729 AC_FUNC_MMAP
 730
 731 AC_CHECK_FUNCS(mallinfo)
 732 AC_CHECK_FUNCS(getresuid)
 733 AC_TYPE_UID_T
 734
 735 # Check if <sys/select.h> needs to be included for fd_set
 736 AC_MSG_CHECKING([for fd_set])
 737 AC_TRY_COMPILE([#include <sys/types.h>],
 738         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 739 if test $gtk_ok = yes; then
 740     AC_MSG_RESULT([yes, found in sys/types.h])
 741 else
 742     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 743     if test $gtk_ok = yes; then
 744         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 745                   [Define to 1 if sys/select.h is available])
 746         AC_MSG_RESULT([yes, found in sys/select.h])
 747     else
 748         AC_DEFINE(NO_FD_SET, 1,
 749                   [Define to 1 if fd_set is not available])
 750         AC_MSG_RESULT(no)
 751     fi
 752 fi
 753
 754 # Check for uxtheme.h (for MS-Windows Engine)
 755 AC_MSG_CHECKING(for uxtheme.h)
 756 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 757 if test $gtk_uxtheme_h = yes; then
 758    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 759 fi
 760 AC_MSG_RESULT($gtk_uxtheme_h)
 761
 762 # Checks for gdkspawn
 763 AC_CHECK_HEADERS(crt_externs.h)
 764 AC_CHECK_FUNCS(_NSGetEnviron)
 765
 766 AC_MSG_CHECKING(whether to build dynamic modules)
 767
 768 AC_ARG_ENABLE(modules,
 769               [AC_HELP_STRING([--disable-modules],
 770                               [disable dynamic module loading])])
 771
 772 dynworks=false
 773 build_dynamic_modules=no
 774 deps=
 775 if test x$enable_modules = xno; then
 776     AC_MSG_RESULT(no)
 777 else
 778     AC_MSG_RESULT(yes)
 779     AC_MSG_CHECKING(whether dynamic modules work)
 780     ## for loop is to strip newline
 781     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 782     for I in $tmp; do
 783         dynworks=$I
 784     done
 785
 786     dnl Now we check to see if our libtool supports shared lib deps
 787     dnl (in a rather ugly way even)
 788     if $dynworks; then
 789         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 790         module_deplibs_check=`$module_libtool_config | \
 791             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 792             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 793         if test "x$module_deplibs_check" = "xnone" || \
 794            test "x$module_deplibs_check" = "xunknown" || \
 795            test "x$module_deplibs_check" = "x"; then
 796             dynworks=false
 797         fi
 798     fi
 799
 800     if $dynworks; then
 801         build_dynamic_modules=yes
 802         AC_DEFINE(USE_GMODULE, 1,
 803                   [Define to 1 if gmodule works and should be used])
 804         AC_MSG_RESULT(yes)
 805     else
 806         build_dynamic_modules=no
 807         AC_MSG_RESULT(no)
 808     fi
 809 fi
 810
 811 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 812
 813 #
 814 # Allow building some or all immodules included
 815 #
 816 AC_MSG_CHECKING(immodules to build)
 817
 818 dnl due to an autoconf bug, commas in the first arg to
 819 dnl AC_HELP_STRING cause problems.
 820 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
 821 dnl                [build the specified input method modules into gtk])
 822 AC_ARG_WITH(included_immodules,
 823             AC_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 824                            [build the specified input methods into gtk]))
 825
 826 if $dynworks; then
 827    :
 828 else
 829    ## if the option was specified, leave it; otherwise disable included immodules
 830    if test x$with_included_immodules = xno; then
 831            with_included_immodules=yes
 832    fi
 833 fi
 834
 835 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 836
 837 included_immodules=""
 838 # If the switch specified without listing any specific ones, include all
 839 if test "x$with_included_immodules" = xyes ; then
 840   included_immodules="$all_immodules"
 841 else
 842   included_immodules="$with_included_immodules"
 843 fi
 844
 845 AC_MSG_RESULT($included_immodules)
 846 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 847
 848 INCLUDED_IMMODULE_OBJ=
 849 INCLUDED_IMMODULE_DEFINE=
 850
 851 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 852 for immodule in $included_immodules; do
 853  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 854  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 855    :
 856  else
 857    AC_MSG_ERROR([the specified input method $immodule does not exist])
 858  fi
 859
 860  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 861  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 862  eval INCLUDE_$immodule_underscores=yes
 863 done
 864 IFS="$gtk_save_ifs"
 865 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 866 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 867
 868 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 869 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 870 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 871 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 872 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 873 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 874 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 875 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 876 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 877 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 878 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 879 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 880
 881 AC_HEADER_SYS_WAIT
 882
 883 AC_TYPE_SIGNAL
 884
 885 # Checks to see whether we should include mediaLib
 886 # support.
 887 #
 888 AC_CHECK_HEADER(sys/systeminfo.h,
 889                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 890                           [Define to 1 if sys/systeminfo.h is available]))
 891 AC_CHECK_HEADER(sys/sysinfo.h,
 892                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 893                           [Define to 1 if sys/sysinfo.h is available]))
 894
 895 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 896
 897 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 898
 899 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 900   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 901   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 902     REBUILD_PNGS=#
 903   fi
 904 fi
 905
 906 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 907
 908 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 909
 910 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 911    test "x$REBUILD_PNGS" = "x#" ; then
 912      AC_MSG_ERROR([
 913 *** gtkbuiltincache.h is not in the tree, and cannot be built
 914 *** because you don't have libpng, or (when cross-compiling) you
 915 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 916 fi
 917
 918 ########################################
 919 # Windowing system checks
 920 ########################################
 921
 922 # GTK+ uses some X calls, so needs to link against X directly
 923 GTK_DEP_PACKAGES_FOR_X=
 924 GTK_DEP_LIBS_FOR_X=
 925 X_EXTENSIONS=
 926
 927 if test "x$enable_x11_backend" == xyes; then
 928   X_PACKAGES=fontconfig
 929
 930   #
 931   # We use fontconfig very peripherally when decoding the default
 932   # settings.
 933   #
 934   if $PKG_CONFIG --exists fontconfig; then : ; else
 935     AC_MSG_ERROR([
 936 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 937   fi
 938
 939   #
 940   # Check for basic X packages; we use pkg-config if available
 941   #
 942   if $PKG_CONFIG --exists x11 xext; then
 943     have_base_x_pc=true
 944     X_PACKAGES="$X_PACKAGES x11 xext"
 945     x_libs="`$PKG_CONFIG --libs x11 xext`"
 946     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 947
 948     # Strip out any .la files that pkg-config might give us (this happens
 949     # with -uninstalled.pc files)
 950     x_libs_for_checks=
 951     for I in $x_libs ; do
 952       case $I in
 953         *.la) ;;
 954         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 955       esac
 956     done
 957
 958     GTK_PACKAGES_FOR_X="x11"
 959   else
 960     have_base_x_pc=false
 961     AC_PATH_XTRA
 962     if test x$no_x = xyes ; then
 963       AC_MSG_ERROR([X development libraries not found])
 964     fi
 965
 966     x_cflags="$X_CFLAGS"
 967     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 968
 969     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 970   fi
 971
 972   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 973   x_extra_libs=
 974
 975   gtk_save_cppflags="$CPPFLAGS"
 976   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 977
 978   gtk_save_LIBS=$LIBS
 979   LIBS="$x_libs_for_checks $LIBS"
 980
 981   # Sanity check for the X11 and Xext libraries. While everything we need from
 982   # Xext is optional, the chances a system has *none* of these things is so
 983   # small that we just unconditionally require it.
 984   AC_CHECK_FUNC(XOpenDisplay, :,
 985                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 986   AC_CHECK_FUNC(XextFindDisplay, :,
 987                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 988
 989   # Check for xReply
 990
 991   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 992   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
 993       [xReply *rep;],
 994       [AC_MSG_RESULT([no])],
 995       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
 996 #include <X11/Xlibint.h>],
 997            [xReply *rep;],
 998            [AC_MSG_RESULT([yes])
 999             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
1000                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
1001            [AC_MSG_RESULT([unknown])
1002             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1003
1004   # Check for XConvertCase, XInternAtoms (X11R6 specific)
1005
1006   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
1007
1008   # Generic X11R6 check needed for XIM support; we could
1009   # probably use this to replace the above, but we'll
1010   # leave the separate checks for XConvertCase and XInternAtoms
1011   # for clarity
1012
1013   have_x11r6=false
1014   AC_CHECK_FUNC(XAddConnectionWatch,
1015       have_x11r6=true)
1016
1017   if $have_x11r6; then
1018     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1019   fi
1020   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1021
1022   # Check for XKB support.
1023
1024   if test "x$enable_xkb" = "xyes"; then
1025         AC_CHECK_FUNC(XkbQueryExtension,
1026                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1027                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1028                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1029   elif test "x$enable_xkb" = "xmaybe"; then
1030         AC_CHECK_FUNC(XkbQueryExtension,
1031                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1032                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1033   else
1034         AC_MSG_WARN(XKB support explicitly disabled)
1035   fi
1036
1037   # Check for shaped window extension
1038
1039   AC_CHECK_FUNC(XShapeCombineMask, :,
1040      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1041
1042   # X SYNC check
1043   gtk_save_CFLAGS="$CFLAGS"
1044   CFLAGS="$CFLAGS $x_cflags"
1045
1046   AC_CHECK_FUNC(XSyncQueryExtension,
1047       [AC_CHECK_HEADER(X11/extensions/sync.h,
1048           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1049           :, [#include <X11/Xlib.h>])])
1050
1051   CFLAGS="$gtk_save_CFLAGS"
1052
1053   if test "x$enable_xinerama" != "xno"; then
1054     # Check for Xinerama extension (Solaris impl or Xfree impl)
1055     have_xfree_xinerama=false
1056     have_solaris_xinerama=false
1057
1058     gtk_save_cppflags="$CPPFLAGS"
1059     CPPFLAGS="$CPPFLAGS $x_cflags"
1060
1061     # Check for XFree
1062     AC_MSG_CHECKING(for Xinerama packages)
1063
1064     if $PKG_CONFIG --exists xinerama ; then
1065        AC_MSG_RESULT(yes)
1066        have_xfree_xinerama=true
1067        X_PACKAGES="$X_PACKAGES xinerama"
1068     else
1069        AC_MSG_RESULT(no)
1070        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1071            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1072            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1073            have_xfree_xinerama=true], :,
1074            [#include <X11/Xlib.h>])])
1075     fi
1076
1077     if $have_xfree_xinerama ; then
1078       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1079       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1080                 [Define to 1 if XFree Xinerama is available])
1081       AC_DEFINE(HAVE_XINERAMA, 1,
1082                 [Define to 1 is Xinerama is available])
1083     else
1084       case "$host" in
1085         *-*-solaris*)
1086             # Check for solaris
1087             AC_MSG_CHECKING(for Xinerama support on Solaris)
1088
1089             have_solaris_xinerama=false
1090             AC_CHECK_FUNC(XineramaGetInfo,
1091                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1092                     [have_solaris_xinerama=true], :,
1093                     [#include <X11/Xlib.h>])])
1094
1095             if $have_solaris_xinerama ; then
1096               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1097               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1098                         [Define to 1 if solaris xinerama is available])
1099               AC_DEFINE(HAVE_XINERAMA, 1,
1100                         [Define to 1 if xinerama is available])
1101               AC_MSG_RESULT(yes)
1102             else
1103               AC_MSG_RESULT(no)
1104             fi
1105             ;;
1106         *)
1107             ;;
1108       esac
1109     fi
1110   fi
1111   if test "x$enable_xinerama" = "xyes" ; then
1112     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1113       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1114     fi
1115   fi
1116
1117   # set up things for XInput
1118   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1119     have_xinput=yes
1120
1121     AC_DEFINE(XINPUT_XFREE, 1,
1122               [Define to 1 if XFree XInput should be used])
1123
1124     X_PACKAGES="$X_PACKAGES xi"
1125
1126     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1127                     have_xinput2=yes
1128                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1129                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]),
1130                     X_EXTENSIONS="$X_EXTENSIONS XInput")
1131
1132   else
1133     AC_DEFINE(XINPUT_NONE, 1,
1134               [Define to 1 if no XInput should be used])
1135   fi
1136
1137   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1138   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1139
1140   if test "x$enable_xinput" = "xyes" ; then
1141     if test "x$have_xinput" != "xyes" -a "x$have_xinput2" != "xyes" ; then
1142       AC_MSG_ERROR([*** XInput extension not found. Check 'config.log' for more details.])
1143     fi
1144   fi
1145
1146   # Check for the RANDR extension
1147   if test x"$enable_xrandr" != xno; then
1148     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1149       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1150
1151       X_PACKAGES="$X_PACKAGES xrandr"
1152       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1153     elif test x"$enable_xrandr" = xyes; then
1154       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1155     fi
1156   fi
1157
1158   # Checks for Xcursor library
1159
1160   if $PKG_CONFIG --exists xcursor ; then
1161     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1162
1163     X_PACKAGES="$X_PACKAGES xcursor"
1164   fi
1165
1166   # Checks for XFixes extension
1167
1168   if test x"$enable_xfixes" != xno; then
1169     if $PKG_CONFIG --exists xfixes ; then
1170       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1171
1172       X_PACKAGES="$X_PACKAGES xfixes"
1173       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1174       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1175     elif test x"$enable_xfixes" = xyes; then
1176       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1177     fi
1178   fi
1179
1180   # Checks for Xcomposite extension
1181
1182   if test x"$enable_xcomposite" != xno; then
1183     if $PKG_CONFIG --exists xcomposite ; then
1184       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1185
1186       X_PACKAGES="$X_PACKAGES xcomposite"
1187       X_EXTENSIONS="$X_EXTENSIONS Composite"
1188       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1189     elif test x"$enable_xcomposite" = xyes; then
1190       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1191     fi
1192   fi
1193
1194   # Checks for Xdamage extension
1195
1196   if test x"$enable_xdamage" != xno; then
1197     if $PKG_CONFIG --exists xdamage ; then
1198       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1199
1200       X_PACKAGES="$X_PACKAGES xdamage"
1201       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1202       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1203     elif test x"$enable_xdamage" = xyes; then
1204       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1205     fi
1206   fi
1207
1208   if $have_base_x_pc ; then
1209     GDK_EXTRA_LIBS="$x_extra_libs"
1210   else
1211     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1212   fi
1213
1214   CPPFLAGS="$gtk_save_cppflags"
1215   LIBS="$gtk_save_libs"
1216
1217   AM_CONDITIONAL(USE_X11, true)
1218
1219   # strip leading space
1220   X_EXTENSIONS=${X_EXTENSIONS/# }
1221
1222 else
1223   XPACKAGES=
1224
1225   AM_CONDITIONAL(XINPUT_XFREE, false)
1226   AM_CONDITIONAL(XINPUT_2, false)
1227   AM_CONDITIONAL(USE_X11, false)
1228   AM_CONDITIONAL(HAVE_X11R6, false)
1229 fi
1230
1231 # Check for Pango flags
1232
1233 AC_MSG_CHECKING(Pango flags)
1234 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1235         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1236         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1237
1238         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1239 else
1240         AC_MSG_ERROR([
1241 *** Pango not found. Pango built with Cairo support is required
1242 *** to build GTK+. See http://www.pango.org for Pango information.
1243 ])
1244 fi
1245
1246 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1247
1248 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1249         :
1250 else
1251         gtk_save_LIBS="$LIBS"
1252         LIBS="$PANGO_LIBS $LIBS"
1253         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1254 *** Can't link to Pango. Pango is required to build
1255 *** GTK+. For more information see http://www.pango.org]))
1256         LIBS="$gtk_save_LIBS"
1257 fi
1258
1259 CFLAGS="$saved_cflags"
1260 LDFLAGS="$saved_ldflags"
1261
1262 GDK_PACKAGES="$PANGO_PACKAGES $GIO_PACKAGE $X_PACKAGES gdk-pixbuf-2.0 $cairo_backends cairo-gobject"
1263
1264 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1265 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1266 #
1267 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1268 # into the pkg-config files
1269 #
1270 if test $enable_explicit_deps != yes ; then
1271   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo-gobject"
1272   GDK_EXTRA_LIBS=
1273 fi
1274
1275 AC_SUBST(GDK_PACKAGES)
1276 AC_SUBST(GDK_EXTRA_LIBS)
1277 AC_SUBST(GDK_EXTRA_CFLAGS)
1278 AC_SUBST(GDK_DEP_LIBS)
1279 AC_SUBST(GDK_DEP_CFLAGS)
1280
1281
1282 ########################################
1283 # Check for Accessibility Toolkit flags
1284 ########################################
1285
1286 ATK_PACKAGES=atk
1287 AC_MSG_CHECKING(ATK flags)
1288 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1289         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1290         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1291
1292         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1293 else
1294         AC_MSG_ERROR([
1295 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1296 *** to build GTK+.
1297 ])
1298 fi
1299
1300 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1301         :
1302 else
1303         gtk_save_LIBS="$LIBS"
1304         LIBS="$ATK_LIBS $LIBS"
1305         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1306                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1307                 *** to build GTK+]))
1308         LIBS="$gtk_save_LIBS"
1309 fi
1310
1311 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1312 if test "x$enable_x11_backend" == xyes; then
1313   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1314 fi
1315 GTK_EXTRA_LIBS=
1316 GTK_EXTRA_CFLAGS=
1317 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1318 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1319
1320 if test x"$os_win32" = xyes; then
1321   GTK_EXTRA_CFLAGS="$msnative_struct"
1322 fi
1323
1324 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1325 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1326 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1327 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1328
1329 AC_SUBST(GTK_PACKAGES)
1330 AC_SUBST(GTK_EXTRA_LIBS)
1331 AC_SUBST(GTK_EXTRA_CFLAGS)
1332 AC_SUBST(GTK_DEP_LIBS)
1333 AC_SUBST(GTK_DEP_CFLAGS)
1334
1335 AC_SUBST(GLIB_PREFIX)
1336 AC_SUBST(ATK_PREFIX)
1337 AC_SUBST(PANGO_PREFIX)
1338 AC_SUBST(CAIRO_PREFIX)
1339
1340 AC_SUBST(GTK_DEBUG_FLAGS)
1341 AC_SUBST(GTK_XIM_FLAGS)
1342
1343 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1344 AC_SUBST(GDK_PIXBUF_LIBS)
1345
1346 ########################
1347 # Checks needed for gail
1348 ########################
1349
1350 old_LIBS="$LIBS"
1351 dnl Checks for inet libraries:
1352 AC_SEARCH_LIBS(gethostent, nsl)
1353 AC_SEARCH_LIBS(setsockopt, socket)
1354 AC_SEARCH_LIBS(connect, inet)
1355
1356 dnl check for the sockaddr_un.sun_len member
1357 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1358                 [struct_sockaddr_un_sun_len=true],
1359                 [struct_sockaddr_un_suin_len=false],
1360                 [#include <sys/types.h>
1361                  #include <sys/un.h>]
1362                 )
1363 case $struct_sockaddr_un_sun_len in
1364         true)
1365                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1366                                    [Have the sockaddr_un.sun_len member])
1367                 ;;
1368         *)
1369                 ;;
1370 esac
1371
1372 GAIL_INET_LIBS="$LIBS"
1373 AC_SUBST([GAIL_INET_LIBS])
1374
1375 LIBS="$old_LIBS"
1376
1377 ################################################################
1378 # Printing system checks
1379 ################################################################
1380
1381 PRINT_BACKENDS="file lpr"
1382
1383 AC_ARG_ENABLE(cups,
1384               [AC_HELP_STRING([--disable-cups],
1385                               [disable cups print backend])],,
1386               [enable_cups=auto])
1387
1388 if test "x$enable_cups" = "xno"; then
1389   AM_CONDITIONAL(HAVE_CUPS, false)
1390 else
1391   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1392   if test "x$CUPS_CONFIG" = "xno"; then
1393     if test "x$enable_cups" = "xauto"; then
1394       AM_CONDITIONAL(HAVE_CUPS, false)
1395     else
1396       AC_MSG_ERROR([
1397 *** cups not found.
1398 ])
1399     fi
1400   else
1401     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1402     CUPS_LIBS=`$CUPS_CONFIG --libs`
1403
1404     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1405     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1406     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1407
1408     if test $CUPS_API_MAJOR -gt 1 -o \
1409             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1410       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1411                 [Define to 1 if CUPS 1.2 API is available])
1412     fi
1413
1414     AC_SUBST(CUPS_API_MAJOR)
1415     AC_SUBST(CUPS_API_MINOR)
1416     AC_SUBST(CUPS_CFLAGS)
1417     AC_SUBST(CUPS_LIBS)
1418
1419     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1420
1421     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1422     AM_CONDITIONAL(HAVE_CUPS, true)
1423
1424     gtk_save_cflags="$CFLAGS"
1425     CFLAGS="$CUPS_CFLAGS"
1426     AC_TRY_COMPILE([#include <cups/http.h>],
1427                    [http_t http; char *s = http.authstring;],
1428                    [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1429                               [Define if cups http_t authstring field is accessible])],)
1430     CFLAGS="$gtk_save_cflags"
1431
1432     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1433
1434     gtk_save_libs="$LIBS"
1435     LIBS="$CUPS_LIBS"
1436     AC_CHECK_FUNCS(httpGetAuthString)
1437     LIBS="$gtk_save_libs"
1438   fi
1439 fi
1440
1441 # Checks to see if we should compile with PAPI backend for GTK+
1442 #
1443
1444 AC_ARG_ENABLE(papi,
1445               [AC_HELP_STRING([--disable-papi],
1446                               [disable papi print backend])],,
1447              [enable_papi=auto])
1448
1449 if test "x$enable_papi" = "xno"; then
1450   AM_CONDITIONAL(HAVE_PAPI, false)
1451 else
1452   AC_MSG_CHECKING(libpapi)
1453   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1454   if test $have_papi = yes; then
1455     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1456     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1457   fi
1458   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1459   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1460     AC_MSG_ERROR([
1461 *** papi not found.
1462 ])
1463   fi
1464 fi
1465
1466 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1467
1468 gtk_save_cppflags="$CPPFLAGS"
1469 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1470
1471 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1472 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1473 *** backend enabled.]))
1474
1475 if test "$os_win32" != "yes"; then
1476   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1477 *** Can't find cairo-ps.h. You must build Cairo with the
1478 *** postscript backend enabled.]))
1479
1480   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1481 *** Cannot find cairo-svg.h. You must build Cairo with the
1482 *** svg backend enabled.]))
1483 fi
1484
1485 CPPFLAGS="$gtk_save_cppflags"
1486
1487
1488 AC_ARG_ENABLE(test-print-backend,
1489               [AC_HELP_STRING([--enable-test-print-backend],
1490                               [build test print backend])],,
1491               [enable_test_print_backend=no])
1492 if test "x$enable_test_print_backend" != "xno" ; then
1493   PRINT_BACKENDS="$PRINT_BACKENDS test"
1494 fi
1495 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1496
1497
1498 ################################################################
1499 # Strip -export-dynamic from the link lines of various libraries
1500 ################################################################
1501
1502 #
1503 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1504 #  but this flag is only meaningful for executables. For libraries
1505 #  the effect is undefined; what it causes on Linux is that the
1506 #  export list from -export-symbols-regex is ignored and everything
1507 #  is exported
1508 #
1509 # We are using gmodule-no-export now, but I'm leaving the stripping
1510 # code in place for now, since pango and atk still require gmodule.
1511 export SED
1512 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1513 if test -n "$export_dynamic"; then
1514   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1515   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1516 fi
1517
1518 #############
1519 # GSettings #
1520 #############
1521
1522 GLIB_GSETTINGS
1523
1524 ##################################################
1525 # GObject introspection
1526 ##################################################
1527
1528 GOBJECT_INTROSPECTION_CHECK([0.9.3])
1529
1530 ##################################################
1531 # Packagekit module
1532 #################################################
1533
1534 AC_ARG_ENABLE(packagekit,
1535               AC_HELP_STRING([--disable-packagekit],
1536                              [build packagekit open-with module]))
1537
1538 build_packagekit=no
1539 if test "os_win32" != "yes"; then
1540         if test "x$enable_packagekit" != "xno"; then
1541                 build_packagekit=yes
1542                 AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1543         fi
1544 fi
1545
1546 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1547
1548 ##################################################
1549 # Checks for gtk-doc and docbook-tools
1550 ##################################################
1551
1552 GTK_DOC_CHECK([1.11])
1553
1554 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1555 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1556
1557 AC_ARG_ENABLE(man,
1558               [AC_HELP_STRING([--enable-man],
1559                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1560               enable_man=no)
1561
1562 if test "${enable_man}" != no; then
1563   dnl
1564   dnl Check for xsltproc
1565   dnl
1566   AC_PATH_PROG([XSLTPROC], [xsltproc])
1567   if test -z "$XSLTPROC"; then
1568     enable_man=no
1569   fi
1570
1571   dnl check for DocBook DTD and stylesheets in the local catalog.
1572   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1573      [DocBook XML DTD V4.1.2],,enable_man=no)
1574   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1575      [DocBook XSL Stylesheets],,enable_man=no)
1576 fi
1577
1578 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1579
1580
1581 ##################################################
1582 # Output commands
1583 ##################################################
1584
1585 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1586         outfile=gdkconfig.h-tmp
1587         cat > $outfile <<\_______EOF
1588 /* gdkconfig.h
1589  *
1590  * This is a generated file.  Please modify `configure.ac'
1591  */
1592
1593 #ifndef __GDKCONFIG_H__
1594 #define __GDKCONFIG_H__
1595
1596 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1597 #error "Only <gdk/gdk.h> can be included directly."
1598 #endif
1599
1600 #include <glib.h>
1601
1602 G_BEGIN_DECLS
1603
1604 _______EOF
1605
1606         cat >>$outfile <<_______EOF
1607 $gdk_windowing
1608 _______EOF
1609
1610         cat >>$outfile <<_______EOF
1611
1612 G_END_DECLS
1613
1614 #endif  /* __GDKCONFIG_H__ */
1615 _______EOF
1616
1617
1618         if cmp -s $outfile gdk/gdkconfig.h; then
1619           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1620           rm -f $outfile
1621         else
1622           mv $outfile gdk/gdkconfig.h
1623         fi
1624 ],[
1625 gdk_windowing='$GDK_WINDOWING'
1626 ])
1627
1628 dnl
1629 dnl Check for -Bsymbolic-functions linker flag used to avoid
1630 dnl intra-library PLT jumps, if available.
1631 dnl
1632 AC_ARG_ENABLE(Bsymbolic,
1633               [AC_HELP_STRING([--disable-Bsymbolic],
1634                               [avoid linking with -Bsymbolic])],,
1635               [SAVED_LDFLAGS="${LDFLAGS}"
1636                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1637                LDFLAGS=-Wl,-Bsymbolic-functions
1638                AC_TRY_LINK([], [int main (void) { return 0; }],
1639                            AC_MSG_RESULT(yes)
1640                            enable_Bsymbolic=yes,
1641                            AC_MSG_RESULT(no)
1642                            enable_Bsymbolic=no)
1643                LDFLAGS="${SAVED_LDFLAGS}"])
1644
1645 if test "x${enable_Bsymbolic}" = "xyes" ; then
1646   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1647 fi
1648 AC_SUBST(GTK_LINK_FLAGS)
1649
1650 AC_CONFIG_FILES([
1651 config.h.win32
1652 gtk-zip.sh
1653 Makefile
1654 gdk-3.0.pc
1655 gtk+-3.0.pc
1656 gtk+-unix-print-3.0.pc
1657 gail-3.0.pc
1658 gtk+-3.0-uninstalled.pc
1659 gail-3.0-uninstalled.pc
1660 m4macros/Makefile
1661 po/Makefile.in
1662 po-properties/Makefile.in
1663 demos/Makefile
1664 demos/gtk-demo/Makefile
1665 demos/gtk-demo/geninclude.pl
1666 examples/Makefile
1667 tests/Makefile
1668 docs/Makefile
1669 docs/reference/Makefile
1670 docs/reference/gdk/Makefile
1671 docs/reference/gdk/version.xml
1672 docs/reference/gtk/Makefile
1673 docs/reference/gtk/version.xml
1674 docs/reference/libgail-util/Makefile
1675 docs/reference/libgail-util/version.xml
1676 docs/tools/Makefile
1677 build/Makefile
1678 build/win32/Makefile
1679 build/win32/vs9/Makefile
1680 gdk/Makefile
1681 gdk/broadway/Makefile
1682 gdk/x11/Makefile
1683 gdk/win32/Makefile
1684 gdk/win32/rc/Makefile
1685 gdk/win32/rc/gdk.rc
1686 gdk/quartz/Makefile
1687 gdk/tests/Makefile
1688 gtk/Makefile
1689 gtk/makefile.msc
1690 gtk/gtkversion.h
1691 gtk/gtk-win32.rc
1692 gtk/theme-bits/Makefile
1693 gtk/tests/Makefile
1694 modules/Makefile
1695 modules/other/Makefile
1696 modules/other/gail/Makefile
1697 modules/other/gail/libgail-util/Makefile
1698 modules/other/gail/tests/Makefile
1699 modules/engines/Makefile
1700 modules/engines/pixbuf/Makefile
1701 modules/engines/ms-windows/Makefile
1702 modules/engines/ms-windows/Theme/Makefile
1703 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1704 modules/input/Makefile
1705 modules/printbackends/Makefile
1706 modules/printbackends/cups/Makefile
1707 modules/printbackends/lpr/Makefile
1708 modules/printbackends/file/Makefile
1709 modules/printbackends/papi/Makefile
1710 modules/printbackends/test/Makefile
1711 perf/Makefile
1712 ])
1713
1714 AC_OUTPUT
1715
1716 # beautify the immodule list a bit
1717 included_immodules=${included_immodules//,/ }
1718 included_immodules=${included_immodules:-none}
1719
1720 echo "configuration:"
1721 echo "        GDK backends:         $GDK_BACKENDS"
1722 if test "x$enable_x11_backend" = "xyes"; then
1723 echo "        X11 extensions:       $X_EXTENSIONS"
1724 fi
1725 echo "        Print backends:       $PRINT_BACKENDS"
1726 echo "        Dynamic modules:      $build_dynamic_modules"
1727 echo "        Included immodules:   $included_immodules"
1728 echo "        PackageKit support:   $build_packagekit"
1729 echo "        Introspection:        $found_introspection"
1730 echo "        Debugging:            $enable_debug"
1731 echo "        Documentation:        $enable_gtk_doc"