Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ([2.62])
   4
   5 # Making releases:
   6 #   GTK_MICRO_VERSION += 1;
   7 #   GTK_INTERFACE_AGE += 1;
   8 #   GTK_BINARY_AGE += 1;
   9 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  10 # if backwards compatibility has been broken,
  11 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  12
  13 m4_define([gtk_major_version], [2])
  14 m4_define([gtk_minor_version], [90])
  15 m4_define([gtk_micro_version], [6])
  16 m4_define([gtk_interface_age], [0])
  17 m4_define([gtk_binary_age],
  18           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  19 m4_define([gtk_version],
  20           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  21 # This is the X.Y used in -lgtk-FOO-X.Y
  22 m4_define([gtk_api_version], [3.0])
  23
  24 # Define a string for the earliest version that this release has
  25 # backwards binary compatibility with for all interfaces a module
  26 # might. Unless we add module-only API with lower stability
  27 # guarantees, this should be unchanged until we break binary compat
  28 # for GTK+.
  29 #
  30 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  31 m4_define([gtk_binary_version], [3.0.0])
  32
  33 # required versions of other packages
  34 m4_define([glib_required_version], [2.25.11])
  35 m4_define([pango_required_version], [1.20])
  36 m4_define([atk_required_version], [1.29.2])
  37 m4_define([cairo_required_version], [1.9.10])
  38 m4_define([gdk_pixbuf_required_version], [2.21.0])
  39
  40
  41 AC_INIT([gtk+], [gtk_version],
  42         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  43         [gtk+])
  44
  45 AC_CONFIG_HEADER([config.h])
  46 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  47 AC_CONFIG_MACRO_DIR([m4])
  48
  49 # Save this value here, since automake will set cflags later
  50 cflags_set=${CFLAGS+set}
  51
  52 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  53 AM_MAINTAINER_MODE([enable])
  54
  55 # Support silent build rules, requires at least automake-1.11. Enable
  56 # by either passing --enable-silent-rules to configure or passing V=0
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([no])])
  59
  60 #
  61 # For each of the libraries we build, we define the following
  62 # substituted variables:
  63 #
  64 # foo_PACKAGES:     pkg-config packages this library requires
  65 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  66 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  67 # foo_DEP_LIBS:     All libraries this module requires
  68 # foo_DEP_CFLAGS:   All cflags this module requires
  69
  70
  71 GTK_MAJOR_VERSION=gtk_major_version
  72 GTK_MINOR_VERSION=gtk_minor_version
  73 GTK_MICRO_VERSION=gtk_micro_version
  74 GTK_INTERFACE_AGE=gtk_interface_age
  75 GTK_BINARY_AGE=gtk_binary_age
  76 GTK_VERSION=gtk_version
  77 GTK_API_VERSION=gtk_api_version
  78 GTK_BINARY_VERSION=gtk_binary_version
  79 AC_SUBST(GTK_MAJOR_VERSION)
  80 AC_SUBST(GTK_MINOR_VERSION)
  81 AC_SUBST(GTK_MICRO_VERSION)
  82 AC_SUBST(GTK_INTERFACE_AGE)
  83 AC_SUBST(GTK_BINARY_AGE)
  84 AC_SUBST(GTK_API_VERSION)
  85 AC_SUBST(GTK_VERSION)
  86 AC_SUBST(GTK_BINARY_VERSION)
  87
  88 # libtool versioning
  89 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  90 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
  91 #LT_REVISION=$GTK_INTERFACE_AGE
  92 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
  93 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  94
  95 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
  96 m4_define([lt_revision], [gtk_interface_age])
  97 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
  98 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
  99 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 100 AC_SUBST(LT_VERSION_INFO)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 m4_define([gail_lt_current],[0])
 104 m4_define([gail_lt_revision],[0])
 105 m4_define([gail_lt_age],[0])
 106 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 107 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 108 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 109 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 110
 111 # Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CC_C_O
 114 AC_PROG_CC_STDC
 115 AC_PROG_INSTALL
 116 AC_PROG_MAKE_SET
 117
 118
 119 GETTEXT_PACKAGE=gtk30
 120 AC_SUBST(GETTEXT_PACKAGE)
 121 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 122                    [The prefix for our gettext translation domains.])
 123
 124 AC_CANONICAL_HOST
 125
 126 MATH_LIB=-lm
 127 AC_MSG_CHECKING([for native Win32])
 128 LIB_EXE_MACHINE_FLAG=X86
 129 EXE_MANIFEST_ARCHITECTURE=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     os_win32=yes
 133     gio_can_sniff=no
 134     MATH_LIB=
 135     case "$host" in
 136     x86_64-*-*)
 137       LIB_EXE_MACHINE_FLAG=X64
 138       EXE_MANIFEST_ARCHITECTURE=AMD64
 139       ;;
 140     esac
 141     ;;
 142   *)
 143     os_win32=no
 144     ;;
 145 esac
 146 AC_MSG_RESULT([$os_win32])
 147
 148 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 149 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 150
 151 case $host in
 152   *-*-linux*)
 153     os_linux=yes
 154     ;;
 155 esac
 156
 157 dnl
 158 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 159 dnl We use this for an automated test for C++ header correctness.
 160 dnl
 161 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 162 AC_LANG_PUSH([C++])
 163
 164 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 165 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 166
 167 gtk_save_cxxflags="$CXXFLAGS"
 168 CXXFLAGS="$CXXFLAGS -x objective-c++"
 169 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 170 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 171 CXXFLAGS="$gtk_save_cxxflags"
 172 AC_LANG_POP([C++])
 173
 174 if test "$os_win32" = "yes"; then
 175   if test x$enable_static = xyes -o x$enable_static = x; then
 176     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 177     enable_static=no
 178   fi
 179   if test x$enable_shared = xno; then
 180     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 181   fi
 182   enable_shared=yes
 183 fi
 184
 185 dnl Initialize libtool
 186 LT_PREREQ([2.2.6])
 187 LT_INIT([disable-static win32-dll])
 188 # Create libtool early, because it's used in configure
 189 LT_OUTPUT
 190
 191 # Make sure we use 64-bit versions of various file stuff.
 192 AC_SYS_LARGEFILE
 193
 194 AM_PROG_AS
 195 AC_PATH_PROG(NM, nm, nm)
 196
 197 AC_MSG_CHECKING([for some Win32 platform])
 198 case "$host" in
 199   *-*-mingw*|*-*-cygwin*)
 200     platform_win32=yes
 201     ;;
 202   *)
 203     platform_win32=no
 204     ;;
 205 esac
 206 AC_MSG_RESULT([$platform_win32])
 207 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 208
 209 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 210 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 211 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 212
 213 if test "$os_win32" = "yes"; then
 214   AC_CHECK_TOOL(WINDRES, windres, no)
 215   if test "$WINDRES" = no; then
 216     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 217   fi
 218   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 219 fi
 220 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 221
 222 m4_define([debug_default],
 223           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 224
 225 dnl declare --enable-* args and collect ac_help strings
 226 AC_ARG_ENABLE(debug,
 227               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 228                              [turn on debugging @<:@default=debug_default@:>@]),,
 229               enable_debug=debug_default)
 230 AC_ARG_ENABLE(shm,
 231               [AC_HELP_STRING([--enable-shm],
 232                               [support shared memory if available [default=yes]])],,
 233               [enable_shm="yes"])
 234 AC_ARG_ENABLE(xkb,
 235               [AC_HELP_STRING([--enable-xkb],
 236                               [support XKB [default=maybe]])],,
 237               [enable_xkb="maybe"])
 238 AC_ARG_ENABLE(xinerama,
 239               [AC_HELP_STRING([--enable-xinerama],
 240                               [support xinerama extension if available [default=yes]])],,
 241               [enable_xinerama="yes"])
 242 AC_ARG_ENABLE(rebuilds,
 243               [AC_HELP_STRING([--disable-rebuilds],
 244                               [disable all source autogeneration rules])],,
 245               [enable_rebuilds=yes])
 246 AC_ARG_ENABLE(visibility,
 247               [AC_HELP_STRING([--disable-visibility],
 248                               [do not use ELF visibility attributes])],,
 249               [enable_visibility=yes])
 250
 251 AC_ARG_WITH(xinput,
 252             [AC_HELP_STRING([--with-xinput=@<:@no/yes@:>@], [support XInput])])
 253
 254 if test "$platform_win32" = yes; then
 255   gdktarget=win32
 256 else
 257   gdktarget=x11
 258 fi
 259
 260 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/win32/quartz/directfb]] select non-default GDK target],
 261         gdktarget=$with_gdktarget)
 262
 263 AC_SUBST(gdktarget)
 264 case $gdktarget in
 265   x11|win32|quartz|directfb) ;;
 266   *) AC_MSG_ERROR([Invalid target for GDK: use x11, quartz, directfb or win32.]);;
 267 esac
 268
 269 gdktargetlib=libgdk-$gdktarget-$GTK_API_VERSION.la
 270 gtktargetlib=libgtk-$gdktarget-$GTK_API_VERSION.la
 271
 272 AC_SUBST(gdktargetlib)
 273 AC_SUBST(gtktargetlib)
 274
 275 if test "x$enable_debug" = "xyes"; then
 276   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 277   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 278 else
 279   if test "x$enable_debug" = "xno"; then
 280     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 281   else
 282     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 283   fi
 284 fi
 285
 286
 287 if test "x$enable_visibility" = "xno"; then
 288   GTK_DEBUG_FLAGS="$GTK_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 289 fi
 290
 291
 292 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 293                    [Define if debugging is enabled])
 294
 295
 296 # Build time sanity check...
 297 AM_SANITY_CHECK
 298
 299 changequote(,)dnl
 300 if test "x$GCC" = "xyes"; then
 301   case " $CFLAGS " in
 302   *[\ \ ]-Wall[\ \      ]*) ;;
 303   *) CFLAGS="$CFLAGS -Wall" ;;
 304   esac
 305
 306   if test "x$enable_ansi" = "xyes"; then
 307     case " $CFLAGS " in
 308     *[\ \       ]-ansi[\ \      ]*) ;;
 309     *) CFLAGS="$CFLAGS -ansi" ;;
 310     esac
 311
 312     case " $CFLAGS " in
 313     *[\ \       ]-pedantic[\ \  ]*) ;;
 314     *) CFLAGS="$CFLAGS -pedantic" ;;
 315     esac
 316   fi
 317 fi
 318 changequote([,])dnl
 319
 320 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 321
 322 # Ensure MSVC-compatible struct packing convention is used when
 323 # compiling for Win32 with gcc.
 324 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 325 # gcc2 uses "-fnative-struct".
 326 if test x"$os_win32" = xyes; then
 327   if test x"$GCC" = xyes; then
 328     msnative_struct=''
 329     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 330     if test -z "$ac_cv_prog_CC"; then
 331       our_gcc="$CC"
 332     else
 333       our_gcc="$ac_cv_prog_CC"
 334     fi
 335     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 336       2.)
 337         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 338           msnative_struct='-fnative-struct'
 339         fi
 340         ;;
 341       *)
 342         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 343           msnative_struct='-mms-bitfields'
 344         fi
 345         ;;
 346     esac
 347     if test x"$msnative_struct" = x ; then
 348       AC_MSG_RESULT([no way])
 349       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 350     else
 351       CFLAGS="$CFLAGS $msnative_struct"
 352       AC_MSG_RESULT([${msnative_struct}])
 353     fi
 354   fi
 355 fi
 356
 357 ## Initial sanity check, done here so that users get told they
 358 ## have the wrong dependencies as early in the process as possible.
 359 ## Later on we actually use the cflags/libs from separate pkg-config
 360 ## calls. Oh, also the later pkg-config calls don't include
 361 ## the version requirements since those make the module lists
 362 ## annoying to construct
 363 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 364   [glib-2.0 >= glib_required_version dnl
 365    atk >= atk_required_version dnl
 366    pango >= pango_required_version dnl
 367    cairo >= cairo_required_version dnl
 368    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 369
 370 ## In addition to checking that cairo is present, we also need to
 371 ## check that the correct cairo backend is there. E.g. if the GDK
 372 ## target is win32 we need the cairo-win32 backend and so on.
 373 cairo_backend=$gdktarget
 374
 375 # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 376 # backend names are identical.
 377 if test "x$cairo_backend" = "xx11"; then
 378    cairo_backend=xlib
 379 fi
 380 PKG_CHECK_MODULES(CAIRO_BACKEND,
 381   [cairo-$cairo_backend >= cairo_required_version])
 382
 383 if test "$os_win32" != yes; then
 384     # libtool option to control which symbols are exported
 385     # right now, symbols starting with _ are not exported
 386     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 387 else
 388     # We currently use .def files on Windows (for gdk and gtk)
 389     LIBTOOL_EXPORT_OPTIONS=
 390 fi
 391 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 392
 393 dnl ******************************************************
 394 dnl * See whether to include shared library dependencies *
 395 dnl ******************************************************
 396
 397 AC_ARG_ENABLE(explicit-deps,
 398               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 399                               [use explicit dependencies in .pc files [default=auto]])],,
 400               [enable_explicit_deps=auto])
 401
 402 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 403 case $enable_explicit_deps in
 404   auto)
 405     export SED
 406     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 407     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 408       enable_explicit_deps=yes
 409     else
 410       enable_explicit_deps=no
 411     fi
 412   ;;
 413   yes|no)
 414   ;;
 415   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 416   ;;
 417 esac
 418 AC_MSG_RESULT($enable_explicit_deps)
 419
 420 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 421
 422 # define a MAINT-like variable REBUILD which is set if Perl
 423 # and awk are found, so autogenerated sources can be rebuilt
 424
 425 AC_PATH_PROGS(PERL, perl5 perl)
 426
 427 # We would like indent, but don't require it.
 428 AC_CHECK_PROG(INDENT, indent, indent)
 429
 430 REBUILD=\#
 431 if test "x$enable_rebuilds" = "xyes" && \
 432      test -n "$PERL" && \
 433      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 434   REBUILD=
 435 fi
 436 AC_SUBST(REBUILD)
 437
 438 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 439 AC_CHECK_FUNCS(localtime_r)
 440
 441 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 442 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 443 AC_TRY_LINK([#include <langinfo.h>], [
 444 char c;
 445 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 446 ], gtk_ok=yes, gtk_ok=no)
 447 AC_MSG_RESULT($gtk_ok)
 448 if test "$gtk_ok" = "yes"; then
 449   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 450             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 451 fi
 452
 453 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 454 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 455 AC_TRY_LINK([#include <langinfo.h>], [
 456 char c;
 457 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 458 ], gtk_ok=yes, gtk_ok=no)
 459 AC_MSG_RESULT($gtk_ok)
 460 if test "$gtk_ok" = "yes"; then
 461   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 462             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 463 fi
 464
 465 # _NL_PAPER_HEIGHT is an enum and not a define
 466 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 467 AC_TRY_LINK([#include <langinfo.h>], [
 468 char c;
 469 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 470 ], gtk_ok=yes, gtk_ok=no)
 471 AC_MSG_RESULT($gtk_ok)
 472 if test "$gtk_ok" = "yes"; then
 473   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 474             [Define if _NL_PAPER_HEIGHT is available])
 475 fi
 476
 477 # _NL_PAPER_WIDTH is an enum and not a define
 478 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 479 AC_TRY_LINK([#include <langinfo.h>], [
 480 char c;
 481 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 482 ], gtk_ok=yes, gtk_ok=no)
 483 AC_MSG_RESULT($gtk_ok)
 484 if test "$gtk_ok" = "yes"; then
 485   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 486             [Define if _NL_PAPER_WIDTH is available])
 487 fi
 488
 489 # sigsetjmp is a macro on some platforms, so AC_CHECK_FUNCS is not reliable
 490 AC_MSG_CHECKING(for sigsetjmp)
 491 AC_TRY_LINK([#include <setjmp.h>], [
 492 sigjmp_buf env;
 493 sigsetjmp(env, 0);
 494 ], gtk_ok=yes, gtk_ok=no)
 495 AC_MSG_RESULT($gtk_ok)
 496 if test "$gtk_ok" = "yes"; then
 497   AC_DEFINE(HAVE_SIGSETJMP, 1,
 498             [Define to 1 if sigsetjmp is available])
 499 fi
 500
 501 # i18n stuff
 502 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 503 AM_GLIB_GNU_GETTEXT
 504 LIBS="$LIBS $INTLLIBS"
 505 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 506         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 507       esac])
 508
 509 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 510 dnl po-properties/POTFILES during configure; see GNOME #573515.
 511 dnl
 512 dnl Generate list of files to be processed by xgettext which will
 513 dnl be included in po-properties/Makefile.
 514 test -d po-properties || mkdir po-properties
 515 if test "x$srcdir" != "x."; then
 516   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 517     popropsrcprefix="$srcdir/"
 518   else
 519     popropsrcprefix="../$srcdir/"
 520   fi
 521 else
 522   popropsrcprefix="../"
 523 fi
 524 rm -f po-properties/POTFILES
 525 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 526 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 527 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 528
 529 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 530
 531 dnl The DU4 header files don't provide library prototypes unless
 532 dnl -std1 is given to the native cc.
 533 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 534
 535 gtk_save_LIBS=$LIBS
 536 LIBS="$LIBS -lm"
 537 AC_TRY_RUN([#include <math.h>
 538              int main (void) { return (log(1) != log(1.)); }],
 539      AC_MSG_RESULT(none needed),
 540      gtk_save_CFLAGS="$CFLAGS"
 541      CFLAGS="$CFLAGS -std1"
 542      AC_TRY_RUN([#include <math.h>
 543                  int main (void) { return (log(1) != log(1.)); }],
 544          AC_MSG_RESULT(-std1),
 545          AC_MSG_RESULT()
 546          CFLAGS="$gtk_save_CFLAGS"
 547          AC_MSG_WARN(
 548                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 549          true
 550      ),
 551      AC_MSG_RESULT(none needed)
 552 )
 553 LIBS=$gtk_save_LIBS
 554
 555 AC_MSG_CHECKING(for the BeOS)
 556 case $host in
 557   *-*-beos*)
 558     AC_MSG_RESULT(yes)
 559     MATH_LIB=
 560   ;;
 561   *)
 562     AC_MSG_RESULT(no)
 563   ;;
 564 esac
 565
 566 AC_SUBST(MATH_LIB)
 567 #
 568 # see bug 162979
 569 #
 570 AC_MSG_CHECKING(for HP-UX)
 571 case $host_os in
 572   hpux9* | hpux10* | hpux11*)
 573     AC_MSG_RESULT(yes)
 574     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 575   ;;
 576   *)
 577     AC_MSG_RESULT(no)
 578   ;;
 579 esac
 580
 581 dnl NeXTStep cc seems to need this
 582 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 583 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 584   AC_MSG_RESULT(none needed),
 585   gtk_save_CFLAGS="$CFLAGS"
 586   CFLAGS="$CFLAGS -posix"
 587   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 588     AC_MSG_RESULT(-posix),
 589     AC_MSG_RESULT()
 590     CFLAGS="$gtk_save_CFLAGS"
 591     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 592
 593 #
 594 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 595 #
 596
 597 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 598
 599 AM_PATH_GLIB_2_0(glib_required_version, :,
 600   AC_MSG_ERROR([
 601 *** GLIB glib_required_version or better is required. The latest version of
 602 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 603   gobject gmodule-no-export gthread)
 604
 605 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 606 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 607 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 608 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 609   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 610 fi
 611
 612 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 613
 614
 615 dnl
 616 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 617 dnl
 618 gtk_save_LIBS=$LIBS
 619 LIBS="$LIBS $GLIB_LIBS"
 620 AC_CHECK_FUNCS(bind_textdomain_codeset)
 621 LIBS=$gtk_save_LIBS
 622
 623 AC_CHECK_HEADERS(pwd.h,
 624                  AC_DEFINE(HAVE_PWD_H, 1,
 625                            [Define to 1 if pwd.h is available]))
 626 AC_CHECK_HEADERS(sys/time.h,
 627                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 628                            [Define to 1 if time.h is available]))
 629 AC_CHECK_HEADERS(unistd.h,
 630                  AC_DEFINE(HAVE_UNISTD_H, 1,
 631                            [Define to 1 if unistd.h is available]))
 632 AC_CHECK_HEADERS(ftw.h,
 633                  AC_DEFINE(HAVE_FTW_H, 1,
 634                            [Define to 1 if ftw.h is available]))
 635
 636 AC_MSG_CHECKING([for GNU ftw extensions])
 637 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 638 #define _GNU_SOURCE
 639 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 640 if test $gtk_ok = yes; then
 641     AC_MSG_RESULT([yes])
 642     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 643 else
 644     AC_MSG_RESULT([no])
 645 fi
 646
 647 saved_cflags="$CFLAGS"
 648 saved_ldflags="$LDFLAGS"
 649
 650
 651 # Checks for header files.
 652 AC_HEADER_STDC
 653
 654 # Checks for typedefs, structures, and compiler characteristics.
 655 AC_C_CONST
 656
 657 # Checks for library functions.
 658 AC_TYPE_SIGNAL
 659 AC_FUNC_MMAP
 660
 661 AC_CHECK_FUNCS(mallinfo)
 662 AC_CHECK_FUNCS(getresuid)
 663 AC_TYPE_UID_T
 664
 665 # Check if <sys/select.h> needs to be included for fd_set
 666 AC_MSG_CHECKING([for fd_set])
 667 AC_TRY_COMPILE([#include <sys/types.h>],
 668         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 669 if test $gtk_ok = yes; then
 670     AC_MSG_RESULT([yes, found in sys/types.h])
 671 else
 672     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 673     if test $gtk_ok = yes; then
 674         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 675                   [Define to 1 if sys/select.h is available])
 676         AC_MSG_RESULT([yes, found in sys/select.h])
 677     else
 678         AC_DEFINE(NO_FD_SET, 1,
 679                   [Define to 1 if fd_set is not available])
 680         AC_MSG_RESULT(no)
 681     fi
 682 fi
 683
 684 # `widechar' tests for gdki18n.h
 685 AC_MSG_CHECKING(for wchar.h)
 686 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 687 if test $gdk_wchar_h = yes; then
 688    AC_DEFINE(HAVE_WCHAR_H, 1, [Have wchar.h include file])
 689 fi
 690 AC_MSG_RESULT($gdk_wchar_h)
 691
 692 # Check for wctype.h (for iswalnum)
 693 AC_MSG_CHECKING(for wctype.h)
 694 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 695 if test $gdk_wctype_h = yes; then
 696    AC_DEFINE(HAVE_WCTYPE_H, 1, [Have wctype.h include file])
 697 fi
 698 AC_MSG_RESULT($gdk_wctype_h)
 699
 700 # in Solaris 2.5, `iswalnum' is in -lw
 701 GDK_WLIBS=
 702 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 703
 704 oLIBS="$LIBS"
 705 LIBS="$LIBS $GDK_WLIBS"
 706 # The following is necessary for Linux libc-5.4.38
 707 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 708 AC_TRY_LINK([#include <stdlib.h>],[
 709 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 710 #  ifdef HAVE_WCTYPE_H
 711 #    include <wctype.h>
 712 #  else
 713 #    ifdef HAVE_WCHAR_H
 714 #      include <wchar.h>
 715 #    endif
 716 #  endif
 717 #else
 718 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 719 #endif
 720 iswalnum((wchar_t) 0);
 721 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 722 LIBS="$oLIBS"
 723
 724 if test $gdk_working_wctype = no; then
 725    AC_DEFINE(HAVE_BROKEN_WCTYPE, 1, [Is the wctype implementation broken])
 726    GDK_WLIBS=
 727 fi
 728 AC_MSG_RESULT($gdk_working_wctype)
 729 AC_SUBST(GDK_WLIBS)
 730
 731 # Check for uxtheme.h (for MS-Windows Engine)
 732 AC_MSG_CHECKING(for uxtheme.h)
 733 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 734 if test $gtk_uxtheme_h = yes; then
 735    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 736 fi
 737 AC_MSG_RESULT($gtk_uxtheme_h)
 738
 739 # Checks for gdkspawn
 740 AC_CHECK_HEADERS(crt_externs.h)
 741 AC_CHECK_FUNCS(_NSGetEnviron)
 742
 743 AC_MSG_CHECKING(whether to build dynamic modules)
 744
 745 AC_ARG_ENABLE(modules,
 746               [AC_HELP_STRING([--disable-modules],
 747                               [disable dynamic module loading])])
 748
 749 dynworks=false
 750 deps=
 751 if test x$enable_modules = xno; then
 752     AC_MSG_RESULT(no)
 753 else
 754     AC_MSG_RESULT(yes)
 755     AC_MSG_CHECKING(whether dynamic modules work)
 756     ## for loop is to strip newline
 757     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 758     for I in $tmp; do
 759         dynworks=$I
 760     done
 761
 762     dnl Now we check to see if our libtool supports shared lib deps
 763     dnl (in a rather ugly way even)
 764     if $dynworks; then
 765         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 766         module_deplibs_check=`$module_libtool_config | \
 767             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 768             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 769         if test "x$module_deplibs_check" = "xnone" || \
 770            test "x$module_deplibs_check" = "xunknown" || \
 771            test "x$module_deplibs_check" = "x"; then
 772             dynworks=false
 773         fi
 774     fi
 775
 776     if $dynworks; then
 777         AC_DEFINE(USE_GMODULE, 1,
 778                   [Define to 1 if gmodule works and should be used])
 779         AC_MSG_RESULT(yes)
 780     else
 781         AC_MSG_RESULT(no)
 782     fi
 783 fi
 784
 785 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 786
 787 #
 788 # Allow building some or all immodules included
 789 #
 790 AC_MSG_CHECKING(immodules to build)
 791
 792 dnl due to an autoconf bug, commas in the first arg to
 793 dnl AC_HELP_STRING cause problems.
 794 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
 795 dnl                [build the specified input method modules into gtk])
 796 AC_ARG_WITH(included_immodules,
 797 [  --with-included-immodules=MODULE1,MODULE2,...
 798                           build the specified input methods into gtk])
 799
 800 if $dynworks; then
 801    :
 802 else
 803    ## if the option was specified, leave it; otherwise disable included immodules
 804    if test x$with_included_immodules = xno; then
 805            with_included_immodules=yes
 806    fi
 807 fi
 808
 809 all_immodules="am-et,cedilla,cyrillic-translit"
 810 if test "$gdktarget" = "win32"; then
 811    all_immodules="${all_immodules},ime"
 812 fi
 813 all_immodules="${all_immodules},inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr"
 814 if test "$gdktarget" = "x11"; then
 815    all_immodules="${all_immodules},xim"
 816 fi
 817
 818 included_immodules=""
 819 # If the switch specified without listing any specific ones, include all
 820 if test "x$with_included_immodules" = xyes ; then
 821   included_immodules="$all_immodules"
 822 else
 823   included_immodules="$with_included_immodules"
 824 fi
 825
 826 AC_MSG_RESULT($included_immodules)
 827 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 828
 829 INCLUDED_IMMODULE_OBJ=
 830 INCLUDED_IMMODULE_DEFINE=
 831
 832 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 833 for immodule in $included_immodules; do
 834  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 835  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 836    :
 837  else
 838    AC_MSG_ERROR([the specified input method $immodule does not exist])
 839  fi
 840
 841  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 842  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 843  eval INCLUDE_$immodule_underscores=yes
 844 done
 845 IFS="$gtk_save_ifs"
 846 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 847 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 848
 849 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 850 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 851 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 852 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 853 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 854 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 855 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 856 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 857 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 858 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 859 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 860 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 861
 862 AC_HEADER_SYS_WAIT
 863
 864 AC_TYPE_SIGNAL
 865
 866 # Checks to see whether we should include mediaLib
 867 # support.
 868 #
 869 AC_CHECK_HEADER(sys/systeminfo.h,
 870                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 871                           [Define to 1 if sys/systeminfo.h is available]))
 872 AC_CHECK_HEADER(sys/sysinfo.h,
 873                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 874                           [Define to 1 if sys/sysinfo.h is available]))
 875
 876 AC_MSG_CHECKING(for mediaLib 2.3)
 877 use_mlib25=no
 878 # Check for a mediaLib 2.3 function since that is what the GTK+ mediaLib
 879 # patch requires.
 880 AC_CHECK_LIB(mlib, mlib_ImageSetStruct, use_mlib=yes, use_mlib=no)
 881 if test $use_mlib = yes; then
 882     AC_DEFINE(USE_MEDIALIB, 1,
 883               [Define to 1 if medialib is available and should be used])
 884     MEDIA_LIB=-lmlib
 885
 886     AC_MSG_CHECKING(for mediaLib 2.5)
 887     # Check for a mediaLib 2.5 function since that is what is needed for
 888     # gdk_rgb_convert integration.
 889     AC_CHECK_LIB(mlib, mlib_VideoColorRGBint_to_BGRAint, use_mlib25=yes, use_mlib25=no)
 890     if test $use_mlib25 = yes; then
 891         AC_DEFINE(USE_MEDIALIB25, 1,
 892                   [Define to 1 if medialib 2.5 is available])
 893     fi
 894 fi
 895 AM_CONDITIONAL(USE_MEDIALIB, test $use_mlib = yes)
 896 AM_CONDITIONAL(USE_MEDIALIB25, test $use_mlib25 = yes)
 897
 898 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 899
 900 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 901
 902 if test $cross_compiling = yes; then
 903   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 904   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 905     REBUILD_PNGS=#
 906   fi
 907 fi
 908
 909 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 910
 911 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 912    test "x$REBUILD_PNGS" = "x#" ; then
 913      AC_MSG_ERROR([
 914 *** gtkbuiltincache.h is not in the tree, and cannot be built
 915 *** because you don't have libpng, or (when cross-compiling) you
 916 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 917 fi
 918
 919 ########################################
 920 # Windowing system checks
 921 ########################################
 922
 923 GDK_EXTRA_LIBS="$GDK_WLIBS"
 924 GDK_EXTRA_CFLAGS=
 925
 926 # GTK+ uses some X calls, so needs to link against X directly
 927 GTK_DEP_PACKAGES_FOR_X=
 928 GTK_DEP_LIBS_FOR_X=
 929
 930 if test "x$gdktarget" = "xx11"; then
 931   X_PACKAGES=fontconfig
 932
 933   #
 934   # We use fontconfig very peripherally when decoding the default
 935   # settings.
 936   #
 937   if $PKG_CONFIG --exists fontconfig; then : ; else
 938     AC_MSG_ERROR([
 939 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 940   fi
 941
 942   #
 943   # Check for basic X packages; we use pkg-config if available
 944   #
 945   if $PKG_CONFIG --exists x11 xext xrender; then
 946     have_base_x_pc=true
 947     X_PACKAGES="$X_PACKAGES x11 xext xrender"
 948     x_libs="`$PKG_CONFIG --libs x11 xext xrender`"
 949     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext xrender`"
 950
 951     # Strip out any .la files that pkg-config might give us (this happens
 952     # with -uninstalled.pc files)
 953     x_libs_for_checks=
 954     for I in $x_libs ; do
 955       case $I in
 956         *.la) ;;
 957         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 958       esac
 959     done
 960
 961     GTK_PACKAGES_FOR_X="x11"
 962   else
 963     have_base_x_pc=false
 964     AC_PATH_XTRA
 965     if test x$no_x = xyes ; then
 966       AC_MSG_ERROR([X development libraries not found])
 967     fi
 968
 969     x_cflags="$X_CFLAGS"
 970     x_libs_for_checks="$X_LIBS -lXext -lXrender -lX11 $X_EXTRA_LIBS"
 971
 972     GTK_DEP_LIBS_FOR_X="$X_LIBS -lXrender -lX11 $X_EXTRA_LIBS"
 973   fi
 974
 975   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 976   x_extra_libs=
 977
 978   gtk_save_cppflags="$CPPFLAGS"
 979   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 980
 981   gtk_save_LIBS=$LIBS
 982   LIBS="$x_libs_for_checks $LIBS"
 983
 984   # Sanity check for the X11 and Xext libraries. While everything we need from
 985   # Xext is optional, the chances a system has *none* of these things is so
 986   # small that we just unconditionally require it.
 987   AC_CHECK_FUNC(XOpenDisplay, :,
 988                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 989   AC_CHECK_FUNC(XextFindDisplay, :,
 990                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 991   AC_CHECK_FUNC(XRenderQueryExtension, :,
 992                 AC_MSG_ERROR([*** libXrender not found. Check 'config.log' for more details.]))
 993
 994   # Check for xReply
 995
 996   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 997   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
 998       [xReply *rep;],
 999       [AC_MSG_RESULT([no])],
1000       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
1001 #include <X11/Xlibint.h>],
1002            [xReply *rep;],
1003            [AC_MSG_RESULT([yes])
1004             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
1005                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
1006            [AC_MSG_RESULT([unknown])
1007             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1008
1009   # Check for XConvertCase, XInternAtoms (X11R6 specific)
1010
1011   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
1012
1013   # Generic X11R6 check needed for XIM support; we could
1014   # probably use this to replace the above, but we'll
1015   # leave the separate checks for XConvertCase and XInternAtoms
1016   # for clarity
1017
1018   have_x11r6=false
1019   AC_CHECK_FUNC(XAddConnectionWatch,
1020       have_x11r6=true)
1021
1022   if $have_x11r6; then
1023     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1024   fi
1025   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1026
1027   # Check for XKB support.
1028
1029   if test "x$enable_xkb" = "xyes"; then
1030         AC_MSG_WARN(XKB support explicitly enabled)
1031         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
1032   elif test "x$enable_xkb" = "xmaybe"; then
1033         AC_CHECK_FUNC(XkbQueryExtension,
1034                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1035   else
1036         AC_MSG_WARN(XKB support explicitly disabled)
1037   fi
1038
1039   # Check for shaped window extension
1040
1041   AC_CHECK_FUNC(XShapeCombineMask, :,
1042      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1043
1044   # X SYNC check
1045   gtk_save_CFLAGS="$CFLAGS"
1046   CFLAGS="$CFLAGS $x_cflags"
1047
1048   AC_CHECK_FUNC(XSyncQueryExtension,
1049       [AC_CHECK_HEADER(X11/extensions/sync.h,
1050           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1051           :, [#include <X11/Xlib.h>])])
1052
1053   CFLAGS="$gtk_save_CFLAGS"
1054
1055   # Xshm checks
1056
1057   if test "x$enable_shm" = "xyes"; then
1058      # Check for the XShm extension, normally in Xext
1059      AC_CHECK_FUNC(XShmAttach,
1060         :,
1061         # On AIX, it is in XextSam instead
1062         [AC_CHECK_LIB(XextSam, XShmAttach,
1063             [GTK_ADD_LIB(x_extra_libs,XextSam)])])
1064   fi
1065
1066   if test "x$enable_shm" = "xyes"; then
1067     # Check for shared memory
1068     AC_CHECK_HEADER(sys/ipc.h,
1069                     AC_DEFINE(HAVE_IPC_H, 1,
1070                               [Define to 1 if ipc.h is available]),
1071                     no_sys_ipc=yes)
1072     AC_CHECK_HEADER(sys/shm.h,
1073                     AC_DEFINE(HAVE_SHM_H, 1,
1074                               [Define to 1 if shm.h is available]),
1075                     no_sys_shm=yes)
1076
1077     # Check for the X shared memory extension header file
1078     have_xshm=no
1079     AC_MSG_CHECKING(X11/extensions/XShm.h)
1080     if test "x$no_xext_lib" = "xyes"; then
1081       :
1082     else
1083       gtk_save_CFLAGS="$CFLAGS"
1084       CFLAGS="$CFLAGS $x_cflags"
1085       AC_TRY_COMPILE([
1086 #include <stdlib.h>
1087 #include <sys/types.h>
1088 #include <sys/ipc.h>
1089 #include <sys/shm.h>
1090 #include <X11/Xlib.h>
1091 #include <X11/Xutil.h>
1092 #include <X11/extensions/XShm.h>
1093 ], [XShmSegmentInfo *x_shm_info;], have_xshm=yes)
1094       CFLAGS="$gtk_save_CFLAGS"
1095     fi
1096     AC_MSG_RESULT($have_xshm)
1097     if test $have_xshm = yes ; then
1098       AC_DEFINE(HAVE_XSHM_H, 1,
1099                 [Define to 1 if xshm.h is available])
1100     fi
1101   fi
1102
1103   if test "x$enable_xinerama" = "xyes"; then
1104     # Check for Xinerama extension (Solaris impl or Xfree impl)
1105     gtk_save_cppflags="$CPPFLAGS"
1106     CPPFLAGS="$CPPFLAGS $x_cflags"
1107
1108     # Check for XFree
1109     AC_MSG_CHECKING(for Xinerama support on XFree86)
1110
1111     have_xfree_xinerama=false
1112     if $PKG_CONFIG --exists xinerama ; then
1113        have_xfree_xinerama=true
1114        X_PACKAGES="$X_PACKAGES xinerama"
1115     else
1116        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1117            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1118            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1119            have_xfree_xinerama=true], :,
1120            [#include <X11/Xlib.h>])])
1121     fi
1122
1123     if $have_xfree_xinerama ; then
1124       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1125                 [Define to 1 if XFree Xinerama is available])
1126       AC_DEFINE(HAVE_XINERAMA, 1,
1127                 [Define to 1 is Xinerama is available])
1128       AC_MSG_RESULT(yes)
1129     else
1130       AC_MSG_RESULT(no)
1131
1132       case "$host" in
1133         *-*-solaris*)
1134             # Check for solaris
1135             AC_MSG_CHECKING(for Xinerama support on Solaris)
1136
1137             have_solaris_xinerama=false
1138             AC_CHECK_FUNC(XineramaGetInfo,
1139                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1140                     [have_solaris_xinerama=true], :,
1141                     [#include <X11/Xlib.h>])])
1142
1143             if $have_solaris_xinerama ; then
1144               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1145                         [Define to 1 if solaris xinerama is available])
1146               AC_DEFINE(HAVE_XINERAMA, 1,
1147                         [Define to 1 if xinerama is available])
1148               AC_MSG_RESULT(yes)
1149             else
1150               AC_MSG_RESULT(no)
1151             fi
1152             ;;
1153         *)
1154             ;;
1155       esac
1156     fi
1157   fi
1158
1159   # set up things for XInput
1160   if test "x$with_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1161     have_xinput=yes
1162
1163     AC_DEFINE(XINPUT_XFREE, 1,
1164               [Define to 1 if XFree XInput should be used])
1165
1166     X_PACKAGES="$X_PACKAGES xi"
1167
1168     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1169                     have_xinput2=yes; AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1170   else
1171     AC_DEFINE(XINPUT_NONE, 1,
1172               [Define to 1 if no XInput should be used])
1173   fi
1174
1175   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1176   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1177
1178   # Check for the RANDR extension
1179   if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1180      AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1181
1182      X_PACKAGES="$X_PACKAGES xrandr"
1183   fi
1184
1185   # Checks for Xcursor library
1186
1187   if $PKG_CONFIG --exists xcursor ; then
1188     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1189
1190     X_PACKAGES="$X_PACKAGES xcursor"
1191   fi
1192
1193   # Checks for XFixes extension
1194
1195   if $PKG_CONFIG --exists xfixes ; then
1196     AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1197
1198     X_PACKAGES="$X_PACKAGES xfixes"
1199     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1200   fi
1201
1202   # Checks for Xcomposite extension
1203
1204   if $PKG_CONFIG --exists xcomposite ; then
1205     AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1206
1207     X_PACKAGES="$X_PACKAGES xcomposite"
1208     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1209   fi
1210
1211   # Checks for Xdamage extension
1212
1213   if $PKG_CONFIG --exists xdamage ; then
1214     AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1215
1216     X_PACKAGES="$X_PACKAGES xdamage"
1217     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1218   fi
1219
1220   if $have_base_x_pc ; then
1221     GDK_EXTRA_LIBS="$x_extra_libs"
1222   else
1223     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1224   fi
1225
1226   CPPFLAGS="$gtk_save_cppflags"
1227   LIBS="$gtk_save_libs"
1228
1229   AM_CONDITIONAL(USE_X11, true)
1230 else
1231   XPACKAGES=
1232
1233   AM_CONDITIONAL(XINPUT_XFREE, false)
1234   AM_CONDITIONAL(XINPUT_2, false)
1235   AM_CONDITIONAL(USE_X11, false)
1236   AM_CONDITIONAL(HAVE_X11R6, false)
1237 fi
1238
1239 if test "x$gdktarget" = "xwin32"; then
1240   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
1241   AM_CONDITIONAL(USE_WIN32, true)
1242 else
1243   AM_CONDITIONAL(USE_WIN32, false)
1244 fi
1245
1246 if test "x$gdktarget" = "xquartz"; then
1247   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
1248   AM_CONDITIONAL(USE_QUARTZ, true)
1249 else
1250   AM_CONDITIONAL(USE_QUARTZ, false)
1251 fi
1252
1253 if test "x$gdktarget" = "xdirectfb"; then
1254   DIRECTFB_REQUIRED_VERSION=1.0.0
1255   AC_MSG_CHECKING(for DirectFB)
1256
1257   PKG_CHECK_MODULES(DIRECTFB, [directfb >= $DIRECTFB_REQUIRED_VERSION])
1258   AM_CONDITIONAL(USE_DIRECTFB, true)
1259 else
1260   AM_CONDITIONAL(USE_DIRECTFB, false)
1261 fi
1262
1263
1264 # Check for Pango flags
1265
1266 if test "x$gdktarget" = "xwin32"; then
1267         PANGO_PACKAGES="pangowin32 pangocairo"
1268 else
1269         PANGO_PACKAGES="pango pangocairo"
1270 fi
1271
1272 AC_MSG_CHECKING(Pango flags)
1273 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1274         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1275         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1276
1277         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1278 else
1279         AC_MSG_ERROR([
1280 *** Pango not found. Pango built with Cairo support is required
1281 *** to build GTK+. See http://www.pango.org for Pango information.
1282 ])
1283 fi
1284
1285 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1286
1287 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1288         :
1289 else
1290         gtk_save_LIBS="$LIBS"
1291         LIBS="$PANGO_LIBS $LIBS"
1292         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1293 *** Can't link to Pango. Pango is required to build
1294 *** GTK+. For more information see http://www.pango.org]))
1295         LIBS="$gtk_save_LIBS"
1296 fi
1297
1298 CFLAGS="$saved_cflags"
1299 LDFLAGS="$saved_ldflags"
1300
1301 # Pull in gio-unix for GDesktopAppInfo usage, see at least gdkapplaunchcontext-x11.c
1302 if test "x$gdktarget" = "xx11"; then
1303   GDK_PACKAGES="$PANGO_PACKAGES gio-unix-2.0 $X_PACKAGES gdk-pixbuf-2.0 cairo-$cairo_backend"
1304 else
1305   GDK_PACKAGES="$PANGO_PACKAGES gio-2.0 gdk-pixbuf-2.0 cairo-$cairo_backend"
1306 fi
1307
1308 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1309 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1310 #
1311 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1312 # into the pkg-config files
1313 #
1314 if test $enable_explicit_deps != yes ; then
1315   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0"
1316   GDK_EXTRA_LIBS=
1317 fi
1318
1319 AC_SUBST(GDK_PACKAGES)
1320 AC_SUBST(GDK_EXTRA_LIBS)
1321 AC_SUBST(GDK_EXTRA_CFLAGS)
1322 AC_SUBST(GDK_DEP_LIBS)
1323 AC_SUBST(GDK_DEP_CFLAGS)
1324
1325
1326 ########################################
1327 # Check for Accessibility Toolkit flags
1328 ########################################
1329
1330 ATK_PACKAGES=atk
1331 AC_MSG_CHECKING(ATK flags)
1332 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1333         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1334         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1335
1336         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1337 else
1338         AC_MSG_ERROR([
1339 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1340 *** to build GTK+.
1341 ])
1342 fi
1343
1344 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1345         :
1346 else
1347         gtk_save_LIBS="$LIBS"
1348         LIBS="$ATK_LIBS $LIBS"
1349         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1350                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1351                 *** to build GTK+]))
1352         LIBS="$gtk_save_LIBS"
1353 fi
1354
1355 GTK_PACKAGES="atk cairo gdk-pixbuf-2.0 gio-2.0"
1356 if test "x$gdktarget" = "xx11"; then
1357   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1358 fi
1359 GTK_EXTRA_LIBS=
1360 GTK_EXTRA_CFLAGS=
1361 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1362 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1363
1364 if test x"$os_win32" = xyes; then
1365   GTK_EXTRA_CFLAGS="$msnative_struct"
1366 fi
1367
1368 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1369 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1370 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1371 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1372
1373 AC_SUBST(GTK_PACKAGES)
1374 AC_SUBST(GTK_EXTRA_LIBS)
1375 AC_SUBST(GTK_EXTRA_CFLAGS)
1376 AC_SUBST(GTK_DEP_LIBS)
1377 AC_SUBST(GTK_DEP_CFLAGS)
1378
1379 AC_SUBST(GLIB_PREFIX)
1380 AC_SUBST(ATK_PREFIX)
1381 AC_SUBST(PANGO_PREFIX)
1382 AC_SUBST(CAIRO_PREFIX)
1383
1384 AC_SUBST(GTK_DEBUG_FLAGS)
1385 AC_SUBST(GTK_XIM_FLAGS)
1386
1387 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1388 AC_SUBST(GDK_PIXBUF_LIBS)
1389
1390 ########################
1391 # Checks needed for gail
1392 ########################
1393
1394 old_LIBS="$LIBS"
1395 dnl Checks for inet libraries:
1396 AC_SEARCH_LIBS(gethostent, nsl)
1397 AC_SEARCH_LIBS(setsockopt, socket)
1398 AC_SEARCH_LIBS(connect, inet)
1399
1400 dnl check for the sockaddr_un.sun_len member
1401 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1402                 [struct_sockaddr_un_sun_len=true],
1403                 [struct_sockaddr_un_suin_len=false],
1404                 [#include <sys/types.h>
1405                  #include <sys/un.h>]
1406                 )
1407 case $struct_sockaddr_un_sun_len in
1408         true)
1409                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1410                                    [Have the sockaddr_un.sun_len member])
1411                 ;;
1412         *)
1413                 ;;
1414 esac
1415
1416 GAIL_INET_LIBS="$LIBS"
1417 AC_SUBST([GAIL_INET_LIBS])
1418
1419 LIBS="$old_LIBS"
1420
1421 ################################################################
1422 # Printing system checks
1423 ################################################################
1424
1425 AC_ARG_ENABLE(cups,
1426               [AC_HELP_STRING([--disable-cups]
1427                               [disable cups print backend])],,
1428               [enable_cups=auto])
1429
1430 if test "x$enable_cups" = "xno"; then
1431   AM_CONDITIONAL(HAVE_CUPS, false)
1432 else
1433   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1434   if test "x$CUPS_CONFIG" = "xno"; then
1435     if test "x$enable_cups" = "xauto"; then
1436       AM_CONDITIONAL(HAVE_CUPS, false)
1437     else
1438       AC_MSG_ERROR([
1439 *** cups not found.
1440 ])
1441     fi
1442   else
1443     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1444     CUPS_LIBS=`$CUPS_CONFIG --libs`
1445
1446     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1447     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1448     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1449
1450     if test $CUPS_API_MAJOR -gt 1 -o \
1451             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1452       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1453                 [Define to 1 if CUPS 1.2 API is available])
1454     fi
1455
1456     AC_SUBST(CUPS_API_MAJOR)
1457     AC_SUBST(CUPS_API_MINOR)
1458     AC_SUBST(CUPS_CFLAGS)
1459     AC_SUBST(CUPS_LIBS)
1460
1461     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1462
1463     AM_CONDITIONAL(HAVE_CUPS, true)
1464
1465     gtk_save_cflags="$CFLAGS"
1466     CFLAGS="$CUPS_CFLAGS"
1467     AC_TRY_COMPILE([#include <cups/http.h>],
1468                    [http_t http; char *s = http.authstring;],
1469                    [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1470                               [Define if cups http_t authstring field is accessible])],)
1471     CFLAGS="$gtk_save_cflags"
1472
1473     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1474
1475     gtk_save_libs="$LIBS"
1476     LIBS="$CUPS_LIBS"
1477     AC_CHECK_FUNCS(httpGetAuthString)
1478     LIBS="$gtk_save_libs"
1479   fi
1480 fi
1481
1482 # Checks to see if we should compile with PAPI backend for GTK+
1483 #
1484
1485 AC_ARG_ENABLE(papi,
1486               [AC_HELP_STRING([--disable-papi]
1487                               [disable papi print backend])],,
1488              [enable_papi=auto])
1489
1490 if test "x$enable_papi" = "xno"; then
1491   AM_CONDITIONAL(HAVE_PAPI, false)
1492 else
1493   AC_MSG_CHECKING(libpapi)
1494   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1495   if test $have_papi = yes; then
1496     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1497   fi
1498   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1499   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1500     AC_MSG_ERROR([
1501 *** papi not found.
1502 ])
1503   fi
1504 fi
1505
1506 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1507
1508 gtk_save_cppflags="$CPPFLAGS"
1509 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1510
1511 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1512 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1513 *** backend enabled.]))
1514
1515 if test "$os_win32" != "yes"; then
1516   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1517 *** Can't find cairo-ps.h. You must build Cairo with the
1518 *** postscript backend enabled.]))
1519
1520   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1521 *** Can't find cairo-svg.h. You must build Cairo with the
1522 *** svg backend enabled.]))
1523 fi
1524
1525 CPPFLAGS="$gtk_save_cppflags"
1526
1527
1528 AC_ARG_ENABLE(test-print-backend,
1529               [AC_HELP_STRING([--enable-test-print-backend],
1530                               [build test print backend])],,
1531               [enable_test_print_backend=no])
1532 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1533
1534
1535 ################################################################
1536 # Strip -export-dynamic from the link lines of various libraries
1537 ################################################################
1538
1539 #
1540 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1541 #  but this flag is only meaningful for executables. For libraries
1542 #  the effect is undefined; what it causes on Linux is that the
1543 #  export list from -export-symbols-regex is ignored and everything
1544 #  is exported
1545 #
1546 # We are using gmodule-no-export now, but I'm leaving the stripping
1547 # code in place for now, since pango and atk still require gmodule.
1548 export SED
1549 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1550 if test -n "$export_dynamic"; then
1551   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1552   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1553 fi
1554
1555 ##################################################
1556 # GObject introspection
1557 ##################################################
1558
1559 GOBJECT_INTROSPECTION_CHECK([0.9.0])
1560
1561 ##################################################
1562 # Checks for gtk-doc and docbook-tools
1563 ##################################################
1564
1565 GTK_DOC_CHECK([1.11])
1566
1567 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1568 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1569
1570 AC_ARG_ENABLE(man,
1571               [AC_HELP_STRING([--enable-man],
1572                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1573               enable_man=no)
1574
1575 if test "${enable_man}" != no; then
1576   dnl
1577   dnl Check for xsltproc
1578   dnl
1579   AC_PATH_PROG([XSLTPROC], [xsltproc])
1580   if test -z "$XSLTPROC"; then
1581     enable_man=no
1582   fi
1583
1584   dnl check for DocBook DTD and stylesheets in the local catalog.
1585   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1586      [DocBook XML DTD V4.1.2],,enable_man=no)
1587   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1588      [DocBook XSL Stylesheets],,enable_man=no)
1589 fi
1590
1591 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1592
1593
1594 ##################################################
1595 # Output commands
1596 ##################################################
1597
1598 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1599         outfile=gdkconfig.h-tmp
1600         cat > $outfile <<\_______EOF
1601 /* gdkconfig.h
1602  *
1603  * This is a generated file.  Please modify `configure.ac'
1604  */
1605
1606 #ifndef GDKCONFIG_H
1607 #define GDKCONFIG_H
1608
1609 #ifdef __cplusplus
1610 extern "C" {
1611 #endif /* __cplusplus */
1612
1613 #ifndef GSEAL
1614 /* introduce GSEAL() here for all of Gdk and Gtk+ without the need to modify GLib */
1615 #  ifdef GSEAL_ENABLE
1616 #    define GSEAL(ident)      _g_sealed__ ## ident
1617 #  else
1618 #    define GSEAL(ident)      ident
1619 #  endif
1620 #endif /* !GSEAL */
1621
1622 _______EOF
1623
1624         cat >>$outfile <<_______EOF
1625 $gdk_windowing
1626 $gdk_wc
1627 _______EOF
1628
1629         cat >>$outfile <<_______EOF
1630
1631 #ifdef __cplusplus
1632 }
1633 #endif /* __cplusplus */
1634
1635 #endif /* GDKCONFIG_H */
1636 _______EOF
1637
1638
1639         if cmp -s $outfile gdk/gdkconfig.h; then
1640           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1641           rm -f $outfile
1642         else
1643           mv $outfile gdk/gdkconfig.h
1644         fi
1645 ],[
1646 if test "x$gdktarget" = "xx11" ; then
1647   gdk_windowing='
1648 #define GDK_WINDOWING_X11'
1649 elif test "x$gdktarget" = "xwin32" ; then
1650   gdk_windowing='
1651 #define GDK_NATIVE_WINDOW_POINTER
1652
1653 #define GDK_WINDOWING_WIN32'
1654 elif test "x$gdktarget" = "xquartz" ; then
1655   gdk_windowing='
1656 #define GDK_WINDOWING_QUARTZ'
1657 elif test "x$gdktarget" = "xdirectfb" ; then
1658   gdk_windowing='
1659 #define GDK_WINDOWING_DIRECTFB'
1660 fi
1661
1662 if test x$gdk_wchar_h = xyes; then
1663   gdk_wc='
1664 #define GDK_HAVE_WCHAR_H 1'
1665 fi
1666 if test x$gdk_wctype_h = xyes; then
1667   gdk_wc="\$gdk_wc
1668 #define GDK_HAVE_WCTYPE_H 1"
1669 fi
1670 if test x$gdk_working_wctype = xno; then
1671   gdk_wc="\$gdk_wc
1672 #define GDK_HAVE_BROKEN_WCTYPE 1"
1673 fi
1674 ])
1675
1676 dnl
1677 dnl Check for -Bsymbolic-functions linker flag used to avoid
1678 dnl intra-library PLT jumps, if available.
1679 dnl
1680 AC_ARG_ENABLE(Bsymbolic,
1681               [AC_HELP_STRING([--disable-Bsymbolic],
1682                               [avoid linking with -Bsymbolic])],,
1683               [SAVED_LDFLAGS="${LDFLAGS}"
1684                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1685                LDFLAGS=-Wl,-Bsymbolic-functions
1686                AC_TRY_LINK([], [int main (void) { return 0; }],
1687                            AC_MSG_RESULT(yes)
1688                            enable_Bsymbolic=yes,
1689                            AC_MSG_RESULT(no)
1690                            enable_Bsymbolic=no)
1691                LDFLAGS="${SAVED_LDFLAGS}"])
1692
1693 if test "x${enable_Bsymbolic}" == "xyes"; then
1694   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1695 fi
1696 AC_SUBST(GTK_LINK_FLAGS)
1697
1698 AC_CONFIG_FILES([
1699 config.h.win32
1700 gtk-zip.sh
1701 Makefile
1702 gdk-3.0.pc
1703 gtk+-3.0.pc
1704 gtk+-unix-print-3.0.pc
1705 gail-3.0.pc
1706 gdk-3.0-uninstalled.pc
1707 gtk+-3.0-uninstalled.pc
1708 gail-3.0-uninstalled.pc
1709 m4macros/Makefile
1710 po/Makefile.in
1711 po-properties/Makefile.in
1712 demos/Makefile
1713 demos/gtk-demo/Makefile
1714 demos/gtk-demo/geninclude.pl
1715 tests/Makefile
1716 docs/Makefile
1717 docs/reference/Makefile
1718 docs/reference/gdk/Makefile
1719 docs/reference/gdk/version.xml
1720 docs/reference/gtk/Makefile
1721 docs/reference/gtk/version.xml
1722 docs/reference/libgail-util/Makefile
1723 docs/faq/Makefile
1724 docs/tools/Makefile
1725 docs/tutorial/Makefile
1726 build/Makefile
1727 build/win32/Makefile
1728 build/win32/vs9/Makefile
1729 gdk/Makefile
1730 gdk/x11/Makefile
1731 gdk/win32/Makefile
1732 gdk/win32/rc/Makefile
1733 gdk/win32/rc/gdk.rc
1734 gdk/quartz/Makefile
1735 gdk/directfb/Makefile
1736 gdk/tests/Makefile
1737 gtk/Makefile
1738 gtk/makefile.msc
1739 gtk/gtkversion.h
1740 gtk/gtk-win32.rc
1741 gtk/theme-bits/Makefile
1742 gtk/tests/Makefile
1743 modules/Makefile
1744 modules/other/Makefile
1745 modules/other/gail/Makefile
1746 modules/other/gail/libgail-util/Makefile
1747 modules/other/gail/tests/Makefile
1748 modules/engines/Makefile
1749 modules/engines/pixbuf/Makefile
1750 modules/engines/ms-windows/Makefile
1751 modules/engines/ms-windows/Theme/Makefile
1752 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1753 modules/input/Makefile
1754 modules/printbackends/Makefile
1755 modules/printbackends/cups/Makefile
1756 modules/printbackends/lpr/Makefile
1757 modules/printbackends/file/Makefile
1758 modules/printbackends/papi/Makefile
1759 modules/printbackends/test/Makefile
1760 perf/Makefile
1761 ])
1762
1763 AC_OUTPUT
1764
1765 echo "configuration:
1766         target: $gdktarget"