Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [2])
  12 m4_define([gtk_minor_version], [91])
  13 m4_define([gtk_micro_version], [5])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.64])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Define a string for the earliest version that this release has
  32 # backwards binary compatibility with for all interfaces a module
  33 # might. Unless we add module-only API with lower stability
  34 # guarantees, this should be unchanged until we break binary compat
  35 # for GTK+.
  36 #
  37 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  38 m4_define([gtk_binary_version], [3.0.0])
  39
  40 # required versions of other packages
  41 m4_define([glib_required_version], [2.27.3])
  42 m4_define([pango_required_version], [1.20])
  43 m4_define([atk_required_version], [1.29.2])
  44 m4_define([cairo_required_version], [1.10.0])
  45 m4_define([gdk_pixbuf_required_version], [2.21.0])
  46 GLIB_REQUIRED_VERSION=glib_required_version
  47 PANGO_REQUIRED_VERSION=pango_required_version
  48 ATK_REQUIRED_VERSION=atk_required_version
  49 CAIRO_REQUIRED_VERSION=cairo_required_version
  50 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  51 AC_SUBST(GLIB_REQUIRED_VERSION)
  52 AC_SUBST(PANGO_REQUIRED_VERSION)
  53 AC_SUBST(ATK_REQUIRED_VERSION)
  54 AC_SUBST(CAIRO_REQUIRED_VERSION)
  55 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  56
  57
  58 # Save this value here, since automake will set cflags later
  59 cflags_set=${CFLAGS+set}
  60
  61 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  62 AM_MAINTAINER_MODE([enable])
  63
  64 # Support silent build rules, requires at least automake-1.11. Enable
  65 # by either passing --enable-silent-rules to configure or passing V=0
  66 # to make
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69 #
  70 # For each of the libraries we build, we define the following
  71 # substituted variables:
  72 #
  73 # foo_PACKAGES:     pkg-config packages this library requires
  74 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  75 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  76 # foo_DEP_LIBS:     All libraries this module requires
  77 # foo_DEP_CFLAGS:   All cflags this module requires
  78
  79
  80 GTK_MAJOR_VERSION=gtk_major_version
  81 GTK_MINOR_VERSION=gtk_minor_version
  82 GTK_MICRO_VERSION=gtk_micro_version
  83 GTK_INTERFACE_AGE=gtk_interface_age
  84 GTK_BINARY_AGE=gtk_binary_age
  85 GTK_VERSION=gtk_version
  86 GTK_API_VERSION=gtk_api_version
  87 GTK_BINARY_VERSION=gtk_binary_version
  88 AC_SUBST(GTK_MAJOR_VERSION)
  89 AC_SUBST(GTK_MINOR_VERSION)
  90 AC_SUBST(GTK_MICRO_VERSION)
  91 AC_SUBST(GTK_INTERFACE_AGE)
  92 AC_SUBST(GTK_BINARY_AGE)
  93 AC_SUBST(GTK_API_VERSION)
  94 AC_SUBST(GTK_VERSION)
  95 AC_SUBST(GTK_BINARY_VERSION)
  96
  97 # libtool versioning
  98 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  99 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 100 #LT_REVISION=$GTK_INTERFACE_AGE
 101 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 102 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 103
 104 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 105 m4_define([lt_revision], [gtk_interface_age])
 106 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 107 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 108 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 109 AC_SUBST(LT_VERSION_INFO)
 110 AC_SUBST(LT_CURRENT_MINUS_AGE)
 111
 112 m4_define([gail_lt_current],[0])
 113 m4_define([gail_lt_revision],[0])
 114 m4_define([gail_lt_age],[0])
 115 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 116 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 117 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 118 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 119
 120 # Checks for programs.
 121 AC_PROG_CC
 122 AC_PROG_CC_C_O
 123 AC_PROG_CC_STDC
 124 AC_PROG_INSTALL
 125 AC_PROG_MAKE_SET
 126
 127
 128 GETTEXT_PACKAGE=gtk30
 129 AC_SUBST(GETTEXT_PACKAGE)
 130 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 131                    [The prefix for our gettext translation domains.])
 132
 133 AC_CANONICAL_HOST
 134
 135 MATH_LIB=-lm
 136 AC_MSG_CHECKING([for native Win32])
 137 LIB_EXE_MACHINE_FLAG=X86
 138 EXE_MANIFEST_ARCHITECTURE=X86
 139 case "$host" in
 140   *-*-mingw*)
 141     os_win32=yes
 142     gio_can_sniff=no
 143     MATH_LIB=
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       EXE_MANIFEST_ARCHITECTURE=AMD64
 148       ;;
 149     esac
 150     ;;
 151   *)
 152     os_win32=no
 153     ;;
 154 esac
 155 AC_MSG_RESULT([$os_win32])
 156
 157 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 158 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 159
 160 case $host in
 161   *-*-linux*)
 162     os_linux=yes
 163     ;;
 164 esac
 165
 166 dnl
 167 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 168 dnl We use this for an automated test for C++ header correctness.
 169 dnl
 170 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 171 AC_LANG_PUSH([C++])
 172
 173 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 174 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 175
 176 gtk_save_cxxflags="$CXXFLAGS"
 177 CXXFLAGS="$CXXFLAGS -x objective-c++"
 178 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 179 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 180 CXXFLAGS="$gtk_save_cxxflags"
 181 AC_LANG_POP([C++])
 182
 183 if test "$os_win32" = "yes"; then
 184   if test x$enable_static = xyes -o x$enable_static = x; then
 185     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 186     enable_static=no
 187   fi
 188   if test x$enable_shared = xno; then
 189     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 190   fi
 191   enable_shared=yes
 192 fi
 193
 194 dnl Initialize libtool
 195 LT_PREREQ([2.2.6])
 196 LT_INIT([disable-static win32-dll])
 197 # Create libtool early, because it's used in configure
 198 LT_OUTPUT
 199
 200 # Make sure we use 64-bit versions of various file stuff.
 201 AC_SYS_LARGEFILE
 202
 203 AM_PROG_AS
 204 AC_PATH_PROG(NM, nm, nm)
 205
 206 AC_MSG_CHECKING([for some Win32 platform])
 207 case "$host" in
 208   *-*-mingw*|*-*-cygwin*)
 209     platform_win32=yes
 210     ;;
 211   *)
 212     platform_win32=no
 213     ;;
 214 esac
 215 AC_MSG_RESULT([$platform_win32])
 216 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 217
 218 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 219 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 220 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 221
 222 if test "$os_win32" = "yes"; then
 223   AC_CHECK_TOOL(WINDRES, windres, no)
 224   if test "$WINDRES" = no; then
 225     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 226   fi
 227   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 228 fi
 229 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 230
 231 m4_define([debug_default],
 232           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 233
 234 dnl declare --enable-* args and collect ac_help strings
 235 AC_ARG_ENABLE(debug,
 236               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 237                              [turn on debugging @<:@default=debug_default@:>@]),,
 238               enable_debug=debug_default)
 239 AC_ARG_ENABLE(xkb,
 240               [AC_HELP_STRING([--enable-xkb],
 241                               [support XKB [default=maybe]])],,
 242               [enable_xkb="maybe"])
 243 AC_ARG_ENABLE(xinerama,
 244               [AC_HELP_STRING([--enable-xinerama],
 245                               [support xinerama extension if available [default=yes]])],,
 246               [enable_xinerama="yes"])
 247 AC_ARG_ENABLE(rebuilds,
 248               [AC_HELP_STRING([--disable-rebuilds],
 249                               [disable all source autogeneration rules])],,
 250               [enable_rebuilds=yes])
 251
 252 AC_ARG_WITH(xinput,
 253             [AC_HELP_STRING([--with-xinput=@<:@no/yes@:>@], [support XInput])])
 254
 255 if test "$platform_win32" = yes; then
 256   gdktarget=win32
 257 else
 258   gdktarget=x11
 259 fi
 260
 261 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/win32/quartz]] select non-default GDK target],
 262         gdktarget=$with_gdktarget)
 263
 264 AC_SUBST(gdktarget)
 265 case $gdktarget in
 266   x11|win32|quartz) ;;
 267   *) AC_MSG_ERROR([Invalid target for GDK: use x11, quartz or win32.]);;
 268 esac
 269
 270 gdktargetlib=libgdk-$gdktarget-$GTK_API_VERSION.la
 271 gtktargetlib=libgtk-$gdktarget-$GTK_API_VERSION.la
 272
 273 AC_SUBST(gdktargetlib)
 274 AC_SUBST(gtktargetlib)
 275
 276 if test "x$enable_debug" = "xyes"; then
 277   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 278   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 279 else
 280   if test "x$enable_debug" = "xno"; then
 281     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 282   else
 283     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 284   fi
 285 fi
 286
 287
 288 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 289                    [Define if debugging is enabled])
 290
 291
 292 # Build time sanity check...
 293 AM_SANITY_CHECK
 294
 295 changequote(,)dnl
 296 if test "x$GCC" = "xyes"; then
 297   case " $CFLAGS " in
 298   *[\ \ ]-Wall[\ \      ]*) ;;
 299   *) CFLAGS="$CFLAGS -Wall" ;;
 300   esac
 301
 302   if test "x$enable_ansi" = "xyes"; then
 303     case " $CFLAGS " in
 304     *[\ \       ]-ansi[\ \      ]*) ;;
 305     *) CFLAGS="$CFLAGS -ansi" ;;
 306     esac
 307
 308     case " $CFLAGS " in
 309     *[\ \       ]-pedantic[\ \  ]*) ;;
 310     *) CFLAGS="$CFLAGS -pedantic" ;;
 311     esac
 312   fi
 313 fi
 314 changequote([,])dnl
 315
 316 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 317
 318 # Ensure MSVC-compatible struct packing convention is used when
 319 # compiling for Win32 with gcc.
 320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 321 # gcc2 uses "-fnative-struct".
 322 if test x"$os_win32" = xyes; then
 323   if test x"$GCC" = xyes; then
 324     msnative_struct=''
 325     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 326     if test -z "$ac_cv_prog_CC"; then
 327       our_gcc="$CC"
 328     else
 329       our_gcc="$ac_cv_prog_CC"
 330     fi
 331     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 332       2.)
 333         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 334           msnative_struct='-fnative-struct'
 335         fi
 336         ;;
 337       *)
 338         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 339           msnative_struct='-mms-bitfields'
 340         fi
 341         ;;
 342     esac
 343     if test x"$msnative_struct" = x ; then
 344       AC_MSG_RESULT([no way])
 345       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 346     else
 347       CFLAGS="$CFLAGS $msnative_struct"
 348       AC_MSG_RESULT([${msnative_struct}])
 349     fi
 350   fi
 351 fi
 352
 353 ## Initial sanity check, done here so that users get told they
 354 ## have the wrong dependencies as early in the process as possible.
 355 ## Later on we actually use the cflags/libs from separate pkg-config
 356 ## calls. Oh, also the later pkg-config calls don't include
 357 ## the version requirements since those make the module lists
 358 ## annoying to construct
 359 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 360   [glib-2.0 >= glib_required_version dnl
 361    atk >= atk_required_version dnl
 362    pango >= pango_required_version dnl
 363    cairo >= cairo_required_version dnl
 364    cairo-gobject >= cairo_required_version dnl
 365    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 366
 367 ## In addition to checking that cairo is present, we also need to
 368 ## check that the correct cairo backend is there. E.g. if the GDK
 369 ## target is win32 we need the cairo-win32 backend and so on.
 370 cairo_backend=$gdktarget
 371
 372 # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 373 # backend names are identical.
 374 if test "x$cairo_backend" = "xx11"; then
 375    cairo_backend=xlib
 376 fi
 377 PKG_CHECK_MODULES(CAIRO_BACKEND,
 378   [cairo-$cairo_backend >= cairo_required_version])
 379
 380 if test "$os_win32" != yes; then
 381     # libtool option to control which symbols are exported
 382     # right now, symbols starting with _ are not exported
 383     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 384 else
 385     # We currently use .def files on Windows (for gdk and gtk)
 386     LIBTOOL_EXPORT_OPTIONS=
 387 fi
 388 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 389
 390 dnl ******************************************************
 391 dnl * See whether to include shared library dependencies *
 392 dnl ******************************************************
 393
 394 AC_ARG_ENABLE(explicit-deps,
 395               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 396                               [use explicit dependencies in .pc files [default=auto]])],,
 397               [enable_explicit_deps=auto])
 398
 399 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 400 case $enable_explicit_deps in
 401   auto)
 402     export SED
 403     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 404     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 405       enable_explicit_deps=yes
 406     else
 407       enable_explicit_deps=no
 408     fi
 409   ;;
 410   yes|no)
 411   ;;
 412   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 413   ;;
 414 esac
 415 AC_MSG_RESULT($enable_explicit_deps)
 416
 417 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 418
 419 # define a MAINT-like variable REBUILD which is set if Perl
 420 # and awk are found, so autogenerated sources can be rebuilt
 421
 422 AC_PATH_PROGS(PERL, perl5 perl)
 423
 424 # We would like indent, but don't require it.
 425 AC_CHECK_PROG(INDENT, indent, indent)
 426
 427 REBUILD=\#
 428 if test "x$enable_rebuilds" = "xyes" && \
 429      test -n "$PERL" && \
 430      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 431   REBUILD=
 432 fi
 433 AC_SUBST(REBUILD)
 434
 435 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 436 AC_CHECK_FUNCS(localtime_r)
 437
 438 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 439 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 440 AC_TRY_LINK([#include <langinfo.h>], [
 441 char c;
 442 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 443 ], gtk_ok=yes, gtk_ok=no)
 444 AC_MSG_RESULT($gtk_ok)
 445 if test "$gtk_ok" = "yes"; then
 446   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 447             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 448 fi
 449
 450 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 451 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 452 AC_TRY_LINK([#include <langinfo.h>], [
 453 char c;
 454 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 455 ], gtk_ok=yes, gtk_ok=no)
 456 AC_MSG_RESULT($gtk_ok)
 457 if test "$gtk_ok" = "yes"; then
 458   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 459             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 460 fi
 461
 462 # _NL_PAPER_HEIGHT is an enum and not a define
 463 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 464 AC_TRY_LINK([#include <langinfo.h>], [
 465 char c;
 466 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 467 ], gtk_ok=yes, gtk_ok=no)
 468 AC_MSG_RESULT($gtk_ok)
 469 if test "$gtk_ok" = "yes"; then
 470   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 471             [Define if _NL_PAPER_HEIGHT is available])
 472 fi
 473
 474 # _NL_PAPER_WIDTH is an enum and not a define
 475 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 476 AC_TRY_LINK([#include <langinfo.h>], [
 477 char c;
 478 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 479 ], gtk_ok=yes, gtk_ok=no)
 480 AC_MSG_RESULT($gtk_ok)
 481 if test "$gtk_ok" = "yes"; then
 482   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 483             [Define if _NL_PAPER_WIDTH is available])
 484 fi
 485
 486 # i18n stuff
 487 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 488 AM_GLIB_GNU_GETTEXT
 489 LIBS="$LIBS $INTLLIBS"
 490 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 491         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 492       esac])
 493
 494 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 495 dnl po-properties/POTFILES during configure; see GNOME #573515.
 496 dnl
 497 dnl Generate list of files to be processed by xgettext which will
 498 dnl be included in po-properties/Makefile.
 499 test -d po-properties || mkdir po-properties
 500 if test "x$srcdir" != "x."; then
 501   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 502     popropsrcprefix="$srcdir/"
 503   else
 504     popropsrcprefix="../$srcdir/"
 505   fi
 506 else
 507   popropsrcprefix="../"
 508 fi
 509 rm -f po-properties/POTFILES
 510 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 511 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 512 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 513
 514 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 515
 516 dnl The DU4 header files don't provide library prototypes unless
 517 dnl -std1 is given to the native cc.
 518 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 519
 520 gtk_save_LIBS=$LIBS
 521 LIBS="$LIBS -lm"
 522 AC_TRY_RUN([#include <math.h>
 523              int main (void) { return (log(1) != log(1.)); }],
 524      AC_MSG_RESULT(none needed),
 525      gtk_save_CFLAGS="$CFLAGS"
 526      CFLAGS="$CFLAGS -std1"
 527      AC_TRY_RUN([#include <math.h>
 528                  int main (void) { return (log(1) != log(1.)); }],
 529          AC_MSG_RESULT(-std1),
 530          AC_MSG_RESULT()
 531          CFLAGS="$gtk_save_CFLAGS"
 532          AC_MSG_WARN(
 533                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 534          true
 535      ),
 536      AC_MSG_RESULT(none needed)
 537 )
 538 LIBS=$gtk_save_LIBS
 539
 540 AC_MSG_CHECKING(for the BeOS)
 541 case $host in
 542   *-*-beos*)
 543     AC_MSG_RESULT(yes)
 544     MATH_LIB=
 545   ;;
 546   *)
 547     AC_MSG_RESULT(no)
 548   ;;
 549 esac
 550
 551 AC_SUBST(MATH_LIB)
 552 #
 553 # see bug 162979
 554 #
 555 AC_MSG_CHECKING(for HP-UX)
 556 case $host_os in
 557   hpux9* | hpux10* | hpux11*)
 558     AC_MSG_RESULT(yes)
 559     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 560   ;;
 561   *)
 562     AC_MSG_RESULT(no)
 563   ;;
 564 esac
 565
 566 dnl NeXTStep cc seems to need this
 567 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 568 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 569   AC_MSG_RESULT(none needed),
 570   gtk_save_CFLAGS="$CFLAGS"
 571   CFLAGS="$CFLAGS -posix"
 572   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 573     AC_MSG_RESULT(-posix),
 574     AC_MSG_RESULT()
 575     CFLAGS="$gtk_save_CFLAGS"
 576     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 577
 578 #
 579 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 580 #
 581
 582 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 583
 584 AM_PATH_GLIB_2_0(glib_required_version, :,
 585   AC_MSG_ERROR([
 586 *** GLIB glib_required_version or better is required. The latest version of
 587 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 588   gobject gmodule-no-export gthread)
 589
 590 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 591 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 592 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 593 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 594   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 595 fi
 596
 597 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 598
 599
 600 dnl
 601 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 602 dnl
 603 gtk_save_LIBS=$LIBS
 604 LIBS="$LIBS $GLIB_LIBS"
 605 AC_CHECK_FUNCS(bind_textdomain_codeset)
 606 LIBS=$gtk_save_LIBS
 607
 608 AC_CHECK_HEADERS(pwd.h,
 609                  AC_DEFINE(HAVE_PWD_H, 1,
 610                            [Define to 1 if pwd.h is available]))
 611 AC_CHECK_HEADERS(sys/time.h,
 612                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 613                            [Define to 1 if time.h is available]))
 614 AC_CHECK_HEADERS(unistd.h,
 615                  AC_DEFINE(HAVE_UNISTD_H, 1,
 616                            [Define to 1 if unistd.h is available]))
 617 AC_CHECK_HEADERS(ftw.h,
 618                  AC_DEFINE(HAVE_FTW_H, 1,
 619                            [Define to 1 if ftw.h is available]))
 620
 621 AC_MSG_CHECKING([for GNU ftw extensions])
 622 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 623 #define _GNU_SOURCE
 624 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 625 if test $gtk_ok = yes; then
 626     AC_MSG_RESULT([yes])
 627     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 628 else
 629     AC_MSG_RESULT([no])
 630 fi
 631
 632 saved_cflags="$CFLAGS"
 633 saved_ldflags="$LDFLAGS"
 634
 635
 636 # Checks for header files.
 637 AC_HEADER_STDC
 638
 639 # Checks for typedefs, structures, and compiler characteristics.
 640 AC_C_CONST
 641
 642 # Checks for library functions.
 643 AC_TYPE_SIGNAL
 644 AC_FUNC_MMAP
 645
 646 AC_CHECK_FUNCS(mallinfo)
 647 AC_CHECK_FUNCS(getresuid)
 648 AC_TYPE_UID_T
 649
 650 # Check if <sys/select.h> needs to be included for fd_set
 651 AC_MSG_CHECKING([for fd_set])
 652 AC_TRY_COMPILE([#include <sys/types.h>],
 653         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 654 if test $gtk_ok = yes; then
 655     AC_MSG_RESULT([yes, found in sys/types.h])
 656 else
 657     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 658     if test $gtk_ok = yes; then
 659         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 660                   [Define to 1 if sys/select.h is available])
 661         AC_MSG_RESULT([yes, found in sys/select.h])
 662     else
 663         AC_DEFINE(NO_FD_SET, 1,
 664                   [Define to 1 if fd_set is not available])
 665         AC_MSG_RESULT(no)
 666     fi
 667 fi
 668
 669 # `widechar' tests for gdki18n.h
 670 AC_MSG_CHECKING(for wchar.h)
 671 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 672 if test $gdk_wchar_h = yes; then
 673    AC_DEFINE(HAVE_WCHAR_H, 1, [Have wchar.h include file])
 674 fi
 675 AC_MSG_RESULT($gdk_wchar_h)
 676
 677 # Check for wctype.h (for iswalnum)
 678 AC_MSG_CHECKING(for wctype.h)
 679 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 680 if test $gdk_wctype_h = yes; then
 681    AC_DEFINE(HAVE_WCTYPE_H, 1, [Have wctype.h include file])
 682 fi
 683 AC_MSG_RESULT($gdk_wctype_h)
 684
 685 # in Solaris 2.5, `iswalnum' is in -lw
 686 GDK_WLIBS=
 687 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 688
 689 oLIBS="$LIBS"
 690 LIBS="$LIBS $GDK_WLIBS"
 691 # The following is necessary for Linux libc-5.4.38
 692 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 693 AC_TRY_LINK([#include <stdlib.h>],[
 694 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 695 #  ifdef HAVE_WCTYPE_H
 696 #    include <wctype.h>
 697 #  else
 698 #    ifdef HAVE_WCHAR_H
 699 #      include <wchar.h>
 700 #    endif
 701 #  endif
 702 #else
 703 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 704 #endif
 705 iswalnum((wchar_t) 0);
 706 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 707 LIBS="$oLIBS"
 708
 709 if test $gdk_working_wctype = no; then
 710    AC_DEFINE(HAVE_BROKEN_WCTYPE, 1, [Is the wctype implementation broken])
 711    GDK_WLIBS=
 712 fi
 713 AC_MSG_RESULT($gdk_working_wctype)
 714 AC_SUBST(GDK_WLIBS)
 715
 716 # Check for uxtheme.h (for MS-Windows Engine)
 717 AC_MSG_CHECKING(for uxtheme.h)
 718 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 719 if test $gtk_uxtheme_h = yes; then
 720    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 721 fi
 722 AC_MSG_RESULT($gtk_uxtheme_h)
 723
 724 # Checks for gdkspawn
 725 AC_CHECK_HEADERS(crt_externs.h)
 726 AC_CHECK_FUNCS(_NSGetEnviron)
 727
 728 AC_MSG_CHECKING(whether to build dynamic modules)
 729
 730 AC_ARG_ENABLE(modules,
 731               [AC_HELP_STRING([--disable-modules],
 732                               [disable dynamic module loading])])
 733
 734 dynworks=false
 735 deps=
 736 if test x$enable_modules = xno; then
 737     AC_MSG_RESULT(no)
 738 else
 739     AC_MSG_RESULT(yes)
 740     AC_MSG_CHECKING(whether dynamic modules work)
 741     ## for loop is to strip newline
 742     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 743     for I in $tmp; do
 744         dynworks=$I
 745     done
 746
 747     dnl Now we check to see if our libtool supports shared lib deps
 748     dnl (in a rather ugly way even)
 749     if $dynworks; then
 750         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 751         module_deplibs_check=`$module_libtool_config | \
 752             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 753             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 754         if test "x$module_deplibs_check" = "xnone" || \
 755            test "x$module_deplibs_check" = "xunknown" || \
 756            test "x$module_deplibs_check" = "x"; then
 757             dynworks=false
 758         fi
 759     fi
 760
 761     if $dynworks; then
 762         AC_DEFINE(USE_GMODULE, 1,
 763                   [Define to 1 if gmodule works and should be used])
 764         AC_MSG_RESULT(yes)
 765     else
 766         AC_MSG_RESULT(no)
 767     fi
 768 fi
 769
 770 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 771
 772 #
 773 # Allow building some or all immodules included
 774 #
 775 AC_MSG_CHECKING(immodules to build)
 776
 777 dnl due to an autoconf bug, commas in the first arg to
 778 dnl AC_HELP_STRING cause problems.
 779 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
 780 dnl                [build the specified input method modules into gtk])
 781 AC_ARG_WITH(included_immodules,
 782 [  --with-included-immodules=MODULE1,MODULE2,...
 783                           build the specified input methods into gtk])
 784
 785 if $dynworks; then
 786    :
 787 else
 788    ## if the option was specified, leave it; otherwise disable included immodules
 789    if test x$with_included_immodules = xno; then
 790            with_included_immodules=yes
 791    fi
 792 fi
 793
 794 all_immodules="am-et,cedilla,cyrillic-translit"
 795 if test "$gdktarget" = "win32"; then
 796    all_immodules="${all_immodules},ime"
 797 fi
 798 all_immodules="${all_immodules},inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr"
 799 if test "$gdktarget" = "x11"; then
 800    all_immodules="${all_immodules},xim"
 801 fi
 802
 803 included_immodules=""
 804 # If the switch specified without listing any specific ones, include all
 805 if test "x$with_included_immodules" = xyes ; then
 806   included_immodules="$all_immodules"
 807 else
 808   included_immodules="$with_included_immodules"
 809 fi
 810
 811 AC_MSG_RESULT($included_immodules)
 812 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 813
 814 INCLUDED_IMMODULE_OBJ=
 815 INCLUDED_IMMODULE_DEFINE=
 816
 817 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 818 for immodule in $included_immodules; do
 819  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 820  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 821    :
 822  else
 823    AC_MSG_ERROR([the specified input method $immodule does not exist])
 824  fi
 825
 826  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 827  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 828  eval INCLUDE_$immodule_underscores=yes
 829 done
 830 IFS="$gtk_save_ifs"
 831 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 832 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 833
 834 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 835 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 836 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 837 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 838 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 839 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 840 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 841 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 842 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 843 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 844 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 845 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 846
 847 AC_HEADER_SYS_WAIT
 848
 849 AC_TYPE_SIGNAL
 850
 851 # Checks to see whether we should include mediaLib
 852 # support.
 853 #
 854 AC_CHECK_HEADER(sys/systeminfo.h,
 855                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 856                           [Define to 1 if sys/systeminfo.h is available]))
 857 AC_CHECK_HEADER(sys/sysinfo.h,
 858                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 859                           [Define to 1 if sys/sysinfo.h is available]))
 860
 861 AC_MSG_CHECKING(for mediaLib 2.3)
 862 use_mlib25=no
 863 # Check for a mediaLib 2.3 function since that is what the GTK+ mediaLib
 864 # patch requires.
 865 AC_CHECK_LIB(mlib, mlib_ImageSetStruct, use_mlib=yes, use_mlib=no)
 866 if test $use_mlib = yes; then
 867     AC_DEFINE(USE_MEDIALIB, 1,
 868               [Define to 1 if medialib is available and should be used])
 869     MEDIA_LIB=-lmlib
 870
 871     AC_MSG_CHECKING(for mediaLib 2.5)
 872     # Check for a mediaLib 2.5 function since that is what is needed for
 873     # gdk_rgb_convert integration.
 874     AC_CHECK_LIB(mlib, mlib_VideoColorRGBint_to_BGRAint, use_mlib25=yes, use_mlib25=no)
 875     if test $use_mlib25 = yes; then
 876         AC_DEFINE(USE_MEDIALIB25, 1,
 877                   [Define to 1 if medialib 2.5 is available])
 878     fi
 879 fi
 880 AM_CONDITIONAL(USE_MEDIALIB, test $use_mlib = yes)
 881 AM_CONDITIONAL(USE_MEDIALIB25, test $use_mlib25 = yes)
 882
 883 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 884
 885 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 886
 887 if test $cross_compiling = yes; then
 888   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 889   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 890     REBUILD_PNGS=#
 891   fi
 892 fi
 893
 894 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 895
 896 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 897    test "x$REBUILD_PNGS" = "x#" ; then
 898      AC_MSG_ERROR([
 899 *** gtkbuiltincache.h is not in the tree, and cannot be built
 900 *** because you don't have libpng, or (when cross-compiling) you
 901 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 902 fi
 903
 904 ########################################
 905 # Windowing system checks
 906 ########################################
 907
 908 GDK_EXTRA_LIBS="$GDK_WLIBS"
 909 GDK_EXTRA_CFLAGS=
 910
 911 # GTK+ uses some X calls, so needs to link against X directly
 912 GTK_DEP_PACKAGES_FOR_X=
 913 GTK_DEP_LIBS_FOR_X=
 914
 915 if test "x$gdktarget" = "xx11"; then
 916   X_PACKAGES=fontconfig
 917
 918   #
 919   # We use fontconfig very peripherally when decoding the default
 920   # settings.
 921   #
 922   if $PKG_CONFIG --exists fontconfig; then : ; else
 923     AC_MSG_ERROR([
 924 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 925   fi
 926
 927   #
 928   # Check for basic X packages; we use pkg-config if available
 929   #
 930   if $PKG_CONFIG --exists x11 xext; then
 931     have_base_x_pc=true
 932     X_PACKAGES="$X_PACKAGES x11 xext"
 933     x_libs="`$PKG_CONFIG --libs x11 xext`"
 934     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 935
 936     # Strip out any .la files that pkg-config might give us (this happens
 937     # with -uninstalled.pc files)
 938     x_libs_for_checks=
 939     for I in $x_libs ; do
 940       case $I in
 941         *.la) ;;
 942         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 943       esac
 944     done
 945
 946     GTK_PACKAGES_FOR_X="x11"
 947   else
 948     have_base_x_pc=false
 949     AC_PATH_XTRA
 950     if test x$no_x = xyes ; then
 951       AC_MSG_ERROR([X development libraries not found])
 952     fi
 953
 954     x_cflags="$X_CFLAGS"
 955     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 956
 957     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 958   fi
 959
 960   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 961   x_extra_libs=
 962
 963   gtk_save_cppflags="$CPPFLAGS"
 964   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 965
 966   gtk_save_LIBS=$LIBS
 967   LIBS="$x_libs_for_checks $LIBS"
 968
 969   # Sanity check for the X11 and Xext libraries. While everything we need from
 970   # Xext is optional, the chances a system has *none* of these things is so
 971   # small that we just unconditionally require it.
 972   AC_CHECK_FUNC(XOpenDisplay, :,
 973                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 974   AC_CHECK_FUNC(XextFindDisplay, :,
 975                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 976
 977   # Check for xReply
 978
 979   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 980   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
 981       [xReply *rep;],
 982       [AC_MSG_RESULT([no])],
 983       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
 984 #include <X11/Xlibint.h>],
 985            [xReply *rep;],
 986            [AC_MSG_RESULT([yes])
 987             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
 988                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
 989            [AC_MSG_RESULT([unknown])
 990             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 991
 992   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 993
 994   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 995
 996   # Generic X11R6 check needed for XIM support; we could
 997   # probably use this to replace the above, but we'll
 998   # leave the separate checks for XConvertCase and XInternAtoms
 999   # for clarity
1000
1001   have_x11r6=false
1002   AC_CHECK_FUNC(XAddConnectionWatch,
1003       have_x11r6=true)
1004
1005   if $have_x11r6; then
1006     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1007   fi
1008   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1009
1010   # Check for XKB support.
1011
1012   if test "x$enable_xkb" = "xyes"; then
1013         AC_MSG_WARN(XKB support explicitly enabled)
1014         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
1015   elif test "x$enable_xkb" = "xmaybe"; then
1016         AC_CHECK_FUNC(XkbQueryExtension,
1017                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1018   else
1019         AC_MSG_WARN(XKB support explicitly disabled)
1020   fi
1021
1022   # Check for shaped window extension
1023
1024   AC_CHECK_FUNC(XShapeCombineMask, :,
1025      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1026
1027   # X SYNC check
1028   gtk_save_CFLAGS="$CFLAGS"
1029   CFLAGS="$CFLAGS $x_cflags"
1030
1031   AC_CHECK_FUNC(XSyncQueryExtension,
1032       [AC_CHECK_HEADER(X11/extensions/sync.h,
1033           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1034           :, [#include <X11/Xlib.h>])])
1035
1036   CFLAGS="$gtk_save_CFLAGS"
1037
1038   if test "x$enable_xinerama" = "xyes"; then
1039     # Check for Xinerama extension (Solaris impl or Xfree impl)
1040     gtk_save_cppflags="$CPPFLAGS"
1041     CPPFLAGS="$CPPFLAGS $x_cflags"
1042
1043     # Check for XFree
1044     AC_MSG_CHECKING(for Xinerama support on XFree86)
1045
1046     have_xfree_xinerama=false
1047     if $PKG_CONFIG --exists xinerama ; then
1048        have_xfree_xinerama=true
1049        X_PACKAGES="$X_PACKAGES xinerama"
1050     else
1051        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1052            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1053            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1054            have_xfree_xinerama=true], :,
1055            [#include <X11/Xlib.h>])])
1056     fi
1057
1058     if $have_xfree_xinerama ; then
1059       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1060                 [Define to 1 if XFree Xinerama is available])
1061       AC_DEFINE(HAVE_XINERAMA, 1,
1062                 [Define to 1 is Xinerama is available])
1063       AC_MSG_RESULT(yes)
1064     else
1065       AC_MSG_RESULT(no)
1066
1067       case "$host" in
1068         *-*-solaris*)
1069             # Check for solaris
1070             AC_MSG_CHECKING(for Xinerama support on Solaris)
1071
1072             have_solaris_xinerama=false
1073             AC_CHECK_FUNC(XineramaGetInfo,
1074                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1075                     [have_solaris_xinerama=true], :,
1076                     [#include <X11/Xlib.h>])])
1077
1078             if $have_solaris_xinerama ; then
1079               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1080                         [Define to 1 if solaris xinerama is available])
1081               AC_DEFINE(HAVE_XINERAMA, 1,
1082                         [Define to 1 if xinerama is available])
1083               AC_MSG_RESULT(yes)
1084             else
1085               AC_MSG_RESULT(no)
1086             fi
1087             ;;
1088         *)
1089             ;;
1090       esac
1091     fi
1092   fi
1093
1094   # set up things for XInput
1095   if test "x$with_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1096     have_xinput=yes
1097
1098     AC_DEFINE(XINPUT_XFREE, 1,
1099               [Define to 1 if XFree XInput should be used])
1100
1101     X_PACKAGES="$X_PACKAGES xi"
1102
1103     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1104                     have_xinput2=yes; AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1105   else
1106     AC_DEFINE(XINPUT_NONE, 1,
1107               [Define to 1 if no XInput should be used])
1108   fi
1109
1110   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1111   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1112
1113   # Check for the RANDR extension
1114   if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1115      AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1116
1117      X_PACKAGES="$X_PACKAGES xrandr"
1118   fi
1119
1120   # Checks for Xcursor library
1121
1122   if $PKG_CONFIG --exists xcursor ; then
1123     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1124
1125     X_PACKAGES="$X_PACKAGES xcursor"
1126   fi
1127
1128   # Checks for XFixes extension
1129
1130   if $PKG_CONFIG --exists xfixes ; then
1131     AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1132
1133     X_PACKAGES="$X_PACKAGES xfixes"
1134     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1135   fi
1136
1137   # Checks for Xcomposite extension
1138
1139   if $PKG_CONFIG --exists xcomposite ; then
1140     AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1141
1142     X_PACKAGES="$X_PACKAGES xcomposite"
1143     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1144   fi
1145
1146   # Checks for Xdamage extension
1147
1148   if $PKG_CONFIG --exists xdamage ; then
1149     AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1150
1151     X_PACKAGES="$X_PACKAGES xdamage"
1152     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1153   fi
1154
1155   if $have_base_x_pc ; then
1156     GDK_EXTRA_LIBS="$x_extra_libs"
1157   else
1158     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1159   fi
1160
1161   CPPFLAGS="$gtk_save_cppflags"
1162   LIBS="$gtk_save_libs"
1163
1164   AM_CONDITIONAL(USE_X11, true)
1165 else
1166   XPACKAGES=
1167
1168   AM_CONDITIONAL(XINPUT_XFREE, false)
1169   AM_CONDITIONAL(XINPUT_2, false)
1170   AM_CONDITIONAL(USE_X11, false)
1171   AM_CONDITIONAL(HAVE_X11R6, false)
1172 fi
1173
1174 if test "x$gdktarget" = "xwin32"; then
1175   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
1176   AM_CONDITIONAL(USE_WIN32, true)
1177 else
1178   AM_CONDITIONAL(USE_WIN32, false)
1179 fi
1180
1181 if test "x$gdktarget" = "xquartz"; then
1182   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
1183   AM_CONDITIONAL(USE_QUARTZ, true)
1184 else
1185   AM_CONDITIONAL(USE_QUARTZ, false)
1186 fi
1187
1188 # Check for Pango flags
1189
1190 if test "x$gdktarget" = "xwin32"; then
1191         PANGO_PACKAGES="pangowin32 pangocairo"
1192 else
1193         PANGO_PACKAGES="pango pangocairo"
1194 fi
1195
1196 AC_MSG_CHECKING(Pango flags)
1197 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1198         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1199         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1200
1201         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1202 else
1203         AC_MSG_ERROR([
1204 *** Pango not found. Pango built with Cairo support is required
1205 *** to build GTK+. See http://www.pango.org for Pango information.
1206 ])
1207 fi
1208
1209 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1210
1211 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1212         :
1213 else
1214         gtk_save_LIBS="$LIBS"
1215         LIBS="$PANGO_LIBS $LIBS"
1216         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1217 *** Can't link to Pango. Pango is required to build
1218 *** GTK+. For more information see http://www.pango.org]))
1219         LIBS="$gtk_save_LIBS"
1220 fi
1221
1222 CFLAGS="$saved_cflags"
1223 LDFLAGS="$saved_ldflags"
1224
1225 # Pull in gio-unix for GDesktopAppInfo usage, see at least gdkapplaunchcontext-x11.c
1226 if test "x$gdktarget" = "xx11"; then
1227   GDK_PACKAGES="$PANGO_PACKAGES gio-unix-2.0 $X_PACKAGES gdk-pixbuf-2.0 cairo-$cairo_backend cairo-gobject"
1228 else
1229   GDK_PACKAGES="$PANGO_PACKAGES gio-2.0 gdk-pixbuf-2.0 cairo-$cairo_backend cairo-gobject"
1230 fi
1231
1232 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1233 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1234 #
1235 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1236 # into the pkg-config files
1237 #
1238 if test $enable_explicit_deps != yes ; then
1239   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0"
1240   GDK_EXTRA_LIBS=
1241 fi
1242
1243 AC_SUBST(GDK_PACKAGES)
1244 AC_SUBST(GDK_EXTRA_LIBS)
1245 AC_SUBST(GDK_EXTRA_CFLAGS)
1246 AC_SUBST(GDK_DEP_LIBS)
1247 AC_SUBST(GDK_DEP_CFLAGS)
1248
1249
1250 ########################################
1251 # Check for Accessibility Toolkit flags
1252 ########################################
1253
1254 ATK_PACKAGES=atk
1255 AC_MSG_CHECKING(ATK flags)
1256 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1257         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1258         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1259
1260         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1261 else
1262         AC_MSG_ERROR([
1263 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1264 *** to build GTK+.
1265 ])
1266 fi
1267
1268 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1269         :
1270 else
1271         gtk_save_LIBS="$LIBS"
1272         LIBS="$ATK_LIBS $LIBS"
1273         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1274                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1275                 *** to build GTK+]))
1276         LIBS="$gtk_save_LIBS"
1277 fi
1278
1279 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1280 if test "x$gdktarget" = "xx11"; then
1281   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1282 fi
1283 GTK_EXTRA_LIBS=
1284 GTK_EXTRA_CFLAGS=
1285 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1286 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1287
1288 if test x"$os_win32" = xyes; then
1289   GTK_EXTRA_CFLAGS="$msnative_struct"
1290 fi
1291
1292 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1293 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1294 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1295 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1296
1297 AC_SUBST(GTK_PACKAGES)
1298 AC_SUBST(GTK_EXTRA_LIBS)
1299 AC_SUBST(GTK_EXTRA_CFLAGS)
1300 AC_SUBST(GTK_DEP_LIBS)
1301 AC_SUBST(GTK_DEP_CFLAGS)
1302
1303 AC_SUBST(GLIB_PREFIX)
1304 AC_SUBST(ATK_PREFIX)
1305 AC_SUBST(PANGO_PREFIX)
1306 AC_SUBST(CAIRO_PREFIX)
1307
1308 AC_SUBST(GTK_DEBUG_FLAGS)
1309 AC_SUBST(GTK_XIM_FLAGS)
1310
1311 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1312 AC_SUBST(GDK_PIXBUF_LIBS)
1313
1314 ########################
1315 # Checks needed for gail
1316 ########################
1317
1318 old_LIBS="$LIBS"
1319 dnl Checks for inet libraries:
1320 AC_SEARCH_LIBS(gethostent, nsl)
1321 AC_SEARCH_LIBS(setsockopt, socket)
1322 AC_SEARCH_LIBS(connect, inet)
1323
1324 dnl check for the sockaddr_un.sun_len member
1325 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1326                 [struct_sockaddr_un_sun_len=true],
1327                 [struct_sockaddr_un_suin_len=false],
1328                 [#include <sys/types.h>
1329                  #include <sys/un.h>]
1330                 )
1331 case $struct_sockaddr_un_sun_len in
1332         true)
1333                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1334                                    [Have the sockaddr_un.sun_len member])
1335                 ;;
1336         *)
1337                 ;;
1338 esac
1339
1340 GAIL_INET_LIBS="$LIBS"
1341 AC_SUBST([GAIL_INET_LIBS])
1342
1343 LIBS="$old_LIBS"
1344
1345 ################################################################
1346 # Printing system checks
1347 ################################################################
1348
1349 AC_ARG_ENABLE(cups,
1350               [AC_HELP_STRING([--disable-cups]
1351                               [disable cups print backend])],,
1352               [enable_cups=auto])
1353
1354 if test "x$enable_cups" = "xno"; then
1355   AM_CONDITIONAL(HAVE_CUPS, false)
1356 else
1357   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1358   if test "x$CUPS_CONFIG" = "xno"; then
1359     if test "x$enable_cups" = "xauto"; then
1360       AM_CONDITIONAL(HAVE_CUPS, false)
1361     else
1362       AC_MSG_ERROR([
1363 *** cups not found.
1364 ])
1365     fi
1366   else
1367     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1368     CUPS_LIBS=`$CUPS_CONFIG --libs`
1369
1370     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1371     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1372     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1373
1374     if test $CUPS_API_MAJOR -gt 1 -o \
1375             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1376       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1377                 [Define to 1 if CUPS 1.2 API is available])
1378     fi
1379
1380     AC_SUBST(CUPS_API_MAJOR)
1381     AC_SUBST(CUPS_API_MINOR)
1382     AC_SUBST(CUPS_CFLAGS)
1383     AC_SUBST(CUPS_LIBS)
1384
1385     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1386
1387     AM_CONDITIONAL(HAVE_CUPS, true)
1388
1389     gtk_save_cflags="$CFLAGS"
1390     CFLAGS="$CUPS_CFLAGS"
1391     AC_TRY_COMPILE([#include <cups/http.h>],
1392                    [http_t http; char *s = http.authstring;],
1393                    [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1394                               [Define if cups http_t authstring field is accessible])],)
1395     CFLAGS="$gtk_save_cflags"
1396
1397     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1398
1399     gtk_save_libs="$LIBS"
1400     LIBS="$CUPS_LIBS"
1401     AC_CHECK_FUNCS(httpGetAuthString)
1402     LIBS="$gtk_save_libs"
1403   fi
1404 fi
1405
1406 # Checks to see if we should compile with PAPI backend for GTK+
1407 #
1408
1409 AC_ARG_ENABLE(papi,
1410               [AC_HELP_STRING([--disable-papi]
1411                               [disable papi print backend])],,
1412              [enable_papi=auto])
1413
1414 if test "x$enable_papi" = "xno"; then
1415   AM_CONDITIONAL(HAVE_PAPI, false)
1416 else
1417   AC_MSG_CHECKING(libpapi)
1418   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1419   if test $have_papi = yes; then
1420     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1421   fi
1422   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1423   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1424     AC_MSG_ERROR([
1425 *** papi not found.
1426 ])
1427   fi
1428 fi
1429
1430 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1431
1432 gtk_save_cppflags="$CPPFLAGS"
1433 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1434
1435 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1436 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1437 *** backend enabled.]))
1438
1439 if test "$os_win32" != "yes"; then
1440   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1441 *** Can't find cairo-ps.h. You must build Cairo with the
1442 *** postscript backend enabled.]))
1443
1444   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1445 *** Can't find cairo-svg.h. You must build Cairo with the
1446 *** svg backend enabled.]))
1447 fi
1448
1449 CPPFLAGS="$gtk_save_cppflags"
1450
1451
1452 AC_ARG_ENABLE(test-print-backend,
1453               [AC_HELP_STRING([--enable-test-print-backend],
1454                               [build test print backend])],,
1455               [enable_test_print_backend=no])
1456 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1457
1458
1459 ################################################################
1460 # Strip -export-dynamic from the link lines of various libraries
1461 ################################################################
1462
1463 #
1464 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1465 #  but this flag is only meaningful for executables. For libraries
1466 #  the effect is undefined; what it causes on Linux is that the
1467 #  export list from -export-symbols-regex is ignored and everything
1468 #  is exported
1469 #
1470 # We are using gmodule-no-export now, but I'm leaving the stripping
1471 # code in place for now, since pango and atk still require gmodule.
1472 export SED
1473 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1474 if test -n "$export_dynamic"; then
1475   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1476   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1477 fi
1478
1479 #############
1480 # GSettings #
1481 #############
1482
1483 GLIB_GSETTINGS
1484
1485 ##################################################
1486 # GObject introspection
1487 ##################################################
1488
1489 GOBJECT_INTROSPECTION_CHECK([0.9.3])
1490
1491 ##################################################
1492 # Checks for gtk-doc and docbook-tools
1493 ##################################################
1494
1495 GTK_DOC_CHECK([1.11])
1496
1497 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1498 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1499
1500 AC_ARG_ENABLE(man,
1501               [AC_HELP_STRING([--enable-man],
1502                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1503               enable_man=no)
1504
1505 if test "${enable_man}" != no; then
1506   dnl
1507   dnl Check for xsltproc
1508   dnl
1509   AC_PATH_PROG([XSLTPROC], [xsltproc])
1510   if test -z "$XSLTPROC"; then
1511     enable_man=no
1512   fi
1513
1514   dnl check for DocBook DTD and stylesheets in the local catalog.
1515   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1516      [DocBook XML DTD V4.1.2],,enable_man=no)
1517   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1518      [DocBook XSL Stylesheets],,enable_man=no)
1519 fi
1520
1521 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1522
1523
1524 ##################################################
1525 # Output commands
1526 ##################################################
1527
1528 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1529         outfile=gdkconfig.h-tmp
1530         cat > $outfile <<\_______EOF
1531 /* gdkconfig.h
1532  *
1533  * This is a generated file.  Please modify `configure.ac'
1534  */
1535
1536 #ifndef GDKCONFIG_H
1537 #define GDKCONFIG_H
1538
1539 #ifdef __cplusplus
1540 extern "C" {
1541 #endif /* __cplusplus */
1542
1543 #ifndef GSEAL
1544 /* introduce GSEAL() here for all of Gdk and Gtk+ without the need to modify GLib */
1545 #  ifdef GSEAL_ENABLE
1546 #    define GSEAL(ident)      _g_sealed__ ## ident
1547 #  else
1548 #    define GSEAL(ident)      ident
1549 #  endif
1550 #endif /* !GSEAL */
1551
1552 _______EOF
1553
1554         cat >>$outfile <<_______EOF
1555 $gdk_windowing
1556 $gdk_wc
1557 _______EOF
1558
1559         cat >>$outfile <<_______EOF
1560
1561 #ifdef __cplusplus
1562 }
1563 #endif /* __cplusplus */
1564
1565 #endif /* GDKCONFIG_H */
1566 _______EOF
1567
1568
1569         if cmp -s $outfile gdk/gdkconfig.h; then
1570           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1571           rm -f $outfile
1572         else
1573           mv $outfile gdk/gdkconfig.h
1574         fi
1575 ],[
1576 if test "x$gdktarget" = "xx11" ; then
1577   gdk_windowing='
1578 #define GDK_WINDOWING_X11'
1579 elif test "x$gdktarget" = "xwin32" ; then
1580   gdk_windowing='
1581 #define GDK_NATIVE_WINDOW_POINTER
1582
1583 #define GDK_WINDOWING_WIN32'
1584 elif test "x$gdktarget" = "xquartz" ; then
1585   gdk_windowing='
1586 #define GDK_WINDOWING_QUARTZ'
1587 fi
1588
1589 if test x$gdk_wchar_h = xyes; then
1590   gdk_wc='
1591 #define GDK_HAVE_WCHAR_H 1'
1592 fi
1593 if test x$gdk_wctype_h = xyes; then
1594   gdk_wc="\$gdk_wc
1595 #define GDK_HAVE_WCTYPE_H 1"
1596 fi
1597 if test x$gdk_working_wctype = xno; then
1598   gdk_wc="\$gdk_wc
1599 #define GDK_HAVE_BROKEN_WCTYPE 1"
1600 fi
1601 ])
1602
1603 dnl
1604 dnl Check for -Bsymbolic-functions linker flag used to avoid
1605 dnl intra-library PLT jumps, if available.
1606 dnl
1607 AC_ARG_ENABLE(Bsymbolic,
1608               [AC_HELP_STRING([--disable-Bsymbolic],
1609                               [avoid linking with -Bsymbolic])],,
1610               [SAVED_LDFLAGS="${LDFLAGS}"
1611                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1612                LDFLAGS=-Wl,-Bsymbolic-functions
1613                AC_TRY_LINK([], [int main (void) { return 0; }],
1614                            AC_MSG_RESULT(yes)
1615                            enable_Bsymbolic=yes,
1616                            AC_MSG_RESULT(no)
1617                            enable_Bsymbolic=no)
1618                LDFLAGS="${SAVED_LDFLAGS}"])
1619
1620 if test "x${enable_Bsymbolic}" == "xyes"; then
1621   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1622 fi
1623 AC_SUBST(GTK_LINK_FLAGS)
1624
1625 AC_CONFIG_FILES([
1626 config.h.win32
1627 gtk-zip.sh
1628 Makefile
1629 gdk-3.0.pc
1630 gtk+-3.0.pc
1631 gtk+-unix-print-3.0.pc
1632 gail-3.0.pc
1633 gdk-3.0-uninstalled.pc
1634 gtk+-3.0-uninstalled.pc
1635 gail-3.0-uninstalled.pc
1636 m4macros/Makefile
1637 po/Makefile.in
1638 po-properties/Makefile.in
1639 demos/Makefile
1640 demos/gtk-demo/Makefile
1641 demos/gtk-demo/geninclude.pl
1642 examples/Makefile
1643 tests/Makefile
1644 docs/Makefile
1645 docs/reference/Makefile
1646 docs/reference/gdk/Makefile
1647 docs/reference/gdk/version.xml
1648 docs/reference/gtk/Makefile
1649 docs/reference/gtk/version.xml
1650 docs/reference/libgail-util/Makefile
1651 docs/tools/Makefile
1652 build/Makefile
1653 build/win32/Makefile
1654 build/win32/vs9/Makefile
1655 gdk/Makefile
1656 gdk/x11/Makefile
1657 gdk/win32/Makefile
1658 gdk/win32/rc/Makefile
1659 gdk/win32/rc/gdk.rc
1660 gdk/quartz/Makefile
1661 gdk/tests/Makefile
1662 gtk/Makefile
1663 gtk/makefile.msc
1664 gtk/gtkversion.h
1665 gtk/gtk-win32.rc
1666 gtk/theme-bits/Makefile
1667 gtk/tests/Makefile
1668 modules/Makefile
1669 modules/other/Makefile
1670 modules/other/gail/Makefile
1671 modules/other/gail/libgail-util/Makefile
1672 modules/other/gail/tests/Makefile
1673 modules/engines/Makefile
1674 modules/engines/pixbuf/Makefile
1675 modules/engines/ms-windows/Makefile
1676 modules/engines/ms-windows/Theme/Makefile
1677 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1678 modules/input/Makefile
1679 modules/printbackends/Makefile
1680 modules/printbackends/cups/Makefile
1681 modules/printbackends/lpr/Makefile
1682 modules/printbackends/file/Makefile
1683 modules/printbackends/papi/Makefile
1684 modules/printbackends/test/Makefile
1685 perf/Makefile
1686 ])
1687
1688 AC_OUTPUT
1689
1690 echo "configuration:
1691         target:             $gdktarget"