Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ([2.62])
   4
   5 # Making releases:
   6 #   GTK_MICRO_VERSION += 1;
   7 #   GTK_INTERFACE_AGE += 1;
   8 #   GTK_BINARY_AGE += 1;
   9 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
  10 # if backwards compatibility has been broken,
  11 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  12
  13 m4_define([gtk_major_version], [2])
  14 m4_define([gtk_minor_version], [90])
  15 m4_define([gtk_micro_version], [8])
  16 m4_define([gtk_interface_age], [0])
  17 m4_define([gtk_binary_age],
  18           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  19 m4_define([gtk_version],
  20           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  21 # This is the X.Y used in -lgtk-FOO-X.Y
  22 m4_define([gtk_api_version], [3.0])
  23
  24 # Define a string for the earliest version that this release has
  25 # backwards binary compatibility with for all interfaces a module
  26 # might. Unless we add module-only API with lower stability
  27 # guarantees, this should be unchanged until we break binary compat
  28 # for GTK+.
  29 #
  30 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  31 m4_define([gtk_binary_version], [3.0.0])
  32
  33 # required versions of other packages
  34 m4_define([glib_required_version], [2.27.0])
  35 m4_define([pango_required_version], [1.20])
  36 m4_define([atk_required_version], [1.29.2])
  37 m4_define([cairo_required_version], [1.9.10])
  38 m4_define([gdk_pixbuf_required_version], [2.21.0])
  39 GLIB_REQUIRED_VERSION=glib_required_version
  40 PANGO_REQUIRED_VERSION=pango_required_version
  41 ATK_REQUIRED_VERSION=atk_required_version
  42 CAIRO_REQUIRED_VERSION=cairo_required_version
  43 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  44 AC_SUBST(GLIB_REQUIRED_VERSION)
  45 AC_SUBST(PANGO_REQUIRED_VERSION)
  46 AC_SUBST(ATK_REQUIRED_VERSION)
  47 AC_SUBST(CAIRO_REQUIRED_VERSION)
  48 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  49
  50
  51 AC_INIT([gtk+], [gtk_version],
  52         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  53         [gtk+])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  57 AC_CONFIG_MACRO_DIR([m4])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules, requires at least automake-1.11. Enable
  66 # by either passing --enable-silent-rules to configure or passing V=0
  67 # to make
  68 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([no])])
  69
  70 #
  71 # For each of the libraries we build, we define the following
  72 # substituted variables:
  73 #
  74 # foo_PACKAGES:     pkg-config packages this library requires
  75 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  76 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  77 # foo_DEP_LIBS:     All libraries this module requires
  78 # foo_DEP_CFLAGS:   All cflags this module requires
  79
  80
  81 GTK_MAJOR_VERSION=gtk_major_version
  82 GTK_MINOR_VERSION=gtk_minor_version
  83 GTK_MICRO_VERSION=gtk_micro_version
  84 GTK_INTERFACE_AGE=gtk_interface_age
  85 GTK_BINARY_AGE=gtk_binary_age
  86 GTK_VERSION=gtk_version
  87 GTK_API_VERSION=gtk_api_version
  88 GTK_BINARY_VERSION=gtk_binary_version
  89 AC_SUBST(GTK_MAJOR_VERSION)
  90 AC_SUBST(GTK_MINOR_VERSION)
  91 AC_SUBST(GTK_MICRO_VERSION)
  92 AC_SUBST(GTK_INTERFACE_AGE)
  93 AC_SUBST(GTK_BINARY_AGE)
  94 AC_SUBST(GTK_API_VERSION)
  95 AC_SUBST(GTK_VERSION)
  96 AC_SUBST(GTK_BINARY_VERSION)
  97
  98 # libtool versioning
  99 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 100 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 101 #LT_REVISION=$GTK_INTERFACE_AGE
 102 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 103 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 104
 105 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 106 m4_define([lt_revision], [gtk_interface_age])
 107 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 108 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 109 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 110 AC_SUBST(LT_VERSION_INFO)
 111 AC_SUBST(LT_CURRENT_MINUS_AGE)
 112
 113 m4_define([gail_lt_current],[0])
 114 m4_define([gail_lt_revision],[0])
 115 m4_define([gail_lt_age],[0])
 116 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 117 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 118 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 119 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 120
 121 # Checks for programs.
 122 AC_PROG_CC
 123 AC_PROG_CC_C_O
 124 AC_PROG_CC_STDC
 125 AC_PROG_INSTALL
 126 AC_PROG_MAKE_SET
 127
 128
 129 GETTEXT_PACKAGE=gtk30
 130 AC_SUBST(GETTEXT_PACKAGE)
 131 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 132                    [The prefix for our gettext translation domains.])
 133
 134 AC_CANONICAL_HOST
 135
 136 MATH_LIB=-lm
 137 AC_MSG_CHECKING([for native Win32])
 138 LIB_EXE_MACHINE_FLAG=X86
 139 EXE_MANIFEST_ARCHITECTURE=X86
 140 case "$host" in
 141   *-*-mingw*)
 142     os_win32=yes
 143     gio_can_sniff=no
 144     MATH_LIB=
 145     case "$host" in
 146     x86_64-*-*)
 147       LIB_EXE_MACHINE_FLAG=X64
 148       EXE_MANIFEST_ARCHITECTURE=AMD64
 149       ;;
 150     esac
 151     ;;
 152   *)
 153     os_win32=no
 154     ;;
 155 esac
 156 AC_MSG_RESULT([$os_win32])
 157
 158 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 159 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 160
 161 case $host in
 162   *-*-linux*)
 163     os_linux=yes
 164     ;;
 165 esac
 166
 167 dnl
 168 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 169 dnl We use this for an automated test for C++ header correctness.
 170 dnl
 171 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 172 AC_LANG_PUSH([C++])
 173
 174 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 175 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 176
 177 gtk_save_cxxflags="$CXXFLAGS"
 178 CXXFLAGS="$CXXFLAGS -x objective-c++"
 179 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 180 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 181 CXXFLAGS="$gtk_save_cxxflags"
 182 AC_LANG_POP([C++])
 183
 184 if test "$os_win32" = "yes"; then
 185   if test x$enable_static = xyes -o x$enable_static = x; then
 186     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 187     enable_static=no
 188   fi
 189   if test x$enable_shared = xno; then
 190     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 191   fi
 192   enable_shared=yes
 193 fi
 194
 195 dnl Initialize libtool
 196 LT_PREREQ([2.2.6])
 197 LT_INIT([disable-static win32-dll])
 198 # Create libtool early, because it's used in configure
 199 LT_OUTPUT
 200
 201 # Make sure we use 64-bit versions of various file stuff.
 202 AC_SYS_LARGEFILE
 203
 204 AM_PROG_AS
 205 AC_PATH_PROG(NM, nm, nm)
 206
 207 AC_MSG_CHECKING([for some Win32 platform])
 208 case "$host" in
 209   *-*-mingw*|*-*-cygwin*)
 210     platform_win32=yes
 211     ;;
 212   *)
 213     platform_win32=no
 214     ;;
 215 esac
 216 AC_MSG_RESULT([$platform_win32])
 217 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 218
 219 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 220 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 221 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 222
 223 if test "$os_win32" = "yes"; then
 224   AC_CHECK_TOOL(WINDRES, windres, no)
 225   if test "$WINDRES" = no; then
 226     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 227   fi
 228   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 229 fi
 230 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 231
 232 m4_define([debug_default],
 233           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 234
 235 dnl declare --enable-* args and collect ac_help strings
 236 AC_ARG_ENABLE(debug,
 237               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 238                              [turn on debugging @<:@default=debug_default@:>@]),,
 239               enable_debug=debug_default)
 240 AC_ARG_ENABLE(shm,
 241               [AC_HELP_STRING([--enable-shm],
 242                               [support shared memory if available [default=yes]])],,
 243               [enable_shm="yes"])
 244 AC_ARG_ENABLE(xkb,
 245               [AC_HELP_STRING([--enable-xkb],
 246                               [support XKB [default=maybe]])],,
 247               [enable_xkb="maybe"])
 248 AC_ARG_ENABLE(xinerama,
 249               [AC_HELP_STRING([--enable-xinerama],
 250                               [support xinerama extension if available [default=yes]])],,
 251               [enable_xinerama="yes"])
 252 AC_ARG_ENABLE(rebuilds,
 253               [AC_HELP_STRING([--disable-rebuilds],
 254                               [disable all source autogeneration rules])],,
 255               [enable_rebuilds=yes])
 256
 257 AC_ARG_WITH(xinput,
 258             [AC_HELP_STRING([--with-xinput=@<:@no/yes@:>@], [support XInput])])
 259
 260 if test "$platform_win32" = yes; then
 261   gdktarget=win32
 262 else
 263   gdktarget=x11
 264 fi
 265
 266 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/win32/quartz]] select non-default GDK target],
 267         gdktarget=$with_gdktarget)
 268
 269 AC_SUBST(gdktarget)
 270 case $gdktarget in
 271   x11|win32|quartz) ;;
 272   *) AC_MSG_ERROR([Invalid target for GDK: use x11, quartz or win32.]);;
 273 esac
 274
 275 gdktargetlib=libgdk-$gdktarget-$GTK_API_VERSION.la
 276 gtktargetlib=libgtk-$gdktarget-$GTK_API_VERSION.la
 277
 278 AC_SUBST(gdktargetlib)
 279 AC_SUBST(gtktargetlib)
 280
 281 if test "x$enable_debug" = "xyes"; then
 282   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 283   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 284 else
 285   if test "x$enable_debug" = "xno"; then
 286     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 287   else
 288     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 289   fi
 290 fi
 291
 292
 293 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 294                    [Define if debugging is enabled])
 295
 296
 297 # Build time sanity check...
 298 AM_SANITY_CHECK
 299
 300 changequote(,)dnl
 301 if test "x$GCC" = "xyes"; then
 302   case " $CFLAGS " in
 303   *[\ \ ]-Wall[\ \      ]*) ;;
 304   *) CFLAGS="$CFLAGS -Wall" ;;
 305   esac
 306
 307   if test "x$enable_ansi" = "xyes"; then
 308     case " $CFLAGS " in
 309     *[\ \       ]-ansi[\ \      ]*) ;;
 310     *) CFLAGS="$CFLAGS -ansi" ;;
 311     esac
 312
 313     case " $CFLAGS " in
 314     *[\ \       ]-pedantic[\ \  ]*) ;;
 315     *) CFLAGS="$CFLAGS -pedantic" ;;
 316     esac
 317   fi
 318 fi
 319 changequote([,])dnl
 320
 321 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 322
 323 # Ensure MSVC-compatible struct packing convention is used when
 324 # compiling for Win32 with gcc.
 325 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 326 # gcc2 uses "-fnative-struct".
 327 if test x"$os_win32" = xyes; then
 328   if test x"$GCC" = xyes; then
 329     msnative_struct=''
 330     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 331     if test -z "$ac_cv_prog_CC"; then
 332       our_gcc="$CC"
 333     else
 334       our_gcc="$ac_cv_prog_CC"
 335     fi
 336     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 337       2.)
 338         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 339           msnative_struct='-fnative-struct'
 340         fi
 341         ;;
 342       *)
 343         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 344           msnative_struct='-mms-bitfields'
 345         fi
 346         ;;
 347     esac
 348     if test x"$msnative_struct" = x ; then
 349       AC_MSG_RESULT([no way])
 350       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 351     else
 352       CFLAGS="$CFLAGS $msnative_struct"
 353       AC_MSG_RESULT([${msnative_struct}])
 354     fi
 355   fi
 356 fi
 357
 358 ## Initial sanity check, done here so that users get told they
 359 ## have the wrong dependencies as early in the process as possible.
 360 ## Later on we actually use the cflags/libs from separate pkg-config
 361 ## calls. Oh, also the later pkg-config calls don't include
 362 ## the version requirements since those make the module lists
 363 ## annoying to construct
 364 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 365   [glib-2.0 >= glib_required_version dnl
 366    atk >= atk_required_version dnl
 367    pango >= pango_required_version dnl
 368    cairo >= cairo_required_version dnl
 369    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 370
 371 ## In addition to checking that cairo is present, we also need to
 372 ## check that the correct cairo backend is there. E.g. if the GDK
 373 ## target is win32 we need the cairo-win32 backend and so on.
 374 cairo_backend=$gdktarget
 375
 376 # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 377 # backend names are identical.
 378 if test "x$cairo_backend" = "xx11"; then
 379    cairo_backend=xlib
 380 fi
 381 PKG_CHECK_MODULES(CAIRO_BACKEND,
 382   [cairo-$cairo_backend >= cairo_required_version])
 383
 384 if test "$os_win32" != yes; then
 385     # libtool option to control which symbols are exported
 386     # right now, symbols starting with _ are not exported
 387     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 388 else
 389     # We currently use .def files on Windows (for gdk and gtk)
 390     LIBTOOL_EXPORT_OPTIONS=
 391 fi
 392 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 393
 394 dnl ******************************************************
 395 dnl * See whether to include shared library dependencies *
 396 dnl ******************************************************
 397
 398 AC_ARG_ENABLE(explicit-deps,
 399               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 400                               [use explicit dependencies in .pc files [default=auto]])],,
 401               [enable_explicit_deps=auto])
 402
 403 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 404 case $enable_explicit_deps in
 405   auto)
 406     export SED
 407     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 408     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 409       enable_explicit_deps=yes
 410     else
 411       enable_explicit_deps=no
 412     fi
 413   ;;
 414   yes|no)
 415   ;;
 416   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 417   ;;
 418 esac
 419 AC_MSG_RESULT($enable_explicit_deps)
 420
 421 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 422
 423 # define a MAINT-like variable REBUILD which is set if Perl
 424 # and awk are found, so autogenerated sources can be rebuilt
 425
 426 AC_PATH_PROGS(PERL, perl5 perl)
 427
 428 # We would like indent, but don't require it.
 429 AC_CHECK_PROG(INDENT, indent, indent)
 430
 431 REBUILD=\#
 432 if test "x$enable_rebuilds" = "xyes" && \
 433      test -n "$PERL" && \
 434      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 435   REBUILD=
 436 fi
 437 AC_SUBST(REBUILD)
 438
 439 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 440 AC_CHECK_FUNCS(localtime_r)
 441
 442 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 443 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 444 AC_TRY_LINK([#include <langinfo.h>], [
 445 char c;
 446 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 447 ], gtk_ok=yes, gtk_ok=no)
 448 AC_MSG_RESULT($gtk_ok)
 449 if test "$gtk_ok" = "yes"; then
 450   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 451             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 452 fi
 453
 454 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 455 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 456 AC_TRY_LINK([#include <langinfo.h>], [
 457 char c;
 458 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 459 ], gtk_ok=yes, gtk_ok=no)
 460 AC_MSG_RESULT($gtk_ok)
 461 if test "$gtk_ok" = "yes"; then
 462   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 463             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 464 fi
 465
 466 # _NL_PAPER_HEIGHT is an enum and not a define
 467 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 468 AC_TRY_LINK([#include <langinfo.h>], [
 469 char c;
 470 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 471 ], gtk_ok=yes, gtk_ok=no)
 472 AC_MSG_RESULT($gtk_ok)
 473 if test "$gtk_ok" = "yes"; then
 474   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 475             [Define if _NL_PAPER_HEIGHT is available])
 476 fi
 477
 478 # _NL_PAPER_WIDTH is an enum and not a define
 479 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 480 AC_TRY_LINK([#include <langinfo.h>], [
 481 char c;
 482 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 483 ], gtk_ok=yes, gtk_ok=no)
 484 AC_MSG_RESULT($gtk_ok)
 485 if test "$gtk_ok" = "yes"; then
 486   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 487             [Define if _NL_PAPER_WIDTH is available])
 488 fi
 489
 490 # i18n stuff
 491 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 492 AM_GLIB_GNU_GETTEXT
 493 LIBS="$LIBS $INTLLIBS"
 494 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 495         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 496       esac])
 497
 498 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 499 dnl po-properties/POTFILES during configure; see GNOME #573515.
 500 dnl
 501 dnl Generate list of files to be processed by xgettext which will
 502 dnl be included in po-properties/Makefile.
 503 test -d po-properties || mkdir po-properties
 504 if test "x$srcdir" != "x."; then
 505   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 506     popropsrcprefix="$srcdir/"
 507   else
 508     popropsrcprefix="../$srcdir/"
 509   fi
 510 else
 511   popropsrcprefix="../"
 512 fi
 513 rm -f po-properties/POTFILES
 514 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 515 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 516 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 517
 518 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 519
 520 dnl The DU4 header files don't provide library prototypes unless
 521 dnl -std1 is given to the native cc.
 522 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 523
 524 gtk_save_LIBS=$LIBS
 525 LIBS="$LIBS -lm"
 526 AC_TRY_RUN([#include <math.h>
 527              int main (void) { return (log(1) != log(1.)); }],
 528      AC_MSG_RESULT(none needed),
 529      gtk_save_CFLAGS="$CFLAGS"
 530      CFLAGS="$CFLAGS -std1"
 531      AC_TRY_RUN([#include <math.h>
 532                  int main (void) { return (log(1) != log(1.)); }],
 533          AC_MSG_RESULT(-std1),
 534          AC_MSG_RESULT()
 535          CFLAGS="$gtk_save_CFLAGS"
 536          AC_MSG_WARN(
 537                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 538          true
 539      ),
 540      AC_MSG_RESULT(none needed)
 541 )
 542 LIBS=$gtk_save_LIBS
 543
 544 AC_MSG_CHECKING(for the BeOS)
 545 case $host in
 546   *-*-beos*)
 547     AC_MSG_RESULT(yes)
 548     MATH_LIB=
 549   ;;
 550   *)
 551     AC_MSG_RESULT(no)
 552   ;;
 553 esac
 554
 555 AC_SUBST(MATH_LIB)
 556 #
 557 # see bug 162979
 558 #
 559 AC_MSG_CHECKING(for HP-UX)
 560 case $host_os in
 561   hpux9* | hpux10* | hpux11*)
 562     AC_MSG_RESULT(yes)
 563     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 564   ;;
 565   *)
 566     AC_MSG_RESULT(no)
 567   ;;
 568 esac
 569
 570 dnl NeXTStep cc seems to need this
 571 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 572 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 573   AC_MSG_RESULT(none needed),
 574   gtk_save_CFLAGS="$CFLAGS"
 575   CFLAGS="$CFLAGS -posix"
 576   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 577     AC_MSG_RESULT(-posix),
 578     AC_MSG_RESULT()
 579     CFLAGS="$gtk_save_CFLAGS"
 580     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 581
 582 #
 583 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 584 #
 585
 586 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 587
 588 AM_PATH_GLIB_2_0(glib_required_version, :,
 589   AC_MSG_ERROR([
 590 *** GLIB glib_required_version or better is required. The latest version of
 591 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 592   gobject gmodule-no-export gthread)
 593
 594 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 595 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 596 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 597 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 598   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 599 fi
 600
 601 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 602
 603
 604 dnl
 605 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 606 dnl
 607 gtk_save_LIBS=$LIBS
 608 LIBS="$LIBS $GLIB_LIBS"
 609 AC_CHECK_FUNCS(bind_textdomain_codeset)
 610 LIBS=$gtk_save_LIBS
 611
 612 AC_CHECK_HEADERS(pwd.h,
 613                  AC_DEFINE(HAVE_PWD_H, 1,
 614                            [Define to 1 if pwd.h is available]))
 615 AC_CHECK_HEADERS(sys/time.h,
 616                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 617                            [Define to 1 if time.h is available]))
 618 AC_CHECK_HEADERS(unistd.h,
 619                  AC_DEFINE(HAVE_UNISTD_H, 1,
 620                            [Define to 1 if unistd.h is available]))
 621 AC_CHECK_HEADERS(ftw.h,
 622                  AC_DEFINE(HAVE_FTW_H, 1,
 623                            [Define to 1 if ftw.h is available]))
 624
 625 AC_MSG_CHECKING([for GNU ftw extensions])
 626 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 627 #define _GNU_SOURCE
 628 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 629 if test $gtk_ok = yes; then
 630     AC_MSG_RESULT([yes])
 631     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 632 else
 633     AC_MSG_RESULT([no])
 634 fi
 635
 636 saved_cflags="$CFLAGS"
 637 saved_ldflags="$LDFLAGS"
 638
 639
 640 # Checks for header files.
 641 AC_HEADER_STDC
 642
 643 # Checks for typedefs, structures, and compiler characteristics.
 644 AC_C_CONST
 645
 646 # Checks for library functions.
 647 AC_TYPE_SIGNAL
 648 AC_FUNC_MMAP
 649
 650 AC_CHECK_FUNCS(mallinfo)
 651 AC_CHECK_FUNCS(getresuid)
 652 AC_TYPE_UID_T
 653
 654 # Check if <sys/select.h> needs to be included for fd_set
 655 AC_MSG_CHECKING([for fd_set])
 656 AC_TRY_COMPILE([#include <sys/types.h>],
 657         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 658 if test $gtk_ok = yes; then
 659     AC_MSG_RESULT([yes, found in sys/types.h])
 660 else
 661     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 662     if test $gtk_ok = yes; then
 663         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 664                   [Define to 1 if sys/select.h is available])
 665         AC_MSG_RESULT([yes, found in sys/select.h])
 666     else
 667         AC_DEFINE(NO_FD_SET, 1,
 668                   [Define to 1 if fd_set is not available])
 669         AC_MSG_RESULT(no)
 670     fi
 671 fi
 672
 673 # `widechar' tests for gdki18n.h
 674 AC_MSG_CHECKING(for wchar.h)
 675 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 676 if test $gdk_wchar_h = yes; then
 677    AC_DEFINE(HAVE_WCHAR_H, 1, [Have wchar.h include file])
 678 fi
 679 AC_MSG_RESULT($gdk_wchar_h)
 680
 681 # Check for wctype.h (for iswalnum)
 682 AC_MSG_CHECKING(for wctype.h)
 683 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 684 if test $gdk_wctype_h = yes; then
 685    AC_DEFINE(HAVE_WCTYPE_H, 1, [Have wctype.h include file])
 686 fi
 687 AC_MSG_RESULT($gdk_wctype_h)
 688
 689 # in Solaris 2.5, `iswalnum' is in -lw
 690 GDK_WLIBS=
 691 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 692
 693 oLIBS="$LIBS"
 694 LIBS="$LIBS $GDK_WLIBS"
 695 # The following is necessary for Linux libc-5.4.38
 696 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 697 AC_TRY_LINK([#include <stdlib.h>],[
 698 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 699 #  ifdef HAVE_WCTYPE_H
 700 #    include <wctype.h>
 701 #  else
 702 #    ifdef HAVE_WCHAR_H
 703 #      include <wchar.h>
 704 #    endif
 705 #  endif
 706 #else
 707 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 708 #endif
 709 iswalnum((wchar_t) 0);
 710 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 711 LIBS="$oLIBS"
 712
 713 if test $gdk_working_wctype = no; then
 714    AC_DEFINE(HAVE_BROKEN_WCTYPE, 1, [Is the wctype implementation broken])
 715    GDK_WLIBS=
 716 fi
 717 AC_MSG_RESULT($gdk_working_wctype)
 718 AC_SUBST(GDK_WLIBS)
 719
 720 # Check for uxtheme.h (for MS-Windows Engine)
 721 AC_MSG_CHECKING(for uxtheme.h)
 722 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 723 if test $gtk_uxtheme_h = yes; then
 724    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 725 fi
 726 AC_MSG_RESULT($gtk_uxtheme_h)
 727
 728 # Checks for gdkspawn
 729 AC_CHECK_HEADERS(crt_externs.h)
 730 AC_CHECK_FUNCS(_NSGetEnviron)
 731
 732 AC_MSG_CHECKING(whether to build dynamic modules)
 733
 734 AC_ARG_ENABLE(modules,
 735               [AC_HELP_STRING([--disable-modules],
 736                               [disable dynamic module loading])])
 737
 738 dynworks=false
 739 deps=
 740 if test x$enable_modules = xno; then
 741     AC_MSG_RESULT(no)
 742 else
 743     AC_MSG_RESULT(yes)
 744     AC_MSG_CHECKING(whether dynamic modules work)
 745     ## for loop is to strip newline
 746     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 747     for I in $tmp; do
 748         dynworks=$I
 749     done
 750
 751     dnl Now we check to see if our libtool supports shared lib deps
 752     dnl (in a rather ugly way even)
 753     if $dynworks; then
 754         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 755         module_deplibs_check=`$module_libtool_config | \
 756             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 757             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 758         if test "x$module_deplibs_check" = "xnone" || \
 759            test "x$module_deplibs_check" = "xunknown" || \
 760            test "x$module_deplibs_check" = "x"; then
 761             dynworks=false
 762         fi
 763     fi
 764
 765     if $dynworks; then
 766         AC_DEFINE(USE_GMODULE, 1,
 767                   [Define to 1 if gmodule works and should be used])
 768         AC_MSG_RESULT(yes)
 769     else
 770         AC_MSG_RESULT(no)
 771     fi
 772 fi
 773
 774 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 775
 776 #
 777 # Allow building some or all immodules included
 778 #
 779 AC_MSG_CHECKING(immodules to build)
 780
 781 dnl due to an autoconf bug, commas in the first arg to
 782 dnl AC_HELP_STRING cause problems.
 783 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
 784 dnl                [build the specified input method modules into gtk])
 785 AC_ARG_WITH(included_immodules,
 786 [  --with-included-immodules=MODULE1,MODULE2,...
 787                           build the specified input methods into gtk])
 788
 789 if $dynworks; then
 790    :
 791 else
 792    ## if the option was specified, leave it; otherwise disable included immodules
 793    if test x$with_included_immodules = xno; then
 794            with_included_immodules=yes
 795    fi
 796 fi
 797
 798 all_immodules="am-et,cedilla,cyrillic-translit"
 799 if test "$gdktarget" = "win32"; then
 800    all_immodules="${all_immodules},ime"
 801 fi
 802 all_immodules="${all_immodules},inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr"
 803 if test "$gdktarget" = "x11"; then
 804    all_immodules="${all_immodules},xim"
 805 fi
 806
 807 included_immodules=""
 808 # If the switch specified without listing any specific ones, include all
 809 if test "x$with_included_immodules" = xyes ; then
 810   included_immodules="$all_immodules"
 811 else
 812   included_immodules="$with_included_immodules"
 813 fi
 814
 815 AC_MSG_RESULT($included_immodules)
 816 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 817
 818 INCLUDED_IMMODULE_OBJ=
 819 INCLUDED_IMMODULE_DEFINE=
 820
 821 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 822 for immodule in $included_immodules; do
 823  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 824  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 825    :
 826  else
 827    AC_MSG_ERROR([the specified input method $immodule does not exist])
 828  fi
 829
 830  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 831  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 832  eval INCLUDE_$immodule_underscores=yes
 833 done
 834 IFS="$gtk_save_ifs"
 835 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 836 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 837
 838 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 839 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 840 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 841 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 842 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 843 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 844 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 845 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 846 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 847 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 848 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 849 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 850
 851 AC_HEADER_SYS_WAIT
 852
 853 AC_TYPE_SIGNAL
 854
 855 # Checks to see whether we should include mediaLib
 856 # support.
 857 #
 858 AC_CHECK_HEADER(sys/systeminfo.h,
 859                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 860                           [Define to 1 if sys/systeminfo.h is available]))
 861 AC_CHECK_HEADER(sys/sysinfo.h,
 862                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 863                           [Define to 1 if sys/sysinfo.h is available]))
 864
 865 AC_MSG_CHECKING(for mediaLib 2.3)
 866 use_mlib25=no
 867 # Check for a mediaLib 2.3 function since that is what the GTK+ mediaLib
 868 # patch requires.
 869 AC_CHECK_LIB(mlib, mlib_ImageSetStruct, use_mlib=yes, use_mlib=no)
 870 if test $use_mlib = yes; then
 871     AC_DEFINE(USE_MEDIALIB, 1,
 872               [Define to 1 if medialib is available and should be used])
 873     MEDIA_LIB=-lmlib
 874
 875     AC_MSG_CHECKING(for mediaLib 2.5)
 876     # Check for a mediaLib 2.5 function since that is what is needed for
 877     # gdk_rgb_convert integration.
 878     AC_CHECK_LIB(mlib, mlib_VideoColorRGBint_to_BGRAint, use_mlib25=yes, use_mlib25=no)
 879     if test $use_mlib25 = yes; then
 880         AC_DEFINE(USE_MEDIALIB25, 1,
 881                   [Define to 1 if medialib 2.5 is available])
 882     fi
 883 fi
 884 AM_CONDITIONAL(USE_MEDIALIB, test $use_mlib = yes)
 885 AM_CONDITIONAL(USE_MEDIALIB25, test $use_mlib25 = yes)
 886
 887 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 888
 889 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 890
 891 if test $cross_compiling = yes; then
 892   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 893   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 894     REBUILD_PNGS=#
 895   fi
 896 fi
 897
 898 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 899
 900 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 901    test "x$REBUILD_PNGS" = "x#" ; then
 902      AC_MSG_ERROR([
 903 *** gtkbuiltincache.h is not in the tree, and cannot be built
 904 *** because you don't have libpng, or (when cross-compiling) you
 905 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 906 fi
 907
 908 ########################################
 909 # Windowing system checks
 910 ########################################
 911
 912 GDK_EXTRA_LIBS="$GDK_WLIBS"
 913 GDK_EXTRA_CFLAGS=
 914
 915 # GTK+ uses some X calls, so needs to link against X directly
 916 GTK_DEP_PACKAGES_FOR_X=
 917 GTK_DEP_LIBS_FOR_X=
 918
 919 if test "x$gdktarget" = "xx11"; then
 920   X_PACKAGES=fontconfig
 921
 922   #
 923   # We use fontconfig very peripherally when decoding the default
 924   # settings.
 925   #
 926   if $PKG_CONFIG --exists fontconfig; then : ; else
 927     AC_MSG_ERROR([
 928 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 929   fi
 930
 931   #
 932   # Check for basic X packages; we use pkg-config if available
 933   #
 934   if $PKG_CONFIG --exists x11 xext; then
 935     have_base_x_pc=true
 936     X_PACKAGES="$X_PACKAGES x11 xext"
 937     x_libs="`$PKG_CONFIG --libs x11 xext`"
 938     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 939
 940     # Strip out any .la files that pkg-config might give us (this happens
 941     # with -uninstalled.pc files)
 942     x_libs_for_checks=
 943     for I in $x_libs ; do
 944       case $I in
 945         *.la) ;;
 946         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 947       esac
 948     done
 949
 950     GTK_PACKAGES_FOR_X="x11"
 951   else
 952     have_base_x_pc=false
 953     AC_PATH_XTRA
 954     if test x$no_x = xyes ; then
 955       AC_MSG_ERROR([X development libraries not found])
 956     fi
 957
 958     x_cflags="$X_CFLAGS"
 959     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 960
 961     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 962   fi
 963
 964   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 965   x_extra_libs=
 966
 967   gtk_save_cppflags="$CPPFLAGS"
 968   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 969
 970   gtk_save_LIBS=$LIBS
 971   LIBS="$x_libs_for_checks $LIBS"
 972
 973   # Sanity check for the X11 and Xext libraries. While everything we need from
 974   # Xext is optional, the chances a system has *none* of these things is so
 975   # small that we just unconditionally require it.
 976   AC_CHECK_FUNC(XOpenDisplay, :,
 977                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 978   AC_CHECK_FUNC(XextFindDisplay, :,
 979                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 980
 981   # Check for xReply
 982
 983   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 984   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
 985       [xReply *rep;],
 986       [AC_MSG_RESULT([no])],
 987       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
 988 #include <X11/Xlibint.h>],
 989            [xReply *rep;],
 990            [AC_MSG_RESULT([yes])
 991             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
 992                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
 993            [AC_MSG_RESULT([unknown])
 994             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 995
 996   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 997
 998   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 999
1000   # Generic X11R6 check needed for XIM support; we could
1001   # probably use this to replace the above, but we'll
1002   # leave the separate checks for XConvertCase and XInternAtoms
1003   # for clarity
1004
1005   have_x11r6=false
1006   AC_CHECK_FUNC(XAddConnectionWatch,
1007       have_x11r6=true)
1008
1009   if $have_x11r6; then
1010     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1011   fi
1012   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1013
1014   # Check for XKB support.
1015
1016   if test "x$enable_xkb" = "xyes"; then
1017         AC_MSG_WARN(XKB support explicitly enabled)
1018         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
1019   elif test "x$enable_xkb" = "xmaybe"; then
1020         AC_CHECK_FUNC(XkbQueryExtension,
1021                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1022   else
1023         AC_MSG_WARN(XKB support explicitly disabled)
1024   fi
1025
1026   # Check for shaped window extension
1027
1028   AC_CHECK_FUNC(XShapeCombineMask, :,
1029      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1030
1031   # X SYNC check
1032   gtk_save_CFLAGS="$CFLAGS"
1033   CFLAGS="$CFLAGS $x_cflags"
1034
1035   AC_CHECK_FUNC(XSyncQueryExtension,
1036       [AC_CHECK_HEADER(X11/extensions/sync.h,
1037           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1038           :, [#include <X11/Xlib.h>])])
1039
1040   CFLAGS="$gtk_save_CFLAGS"
1041
1042   # Xshm checks
1043
1044   if test "x$enable_shm" = "xyes"; then
1045      # Check for the XShm extension, normally in Xext
1046      AC_CHECK_FUNC(XShmAttach,
1047         :,
1048         # On AIX, it is in XextSam instead
1049         [AC_CHECK_LIB(XextSam, XShmAttach,
1050             [GTK_ADD_LIB(x_extra_libs,XextSam)])])
1051   fi
1052
1053   if test "x$enable_shm" = "xyes"; then
1054     # Check for shared memory
1055     AC_CHECK_HEADER(sys/ipc.h,
1056                     AC_DEFINE(HAVE_IPC_H, 1,
1057                               [Define to 1 if ipc.h is available]),
1058                     no_sys_ipc=yes)
1059     AC_CHECK_HEADER(sys/shm.h,
1060                     AC_DEFINE(HAVE_SHM_H, 1,
1061                               [Define to 1 if shm.h is available]),
1062                     no_sys_shm=yes)
1063
1064     # Check for the X shared memory extension header file
1065     have_xshm=no
1066     AC_MSG_CHECKING(X11/extensions/XShm.h)
1067     if test "x$no_xext_lib" = "xyes"; then
1068       :
1069     else
1070       gtk_save_CFLAGS="$CFLAGS"
1071       CFLAGS="$CFLAGS $x_cflags"
1072       AC_TRY_COMPILE([
1073 #include <stdlib.h>
1074 #include <sys/types.h>
1075 #include <sys/ipc.h>
1076 #include <sys/shm.h>
1077 #include <X11/Xlib.h>
1078 #include <X11/Xutil.h>
1079 #include <X11/extensions/XShm.h>
1080 ], [XShmSegmentInfo *x_shm_info;], have_xshm=yes)
1081       CFLAGS="$gtk_save_CFLAGS"
1082     fi
1083     AC_MSG_RESULT($have_xshm)
1084     if test $have_xshm = yes ; then
1085       AC_DEFINE(HAVE_XSHM_H, 1,
1086                 [Define to 1 if xshm.h is available])
1087     fi
1088   fi
1089
1090   if test "x$enable_xinerama" = "xyes"; then
1091     # Check for Xinerama extension (Solaris impl or Xfree impl)
1092     gtk_save_cppflags="$CPPFLAGS"
1093     CPPFLAGS="$CPPFLAGS $x_cflags"
1094
1095     # Check for XFree
1096     AC_MSG_CHECKING(for Xinerama support on XFree86)
1097
1098     have_xfree_xinerama=false
1099     if $PKG_CONFIG --exists xinerama ; then
1100        have_xfree_xinerama=true
1101        X_PACKAGES="$X_PACKAGES xinerama"
1102     else
1103        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1104            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1105            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1106            have_xfree_xinerama=true], :,
1107            [#include <X11/Xlib.h>])])
1108     fi
1109
1110     if $have_xfree_xinerama ; then
1111       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1112                 [Define to 1 if XFree Xinerama is available])
1113       AC_DEFINE(HAVE_XINERAMA, 1,
1114                 [Define to 1 is Xinerama is available])
1115       AC_MSG_RESULT(yes)
1116     else
1117       AC_MSG_RESULT(no)
1118
1119       case "$host" in
1120         *-*-solaris*)
1121             # Check for solaris
1122             AC_MSG_CHECKING(for Xinerama support on Solaris)
1123
1124             have_solaris_xinerama=false
1125             AC_CHECK_FUNC(XineramaGetInfo,
1126                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1127                     [have_solaris_xinerama=true], :,
1128                     [#include <X11/Xlib.h>])])
1129
1130             if $have_solaris_xinerama ; then
1131               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1132                         [Define to 1 if solaris xinerama is available])
1133               AC_DEFINE(HAVE_XINERAMA, 1,
1134                         [Define to 1 if xinerama is available])
1135               AC_MSG_RESULT(yes)
1136             else
1137               AC_MSG_RESULT(no)
1138             fi
1139             ;;
1140         *)
1141             ;;
1142       esac
1143     fi
1144   fi
1145
1146   # set up things for XInput
1147   if test "x$with_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1148     have_xinput=yes
1149
1150     AC_DEFINE(XINPUT_XFREE, 1,
1151               [Define to 1 if XFree XInput should be used])
1152
1153     X_PACKAGES="$X_PACKAGES xi"
1154
1155     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1156                     have_xinput2=yes; AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1157   else
1158     AC_DEFINE(XINPUT_NONE, 1,
1159               [Define to 1 if no XInput should be used])
1160   fi
1161
1162   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1163   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1164
1165   # Check for the RANDR extension
1166   if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1167      AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1168
1169      X_PACKAGES="$X_PACKAGES xrandr"
1170   fi
1171
1172   # Checks for Xcursor library
1173
1174   if $PKG_CONFIG --exists xcursor ; then
1175     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1176
1177     X_PACKAGES="$X_PACKAGES xcursor"
1178   fi
1179
1180   # Checks for XFixes extension
1181
1182   if $PKG_CONFIG --exists xfixes ; then
1183     AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1184
1185     X_PACKAGES="$X_PACKAGES xfixes"
1186     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1187   fi
1188
1189   # Checks for Xcomposite extension
1190
1191   if $PKG_CONFIG --exists xcomposite ; then
1192     AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1193
1194     X_PACKAGES="$X_PACKAGES xcomposite"
1195     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1196   fi
1197
1198   # Checks for Xdamage extension
1199
1200   if $PKG_CONFIG --exists xdamage ; then
1201     AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1202
1203     X_PACKAGES="$X_PACKAGES xdamage"
1204     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1205   fi
1206
1207   if $have_base_x_pc ; then
1208     GDK_EXTRA_LIBS="$x_extra_libs"
1209   else
1210     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1211   fi
1212
1213   CPPFLAGS="$gtk_save_cppflags"
1214   LIBS="$gtk_save_libs"
1215
1216   AM_CONDITIONAL(USE_X11, true)
1217 else
1218   XPACKAGES=
1219
1220   AM_CONDITIONAL(XINPUT_XFREE, false)
1221   AM_CONDITIONAL(XINPUT_2, false)
1222   AM_CONDITIONAL(USE_X11, false)
1223   AM_CONDITIONAL(HAVE_X11R6, false)
1224 fi
1225
1226 if test "x$gdktarget" = "xwin32"; then
1227   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
1228   AM_CONDITIONAL(USE_WIN32, true)
1229 else
1230   AM_CONDITIONAL(USE_WIN32, false)
1231 fi
1232
1233 if test "x$gdktarget" = "xquartz"; then
1234   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
1235   AM_CONDITIONAL(USE_QUARTZ, true)
1236 else
1237   AM_CONDITIONAL(USE_QUARTZ, false)
1238 fi
1239
1240 # Check for Pango flags
1241
1242 if test "x$gdktarget" = "xwin32"; then
1243         PANGO_PACKAGES="pangowin32 pangocairo"
1244 else
1245         PANGO_PACKAGES="pango pangocairo"
1246 fi
1247
1248 AC_MSG_CHECKING(Pango flags)
1249 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1250         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1251         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1252
1253         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1254 else
1255         AC_MSG_ERROR([
1256 *** Pango not found. Pango built with Cairo support is required
1257 *** to build GTK+. See http://www.pango.org for Pango information.
1258 ])
1259 fi
1260
1261 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1262
1263 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1264         :
1265 else
1266         gtk_save_LIBS="$LIBS"
1267         LIBS="$PANGO_LIBS $LIBS"
1268         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1269 *** Can't link to Pango. Pango is required to build
1270 *** GTK+. For more information see http://www.pango.org]))
1271         LIBS="$gtk_save_LIBS"
1272 fi
1273
1274 CFLAGS="$saved_cflags"
1275 LDFLAGS="$saved_ldflags"
1276
1277 # Pull in gio-unix for GDesktopAppInfo usage, see at least gdkapplaunchcontext-x11.c
1278 if test "x$gdktarget" = "xx11"; then
1279   GDK_PACKAGES="$PANGO_PACKAGES gio-unix-2.0 $X_PACKAGES gdk-pixbuf-2.0 cairo-$cairo_backend"
1280 else
1281   GDK_PACKAGES="$PANGO_PACKAGES gio-2.0 gdk-pixbuf-2.0 cairo-$cairo_backend"
1282 fi
1283
1284 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1285 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1286 #
1287 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1288 # into the pkg-config files
1289 #
1290 if test $enable_explicit_deps != yes ; then
1291   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0"
1292   GDK_EXTRA_LIBS=
1293 fi
1294
1295 AC_SUBST(GDK_PACKAGES)
1296 AC_SUBST(GDK_EXTRA_LIBS)
1297 AC_SUBST(GDK_EXTRA_CFLAGS)
1298 AC_SUBST(GDK_DEP_LIBS)
1299 AC_SUBST(GDK_DEP_CFLAGS)
1300
1301
1302 ########################################
1303 # Check for Accessibility Toolkit flags
1304 ########################################
1305
1306 ATK_PACKAGES=atk
1307 AC_MSG_CHECKING(ATK flags)
1308 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1309         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1310         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1311
1312         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1313 else
1314         AC_MSG_ERROR([
1315 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1316 *** to build GTK+.
1317 ])
1318 fi
1319
1320 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1321         :
1322 else
1323         gtk_save_LIBS="$LIBS"
1324         LIBS="$ATK_LIBS $LIBS"
1325         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1326                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1327                 *** to build GTK+]))
1328         LIBS="$gtk_save_LIBS"
1329 fi
1330
1331 GTK_PACKAGES="atk cairo gdk-pixbuf-2.0 gio-2.0"
1332 if test "x$gdktarget" = "xx11"; then
1333   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1334 fi
1335 GTK_EXTRA_LIBS=
1336 GTK_EXTRA_CFLAGS=
1337 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1338 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1339
1340 if test x"$os_win32" = xyes; then
1341   GTK_EXTRA_CFLAGS="$msnative_struct"
1342 fi
1343
1344 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1345 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1346 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1347 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1348
1349 AC_SUBST(GTK_PACKAGES)
1350 AC_SUBST(GTK_EXTRA_LIBS)
1351 AC_SUBST(GTK_EXTRA_CFLAGS)
1352 AC_SUBST(GTK_DEP_LIBS)
1353 AC_SUBST(GTK_DEP_CFLAGS)
1354
1355 AC_SUBST(GLIB_PREFIX)
1356 AC_SUBST(ATK_PREFIX)
1357 AC_SUBST(PANGO_PREFIX)
1358 AC_SUBST(CAIRO_PREFIX)
1359
1360 AC_SUBST(GTK_DEBUG_FLAGS)
1361 AC_SUBST(GTK_XIM_FLAGS)
1362
1363 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1364 AC_SUBST(GDK_PIXBUF_LIBS)
1365
1366 ########################
1367 # Checks needed for gail
1368 ########################
1369
1370 old_LIBS="$LIBS"
1371 dnl Checks for inet libraries:
1372 AC_SEARCH_LIBS(gethostent, nsl)
1373 AC_SEARCH_LIBS(setsockopt, socket)
1374 AC_SEARCH_LIBS(connect, inet)
1375
1376 dnl check for the sockaddr_un.sun_len member
1377 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1378                 [struct_sockaddr_un_sun_len=true],
1379                 [struct_sockaddr_un_suin_len=false],
1380                 [#include <sys/types.h>
1381                  #include <sys/un.h>]
1382                 )
1383 case $struct_sockaddr_un_sun_len in
1384         true)
1385                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1386                                    [Have the sockaddr_un.sun_len member])
1387                 ;;
1388         *)
1389                 ;;
1390 esac
1391
1392 GAIL_INET_LIBS="$LIBS"
1393 AC_SUBST([GAIL_INET_LIBS])
1394
1395 LIBS="$old_LIBS"
1396
1397 ################################################################
1398 # Printing system checks
1399 ################################################################
1400
1401 AC_ARG_ENABLE(cups,
1402               [AC_HELP_STRING([--disable-cups]
1403                               [disable cups print backend])],,
1404               [enable_cups=auto])
1405
1406 if test "x$enable_cups" = "xno"; then
1407   AM_CONDITIONAL(HAVE_CUPS, false)
1408 else
1409   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1410   if test "x$CUPS_CONFIG" = "xno"; then
1411     if test "x$enable_cups" = "xauto"; then
1412       AM_CONDITIONAL(HAVE_CUPS, false)
1413     else
1414       AC_MSG_ERROR([
1415 *** cups not found.
1416 ])
1417     fi
1418   else
1419     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1420     CUPS_LIBS=`$CUPS_CONFIG --libs`
1421
1422     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1423     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1424     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1425
1426     if test $CUPS_API_MAJOR -gt 1 -o \
1427             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1428       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1429                 [Define to 1 if CUPS 1.2 API is available])
1430     fi
1431
1432     AC_SUBST(CUPS_API_MAJOR)
1433     AC_SUBST(CUPS_API_MINOR)
1434     AC_SUBST(CUPS_CFLAGS)
1435     AC_SUBST(CUPS_LIBS)
1436
1437     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1438
1439     AM_CONDITIONAL(HAVE_CUPS, true)
1440
1441     gtk_save_cflags="$CFLAGS"
1442     CFLAGS="$CUPS_CFLAGS"
1443     AC_TRY_COMPILE([#include <cups/http.h>],
1444                    [http_t http; char *s = http.authstring;],
1445                    [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1446                               [Define if cups http_t authstring field is accessible])],)
1447     CFLAGS="$gtk_save_cflags"
1448
1449     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1450
1451     gtk_save_libs="$LIBS"
1452     LIBS="$CUPS_LIBS"
1453     AC_CHECK_FUNCS(httpGetAuthString)
1454     LIBS="$gtk_save_libs"
1455   fi
1456 fi
1457
1458 # Checks to see if we should compile with PAPI backend for GTK+
1459 #
1460
1461 AC_ARG_ENABLE(papi,
1462               [AC_HELP_STRING([--disable-papi]
1463                               [disable papi print backend])],,
1464              [enable_papi=auto])
1465
1466 if test "x$enable_papi" = "xno"; then
1467   AM_CONDITIONAL(HAVE_PAPI, false)
1468 else
1469   AC_MSG_CHECKING(libpapi)
1470   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1471   if test $have_papi = yes; then
1472     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1473   fi
1474   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1475   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1476     AC_MSG_ERROR([
1477 *** papi not found.
1478 ])
1479   fi
1480 fi
1481
1482 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1483
1484 gtk_save_cppflags="$CPPFLAGS"
1485 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1486
1487 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1488 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1489 *** backend enabled.]))
1490
1491 if test "$os_win32" != "yes"; then
1492   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1493 *** Can't find cairo-ps.h. You must build Cairo with the
1494 *** postscript backend enabled.]))
1495
1496   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1497 *** Can't find cairo-svg.h. You must build Cairo with the
1498 *** svg backend enabled.]))
1499 fi
1500
1501 CPPFLAGS="$gtk_save_cppflags"
1502
1503
1504 AC_ARG_ENABLE(test-print-backend,
1505               [AC_HELP_STRING([--enable-test-print-backend],
1506                               [build test print backend])],,
1507               [enable_test_print_backend=no])
1508 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1509
1510
1511 ################################################################
1512 # Strip -export-dynamic from the link lines of various libraries
1513 ################################################################
1514
1515 #
1516 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1517 #  but this flag is only meaningful for executables. For libraries
1518 #  the effect is undefined; what it causes on Linux is that the
1519 #  export list from -export-symbols-regex is ignored and everything
1520 #  is exported
1521 #
1522 # We are using gmodule-no-export now, but I'm leaving the stripping
1523 # code in place for now, since pango and atk still require gmodule.
1524 export SED
1525 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1526 if test -n "$export_dynamic"; then
1527   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1528   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1529 fi
1530
1531 ##################################################
1532 # GObject introspection
1533 ##################################################
1534
1535 GOBJECT_INTROSPECTION_CHECK([0.9.3])
1536
1537 ##################################################
1538 # Checks for gtk-doc and docbook-tools
1539 ##################################################
1540
1541 GTK_DOC_CHECK([1.11])
1542
1543 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1544 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1545
1546 AC_ARG_ENABLE(man,
1547               [AC_HELP_STRING([--enable-man],
1548                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1549               enable_man=no)
1550
1551 if test "${enable_man}" != no; then
1552   dnl
1553   dnl Check for xsltproc
1554   dnl
1555   AC_PATH_PROG([XSLTPROC], [xsltproc])
1556   if test -z "$XSLTPROC"; then
1557     enable_man=no
1558   fi
1559
1560   dnl check for DocBook DTD and stylesheets in the local catalog.
1561   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1562      [DocBook XML DTD V4.1.2],,enable_man=no)
1563   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1564      [DocBook XSL Stylesheets],,enable_man=no)
1565 fi
1566
1567 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1568
1569
1570 ##################################################
1571 # Output commands
1572 ##################################################
1573
1574 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1575         outfile=gdkconfig.h-tmp
1576         cat > $outfile <<\_______EOF
1577 /* gdkconfig.h
1578  *
1579  * This is a generated file.  Please modify `configure.ac'
1580  */
1581
1582 #ifndef GDKCONFIG_H
1583 #define GDKCONFIG_H
1584
1585 #ifdef __cplusplus
1586 extern "C" {
1587 #endif /* __cplusplus */
1588
1589 #ifndef GSEAL
1590 /* introduce GSEAL() here for all of Gdk and Gtk+ without the need to modify GLib */
1591 #  ifdef GSEAL_ENABLE
1592 #    define GSEAL(ident)      _g_sealed__ ## ident
1593 #  else
1594 #    define GSEAL(ident)      ident
1595 #  endif
1596 #endif /* !GSEAL */
1597
1598 _______EOF
1599
1600         cat >>$outfile <<_______EOF
1601 $gdk_windowing
1602 $gdk_wc
1603 _______EOF
1604
1605         cat >>$outfile <<_______EOF
1606
1607 #ifdef __cplusplus
1608 }
1609 #endif /* __cplusplus */
1610
1611 #endif /* GDKCONFIG_H */
1612 _______EOF
1613
1614
1615         if cmp -s $outfile gdk/gdkconfig.h; then
1616           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1617           rm -f $outfile
1618         else
1619           mv $outfile gdk/gdkconfig.h
1620         fi
1621 ],[
1622 if test "x$gdktarget" = "xx11" ; then
1623   gdk_windowing='
1624 #define GDK_WINDOWING_X11'
1625 elif test "x$gdktarget" = "xwin32" ; then
1626   gdk_windowing='
1627 #define GDK_NATIVE_WINDOW_POINTER
1628
1629 #define GDK_WINDOWING_WIN32'
1630 elif test "x$gdktarget" = "xquartz" ; then
1631   gdk_windowing='
1632 #define GDK_WINDOWING_QUARTZ'
1633 fi
1634
1635 if test x$gdk_wchar_h = xyes; then
1636   gdk_wc='
1637 #define GDK_HAVE_WCHAR_H 1'
1638 fi
1639 if test x$gdk_wctype_h = xyes; then
1640   gdk_wc="\$gdk_wc
1641 #define GDK_HAVE_WCTYPE_H 1"
1642 fi
1643 if test x$gdk_working_wctype = xno; then
1644   gdk_wc="\$gdk_wc
1645 #define GDK_HAVE_BROKEN_WCTYPE 1"
1646 fi
1647 ])
1648
1649 dnl
1650 dnl Check for -Bsymbolic-functions linker flag used to avoid
1651 dnl intra-library PLT jumps, if available.
1652 dnl
1653 AC_ARG_ENABLE(Bsymbolic,
1654               [AC_HELP_STRING([--disable-Bsymbolic],
1655                               [avoid linking with -Bsymbolic])],,
1656               [SAVED_LDFLAGS="${LDFLAGS}"
1657                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1658                LDFLAGS=-Wl,-Bsymbolic-functions
1659                AC_TRY_LINK([], [int main (void) { return 0; }],
1660                            AC_MSG_RESULT(yes)
1661                            enable_Bsymbolic=yes,
1662                            AC_MSG_RESULT(no)
1663                            enable_Bsymbolic=no)
1664                LDFLAGS="${SAVED_LDFLAGS}"])
1665
1666 if test "x${enable_Bsymbolic}" == "xyes"; then
1667   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1668 fi
1669 AC_SUBST(GTK_LINK_FLAGS)
1670
1671 AC_CONFIG_FILES([
1672 config.h.win32
1673 gtk-zip.sh
1674 Makefile
1675 gdk-3.0.pc
1676 gtk+-3.0.pc
1677 gtk+-unix-print-3.0.pc
1678 gail-3.0.pc
1679 gdk-3.0-uninstalled.pc
1680 gtk+-3.0-uninstalled.pc
1681 gail-3.0-uninstalled.pc
1682 m4macros/Makefile
1683 po/Makefile.in
1684 po-properties/Makefile.in
1685 demos/Makefile
1686 demos/gtk-demo/Makefile
1687 demos/gtk-demo/geninclude.pl
1688 tests/Makefile
1689 docs/Makefile
1690 docs/reference/Makefile
1691 docs/reference/gdk/Makefile
1692 docs/reference/gdk/version.xml
1693 docs/reference/gtk/Makefile
1694 docs/reference/gtk/version.xml
1695 docs/reference/libgail-util/Makefile
1696 docs/faq/Makefile
1697 docs/tools/Makefile
1698 docs/tutorial/Makefile
1699 build/Makefile
1700 build/win32/Makefile
1701 build/win32/vs9/Makefile
1702 gdk/Makefile
1703 gdk/x11/Makefile
1704 gdk/win32/Makefile
1705 gdk/win32/rc/Makefile
1706 gdk/win32/rc/gdk.rc
1707 gdk/quartz/Makefile
1708 gdk/tests/Makefile
1709 gtk/Makefile
1710 gtk/makefile.msc
1711 gtk/gtkversion.h
1712 gtk/gtk-win32.rc
1713 gtk/theme-bits/Makefile
1714 gtk/tests/Makefile
1715 modules/Makefile
1716 modules/other/Makefile
1717 modules/other/gail/Makefile
1718 modules/other/gail/libgail-util/Makefile
1719 modules/other/gail/tests/Makefile
1720 modules/engines/Makefile
1721 modules/engines/pixbuf/Makefile
1722 modules/engines/ms-windows/Makefile
1723 modules/engines/ms-windows/Theme/Makefile
1724 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1725 modules/input/Makefile
1726 modules/printbackends/Makefile
1727 modules/printbackends/cups/Makefile
1728 modules/printbackends/lpr/Makefile
1729 modules/printbackends/file/Makefile
1730 modules/printbackends/papi/Makefile
1731 modules/printbackends/test/Makefile
1732 perf/Makefile
1733 ])
1734
1735 AC_OUTPUT
1736
1737 echo "configuration:
1738         target:             $gdktarget"