Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 dnl Eric S. Raymond <esr@thyrsus.com>
   3 dnl
   4 dnl Process this file with autoconf to produce a configure script.
   5 dnl
   6
   7 AC_INIT([fetchmail],[6.2.6-pre5])
   8 AC_CONFIG_SRCDIR([fetchmail.h])
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CONFIG_LIBOBJ_DIR([.])
  11
  12 dnl we may need a newer automake version - the oldest tested is 1.7
  13 AC_PREREQ(2.59)
  14 AM_INIT_AUTOMAKE(1.5 foreign no-installinfo)
  15
  16 AC_PROG_AWK
  17 AC_PROG_CC
  18 AC_PROG_INSTALL
  19 AC_PROG_CPP                     dnl Later checks need this.
  20 AM_PROG_CC_C_O
  21 AC_AIX
  22 AC_ISC_POSIX
  23 AC_MINIX
  24 AC_HEADER_STDC
  25 AC_HEADER_TIME
  26 AC_TYPE_SIZE_T
  27 AC_TYPE_PID_T
  28 AC_TYPE_SIGNAL
  29 AC_CHECK_HEADERS([unistd.h termios.h termio.h sgtty.h stdarg.h \
  30         alloca.h sys/itimer.h fcntl.h sys/fcntl.h memory.h sys/wait.h \
  31         arpa/inet.h arpa/nameser.h netinet/in.h net/socket.h \
  32         sys/select.h sys/socket.h sys/time.h langinfo.h])
  33 AC_CHECK_HEADERS([resolv.h],,,[
  34 #include <sys/types.h>
  35 #ifdef HAVE_NETINET_IN_H
  36 #include <netinet/in.h>
  37 #endif
  38 #ifdef HAVE_ARPA_NAMESER_H
  39 #include <arpa/nameser.h>
  40 #endif
  41 ])
  42
  43 AC_C_CONST                      dnl getopt needs this.
  44
  45 AM_PROG_LEX
  46 AC_PROG_MAKE_SET
  47 AC_PROG_YACC
  48
  49 AC_FUNC_ALLOCA
  50
  51 # Check for LynxOS special case: -lbsd needed (at least on 2.3.0) and -s
  52 # not working.
  53 if test `uname` = "LynxOS"
  54 then
  55   echo "Adding -lbsd to standard libraries"
  56   LIBS="$LIBS -lbsd"
  57   LDFLAGS=""
  58   echo "Prepending standard include path to gcc flags"
  59   CPFLAGS="-I/usr/include"
  60 fi
  61
  62 # Check for FreeBSD special case: more libs needed
  63 if test `uname` = "FreeBSD"
  64 then
  65    echo "Adding -lmd -lkvm -lcom_err to standard libraries"
  66    LIBS="$LIBS -lmd -lkvm -lcom_err"
  67 fi
  68
  69 # Check for Rhapsody special case: it doesn't like -s
  70 if test `uname` = "Rhapsody"
  71 then
  72    echo "Removing -s load flag"
  73    LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
  74 fi
  75
  76 dnl i18n
  77 AM_GNU_GETTEXT(no-libtool, need-ngettext)
  78 AM_GNU_GETTEXT_VERSION(0.14.1)
  79 dnl end i18n
  80
  81 # Under sysV68, socket and friends are provided by the C library.
  82 # -linet does not provide socket, but causes multiple definition
  83 # errors at link-time.  It is thus better to only use the C library.
  84 # So don't add -linet to the link list unless it's necessary
  85 AC_CHECK_FUNC(socket,
  86     AC_MSG_RESULT(using libc's socket),
  87     AC_CHECK_LIB(socket,socket)
  88     AC_CHECK_LIB(inet,socket))
  89
  90 # The condition in this test copes with the presence of inet_addr in libc6.
  91 AC_CHECK_FUNC(inet_addr,
  92     AC_MSG_RESULT(using libc's inet_addr),
  93     AC_CHECK_LIB(nsl,inet_addr))
  94
  95 dnl Port hack for Interactive UNIX System V/386 Release 3.2
  96 AC_CHECK_LIB(cposix, strchr,
  97                 [DEFS="$DEFS -D_SYSV3"
  98                 LIBS="$LIBS -lcposix"])
  99
 100 dnl Port hack for Sparc/NetBSD-1.5
 101 AC_CHECK_LIB(intl, gettext,
 102                 [LIBS="$LIBS -lintl"])
 103
 104 AC_REPLACE_FUNCS([strstr strcasecmp memmove stpcpy strlcpy strlcat])
 105
 106 AC_CHECK_FUNC(MD5Init, [],
 107               [AC_LIBSOURCE(md5c.c)
 108                EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"])
 109
 110 AC_CHECK_FUNC(getopt_long, [],
 111               [AC_LIBSOURCES([getopt.c, getopt1.c])
 112                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 113
 114 AC_FUNC_VPRINTF
 115 if test -n "$ALLOCA"
 116 then
 117   EXTRAOBJ="$EXTRAOBJ alloca.\$(OBJEXT)"
 118 fi
 119
 120 AC_SUBST(EXTRAOBJ)
 121
 122 AC_CHECK_FUNCS(tcsetattr stty setsid geteuid seteuid gethostbyname \
 123   res_search strerror syslog \
 124   snprintf vprintf vsnprintf vsyslog \
 125   atexit inet_aton strftime setrlimit socketpair sigprocmask sigaction \
 126   strdup)
 127
 128 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 129 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 130 # library.  So don't add -lresolv to the link list unless it's necessary
 131 # (It will be necessary when using GNU libc6).
 132 AC_CHECK_FUNC(res_search,
 133     AC_MSG_RESULT(using libc's resolver functions),
 134     AC_CHECK_LIB(resolv,res_search,
 135         [AC_DEFINE(HAVE_RES_SEARCH) AC_MSG_RESULT(found resolver functions in libresolv); LIBS="$LIBS -lresolv"], AC_MSG_RESULT(no resolver calls found)))
 136
 137 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 138 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 139
 140 dnl Check for RSA refersence library in case we're using SSL
 141 AC_CHECK_LIB(rsaref, RSAPublicDecrypt)
 142
 143 dnl AC_FUNC_SETVBUF_REVERSED
 144
 145 dnl Check for usable void pointer type
 146 AC_MSG_CHECKING(use of void pointer type)
 147 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[char *p;
 148     void *xmalloc();
 149     p = (char *) xmalloc(1);
 150    ]])],[AC_DEFINE(HAVE_VOIDPOINTER,1,[Define if your C compiler allows void * as a function result]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 151
 152 dnl Check for ANSI volatile
 153 AC_C_VOLATILE
 154
 155 dnl Check out the wait reality.  We have to assume sys/wait.h is present.
 156 AC_CHECK_FUNCS(waitpid wait3)
 157 AC_MSG_CHECKING(for union wait);
 158 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 159 #include <sys/wait.h>]], [[union wait status; int pid; pid = wait (&status);
 160 #ifdef WEXITSTATUS
 161 /* Some POSIXoid systems have both the new-style macros and the old
 162    union wait type, and they do not work together.  If union wait
 163    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 164 if (WEXITSTATUS (status) != 0) pid = -1;
 165 #endif
 166 #ifdef HAVE_WAITPID
 167 /* Make sure union wait works with waitpid.  */
 168 pid = waitpid (-1, &status, 0);
 169 #endif
 170 ]])],[AC_DEFINE(HAVE_UNION_WAIT,1,Define if 'union wait' is the type of the first arg to wait functions.) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 171
 172 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 173 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 174 /* NetBSD declares sys_siglist in <unistd.h>.  */
 175 #ifdef HAVE_UNISTD_H
 176 #include <unistd.h>
 177 #endif]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 178
 179 # Find the right directory to put the root-mode PID file in
 180 for dir in "/var/run" "/etc"
 181 do
 182         if test -d $dir
 183         then
 184                 break;
 185         fi
 186 done
 187 AC_MSG_RESULT(root-mode pid file will go in $dir)
 188 AC_DEFINE_UNQUOTED(PID_DIR, "$dir", directory for PID lock files)
 189
 190 # We may have a fallback MDA available in case the socket open to the
 191 # local SMTP listener fails.  Best to use procmail for this, as we know
 192 # it won't try delivering through local SMTP and cause a mail loop.
 193 # Sendmail without the -t option to use the message headers will work too,
 194 # not just for sendmail itself but for workalikes like exim.
 195 #
 196 # Note1: A disadvantage of using procmail is that local alias expansion
 197 # according to /etc/aliases won't get done if we fall back.  This doesn't
 198 # matter in single-drop mode.
 199 #
 200 # Note2: it would be a very bad idea to use any MDA that doesn't return
 201 # a refuse-to-deliver status on disk- or process-table-full
 202 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 203 # like exim that might be lurking under a sendmail alias) do the right
 204 # thing in this circumstance.  Matthias Andree warns that procmail does
 205 # not.
 206 #
 207 # Note3: Defalt value of fallback is now off.  Matthias writes:
 208 #
 209 # 1. there is no way to predict when the fallback is used. With some MTAs
 210 #    (such as those limiting load average), outer circumstances can cause
 211 #    the fallback to kick in.
 212 #
 213 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 214 #    not only about alias expansion, .forwards to special filters won't
 215 #    work, mail may end up in a different place (users claim "mail loss"
 216 #    for that).
 217 #
 218 # 3. The claim procmail did the right thing with its exit codes is plain
 219 #    wrong. I've seen procmail exit with code 1 when it should have exited
 220 #    with code 75, like, configuration errors. Procmail is a dangerous
 221 #    beast and is best replaced by maildrop.
 222 #
 223 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 224 #    cannot tell which one it should choose. Say, your MTA is configured
 225 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 226 #    chooses procmail, this is plain wrong.
 227 #
 228
 229 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 230 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 231 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 232
 233 ###     use option --disable-fallback to disable fallback MDA
 234 ###     use option --enable-fallback=procmail or
 235 ###                --enable-fallback=sendmail to select
 236 AC_ARG_ENABLE(fallback,
 237         [  --enable-fallback=procmail    enable procmail as fallback
 238   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 239   --enable-fallback=maildrop    enable maildrop as fallback
 240   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 241
 242 case "$enable_fallback" in
 243         sendmail)       if test -z "$sendmail" ; then
 244                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 245                                 #not reached
 246                         fi
 247                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 248                         echo "Will use $sendmail as fallback MDA."
 249                         ;;
 250         procmail)       if test -z "$procmail" ; then
 251                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 252                                 #not reached
 253                         fi
 254                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 255                         echo "Will use $procmail as fallback MDA."
 256                         ;;
 257         maildrop)       if test -z "$maildrop" ; then
 258                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 259                                 #not reached
 260                         fi
 261                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 262                         echo "Will use $maildrop as fallback MDA."
 263                         ;;
 264         no|unset)       echo "Will not use a fallback MDA"
 265                         ;;
 266         auto|yes|set)   if test -n "$sendmail" ; then
 267                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 268                                 echo "Will use $sendmail as fallback MDA."
 269                         else
 270                                 echo "No fallback MDA available. procmail and maildrop are not eligible"
 271                                 echo "for automatic fallback MDA configuration for reliability reasons."
 272                         fi
 273                         ;;
 274         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 275                         #notreached
 276                         ;;
 277 esac
 278
 279 AC_CHECK_SIZEOF(short)
 280 AC_CHECK_SIZEOF(int)
 281 AC_CHECK_SIZEOF(long)
 282
 283 ###     use option --enable-POP2 to compile in the POP2 support
 284 AC_ARG_ENABLE(POP2,
 285         [  --enable-POP2           compile in POP2 protocol support (obsolete)],
 286         [with_POP2=$enableval],
 287         [with_POP2=no])
 288 test "$with_POP2" = "yes" && AC_DEFINE(POP2_ENABLE,1,Define if you want POP2 support compiled in)
 289
 290 ###     use option --disable-POP3 to omit the POP3 support
 291 AC_ARG_ENABLE(POP3,
 292         [  --disable-POP3          don't compile in POP3 protocol support],
 293         [with_POP3=$enableval],
 294         [with_POP3=yes])
 295 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 296
 297 ###     use option --disable-IMAP to omit the IMAP support
 298 AC_ARG_ENABLE(IMAP,
 299         [  --disable-IMAP          don't compile in IMAP protocol support],
 300         [with_IMAP=$enableval],
 301         [with_IMAP=yes])
 302 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,"Define if you want IMAP support compiled in")
 303
 304 ###     use option --disable-ETRN to omit the ETRN support
 305 AC_ARG_ENABLE(ETRN,
 306         [  --disable-ETRN          don't compile in ETRN protocol support],
 307         [with_ETRN=$enableval],
 308         [with_ETRN=yes])
 309 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 310
 311 ###     use option --disable-ODMR to omit the ODMR support
 312 AC_ARG_ENABLE(ODMR,
 313         [  --disable-ODMR          don't compile in ODMR protocol support],
 314         [with_ODMR=$enableval],
 315         [with_ODMR=yes])
 316 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 317
 318 ###     use option --enable-RPA to compile in the RPA support
 319 AC_ARG_ENABLE(RPA,
 320         [  --enable-RPA            compile in RPA protocol support],
 321         [with_RPA=$enableval],
 322         [with_RPA=no])
 323 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 324
 325 ###     use option --enable-NTLM to compile in the NTLM support
 326 AC_ARG_ENABLE(NTLM,
 327         [  --enable-NTLM           compile in NTLM authentication support],
 328         [with_NTLM=$enableval],
 329         [with_NTLM=no])
 330 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 331
 332 ###     use option --enable-SDPS to compile in the SDPS support
 333 AC_ARG_ENABLE(SDPS,
 334         [  --enable-SDPS           compile in SDPS protocol support],
 335         [with_SDPS=$enableval],
 336         [with_SDPS=no])
 337 test "$with_SDPS" = "yes" && AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 338
 339 ###     use option --enable-opie to compile in the OPIE support
 340 AC_ARG_ENABLE(opie,
 341         [  --enable-opie           support OTP through the OPIE library],
 342         [ AC_CHECK_HEADER(opie.h,, [echo 'configure: cannot find <opie.h>, which is required for OPIE support.'; exit 1])
 343           AC_CHECK_LIB(opie,opiegenerator,, [echo 'configure: cannot find libopie, which is required for OPIE support.'; exit 1])
 344           with_opie=$enableval],
 345         [with_opie=no])
 346 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 347
 348 ### XXX FIXME: the inet6-apps library is no longer available,
 349 ### http://www.inner.net/pub/ipv6/ states, as of 2005-07-03:
 350 ### "/pub/ipv6
 351 ### Our IPv6 software is now long defunct. Please find a more modern
 352 ### source."
 353 AC_ARG_ENABLE(inet6,
 354         [  --enable-inet6          support IPv6],
 355
 356         [ AC_CHECK_FUNC(getaddrinfo, [with_inet6=yes],
 357           [ LDFLAGS="$LDFLAGS -L/usr/inet6/lib";
 358             AC_CHECK_LIB(inet6, getaddrinfo, [with_inet6=yes
 359             LIBS="$LIBS -linet6"],
 360             [ echo 'configure: cannot find proper glibc version or libinet6,';
 361               echo '           which is required for IPv6 support.';
 362               exit 1]) ] )],
 363         [with_inet6=no])
 364 test "$with_inet6" = "yes" && AC_DEFINE(INET6_ENABLE,1,Define if you want IPv6 support compiled in)
 365
 366 AC_CHECK_FUNCS(inner_connect)
 367
 368 AC_ARG_ENABLE(netsec,
 369         [  --enable-netsec         support network security (requires inet6-apps library)],
 370         [ unset ac_cv_lib_inet6_net_security_strtorequest; AC_CHECK_LIB(inet6, net_security_strtorequest,,
 371           [ unset ac_cv_lib_inet6_net_security_strtorequest;
 372             LDFLAGS="$LDFLAGS -L/usr/inet6/lib";
 373             AC_CHECK_LIB(inet6, net_security_strtorequest,,
 374             [ echo 'configure: cannot find net_security_strtorequest in libinet6, which is required';
 375               echo '           for network security support. Either it does not exist, or it was';
 376               echo '           not built with network security support enabled.';
 377               exit 1]) ])
 378         unset ac_cv_header_net_security_h; AC_CHECK_HEADER(net/security.h,,
 379         [ unset ac_cv_header_net_security_h;
 380         CPPFLAGS="$CPPFLAGS -I/usr/inet6/include";
 381         CFLAGS="$CFLAGS -I/usr/inet6/include"; AC_CHECK_HEADER(net/security.h,,
 382           [ echo 'configure: cannot find <net/security.h>, which is required';
 383           echo '             for network security support.';
 384           exit 1]) ]) ]
 385         [with_netsec=no])
 386 test "$with_netsec" = "yes" && AC_DEFINE(NET_SECURITY,1,Define if you want network security support compiled in)
 387
 388 # This version of the Kerberos 4 and 5 options addresses the follwing issues:
 389 #
 390 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 391 #   OpenSSL support (Debian's is)
 392 # * Build the kerberos.c stuff (KPOP) only for kerberosIV, to avoid breakage.
 393 #   I don't know if this is 100% correct, but now at least IMAP and POP3
 394 #   behave the same way regarding kerberosV.
 395 # * Build without any fuss for both kerberosIV and V at the same time.
 396 # * Move all the kerberos header mess to kerberos.h, and #include that
 397 #   in driver.c and kerberos.c.
 398 #
 399 # Tested using the Heimdal Kerberos V libs, Kungliga Tekniska Högskolan (the
 400 # Royal Institute of Technology in Stockholm, Sweden)'s kerberos IV libs, and
 401 # the MIT reference implementation of KerberosV (all as packaged in Debian).
 402
 403 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 404 ### make sure --with-ssl is run before --with-kerberos* !
 405 AC_ARG_WITH(kerberos5,
 406        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5
 407 directory],
 408 [
 409 if test "$with_kerberos5" != "no"
 410 then
 411 # Check for a OpenBSD special case
 412 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 413 then
 414   AS_MESSAGE(checking kerberosV for OpenBSD...)
 415   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 416   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 417   CEFLAGS="$CEFLAGS -I/usr/include/kerberosV"
 418   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 419 elif krb5-config 2> /dev/null >/dev/null ; then
 420   krb5_prefix=`krb5-config --prefix krb5`
 421   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 422   if test -f ${krb5_prefix}/include/et/com_err.h && \
 423    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 424     CEFLAGS="$CEFLAGS -I${krb5_prefix}/include/et"
 425   fi
 426   unset krb5_prefix
 427   CEFLAGS="$CEFLAGS `krb5-config --cflags krb5`"
 428   LIBS="$LIBS `krb5-config --libs krb5`"
 429   AC_DEFINE(KERBEROS_V5)
 430 else
 431   if test "$with_kerberos5" != "yes"
 432   then
 433       LDEFLAGS="$LDEFLAGS -L${with_kerberos5}/lib"
 434       searchdirs="$with_kerberos5"
 435   else
 436       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 437   fi
 438   with_kerberos5=
 439   for dir in $searchdirs
 440   do AC_MSG_CHECKING([for Kerberos V in $dir])
 441      if test -f "$dir/include/krb5.h"
 442      then
 443         ac_krblibs=
 444         if test -f "$dir/include/roken.h"
 445         then
 446            ac_krblibs="-lasn1 -lroken -lcom_err"
 447            AC_MSG_RESULT([Heimdal found])
 448           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 449           dnl we assume we do if it is available
 450            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 451                 ${LDEFLAGS})
 452            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 453               AC_CHECK_LIB(ssl, MD5_Init, [],
 454                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 455                 ${LDEFLAGS} ${ac_krblibs}),
 456            ${LDEFLAGS} ${ac_krblibs})
 457            AC_DEFINE(HEIMDAL)
 458         else
 459           AC_MSG_RESULT([found])
 460           ac_krblibs="-lcom_err"
 461            AC_CHECK_LIB(crypto,
 462              krb5_des_string_to_key,
 463              libk5crypto=-lcrypto,
 464                 AC_CHECK_LIB(k5crypto,
 465                    krb5_des_string_to_key,
 466                    libk5crypto=-lk5crypto,
 467                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 468                    ${LDEFLAGS} ${ac_krblibs}),
 469                  ${LDEFLAGS} ${ac_krblibs})
 470         fi
 471         AC_CHECK_LIB(krb5, krb5_init_context,[],
 472            continue,
 473            ${LDEFLAGS} ${ac_krblibs})
 474         AC_DEFINE(KERBEROS_V5)
 475         test "$dir" != "/usr" && CEFLAGS="$CEFLAGS -I$dir/include"
 476         LDEFLAGS="$LDEFLAGS -L$dir/lib"
 477        LIBS="$LIBS $ac_krblibs $libk5crypto"
 478         with_kerberos5=$dir
 479         break
 480      else
 481         AC_MSG_RESULT([not found])
 482      fi
 483   done
 484   if test -z "$with_kerberos5" ; then
 485      AC_MSG_ERROR([Kerberos 5 libraries not found])
 486   fi
 487 fi
 488 fi
 489 ]) dnl --with-kerberos5=DIR
 490
 491 ###    use option --with-kerberos=DIR to point at a Kerberos 4 directory
 492 AC_ARG_WITH(kerberos,
 493        [  --with-kerberos=DIR     point fetchmail compilation at a Kerberos 4
 494 directory],
 495 [
 496 if test "$with_kerberos" != "no"
 497 then
 498 # Check for a NetBSD/OpenBSD special case
 499 if test "$with_kerberos" = "yes" && ( test `uname` = "NetBSD" || test `uname` = "OpenBSD" )
 500 then
 501   AS_MESSAGE(checking kerberosIV for `uname`...)
 502   AC_DEFINE(KERBEROS_V4,1,Define if you have Kerberos V4)
 503   CEFLAGS="$CEFLAGS -I/usr/include/kerberosIV"
 504   LIBS="$LIBS -lkrb -ldes"
 505 elif krb4-config 2> /dev/null >/dev/null ; then
 506   krb4_prefix=`krb4-config --prefix`
 507   AC_MSG_RESULT([krb4-config points to kerberosIV under $krb4_prefix])
 508   unset krb4_prefix
 509   CEFLAGS="$CEFLAGS `krb4-config --cflags`"
 510   LIBS="$LIBS `krb4-config --libs`"
 511   AC_DEFINE(KERBEROS_V4)
 512 elif krb5-config 2> /dev/null >/dev/null ; then
 513   krb4_prefix=`krb5-config --prefix krb4`
 514   AC_MSG_RESULT([krb5-config points to kerberosIV under $krb4_prefix])
 515   if test -f ${krb4_prefix}/include/kerberosIV/krb.h ; then
 516     AC_DEFINE(KERBEROS_V4_V5,1,Define if you have Kerberos V4 headers under a kerberosIV directory)
 517   fi
 518   unset krb4_prefix
 519   CEFLAGS="$CEFLAGS `krb5-config --cflags krb4`"
 520   LIBS="$LIBS `krb5-config --libs krb4`"
 521   AC_DEFINE(KERBEROS_V4)
 522 else
 523   #we need to detect when we're building under a kerberosV compatibility
 524   #layer, btw...
 525   if test "$with_kerberos" != "yes" ; then
 526      searchdirs="$with_kerberos"
 527   else
 528      searchdirs="$with_kerberos5 /usr/kerberos /usr/kerberosIV /usr/athena/usr"
 529   fi
 530   with_kerberos=
 531   ac_saveLDFLAGS="$LDFLAGS"
 532   for dir in $searchdirs
 533   do
 534      AC_MSG_CHECKING([for Kerberos IV in $dir])
 535      if test -f "$dir/include/krb.h" || test -f "$dir/include/krb4.h" \
 536             || test -f "$dir/include/kerberosIV/krb.h"
 537      then
 538         AC_MSG_RESULT([found])
 539      else
 540         AC_MSG_RESULT([not found])
 541        continue
 542      fi
 543      #Find libs
 544      if test -f "$with_kerberos5/roken.h" ; then
 545        AC_CHECK_LIB(45, krb_mk_req)
 546      fi
 547      LDFLAGS="-L$dir/lib $ac_saveLDFLAGS"
 548      AC_SEARCH_LIBS(des_string_to_key, [des425 des crypto], [], continue)
 549      AC_SEARCH_LIBS(krb_realmofhost, [krb4 krb], [], continue)
 550      with_kerberos="$dir"
 551      if test -f "$dir/include/kerberosIV/krb.h" ; then
 552         dir="$dir/include/kerberosIV"
 553      else
 554        dir="$dir/include"
 555      fi
 556      AC_DEFINE(KERBEROS_V4)
 557      test -f "$with_kerberos5/roken.h" && AC_DEFINE(HEIMDAL)
 558      test "$dir" != "/usr/include" && CEFLAGS="$CEFLAGS -I$dir"
 559      LDEFLAGS="$LDEFLAGS -L$with_kerberos/lib"
 560      break
 561   done
 562   if test -z "$with_kerberos" ; then
 563      AC_MSG_ERROR([Kerberos 4 libraries not found])
 564   fi
 565   LDFLAGS="$ac_saveLDFLAGS"
 566 fi
 567 fi
 568 ]) dnl --with-kerberos=DIR
 569
 570 ###     use option --with-ssl to compile in the SSL support
 571 AC_ARG_WITH(ssl,
 572         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 573         [with_ssl=$withval],
 574         [with_ssl=no])
 575 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 576
 577 if test "$with_ssl" = "yes"
 578 then
 579     #   He didn't specify an SSL location.  Let's look at some common
 580     #   directories where SSL has been found in the past and try and auto
 581     #   configure for SSL.  OpenSSL determination will be made later.
 582     #   This will screw up if an OpenSSL install is located in a later
 583     #   directory than an older SSLeay install, but the user should fix that
 584     #   anyways and he can override on the configure line.
 585     #   Just testing for directories is not sufficient, /usr exists on
 586     #   all systems!
 587     for ac_dir in \
 588       /usr/local/ssl \
 589       /usr/local \
 590       /usr/ssl \
 591       /usr \
 592       /local/ssl \
 593       /opt/ssl \
 594       /opt/csw \
 595       ; \
 596     do
 597         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 598             with_ssl=$ac_dir
 599             break;
 600         fi
 601     done
 602 fi
 603
 604 if test -n "$with_ssl" -a "$with_ssl" != "no"
 605 then
 606   # With the autoconfigure above, the only time this is going to be
 607   # true is going to be when we could not find the headers.  If they
 608   # are not in system standard locations, we are going to be broken.
 609   if test "$with_ssl" = "yes"
 610   then
 611     # Let's just define the standard location for the SSLeay root
 612     with_ssl="/usr/local/ssl"
 613   fi
 614   if test -r $with_ssl/include/openssl/ssl.h
 615   then
 616     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 617     echo "Enabling OpenSSL support in $with_ssl"
 618     test "$with_ssl" != "/usr" && CEFLAGS="$CEFLAGS -I$with_ssl/include"
 619     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 620     ### force the Kerberos direcory onto the include path so it will build.
 621     CEFLAGS="$CEFLAGS -I/usr/kerberos/include"
 622     ### OpenBSD comes with ssl headers
 623   else
 624     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 625   fi
 626   LDEFLAGS="$LDEFLAGS -L$with_ssl/lib"
 627   LIBS="$LIBS -lssl -lcrypto"
 628   AC_DEFINE(SSL_ENABLE)
 629 else
 630   echo 'Disabling SSL support...'
 631 fi
 632
 633 ###     use option --with-socks=DIR to point at SOCKS library
 634 AC_ARG_WITH(socks,
 635         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 636 [
 637 if test "$with_socks" != no
 638 then
 639     if test "$with_socks" != yes
 640     then
 641         LDEFLAGS="$LDEFLAGS -L$with_socks"
 642     else
 643         AC_CHECK_LIB(socks, Rconnect,,
 644                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 645     fi
 646     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 647     CEFLAGS="$CEFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 648     LIBS="-lsocks $LIBS"
 649 fi])
 650
 651 ###     use option --with-socks5=DIR to point at SOCKS library
 652 AC_ARG_WITH(socks5,
 653         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 654 [
 655 if test "$with_socks5" != no
 656 then
 657   if test "$with_socks5" != yes
 658   then
 659     LDEFLAGS="$LDEFLAGS -L$with_socks5"
 660   fi
 661   ac_savedLDFLAGS="$LDFLAGS"
 662   LDFLAGS="$LDEFLAGS $LDFLAGS"
 663   AC_CHECK_LIB(socks5, SOCKSconnect,,
 664         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 665   AC_DEFINE(HAVE_SOCKS)
 666   CEFLAGS="$CEFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 667   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 668   LDFLAGS="$ac_savedLDFLAGS"
 669 fi])
 670
 671 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 672 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 673
 674 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 675 AC_ARG_WITH(gssapi,
 676         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 677 [
 678 if test "$with_gssapi" != "no"
 679 then
 680   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 681   then
 682     with_gssapi=$with_kerberos5
 683   fi
 684   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 685   then
 686     CFLAGS="$CFLAGS -I$with_gssapi/include"
 687     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 688   fi
 689
 690   AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 691   if test -n "$nogss"
 692   then
 693   if test -f "$with_gssapi/include/roken.h"
 694   then
 695      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl"
 696      AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 697                   AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 698      AC_DEFINE(HEIMDAL)
 699   else
 700      AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 701                   AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 702   fi
 703   fi
 704   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 705   save_CPPFLAGS=$CPPFLAGS
 706   CPPFLAGS="-I$with_gssapi/include"
 707   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 708   if test "$ac_cv_header_gssapi_h" = "yes"; then
 709     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 710   else
 711     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 712   fi
 713 fi])
 714
 715 AC_SUBST(CPFLAGS)
 716 AC_SUBST(CEFLAGS)
 717 AC_SUBST(LDEFLAGS)
 718
 719 dnl ,------------------------------------------------------------------
 720 dnl Check if we need TRIO
 721 needtrio=0
 722 if test "$FORCE_TRIO" = "yes" ; then
 723     needtrio=1
 724     ac_cv_func_vsnprintf=no
 725     ac_cv_func_snprintf=no
 726 fi
 727 if test "x$ac_cv_func_snprintf" != "xyes" ; then
 728     AC_DEFINE(snprintf, trio_snprintf,
 729               [Define to trio_snprintf if your system lacks snprintf])
 730     needtrio=1
 731 fi
 732 if test "x$ac_cv_func_vsnprintf" != "xyes" ; then
 733     AC_DEFINE(vsnprintf, trio_vsnprintf,
 734               [Define to trio_vsnprintf if your system lacks vsnprintf])
 735     needtrio=1
 736 fi
 737 AM_CONDITIONAL(NEED_TRIO, test "$needtrio" = 1)
 738
 739 dnl TRIO IEEE compiler option for Alpha
 740 dnl
 741 if test "$needtrio" = 1 ; then
 742     AC_MSG_CHECKING(for IEEE compilation options)
 743     AC_CACHE_VAL(ac_cv_ieee_option, [
 744     AC_TRY_COMPILE(,[
 745     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
 746     # error "Option needed"
 747     #endif
 748     ],ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
 749     AC_TRY_COMPILE(,[
 750     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
 751     # error "Option needed"
 752     #endif
 753     ],ac_cv_ieee_option="-ieee",
 754     AC_TRY_COMPILE(,[
 755     #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
 756     # error "Option needed"
 757     #endif
 758     ],ac_cv_ieee_option="-mieee",
 759     ac_cv_ieee_option="none"
 760     )
 761     )
 762     )
 763     ])
 764     AC_MSG_RESULT($ac_cv_ieee_option)
 765     if test $ac_cv_ieee_option != none; then
 766       CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
 767     fi
 768 fi
 769 dnl ----------------------------------------------------------------'
 770
 771 AC_CONFIG_FILES([Makefile m4/Makefile m4-local/Makefile
 772                 po/Makefile.in intl/Makefile])
 773 AC_OUTPUT
 774
 775 dnl Local Variables:
 776 dnl comment-start: "dnl "
 777 dnl comment-end: ""
 778 dnl comment-start-skip: "\\bdnl\\b\\s *"
 779 dnl compile-command: "make configure config.h.in"
 780 dnl End: