Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 dnl Eric S. Raymond <esr@thyrsus.com>
   3 dnl Matthias Andree <matthias.andree@gmx.de>
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6 dnl
   7
   8 AC_INIT([fetchmail],[6.2.9-rc2])
   9 AC_CONFIG_SRCDIR([fetchmail.h])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_LIBOBJ_DIR([.])
  12
  13 dnl we may need a newer automake version - the oldest tested is 1.7
  14 AC_PREREQ(2.59)
  15 AM_INIT_AUTOMAKE(1.5 foreign no-installinfo)
  16
  17 dnl the : states that python is optional
  18 AM_PATH_PYTHON(2.0,,:)
  19
  20 AC_PROG_AWK
  21 AC_PROG_CC
  22 AC_PROG_INSTALL
  23 AC_PROG_CPP                     dnl Later checks need this.
  24 AC_PROG_RANLIB
  25 AM_PROG_CC_C_O
  26 AC_AIX
  27 AC_ISC_POSIX
  28 AC_MINIX
  29 AC_HEADER_STDC
  30 AC_HEADER_TIME
  31 AC_TYPE_SIZE_T
  32 AC_TYPE_PID_T
  33 AC_TYPE_SIGNAL
  34 AC_CHECK_TYPE(u_int32_t,unsigned int)
  35 AC_CHECK_HEADERS([unistd.h termios.h termio.h sgtty.h stdarg.h \
  36         sys/itimer.h fcntl.h sys/fcntl.h memory.h sys/wait.h \
  37         arpa/inet.h arpa/nameser.h netinet/in.h net/socket.h \
  38         sys/select.h sys/socket.h sys/time.h langinfo.h])
  39 AC_CHECK_HEADERS([resolv.h],,,[
  40 #include <sys/types.h>
  41 #ifdef HAVE_NETINET_IN_H
  42 #include <netinet/in.h>
  43 #endif
  44 #ifdef HAVE_ARPA_NAMESER_H
  45 #include <arpa/nameser.h>
  46 #endif
  47 ])
  48
  49 AC_C_CONST                      dnl getopt needs this.
  50
  51 AM_PROG_LEX
  52 AC_PROG_MAKE_SET
  53 AC_PROG_YACC
  54
  55 # Check for LynxOS special case: -lbsd needed (at least on 2.3.0) and -s
  56 # not working.
  57 if test `uname` = "LynxOS"
  58 then
  59   echo "Adding -lbsd to standard libraries"
  60   LIBS="$LIBS -lbsd"
  61   LDFLAGS=""
  62   echo "Prepending standard include path to gcc flags"
  63   CPFLAGS="-I/usr/include"
  64 fi
  65
  66 # Check for FreeBSD special case: more libs needed
  67 if test `uname` = "FreeBSD"
  68 then
  69    echo "Adding -lmd -lkvm -lcom_err to standard libraries"
  70    LIBS="$LIBS -lmd -lkvm -lcom_err"
  71 fi
  72
  73 # Check for Rhapsody special case: it doesn't like -s
  74 if test `uname` = "Rhapsody"
  75 then
  76    echo "Removing -s load flag"
  77    LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
  78 fi
  79
  80 dnl i18n
  81 AM_GNU_GETTEXT([external], [need-ngettext])
  82 AM_GNU_GETTEXT_VERSION(0.14.1)
  83 dnl end i18n
  84
  85 # Under sysV68, socket and friends are provided by the C library.
  86 # -linet does not provide socket, but causes multiple definition
  87 # errors at link-time.  It is thus better to only use the C library.
  88 # So don't add -linet to the link list unless it's necessary
  89 AC_CHECK_FUNC(socket,
  90     AC_MSG_RESULT(using libc's socket),
  91     AC_CHECK_LIB(socket,socket)
  92     AC_CHECK_LIB(inet,socket))
  93
  94 # The condition in this test copes with the presence of inet_addr in libc6.
  95 AC_CHECK_FUNC(inet_addr,
  96     AC_MSG_RESULT(using libc's inet_addr),
  97     AC_CHECK_LIB(nsl,inet_addr))
  98
  99 dnl Port hack for Interactive UNIX System V/386 Release 3.2
 100 AC_CHECK_LIB(cposix, strchr,
 101                 [DEFS="$DEFS -D_SYSV3"
 102                 LIBS="$LIBS -lcposix"])
 103
 104 dnl Port hack for Sparc/NetBSD-1.5
 105 AC_CHECK_LIB(intl, gettext,
 106                 [LIBS="$LIBS -lintl"])
 107
 108 AC_REPLACE_FUNCS([strstr strcasecmp memmove stpcpy strlcpy strlcat])
 109
 110 AC_CHECK_FUNC(MD5Init, [],
 111               [AC_LIBSOURCE(md5c.c)
 112                EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"])
 113
 114 AC_CHECK_FUNC(getopt_long, [],
 115               [AC_LIBSOURCES([getopt.c, getopt1.c])
 116                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 117
 118 AC_FUNC_VPRINTF
 119
 120 AC_SUBST(EXTRAOBJ)
 121
 122 AC_CHECK_FUNCS(tcsetattr stty setsid geteuid seteuid dnl
 123   res_search strerror syslog snprintf vprintf vsnprintf vsyslog dnl
 124   atexit inet_aton strftime setrlimit socketpair sigprocmask dnl
 125   sigaction strdup setlocale)
 126
 127 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 128 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 129 # library.  So don't add -lresolv to the link list unless it's necessary
 130 # (It will be necessary when using GNU libc6).
 131 AC_CHECK_FUNC(res_search,
 132     AC_MSG_RESULT(using libc's resolver functions),
 133     AC_CHECK_LIB(resolv,res_search,
 134         [AC_DEFINE(HAVE_RES_SEARCH) AC_MSG_RESULT(found resolver functions in libresolv); LIBS="$LIBS -lresolv"], AC_MSG_RESULT(no resolver calls found)))
 135
 136 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 137 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 138
 139 dnl Check for RSA refersence library in case we're using SSL
 140 AC_CHECK_LIB(rsaref, RSAPublicDecrypt)
 141
 142 dnl AC_FUNC_SETVBUF_REVERSED
 143
 144 dnl Check for usable void pointer type
 145 AC_MSG_CHECKING(use of void pointer type)
 146 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[char *p;
 147     void *xmalloc();
 148     p = (char *) xmalloc(1);
 149    ]])],[AC_DEFINE(HAVE_VOIDPOINTER,1,[Define if your C compiler allows void * as a function result]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 150
 151 dnl Check for ANSI volatile
 152 AC_C_VOLATILE
 153
 154 dnl Check out the wait reality.  We have to assume sys/wait.h is present.
 155 AC_CHECK_FUNCS(waitpid wait3)
 156 AC_MSG_CHECKING(for union wait);
 157 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 158 #include <sys/wait.h>]], [[union wait status; int pid; pid = wait (&status);
 159 #ifdef WEXITSTATUS
 160 /* Some POSIXoid systems have both the new-style macros and the old
 161    union wait type, and they do not work together.  If union wait
 162    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 163 if (WEXITSTATUS (status) != 0) pid = -1;
 164 #endif
 165 #ifdef HAVE_WAITPID
 166 /* Make sure union wait works with waitpid.  */
 167 pid = waitpid (-1, &status, 0);
 168 #endif
 169 ]])],[AC_DEFINE(HAVE_UNION_WAIT,1,Define if 'union wait' is the type of the first arg to wait functions.) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 170
 171 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 172 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 173 /* NetBSD declares sys_siglist in <unistd.h>.  */
 174 #ifdef HAVE_UNISTD_H
 175 #include <unistd.h>
 176 #endif]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 177
 178 # Find the right directory to put the root-mode PID file in
 179 for dir in "/var/run" "/etc"
 180 do
 181         if test -d $dir
 182         then
 183                 break;
 184         fi
 185 done
 186 AC_MSG_RESULT(root-mode pid file will go in $dir)
 187 AC_DEFINE_UNQUOTED(PID_DIR, "$dir", directory for PID lock files)
 188
 189 # We may have a fallback MDA available in case the socket open to the
 190 # local SMTP listener fails.  Best to use procmail for this, as we know
 191 # it won't try delivering through local SMTP and cause a mail loop.
 192 # Sendmail without the -t option to use the message headers will work too,
 193 # not just for sendmail itself but for workalikes like exim.
 194 #
 195 # Note1: A disadvantage of using procmail is that local alias expansion
 196 # according to /etc/aliases won't get done if we fall back.  This doesn't
 197 # matter in single-drop mode.
 198 #
 199 # Note2: it would be a very bad idea to use any MDA that doesn't return
 200 # a refuse-to-deliver status on disk- or process-table-full
 201 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 202 # like exim that might be lurking under a sendmail alias) do the right
 203 # thing in this circumstance.  Matthias Andree warns that procmail does
 204 # not.
 205 #
 206 # Note3: Defalt value of fallback is now off.  Matthias writes:
 207 #
 208 # 1. there is no way to predict when the fallback is used. With some MTAs
 209 #    (such as those limiting load average), outer circumstances can cause
 210 #    the fallback to kick in.
 211 #
 212 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 213 #    not only about alias expansion, .forwards to special filters won't
 214 #    work, mail may end up in a different place (users claim "mail loss"
 215 #    for that).
 216 #
 217 # 3. The claim procmail did the right thing with its exit codes is plain
 218 #    wrong. I've seen procmail exit with code 1 when it should have exited
 219 #    with code 75, like, configuration errors. Procmail is a dangerous
 220 #    beast and is best replaced by maildrop.
 221 #
 222 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 223 #    cannot tell which one it should choose. Say, your MTA is configured
 224 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 225 #    chooses procmail, this is plain wrong.
 226 #
 227
 228 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 229 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 230 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 231
 232 ###     use option --disable-fallback to disable fallback MDA
 233 ###     use option --enable-fallback=procmail or
 234 ###                --enable-fallback=sendmail to select
 235 AC_ARG_ENABLE(fallback,
 236         [  --enable-fallback=procmail    enable procmail as fallback
 237   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 238   --enable-fallback=maildrop    enable maildrop as fallback
 239   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 240
 241 case "$enable_fallback" in
 242         sendmail)       if test -z "$sendmail" ; then
 243                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 244                                 #not reached
 245                         fi
 246                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 247                         echo "Will use $sendmail as fallback MDA."
 248                         ;;
 249         procmail)       if test -z "$procmail" ; then
 250                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 251                                 #not reached
 252                         fi
 253                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 254                         echo "Will use $procmail as fallback MDA."
 255                         ;;
 256         maildrop)       if test -z "$maildrop" ; then
 257                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 258                                 #not reached
 259                         fi
 260                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 261                         echo "Will use $maildrop as fallback MDA."
 262                         ;;
 263         no|unset)       echo "Will not use a fallback MDA"
 264                         ;;
 265         auto|yes|set)   if test -n "$sendmail" ; then
 266                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 267                                 echo "Will use $sendmail as fallback MDA."
 268                         else
 269                                 echo "No fallback MDA available. procmail and maildrop are not eligible"
 270                                 echo "for automatic fallback MDA configuration for reliability reasons."
 271                         fi
 272                         ;;
 273         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 274                         #notreached
 275                         ;;
 276 esac
 277
 278 AC_CHECK_SIZEOF(short)
 279 AC_CHECK_SIZEOF(int)
 280 AC_CHECK_SIZEOF(long)
 281
 282 ###     use option --enable-POP2 to compile in the POP2 support
 283 AC_ARG_ENABLE(POP2,
 284         [  --enable-POP2           compile in POP2 protocol support (obsolete)],
 285         [with_POP2=$enableval],
 286         [with_POP2=no])
 287 test "$with_POP2" = "yes" && AC_DEFINE(POP2_ENABLE,1,Define if you want POP2 support compiled in)
 288
 289 ###     use option --disable-POP3 to omit the POP3 support
 290 AC_ARG_ENABLE(POP3,
 291         [  --disable-POP3          don't compile in POP3 protocol support],
 292         [with_POP3=$enableval],
 293         [with_POP3=yes])
 294 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 295
 296 ###     use option --disable-IMAP to omit the IMAP support
 297 AC_ARG_ENABLE(IMAP,
 298         [  --disable-IMAP          don't compile in IMAP protocol support],
 299         [with_IMAP=$enableval],
 300         [with_IMAP=yes])
 301 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,"Define if you want IMAP support compiled in")
 302
 303 ###     use option --disable-ETRN to omit the ETRN support
 304 AC_ARG_ENABLE(ETRN,
 305         [  --disable-ETRN          don't compile in ETRN protocol support],
 306         [with_ETRN=$enableval],
 307         [with_ETRN=yes])
 308 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 309
 310 ###     use option --disable-ODMR to omit the ODMR support
 311 AC_ARG_ENABLE(ODMR,
 312         [  --disable-ODMR          don't compile in ODMR protocol support],
 313         [with_ODMR=$enableval],
 314         [with_ODMR=yes])
 315 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 316
 317 ###     use option --enable-RPA to compile in the RPA support
 318 AC_ARG_ENABLE(RPA,
 319         [  --enable-RPA            compile in RPA protocol support],
 320         [with_RPA=$enableval],
 321         [with_RPA=no])
 322 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 323
 324 ###     use option --enable-NTLM to compile in the NTLM support
 325 AC_ARG_ENABLE(NTLM,
 326         [  --enable-NTLM           compile in NTLM authentication support],
 327         [with_NTLM=$enableval],
 328         [with_NTLM=no])
 329 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 330
 331 ###     use option --enable-SDPS to compile in the SDPS support
 332 AC_ARG_ENABLE(SDPS,
 333         [  --enable-SDPS           compile in SDPS protocol support],
 334         [with_SDPS=$enableval],
 335         [with_SDPS=no])
 336 test "$with_SDPS" = "yes" && AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 337
 338 ###     use option --enable-opie to compile in the OPIE support
 339 AC_ARG_ENABLE(opie,
 340         [  --enable-opie           support OTP through the OPIE library],
 341         [ AC_CHECK_HEADER(opie.h,, [echo 'configure: cannot find <opie.h>, which is required for OPIE support.'; exit 1])
 342           AC_CHECK_LIB(opie,opiegenerator,, [echo 'configure: cannot find libopie, which is required for OPIE support.'; exit 1])
 343           with_opie=$enableval],
 344         [with_opie=no])
 345 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 346
 347 AC_SEARCH_LIBS(getaddrinfo, inet6, [AC_DEFINE(HAVE_GETADDRINFO,1,[define to 1 if you have the getaddrinfo function])])
 348 AC_CHECK_FUNCS(getnameinfo)
 349
 350 # This version of the Kerberos 4 and 5 options addresses the follwing issues:
 351 #
 352 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 353 #   OpenSSL support (Debian's is)
 354 # * Build the kerberos.c stuff (KPOP) only for kerberosIV, to avoid breakage.
 355 #   I don't know if this is 100% correct, but now at least IMAP and POP3
 356 #   behave the same way regarding kerberosV.
 357 # * Build without any fuss for both kerberosIV and V at the same time.
 358 # * Move all the kerberos header mess to kerberos.h, and #include that
 359 #   in driver.c and kerberos.c.
 360 #
 361 # Tested using the Heimdal Kerberos V libs, Kungliga Tekniska Högskolan (the
 362 # Royal Institute of Technology in Stockholm, Sweden)'s kerberos IV libs, and
 363 # the MIT reference implementation of KerberosV (all as packaged in Debian).
 364
 365 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 366 ### make sure --with-ssl is run before --with-kerberos* !
 367 AC_ARG_WITH(kerberos5,
 368        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5
 369 directory],
 370 [
 371 if test "$with_kerberos5" != "no"
 372 then
 373 # Check for a OpenBSD special case
 374 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 375 then
 376   AS_MESSAGE(checking kerberosV for OpenBSD...)
 377   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 378   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 379   CEFLAGS="$CEFLAGS -I/usr/include/kerberosV"
 380   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 381 elif krb5-config 2> /dev/null >/dev/null ; then
 382   krb5_prefix=`krb5-config --prefix krb5`
 383   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 384   if test -f ${krb5_prefix}/include/et/com_err.h && \
 385    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 386     CEFLAGS="$CEFLAGS -I${krb5_prefix}/include/et"
 387   fi
 388   unset krb5_prefix
 389   CEFLAGS="$CEFLAGS `krb5-config --cflags krb5`"
 390   LIBS="$LIBS `krb5-config --libs krb5`"
 391   AC_DEFINE(KERBEROS_V5)
 392 else
 393   if test "$with_kerberos5" != "yes"
 394   then
 395       LDEFLAGS="$LDEFLAGS -L${with_kerberos5}/lib"
 396       searchdirs="$with_kerberos5"
 397   else
 398       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 399   fi
 400   with_kerberos5=
 401   for dir in $searchdirs
 402   do AC_MSG_CHECKING([for Kerberos V in $dir])
 403      if test -f "$dir/include/krb5.h"
 404      then
 405         ac_krblibs=
 406         if test -f "$dir/include/roken.h"
 407         then
 408            ac_krblibs="-lasn1 -lroken -lcom_err"
 409            AC_MSG_RESULT([Heimdal found])
 410           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 411           dnl we assume we do if it is available
 412            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 413                 ${LDEFLAGS})
 414            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 415               AC_CHECK_LIB(ssl, MD5_Init, [],
 416                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 417                 ${LDEFLAGS} ${ac_krblibs}),
 418            ${LDEFLAGS} ${ac_krblibs})
 419            AC_DEFINE(HEIMDAL)
 420         else
 421           AC_MSG_RESULT([found])
 422           ac_krblibs="-lcom_err"
 423            AC_CHECK_LIB(crypto,
 424              krb5_des_string_to_key,
 425              libk5crypto=-lcrypto,
 426                 AC_CHECK_LIB(k5crypto,
 427                    krb5_des_string_to_key,
 428                    libk5crypto=-lk5crypto,
 429                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 430                    ${LDEFLAGS} ${ac_krblibs}),
 431                  ${LDEFLAGS} ${ac_krblibs})
 432         fi
 433         AC_CHECK_LIB(krb5, krb5_init_context,[],
 434            continue,
 435            ${LDEFLAGS} ${ac_krblibs})
 436         AC_DEFINE(KERBEROS_V5)
 437         test "$dir" != "/usr" && CEFLAGS="$CEFLAGS -I$dir/include"
 438         LDEFLAGS="$LDEFLAGS -L$dir/lib"
 439        LIBS="$LIBS $ac_krblibs $libk5crypto"
 440         with_kerberos5=$dir
 441         break
 442      else
 443         AC_MSG_RESULT([not found])
 444      fi
 445   done
 446   if test -z "$with_kerberos5" ; then
 447      AC_MSG_ERROR([Kerberos 5 libraries not found])
 448   fi
 449 fi
 450 fi
 451 ]) dnl --with-kerberos5=DIR
 452
 453 ###    use option --with-kerberos=DIR to point at a Kerberos 4 directory
 454 AC_ARG_WITH(kerberos,
 455        [  --with-kerberos=DIR     point fetchmail compilation at a Kerberos 4
 456 directory],
 457 [
 458 if test "$with_kerberos" != "no"
 459 then
 460 # Check for a NetBSD/OpenBSD special case
 461 if test "$with_kerberos" = "yes" && ( test `uname` = "NetBSD" || test `uname` = "OpenBSD" )
 462 then
 463   AS_MESSAGE(checking kerberosIV for `uname`...)
 464   AC_DEFINE(KERBEROS_V4,1,Define if you have Kerberos V4)
 465   CEFLAGS="$CEFLAGS -I/usr/include/kerberosIV"
 466   LIBS="$LIBS -lkrb -ldes"
 467 elif krb4-config 2> /dev/null >/dev/null ; then
 468   krb4_prefix=`krb4-config --prefix`
 469   AC_MSG_RESULT([krb4-config points to kerberosIV under $krb4_prefix])
 470   unset krb4_prefix
 471   CEFLAGS="$CEFLAGS `krb4-config --cflags`"
 472   LIBS="$LIBS `krb4-config --libs`"
 473   AC_DEFINE(KERBEROS_V4)
 474 elif krb5-config 2> /dev/null >/dev/null ; then
 475   krb4_prefix=`krb5-config --prefix krb4`
 476   AC_MSG_RESULT([krb5-config points to kerberosIV under $krb4_prefix])
 477   if test -f ${krb4_prefix}/include/kerberosIV/krb.h ; then
 478     AC_DEFINE(KERBEROS_V4_V5,1,Define if you have Kerberos V4 headers under a kerberosIV directory)
 479   fi
 480   unset krb4_prefix
 481   CEFLAGS="$CEFLAGS `krb5-config --cflags krb4`"
 482   LIBS="$LIBS `krb5-config --libs krb4`"
 483   AC_DEFINE(KERBEROS_V4)
 484 else
 485   #we need to detect when we're building under a kerberosV compatibility
 486   #layer, btw...
 487   if test "$with_kerberos" != "yes" ; then
 488      searchdirs="$with_kerberos"
 489   else
 490      searchdirs="$with_kerberos5 /usr/kerberos /usr/kerberosIV /usr/athena /usr"
 491   fi
 492   with_kerberos=
 493   ac_saveLDFLAGS="$LDFLAGS"
 494   for dir in $searchdirs
 495   do
 496      AC_MSG_CHECKING([for Kerberos IV in $dir])
 497      if test -f "$dir/include/krb.h" || test -f "$dir/include/krb4.h" \
 498             || test -f "$dir/include/kerberosIV/krb.h"
 499      then
 500         AC_MSG_RESULT([found])
 501      else
 502         AC_MSG_RESULT([not found])
 503        continue
 504      fi
 505      #Find libs
 506      if test -f "$with_kerberos5/roken.h" ; then
 507        AC_CHECK_LIB(45, krb_mk_req)
 508      fi
 509      LDFLAGS="-L$dir/lib $ac_saveLDFLAGS"
 510      AC_SEARCH_LIBS(des_string_to_key, [des425 des crypto], [], continue)
 511      AC_SEARCH_LIBS(krb_realmofhost, [krb4 krb], [], continue)
 512      with_kerberos="$dir"
 513      if test -f "$dir/include/kerberosIV/krb.h" ; then
 514         dir="$dir/include/kerberosIV"
 515      else
 516        dir="$dir/include"
 517      fi
 518      AC_DEFINE(KERBEROS_V4)
 519      test -f "$with_kerberos5/roken.h" && AC_DEFINE(HEIMDAL)
 520      test "$dir" != "/usr/include" && CEFLAGS="$CEFLAGS -I$dir"
 521      LDEFLAGS="$LDEFLAGS -L$with_kerberos/lib"
 522      break
 523   done
 524   if test -z "$with_kerberos" ; then
 525      AC_MSG_ERROR([Kerberos 4 libraries not found])
 526   fi
 527   LDFLAGS="$ac_saveLDFLAGS"
 528 fi
 529 fi
 530 ]) dnl --with-kerberos=DIR
 531
 532 ###     use option --with-ssl to compile in the SSL support
 533 AC_ARG_WITH(ssl,
 534         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 535         [with_ssl=$withval],
 536         [with_ssl=no])
 537 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 538
 539 if test "$with_ssl" = "yes"
 540 then
 541     #   He didn't specify an SSL location.  Let's look at some common
 542     #   directories where SSL has been found in the past and try and auto
 543     #   configure for SSL.  OpenSSL determination will be made later.
 544     #   This will screw up if an OpenSSL install is located in a later
 545     #   directory than an older SSLeay install, but the user should fix that
 546     #   anyways and he can override on the configure line.
 547     #   Just testing for directories is not sufficient, /usr exists on
 548     #   all systems!
 549     for ac_dir in \
 550       /usr/local/ssl \
 551       /usr/local \
 552       /usr/ssl \
 553       /usr \
 554       /local/ssl \
 555       /opt/ssl \
 556       /opt/csw \
 557       ; \
 558     do
 559         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 560             with_ssl=$ac_dir
 561             break;
 562         fi
 563     done
 564 fi
 565
 566 if test -n "$with_ssl" -a "$with_ssl" != "no"
 567 then
 568   # With the autoconfigure above, the only time this is going to be
 569   # true is going to be when we could not find the headers.  If they
 570   # are not in system standard locations, we are going to be broken.
 571   if test "$with_ssl" = "yes"
 572   then
 573     # Let's just define the standard location for the SSLeay root
 574     with_ssl="/usr/local/ssl"
 575   fi
 576   if test -r $with_ssl/include/openssl/ssl.h
 577   then
 578     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 579     echo "Enabling OpenSSL support in $with_ssl"
 580     test "$with_ssl" != "/usr" && CEFLAGS="$CEFLAGS -I$with_ssl/include"
 581     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 582     ### force the Kerberos direcory onto the include path so it will build.
 583     CEFLAGS="$CEFLAGS -I/usr/kerberos/include"
 584     ### OpenBSD comes with ssl headers
 585   else
 586     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 587   fi
 588   LDEFLAGS="$LDEFLAGS -L$with_ssl/lib"
 589   LIBS="$LIBS -lssl -lcrypto"
 590   AC_DEFINE(SSL_ENABLE)
 591 else
 592   echo 'Disabling SSL support...'
 593 fi
 594
 595 ###     use option --with-socks=DIR to point at SOCKS library
 596 AC_ARG_WITH(socks,
 597         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 598 [
 599 if test "$with_socks" != no
 600 then
 601     if test "$with_socks" != yes
 602     then
 603         LDEFLAGS="$LDEFLAGS -L$with_socks"
 604     else
 605         AC_CHECK_LIB(socks, Rconnect,,
 606                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 607     fi
 608     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 609     CEFLAGS="$CEFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 610     LIBS="-lsocks $LIBS"
 611 fi])
 612
 613 ###     use option --with-socks5=DIR to point at SOCKS library
 614 AC_ARG_WITH(socks5,
 615         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 616 [
 617 if test "$with_socks5" != no
 618 then
 619   if test "$with_socks5" != yes
 620   then
 621     LDEFLAGS="$LDEFLAGS -L$with_socks5"
 622   fi
 623   ac_savedLDFLAGS="$LDFLAGS"
 624   LDFLAGS="$LDEFLAGS $LDFLAGS"
 625   AC_CHECK_LIB(socks5, SOCKSconnect,,
 626         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 627   AC_DEFINE(HAVE_SOCKS)
 628   CEFLAGS="$CEFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 629   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 630   LDFLAGS="$ac_savedLDFLAGS"
 631 fi])
 632
 633 ACX_WHICH_GETHOSTBYNAME_R
 634
 635 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 636 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 637
 638 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 639 AC_ARG_WITH(gssapi,
 640         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 641 [
 642 if test "$with_gssapi" != "no"
 643 then
 644   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 645   then
 646     with_gssapi=$with_kerberos5
 647   fi
 648   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 649   then
 650     CFLAGS="$CFLAGS -I$with_gssapi/include"
 651     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 652   fi
 653
 654   AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 655   if test -n "$nogss"
 656   then
 657   if test -f "$with_gssapi/include/roken.h"
 658   then
 659      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl"
 660      AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 661                   AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 662      AC_DEFINE(HEIMDAL)
 663   else
 664      AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 665                   AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 666   fi
 667   fi
 668   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 669   save_CPPFLAGS=$CPPFLAGS
 670   CPPFLAGS="-I$with_gssapi/include"
 671   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 672   if test "$ac_cv_header_gssapi_h" = "yes"; then
 673     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 674   else
 675     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 676   fi
 677 fi])
 678
 679 AC_SUBST(CPFLAGS)
 680 AC_SUBST(CEFLAGS)
 681 AC_SUBST(LDEFLAGS)
 682
 683 dnl ,------------------------------------------------------------------
 684 dnl Check if we need TRIO
 685 needtrio=0
 686 if test "$FORCE_TRIO" = "yes" ; then
 687     needtrio=1
 688     ac_cv_func_vsnprintf=no
 689     ac_cv_func_snprintf=no
 690 fi
 691 if test "x$ac_cv_func_snprintf" != "xyes" ; then
 692     AC_DEFINE(snprintf, trio_snprintf,
 693               [Define to trio_snprintf if your system lacks snprintf])
 694     needtrio=1
 695 fi
 696 if test "x$ac_cv_func_vsnprintf" != "xyes" ; then
 697     AC_DEFINE(vsnprintf, trio_vsnprintf,
 698               [Define to trio_vsnprintf if your system lacks vsnprintf])
 699     needtrio=1
 700 fi
 701 AM_CONDITIONAL(NEED_TRIO, test "$needtrio" = 1)
 702
 703 dnl TRIO IEEE compiler option for Alpha
 704 dnl
 705 if test "$needtrio" = 1 ; then
 706     AC_MSG_CHECKING(for IEEE compilation options)
 707     AC_CACHE_VAL(ac_cv_ieee_option, [
 708     AC_TRY_COMPILE(,[
 709     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
 710     # error "Option needed"
 711     #endif
 712     ],ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
 713     AC_TRY_COMPILE(,[
 714     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
 715     # error "Option needed"
 716     #endif
 717     ],ac_cv_ieee_option="-ieee",
 718     AC_TRY_COMPILE(,[
 719     #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
 720     # error "Option needed"
 721     #endif
 722     ],ac_cv_ieee_option="-mieee",
 723     ac_cv_ieee_option="none"
 724     )
 725     )
 726     )
 727     ])
 728     AC_MSG_RESULT($ac_cv_ieee_option)
 729     if test $ac_cv_ieee_option != none; then
 730       CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
 731     fi
 732 fi
 733 dnl ----------------------------------------------------------------'
 734
 735 AC_CONFIG_FILES([Makefile m4/Makefile po/Makefile.in])
 736 AC_OUTPUT
 737
 738 dnl Local Variables:
 739 dnl comment-start: "dnl "
 740 dnl comment-end: ""
 741 dnl comment-start-skip: "\\bdnl\\b\\s *"
 742 dnl compile-command: "make configure config.h.in"
 743 dnl End: