Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [2])
  12 m4_define([gtk_minor_version], [99])
  13 m4_define([gtk_micro_version], [1])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Define a string for the earliest version that this release has
  32 # backwards binary compatibility with for all interfaces a module
  33 # might. Unless we add module-only API with lower stability
  34 # guarantees, this should be unchanged until we break binary compat
  35 # for GTK+.
  36 #
  37 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  38 m4_define([gtk_binary_version], [3.0.0])
  39
  40 # required versions of other packages
  41 m4_define([glib_required_version], [2.27.5])
  42 m4_define([pango_required_version], [1.20])
  43 m4_define([atk_required_version], [1.29.2])
  44 m4_define([cairo_required_version], [1.10.0])
  45 m4_define([gdk_pixbuf_required_version], [2.21.0])
  46 GLIB_REQUIRED_VERSION=glib_required_version
  47 PANGO_REQUIRED_VERSION=pango_required_version
  48 ATK_REQUIRED_VERSION=atk_required_version
  49 CAIRO_REQUIRED_VERSION=cairo_required_version
  50 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  51 AC_SUBST(GLIB_REQUIRED_VERSION)
  52 AC_SUBST(PANGO_REQUIRED_VERSION)
  53 AC_SUBST(ATK_REQUIRED_VERSION)
  54 AC_SUBST(CAIRO_REQUIRED_VERSION)
  55 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  56
  57
  58 # Save this value here, since automake will set cflags later
  59 cflags_set=${CFLAGS+set}
  60
  61 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  62 AM_MAINTAINER_MODE([enable])
  63
  64 # Support silent build rules, requires at least automake-1.11. Disable
  65 # by either passing --disable-silent-rules to configure or passing V=1
  66 # to make
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69 #
  70 # For each of the libraries we build, we define the following
  71 # substituted variables:
  72 #
  73 # foo_PACKAGES:     pkg-config packages this library requires
  74 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  75 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  76 # foo_DEP_LIBS:     All libraries this module requires
  77 # foo_DEP_CFLAGS:   All cflags this module requires
  78
  79
  80 GTK_MAJOR_VERSION=gtk_major_version
  81 GTK_MINOR_VERSION=gtk_minor_version
  82 GTK_MICRO_VERSION=gtk_micro_version
  83 GTK_INTERFACE_AGE=gtk_interface_age
  84 GTK_BINARY_AGE=gtk_binary_age
  85 GTK_VERSION=gtk_version
  86 GTK_API_VERSION=gtk_api_version
  87 GTK_BINARY_VERSION=gtk_binary_version
  88 AC_SUBST(GTK_MAJOR_VERSION)
  89 AC_SUBST(GTK_MINOR_VERSION)
  90 AC_SUBST(GTK_MICRO_VERSION)
  91 AC_SUBST(GTK_INTERFACE_AGE)
  92 AC_SUBST(GTK_BINARY_AGE)
  93 AC_SUBST(GTK_API_VERSION)
  94 AC_SUBST(GTK_VERSION)
  95 AC_SUBST(GTK_BINARY_VERSION)
  96
  97 # libtool versioning
  98 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  99 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 100 #LT_REVISION=$GTK_INTERFACE_AGE
 101 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 102 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 103
 104 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 105 m4_define([lt_revision], [gtk_interface_age])
 106 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 107 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 108 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 109 AC_SUBST(LT_VERSION_INFO)
 110 AC_SUBST(LT_CURRENT_MINUS_AGE)
 111
 112 m4_define([gail_lt_current],[0])
 113 m4_define([gail_lt_revision],[0])
 114 m4_define([gail_lt_age],[0])
 115 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 116 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 117 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 118 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 119
 120 # Checks for programs.
 121 AC_PROG_CC
 122 AC_PROG_CC_C_O
 123 AC_PROG_CC_STDC
 124 AC_PROG_INSTALL
 125 AC_PROG_MAKE_SET
 126
 127
 128 GETTEXT_PACKAGE=gtk30
 129 AC_SUBST(GETTEXT_PACKAGE)
 130 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 131                    [The prefix for our gettext translation domains.])
 132
 133 AC_CANONICAL_HOST
 134
 135 MATH_LIB=-lm
 136 AC_MSG_CHECKING([for native Win32])
 137 LIB_EXE_MACHINE_FLAG=X86
 138 EXE_MANIFEST_ARCHITECTURE=X86
 139 case "$host" in
 140   *-*-mingw*)
 141     os_win32=yes
 142     gio_can_sniff=no
 143     MATH_LIB=
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       EXE_MANIFEST_ARCHITECTURE=AMD64
 148       ;;
 149     esac
 150     ;;
 151   *)
 152     os_win32=no
 153     ;;
 154 esac
 155 AC_MSG_RESULT([$os_win32])
 156
 157 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 158 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 159
 160 case $host in
 161   *-*-linux*)
 162     os_linux=yes
 163     ;;
 164 esac
 165
 166 dnl
 167 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 168 dnl We use this for an automated test for C++ header correctness.
 169 dnl
 170 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 171 AC_LANG_PUSH([C++])
 172
 173 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 174 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 175
 176 gtk_save_cxxflags="$CXXFLAGS"
 177 CXXFLAGS="$CXXFLAGS -x objective-c++"
 178 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 179 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 180 CXXFLAGS="$gtk_save_cxxflags"
 181 AC_LANG_POP([C++])
 182
 183 if test "$os_win32" = "yes"; then
 184   if test x$enable_static = xyes -o x$enable_static = x; then
 185     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 186     enable_static=no
 187   fi
 188   if test x$enable_shared = xno; then
 189     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 190   fi
 191   enable_shared=yes
 192 fi
 193
 194 dnl Initialize libtool
 195 LT_PREREQ([2.2.6])
 196 LT_INIT([disable-static win32-dll])
 197 # Create libtool early, because it's used in configure
 198 LT_OUTPUT
 199
 200 # Make sure we use 64-bit versions of various file stuff.
 201 AC_SYS_LARGEFILE
 202
 203 AM_PROG_AS
 204 AC_PATH_PROG(NM, nm, nm)
 205
 206 AC_MSG_CHECKING([for some Win32 platform])
 207 case "$host" in
 208   *-*-mingw*|*-*-cygwin*)
 209     platform_win32=yes
 210     ;;
 211   *)
 212     platform_win32=no
 213     ;;
 214 esac
 215 AC_MSG_RESULT([$platform_win32])
 216 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 217
 218 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 219 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 220 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 221
 222 if test "$os_win32" = "yes"; then
 223   AC_CHECK_TOOL(WINDRES, windres, no)
 224   if test "$WINDRES" = no; then
 225     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 226   fi
 227   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 228 fi
 229 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 230
 231 m4_define([debug_default],
 232           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 233
 234 dnl declare --enable-* args and collect ac_help strings
 235 AC_ARG_ENABLE(debug,
 236               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 237                              [turn on debugging @<:@default=debug_default@:>@]),,
 238               enable_debug=debug_default)
 239
 240 AC_ARG_ENABLE(rebuilds,
 241               [AC_HELP_STRING([--disable-rebuilds],
 242                               [disable all source autogeneration rules])],,
 243               [enable_rebuilds=yes])
 244
 245 AC_ARG_ENABLE(xkb,
 246               [AC_HELP_STRING([--enable-xkb],
 247                               [support XKB extension [default=maybe]])],,
 248               [enable_xkb="maybe"])
 249 AC_ARG_ENABLE(xinerama,
 250               [AC_HELP_STRING([--enable-xinerama],
 251                               [support Xinerama extension if available [default=maybe]])],,
 252               [enable_xinerama="maybe"])
 253 AC_ARG_ENABLE(xinput,
 254               [AC_HELP_STRING([--enable-xinput],
 255                               [support XInput extension if available [default=yes]])],,
 256               [enable_xinput="maybe"])
 257
 258 AC_ARG_ENABLE(x11-backend,
 259               [AC_HELP_STRING([--enable-x11-backend],
 260                               [enable the X11 gdk backend])],
 261                               [backend_set=yes])
 262 AC_ARG_ENABLE(win32-backend,
 263               [AC_HELP_STRING([--enable-win32-backend],
 264                               [enable the Win32 gdk backend])],
 265                               [backend_set=yes])
 266 AC_ARG_ENABLE(quartz-backend,
 267               [AC_HELP_STRING([--enable-quartz-backend],
 268                               [enable the quartz gdk backend])],
 269                               [backend_set=yes])
 270
 271 if test -z "$backend_set"; then
 272   if test "$platform_win32" = yes; then
 273     enable_win32_backend=yes
 274   else
 275     enable_x11_backend=yes
 276   fi
 277 fi
 278
 279 cairo_backends=
 280 backend_immodules=
 281 GDK_BACKENDS=
 282 GDK_EXTRA_LIBS=
 283 GDK_EXTRA_CFLAGS=
 284 GDK_WINDOWING=
 285 GIO_PACKAGE=gio-2.0
 286 PANGO_PACKAGES="pango pangocairo"
 287
 288 if test "x$enable_x11_backend" == xyes; then
 289   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 290   # backend names are identical.
 291   cairo_backends="$cairo_backends cairo-xlib"
 292   GDK_BACKENDS="$GDK_BACKENDS x11"
 293   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 294   # gdkapplaunchcontext-x11.c
 295   GIO_PACKAGE=gio-unix-2.0
 296   backend_immodules="$backend_immodules,xim"
 297   GDK_WINDOWING="$GDK_WINDOWING
 298 #define GDK_WINDOWING_X11"
 299 fi
 300
 301 if test "x$enable_win32_backend" == xyes; then
 302   cairo_backends="$cairo_backends cairo-win32"
 303   GDK_BACKENDS="$GDK_BACKENDS win32"
 304   backend_immodules="$backend_immodules,ime"
 305   GDK_WINDOWING="$GDK_WINDOWING
 306 #define GDK_NATIVE_WINDOW_POINTER
 307 #define GDK_WINDOWING_WIN32"
 308   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 309   AM_CONDITIONAL(USE_WIN32, true)
 310   PANGO_PACKAGES="pangowin32 pangocairo"
 311 else
 312   AM_CONDITIONAL(USE_WIN32, false)
 313 fi
 314
 315 if test "x$enable_quartz_backend" == xyes; then
 316   cairo_backends="$cairo_backends cairo-quartz"
 317   GDK_BACKENDS="$GDK_BACKENDS quartz"
 318   GDK_WINDOWING="$GDK_WINDOWING
 319 #define GDK_WINDOWING_QUARTZ"
 320   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 321   AM_CONDITIONAL(USE_QUARTZ, true)
 322 else
 323   AM_CONDITIONAL(USE_QUARTZ, false)
 324 fi
 325
 326 # strip leading space
 327 GDK_BACKENDS=${GDK_BACKENDS/# }
 328
 329 AC_SUBST(GDK_BACKENDS)
 330
 331 if test -z "$GDK_BACKENDS"; then
 332   AC_MSG_ERROR([No GDK backends selected.])
 333 fi
 334
 335 if test "x$enable_debug" = "xyes"; then
 336   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 337   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 338 else
 339   if test "x$enable_debug" = "xno"; then
 340     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 341   else
 342     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 343   fi
 344 fi
 345
 346
 347 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 348                    [Define if debugging is enabled])
 349
 350
 351 # Build time sanity check...
 352 AM_SANITY_CHECK
 353
 354 changequote(,)dnl
 355 if test "x$GCC" = "xyes"; then
 356   case " $CFLAGS " in
 357   *[\ \ ]-Wall[\ \      ]*) ;;
 358   *) CFLAGS="$CFLAGS -Wall" ;;
 359   esac
 360
 361   if test "x$enable_ansi" = "xyes"; then
 362     case " $CFLAGS " in
 363     *[\ \       ]-ansi[\ \      ]*) ;;
 364     *) CFLAGS="$CFLAGS -ansi" ;;
 365     esac
 366
 367     case " $CFLAGS " in
 368     *[\ \       ]-pedantic[\ \  ]*) ;;
 369     *) CFLAGS="$CFLAGS -pedantic" ;;
 370     esac
 371   fi
 372 fi
 373 changequote([,])dnl
 374
 375 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 376
 377 # Ensure MSVC-compatible struct packing convention is used when
 378 # compiling for Win32 with gcc.
 379 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 380 # gcc2 uses "-fnative-struct".
 381 if test x"$os_win32" = xyes; then
 382   if test x"$GCC" = xyes; then
 383     msnative_struct=''
 384     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 385     if test -z "$ac_cv_prog_CC"; then
 386       our_gcc="$CC"
 387     else
 388       our_gcc="$ac_cv_prog_CC"
 389     fi
 390     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 391       2.)
 392         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 393           msnative_struct='-fnative-struct'
 394         fi
 395         ;;
 396       *)
 397         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 398           msnative_struct='-mms-bitfields'
 399         fi
 400         ;;
 401     esac
 402     if test x"$msnative_struct" = x ; then
 403       AC_MSG_RESULT([no way])
 404       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 405     else
 406       CFLAGS="$CFLAGS $msnative_struct"
 407       AC_MSG_RESULT([${msnative_struct}])
 408     fi
 409   fi
 410 fi
 411
 412 ## Initial sanity check, done here so that users get told they
 413 ## have the wrong dependencies as early in the process as possible.
 414 ## Later on we actually use the cflags/libs from separate pkg-config
 415 ## calls. Oh, also the later pkg-config calls don't include
 416 ## the version requirements since those make the module lists
 417 ## annoying to construct
 418 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 419   [glib-2.0 >= glib_required_version dnl
 420    atk >= atk_required_version dnl
 421    pango >= pango_required_version dnl
 422    cairo >= cairo_required_version dnl
 423    cairo-gobject >= cairo_required_version dnl
 424    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 425
 426 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 427
 428 if test "$os_win32" != yes; then
 429     # libtool option to control which symbols are exported
 430     # right now, symbols starting with _ are not exported
 431     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 432 else
 433     # We currently use .def files on Windows (for gdk and gtk)
 434     LIBTOOL_EXPORT_OPTIONS=
 435 fi
 436 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 437
 438 dnl ******************************************************
 439 dnl * See whether to include shared library dependencies *
 440 dnl ******************************************************
 441
 442 AC_ARG_ENABLE(explicit-deps,
 443               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 444                               [use explicit dependencies in .pc files [default=auto]])],,
 445               [enable_explicit_deps=auto])
 446
 447 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 448 case $enable_explicit_deps in
 449   auto)
 450     export SED
 451     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 452     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 453       enable_explicit_deps=yes
 454     else
 455       enable_explicit_deps=no
 456     fi
 457   ;;
 458   yes|no)
 459   ;;
 460   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 461   ;;
 462 esac
 463 AC_MSG_RESULT($enable_explicit_deps)
 464
 465 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 466
 467 # define a MAINT-like variable REBUILD which is set if Perl
 468 # and awk are found, so autogenerated sources can be rebuilt
 469
 470 AC_PATH_PROGS(PERL, perl5 perl)
 471
 472 # We would like indent, but don't require it.
 473 AC_CHECK_PROG(INDENT, indent, indent)
 474
 475 REBUILD=\#
 476 if test "x$enable_rebuilds" = "xyes" && \
 477      test -n "$PERL" && \
 478      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 479   REBUILD=
 480 fi
 481 AC_SUBST(REBUILD)
 482
 483 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 484 AC_CHECK_FUNCS(localtime_r)
 485
 486 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 487 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 488 AC_TRY_LINK([#include <langinfo.h>], [
 489 char c;
 490 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 491 ], gtk_ok=yes, gtk_ok=no)
 492 AC_MSG_RESULT($gtk_ok)
 493 if test "$gtk_ok" = "yes"; then
 494   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 495             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 496 fi
 497
 498 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 499 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 500 AC_TRY_LINK([#include <langinfo.h>], [
 501 char c;
 502 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 503 ], gtk_ok=yes, gtk_ok=no)
 504 AC_MSG_RESULT($gtk_ok)
 505 if test "$gtk_ok" = "yes"; then
 506   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 507             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 508 fi
 509
 510 # _NL_PAPER_HEIGHT is an enum and not a define
 511 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 512 AC_TRY_LINK([#include <langinfo.h>], [
 513 char c;
 514 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 515 ], gtk_ok=yes, gtk_ok=no)
 516 AC_MSG_RESULT($gtk_ok)
 517 if test "$gtk_ok" = "yes"; then
 518   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 519             [Define if _NL_PAPER_HEIGHT is available])
 520 fi
 521
 522 # _NL_PAPER_WIDTH is an enum and not a define
 523 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 524 AC_TRY_LINK([#include <langinfo.h>], [
 525 char c;
 526 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 527 ], gtk_ok=yes, gtk_ok=no)
 528 AC_MSG_RESULT($gtk_ok)
 529 if test "$gtk_ok" = "yes"; then
 530   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 531             [Define if _NL_PAPER_WIDTH is available])
 532 fi
 533
 534 # i18n stuff
 535 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 536 AM_GLIB_GNU_GETTEXT
 537 LIBS="$LIBS $INTLLIBS"
 538 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 539         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 540       esac])
 541
 542 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 543 dnl po-properties/POTFILES during configure; see GNOME #573515.
 544 dnl
 545 dnl Generate list of files to be processed by xgettext which will
 546 dnl be included in po-properties/Makefile.
 547 test -d po-properties || mkdir po-properties
 548 if test "x$srcdir" != "x."; then
 549   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 550     popropsrcprefix="$srcdir/"
 551   else
 552     popropsrcprefix="../$srcdir/"
 553   fi
 554 else
 555   popropsrcprefix="../"
 556 fi
 557 rm -f po-properties/POTFILES
 558 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 559 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 560 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 561
 562 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 563
 564 dnl The DU4 header files don't provide library prototypes unless
 565 dnl -std1 is given to the native cc.
 566 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 567
 568 gtk_save_LIBS=$LIBS
 569 LIBS="$LIBS -lm"
 570 AC_TRY_RUN([#include <math.h>
 571              int main (void) { return (log(1) != log(1.)); }],
 572      AC_MSG_RESULT(none needed),
 573      gtk_save_CFLAGS="$CFLAGS"
 574      CFLAGS="$CFLAGS -std1"
 575      AC_TRY_RUN([#include <math.h>
 576                  int main (void) { return (log(1) != log(1.)); }],
 577          AC_MSG_RESULT(-std1),
 578          AC_MSG_RESULT()
 579          CFLAGS="$gtk_save_CFLAGS"
 580          AC_MSG_WARN(
 581                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 582          true
 583      ),
 584      AC_MSG_RESULT(none needed)
 585 )
 586 LIBS=$gtk_save_LIBS
 587
 588 AC_MSG_CHECKING(for the BeOS)
 589 case $host in
 590   *-*-beos*)
 591     AC_MSG_RESULT(yes)
 592     MATH_LIB=
 593   ;;
 594   *)
 595     AC_MSG_RESULT(no)
 596   ;;
 597 esac
 598
 599 AC_SUBST(MATH_LIB)
 600 #
 601 # see bug 162979
 602 #
 603 AC_MSG_CHECKING(for HP-UX)
 604 case $host_os in
 605   hpux9* | hpux10* | hpux11*)
 606     AC_MSG_RESULT(yes)
 607     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 608   ;;
 609   *)
 610     AC_MSG_RESULT(no)
 611   ;;
 612 esac
 613
 614 dnl NeXTStep cc seems to need this
 615 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 616 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 617   AC_MSG_RESULT(none needed),
 618   gtk_save_CFLAGS="$CFLAGS"
 619   CFLAGS="$CFLAGS -posix"
 620   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 621     AC_MSG_RESULT(-posix),
 622     AC_MSG_RESULT()
 623     CFLAGS="$gtk_save_CFLAGS"
 624     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 625
 626 #
 627 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 628 #
 629
 630 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 631
 632 AM_PATH_GLIB_2_0(glib_required_version, :,
 633   AC_MSG_ERROR([
 634 *** GLIB glib_required_version or better is required. The latest version of
 635 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 636   gobject gmodule-no-export gthread)
 637
 638 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 639 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 640 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 641 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 642   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 643 fi
 644
 645 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 646
 647
 648 dnl
 649 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 650 dnl
 651 gtk_save_LIBS=$LIBS
 652 LIBS="$LIBS $GLIB_LIBS"
 653 AC_CHECK_FUNCS(bind_textdomain_codeset)
 654 LIBS=$gtk_save_LIBS
 655
 656 AC_CHECK_HEADERS(pwd.h,
 657                  AC_DEFINE(HAVE_PWD_H, 1,
 658                            [Define to 1 if pwd.h is available]))
 659 AC_CHECK_HEADERS(sys/time.h,
 660                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 661                            [Define to 1 if time.h is available]))
 662 AC_CHECK_HEADERS(unistd.h,
 663                  AC_DEFINE(HAVE_UNISTD_H, 1,
 664                            [Define to 1 if unistd.h is available]))
 665 AC_CHECK_HEADERS(ftw.h,
 666                  AC_DEFINE(HAVE_FTW_H, 1,
 667                            [Define to 1 if ftw.h is available]))
 668
 669 AC_MSG_CHECKING([for GNU ftw extensions])
 670 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 671 #define _GNU_SOURCE
 672 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 673 if test $gtk_ok = yes; then
 674     AC_MSG_RESULT([yes])
 675     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 676 else
 677     AC_MSG_RESULT([no])
 678 fi
 679
 680 saved_cflags="$CFLAGS"
 681 saved_ldflags="$LDFLAGS"
 682
 683
 684 # Checks for header files.
 685 AC_HEADER_STDC
 686
 687 # Checks for typedefs, structures, and compiler characteristics.
 688 AC_C_CONST
 689
 690 # Checks for library functions.
 691 AC_TYPE_SIGNAL
 692 AC_FUNC_MMAP
 693
 694 AC_CHECK_FUNCS(mallinfo)
 695 AC_CHECK_FUNCS(getresuid)
 696 AC_TYPE_UID_T
 697
 698 # Check if <sys/select.h> needs to be included for fd_set
 699 AC_MSG_CHECKING([for fd_set])
 700 AC_TRY_COMPILE([#include <sys/types.h>],
 701         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 702 if test $gtk_ok = yes; then
 703     AC_MSG_RESULT([yes, found in sys/types.h])
 704 else
 705     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 706     if test $gtk_ok = yes; then
 707         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 708                   [Define to 1 if sys/select.h is available])
 709         AC_MSG_RESULT([yes, found in sys/select.h])
 710     else
 711         AC_DEFINE(NO_FD_SET, 1,
 712                   [Define to 1 if fd_set is not available])
 713         AC_MSG_RESULT(no)
 714     fi
 715 fi
 716
 717 # Check for uxtheme.h (for MS-Windows Engine)
 718 AC_MSG_CHECKING(for uxtheme.h)
 719 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 720 if test $gtk_uxtheme_h = yes; then
 721    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 722 fi
 723 AC_MSG_RESULT($gtk_uxtheme_h)
 724
 725 # Checks for gdkspawn
 726 AC_CHECK_HEADERS(crt_externs.h)
 727 AC_CHECK_FUNCS(_NSGetEnviron)
 728
 729 AC_MSG_CHECKING(whether to build dynamic modules)
 730
 731 AC_ARG_ENABLE(modules,
 732               [AC_HELP_STRING([--disable-modules],
 733                               [disable dynamic module loading])])
 734
 735 dynworks=false
 736 build_dynamic_modules=no
 737 deps=
 738 if test x$enable_modules = xno; then
 739     AC_MSG_RESULT(no)
 740 else
 741     AC_MSG_RESULT(yes)
 742     AC_MSG_CHECKING(whether dynamic modules work)
 743     ## for loop is to strip newline
 744     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 745     for I in $tmp; do
 746         dynworks=$I
 747     done
 748
 749     dnl Now we check to see if our libtool supports shared lib deps
 750     dnl (in a rather ugly way even)
 751     if $dynworks; then
 752         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 753         module_deplibs_check=`$module_libtool_config | \
 754             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 755             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 756         if test "x$module_deplibs_check" = "xnone" || \
 757            test "x$module_deplibs_check" = "xunknown" || \
 758            test "x$module_deplibs_check" = "x"; then
 759             dynworks=false
 760         fi
 761     fi
 762
 763     if $dynworks; then
 764         build_dynamic_modules=yes
 765         AC_DEFINE(USE_GMODULE, 1,
 766                   [Define to 1 if gmodule works and should be used])
 767         AC_MSG_RESULT(yes)
 768     else
 769         build_dynamic_modules=no
 770         AC_MSG_RESULT(no)
 771     fi
 772 fi
 773
 774 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 775
 776 #
 777 # Allow building some or all immodules included
 778 #
 779 AC_MSG_CHECKING(immodules to build)
 780
 781 dnl due to an autoconf bug, commas in the first arg to
 782 dnl AC_HELP_STRING cause problems.
 783 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
 784 dnl                [build the specified input method modules into gtk])
 785 AC_ARG_WITH(included_immodules,
 786             AC_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 787                            [build the specified input methods into gtk]))
 788
 789 if $dynworks; then
 790    :
 791 else
 792    ## if the option was specified, leave it; otherwise disable included immodules
 793    if test x$with_included_immodules = xno; then
 794            with_included_immodules=yes
 795    fi
 796 fi
 797
 798 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 799
 800 included_immodules=""
 801 # If the switch specified without listing any specific ones, include all
 802 if test "x$with_included_immodules" = xyes ; then
 803   included_immodules="$all_immodules"
 804 else
 805   included_immodules="$with_included_immodules"
 806 fi
 807
 808 AC_MSG_RESULT($included_immodules)
 809 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 810
 811 INCLUDED_IMMODULE_OBJ=
 812 INCLUDED_IMMODULE_DEFINE=
 813
 814 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 815 for immodule in $included_immodules; do
 816  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 817  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 818    :
 819  else
 820    AC_MSG_ERROR([the specified input method $immodule does not exist])
 821  fi
 822
 823  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 824  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 825  eval INCLUDE_$immodule_underscores=yes
 826 done
 827 IFS="$gtk_save_ifs"
 828 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 829 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 830
 831 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 832 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 833 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 834 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 835 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 836 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 837 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 838 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 839 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 840 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 841 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 842 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 843
 844 AC_HEADER_SYS_WAIT
 845
 846 AC_TYPE_SIGNAL
 847
 848 # Checks to see whether we should include mediaLib
 849 # support.
 850 #
 851 AC_CHECK_HEADER(sys/systeminfo.h,
 852                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 853                           [Define to 1 if sys/systeminfo.h is available]))
 854 AC_CHECK_HEADER(sys/sysinfo.h,
 855                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 856                           [Define to 1 if sys/sysinfo.h is available]))
 857
 858 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 859
 860 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 861
 862 if test $cross_compiling = yes; then
 863   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 864   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 865     REBUILD_PNGS=#
 866   fi
 867 fi
 868
 869 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 870
 871 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 872    test "x$REBUILD_PNGS" = "x#" ; then
 873      AC_MSG_ERROR([
 874 *** gtkbuiltincache.h is not in the tree, and cannot be built
 875 *** because you don't have libpng, or (when cross-compiling) you
 876 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 877 fi
 878
 879 ########################################
 880 # Windowing system checks
 881 ########################################
 882
 883 # GTK+ uses some X calls, so needs to link against X directly
 884 GTK_DEP_PACKAGES_FOR_X=
 885 GTK_DEP_LIBS_FOR_X=
 886 X_EXTENSIONS=
 887
 888 if test "x$enable_x11_backend" == xyes; then
 889   X_PACKAGES=fontconfig
 890
 891   #
 892   # We use fontconfig very peripherally when decoding the default
 893   # settings.
 894   #
 895   if $PKG_CONFIG --exists fontconfig; then : ; else
 896     AC_MSG_ERROR([
 897 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 898   fi
 899
 900   #
 901   # Check for basic X packages; we use pkg-config if available
 902   #
 903   if $PKG_CONFIG --exists x11 xext; then
 904     have_base_x_pc=true
 905     X_PACKAGES="$X_PACKAGES x11 xext"
 906     x_libs="`$PKG_CONFIG --libs x11 xext`"
 907     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 908
 909     # Strip out any .la files that pkg-config might give us (this happens
 910     # with -uninstalled.pc files)
 911     x_libs_for_checks=
 912     for I in $x_libs ; do
 913       case $I in
 914         *.la) ;;
 915         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 916       esac
 917     done
 918
 919     GTK_PACKAGES_FOR_X="x11"
 920   else
 921     have_base_x_pc=false
 922     AC_PATH_XTRA
 923     if test x$no_x = xyes ; then
 924       AC_MSG_ERROR([X development libraries not found])
 925     fi
 926
 927     x_cflags="$X_CFLAGS"
 928     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 929
 930     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 931   fi
 932
 933   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 934   x_extra_libs=
 935
 936   gtk_save_cppflags="$CPPFLAGS"
 937   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 938
 939   gtk_save_LIBS=$LIBS
 940   LIBS="$x_libs_for_checks $LIBS"
 941
 942   # Sanity check for the X11 and Xext libraries. While everything we need from
 943   # Xext is optional, the chances a system has *none* of these things is so
 944   # small that we just unconditionally require it.
 945   AC_CHECK_FUNC(XOpenDisplay, :,
 946                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 947   AC_CHECK_FUNC(XextFindDisplay, :,
 948                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 949
 950   # Check for xReply
 951
 952   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 953   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
 954       [xReply *rep;],
 955       [AC_MSG_RESULT([no])],
 956       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
 957 #include <X11/Xlibint.h>],
 958            [xReply *rep;],
 959            [AC_MSG_RESULT([yes])
 960             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
 961                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
 962            [AC_MSG_RESULT([unknown])
 963             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 964
 965   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 966
 967   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 968
 969   # Generic X11R6 check needed for XIM support; we could
 970   # probably use this to replace the above, but we'll
 971   # leave the separate checks for XConvertCase and XInternAtoms
 972   # for clarity
 973
 974   have_x11r6=false
 975   AC_CHECK_FUNC(XAddConnectionWatch,
 976       have_x11r6=true)
 977
 978   if $have_x11r6; then
 979     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
 980   fi
 981   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
 982
 983   # Check for XKB support.
 984
 985   if test "x$enable_xkb" = "xyes"; then
 986         AC_CHECK_FUNC(XkbQueryExtension,
 987                       X_EXTENSIONS="$X_EXTENSIONS XKB"
 988                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
 989                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
 990   elif test "x$enable_xkb" = "xmaybe"; then
 991         AC_CHECK_FUNC(XkbQueryExtension,
 992                       X_EXTENSIONS="$X_EXTENSIONS XKB"
 993                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
 994   else
 995         AC_MSG_WARN(XKB support explicitly disabled)
 996   fi
 997
 998   # Check for shaped window extension
 999
1000   AC_CHECK_FUNC(XShapeCombineMask, :,
1001      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1002
1003   # X SYNC check
1004   gtk_save_CFLAGS="$CFLAGS"
1005   CFLAGS="$CFLAGS $x_cflags"
1006
1007   AC_CHECK_FUNC(XSyncQueryExtension,
1008       [AC_CHECK_HEADER(X11/extensions/sync.h,
1009           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1010           :, [#include <X11/Xlib.h>])])
1011
1012   CFLAGS="$gtk_save_CFLAGS"
1013
1014   if test "x$enable_xinerama" != "xno"; then
1015     # Check for Xinerama extension (Solaris impl or Xfree impl)
1016     have_xfree_xinerama=false
1017     have_solaris_xinerama=false
1018
1019     gtk_save_cppflags="$CPPFLAGS"
1020     CPPFLAGS="$CPPFLAGS $x_cflags"
1021
1022     # Check for XFree
1023     AC_MSG_CHECKING(for Xinerama packages)
1024
1025     if $PKG_CONFIG --exists xinerama ; then
1026        AC_MSG_RESULT(yes)
1027        have_xfree_xinerama=true
1028        X_PACKAGES="$X_PACKAGES xinerama"
1029     else
1030        AC_MSG_RESULT(no)
1031        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1032            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1033            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1034            have_xfree_xinerama=true], :,
1035            [#include <X11/Xlib.h>])])
1036     fi
1037
1038     if $have_xfree_xinerama ; then
1039       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1040       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1041                 [Define to 1 if XFree Xinerama is available])
1042       AC_DEFINE(HAVE_XINERAMA, 1,
1043                 [Define to 1 is Xinerama is available])
1044     else
1045       case "$host" in
1046         *-*-solaris*)
1047             # Check for solaris
1048             AC_MSG_CHECKING(for Xinerama support on Solaris)
1049
1050             have_solaris_xinerama=false
1051             AC_CHECK_FUNC(XineramaGetInfo,
1052                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1053                     [have_solaris_xinerama=true], :,
1054                     [#include <X11/Xlib.h>])])
1055
1056             if $have_solaris_xinerama ; then
1057               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1058               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1059                         [Define to 1 if solaris xinerama is available])
1060               AC_DEFINE(HAVE_XINERAMA, 1,
1061                         [Define to 1 if xinerama is available])
1062               AC_MSG_RESULT(yes)
1063             else
1064               AC_MSG_RESULT(no)
1065             fi
1066             ;;
1067         *)
1068             ;;
1069       esac
1070     fi
1071   fi
1072   if test "x$enable_xinerama" = "xyes" ; then
1073     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1074       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1075     fi
1076   fi
1077
1078   # set up things for XInput
1079   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1080     have_xinput=yes
1081
1082     AC_DEFINE(XINPUT_XFREE, 1,
1083               [Define to 1 if XFree XInput should be used])
1084
1085     X_PACKAGES="$X_PACKAGES xi"
1086
1087     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1088                     have_xinput2=yes
1089                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1090                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]),
1091                     X_EXTENSIONS="$X_EXTENSIONS XInput")
1092
1093   else
1094     AC_DEFINE(XINPUT_NONE, 1,
1095               [Define to 1 if no XInput should be used])
1096   fi
1097
1098   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1099   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1100
1101   if test "x$enable_xinput" = "xyes" ; then
1102     if test "x$have_xinput" != "xyes" -a "x$have_xinput2" != "xyes" ; then
1103       AC_MSG_ERROR([*** XInput extension not found. Check 'config.log' for more details.])
1104     fi
1105   fi
1106
1107   # Check for the RANDR extension
1108   if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1109      AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1110
1111      X_PACKAGES="$X_PACKAGES xrandr"
1112      X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1113   fi
1114
1115   # Checks for Xcursor library
1116
1117   if $PKG_CONFIG --exists xcursor ; then
1118     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1119
1120     X_PACKAGES="$X_PACKAGES xcursor"
1121   fi
1122
1123   # Checks for XFixes extension
1124
1125   if $PKG_CONFIG --exists xfixes ; then
1126     AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1127
1128     X_PACKAGES="$X_PACKAGES xfixes"
1129     X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1130     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1131   fi
1132
1133   # Checks for Xcomposite extension
1134
1135   if $PKG_CONFIG --exists xcomposite ; then
1136     AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1137
1138     X_PACKAGES="$X_PACKAGES xcomposite"
1139     X_EXTENSIONS="$X_EXTENSIONS Composite"
1140     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1141   fi
1142
1143   # Checks for Xdamage extension
1144
1145   if $PKG_CONFIG --exists xdamage ; then
1146     AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1147
1148     X_PACKAGES="$X_PACKAGES xdamage"
1149     X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1150     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1151   fi
1152
1153   if $have_base_x_pc ; then
1154     GDK_EXTRA_LIBS="$x_extra_libs"
1155   else
1156     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1157   fi
1158
1159   CPPFLAGS="$gtk_save_cppflags"
1160   LIBS="$gtk_save_libs"
1161
1162   AM_CONDITIONAL(USE_X11, true)
1163
1164   # strip leading space
1165   X_EXTENSIONS=${X_EXTENSIONS/# }
1166
1167 else
1168   XPACKAGES=
1169
1170   AM_CONDITIONAL(XINPUT_XFREE, false)
1171   AM_CONDITIONAL(XINPUT_2, false)
1172   AM_CONDITIONAL(USE_X11, false)
1173   AM_CONDITIONAL(HAVE_X11R6, false)
1174 fi
1175
1176 # Check for Pango flags
1177
1178 AC_MSG_CHECKING(Pango flags)
1179 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1180         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1181         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1182
1183         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1184 else
1185         AC_MSG_ERROR([
1186 *** Pango not found. Pango built with Cairo support is required
1187 *** to build GTK+. See http://www.pango.org for Pango information.
1188 ])
1189 fi
1190
1191 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1192
1193 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1194         :
1195 else
1196         gtk_save_LIBS="$LIBS"
1197         LIBS="$PANGO_LIBS $LIBS"
1198         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1199 *** Can't link to Pango. Pango is required to build
1200 *** GTK+. For more information see http://www.pango.org]))
1201         LIBS="$gtk_save_LIBS"
1202 fi
1203
1204 CFLAGS="$saved_cflags"
1205 LDFLAGS="$saved_ldflags"
1206
1207 GDK_PACKAGES="$PANGO_PACKAGES $GIO_PACKAGE $X_PACKAGES gdk-pixbuf-2.0 $cairo_backends cairo-gobject"
1208
1209 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1210 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1211 #
1212 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1213 # into the pkg-config files
1214 #
1215 if test $enable_explicit_deps != yes ; then
1216   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo-gobject"
1217   GDK_EXTRA_LIBS=
1218 fi
1219
1220 AC_SUBST(GDK_PACKAGES)
1221 AC_SUBST(GDK_EXTRA_LIBS)
1222 AC_SUBST(GDK_EXTRA_CFLAGS)
1223 AC_SUBST(GDK_DEP_LIBS)
1224 AC_SUBST(GDK_DEP_CFLAGS)
1225
1226
1227 ########################################
1228 # Check for Accessibility Toolkit flags
1229 ########################################
1230
1231 ATK_PACKAGES=atk
1232 AC_MSG_CHECKING(ATK flags)
1233 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1234         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1235         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1236
1237         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1238 else
1239         AC_MSG_ERROR([
1240 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1241 *** to build GTK+.
1242 ])
1243 fi
1244
1245 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1246         :
1247 else
1248         gtk_save_LIBS="$LIBS"
1249         LIBS="$ATK_LIBS $LIBS"
1250         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1251                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1252                 *** to build GTK+]))
1253         LIBS="$gtk_save_LIBS"
1254 fi
1255
1256 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1257 if test "x$enable_x11_backend" == xyes; then
1258   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1259 fi
1260 GTK_EXTRA_LIBS=
1261 GTK_EXTRA_CFLAGS=
1262 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1263 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1264
1265 if test x"$os_win32" = xyes; then
1266   GTK_EXTRA_CFLAGS="$msnative_struct"
1267 fi
1268
1269 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1270 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1271 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1272 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1273
1274 AC_SUBST(GTK_PACKAGES)
1275 AC_SUBST(GTK_EXTRA_LIBS)
1276 AC_SUBST(GTK_EXTRA_CFLAGS)
1277 AC_SUBST(GTK_DEP_LIBS)
1278 AC_SUBST(GTK_DEP_CFLAGS)
1279
1280 AC_SUBST(GLIB_PREFIX)
1281 AC_SUBST(ATK_PREFIX)
1282 AC_SUBST(PANGO_PREFIX)
1283 AC_SUBST(CAIRO_PREFIX)
1284
1285 AC_SUBST(GTK_DEBUG_FLAGS)
1286 AC_SUBST(GTK_XIM_FLAGS)
1287
1288 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1289 AC_SUBST(GDK_PIXBUF_LIBS)
1290
1291 ########################
1292 # Checks needed for gail
1293 ########################
1294
1295 old_LIBS="$LIBS"
1296 dnl Checks for inet libraries:
1297 AC_SEARCH_LIBS(gethostent, nsl)
1298 AC_SEARCH_LIBS(setsockopt, socket)
1299 AC_SEARCH_LIBS(connect, inet)
1300
1301 dnl check for the sockaddr_un.sun_len member
1302 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1303                 [struct_sockaddr_un_sun_len=true],
1304                 [struct_sockaddr_un_suin_len=false],
1305                 [#include <sys/types.h>
1306                  #include <sys/un.h>]
1307                 )
1308 case $struct_sockaddr_un_sun_len in
1309         true)
1310                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1311                                    [Have the sockaddr_un.sun_len member])
1312                 ;;
1313         *)
1314                 ;;
1315 esac
1316
1317 GAIL_INET_LIBS="$LIBS"
1318 AC_SUBST([GAIL_INET_LIBS])
1319
1320 LIBS="$old_LIBS"
1321
1322 ################################################################
1323 # Printing system checks
1324 ################################################################
1325
1326 PRINT_BACKENDS="file lpr"
1327
1328 AC_ARG_ENABLE(cups,
1329               [AC_HELP_STRING([--disable-cups],
1330                               [disable cups print backend])],,
1331               [enable_cups=auto])
1332
1333 if test "x$enable_cups" = "xno"; then
1334   AM_CONDITIONAL(HAVE_CUPS, false)
1335 else
1336   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1337   if test "x$CUPS_CONFIG" = "xno"; then
1338     if test "x$enable_cups" = "xauto"; then
1339       AM_CONDITIONAL(HAVE_CUPS, false)
1340     else
1341       AC_MSG_ERROR([
1342 *** cups not found.
1343 ])
1344     fi
1345   else
1346     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1347     CUPS_LIBS=`$CUPS_CONFIG --libs`
1348
1349     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1350     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1351     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1352
1353     if test $CUPS_API_MAJOR -gt 1 -o \
1354             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1355       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1356                 [Define to 1 if CUPS 1.2 API is available])
1357     fi
1358
1359     AC_SUBST(CUPS_API_MAJOR)
1360     AC_SUBST(CUPS_API_MINOR)
1361     AC_SUBST(CUPS_CFLAGS)
1362     AC_SUBST(CUPS_LIBS)
1363
1364     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1365
1366     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1367     AM_CONDITIONAL(HAVE_CUPS, true)
1368
1369     gtk_save_cflags="$CFLAGS"
1370     CFLAGS="$CUPS_CFLAGS"
1371     AC_TRY_COMPILE([#include <cups/http.h>],
1372                    [http_t http; char *s = http.authstring;],
1373                    [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1374                               [Define if cups http_t authstring field is accessible])],)
1375     CFLAGS="$gtk_save_cflags"
1376
1377     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1378
1379     gtk_save_libs="$LIBS"
1380     LIBS="$CUPS_LIBS"
1381     AC_CHECK_FUNCS(httpGetAuthString)
1382     LIBS="$gtk_save_libs"
1383   fi
1384 fi
1385
1386 # Checks to see if we should compile with PAPI backend for GTK+
1387 #
1388
1389 AC_ARG_ENABLE(papi,
1390               [AC_HELP_STRING([--disable-papi],
1391                               [disable papi print backend])],,
1392              [enable_papi=auto])
1393
1394 if test "x$enable_papi" = "xno"; then
1395   AM_CONDITIONAL(HAVE_PAPI, false)
1396 else
1397   AC_MSG_CHECKING(libpapi)
1398   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1399   if test $have_papi = yes; then
1400     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1401     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1402   fi
1403   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1404   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1405     AC_MSG_ERROR([
1406 *** papi not found.
1407 ])
1408   fi
1409 fi
1410
1411 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1412
1413 gtk_save_cppflags="$CPPFLAGS"
1414 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1415
1416 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1417 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1418 *** backend enabled.]))
1419
1420 if test "$os_win32" != "yes"; then
1421   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1422 *** Can't find cairo-ps.h. You must build Cairo with the
1423 *** postscript backend enabled.]))
1424
1425   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1426 *** Cannot find cairo-svg.h. You must build Cairo with the
1427 *** svg backend enabled.]))
1428 fi
1429
1430 CPPFLAGS="$gtk_save_cppflags"
1431
1432
1433 AC_ARG_ENABLE(test-print-backend,
1434               [AC_HELP_STRING([--enable-test-print-backend],
1435                               [build test print backend])],,
1436               [enable_test_print_backend=no])
1437 if test "x$enable_test_print_backend" != "xno" ; then
1438   PRINT_BACKENDS="$PRINT_BACKENDS test"
1439 fi
1440 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1441
1442
1443 ################################################################
1444 # Strip -export-dynamic from the link lines of various libraries
1445 ################################################################
1446
1447 #
1448 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1449 #  but this flag is only meaningful for executables. For libraries
1450 #  the effect is undefined; what it causes on Linux is that the
1451 #  export list from -export-symbols-regex is ignored and everything
1452 #  is exported
1453 #
1454 # We are using gmodule-no-export now, but I'm leaving the stripping
1455 # code in place for now, since pango and atk still require gmodule.
1456 export SED
1457 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1458 if test -n "$export_dynamic"; then
1459   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1460   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1461 fi
1462
1463 #############
1464 # GSettings #
1465 #############
1466
1467 GLIB_GSETTINGS
1468
1469 ##################################################
1470 # GObject introspection
1471 ##################################################
1472
1473 GOBJECT_INTROSPECTION_CHECK([0.9.3])
1474
1475 ##################################################
1476 # Packagekit module
1477 #################################################
1478
1479 AC_ARG_ENABLE(packagekit,
1480               AC_HELP_STRING([--disable-packagekit],
1481                              [build packagekit open-with module]))
1482
1483 build_packagekit=no
1484 if test "os_win32" != "yes"; then
1485         if test "x$enable_packagekit" != "xno"; then
1486                 build_packagekit=yes
1487                 AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1488         fi
1489 fi
1490
1491 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1492
1493 ##################################################
1494 # Checks for gtk-doc and docbook-tools
1495 ##################################################
1496
1497 GTK_DOC_CHECK([1.11])
1498
1499 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1500 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1501
1502 AC_ARG_ENABLE(man,
1503               [AC_HELP_STRING([--enable-man],
1504                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1505               enable_man=no)
1506
1507 if test "${enable_man}" != no; then
1508   dnl
1509   dnl Check for xsltproc
1510   dnl
1511   AC_PATH_PROG([XSLTPROC], [xsltproc])
1512   if test -z "$XSLTPROC"; then
1513     enable_man=no
1514   fi
1515
1516   dnl check for DocBook DTD and stylesheets in the local catalog.
1517   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1518      [DocBook XML DTD V4.1.2],,enable_man=no)
1519   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1520      [DocBook XSL Stylesheets],,enable_man=no)
1521 fi
1522
1523 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1524
1525
1526 ##################################################
1527 # Output commands
1528 ##################################################
1529
1530 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1531         outfile=gdkconfig.h-tmp
1532         cat > $outfile <<\_______EOF
1533 /* gdkconfig.h
1534  *
1535  * This is a generated file.  Please modify `configure.ac'
1536  */
1537
1538 #ifndef __GDKCONFIG_H__
1539 #define __GDKCONFIG_H__
1540
1541 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1542 #error "Only <gdk/gdk.h> can be included directly."
1543 #endif
1544
1545 #include <glib.h>
1546
1547 G_BEGIN_DECLS
1548
1549 _______EOF
1550
1551         cat >>$outfile <<_______EOF
1552 $gdk_windowing
1553 _______EOF
1554
1555         cat >>$outfile <<_______EOF
1556
1557 G_END_DECLS
1558
1559 #endif  /* __GDKCONFIG_H__ */
1560 _______EOF
1561
1562
1563         if cmp -s $outfile gdk/gdkconfig.h; then
1564           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1565           rm -f $outfile
1566         else
1567           mv $outfile gdk/gdkconfig.h
1568         fi
1569 ],[
1570 gdk_windowing='$GDK_WINDOWING'
1571 ])
1572
1573 dnl
1574 dnl Check for -Bsymbolic-functions linker flag used to avoid
1575 dnl intra-library PLT jumps, if available.
1576 dnl
1577 AC_ARG_ENABLE(Bsymbolic,
1578               [AC_HELP_STRING([--disable-Bsymbolic],
1579                               [avoid linking with -Bsymbolic])],,
1580               [SAVED_LDFLAGS="${LDFLAGS}"
1581                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1582                LDFLAGS=-Wl,-Bsymbolic-functions
1583                AC_TRY_LINK([], [int main (void) { return 0; }],
1584                            AC_MSG_RESULT(yes)
1585                            enable_Bsymbolic=yes,
1586                            AC_MSG_RESULT(no)
1587                            enable_Bsymbolic=no)
1588                LDFLAGS="${SAVED_LDFLAGS}"])
1589
1590 if test "x${enable_Bsymbolic}" = "xyes" ; then
1591   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1592 fi
1593 AC_SUBST(GTK_LINK_FLAGS)
1594
1595 AC_CONFIG_FILES([
1596 config.h.win32
1597 gtk-zip.sh
1598 Makefile
1599 gdk-3.0.pc
1600 gtk+-3.0.pc
1601 gtk+-unix-print-3.0.pc
1602 gail-3.0.pc
1603 gtk+-3.0-uninstalled.pc
1604 gail-3.0-uninstalled.pc
1605 m4macros/Makefile
1606 po/Makefile.in
1607 po-properties/Makefile.in
1608 demos/Makefile
1609 demos/gtk-demo/Makefile
1610 demos/gtk-demo/geninclude.pl
1611 examples/Makefile
1612 tests/Makefile
1613 docs/Makefile
1614 docs/reference/Makefile
1615 docs/reference/gdk/Makefile
1616 docs/reference/gdk/version.xml
1617 docs/reference/gtk/Makefile
1618 docs/reference/gtk/version.xml
1619 docs/reference/libgail-util/Makefile
1620 docs/reference/libgail-util/version.xml
1621 docs/tools/Makefile
1622 build/Makefile
1623 build/win32/Makefile
1624 build/win32/vs9/Makefile
1625 gdk/Makefile
1626 gdk/x11/Makefile
1627 gdk/win32/Makefile
1628 gdk/win32/rc/Makefile
1629 gdk/win32/rc/gdk.rc
1630 gdk/quartz/Makefile
1631 gdk/tests/Makefile
1632 gtk/Makefile
1633 gtk/makefile.msc
1634 gtk/gtkversion.h
1635 gtk/gtk-win32.rc
1636 gtk/theme-bits/Makefile
1637 gtk/tests/Makefile
1638 modules/Makefile
1639 modules/other/Makefile
1640 modules/other/gail/Makefile
1641 modules/other/gail/libgail-util/Makefile
1642 modules/other/gail/tests/Makefile
1643 modules/engines/Makefile
1644 modules/engines/pixbuf/Makefile
1645 modules/engines/ms-windows/Makefile
1646 modules/engines/ms-windows/Theme/Makefile
1647 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1648 modules/input/Makefile
1649 modules/printbackends/Makefile
1650 modules/printbackends/cups/Makefile
1651 modules/printbackends/lpr/Makefile
1652 modules/printbackends/file/Makefile
1653 modules/printbackends/papi/Makefile
1654 modules/printbackends/test/Makefile
1655 perf/Makefile
1656 ])
1657
1658 AC_OUTPUT
1659
1660 # beautify the immodule list a bit
1661 included_immodules=${included_immodules//,/ }
1662 included_immodules=${included_immodules:-none}
1663
1664 echo "configuration:"
1665 echo "        GDK backends:         $GDK_BACKENDS"
1666 if test "x$enable_x11_backend" = "xyes"; then
1667 echo "        X11 extensions:       $X_EXTENSIONS"
1668 fi
1669 echo "        Print backends:       $PRINT_BACKENDS"
1670 echo "        Dynamic modules:      $build_dynamic_modules"
1671 echo "        Included immodules:   $included_immodules"
1672 echo "        PackageKit support:   $build_packagekit"
1673 echo "        Introspection:        $found_introspection"
1674 echo "        Debugging:            $enable_debug"
1675 echo "        Documentation:        $enable_gtk_doc"