Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ([2.62])
   4
   5 AC_INIT([gtk+], [gtk_version],
   6         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
   7         [gtk+])
   8
   9 AC_CONFIG_HEADER([config.h])
  10 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 # Making releases:
  14 #   GTK_MICRO_VERSION += 1;
  15 #   GTK_INTERFACE_AGE += 1;
  16 #   GTK_BINARY_AGE += 1;
  17 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  18 # if backwards compatibility has been broken,
  19 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  20
  21 m4_define([gtk_major_version], [2])
  22 m4_define([gtk_minor_version], [91])
  23 m4_define([gtk_micro_version], [1])
  24 m4_define([gtk_interface_age], [0])
  25 m4_define([gtk_binary_age],
  26           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  27 m4_define([gtk_version],
  28           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  29 # This is the X.Y used in -lgtk-FOO-X.Y
  30 m4_define([gtk_api_version], [3.0])
  31
  32 # Define a string for the earliest version that this release has
  33 # backwards binary compatibility with for all interfaces a module
  34 # might. Unless we add module-only API with lower stability
  35 # guarantees, this should be unchanged until we break binary compat
  36 # for GTK+.
  37 #
  38 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  39 m4_define([gtk_binary_version], [3.0.0])
  40
  41 # required versions of other packages
  42 m4_define([glib_required_version], [2.27.0])
  43 m4_define([pango_required_version], [1.20])
  44 m4_define([atk_required_version], [1.29.2])
  45 m4_define([cairo_required_version], [1.10.0])
  46 m4_define([gdk_pixbuf_required_version], [2.21.0])
  47 GLIB_REQUIRED_VERSION=glib_required_version
  48 PANGO_REQUIRED_VERSION=pango_required_version
  49 ATK_REQUIRED_VERSION=atk_required_version
  50 CAIRO_REQUIRED_VERSION=cairo_required_version
  51 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  52 AC_SUBST(GLIB_REQUIRED_VERSION)
  53 AC_SUBST(PANGO_REQUIRED_VERSION)
  54 AC_SUBST(ATK_REQUIRED_VERSION)
  55 AC_SUBST(CAIRO_REQUIRED_VERSION)
  56 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  57
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules, requires at least automake-1.11. Enable
  66 # by either passing --enable-silent-rules to configure or passing V=0
  67 # to make
  68 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([no])])
  69
  70 #
  71 # For each of the libraries we build, we define the following
  72 # substituted variables:
  73 #
  74 # foo_PACKAGES:     pkg-config packages this library requires
  75 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  76 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  77 # foo_DEP_LIBS:     All libraries this module requires
  78 # foo_DEP_CFLAGS:   All cflags this module requires
  79
  80
  81 GTK_MAJOR_VERSION=gtk_major_version
  82 GTK_MINOR_VERSION=gtk_minor_version
  83 GTK_MICRO_VERSION=gtk_micro_version
  84 GTK_INTERFACE_AGE=gtk_interface_age
  85 GTK_BINARY_AGE=gtk_binary_age
  86 GTK_VERSION=gtk_version
  87 GTK_API_VERSION=gtk_api_version
  88 GTK_BINARY_VERSION=gtk_binary_version
  89 AC_SUBST(GTK_MAJOR_VERSION)
  90 AC_SUBST(GTK_MINOR_VERSION)
  91 AC_SUBST(GTK_MICRO_VERSION)
  92 AC_SUBST(GTK_INTERFACE_AGE)
  93 AC_SUBST(GTK_BINARY_AGE)
  94 AC_SUBST(GTK_API_VERSION)
  95 AC_SUBST(GTK_VERSION)
  96 AC_SUBST(GTK_BINARY_VERSION)
  97
  98 # libtool versioning
  99 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 100 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 101 #LT_REVISION=$GTK_INTERFACE_AGE
 102 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 103 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 104
 105 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 106 m4_define([lt_revision], [gtk_interface_age])
 107 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 108 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 109 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 110 AC_SUBST(LT_VERSION_INFO)
 111 AC_SUBST(LT_CURRENT_MINUS_AGE)
 112
 113 m4_define([gail_lt_current],[0])
 114 m4_define([gail_lt_revision],[0])
 115 m4_define([gail_lt_age],[0])
 116 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 117 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 118 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 119 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 120
 121 # Checks for programs.
 122 AC_PROG_CC
 123 AC_PROG_CC_C_O
 124 AC_PROG_CC_STDC
 125 AC_PROG_INSTALL
 126 AC_PROG_MAKE_SET
 127
 128
 129 GETTEXT_PACKAGE=gtk30
 130 AC_SUBST(GETTEXT_PACKAGE)
 131 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 132                    [The prefix for our gettext translation domains.])
 133
 134 AC_CANONICAL_HOST
 135
 136 MATH_LIB=-lm
 137 AC_MSG_CHECKING([for native Win32])
 138 LIB_EXE_MACHINE_FLAG=X86
 139 EXE_MANIFEST_ARCHITECTURE=X86
 140 case "$host" in
 141   *-*-mingw*)
 142     os_win32=yes
 143     gio_can_sniff=no
 144     MATH_LIB=
 145     case "$host" in
 146     x86_64-*-*)
 147       LIB_EXE_MACHINE_FLAG=X64
 148       EXE_MANIFEST_ARCHITECTURE=AMD64
 149       ;;
 150     esac
 151     ;;
 152   *)
 153     os_win32=no
 154     ;;
 155 esac
 156 AC_MSG_RESULT([$os_win32])
 157
 158 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 159 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 160
 161 case $host in
 162   *-*-linux*)
 163     os_linux=yes
 164     ;;
 165 esac
 166
 167 dnl
 168 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 169 dnl We use this for an automated test for C++ header correctness.
 170 dnl
 171 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 172 AC_LANG_PUSH([C++])
 173
 174 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 175 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 176
 177 gtk_save_cxxflags="$CXXFLAGS"
 178 CXXFLAGS="$CXXFLAGS -x objective-c++"
 179 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 180 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 181 CXXFLAGS="$gtk_save_cxxflags"
 182 AC_LANG_POP([C++])
 183
 184 if test "$os_win32" = "yes"; then
 185   if test x$enable_static = xyes -o x$enable_static = x; then
 186     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 187     enable_static=no
 188   fi
 189   if test x$enable_shared = xno; then
 190     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 191   fi
 192   enable_shared=yes
 193 fi
 194
 195 dnl Initialize libtool
 196 LT_PREREQ([2.2.6])
 197 LT_INIT([disable-static win32-dll])
 198 # Create libtool early, because it's used in configure
 199 LT_OUTPUT
 200
 201 # Make sure we use 64-bit versions of various file stuff.
 202 AC_SYS_LARGEFILE
 203
 204 AM_PROG_AS
 205 AC_PATH_PROG(NM, nm, nm)
 206
 207 AC_MSG_CHECKING([for some Win32 platform])
 208 case "$host" in
 209   *-*-mingw*|*-*-cygwin*)
 210     platform_win32=yes
 211     ;;
 212   *)
 213     platform_win32=no
 214     ;;
 215 esac
 216 AC_MSG_RESULT([$platform_win32])
 217 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 218
 219 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 220 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 221 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 222
 223 if test "$os_win32" = "yes"; then
 224   AC_CHECK_TOOL(WINDRES, windres, no)
 225   if test "$WINDRES" = no; then
 226     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 227   fi
 228   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 229 fi
 230 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 231
 232 m4_define([debug_default],
 233           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 234
 235 dnl declare --enable-* args and collect ac_help strings
 236 AC_ARG_ENABLE(debug,
 237               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 238                              [turn on debugging @<:@default=debug_default@:>@]),,
 239               enable_debug=debug_default)
 240 AC_ARG_ENABLE(xkb,
 241               [AC_HELP_STRING([--enable-xkb],
 242                               [support XKB [default=maybe]])],,
 243               [enable_xkb="maybe"])
 244 AC_ARG_ENABLE(xinerama,
 245               [AC_HELP_STRING([--enable-xinerama],
 246                               [support xinerama extension if available [default=yes]])],,
 247               [enable_xinerama="yes"])
 248 AC_ARG_ENABLE(rebuilds,
 249               [AC_HELP_STRING([--disable-rebuilds],
 250                               [disable all source autogeneration rules])],,
 251               [enable_rebuilds=yes])
 252
 253 AC_ARG_WITH(xinput,
 254             [AC_HELP_STRING([--with-xinput=@<:@no/yes@:>@], [support XInput])])
 255
 256 if test "$platform_win32" = yes; then
 257   gdktarget=win32
 258 else
 259   gdktarget=x11
 260 fi
 261
 262 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/win32/quartz]] select non-default GDK target],
 263         gdktarget=$with_gdktarget)
 264
 265 AC_SUBST(gdktarget)
 266 case $gdktarget in
 267   x11|win32|quartz) ;;
 268   *) AC_MSG_ERROR([Invalid target for GDK: use x11, quartz or win32.]);;
 269 esac
 270
 271 gdktargetlib=libgdk-$gdktarget-$GTK_API_VERSION.la
 272 gtktargetlib=libgtk-$gdktarget-$GTK_API_VERSION.la
 273
 274 AC_SUBST(gdktargetlib)
 275 AC_SUBST(gtktargetlib)
 276
 277 if test "x$enable_debug" = "xyes"; then
 278   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 279   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 280 else
 281   if test "x$enable_debug" = "xno"; then
 282     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 283   else
 284     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 285   fi
 286 fi
 287
 288
 289 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 290                    [Define if debugging is enabled])
 291
 292
 293 # Build time sanity check...
 294 AM_SANITY_CHECK
 295
 296 changequote(,)dnl
 297 if test "x$GCC" = "xyes"; then
 298   case " $CFLAGS " in
 299   *[\ \ ]-Wall[\ \      ]*) ;;
 300   *) CFLAGS="$CFLAGS -Wall" ;;
 301   esac
 302
 303   if test "x$enable_ansi" = "xyes"; then
 304     case " $CFLAGS " in
 305     *[\ \       ]-ansi[\ \      ]*) ;;
 306     *) CFLAGS="$CFLAGS -ansi" ;;
 307     esac
 308
 309     case " $CFLAGS " in
 310     *[\ \       ]-pedantic[\ \  ]*) ;;
 311     *) CFLAGS="$CFLAGS -pedantic" ;;
 312     esac
 313   fi
 314 fi
 315 changequote([,])dnl
 316
 317 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 318
 319 # Ensure MSVC-compatible struct packing convention is used when
 320 # compiling for Win32 with gcc.
 321 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 322 # gcc2 uses "-fnative-struct".
 323 if test x"$os_win32" = xyes; then
 324   if test x"$GCC" = xyes; then
 325     msnative_struct=''
 326     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 327     if test -z "$ac_cv_prog_CC"; then
 328       our_gcc="$CC"
 329     else
 330       our_gcc="$ac_cv_prog_CC"
 331     fi
 332     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 333       2.)
 334         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 335           msnative_struct='-fnative-struct'
 336         fi
 337         ;;
 338       *)
 339         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 340           msnative_struct='-mms-bitfields'
 341         fi
 342         ;;
 343     esac
 344     if test x"$msnative_struct" = x ; then
 345       AC_MSG_RESULT([no way])
 346       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 347     else
 348       CFLAGS="$CFLAGS $msnative_struct"
 349       AC_MSG_RESULT([${msnative_struct}])
 350     fi
 351   fi
 352 fi
 353
 354 ## Initial sanity check, done here so that users get told they
 355 ## have the wrong dependencies as early in the process as possible.
 356 ## Later on we actually use the cflags/libs from separate pkg-config
 357 ## calls. Oh, also the later pkg-config calls don't include
 358 ## the version requirements since those make the module lists
 359 ## annoying to construct
 360 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 361   [glib-2.0 >= glib_required_version dnl
 362    atk >= atk_required_version dnl
 363    pango >= pango_required_version dnl
 364    cairo >= cairo_required_version dnl
 365    cairo-gobject >= cairo_required_version dnl
 366    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 367
 368 ## In addition to checking that cairo is present, we also need to
 369 ## check that the correct cairo backend is there. E.g. if the GDK
 370 ## target is win32 we need the cairo-win32 backend and so on.
 371 cairo_backend=$gdktarget
 372
 373 # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 374 # backend names are identical.
 375 if test "x$cairo_backend" = "xx11"; then
 376    cairo_backend=xlib
 377 fi
 378 PKG_CHECK_MODULES(CAIRO_BACKEND,
 379   [cairo-$cairo_backend >= cairo_required_version])
 380
 381 if test "$os_win32" != yes; then
 382     # libtool option to control which symbols are exported
 383     # right now, symbols starting with _ are not exported
 384     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 385 else
 386     # We currently use .def files on Windows (for gdk and gtk)
 387     LIBTOOL_EXPORT_OPTIONS=
 388 fi
 389 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 390
 391 dnl ******************************************************
 392 dnl * See whether to include shared library dependencies *
 393 dnl ******************************************************
 394
 395 AC_ARG_ENABLE(explicit-deps,
 396               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 397                               [use explicit dependencies in .pc files [default=auto]])],,
 398               [enable_explicit_deps=auto])
 399
 400 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 401 case $enable_explicit_deps in
 402   auto)
 403     export SED
 404     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 405     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 406       enable_explicit_deps=yes
 407     else
 408       enable_explicit_deps=no
 409     fi
 410   ;;
 411   yes|no)
 412   ;;
 413   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 414   ;;
 415 esac
 416 AC_MSG_RESULT($enable_explicit_deps)
 417
 418 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 419
 420 # define a MAINT-like variable REBUILD which is set if Perl
 421 # and awk are found, so autogenerated sources can be rebuilt
 422
 423 AC_PATH_PROGS(PERL, perl5 perl)
 424
 425 # We would like indent, but don't require it.
 426 AC_CHECK_PROG(INDENT, indent, indent)
 427
 428 REBUILD=\#
 429 if test "x$enable_rebuilds" = "xyes" && \
 430      test -n "$PERL" && \
 431      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 432   REBUILD=
 433 fi
 434 AC_SUBST(REBUILD)
 435
 436 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 437 AC_CHECK_FUNCS(localtime_r)
 438
 439 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 440 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 441 AC_TRY_LINK([#include <langinfo.h>], [
 442 char c;
 443 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 444 ], gtk_ok=yes, gtk_ok=no)
 445 AC_MSG_RESULT($gtk_ok)
 446 if test "$gtk_ok" = "yes"; then
 447   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 448             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 449 fi
 450
 451 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 452 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 453 AC_TRY_LINK([#include <langinfo.h>], [
 454 char c;
 455 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 456 ], gtk_ok=yes, gtk_ok=no)
 457 AC_MSG_RESULT($gtk_ok)
 458 if test "$gtk_ok" = "yes"; then
 459   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 460             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 461 fi
 462
 463 # _NL_PAPER_HEIGHT is an enum and not a define
 464 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 465 AC_TRY_LINK([#include <langinfo.h>], [
 466 char c;
 467 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 468 ], gtk_ok=yes, gtk_ok=no)
 469 AC_MSG_RESULT($gtk_ok)
 470 if test "$gtk_ok" = "yes"; then
 471   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 472             [Define if _NL_PAPER_HEIGHT is available])
 473 fi
 474
 475 # _NL_PAPER_WIDTH is an enum and not a define
 476 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 477 AC_TRY_LINK([#include <langinfo.h>], [
 478 char c;
 479 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 480 ], gtk_ok=yes, gtk_ok=no)
 481 AC_MSG_RESULT($gtk_ok)
 482 if test "$gtk_ok" = "yes"; then
 483   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 484             [Define if _NL_PAPER_WIDTH is available])
 485 fi
 486
 487 # i18n stuff
 488 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 489 AM_GLIB_GNU_GETTEXT
 490 LIBS="$LIBS $INTLLIBS"
 491 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 492         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 493       esac])
 494
 495 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 496 dnl po-properties/POTFILES during configure; see GNOME #573515.
 497 dnl
 498 dnl Generate list of files to be processed by xgettext which will
 499 dnl be included in po-properties/Makefile.
 500 test -d po-properties || mkdir po-properties
 501 if test "x$srcdir" != "x."; then
 502   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 503     popropsrcprefix="$srcdir/"
 504   else
 505     popropsrcprefix="../$srcdir/"
 506   fi
 507 else
 508   popropsrcprefix="../"
 509 fi
 510 rm -f po-properties/POTFILES
 511 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 512 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 513 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 514
 515 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 516
 517 dnl The DU4 header files don't provide library prototypes unless
 518 dnl -std1 is given to the native cc.
 519 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 520
 521 gtk_save_LIBS=$LIBS
 522 LIBS="$LIBS -lm"
 523 AC_TRY_RUN([#include <math.h>
 524              int main (void) { return (log(1) != log(1.)); }],
 525      AC_MSG_RESULT(none needed),
 526      gtk_save_CFLAGS="$CFLAGS"
 527      CFLAGS="$CFLAGS -std1"
 528      AC_TRY_RUN([#include <math.h>
 529                  int main (void) { return (log(1) != log(1.)); }],
 530          AC_MSG_RESULT(-std1),
 531          AC_MSG_RESULT()
 532          CFLAGS="$gtk_save_CFLAGS"
 533          AC_MSG_WARN(
 534                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 535          true
 536      ),
 537      AC_MSG_RESULT(none needed)
 538 )
 539 LIBS=$gtk_save_LIBS
 540
 541 AC_MSG_CHECKING(for the BeOS)
 542 case $host in
 543   *-*-beos*)
 544     AC_MSG_RESULT(yes)
 545     MATH_LIB=
 546   ;;
 547   *)
 548     AC_MSG_RESULT(no)
 549   ;;
 550 esac
 551
 552 AC_SUBST(MATH_LIB)
 553 #
 554 # see bug 162979
 555 #
 556 AC_MSG_CHECKING(for HP-UX)
 557 case $host_os in
 558   hpux9* | hpux10* | hpux11*)
 559     AC_MSG_RESULT(yes)
 560     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 561   ;;
 562   *)
 563     AC_MSG_RESULT(no)
 564   ;;
 565 esac
 566
 567 dnl NeXTStep cc seems to need this
 568 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 569 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 570   AC_MSG_RESULT(none needed),
 571   gtk_save_CFLAGS="$CFLAGS"
 572   CFLAGS="$CFLAGS -posix"
 573   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 574     AC_MSG_RESULT(-posix),
 575     AC_MSG_RESULT()
 576     CFLAGS="$gtk_save_CFLAGS"
 577     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 578
 579 #
 580 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 581 #
 582
 583 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 584
 585 AM_PATH_GLIB_2_0(glib_required_version, :,
 586   AC_MSG_ERROR([
 587 *** GLIB glib_required_version or better is required. The latest version of
 588 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 589   gobject gmodule-no-export gthread)
 590
 591 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 592 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 593 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 594 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 595   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 596 fi
 597
 598 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 599
 600
 601 dnl
 602 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 603 dnl
 604 gtk_save_LIBS=$LIBS
 605 LIBS="$LIBS $GLIB_LIBS"
 606 AC_CHECK_FUNCS(bind_textdomain_codeset)
 607 LIBS=$gtk_save_LIBS
 608
 609 AC_CHECK_HEADERS(pwd.h,
 610                  AC_DEFINE(HAVE_PWD_H, 1,
 611                            [Define to 1 if pwd.h is available]))
 612 AC_CHECK_HEADERS(sys/time.h,
 613                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 614                            [Define to 1 if time.h is available]))
 615 AC_CHECK_HEADERS(unistd.h,
 616                  AC_DEFINE(HAVE_UNISTD_H, 1,
 617                            [Define to 1 if unistd.h is available]))
 618 AC_CHECK_HEADERS(ftw.h,
 619                  AC_DEFINE(HAVE_FTW_H, 1,
 620                            [Define to 1 if ftw.h is available]))
 621
 622 AC_MSG_CHECKING([for GNU ftw extensions])
 623 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 624 #define _GNU_SOURCE
 625 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 626 if test $gtk_ok = yes; then
 627     AC_MSG_RESULT([yes])
 628     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 629 else
 630     AC_MSG_RESULT([no])
 631 fi
 632
 633 saved_cflags="$CFLAGS"
 634 saved_ldflags="$LDFLAGS"
 635
 636
 637 # Checks for header files.
 638 AC_HEADER_STDC
 639
 640 # Checks for typedefs, structures, and compiler characteristics.
 641 AC_C_CONST
 642
 643 # Checks for library functions.
 644 AC_TYPE_SIGNAL
 645 AC_FUNC_MMAP
 646
 647 AC_CHECK_FUNCS(mallinfo)
 648 AC_CHECK_FUNCS(getresuid)
 649 AC_TYPE_UID_T
 650
 651 # Check if <sys/select.h> needs to be included for fd_set
 652 AC_MSG_CHECKING([for fd_set])
 653 AC_TRY_COMPILE([#include <sys/types.h>],
 654         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 655 if test $gtk_ok = yes; then
 656     AC_MSG_RESULT([yes, found in sys/types.h])
 657 else
 658     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 659     if test $gtk_ok = yes; then
 660         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 661                   [Define to 1 if sys/select.h is available])
 662         AC_MSG_RESULT([yes, found in sys/select.h])
 663     else
 664         AC_DEFINE(NO_FD_SET, 1,
 665                   [Define to 1 if fd_set is not available])
 666         AC_MSG_RESULT(no)
 667     fi
 668 fi
 669
 670 # `widechar' tests for gdki18n.h
 671 AC_MSG_CHECKING(for wchar.h)
 672 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 673 if test $gdk_wchar_h = yes; then
 674    AC_DEFINE(HAVE_WCHAR_H, 1, [Have wchar.h include file])
 675 fi
 676 AC_MSG_RESULT($gdk_wchar_h)
 677
 678 # Check for wctype.h (for iswalnum)
 679 AC_MSG_CHECKING(for wctype.h)
 680 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 681 if test $gdk_wctype_h = yes; then
 682    AC_DEFINE(HAVE_WCTYPE_H, 1, [Have wctype.h include file])
 683 fi
 684 AC_MSG_RESULT($gdk_wctype_h)
 685
 686 # in Solaris 2.5, `iswalnum' is in -lw
 687 GDK_WLIBS=
 688 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 689
 690 oLIBS="$LIBS"
 691 LIBS="$LIBS $GDK_WLIBS"
 692 # The following is necessary for Linux libc-5.4.38
 693 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 694 AC_TRY_LINK([#include <stdlib.h>],[
 695 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 696 #  ifdef HAVE_WCTYPE_H
 697 #    include <wctype.h>
 698 #  else
 699 #    ifdef HAVE_WCHAR_H
 700 #      include <wchar.h>
 701 #    endif
 702 #  endif
 703 #else
 704 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 705 #endif
 706 iswalnum((wchar_t) 0);
 707 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 708 LIBS="$oLIBS"
 709
 710 if test $gdk_working_wctype = no; then
 711    AC_DEFINE(HAVE_BROKEN_WCTYPE, 1, [Is the wctype implementation broken])
 712    GDK_WLIBS=
 713 fi
 714 AC_MSG_RESULT($gdk_working_wctype)
 715 AC_SUBST(GDK_WLIBS)
 716
 717 # Check for uxtheme.h (for MS-Windows Engine)
 718 AC_MSG_CHECKING(for uxtheme.h)
 719 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 720 if test $gtk_uxtheme_h = yes; then
 721    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 722 fi
 723 AC_MSG_RESULT($gtk_uxtheme_h)
 724
 725 # Checks for gdkspawn
 726 AC_CHECK_HEADERS(crt_externs.h)
 727 AC_CHECK_FUNCS(_NSGetEnviron)
 728
 729 AC_MSG_CHECKING(whether to build dynamic modules)
 730
 731 AC_ARG_ENABLE(modules,
 732               [AC_HELP_STRING([--disable-modules],
 733                               [disable dynamic module loading])])
 734
 735 dynworks=false
 736 deps=
 737 if test x$enable_modules = xno; then
 738     AC_MSG_RESULT(no)
 739 else
 740     AC_MSG_RESULT(yes)
 741     AC_MSG_CHECKING(whether dynamic modules work)
 742     ## for loop is to strip newline
 743     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 744     for I in $tmp; do
 745         dynworks=$I
 746     done
 747
 748     dnl Now we check to see if our libtool supports shared lib deps
 749     dnl (in a rather ugly way even)
 750     if $dynworks; then
 751         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 752         module_deplibs_check=`$module_libtool_config | \
 753             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 754             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 755         if test "x$module_deplibs_check" = "xnone" || \
 756            test "x$module_deplibs_check" = "xunknown" || \
 757            test "x$module_deplibs_check" = "x"; then
 758             dynworks=false
 759         fi
 760     fi
 761
 762     if $dynworks; then
 763         AC_DEFINE(USE_GMODULE, 1,
 764                   [Define to 1 if gmodule works and should be used])
 765         AC_MSG_RESULT(yes)
 766     else
 767         AC_MSG_RESULT(no)
 768     fi
 769 fi
 770
 771 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 772
 773 #
 774 # Allow building some or all immodules included
 775 #
 776 AC_MSG_CHECKING(immodules to build)
 777
 778 dnl due to an autoconf bug, commas in the first arg to
 779 dnl AC_HELP_STRING cause problems.
 780 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
 781 dnl                [build the specified input method modules into gtk])
 782 AC_ARG_WITH(included_immodules,
 783 [  --with-included-immodules=MODULE1,MODULE2,...
 784                           build the specified input methods into gtk])
 785
 786 if $dynworks; then
 787    :
 788 else
 789    ## if the option was specified, leave it; otherwise disable included immodules
 790    if test x$with_included_immodules = xno; then
 791            with_included_immodules=yes
 792    fi
 793 fi
 794
 795 all_immodules="am-et,cedilla,cyrillic-translit"
 796 if test "$gdktarget" = "win32"; then
 797    all_immodules="${all_immodules},ime"
 798 fi
 799 all_immodules="${all_immodules},inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr"
 800 if test "$gdktarget" = "x11"; then
 801    all_immodules="${all_immodules},xim"
 802 fi
 803
 804 included_immodules=""
 805 # If the switch specified without listing any specific ones, include all
 806 if test "x$with_included_immodules" = xyes ; then
 807   included_immodules="$all_immodules"
 808 else
 809   included_immodules="$with_included_immodules"
 810 fi
 811
 812 AC_MSG_RESULT($included_immodules)
 813 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 814
 815 INCLUDED_IMMODULE_OBJ=
 816 INCLUDED_IMMODULE_DEFINE=
 817
 818 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 819 for immodule in $included_immodules; do
 820  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 821  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 822    :
 823  else
 824    AC_MSG_ERROR([the specified input method $immodule does not exist])
 825  fi
 826
 827  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 828  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 829  eval INCLUDE_$immodule_underscores=yes
 830 done
 831 IFS="$gtk_save_ifs"
 832 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 833 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 834
 835 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 836 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 837 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 838 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 839 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 840 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 841 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 842 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 843 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 844 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 845 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 846 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 847
 848 AC_HEADER_SYS_WAIT
 849
 850 AC_TYPE_SIGNAL
 851
 852 # Checks to see whether we should include mediaLib
 853 # support.
 854 #
 855 AC_CHECK_HEADER(sys/systeminfo.h,
 856                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 857                           [Define to 1 if sys/systeminfo.h is available]))
 858 AC_CHECK_HEADER(sys/sysinfo.h,
 859                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 860                           [Define to 1 if sys/sysinfo.h is available]))
 861
 862 AC_MSG_CHECKING(for mediaLib 2.3)
 863 use_mlib25=no
 864 # Check for a mediaLib 2.3 function since that is what the GTK+ mediaLib
 865 # patch requires.
 866 AC_CHECK_LIB(mlib, mlib_ImageSetStruct, use_mlib=yes, use_mlib=no)
 867 if test $use_mlib = yes; then
 868     AC_DEFINE(USE_MEDIALIB, 1,
 869               [Define to 1 if medialib is available and should be used])
 870     MEDIA_LIB=-lmlib
 871
 872     AC_MSG_CHECKING(for mediaLib 2.5)
 873     # Check for a mediaLib 2.5 function since that is what is needed for
 874     # gdk_rgb_convert integration.
 875     AC_CHECK_LIB(mlib, mlib_VideoColorRGBint_to_BGRAint, use_mlib25=yes, use_mlib25=no)
 876     if test $use_mlib25 = yes; then
 877         AC_DEFINE(USE_MEDIALIB25, 1,
 878                   [Define to 1 if medialib 2.5 is available])
 879     fi
 880 fi
 881 AM_CONDITIONAL(USE_MEDIALIB, test $use_mlib = yes)
 882 AM_CONDITIONAL(USE_MEDIALIB25, test $use_mlib25 = yes)
 883
 884 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 885
 886 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 887
 888 if test $cross_compiling = yes; then
 889   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 890   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 891     REBUILD_PNGS=#
 892   fi
 893 fi
 894
 895 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 896
 897 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 898    test "x$REBUILD_PNGS" = "x#" ; then
 899      AC_MSG_ERROR([
 900 *** gtkbuiltincache.h is not in the tree, and cannot be built
 901 *** because you don't have libpng, or (when cross-compiling) you
 902 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 903 fi
 904
 905 ########################################
 906 # Windowing system checks
 907 ########################################
 908
 909 GDK_EXTRA_LIBS="$GDK_WLIBS"
 910 GDK_EXTRA_CFLAGS=
 911
 912 # GTK+ uses some X calls, so needs to link against X directly
 913 GTK_DEP_PACKAGES_FOR_X=
 914 GTK_DEP_LIBS_FOR_X=
 915
 916 if test "x$gdktarget" = "xx11"; then
 917   X_PACKAGES=fontconfig
 918
 919   #
 920   # We use fontconfig very peripherally when decoding the default
 921   # settings.
 922   #
 923   if $PKG_CONFIG --exists fontconfig; then : ; else
 924     AC_MSG_ERROR([
 925 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 926   fi
 927
 928   #
 929   # Check for basic X packages; we use pkg-config if available
 930   #
 931   if $PKG_CONFIG --exists x11 xext; then
 932     have_base_x_pc=true
 933     X_PACKAGES="$X_PACKAGES x11 xext"
 934     x_libs="`$PKG_CONFIG --libs x11 xext`"
 935     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 936
 937     # Strip out any .la files that pkg-config might give us (this happens
 938     # with -uninstalled.pc files)
 939     x_libs_for_checks=
 940     for I in $x_libs ; do
 941       case $I in
 942         *.la) ;;
 943         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 944       esac
 945     done
 946
 947     GTK_PACKAGES_FOR_X="x11"
 948   else
 949     have_base_x_pc=false
 950     AC_PATH_XTRA
 951     if test x$no_x = xyes ; then
 952       AC_MSG_ERROR([X development libraries not found])
 953     fi
 954
 955     x_cflags="$X_CFLAGS"
 956     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 957
 958     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 959   fi
 960
 961   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 962   x_extra_libs=
 963
 964   gtk_save_cppflags="$CPPFLAGS"
 965   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 966
 967   gtk_save_LIBS=$LIBS
 968   LIBS="$x_libs_for_checks $LIBS"
 969
 970   # Sanity check for the X11 and Xext libraries. While everything we need from
 971   # Xext is optional, the chances a system has *none* of these things is so
 972   # small that we just unconditionally require it.
 973   AC_CHECK_FUNC(XOpenDisplay, :,
 974                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 975   AC_CHECK_FUNC(XextFindDisplay, :,
 976                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 977
 978   # Check for xReply
 979
 980   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 981   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
 982       [xReply *rep;],
 983       [AC_MSG_RESULT([no])],
 984       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
 985 #include <X11/Xlibint.h>],
 986            [xReply *rep;],
 987            [AC_MSG_RESULT([yes])
 988             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
 989                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
 990            [AC_MSG_RESULT([unknown])
 991             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 992
 993   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 994
 995   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 996
 997   # Generic X11R6 check needed for XIM support; we could
 998   # probably use this to replace the above, but we'll
 999   # leave the separate checks for XConvertCase and XInternAtoms
1000   # for clarity
1001
1002   have_x11r6=false
1003   AC_CHECK_FUNC(XAddConnectionWatch,
1004       have_x11r6=true)
1005
1006   if $have_x11r6; then
1007     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1008   fi
1009   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1010
1011   # Check for XKB support.
1012
1013   if test "x$enable_xkb" = "xyes"; then
1014         AC_MSG_WARN(XKB support explicitly enabled)
1015         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
1016   elif test "x$enable_xkb" = "xmaybe"; then
1017         AC_CHECK_FUNC(XkbQueryExtension,
1018                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1019   else
1020         AC_MSG_WARN(XKB support explicitly disabled)
1021   fi
1022
1023   # Check for shaped window extension
1024
1025   AC_CHECK_FUNC(XShapeCombineMask, :,
1026      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1027
1028   # X SYNC check
1029   gtk_save_CFLAGS="$CFLAGS"
1030   CFLAGS="$CFLAGS $x_cflags"
1031
1032   AC_CHECK_FUNC(XSyncQueryExtension,
1033       [AC_CHECK_HEADER(X11/extensions/sync.h,
1034           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1035           :, [#include <X11/Xlib.h>])])
1036
1037   CFLAGS="$gtk_save_CFLAGS"
1038
1039   if test "x$enable_xinerama" = "xyes"; then
1040     # Check for Xinerama extension (Solaris impl or Xfree impl)
1041     gtk_save_cppflags="$CPPFLAGS"
1042     CPPFLAGS="$CPPFLAGS $x_cflags"
1043
1044     # Check for XFree
1045     AC_MSG_CHECKING(for Xinerama support on XFree86)
1046
1047     have_xfree_xinerama=false
1048     if $PKG_CONFIG --exists xinerama ; then
1049        have_xfree_xinerama=true
1050        X_PACKAGES="$X_PACKAGES xinerama"
1051     else
1052        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1053            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1054            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1055            have_xfree_xinerama=true], :,
1056            [#include <X11/Xlib.h>])])
1057     fi
1058
1059     if $have_xfree_xinerama ; then
1060       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1061                 [Define to 1 if XFree Xinerama is available])
1062       AC_DEFINE(HAVE_XINERAMA, 1,
1063                 [Define to 1 is Xinerama is available])
1064       AC_MSG_RESULT(yes)
1065     else
1066       AC_MSG_RESULT(no)
1067
1068       case "$host" in
1069         *-*-solaris*)
1070             # Check for solaris
1071             AC_MSG_CHECKING(for Xinerama support on Solaris)
1072
1073             have_solaris_xinerama=false
1074             AC_CHECK_FUNC(XineramaGetInfo,
1075                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1076                     [have_solaris_xinerama=true], :,
1077                     [#include <X11/Xlib.h>])])
1078
1079             if $have_solaris_xinerama ; then
1080               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1081                         [Define to 1 if solaris xinerama is available])
1082               AC_DEFINE(HAVE_XINERAMA, 1,
1083                         [Define to 1 if xinerama is available])
1084               AC_MSG_RESULT(yes)
1085             else
1086               AC_MSG_RESULT(no)
1087             fi
1088             ;;
1089         *)
1090             ;;
1091       esac
1092     fi
1093   fi
1094
1095   # set up things for XInput
1096   if test "x$with_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1097     have_xinput=yes
1098
1099     AC_DEFINE(XINPUT_XFREE, 1,
1100               [Define to 1 if XFree XInput should be used])
1101
1102     X_PACKAGES="$X_PACKAGES xi"
1103
1104     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1105                     have_xinput2=yes; AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1106   else
1107     AC_DEFINE(XINPUT_NONE, 1,
1108               [Define to 1 if no XInput should be used])
1109   fi
1110
1111   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1112   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1113
1114   # Check for the RANDR extension
1115   if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1116      AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1117
1118      X_PACKAGES="$X_PACKAGES xrandr"
1119   fi
1120
1121   # Checks for Xcursor library
1122
1123   if $PKG_CONFIG --exists xcursor ; then
1124     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1125
1126     X_PACKAGES="$X_PACKAGES xcursor"
1127   fi
1128
1129   # Checks for XFixes extension
1130
1131   if $PKG_CONFIG --exists xfixes ; then
1132     AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1133
1134     X_PACKAGES="$X_PACKAGES xfixes"
1135     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1136   fi
1137
1138   # Checks for Xcomposite extension
1139
1140   if $PKG_CONFIG --exists xcomposite ; then
1141     AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1142
1143     X_PACKAGES="$X_PACKAGES xcomposite"
1144     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1145   fi
1146
1147   # Checks for Xdamage extension
1148
1149   if $PKG_CONFIG --exists xdamage ; then
1150     AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1151
1152     X_PACKAGES="$X_PACKAGES xdamage"
1153     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1154   fi
1155
1156   if $have_base_x_pc ; then
1157     GDK_EXTRA_LIBS="$x_extra_libs"
1158   else
1159     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1160   fi
1161
1162   CPPFLAGS="$gtk_save_cppflags"
1163   LIBS="$gtk_save_libs"
1164
1165   AM_CONDITIONAL(USE_X11, true)
1166 else
1167   XPACKAGES=
1168
1169   AM_CONDITIONAL(XINPUT_XFREE, false)
1170   AM_CONDITIONAL(XINPUT_2, false)
1171   AM_CONDITIONAL(USE_X11, false)
1172   AM_CONDITIONAL(HAVE_X11R6, false)
1173 fi
1174
1175 if test "x$gdktarget" = "xwin32"; then
1176   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
1177   AM_CONDITIONAL(USE_WIN32, true)
1178 else
1179   AM_CONDITIONAL(USE_WIN32, false)
1180 fi
1181
1182 if test "x$gdktarget" = "xquartz"; then
1183   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
1184   AM_CONDITIONAL(USE_QUARTZ, true)
1185 else
1186   AM_CONDITIONAL(USE_QUARTZ, false)
1187 fi
1188
1189 # Check for Pango flags
1190
1191 if test "x$gdktarget" = "xwin32"; then
1192         PANGO_PACKAGES="pangowin32 pangocairo"
1193 else
1194         PANGO_PACKAGES="pango pangocairo"
1195 fi
1196
1197 AC_MSG_CHECKING(Pango flags)
1198 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1199         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1200         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1201
1202         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1203 else
1204         AC_MSG_ERROR([
1205 *** Pango not found. Pango built with Cairo support is required
1206 *** to build GTK+. See http://www.pango.org for Pango information.
1207 ])
1208 fi
1209
1210 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1211
1212 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1213         :
1214 else
1215         gtk_save_LIBS="$LIBS"
1216         LIBS="$PANGO_LIBS $LIBS"
1217         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1218 *** Can't link to Pango. Pango is required to build
1219 *** GTK+. For more information see http://www.pango.org]))
1220         LIBS="$gtk_save_LIBS"
1221 fi
1222
1223 CFLAGS="$saved_cflags"
1224 LDFLAGS="$saved_ldflags"
1225
1226 # Pull in gio-unix for GDesktopAppInfo usage, see at least gdkapplaunchcontext-x11.c
1227 if test "x$gdktarget" = "xx11"; then
1228   GDK_PACKAGES="$PANGO_PACKAGES gio-unix-2.0 $X_PACKAGES gdk-pixbuf-2.0 cairo-$cairo_backend cairo-gobject"
1229 else
1230   GDK_PACKAGES="$PANGO_PACKAGES gio-2.0 gdk-pixbuf-2.0 cairo-$cairo_backend cairo-gobject"
1231 fi
1232
1233 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1234 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1235 #
1236 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1237 # into the pkg-config files
1238 #
1239 if test $enable_explicit_deps != yes ; then
1240   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0"
1241   GDK_EXTRA_LIBS=
1242 fi
1243
1244 AC_SUBST(GDK_PACKAGES)
1245 AC_SUBST(GDK_EXTRA_LIBS)
1246 AC_SUBST(GDK_EXTRA_CFLAGS)
1247 AC_SUBST(GDK_DEP_LIBS)
1248 AC_SUBST(GDK_DEP_CFLAGS)
1249
1250
1251 ########################################
1252 # Check for Accessibility Toolkit flags
1253 ########################################
1254
1255 ATK_PACKAGES=atk
1256 AC_MSG_CHECKING(ATK flags)
1257 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1258         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1259         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1260
1261         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1262 else
1263         AC_MSG_ERROR([
1264 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1265 *** to build GTK+.
1266 ])
1267 fi
1268
1269 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1270         :
1271 else
1272         gtk_save_LIBS="$LIBS"
1273         LIBS="$ATK_LIBS $LIBS"
1274         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1275                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1276                 *** to build GTK+]))
1277         LIBS="$gtk_save_LIBS"
1278 fi
1279
1280 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1281 if test "x$gdktarget" = "xx11"; then
1282   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1283 fi
1284 GTK_EXTRA_LIBS=
1285 GTK_EXTRA_CFLAGS=
1286 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1287 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1288
1289 if test x"$os_win32" = xyes; then
1290   GTK_EXTRA_CFLAGS="$msnative_struct"
1291 fi
1292
1293 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1294 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1295 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1296 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1297
1298 AC_SUBST(GTK_PACKAGES)
1299 AC_SUBST(GTK_EXTRA_LIBS)
1300 AC_SUBST(GTK_EXTRA_CFLAGS)
1301 AC_SUBST(GTK_DEP_LIBS)
1302 AC_SUBST(GTK_DEP_CFLAGS)
1303
1304 AC_SUBST(GLIB_PREFIX)
1305 AC_SUBST(ATK_PREFIX)
1306 AC_SUBST(PANGO_PREFIX)
1307 AC_SUBST(CAIRO_PREFIX)
1308
1309 AC_SUBST(GTK_DEBUG_FLAGS)
1310 AC_SUBST(GTK_XIM_FLAGS)
1311
1312 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1313 AC_SUBST(GDK_PIXBUF_LIBS)
1314
1315 ########################
1316 # Checks needed for gail
1317 ########################
1318
1319 old_LIBS="$LIBS"
1320 dnl Checks for inet libraries:
1321 AC_SEARCH_LIBS(gethostent, nsl)
1322 AC_SEARCH_LIBS(setsockopt, socket)
1323 AC_SEARCH_LIBS(connect, inet)
1324
1325 dnl check for the sockaddr_un.sun_len member
1326 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1327                 [struct_sockaddr_un_sun_len=true],
1328                 [struct_sockaddr_un_suin_len=false],
1329                 [#include <sys/types.h>
1330                  #include <sys/un.h>]
1331                 )
1332 case $struct_sockaddr_un_sun_len in
1333         true)
1334                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1335                                    [Have the sockaddr_un.sun_len member])
1336                 ;;
1337         *)
1338                 ;;
1339 esac
1340
1341 GAIL_INET_LIBS="$LIBS"
1342 AC_SUBST([GAIL_INET_LIBS])
1343
1344 LIBS="$old_LIBS"
1345
1346 ################################################################
1347 # Printing system checks
1348 ################################################################
1349
1350 AC_ARG_ENABLE(cups,
1351               [AC_HELP_STRING([--disable-cups]
1352                               [disable cups print backend])],,
1353               [enable_cups=auto])
1354
1355 if test "x$enable_cups" = "xno"; then
1356   AM_CONDITIONAL(HAVE_CUPS, false)
1357 else
1358   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1359   if test "x$CUPS_CONFIG" = "xno"; then
1360     if test "x$enable_cups" = "xauto"; then
1361       AM_CONDITIONAL(HAVE_CUPS, false)
1362     else
1363       AC_MSG_ERROR([
1364 *** cups not found.
1365 ])
1366     fi
1367   else
1368     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1369     CUPS_LIBS=`$CUPS_CONFIG --libs`
1370
1371     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1372     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1373     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1374
1375     if test $CUPS_API_MAJOR -gt 1 -o \
1376             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1377       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1378                 [Define to 1 if CUPS 1.2 API is available])
1379     fi
1380
1381     AC_SUBST(CUPS_API_MAJOR)
1382     AC_SUBST(CUPS_API_MINOR)
1383     AC_SUBST(CUPS_CFLAGS)
1384     AC_SUBST(CUPS_LIBS)
1385
1386     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1387
1388     AM_CONDITIONAL(HAVE_CUPS, true)
1389
1390     gtk_save_cflags="$CFLAGS"
1391     CFLAGS="$CUPS_CFLAGS"
1392     AC_TRY_COMPILE([#include <cups/http.h>],
1393                    [http_t http; char *s = http.authstring;],
1394                    [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1395                               [Define if cups http_t authstring field is accessible])],)
1396     CFLAGS="$gtk_save_cflags"
1397
1398     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1399
1400     gtk_save_libs="$LIBS"
1401     LIBS="$CUPS_LIBS"
1402     AC_CHECK_FUNCS(httpGetAuthString)
1403     LIBS="$gtk_save_libs"
1404   fi
1405 fi
1406
1407 # Checks to see if we should compile with PAPI backend for GTK+
1408 #
1409
1410 AC_ARG_ENABLE(papi,
1411               [AC_HELP_STRING([--disable-papi]
1412                               [disable papi print backend])],,
1413              [enable_papi=auto])
1414
1415 if test "x$enable_papi" = "xno"; then
1416   AM_CONDITIONAL(HAVE_PAPI, false)
1417 else
1418   AC_MSG_CHECKING(libpapi)
1419   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1420   if test $have_papi = yes; then
1421     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1422   fi
1423   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1424   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1425     AC_MSG_ERROR([
1426 *** papi not found.
1427 ])
1428   fi
1429 fi
1430
1431 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1432
1433 gtk_save_cppflags="$CPPFLAGS"
1434 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1435
1436 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1437 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1438 *** backend enabled.]))
1439
1440 if test "$os_win32" != "yes"; then
1441   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1442 *** Can't find cairo-ps.h. You must build Cairo with the
1443 *** postscript backend enabled.]))
1444
1445   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1446 *** Can't find cairo-svg.h. You must build Cairo with the
1447 *** svg backend enabled.]))
1448 fi
1449
1450 CPPFLAGS="$gtk_save_cppflags"
1451
1452
1453 AC_ARG_ENABLE(test-print-backend,
1454               [AC_HELP_STRING([--enable-test-print-backend],
1455                               [build test print backend])],,
1456               [enable_test_print_backend=no])
1457 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1458
1459
1460 ################################################################
1461 # Strip -export-dynamic from the link lines of various libraries
1462 ################################################################
1463
1464 #
1465 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1466 #  but this flag is only meaningful for executables. For libraries
1467 #  the effect is undefined; what it causes on Linux is that the
1468 #  export list from -export-symbols-regex is ignored and everything
1469 #  is exported
1470 #
1471 # We are using gmodule-no-export now, but I'm leaving the stripping
1472 # code in place for now, since pango and atk still require gmodule.
1473 export SED
1474 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1475 if test -n "$export_dynamic"; then
1476   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1477   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1478 fi
1479
1480 #############
1481 # GSettings #
1482 #############
1483
1484 GLIB_GSETTINGS
1485
1486 ##################################################
1487 # GObject introspection
1488 ##################################################
1489
1490 GOBJECT_INTROSPECTION_CHECK([0.9.3])
1491
1492 ##################################################
1493 # Checks for gtk-doc and docbook-tools
1494 ##################################################
1495
1496 GTK_DOC_CHECK([1.11])
1497
1498 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1499 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1500
1501 AC_ARG_ENABLE(man,
1502               [AC_HELP_STRING([--enable-man],
1503                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1504               enable_man=no)
1505
1506 if test "${enable_man}" != no; then
1507   dnl
1508   dnl Check for xsltproc
1509   dnl
1510   AC_PATH_PROG([XSLTPROC], [xsltproc])
1511   if test -z "$XSLTPROC"; then
1512     enable_man=no
1513   fi
1514
1515   dnl check for DocBook DTD and stylesheets in the local catalog.
1516   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1517      [DocBook XML DTD V4.1.2],,enable_man=no)
1518   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1519      [DocBook XSL Stylesheets],,enable_man=no)
1520 fi
1521
1522 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1523
1524
1525 ##################################################
1526 # Output commands
1527 ##################################################
1528
1529 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1530         outfile=gdkconfig.h-tmp
1531         cat > $outfile <<\_______EOF
1532 /* gdkconfig.h
1533  *
1534  * This is a generated file.  Please modify `configure.ac'
1535  */
1536
1537 #ifndef GDKCONFIG_H
1538 #define GDKCONFIG_H
1539
1540 #ifdef __cplusplus
1541 extern "C" {
1542 #endif /* __cplusplus */
1543
1544 #ifndef GSEAL
1545 /* introduce GSEAL() here for all of Gdk and Gtk+ without the need to modify GLib */
1546 #  ifdef GSEAL_ENABLE
1547 #    define GSEAL(ident)      _g_sealed__ ## ident
1548 #  else
1549 #    define GSEAL(ident)      ident
1550 #  endif
1551 #endif /* !GSEAL */
1552
1553 _______EOF
1554
1555         cat >>$outfile <<_______EOF
1556 $gdk_windowing
1557 $gdk_wc
1558 _______EOF
1559
1560         cat >>$outfile <<_______EOF
1561
1562 #ifdef __cplusplus
1563 }
1564 #endif /* __cplusplus */
1565
1566 #endif /* GDKCONFIG_H */
1567 _______EOF
1568
1569
1570         if cmp -s $outfile gdk/gdkconfig.h; then
1571           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1572           rm -f $outfile
1573         else
1574           mv $outfile gdk/gdkconfig.h
1575         fi
1576 ],[
1577 if test "x$gdktarget" = "xx11" ; then
1578   gdk_windowing='
1579 #define GDK_WINDOWING_X11'
1580 elif test "x$gdktarget" = "xwin32" ; then
1581   gdk_windowing='
1582 #define GDK_NATIVE_WINDOW_POINTER
1583
1584 #define GDK_WINDOWING_WIN32'
1585 elif test "x$gdktarget" = "xquartz" ; then
1586   gdk_windowing='
1587 #define GDK_WINDOWING_QUARTZ'
1588 fi
1589
1590 if test x$gdk_wchar_h = xyes; then
1591   gdk_wc='
1592 #define GDK_HAVE_WCHAR_H 1'
1593 fi
1594 if test x$gdk_wctype_h = xyes; then
1595   gdk_wc="\$gdk_wc
1596 #define GDK_HAVE_WCTYPE_H 1"
1597 fi
1598 if test x$gdk_working_wctype = xno; then
1599   gdk_wc="\$gdk_wc
1600 #define GDK_HAVE_BROKEN_WCTYPE 1"
1601 fi
1602 ])
1603
1604 dnl
1605 dnl Check for -Bsymbolic-functions linker flag used to avoid
1606 dnl intra-library PLT jumps, if available.
1607 dnl
1608 AC_ARG_ENABLE(Bsymbolic,
1609               [AC_HELP_STRING([--disable-Bsymbolic],
1610                               [avoid linking with -Bsymbolic])],,
1611               [SAVED_LDFLAGS="${LDFLAGS}"
1612                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1613                LDFLAGS=-Wl,-Bsymbolic-functions
1614                AC_TRY_LINK([], [int main (void) { return 0; }],
1615                            AC_MSG_RESULT(yes)
1616                            enable_Bsymbolic=yes,
1617                            AC_MSG_RESULT(no)
1618                            enable_Bsymbolic=no)
1619                LDFLAGS="${SAVED_LDFLAGS}"])
1620
1621 if test "x${enable_Bsymbolic}" == "xyes"; then
1622   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1623 fi
1624 AC_SUBST(GTK_LINK_FLAGS)
1625
1626 AC_CONFIG_FILES([
1627 config.h.win32
1628 gtk-zip.sh
1629 Makefile
1630 gdk-3.0.pc
1631 gtk+-3.0.pc
1632 gtk+-unix-print-3.0.pc
1633 gail-3.0.pc
1634 gdk-3.0-uninstalled.pc
1635 gtk+-3.0-uninstalled.pc
1636 gail-3.0-uninstalled.pc
1637 m4macros/Makefile
1638 po/Makefile.in
1639 po-properties/Makefile.in
1640 demos/Makefile
1641 demos/gtk-demo/Makefile
1642 demos/gtk-demo/geninclude.pl
1643 examples/Makefile
1644 tests/Makefile
1645 docs/Makefile
1646 docs/reference/Makefile
1647 docs/reference/gdk/Makefile
1648 docs/reference/gdk/version.xml
1649 docs/reference/gtk/Makefile
1650 docs/reference/gtk/version.xml
1651 docs/reference/libgail-util/Makefile
1652 docs/faq/Makefile
1653 docs/tools/Makefile
1654 docs/tutorial/Makefile
1655 build/Makefile
1656 build/win32/Makefile
1657 build/win32/vs9/Makefile
1658 gdk/Makefile
1659 gdk/x11/Makefile
1660 gdk/win32/Makefile
1661 gdk/win32/rc/Makefile
1662 gdk/win32/rc/gdk.rc
1663 gdk/quartz/Makefile
1664 gdk/tests/Makefile
1665 gtk/Makefile
1666 gtk/makefile.msc
1667 gtk/gtkversion.h
1668 gtk/gtk-win32.rc
1669 gtk/theme-bits/Makefile
1670 gtk/tests/Makefile
1671 modules/Makefile
1672 modules/other/Makefile
1673 modules/other/gail/Makefile
1674 modules/other/gail/libgail-util/Makefile
1675 modules/other/gail/tests/Makefile
1676 modules/engines/Makefile
1677 modules/engines/pixbuf/Makefile
1678 modules/engines/ms-windows/Makefile
1679 modules/engines/ms-windows/Theme/Makefile
1680 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1681 modules/input/Makefile
1682 modules/printbackends/Makefile
1683 modules/printbackends/cups/Makefile
1684 modules/printbackends/lpr/Makefile
1685 modules/printbackends/file/Makefile
1686 modules/printbackends/papi/Makefile
1687 modules/printbackends/test/Makefile
1688 perf/Makefile
1689 ])
1690
1691 AC_OUTPUT
1692
1693 echo "configuration:
1694         target:             $gdktarget"