Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [2])
  12 m4_define([gtk_minor_version], [99])
  13 m4_define([gtk_micro_version], [3])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Define a string for the earliest version that this release has
  32 # backwards binary compatibility with for all interfaces a module
  33 # might. Unless we add module-only API with lower stability
  34 # guarantees, this should be unchanged until we break binary compat
  35 # for GTK+.
  36 #
  37 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  38 m4_define([gtk_binary_version], [3.0.0])
  39
  40 # required versions of other packages
  41 m4_define([glib_required_version], [2.27.5])
  42 m4_define([pango_required_version], [1.20])
  43 m4_define([atk_required_version], [1.29.2])
  44 m4_define([cairo_required_version], [1.10.0])
  45 m4_define([gdk_pixbuf_required_version], [2.21.0])
  46 GLIB_REQUIRED_VERSION=glib_required_version
  47 PANGO_REQUIRED_VERSION=pango_required_version
  48 ATK_REQUIRED_VERSION=atk_required_version
  49 CAIRO_REQUIRED_VERSION=cairo_required_version
  50 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  51 AC_SUBST(GLIB_REQUIRED_VERSION)
  52 AC_SUBST(PANGO_REQUIRED_VERSION)
  53 AC_SUBST(ATK_REQUIRED_VERSION)
  54 AC_SUBST(CAIRO_REQUIRED_VERSION)
  55 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  56
  57
  58 # Save this value here, since automake will set cflags later
  59 cflags_set=${CFLAGS+set}
  60
  61 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  62 AM_MAINTAINER_MODE([enable])
  63
  64 # Support silent build rules, requires at least automake-1.11. Disable
  65 # by either passing --disable-silent-rules to configure or passing V=1
  66 # to make
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69 #
  70 # For each of the libraries we build, we define the following
  71 # substituted variables:
  72 #
  73 # foo_PACKAGES:     pkg-config packages this library requires
  74 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  75 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  76 # foo_DEP_LIBS:     All libraries this module requires
  77 # foo_DEP_CFLAGS:   All cflags this module requires
  78
  79
  80 GTK_MAJOR_VERSION=gtk_major_version
  81 GTK_MINOR_VERSION=gtk_minor_version
  82 GTK_MICRO_VERSION=gtk_micro_version
  83 GTK_INTERFACE_AGE=gtk_interface_age
  84 GTK_BINARY_AGE=gtk_binary_age
  85 GTK_VERSION=gtk_version
  86 GTK_API_VERSION=gtk_api_version
  87 GTK_BINARY_VERSION=gtk_binary_version
  88 AC_SUBST(GTK_MAJOR_VERSION)
  89 AC_SUBST(GTK_MINOR_VERSION)
  90 AC_SUBST(GTK_MICRO_VERSION)
  91 AC_SUBST(GTK_INTERFACE_AGE)
  92 AC_SUBST(GTK_BINARY_AGE)
  93 AC_SUBST(GTK_API_VERSION)
  94 AC_SUBST(GTK_VERSION)
  95 AC_SUBST(GTK_BINARY_VERSION)
  96
  97 # libtool versioning
  98 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  99 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 100 #LT_REVISION=$GTK_INTERFACE_AGE
 101 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 102 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 103
 104 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 105 m4_define([lt_revision], [gtk_interface_age])
 106 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 107 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 108 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 109 AC_SUBST(LT_VERSION_INFO)
 110 AC_SUBST(LT_CURRENT_MINUS_AGE)
 111
 112 m4_define([gail_lt_current],[0])
 113 m4_define([gail_lt_revision],[0])
 114 m4_define([gail_lt_age],[0])
 115 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 116 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 117 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 118 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 119
 120 # Checks for programs.
 121 AC_PROG_CC
 122 AC_PROG_CC_C_O
 123 AC_PROG_CC_STDC
 124 AC_PROG_INSTALL
 125 AC_PROG_MAKE_SET
 126
 127
 128 GETTEXT_PACKAGE=gtk30
 129 AC_SUBST(GETTEXT_PACKAGE)
 130 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 131                    [The prefix for our gettext translation domains.])
 132
 133 AC_CANONICAL_HOST
 134
 135 MATH_LIB=-lm
 136 AC_MSG_CHECKING([for native Win32])
 137 LIB_EXE_MACHINE_FLAG=X86
 138 EXE_MANIFEST_ARCHITECTURE=X86
 139 case "$host" in
 140   *-*-mingw*)
 141     os_win32=yes
 142     gio_can_sniff=no
 143     MATH_LIB=
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       EXE_MANIFEST_ARCHITECTURE=AMD64
 148       ;;
 149     esac
 150     ;;
 151   *)
 152     os_win32=no
 153     ;;
 154 esac
 155 AC_MSG_RESULT([$os_win32])
 156
 157 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 158 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 159
 160 case $host in
 161   *-*-linux*)
 162     os_linux=yes
 163     ;;
 164 esac
 165
 166 dnl
 167 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 168 dnl We use this for an automated test for C++ header correctness.
 169 dnl
 170 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 171 AC_LANG_PUSH([C++])
 172
 173 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 174 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 175
 176 gtk_save_cxxflags="$CXXFLAGS"
 177 CXXFLAGS="$CXXFLAGS -x objective-c++"
 178 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 179 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 180 CXXFLAGS="$gtk_save_cxxflags"
 181 AC_LANG_POP([C++])
 182
 183 if test "$os_win32" = "yes"; then
 184   if test x$enable_static = xyes -o x$enable_static = x; then
 185     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 186     enable_static=no
 187   fi
 188   if test x$enable_shared = xno; then
 189     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 190   fi
 191   enable_shared=yes
 192 fi
 193
 194 dnl Initialize libtool
 195 LT_PREREQ([2.2.6])
 196 LT_INIT([disable-static win32-dll])
 197 # Create libtool early, because it's used in configure
 198 LT_OUTPUT
 199
 200 # Make sure we use 64-bit versions of various file stuff.
 201 AC_SYS_LARGEFILE
 202
 203 AM_PROG_AS
 204 AC_PATH_PROG(NM, nm, nm)
 205
 206 AC_MSG_CHECKING([for some Win32 platform])
 207 case "$host" in
 208   *-*-mingw*|*-*-cygwin*)
 209     platform_win32=yes
 210     ;;
 211   *)
 212     platform_win32=no
 213     ;;
 214 esac
 215 AC_MSG_RESULT([$platform_win32])
 216 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 217
 218 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 219 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 220 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 221
 222 if test "$os_win32" = "yes"; then
 223   AC_CHECK_TOOL(WINDRES, windres, no)
 224   if test "$WINDRES" = no; then
 225     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 226   fi
 227   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 228 fi
 229 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 230
 231 m4_define([debug_default],
 232           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 233
 234 dnl declare --enable-* args and collect ac_help strings
 235 AC_ARG_ENABLE(debug,
 236               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 237                              [turn on debugging @<:@default=debug_default@:>@]),,
 238               enable_debug=debug_default)
 239
 240 AC_ARG_ENABLE(rebuilds,
 241               [AC_HELP_STRING([--disable-rebuilds],
 242                               [disable all source autogeneration rules])],,
 243               [enable_rebuilds=yes])
 244
 245 AC_ARG_ENABLE(xkb,
 246               [AC_HELP_STRING([--enable-xkb],
 247                               [support XKB extension [default=maybe]])],,
 248               [enable_xkb="maybe"])
 249 AC_ARG_ENABLE(xinerama,
 250               [AC_HELP_STRING([--enable-xinerama],
 251                               [support Xinerama extension if available [default=maybe]])],,
 252               [enable_xinerama="maybe"])
 253 AC_ARG_ENABLE(xinput,
 254               [AC_HELP_STRING([--enable-xinput],
 255                               [support XInput extension if available [default=yes]])],,
 256               [enable_xinput="maybe"])
 257 AC_ARG_ENABLE(xrandr,
 258               [AC_HELP_STRING([--enable-xrandr],
 259                               [support XRandR extension if available [default=maybe]])],,
 260               [enable_xrandr="maybe"])
 261 AC_ARG_ENABLE(xfixes,
 262               [AC_HELP_STRING([--enable-xfixes],
 263                               [support XFixes extension if available [default=maybe]])],,
 264               [enable_xfixes="maybe"])
 265 AC_ARG_ENABLE(xcomposite,
 266               [AC_HELP_STRING([--enable-xcomposite],
 267                               [support X Composite extension if available [default=maybe]])],,
 268               [enable_xcomposite="maybe"])
 269 AC_ARG_ENABLE(xdamage,
 270               [AC_HELP_STRING([--enable-xdamage],
 271                               [support X Damage extension if available [default=maybe]])],,
 272               [enable_xdamage="maybe"])
 273
 274 AC_ARG_ENABLE(x11-backend,
 275               [AC_HELP_STRING([--enable-x11-backend],
 276                               [enable the X11 gdk backend])],
 277                               [backend_set=yes])
 278 AC_ARG_ENABLE(win32-backend,
 279               [AC_HELP_STRING([--enable-win32-backend],
 280                               [enable the Win32 gdk backend])],
 281                               [backend_set=yes])
 282 AC_ARG_ENABLE(quartz-backend,
 283               [AC_HELP_STRING([--enable-quartz-backend],
 284                               [enable the quartz gdk backend])],
 285                               [backend_set=yes])
 286
 287 if test -z "$backend_set"; then
 288   if test "$platform_win32" = yes; then
 289     enable_win32_backend=yes
 290   else
 291     enable_x11_backend=yes
 292   fi
 293 fi
 294
 295 cairo_backends=
 296 backend_immodules=
 297 GDK_BACKENDS=
 298 GDK_EXTRA_LIBS=
 299 GDK_EXTRA_CFLAGS=
 300 GDK_WINDOWING=
 301 GIO_PACKAGE=gio-2.0
 302 PANGO_PACKAGES="pango pangocairo"
 303
 304 if test "x$enable_x11_backend" == xyes; then
 305   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 306   # backend names are identical.
 307   cairo_backends="$cairo_backends cairo-xlib"
 308   GDK_BACKENDS="$GDK_BACKENDS x11"
 309   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 310   # gdkapplaunchcontext-x11.c
 311   GIO_PACKAGE=gio-unix-2.0
 312   backend_immodules="$backend_immodules,xim"
 313   GDK_WINDOWING="$GDK_WINDOWING
 314 #define GDK_WINDOWING_X11"
 315 fi
 316
 317 if test "x$enable_win32_backend" == xyes; then
 318   cairo_backends="$cairo_backends cairo-win32"
 319   GDK_BACKENDS="$GDK_BACKENDS win32"
 320   backend_immodules="$backend_immodules,ime"
 321   GDK_WINDOWING="$GDK_WINDOWING
 322 #define GDK_NATIVE_WINDOW_POINTER
 323 #define GDK_WINDOWING_WIN32"
 324   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 325   AM_CONDITIONAL(USE_WIN32, true)
 326   PANGO_PACKAGES="pangowin32 pangocairo"
 327 else
 328   AM_CONDITIONAL(USE_WIN32, false)
 329 fi
 330
 331 if test "x$enable_quartz_backend" == xyes; then
 332   cairo_backends="$cairo_backends cairo-quartz"
 333   GDK_BACKENDS="$GDK_BACKENDS quartz"
 334   GDK_WINDOWING="$GDK_WINDOWING
 335 #define GDK_WINDOWING_QUARTZ"
 336   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 337   AM_CONDITIONAL(USE_QUARTZ, true)
 338 else
 339   AM_CONDITIONAL(USE_QUARTZ, false)
 340 fi
 341
 342 # strip leading space
 343 GDK_BACKENDS=${GDK_BACKENDS/# }
 344
 345 AC_SUBST(GDK_BACKENDS)
 346
 347 if test -z "$GDK_BACKENDS"; then
 348   AC_MSG_ERROR([No GDK backends selected.])
 349 fi
 350
 351 if test "x$enable_debug" = "xyes"; then
 352   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 353   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 354 else
 355   if test "x$enable_debug" = "xno"; then
 356     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 357   else
 358     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 359   fi
 360 fi
 361
 362
 363 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 364                    [Define if debugging is enabled])
 365
 366
 367 # Build time sanity check...
 368 AM_SANITY_CHECK
 369
 370 changequote(,)dnl
 371 if test "x$GCC" = "xyes"; then
 372   case " $CFLAGS " in
 373   *[\ \ ]-Wall[\ \      ]*) ;;
 374   *) CFLAGS="$CFLAGS -Wall" ;;
 375   esac
 376
 377   if test "x$enable_ansi" = "xyes"; then
 378     case " $CFLAGS " in
 379     *[\ \       ]-ansi[\ \      ]*) ;;
 380     *) CFLAGS="$CFLAGS -ansi" ;;
 381     esac
 382
 383     case " $CFLAGS " in
 384     *[\ \       ]-pedantic[\ \  ]*) ;;
 385     *) CFLAGS="$CFLAGS -pedantic" ;;
 386     esac
 387   fi
 388 fi
 389 changequote([,])dnl
 390
 391 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 392
 393 # Ensure MSVC-compatible struct packing convention is used when
 394 # compiling for Win32 with gcc.
 395 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 396 # gcc2 uses "-fnative-struct".
 397 if test x"$os_win32" = xyes; then
 398   if test x"$GCC" = xyes; then
 399     msnative_struct=''
 400     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 401     if test -z "$ac_cv_prog_CC"; then
 402       our_gcc="$CC"
 403     else
 404       our_gcc="$ac_cv_prog_CC"
 405     fi
 406     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 407       2.)
 408         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 409           msnative_struct='-fnative-struct'
 410         fi
 411         ;;
 412       *)
 413         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 414           msnative_struct='-mms-bitfields'
 415         fi
 416         ;;
 417     esac
 418     if test x"$msnative_struct" = x ; then
 419       AC_MSG_RESULT([no way])
 420       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 421     else
 422       CFLAGS="$CFLAGS $msnative_struct"
 423       AC_MSG_RESULT([${msnative_struct}])
 424     fi
 425   fi
 426 fi
 427
 428 ## Initial sanity check, done here so that users get told they
 429 ## have the wrong dependencies as early in the process as possible.
 430 ## Later on we actually use the cflags/libs from separate pkg-config
 431 ## calls. Oh, also the later pkg-config calls don't include
 432 ## the version requirements since those make the module lists
 433 ## annoying to construct
 434 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 435   [glib-2.0 >= glib_required_version dnl
 436    atk >= atk_required_version dnl
 437    pango >= pango_required_version dnl
 438    cairo >= cairo_required_version dnl
 439    cairo-gobject >= cairo_required_version dnl
 440    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 441
 442 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 443
 444 if test "$os_win32" != yes; then
 445     # libtool option to control which symbols are exported
 446     # right now, symbols starting with _ are not exported
 447     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 448 else
 449     # We currently use .def files on Windows (for gdk and gtk)
 450     LIBTOOL_EXPORT_OPTIONS=
 451 fi
 452 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 453
 454 dnl ******************************************************
 455 dnl * See whether to include shared library dependencies *
 456 dnl ******************************************************
 457
 458 AC_ARG_ENABLE(explicit-deps,
 459               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 460                               [use explicit dependencies in .pc files [default=auto]])],,
 461               [enable_explicit_deps=auto])
 462
 463 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 464 case $enable_explicit_deps in
 465   auto)
 466     export SED
 467     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 468     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 469       enable_explicit_deps=yes
 470     else
 471       enable_explicit_deps=no
 472     fi
 473   ;;
 474   yes|no)
 475   ;;
 476   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 477   ;;
 478 esac
 479 AC_MSG_RESULT($enable_explicit_deps)
 480
 481 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 482
 483 # define a MAINT-like variable REBUILD which is set if Perl
 484 # and awk are found, so autogenerated sources can be rebuilt
 485
 486 AC_PATH_PROGS(PERL, perl5 perl)
 487
 488 # We would like indent, but don't require it.
 489 AC_CHECK_PROG(INDENT, indent, indent)
 490
 491 REBUILD=\#
 492 if test "x$enable_rebuilds" = "xyes" && \
 493      test -n "$PERL" && \
 494      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 495   REBUILD=
 496 fi
 497 AC_SUBST(REBUILD)
 498
 499 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 500 AC_CHECK_FUNCS(localtime_r)
 501
 502 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 503 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 504 AC_TRY_LINK([#include <langinfo.h>], [
 505 char c;
 506 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 507 ], gtk_ok=yes, gtk_ok=no)
 508 AC_MSG_RESULT($gtk_ok)
 509 if test "$gtk_ok" = "yes"; then
 510   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 511             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 512 fi
 513
 514 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 515 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 516 AC_TRY_LINK([#include <langinfo.h>], [
 517 char c;
 518 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 519 ], gtk_ok=yes, gtk_ok=no)
 520 AC_MSG_RESULT($gtk_ok)
 521 if test "$gtk_ok" = "yes"; then
 522   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 523             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 524 fi
 525
 526 # _NL_PAPER_HEIGHT is an enum and not a define
 527 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 528 AC_TRY_LINK([#include <langinfo.h>], [
 529 char c;
 530 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 531 ], gtk_ok=yes, gtk_ok=no)
 532 AC_MSG_RESULT($gtk_ok)
 533 if test "$gtk_ok" = "yes"; then
 534   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 535             [Define if _NL_PAPER_HEIGHT is available])
 536 fi
 537
 538 # _NL_PAPER_WIDTH is an enum and not a define
 539 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 540 AC_TRY_LINK([#include <langinfo.h>], [
 541 char c;
 542 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 543 ], gtk_ok=yes, gtk_ok=no)
 544 AC_MSG_RESULT($gtk_ok)
 545 if test "$gtk_ok" = "yes"; then
 546   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 547             [Define if _NL_PAPER_WIDTH is available])
 548 fi
 549
 550 # i18n stuff
 551 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 552 AM_GLIB_GNU_GETTEXT
 553 LIBS="$LIBS $INTLLIBS"
 554 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 555         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 556       esac])
 557
 558 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 559 dnl po-properties/POTFILES during configure; see GNOME #573515.
 560 dnl
 561 dnl Generate list of files to be processed by xgettext which will
 562 dnl be included in po-properties/Makefile.
 563 test -d po-properties || mkdir po-properties
 564 if test "x$srcdir" != "x."; then
 565   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 566     popropsrcprefix="$srcdir/"
 567   else
 568     popropsrcprefix="../$srcdir/"
 569   fi
 570 else
 571   popropsrcprefix="../"
 572 fi
 573 rm -f po-properties/POTFILES
 574 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 575 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 576 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 577
 578 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 579
 580 dnl The DU4 header files don't provide library prototypes unless
 581 dnl -std1 is given to the native cc.
 582 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 583
 584 gtk_save_LIBS=$LIBS
 585 LIBS="$LIBS -lm"
 586 AC_TRY_RUN([#include <math.h>
 587              int main (void) { return (log(1) != log(1.)); }],
 588      AC_MSG_RESULT(none needed),
 589      gtk_save_CFLAGS="$CFLAGS"
 590      CFLAGS="$CFLAGS -std1"
 591      AC_TRY_RUN([#include <math.h>
 592                  int main (void) { return (log(1) != log(1.)); }],
 593          AC_MSG_RESULT(-std1),
 594          AC_MSG_RESULT()
 595          CFLAGS="$gtk_save_CFLAGS"
 596          AC_MSG_WARN(
 597                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 598          true
 599      ),
 600      AC_MSG_RESULT(none needed)
 601 )
 602 LIBS=$gtk_save_LIBS
 603
 604 AC_MSG_CHECKING(for the BeOS)
 605 case $host in
 606   *-*-beos*)
 607     AC_MSG_RESULT(yes)
 608     MATH_LIB=
 609   ;;
 610   *)
 611     AC_MSG_RESULT(no)
 612   ;;
 613 esac
 614
 615 AC_SUBST(MATH_LIB)
 616 #
 617 # see bug 162979
 618 #
 619 AC_MSG_CHECKING(for HP-UX)
 620 case $host_os in
 621   hpux9* | hpux10* | hpux11*)
 622     AC_MSG_RESULT(yes)
 623     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 624   ;;
 625   *)
 626     AC_MSG_RESULT(no)
 627   ;;
 628 esac
 629
 630 dnl NeXTStep cc seems to need this
 631 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 632 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 633   AC_MSG_RESULT(none needed),
 634   gtk_save_CFLAGS="$CFLAGS"
 635   CFLAGS="$CFLAGS -posix"
 636   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 637     AC_MSG_RESULT(-posix),
 638     AC_MSG_RESULT()
 639     CFLAGS="$gtk_save_CFLAGS"
 640     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 641
 642 #
 643 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 644 #
 645
 646 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 647
 648 AM_PATH_GLIB_2_0(glib_required_version, :,
 649   AC_MSG_ERROR([
 650 *** GLIB glib_required_version or better is required. The latest version of
 651 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 652   gobject gmodule-no-export gthread)
 653
 654 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 655 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 656 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 657 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 658   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 659 fi
 660
 661 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 662
 663
 664 dnl
 665 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 666 dnl
 667 gtk_save_LIBS=$LIBS
 668 LIBS="$LIBS $GLIB_LIBS"
 669 AC_CHECK_FUNCS(bind_textdomain_codeset)
 670 LIBS=$gtk_save_LIBS
 671
 672 AC_CHECK_HEADERS(pwd.h,
 673                  AC_DEFINE(HAVE_PWD_H, 1,
 674                            [Define to 1 if pwd.h is available]))
 675 AC_CHECK_HEADERS(sys/time.h,
 676                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 677                            [Define to 1 if time.h is available]))
 678 AC_CHECK_HEADERS(unistd.h,
 679                  AC_DEFINE(HAVE_UNISTD_H, 1,
 680                            [Define to 1 if unistd.h is available]))
 681 AC_CHECK_HEADERS(ftw.h,
 682                  AC_DEFINE(HAVE_FTW_H, 1,
 683                            [Define to 1 if ftw.h is available]))
 684
 685 AC_MSG_CHECKING([for GNU ftw extensions])
 686 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 687 #define _GNU_SOURCE
 688 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 689 if test $gtk_ok = yes; then
 690     AC_MSG_RESULT([yes])
 691     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 692 else
 693     AC_MSG_RESULT([no])
 694 fi
 695
 696 saved_cflags="$CFLAGS"
 697 saved_ldflags="$LDFLAGS"
 698
 699
 700 # Checks for header files.
 701 AC_HEADER_STDC
 702
 703 # Checks for typedefs, structures, and compiler characteristics.
 704 AC_C_CONST
 705
 706 # Checks for library functions.
 707 AC_TYPE_SIGNAL
 708 AC_FUNC_MMAP
 709
 710 AC_CHECK_FUNCS(mallinfo)
 711 AC_CHECK_FUNCS(getresuid)
 712 AC_TYPE_UID_T
 713
 714 # Check if <sys/select.h> needs to be included for fd_set
 715 AC_MSG_CHECKING([for fd_set])
 716 AC_TRY_COMPILE([#include <sys/types.h>],
 717         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 718 if test $gtk_ok = yes; then
 719     AC_MSG_RESULT([yes, found in sys/types.h])
 720 else
 721     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 722     if test $gtk_ok = yes; then
 723         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 724                   [Define to 1 if sys/select.h is available])
 725         AC_MSG_RESULT([yes, found in sys/select.h])
 726     else
 727         AC_DEFINE(NO_FD_SET, 1,
 728                   [Define to 1 if fd_set is not available])
 729         AC_MSG_RESULT(no)
 730     fi
 731 fi
 732
 733 # Check for uxtheme.h (for MS-Windows Engine)
 734 AC_MSG_CHECKING(for uxtheme.h)
 735 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 736 if test $gtk_uxtheme_h = yes; then
 737    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 738 fi
 739 AC_MSG_RESULT($gtk_uxtheme_h)
 740
 741 # Checks for gdkspawn
 742 AC_CHECK_HEADERS(crt_externs.h)
 743 AC_CHECK_FUNCS(_NSGetEnviron)
 744
 745 AC_MSG_CHECKING(whether to build dynamic modules)
 746
 747 AC_ARG_ENABLE(modules,
 748               [AC_HELP_STRING([--disable-modules],
 749                               [disable dynamic module loading])])
 750
 751 dynworks=false
 752 build_dynamic_modules=no
 753 deps=
 754 if test x$enable_modules = xno; then
 755     AC_MSG_RESULT(no)
 756 else
 757     AC_MSG_RESULT(yes)
 758     AC_MSG_CHECKING(whether dynamic modules work)
 759     ## for loop is to strip newline
 760     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 761     for I in $tmp; do
 762         dynworks=$I
 763     done
 764
 765     dnl Now we check to see if our libtool supports shared lib deps
 766     dnl (in a rather ugly way even)
 767     if $dynworks; then
 768         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 769         module_deplibs_check=`$module_libtool_config | \
 770             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 771             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 772         if test "x$module_deplibs_check" = "xnone" || \
 773            test "x$module_deplibs_check" = "xunknown" || \
 774            test "x$module_deplibs_check" = "x"; then
 775             dynworks=false
 776         fi
 777     fi
 778
 779     if $dynworks; then
 780         build_dynamic_modules=yes
 781         AC_DEFINE(USE_GMODULE, 1,
 782                   [Define to 1 if gmodule works and should be used])
 783         AC_MSG_RESULT(yes)
 784     else
 785         build_dynamic_modules=no
 786         AC_MSG_RESULT(no)
 787     fi
 788 fi
 789
 790 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 791
 792 #
 793 # Allow building some or all immodules included
 794 #
 795 AC_MSG_CHECKING(immodules to build)
 796
 797 dnl due to an autoconf bug, commas in the first arg to
 798 dnl AC_HELP_STRING cause problems.
 799 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
 800 dnl                [build the specified input method modules into gtk])
 801 AC_ARG_WITH(included_immodules,
 802             AC_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 803                            [build the specified input methods into gtk]))
 804
 805 if $dynworks; then
 806    :
 807 else
 808    ## if the option was specified, leave it; otherwise disable included immodules
 809    if test x$with_included_immodules = xno; then
 810            with_included_immodules=yes
 811    fi
 812 fi
 813
 814 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 815
 816 included_immodules=""
 817 # If the switch specified without listing any specific ones, include all
 818 if test "x$with_included_immodules" = xyes ; then
 819   included_immodules="$all_immodules"
 820 else
 821   included_immodules="$with_included_immodules"
 822 fi
 823
 824 AC_MSG_RESULT($included_immodules)
 825 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 826
 827 INCLUDED_IMMODULE_OBJ=
 828 INCLUDED_IMMODULE_DEFINE=
 829
 830 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 831 for immodule in $included_immodules; do
 832  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 833  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 834    :
 835  else
 836    AC_MSG_ERROR([the specified input method $immodule does not exist])
 837  fi
 838
 839  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 840  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 841  eval INCLUDE_$immodule_underscores=yes
 842 done
 843 IFS="$gtk_save_ifs"
 844 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 845 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 846
 847 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 848 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 849 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 850 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 851 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 852 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 853 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 854 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 855 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 856 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 857 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 858 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 859
 860 AC_HEADER_SYS_WAIT
 861
 862 AC_TYPE_SIGNAL
 863
 864 # Checks to see whether we should include mediaLib
 865 # support.
 866 #
 867 AC_CHECK_HEADER(sys/systeminfo.h,
 868                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 869                           [Define to 1 if sys/systeminfo.h is available]))
 870 AC_CHECK_HEADER(sys/sysinfo.h,
 871                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 872                           [Define to 1 if sys/sysinfo.h is available]))
 873
 874 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 875
 876 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 877
 878 if test $cross_compiling = yes; then
 879   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 880   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 881     REBUILD_PNGS=#
 882   fi
 883 fi
 884
 885 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 886
 887 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 888    test "x$REBUILD_PNGS" = "x#" ; then
 889      AC_MSG_ERROR([
 890 *** gtkbuiltincache.h is not in the tree, and cannot be built
 891 *** because you don't have libpng, or (when cross-compiling) you
 892 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 893 fi
 894
 895 ########################################
 896 # Windowing system checks
 897 ########################################
 898
 899 # GTK+ uses some X calls, so needs to link against X directly
 900 GTK_DEP_PACKAGES_FOR_X=
 901 GTK_DEP_LIBS_FOR_X=
 902 X_EXTENSIONS=
 903
 904 if test "x$enable_x11_backend" == xyes; then
 905   X_PACKAGES=fontconfig
 906
 907   #
 908   # We use fontconfig very peripherally when decoding the default
 909   # settings.
 910   #
 911   if $PKG_CONFIG --exists fontconfig; then : ; else
 912     AC_MSG_ERROR([
 913 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 914   fi
 915
 916   #
 917   # Check for basic X packages; we use pkg-config if available
 918   #
 919   if $PKG_CONFIG --exists x11 xext; then
 920     have_base_x_pc=true
 921     X_PACKAGES="$X_PACKAGES x11 xext"
 922     x_libs="`$PKG_CONFIG --libs x11 xext`"
 923     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 924
 925     # Strip out any .la files that pkg-config might give us (this happens
 926     # with -uninstalled.pc files)
 927     x_libs_for_checks=
 928     for I in $x_libs ; do
 929       case $I in
 930         *.la) ;;
 931         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 932       esac
 933     done
 934
 935     GTK_PACKAGES_FOR_X="x11"
 936   else
 937     have_base_x_pc=false
 938     AC_PATH_XTRA
 939     if test x$no_x = xyes ; then
 940       AC_MSG_ERROR([X development libraries not found])
 941     fi
 942
 943     x_cflags="$X_CFLAGS"
 944     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 945
 946     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 947   fi
 948
 949   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 950   x_extra_libs=
 951
 952   gtk_save_cppflags="$CPPFLAGS"
 953   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 954
 955   gtk_save_LIBS=$LIBS
 956   LIBS="$x_libs_for_checks $LIBS"
 957
 958   # Sanity check for the X11 and Xext libraries. While everything we need from
 959   # Xext is optional, the chances a system has *none* of these things is so
 960   # small that we just unconditionally require it.
 961   AC_CHECK_FUNC(XOpenDisplay, :,
 962                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 963   AC_CHECK_FUNC(XextFindDisplay, :,
 964                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 965
 966   # Check for xReply
 967
 968   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 969   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
 970       [xReply *rep;],
 971       [AC_MSG_RESULT([no])],
 972       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
 973 #include <X11/Xlibint.h>],
 974            [xReply *rep;],
 975            [AC_MSG_RESULT([yes])
 976             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
 977                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
 978            [AC_MSG_RESULT([unknown])
 979             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 980
 981   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 982
 983   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 984
 985   # Generic X11R6 check needed for XIM support; we could
 986   # probably use this to replace the above, but we'll
 987   # leave the separate checks for XConvertCase and XInternAtoms
 988   # for clarity
 989
 990   have_x11r6=false
 991   AC_CHECK_FUNC(XAddConnectionWatch,
 992       have_x11r6=true)
 993
 994   if $have_x11r6; then
 995     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
 996   fi
 997   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
 998
 999   # Check for XKB support.
1000
1001   if test "x$enable_xkb" = "xyes"; then
1002         AC_CHECK_FUNC(XkbQueryExtension,
1003                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1004                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1005                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1006   elif test "x$enable_xkb" = "xmaybe"; then
1007         AC_CHECK_FUNC(XkbQueryExtension,
1008                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1009                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1010   else
1011         AC_MSG_WARN(XKB support explicitly disabled)
1012   fi
1013
1014   # Check for shaped window extension
1015
1016   AC_CHECK_FUNC(XShapeCombineMask, :,
1017      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1018
1019   # X SYNC check
1020   gtk_save_CFLAGS="$CFLAGS"
1021   CFLAGS="$CFLAGS $x_cflags"
1022
1023   AC_CHECK_FUNC(XSyncQueryExtension,
1024       [AC_CHECK_HEADER(X11/extensions/sync.h,
1025           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1026           :, [#include <X11/Xlib.h>])])
1027
1028   CFLAGS="$gtk_save_CFLAGS"
1029
1030   if test "x$enable_xinerama" != "xno"; then
1031     # Check for Xinerama extension (Solaris impl or Xfree impl)
1032     have_xfree_xinerama=false
1033     have_solaris_xinerama=false
1034
1035     gtk_save_cppflags="$CPPFLAGS"
1036     CPPFLAGS="$CPPFLAGS $x_cflags"
1037
1038     # Check for XFree
1039     AC_MSG_CHECKING(for Xinerama packages)
1040
1041     if $PKG_CONFIG --exists xinerama ; then
1042        AC_MSG_RESULT(yes)
1043        have_xfree_xinerama=true
1044        X_PACKAGES="$X_PACKAGES xinerama"
1045     else
1046        AC_MSG_RESULT(no)
1047        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1048            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1049            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1050            have_xfree_xinerama=true], :,
1051            [#include <X11/Xlib.h>])])
1052     fi
1053
1054     if $have_xfree_xinerama ; then
1055       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1056       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1057                 [Define to 1 if XFree Xinerama is available])
1058       AC_DEFINE(HAVE_XINERAMA, 1,
1059                 [Define to 1 is Xinerama is available])
1060     else
1061       case "$host" in
1062         *-*-solaris*)
1063             # Check for solaris
1064             AC_MSG_CHECKING(for Xinerama support on Solaris)
1065
1066             have_solaris_xinerama=false
1067             AC_CHECK_FUNC(XineramaGetInfo,
1068                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1069                     [have_solaris_xinerama=true], :,
1070                     [#include <X11/Xlib.h>])])
1071
1072             if $have_solaris_xinerama ; then
1073               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1074               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1075                         [Define to 1 if solaris xinerama is available])
1076               AC_DEFINE(HAVE_XINERAMA, 1,
1077                         [Define to 1 if xinerama is available])
1078               AC_MSG_RESULT(yes)
1079             else
1080               AC_MSG_RESULT(no)
1081             fi
1082             ;;
1083         *)
1084             ;;
1085       esac
1086     fi
1087   fi
1088   if test "x$enable_xinerama" = "xyes" ; then
1089     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1090       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1091     fi
1092   fi
1093
1094   # set up things for XInput
1095   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1096     have_xinput=yes
1097
1098     AC_DEFINE(XINPUT_XFREE, 1,
1099               [Define to 1 if XFree XInput should be used])
1100
1101     X_PACKAGES="$X_PACKAGES xi"
1102
1103     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1104                     have_xinput2=yes
1105                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1106                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]),
1107                     X_EXTENSIONS="$X_EXTENSIONS XInput")
1108
1109   else
1110     AC_DEFINE(XINPUT_NONE, 1,
1111               [Define to 1 if no XInput should be used])
1112   fi
1113
1114   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1115   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1116
1117   if test "x$enable_xinput" = "xyes" ; then
1118     if test "x$have_xinput" != "xyes" -a "x$have_xinput2" != "xyes" ; then
1119       AC_MSG_ERROR([*** XInput extension not found. Check 'config.log' for more details.])
1120     fi
1121   fi
1122
1123   # Check for the RANDR extension
1124   if test x"$enable_xrandr" != xno; then
1125     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1126       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1127
1128       X_PACKAGES="$X_PACKAGES xrandr"
1129       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1130     elif test x"$enable_xrandr" = xyes; then
1131       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1132     fi
1133   fi
1134
1135   # Checks for Xcursor library
1136
1137   if $PKG_CONFIG --exists xcursor ; then
1138     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1139
1140     X_PACKAGES="$X_PACKAGES xcursor"
1141   fi
1142
1143   # Checks for XFixes extension
1144
1145   if test x"$enable_xfixes" != xno; then
1146     if $PKG_CONFIG --exists xfixes ; then
1147       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1148
1149       X_PACKAGES="$X_PACKAGES xfixes"
1150       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1151       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1152     elif test x"$enable_xfixes" = xyes; then
1153       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1154     fi
1155   fi
1156
1157   # Checks for Xcomposite extension
1158
1159   if test x"$enable_xcomposite" != xno; then
1160     if $PKG_CONFIG --exists xcomposite ; then
1161       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1162
1163       X_PACKAGES="$X_PACKAGES xcomposite"
1164       X_EXTENSIONS="$X_EXTENSIONS Composite"
1165       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1166     elif test x"$enable_xcomposite" = xyes; then
1167       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1168     fi
1169   fi
1170
1171   # Checks for Xdamage extension
1172
1173   if test x"$enable_xdamage" != xno; then
1174     if $PKG_CONFIG --exists xdamage ; then
1175       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1176
1177       X_PACKAGES="$X_PACKAGES xdamage"
1178       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1179       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1180     elif test x"$enable_xdamage" = xyes; then
1181       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1182     fi
1183   fi
1184
1185   if $have_base_x_pc ; then
1186     GDK_EXTRA_LIBS="$x_extra_libs"
1187   else
1188     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1189   fi
1190
1191   CPPFLAGS="$gtk_save_cppflags"
1192   LIBS="$gtk_save_libs"
1193
1194   AM_CONDITIONAL(USE_X11, true)
1195
1196   # strip leading space
1197   X_EXTENSIONS=${X_EXTENSIONS/# }
1198
1199 else
1200   XPACKAGES=
1201
1202   AM_CONDITIONAL(XINPUT_XFREE, false)
1203   AM_CONDITIONAL(XINPUT_2, false)
1204   AM_CONDITIONAL(USE_X11, false)
1205   AM_CONDITIONAL(HAVE_X11R6, false)
1206 fi
1207
1208 # Check for Pango flags
1209
1210 AC_MSG_CHECKING(Pango flags)
1211 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1212         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1213         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1214
1215         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1216 else
1217         AC_MSG_ERROR([
1218 *** Pango not found. Pango built with Cairo support is required
1219 *** to build GTK+. See http://www.pango.org for Pango information.
1220 ])
1221 fi
1222
1223 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1224
1225 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1226         :
1227 else
1228         gtk_save_LIBS="$LIBS"
1229         LIBS="$PANGO_LIBS $LIBS"
1230         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1231 *** Can't link to Pango. Pango is required to build
1232 *** GTK+. For more information see http://www.pango.org]))
1233         LIBS="$gtk_save_LIBS"
1234 fi
1235
1236 CFLAGS="$saved_cflags"
1237 LDFLAGS="$saved_ldflags"
1238
1239 GDK_PACKAGES="$PANGO_PACKAGES $GIO_PACKAGE $X_PACKAGES gdk-pixbuf-2.0 $cairo_backends cairo-gobject"
1240
1241 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1242 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1243 #
1244 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1245 # into the pkg-config files
1246 #
1247 if test $enable_explicit_deps != yes ; then
1248   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo-gobject"
1249   GDK_EXTRA_LIBS=
1250 fi
1251
1252 AC_SUBST(GDK_PACKAGES)
1253 AC_SUBST(GDK_EXTRA_LIBS)
1254 AC_SUBST(GDK_EXTRA_CFLAGS)
1255 AC_SUBST(GDK_DEP_LIBS)
1256 AC_SUBST(GDK_DEP_CFLAGS)
1257
1258
1259 ########################################
1260 # Check for Accessibility Toolkit flags
1261 ########################################
1262
1263 ATK_PACKAGES=atk
1264 AC_MSG_CHECKING(ATK flags)
1265 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1266         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1267         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1268
1269         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1270 else
1271         AC_MSG_ERROR([
1272 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1273 *** to build GTK+.
1274 ])
1275 fi
1276
1277 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1278         :
1279 else
1280         gtk_save_LIBS="$LIBS"
1281         LIBS="$ATK_LIBS $LIBS"
1282         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1283                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1284                 *** to build GTK+]))
1285         LIBS="$gtk_save_LIBS"
1286 fi
1287
1288 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1289 if test "x$enable_x11_backend" == xyes; then
1290   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1291 fi
1292 GTK_EXTRA_LIBS=
1293 GTK_EXTRA_CFLAGS=
1294 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1295 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1296
1297 if test x"$os_win32" = xyes; then
1298   GTK_EXTRA_CFLAGS="$msnative_struct"
1299 fi
1300
1301 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1302 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1303 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1304 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1305
1306 AC_SUBST(GTK_PACKAGES)
1307 AC_SUBST(GTK_EXTRA_LIBS)
1308 AC_SUBST(GTK_EXTRA_CFLAGS)
1309 AC_SUBST(GTK_DEP_LIBS)
1310 AC_SUBST(GTK_DEP_CFLAGS)
1311
1312 AC_SUBST(GLIB_PREFIX)
1313 AC_SUBST(ATK_PREFIX)
1314 AC_SUBST(PANGO_PREFIX)
1315 AC_SUBST(CAIRO_PREFIX)
1316
1317 AC_SUBST(GTK_DEBUG_FLAGS)
1318 AC_SUBST(GTK_XIM_FLAGS)
1319
1320 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1321 AC_SUBST(GDK_PIXBUF_LIBS)
1322
1323 ########################
1324 # Checks needed for gail
1325 ########################
1326
1327 old_LIBS="$LIBS"
1328 dnl Checks for inet libraries:
1329 AC_SEARCH_LIBS(gethostent, nsl)
1330 AC_SEARCH_LIBS(setsockopt, socket)
1331 AC_SEARCH_LIBS(connect, inet)
1332
1333 dnl check for the sockaddr_un.sun_len member
1334 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1335                 [struct_sockaddr_un_sun_len=true],
1336                 [struct_sockaddr_un_suin_len=false],
1337                 [#include <sys/types.h>
1338                  #include <sys/un.h>]
1339                 )
1340 case $struct_sockaddr_un_sun_len in
1341         true)
1342                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1343                                    [Have the sockaddr_un.sun_len member])
1344                 ;;
1345         *)
1346                 ;;
1347 esac
1348
1349 GAIL_INET_LIBS="$LIBS"
1350 AC_SUBST([GAIL_INET_LIBS])
1351
1352 LIBS="$old_LIBS"
1353
1354 ################################################################
1355 # Printing system checks
1356 ################################################################
1357
1358 PRINT_BACKENDS="file lpr"
1359
1360 AC_ARG_ENABLE(cups,
1361               [AC_HELP_STRING([--disable-cups],
1362                               [disable cups print backend])],,
1363               [enable_cups=auto])
1364
1365 if test "x$enable_cups" = "xno"; then
1366   AM_CONDITIONAL(HAVE_CUPS, false)
1367 else
1368   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1369   if test "x$CUPS_CONFIG" = "xno"; then
1370     if test "x$enable_cups" = "xauto"; then
1371       AM_CONDITIONAL(HAVE_CUPS, false)
1372     else
1373       AC_MSG_ERROR([
1374 *** cups not found.
1375 ])
1376     fi
1377   else
1378     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1379     CUPS_LIBS=`$CUPS_CONFIG --libs`
1380
1381     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1382     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1383     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1384
1385     if test $CUPS_API_MAJOR -gt 1 -o \
1386             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1387       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1388                 [Define to 1 if CUPS 1.2 API is available])
1389     fi
1390
1391     AC_SUBST(CUPS_API_MAJOR)
1392     AC_SUBST(CUPS_API_MINOR)
1393     AC_SUBST(CUPS_CFLAGS)
1394     AC_SUBST(CUPS_LIBS)
1395
1396     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1397
1398     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1399     AM_CONDITIONAL(HAVE_CUPS, true)
1400
1401     gtk_save_cflags="$CFLAGS"
1402     CFLAGS="$CUPS_CFLAGS"
1403     AC_TRY_COMPILE([#include <cups/http.h>],
1404                    [http_t http; char *s = http.authstring;],
1405                    [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1406                               [Define if cups http_t authstring field is accessible])],)
1407     CFLAGS="$gtk_save_cflags"
1408
1409     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1410
1411     gtk_save_libs="$LIBS"
1412     LIBS="$CUPS_LIBS"
1413     AC_CHECK_FUNCS(httpGetAuthString)
1414     LIBS="$gtk_save_libs"
1415   fi
1416 fi
1417
1418 # Checks to see if we should compile with PAPI backend for GTK+
1419 #
1420
1421 AC_ARG_ENABLE(papi,
1422               [AC_HELP_STRING([--disable-papi],
1423                               [disable papi print backend])],,
1424              [enable_papi=auto])
1425
1426 if test "x$enable_papi" = "xno"; then
1427   AM_CONDITIONAL(HAVE_PAPI, false)
1428 else
1429   AC_MSG_CHECKING(libpapi)
1430   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1431   if test $have_papi = yes; then
1432     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1433     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1434   fi
1435   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1436   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1437     AC_MSG_ERROR([
1438 *** papi not found.
1439 ])
1440   fi
1441 fi
1442
1443 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1444
1445 gtk_save_cppflags="$CPPFLAGS"
1446 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1447
1448 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1449 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1450 *** backend enabled.]))
1451
1452 if test "$os_win32" != "yes"; then
1453   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1454 *** Can't find cairo-ps.h. You must build Cairo with the
1455 *** postscript backend enabled.]))
1456
1457   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1458 *** Cannot find cairo-svg.h. You must build Cairo with the
1459 *** svg backend enabled.]))
1460 fi
1461
1462 CPPFLAGS="$gtk_save_cppflags"
1463
1464
1465 AC_ARG_ENABLE(test-print-backend,
1466               [AC_HELP_STRING([--enable-test-print-backend],
1467                               [build test print backend])],,
1468               [enable_test_print_backend=no])
1469 if test "x$enable_test_print_backend" != "xno" ; then
1470   PRINT_BACKENDS="$PRINT_BACKENDS test"
1471 fi
1472 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1473
1474
1475 ################################################################
1476 # Strip -export-dynamic from the link lines of various libraries
1477 ################################################################
1478
1479 #
1480 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1481 #  but this flag is only meaningful for executables. For libraries
1482 #  the effect is undefined; what it causes on Linux is that the
1483 #  export list from -export-symbols-regex is ignored and everything
1484 #  is exported
1485 #
1486 # We are using gmodule-no-export now, but I'm leaving the stripping
1487 # code in place for now, since pango and atk still require gmodule.
1488 export SED
1489 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1490 if test -n "$export_dynamic"; then
1491   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1492   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1493 fi
1494
1495 #############
1496 # GSettings #
1497 #############
1498
1499 GLIB_GSETTINGS
1500
1501 ##################################################
1502 # GObject introspection
1503 ##################################################
1504
1505 GOBJECT_INTROSPECTION_CHECK([0.9.3])
1506
1507 ##################################################
1508 # Packagekit module
1509 #################################################
1510
1511 AC_ARG_ENABLE(packagekit,
1512               AC_HELP_STRING([--disable-packagekit],
1513                              [build packagekit open-with module]))
1514
1515 build_packagekit=no
1516 if test "os_win32" != "yes"; then
1517         if test "x$enable_packagekit" != "xno"; then
1518                 build_packagekit=yes
1519                 AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1520         fi
1521 fi
1522
1523 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1524
1525 ##################################################
1526 # Checks for gtk-doc and docbook-tools
1527 ##################################################
1528
1529 GTK_DOC_CHECK([1.11])
1530
1531 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1532 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1533
1534 AC_ARG_ENABLE(man,
1535               [AC_HELP_STRING([--enable-man],
1536                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1537               enable_man=no)
1538
1539 if test "${enable_man}" != no; then
1540   dnl
1541   dnl Check for xsltproc
1542   dnl
1543   AC_PATH_PROG([XSLTPROC], [xsltproc])
1544   if test -z "$XSLTPROC"; then
1545     enable_man=no
1546   fi
1547
1548   dnl check for DocBook DTD and stylesheets in the local catalog.
1549   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1550      [DocBook XML DTD V4.1.2],,enable_man=no)
1551   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1552      [DocBook XSL Stylesheets],,enable_man=no)
1553 fi
1554
1555 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1556
1557
1558 ##################################################
1559 # Output commands
1560 ##################################################
1561
1562 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1563         outfile=gdkconfig.h-tmp
1564         cat > $outfile <<\_______EOF
1565 /* gdkconfig.h
1566  *
1567  * This is a generated file.  Please modify `configure.ac'
1568  */
1569
1570 #ifndef __GDKCONFIG_H__
1571 #define __GDKCONFIG_H__
1572
1573 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1574 #error "Only <gdk/gdk.h> can be included directly."
1575 #endif
1576
1577 #include <glib.h>
1578
1579 G_BEGIN_DECLS
1580
1581 _______EOF
1582
1583         cat >>$outfile <<_______EOF
1584 $gdk_windowing
1585 _______EOF
1586
1587         cat >>$outfile <<_______EOF
1588
1589 G_END_DECLS
1590
1591 #endif  /* __GDKCONFIG_H__ */
1592 _______EOF
1593
1594
1595         if cmp -s $outfile gdk/gdkconfig.h; then
1596           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1597           rm -f $outfile
1598         else
1599           mv $outfile gdk/gdkconfig.h
1600         fi
1601 ],[
1602 gdk_windowing='$GDK_WINDOWING'
1603 ])
1604
1605 dnl
1606 dnl Check for -Bsymbolic-functions linker flag used to avoid
1607 dnl intra-library PLT jumps, if available.
1608 dnl
1609 AC_ARG_ENABLE(Bsymbolic,
1610               [AC_HELP_STRING([--disable-Bsymbolic],
1611                               [avoid linking with -Bsymbolic])],,
1612               [SAVED_LDFLAGS="${LDFLAGS}"
1613                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1614                LDFLAGS=-Wl,-Bsymbolic-functions
1615                AC_TRY_LINK([], [int main (void) { return 0; }],
1616                            AC_MSG_RESULT(yes)
1617                            enable_Bsymbolic=yes,
1618                            AC_MSG_RESULT(no)
1619                            enable_Bsymbolic=no)
1620                LDFLAGS="${SAVED_LDFLAGS}"])
1621
1622 if test "x${enable_Bsymbolic}" = "xyes" ; then
1623   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1624 fi
1625 AC_SUBST(GTK_LINK_FLAGS)
1626
1627 AC_CONFIG_FILES([
1628 config.h.win32
1629 gtk-zip.sh
1630 Makefile
1631 gdk-3.0.pc
1632 gtk+-3.0.pc
1633 gtk+-unix-print-3.0.pc
1634 gail-3.0.pc
1635 gtk+-3.0-uninstalled.pc
1636 gail-3.0-uninstalled.pc
1637 m4macros/Makefile
1638 po/Makefile.in
1639 po-properties/Makefile.in
1640 demos/Makefile
1641 demos/gtk-demo/Makefile
1642 demos/gtk-demo/geninclude.pl
1643 examples/Makefile
1644 tests/Makefile
1645 docs/Makefile
1646 docs/reference/Makefile
1647 docs/reference/gdk/Makefile
1648 docs/reference/gdk/version.xml
1649 docs/reference/gtk/Makefile
1650 docs/reference/gtk/version.xml
1651 docs/reference/libgail-util/Makefile
1652 docs/reference/libgail-util/version.xml
1653 docs/tools/Makefile
1654 build/Makefile
1655 build/win32/Makefile
1656 build/win32/vs9/Makefile
1657 gdk/Makefile
1658 gdk/x11/Makefile
1659 gdk/win32/Makefile
1660 gdk/win32/rc/Makefile
1661 gdk/win32/rc/gdk.rc
1662 gdk/quartz/Makefile
1663 gdk/tests/Makefile
1664 gtk/Makefile
1665 gtk/makefile.msc
1666 gtk/gtkversion.h
1667 gtk/gtk-win32.rc
1668 gtk/theme-bits/Makefile
1669 gtk/tests/Makefile
1670 modules/Makefile
1671 modules/other/Makefile
1672 modules/other/gail/Makefile
1673 modules/other/gail/libgail-util/Makefile
1674 modules/other/gail/tests/Makefile
1675 modules/engines/Makefile
1676 modules/engines/pixbuf/Makefile
1677 modules/engines/ms-windows/Makefile
1678 modules/engines/ms-windows/Theme/Makefile
1679 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1680 modules/input/Makefile
1681 modules/printbackends/Makefile
1682 modules/printbackends/cups/Makefile
1683 modules/printbackends/lpr/Makefile
1684 modules/printbackends/file/Makefile
1685 modules/printbackends/papi/Makefile
1686 modules/printbackends/test/Makefile
1687 perf/Makefile
1688 ])
1689
1690 AC_OUTPUT
1691
1692 # beautify the immodule list a bit
1693 included_immodules=${included_immodules//,/ }
1694 included_immodules=${included_immodules:-none}
1695
1696 echo "configuration:"
1697 echo "        GDK backends:         $GDK_BACKENDS"
1698 if test "x$enable_x11_backend" = "xyes"; then
1699 echo "        X11 extensions:       $X_EXTENSIONS"
1700 fi
1701 echo "        Print backends:       $PRINT_BACKENDS"
1702 echo "        Dynamic modules:      $build_dynamic_modules"
1703 echo "        Included immodules:   $included_immodules"
1704 echo "        PackageKit support:   $build_packagekit"
1705 echo "        Introspection:        $found_introspection"
1706 echo "        Debugging:            $enable_debug"
1707 echo "        Documentation:        $enable_gtk_doc"