Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 #
   3 # Fetchmail automatic configuration support
   4 #
   5 # Eric S. Raymond <esr@thyrsus.com>
   6 # 2004 - 2009 Matthias Andree <matthias.andree@gmx.de>
   7 #
   8 dnl Process this file with autoconf to produce a configure script.
   9 dnl
  10
  11 dnl XXX - if bumping version here, check fetchmail.man, too!
  12 AC_INIT([fetchmail],[6.3.11],[fetchmail-users@lists.berlios.de])
  13 AC_CONFIG_SRCDIR([fetchmail.h])
  14 AC_CONFIG_HEADERS([config.h])
  15 AC_CONFIG_LIBOBJ_DIR([.])
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl automake options are in Makefile.am
  20 AC_PREREQ(2.60)
  21 dnl 2.60 required for AC_USE_SYSTEM_EXTENSIONS
  22 AM_INIT_AUTOMAKE
  23
  24 dnl python is optional
  25 #
  26 # you can pass PYTHON=: in environment or on the command line
  27 # to disable python detection and continue without building/installing
  28 # fetchmail.conf -- be sure to check README.packaging, too!
  29 #
  30 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  31 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  32
  33 AC_PROG_AWK
  34 AC_PROG_CC
  35 AC_PROG_INSTALL
  36 AC_PROG_CPP                     dnl Later checks need this.
  37 AC_PROG_RANLIB
  38 AM_PROG_CC_C_O
  39 AC_USE_SYSTEM_EXTENSIONS
  40
  41 AC_ISC_POSIX
  42 dnl AC_ISC_POSIX: - XXX FIXME: remove in fetchmail 6.4.
  43 dnl This macro adds `-lcposix' to output variable `LIBS' if necessary
  44 dnl for Posix facilities.  Sun dropped support for the obsolete
  45 dnl INTERACTIVE Systems Corporation Unix on 2006-07-23.  New programs
  46 dnl need not use this macro.  It is implemented as
  47 dnl `AC_SEARCH_LIBS([strerror], [cposix])'
  48
  49 AC_HEADER_STDC
  50 AC_HEADER_TIME
  51 AC_TYPE_SIZE_T
  52 AC_TYPE_PID_T
  53 AC_TYPE_SIGNAL
  54 AC_CHECK_HEADERS([unistd.h termios.h termio.h sgtty.h stdarg.h \
  55         sys/itimer.h fcntl.h sys/fcntl.h memory.h sys/wait.h \
  56         arpa/inet.h arpa/nameser.h netinet/in.h net/socket.h netdb.h \
  57         sys/select.h sys/socket.h sys/time.h langinfo.h])
  58 if test _$ac_cv_header_stdarg_h != _yes ; then
  59 AC_MSG_WARN([stdarg.h is not defined. Unsupported configuration, proceed at your own risk.])
  60 fi
  61 AC_CHECK_TYPE(u_int32_t,,
  62         AC_DEFINE(u_int32_t,unsigned int,
  63                 [Define to unsigned int if <sys/types.h> does not define.]),
  64         [AC_INCLUDES_DEFAULT
  65 #ifdef HAVE_ARPA_NAMESER_H
  66 #include <arpa/nameser.h>
  67 #endif])
  68 AC_CHECK_HEADERS([resolv.h],,,[
  69 #include <sys/types.h>
  70 #ifdef HAVE_NETINET_IN_H
  71 #include <netinet/in.h>
  72 #endif
  73 #ifdef HAVE_ARPA_NAMESER_H
  74 #include <arpa/nameser.h>
  75 #endif
  76 ])
  77
  78 AC_C_CONST                      dnl getopt needs this.
  79
  80 AM_PROG_LEX
  81 AC_PROG_MAKE_SET
  82 AC_PROG_YACC
  83
  84 # Check for OS special cases
  85 case $host_os in
  86 darwin*)
  87     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
  88     CPPFLAGS="$CPPFLAGS -DBIND_8_COMPAT"
  89     ;;
  90 # Check for FreeBSD special case: more libs needed
  91 freebsd*)
  92     AC_MSG_NOTICE(found FreeBSD - Adding -lmd -lkvm -lcom_err to standard libraries)
  93     LIBS="$LIBS -lmd -lkvm -lcom_err"
  94     ;;
  95 # Check for LynxOS special case: -lbsd needed (at least on 2.3.0) and -s
  96 # not working.
  97 lynxos*)
  98     AC_MSG_NOTICE(found LynxOS - Adding -lbsd to standard libraries)
  99     LIBS="$LIBS -lbsd"
 100     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 101     AC_MSG_NOTICE(found LynxOS - Prepending standard include path to gcc flags)
 102     CPPFLAGS="$CPPFLAGS -I/usr/include"
 103     ;;
 104 # Check for Rhapsody special case: it doesn't like -s
 105 rhapsody*)
 106     AC_MSG_NOTICE(found Rhapsody - Removing -s load flag)
 107     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 108     ;;
 109 esac
 110
 111 AC_CACHE_SAVE
 112
 113 dnl i18n
 114 AM_GNU_GETTEXT([external], [need-ngettext])
 115 AM_GNU_GETTEXT_VERSION([0.14.6])
 116 dnl end i18n
 117
 118 # Under sysV68, socket and friends are provided by the C library.
 119 # -linet does not provide socket, but causes multiple definition
 120 # errors at link-time.  It is thus better to only use the C library.
 121 # So don't add -linet to the link list unless it's necessary
 122 AC_CHECK_FUNC(socket,
 123     AC_MSG_RESULT(using libc's socket),
 124     AC_CHECK_LIB(socket,socket)
 125     AC_CHECK_LIB(inet,socket))
 126
 127 # The condition in this test copes with the presence of inet_addr in libc6.
 128 AC_CHECK_FUNC(inet_addr,
 129     AC_MSG_RESULT(using libc's inet_addr),
 130     AC_CHECK_LIB(nsl,inet_addr))
 131
 132 dnl Port hack for Interactive UNIX System V/386 Release 3.2
 133 AC_CHECK_LIB(cposix, strchr,
 134                 [DEFS="$DEFS -D_SYSV3"
 135                 LIBS="$LIBS -lcposix"])
 136
 137 dnl Port hack for Sparc/NetBSD-1.5
 138 dnl
 139 dnl NB: this has been disabled as it causes the unconditional
 140 dnl addition of libintl to the build, which is both undesired
 141 dnl and breaks on Solaris/Blastwave.org machines.
 142 dnl
 143 dnl AC_CHECK_LIB(intl, gettext,
 144 dnl             [LIBS="$LIBS -lintl"])
 145
 146 AC_REPLACE_FUNCS([strstr strcasecmp memmove stpcpy strlcpy strlcat])
 147
 148 AC_CHECK_FUNC(MD5Init, [],
 149               [AC_LIBSOURCE(md5c.c)
 150                EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"])
 151
 152 AC_CHECK_FUNC(getopt_long, [],
 153               [AC_LIBSOURCES([getopt.c, getopt1.c])
 154                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 155
 156 AC_FUNC_VPRINTF
 157
 158 AC_SUBST(EXTRAOBJ)
 159
 160 AC_CHECK_FUNCS(tcsetattr stty setsid geteuid seteuid dnl
 161   strerror syslog snprintf vprintf vsnprintf vsyslog dnl
 162   atexit inet_aton strftime setrlimit socketpair dnl
 163   sigaction strdup setlocale)
 164
 165 AC_CHECK_DECLS(strerror)
 166 dnl INET6 is used by KAME/getnameinfo
 167 AC_CACHE_CHECK(for AF_INET6/PF_INET6,ac_cv_inet6,
 168 AC_COMPILE_IFELSE([
 169   AC_LANG_PROGRAM([[
 170     #ifdef HAVE_SYS_TYPES_H
 171     #include <sys/types.h>
 172     #endif
 173     #ifdef HAVE_SYS_SOCKET_H
 174     #include <sys/socket.h>
 175     #endif
 176   ]],[[
 177     int foo = AF_INET6;
 178     int bar = PF_INET6;
 179   ]])],
 180   ac_cv_inet6=yes , ac_cv_inet6=no
 181 ))
 182 if test "x$ac_cv_inet6" = xyes
 183 then
 184     AC_DEFINE(INET6,1,Define to 1 if your system defines AF_INET6 and PF_INET6.)
 185 fi
 186
 187 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 188 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 189 # library.  So don't add -lresolv to the link list unless it's necessary
 190 # (It will be necessary when using GNU libc6).
 191 old_LIBS="$LIBS"
 192 for lib in '' -lresolv; do
 193     if test -z "$lib"; then
 194        AC_MSG_CHECKING([for res_search in libc])
 195     else
 196        AC_MSG_CHECKING([for res_search in $lib])
 197     fi
 198     LIBS="$old_LIBS $lib"
 199     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 200 #include <sys/types.h>
 201 #ifdef HAVE_NETINET_IN_H
 202 #include <netinet/in.h>
 203 #endif
 204 #ifdef HAVE_ARPA_NAMESER_H
 205 #include <arpa/nameser.h>
 206 #endif
 207 #ifdef HAVE_RESOLV_H
 208 #include <resolv.h>
 209 #endif
 210 extern int res_search();
 211 ]], [[res_search(0, 0, 0, 0, 0); dn_skipname(0,0);]])],
 212     [AC_MSG_RESULT([found])
 213      AC_DEFINE(HAVE_RES_SEARCH, [1],
 214                [Define to 1 if you have the 'res_search' and 'dn_skipname' functions.])
 215      break], [AC_MSG_RESULT([not found])])
 216      LIBS=$old_LIBS
 217 done
 218
 219 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 220 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 221
 222 dnl Check for RSA refersence library in case we're using SSL
 223 AC_CHECK_LIB(rsaref, RSAPublicDecrypt)
 224
 225 dnl AC_FUNC_SETVBUF_REVERSED
 226
 227 dnl Check for usable void pointer type
 228 AC_MSG_CHECKING(use of void pointer type)
 229 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[char *p;
 230     void *xmalloc();
 231     p = (char *) xmalloc(1);
 232    ]])],[AC_DEFINE(HAVE_VOIDPOINTER,1,[Define if your C compiler allows void * as a function result]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 233
 234 dnl Check for ANSI volatile
 235 AC_C_VOLATILE
 236
 237 dnl Check out the wait reality.  We have to assume sys/wait.h is present.
 238 AC_CHECK_FUNCS(waitpid wait3)
 239 AC_MSG_CHECKING(for union wait);
 240 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 241 #include <sys/wait.h>]], [[union wait status; int pid; pid = wait (&status);
 242 #ifdef WEXITSTATUS
 243 /* Some POSIXoid systems have both the new-style macros and the old
 244    union wait type, and they do not work together.  If union wait
 245    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 246 if (WEXITSTATUS (status) != 0) pid = -1;
 247 #endif
 248 #ifdef HAVE_WAITPID
 249 /* Make sure union wait works with waitpid.  */
 250 pid = waitpid (-1, &status, 0);
 251 #endif
 252 ]])],[AC_DEFINE(HAVE_UNION_WAIT,1,Define if 'union wait' is the type of the first arg to wait functions.) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 253
 254 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 255 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 256 /* NetBSD declares sys_siglist in <unistd.h>.  */
 257 #ifdef HAVE_UNISTD_H
 258 #include <unistd.h>
 259 #endif]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 260
 261 # Find the right directory to put the root-mode PID file in
 262 for dir in "/var/run" "/etc"
 263 do
 264         if test -d $dir
 265         then
 266                 break;
 267         fi
 268 done
 269 AC_MSG_RESULT(root-mode pid file will go in $dir)
 270 AC_DEFINE_UNQUOTED(PID_DIR, "$dir", directory for PID lock files)
 271
 272 # We may have a fallback MDA available in case the socket open to the
 273 # local SMTP listener fails.  Best to use procmail for this, as we know
 274 # it won't try delivering through local SMTP and cause a mail loop.
 275 # Sendmail without the -t option to use the message headers will work too,
 276 # not just for sendmail itself but for workalikes like exim.
 277 #
 278 # Note1: A disadvantage of using procmail is that local alias expansion
 279 # according to /etc/aliases won't get done if we fall back.  This doesn't
 280 # matter in single-drop mode.
 281 #
 282 # Note2: it would be a very bad idea to use any MDA that doesn't return
 283 # a refuse-to-deliver status on disk- or process-table-full
 284 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 285 # like exim that might be lurking under a sendmail alias) do the right
 286 # thing in this circumstance.  Matthias Andree warns that procmail does
 287 # not.
 288 #
 289 # Note3: Defalt value of fallback is now off.  Matthias writes:
 290 #
 291 # 1. there is no way to predict when the fallback is used. With some MTAs
 292 #    (such as those limiting load average), outer circumstances can cause
 293 #    the fallback to kick in.
 294 #
 295 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 296 #    not only about alias expansion, .forwards to special filters won't
 297 #    work, mail may end up in a different place (users claim "mail loss"
 298 #    for that).
 299 #
 300 # 3. The claim procmail did the right thing with its exit codes is plain
 301 #    wrong. I've seen procmail exit with code 1 when it should have exited
 302 #    with code 75, like, configuration errors. Procmail is a dangerous
 303 #    beast and is best replaced by maildrop.
 304 #
 305 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 306 #    cannot tell which one it should choose. Say, your MTA is configured
 307 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 308 #    chooses procmail, this is plain wrong.
 309 #
 310
 311 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 312 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 313 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 314
 315 ###     use option --disable-fallback to disable fallback MDA
 316 ###     use option --enable-fallback=procmail or
 317 ###                --enable-fallback=sendmail to select
 318 AC_ARG_ENABLE(fallback,
 319         [  --enable-fallback=procmail    enable procmail as fallback
 320   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 321   --enable-fallback=maildrop    enable maildrop as fallback
 322   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 323
 324 case "$enable_fallback" in
 325         sendmail)       if test -z "$sendmail" ; then
 326                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 327                                 #not reached
 328                         fi
 329                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 330                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 331                         ;;
 332         procmail)       if test -z "$procmail" ; then
 333                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 334                                 #not reached
 335                         fi
 336                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 337                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 338                         ;;
 339         maildrop)       if test -z "$maildrop" ; then
 340                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 341                                 #not reached
 342                         fi
 343                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 344                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 345                         ;;
 346         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 347                         ;;
 348         auto|yes|set)   if test -n "$sendmail" ; then
 349                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 350                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 351                         else
 352                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 353                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 354                         fi
 355                         ;;
 356         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 357                         #notreached
 358                         ;;
 359 esac
 360
 361 AC_CHECK_SIZEOF(short)
 362 AC_CHECK_SIZEOF(int)
 363 AC_CHECK_SIZEOF(long)
 364
 365 ###     use option --enable-POP2 to compile in the POP2 support
 366 AC_ARG_ENABLE(POP2,
 367         [  --enable-POP2           compile in POP2 protocol support (obsolete)],
 368         [with_POP2=$enableval],
 369         [with_POP2=no])
 370 test "$with_POP2" = "yes" && AC_DEFINE(POP2_ENABLE,1,Define if you want POP2 support compiled in)
 371 AM_CONDITIONAL(POP2_ENABLE, test "$with_POP2" = yes)
 372
 373 ###     use option --disable-POP3 to omit the POP3 support
 374 AC_ARG_ENABLE(POP3,
 375         [  --disable-POP3          don't compile in POP3 protocol support],
 376         [with_POP3=$enableval],
 377         [with_POP3=yes])
 378 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 379 AM_CONDITIONAL(POP3_ENABLE, test "$with_POP3" = yes)
 380
 381 ###     use option --disable-IMAP to omit the IMAP support
 382 AC_ARG_ENABLE(IMAP,
 383         [  --disable-IMAP          don't compile in IMAP protocol support],
 384         [with_IMAP=$enableval],
 385         [with_IMAP=yes])
 386 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,Define if you want IMAP support compiled in)
 387 AM_CONDITIONAL(IMAP_ENABLE, test "$with_IMAP" = yes)
 388
 389 ###     use option --disable-ETRN to omit the ETRN support
 390 AC_ARG_ENABLE(ETRN,
 391         [  --disable-ETRN          don't compile in ETRN protocol support],
 392         [with_ETRN=$enableval],
 393         [with_ETRN=yes])
 394 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 395 AM_CONDITIONAL(ETRN_ENABLE, test "$with_ETRN" = yes)
 396
 397 ###     use option --disable-ODMR to omit the ODMR support
 398 AC_ARG_ENABLE(ODMR,
 399         [  --disable-ODMR          don't compile in ODMR protocol support],
 400         [with_ODMR=$enableval],
 401         [with_ODMR=yes])
 402 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 403 AM_CONDITIONAL(ODMR_ENABLE, test "$with_ODMR" = yes)
 404
 405 ###     use option --enable-RPA to compile in the RPA support
 406 AC_ARG_ENABLE(RPA,
 407         [  --enable-RPA            compile in RPA protocol support],
 408         [with_RPA=$enableval],
 409         [with_RPA=no])
 410 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 411 AM_CONDITIONAL(RPA_ENABLE, test "$with_RPA" = yes)
 412
 413 ###     use option --enable-NTLM to compile in the NTLM support
 414 AC_ARG_ENABLE(NTLM,
 415         [  --enable-NTLM           compile in NTLM authentication support],
 416         [with_NTLM=$enableval],
 417         [with_NTLM=no])
 418 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 419
 420 ###     use option --enable-SDPS to compile in the SDPS support
 421 AC_ARG_ENABLE(SDPS,
 422         [  --enable-SDPS           compile in SDPS protocol support],
 423         [with_SDPS=$enableval],
 424         [with_SDPS=no])
 425 if test "$with_SDPS" = yes ; then
 426    if test "$with_POP3" != yes ; then
 427        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 428        with_SDPS=no
 429    else
 430        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 431    fi
 432 fi
 433 if test "$with_POP3" != yes && test "$with_POP2" != yes \
 434     && test "$with_IMAP"  != yes ; then
 435     AC_MSG_ERROR([You must enable at least one of POP2, POP3 and IMAP.])
 436 fi
 437
 438 AC_CACHE_SAVE
 439
 440 ###     use option --enable-opie to compile in the OPIE support
 441 AC_ARG_ENABLE(opie,
 442         [  --enable-opie           support OTP through the OPIE library],
 443         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR(cannot find <opie.h>, which is required for OPIE support.)])
 444           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR(cannot find libopie, which is required for OPIE support.)])
 445           with_opie=$enableval],
 446         [with_opie=no])
 447 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 448
 449 dnl Mostly stolen from gnulib's getaddrinfo.m4
 450 AC_SEARCH_LIBS(getaddrinfo, [nsl socket])
 451 AC_CACHE_CHECK([for getaddrinfo],[fm_cv_getaddrinfo],[
 452   AC_TRY_LINK([
 453 #include <sys/types.h>
 454 #ifdef HAVE_SYS_SOCKET_H
 455 #include <sys/socket.h>
 456 #endif
 457 #ifdef HAVE_NETDB_H
 458 #include <netdb.h>
 459 #endif
 460   ], [getaddrinfo(0, 0, 0, 0);],
 461     [ fm_cv_getaddrinfo=yes],
 462     [ fm_cv_getaddrinfo=no ])
 463 ])
 464
 465 if test x"$fm_cv_getaddrinfo" = "xyes"; then
 466      AC_DEFINE(HAVE_GETADDRINFO, 1,
 467       [Define to 1 if you have the getaddrinfo function.])
 468 fi
 469
 470 AC_CACHE_CHECK([for getnameinfo],[fm_cv_getnameinfo],[
 471   AC_TRY_LINK([
 472 #include <sys/types.h>
 473 #ifdef HAVE_SYS_SOCKET_H
 474 #include <sys/socket.h>
 475 #endif
 476 #ifdef HAVE_NETDB_H
 477 #include <netdb.h>
 478 #endif
 479 #ifndef NULL
 480 #define NULL ((void *)0)
 481 #endif
 482   ], [getnameinfo(NULL,0, NULL,0, NULL, 0, 0);],
 483     [ fm_cv_getnameinfo=yes],
 484     [ fm_cv_getnameinfo=no ])
 485 ])
 486 if test $fm_cv_getnameinfo = yes ; then
 487     AC_DEFINE(HAVE_GETNAMEINFO,1,[Define to 1 if your system has getnameinfo()])
 488 fi
 489
 490 AM_CONDITIONAL(NEED_GETADDRINFO, test "$fm_cv_getaddrinfo" != yes)
 491 AM_CONDITIONAL(NEED_GETNAMEINFO, test "$fm_cv_getnameinfo"   != yes)
 492
 493 AC_CHECK_FUNCS(inet_ntop)
 494 dnl Check if getaddrinfo is async-signal-safe - most implementations aren't
 495 if test "$fm_cv_getaddrinfo" = yes ; then
 496     AC_MSG_CHECKING(if your getaddrinfo is async-signal-safe)
 497     gai_ts=no
 498     dnl we have getaddrinfo() - check if the OS is known to have a async-signal-safe implementation
 499     case $host_os in
 500         darwin9*)                               gai_ts=yes ;;
 501         linux*)                                 gai_ts=yes ;;
 502         freebsd5.5|freebsd6*|freebsd7*)         gai_ts=yes ;;
 503         solaris2.8|solaris2.9|solaris2.10)      gai_ts=yes ;;
 504     esac
 505     AC_MSG_RESULT($gai_ts)
 506     if test $gai_ts = yes ; then
 507         AC_DEFINE(GETADDRINFO_ASYNCSAFE, 1, [define to 1 if you know your getaddrinfo function is async-signal-safe])
 508     fi
 509 fi
 510
 511 # This version of the Kerberos 4 and 5 options addresses the follwing issues:
 512 #
 513 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 514 #   OpenSSL support (Debian's is)
 515 # * Build the kerberos.c stuff (KPOP) only for kerberosIV, to avoid breakage.
 516 #   I don't know if this is 100% correct, but now at least IMAP and POP3
 517 #   behave the same way regarding kerberosV.
 518 # * Build without any fuss for both kerberosIV and V at the same time.
 519 # * Move all the kerberos header mess to kerberos.h, and #include that
 520 #   in driver.c and kerberos.c.
 521 #
 522 # Tested using the Heimdal Kerberos V libs, Kungliga Tekniska Högskolan (the
 523 # Royal Institute of Technology in Stockholm, Sweden)'s kerberos IV libs, and
 524 # the MIT reference implementation of KerberosV (all as packaged in Debian).
 525
 526 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 527 ### make sure --with-ssl is run before --with-kerberos* !
 528 AC_ARG_WITH(kerberos5,
 529        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 530 [
 531 if test "$with_kerberos5" != "no"
 532 then
 533 # Check for a OpenBSD special case
 534 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 535 then
 536   AS_MESSAGE(checking kerberosV for OpenBSD...)
 537   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 538   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 539   CFLAGS="$CFLAGS -I/usr/include/kerberosV"
 540   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 541 elif krb5-config 2> /dev/null >/dev/null ; then
 542   krb5_prefix=`krb5-config --prefix krb5`
 543   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 544   if test -f ${krb5_prefix}/include/et/com_err.h && \
 545    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 546     CFLAGS="$CFLAGS -I${krb5_prefix}/include/et"
 547   fi
 548   unset krb5_prefix
 549   CFLAGS="$CFLAGS `krb5-config --cflags krb5`"
 550   LIBS="$LIBS `krb5-config --libs krb5`"
 551   AC_DEFINE(KERBEROS_V5)
 552 else
 553   if test "$with_kerberos5" != "yes"
 554   then
 555       LDFLAGS="$LDFLAGS -L${with_kerberos5}/lib"
 556       searchdirs="$with_kerberos5"
 557   else
 558       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 559   fi
 560   with_kerberos5=
 561   for dir in $searchdirs
 562   do AC_MSG_CHECKING([for Kerberos V in $dir])
 563      if test -f "$dir/include/krb5.h" || test -f "$dir/include/krb5/krb5.h"
 564      then
 565         if test -d "$dir/include/krb5" ; then CPPFLAGS="$CPPFLAGS -I$dir/include/krb5" ; fi
 566         ac_krblibs=
 567         if test -f "$dir/include/roken.h" || test -f "$dir/include/krb5/roken.h"
 568         then
 569            ac_krblibs="-lasn1 -lroken -lcom_err"
 570            AC_MSG_RESULT([Heimdal found])
 571           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 572           dnl we assume we do if it is available
 573            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 574                 ${LDFLAGS})
 575            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 576               AC_CHECK_LIB(crypto, MD5_Init, [],
 577                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 578                 ${LDFLAGS} ${ac_krblibs}),
 579            ${LDFLAGS} ${ac_krblibs})
 580            AC_DEFINE(HEIMDAL)
 581         else
 582           AC_MSG_RESULT([found])
 583           ac_krblibs="-lcom_err"
 584            AC_CHECK_LIB(crypto,
 585              krb5_des_string_to_key,
 586              libk5crypto=-lcrypto,
 587                 AC_CHECK_LIB(k5crypto,
 588                    krb5_des_string_to_key,
 589                    libk5crypto=-lk5crypto,
 590                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 591                    ${LDFLAGS} ${ac_krblibs}),
 592                  ${LDFLAGS} ${ac_krblibs})
 593         fi
 594         AC_CHECK_LIB(krb5, krb5_init_context,[],
 595            continue,
 596            ${LDFLAGS} ${ac_krblibs})
 597         AC_DEFINE(KERBEROS_V5)
 598         test "$dir" != "/usr" && CFLAGS="$CFLAGS -I$dir/include"
 599         LDFLAGS="$LDFLAGS -L$dir/lib"
 600        LIBS="$LIBS $ac_krblibs $libk5crypto"
 601         with_kerberos5=$dir
 602         break
 603      else
 604         AC_MSG_RESULT([not found])
 605      fi
 606   done
 607   if test -z "$with_kerberos5" ; then
 608      AC_MSG_ERROR([Kerberos 5 libraries not found])
 609   fi
 610 fi
 611 fi
 612 ]) dnl --with-kerberos5=DIR
 613
 614 ###    use option --with-kerberos=DIR to point at a Kerberos 4 directory
 615 KERBEROS_V4=0
 616 AC_ARG_WITH(kerberos,
 617        [  --with-kerberos=DIR     point fetchmail compilation at a Kerberos 4 directory],
 618 [
 619 if test "$with_kerberos" != "no"
 620 then
 621     AC_MSG_WARN([Kerberos IV support is obsolete. Use --with-kerberos5 if possible.])
 622 # Check for a NetBSD/OpenBSD special case
 623 if test "$with_kerberos" = "yes" && ( test `uname` = "NetBSD" || test `uname` = "OpenBSD" )
 624 then
 625   AS_MESSAGE(checking kerberosIV for `uname`...)
 626   KERBEROS_V4=1
 627   CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 628   case `uname` in
 629       NetBSD)  LIBS="$LIBS -lkrb -ldes -lroken -lcom_err" ;;
 630       OpenBSD) LIBS="$LIBS -lkrb -ldes" ;;
 631   esac
 632 elif krb4-config 2> /dev/null >/dev/null ; then
 633   krb4_prefix=`krb4-config --prefix`
 634   AC_MSG_RESULT([krb4-config points to kerberosIV under $krb4_prefix])
 635   unset krb4_prefix
 636   CFLAGS="$CFLAGS `krb4-config --cflags`"
 637   LIBS="$LIBS `krb4-config --libs`"
 638   KERBEROS_V4=1
 639 elif krb5-config 2> /dev/null >/dev/null ; then
 640   krb4_prefix=`krb5-config --prefix krb4`
 641   AC_MSG_RESULT([krb5-config points to kerberosIV under $krb4_prefix])
 642   if test -f ${krb4_prefix}/include/kerberosIV/krb.h ; then
 643     AC_DEFINE(KERBEROS_V4_V5,1,Define if you have Kerberos V4 headers under a kerberosIV directory)
 644   fi
 645   unset krb4_prefix
 646   CFLAGS="$CFLAGS `krb5-config --cflags krb4`"
 647   LIBS="$LIBS `krb5-config --libs krb4`"
 648   KERBEROS_V4=1
 649 else
 650   #we need to detect when we're building under a kerberosV compatibility
 651   #layer, btw...
 652   if test "$with_kerberos" != "yes" ; then
 653      searchdirs="$with_kerberos"
 654   else
 655      searchdirs="$with_kerberos5 /usr/kerberos /usr/kerberosIV /usr/athena /usr"
 656   fi
 657   with_kerberos=
 658   ac_saveLDFLAGS="$LDFLAGS"
 659   for dir in $searchdirs
 660   do
 661      AC_MSG_CHECKING([for Kerberos IV in $dir])
 662      if test -f "$dir/include/krb.h" || test -f "$dir/include/krb4.h" \
 663             || test -f "$dir/include/kerberosIV/krb.h"
 664      then
 665         AC_MSG_RESULT([found])
 666      else
 667         AC_MSG_RESULT([not found])
 668        continue
 669      fi
 670      #Find libs
 671      if test -f "$with_kerberos5/roken.h" ; then
 672        AC_CHECK_LIB(45, krb_mk_req)
 673      fi
 674      LDFLAGS="-L$dir/lib $ac_saveLDFLAGS"
 675      if test `uname` = "FreeBSD"; then
 676         AC_SEARCH_LIBS(_ossl_old_des_string_to_key, [des425 des crypto], [], continue)
 677      else
 678         AC_SEARCH_LIBS(des_string_to_key, [crypto], [], continue)
 679      fi
 680      AC_SEARCH_LIBS(krb_realmofhost, [krb4 krb], [], continue)
 681      with_kerberos="$dir"
 682      if test -f "$dir/include/kerberosIV/krb.h" ; then
 683         dir="$dir/include/kerberosIV"
 684      else
 685        dir="$dir/include"
 686      fi
 687      KERBEROS_V4=1
 688      test -f "$with_kerberos5/roken.h" && AC_DEFINE(HEIMDAL)
 689      test "$dir" != "/usr/include" && CFLAGS="$CFLAGS -I$dir"
 690      LDFLAGS="$LDFLAGS -L$with_kerberos/lib"
 691      break
 692   done
 693   if test -z "$with_kerberos" ; then
 694      AC_MSG_ERROR([Kerberos 4 libraries not found])
 695   fi
 696   LDFLAGS="$ac_saveLDFLAGS"
 697 fi
 698 fi
 699 ]) dnl --with-kerberos=DIR
 700 if test "$KERBEROS_V4" = 1 ; then
 701     AC_DEFINE(KERBEROS_V4,1,Define if you have Kerberos V4)
 702 fi
 703 AM_CONDITIONAL(KERBEROS_V4_ENABLE, test "$KERBEROS_V4" = 1)
 704
 705 ###     use option --with-ssl to compile in the SSL support
 706 AC_ARG_WITH(ssl,
 707         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 708         [with_ssl=$withval],
 709         [with_ssl=no])
 710 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 711
 712 if test "$with_ssl" = "yes"
 713 then
 714     #   User didn't specify an SSL location.  Let's look at some common
 715     #   directories where SSL has been found in the past and try and auto
 716     #   configure for SSL.  OpenSSL determination will be made later.
 717     #   This will screw up if an OpenSSL install is located in a later
 718     #   directory than an older SSLeay install, but the user should fix that
 719     #   anyways and he can override on the configure line.
 720     #   Just testing for directories is not sufficient, /usr exists on
 721     #   all systems!
 722     for ac_dir in \
 723       /usr/local/ssl \
 724       /usr/local \
 725       /usr/ssl \
 726       /usr \
 727       /local/ssl \
 728       /opt/ssl \
 729       /opt/csw \
 730       ; \
 731     do
 732         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 733             with_ssl=$ac_dir
 734             break;
 735         fi
 736     done
 737 fi
 738
 739 if test -n "$with_ssl" -a "$with_ssl" != "no"
 740 then
 741   # With the autoconfigure above, the only time this is going to be
 742   # true is going to be when we could not find the headers.  If they
 743   # are not in system standard locations, we are going to be broken.
 744   if test "$with_ssl" = "yes"
 745   then
 746     # Let's just define the standard location for the SSLeay root
 747     with_ssl="/usr/local/ssl"
 748   fi
 749   if test -r $with_ssl/include/openssl/ssl.h
 750   then
 751     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 752     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 753     test "$with_ssl" != "/usr" && CFLAGS="$CFLAGS -I$with_ssl/include"
 754     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 755     ### force the Kerberos direcory onto the include path so it will build.
 756     CFLAGS="$CFLAGS -I/usr/kerberos/include"
 757     ### OpenBSD comes with ssl headers
 758   else
 759     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 760   fi
 761   LDFLAGS="$LDFLAGS -L$with_ssl/lib"
 762   LIBS="$LIBS -lssl -lcrypto"
 763   dnl check if -ldl is needed
 764   AC_MSG_CHECKING([for additional library dependencies of SSL])
 765   found=0
 766   save_LIBS="$LIBS"
 767   for i in "" "-ldl" ; do
 768       LIBS="$LDFLAGS $save_LIBS $i"
 769       AC_LINK_IFELSE([AC_LANG_PROGRAM(,[SSL_library_init()])],[found=1; break])
 770   done
 771   if test $found = 0 ; then
 772       AC_MSG_RESULT([error])
 773       AC_MSG_ERROR([cannot link with SSL - check config.log])
 774   fi
 775   LIBS="$save_LIBS $i"
 776   if test "$i" = "" ; then i="(none)" ; fi
 777   AC_MSG_RESULT($i)
 778   dnl XXX FIXME: use pkg-config if available!
 779   AC_DEFINE(SSL_ENABLE)
 780 else
 781   AC_MSG_NOTICE(Disabling SSL support.)
 782 fi
 783
 784 ###     use option --with-socks=DIR to point at SOCKS library
 785 AC_ARG_WITH(socks,
 786         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 787 [
 788 if test "$with_socks" != no
 789 then
 790     if test "$with_socks" != yes
 791     then
 792         LDFLAGS="$LDFLAGS -L$with_socks"
 793     else
 794         AC_CHECK_LIB(socks, Rconnect,,
 795                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 796     fi
 797     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 798     CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 799     LIBS="-lsocks $LIBS"
 800 fi])
 801
 802 ###     use option --with-socks5=DIR to point at SOCKS library
 803 AC_ARG_WITH(socks5,
 804         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 805 [
 806 if test "$with_socks5" != no
 807 then
 808   if test "$with_socks5" != yes
 809   then
 810     LDFLAGS="$LDFLAGS -L$with_socks5"
 811   fi
 812   ac_savedLDFLAGS="$LDFLAGS"
 813   LDFLAGS="$LDFLAGS $LDFLAGS"
 814   AC_CHECK_LIB(socks5, SOCKSconnect,,
 815         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 816   AC_DEFINE(HAVE_SOCKS)
 817   CFLAGS="$CFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 818   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 819   LDFLAGS="$ac_savedLDFLAGS"
 820 fi])
 821
 822 ACX_WHICH_GETHOSTBYNAME_R
 823
 824 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 825 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 826
 827 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 828 AC_ARG_WITH(gssapi,
 829         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 830 [
 831 if test "$with_gssapi" != "no"
 832 then
 833   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 834   then
 835     with_gssapi=$with_kerberos5
 836   fi
 837
 838   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 839   then
 840     CFLAGS="$CFLAGS -I$with_gssapi/include"
 841     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 842   fi
 843
 844   dnl obtain gssapi default libs
 845   if krb5-config --libs gssapi 2>/dev/null >/dev/null ; then
 846       LIBS="$LIBS `krb5-config --libs gssapi`"
 847   else
 848     AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 849     if test -n "$nogss"
 850     then
 851       # -lgss not found
 852       if test "$with_gssapi" = yes ; then
 853           with_gssapi=/usr
 854       fi
 855       if test -f "$with_gssapi/include/roken.h" -o -f "$with_gssapi/include/krb5/roken.h"
 856       then
 857          # have roken.h, assume Heimdal
 858          case `uname` in
 859              NetBSD) LIBS="$LIBS -lkrb5" ;;
 860              *)      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl" ;;
 861          esac
 862          AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 863                       AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 864          AC_DEFINE(HEIMDAL)
 865       else
 866          # no roken.h, assume MIT
 867          AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 868                       AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 869       fi
 870     fi
 871   fi
 872   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 873   if test "$with_gssapi" != yes ; then
 874     CPPFLAGS="$CPPFLAGS-I$with_gssapi/include"
 875   fi
 876   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 877   if test "$ac_cv_header_gssapi_h" = "yes"; then
 878     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 879   else
 880     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 881   fi
 882 fi])
 883
 884 dnl ,------------------------------------------------------------------
 885 dnl Check if we need TRIO
 886 needtrio=0
 887 if test "$FORCE_TRIO" = "yes" ; then
 888     needtrio=1
 889     ac_cv_func_vsnprintf=no
 890     ac_cv_func_snprintf=no
 891 fi
 892 if test "x$ac_cv_func_snprintf" != "xyes" ; then
 893     AC_DEFINE(snprintf, trio_snprintf,
 894               [Define to trio_snprintf if your system lacks snprintf])
 895     needtrio=1
 896 fi
 897 if test "x$ac_cv_func_vsnprintf" != "xyes" ; then
 898     AC_DEFINE(vsnprintf, trio_vsnprintf,
 899               [Define to trio_vsnprintf if your system lacks vsnprintf])
 900     needtrio=1
 901 fi
 902 AM_CONDITIONAL(NEED_TRIO, test "$needtrio" = 1)
 903
 904 dnl TRIO IEEE compiler option for Alpha
 905 dnl
 906 if test "$needtrio" = 1 ; then
 907     AC_MSG_CHECKING(for IEEE compilation options)
 908     AC_CACHE_VAL(ac_cv_ieee_option, [
 909     AC_TRY_COMPILE(,[
 910     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
 911     # error "Option needed"
 912     #endif
 913     ],ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
 914     AC_TRY_COMPILE(,[
 915     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
 916     # error "Option needed"
 917     #endif
 918     ],ac_cv_ieee_option="-ieee",
 919     AC_TRY_COMPILE(,[
 920     #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
 921     # error "Option needed"
 922     #endif
 923     ],ac_cv_ieee_option="-mieee",
 924     ac_cv_ieee_option="none"
 925     )
 926     )
 927     )
 928     ])
 929     AC_MSG_RESULT($ac_cv_ieee_option)
 930     if test $ac_cv_ieee_option != none; then
 931       CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
 932     fi
 933 fi
 934 dnl ----------------------------------------------------------------'
 935
 936 AC_CONFIG_FILES([Makefile po/Makefile.in genlsm.sh])
 937 AC_OUTPUT
 938
 939 dnl Local Variables:
 940 dnl comment-start: "dnl "
 941 dnl comment-end: ""
 942 dnl comment-start-skip: "\\bdnl\\b\\s *"
 943 dnl compile-command: "make configure config.h.in"
 944 dnl End: