Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 #
   3 # Fetchmail automatic configuration support
   4 #
   5 # Eric S. Raymond <esr@thyrsus.com>
   6 # 2004 - 2010 Matthias Andree <matthias.andree@gmx.de>
   7 #
   8 dnl Process this file with autoconf to produce a configure script.
   9 dnl
  10
  11 dnl XXX - if bumping version here, check fetchmail.man, too!
  12 AC_INIT([fetchmail],[6.3.17],[fetchmail-users@lists.berlios.de])
  13 AC_CONFIG_SRCDIR([fetchmail.h])
  14 AC_CONFIG_HEADERS([config.h])
  15 AC_CONFIG_LIBOBJ_DIR([.])
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl automake options are in Makefile.am
  20 AC_PREREQ(2.60)
  21 dnl 2.60 required for AC_USE_SYSTEM_EXTENSIONS
  22 AM_INIT_AUTOMAKE
  23
  24 dnl python is optional
  25 #
  26 # you can pass PYTHON=: in environment or on the command line
  27 # to disable python detection and continue without building/installing
  28 # fetchmail.conf -- be sure to check README.packaging, too!
  29 #
  30 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  31 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  32
  33 AC_PROG_AWK
  34 AC_PROG_CC
  35 AM_PROG_CC_C_O
  36 AC_PROG_INSTALL
  37 AC_PROG_CPP                     dnl Later checks need this.
  38 AC_PROG_RANLIB
  39 AM_PROG_CC_C_O
  40 AC_USE_SYSTEM_EXTENSIONS
  41
  42 AC_ISC_POSIX
  43 dnl AC_ISC_POSIX: - XXX FIXME: remove in fetchmail 6.4.
  44 dnl This macro adds `-lcposix' to output variable `LIBS' if necessary
  45 dnl for Posix facilities.  Sun dropped support for the obsolete
  46 dnl INTERACTIVE Systems Corporation Unix on 2006-07-23.  New programs
  47 dnl need not use this macro.  It is implemented as
  48 dnl `AC_SEARCH_LIBS([strerror], [cposix])'
  49
  50 dnl check for b0rked Solaris (and other shells) and find one that works
  51 AC_MSG_CHECKING(for a working shell...)
  52 for i in /usr/xpg6/bin/sh /usr/xpg4/bin/sh /usr/ccs/bin/sh /bin/sh /usr/bin/sh /bin/ksh /bin/bash /usr/local/bin/bash ; do
  53     $i -c 'if ! false ; then echo $(echo ok) ; fi' >config.$$ 2>/dev/null
  54     j=`cat config.$$`
  55     rm -f config.$$
  56     if test "x$j" = "xok" ; then
  57         SHELL=$i
  58         AC_SUBST(SHELL)
  59         break
  60     fi
  61 done
  62 AC_MSG_RESULT($SHELL)
  63 if test "x$SHELL" = "x" ; then
  64     AC_MSG_ERROR(no SUS compliant shell found - on Solaris, install SUNWxcu4)
  65 fi
  66
  67
  68 AC_HEADER_STDC
  69 AC_HEADER_TIME
  70 AC_TYPE_SIZE_T
  71 AC_TYPE_PID_T
  72 AC_TYPE_SIGNAL
  73 AC_CHECK_HEADERS([unistd.h termios.h termio.h sgtty.h stdarg.h \
  74         sys/itimer.h fcntl.h sys/fcntl.h memory.h sys/wait.h \
  75         arpa/inet.h arpa/nameser.h netinet/in.h net/socket.h netdb.h \
  76         sys/select.h sys/socket.h sys/time.h langinfo.h md5.h])
  77 if test _$ac_cv_header_stdarg_h != _yes ; then
  78 AC_MSG_WARN([stdarg.h is not defined. Unsupported configuration, proceed at your own risk.])
  79 fi
  80 AC_CHECK_TYPE(u_int32_t,,
  81         AC_DEFINE(u_int32_t,unsigned int,
  82                 [Define to unsigned int if <sys/types.h> does not define.]),
  83         [AC_INCLUDES_DEFAULT
  84 #ifdef HAVE_ARPA_NAMESER_H
  85 #include <arpa/nameser.h>
  86 #endif])
  87 AC_CHECK_HEADERS([resolv.h],,,[
  88 #include <sys/types.h>
  89 #ifdef HAVE_NETINET_IN_H
  90 #include <netinet/in.h>
  91 #endif
  92 #ifdef HAVE_ARPA_NAMESER_H
  93 #include <arpa/nameser.h>
  94 #endif
  95 ])
  96
  97 AC_CHECK_DECLS([h_errno],,,[
  98         AC_INCLUDES_DEFAULT
  99         #ifdef HAVE_NETDB_H
 100         #include <netdb.h>
 101         #endif
 102 ])
 103
 104 AC_C_CONST                      dnl getopt needs this.
 105
 106 AM_PROG_LEX
 107 AC_PROG_MAKE_SET
 108 AC_PROG_YACC
 109
 110 # Check for OS special cases
 111 case $host_os in
 112 darwin*)
 113     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
 114     CPPFLAGS="$CPPFLAGS -DBIND_8_COMPAT"
 115     ;;
 116 # Check for FreeBSD special case: more libs needed
 117 freebsd*)
 118     AC_MSG_NOTICE(found FreeBSD - Adding -lkvm -lcom_err to standard libraries)
 119     LIBS="$LIBS -lkvm -lcom_err"
 120     ;;
 121 # Check for LynxOS special case: -lbsd needed (at least on 2.3.0) and -s
 122 # not working.
 123 lynxos*)
 124     AC_MSG_NOTICE(found LynxOS - Adding -lbsd to standard libraries)
 125     LIBS="$LIBS -lbsd"
 126     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 127     AC_MSG_NOTICE(found LynxOS - Prepending standard include path to gcc flags)
 128     CPPFLAGS="$CPPFLAGS -I/usr/include"
 129     ;;
 130 # Check for Rhapsody special case: it doesn't like -s
 131 rhapsody*)
 132     AC_MSG_NOTICE(found Rhapsody - Removing -s load flag)
 133     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 134     ;;
 135 esac
 136
 137 AC_CACHE_SAVE
 138
 139 dnl i18n
 140 AM_GNU_GETTEXT([external], [need-ngettext])
 141 AM_GNU_GETTEXT_VERSION([0.14.6])
 142 dnl end i18n
 143
 144 # Under sysV68, socket and friends are provided by the C library.
 145 # -linet does not provide socket, but causes multiple definition
 146 # errors at link-time.  It is thus better to only use the C library.
 147 # So don't add -linet to the link list unless it's necessary
 148 AC_CHECK_FUNC(socket,
 149     AC_MSG_RESULT(using libc's socket),
 150     AC_CHECK_LIB(socket,socket)
 151     AC_CHECK_LIB(inet,socket))
 152
 153 # The condition in this test copes with the presence of inet_addr in libc6.
 154 AC_CHECK_FUNC(inet_addr,
 155     AC_MSG_RESULT(using libc's inet_addr),
 156     AC_CHECK_LIB(nsl,inet_addr))
 157
 158 dnl Port hack for Interactive UNIX System V/386 Release 3.2
 159 AC_CHECK_LIB(cposix, strchr,
 160                 [DEFS="$DEFS -D_SYSV3"
 161                 LIBS="$LIBS -lcposix"])
 162
 163 dnl Port hack for Sparc/NetBSD-1.5
 164 dnl
 165 dnl NB: this has been disabled as it causes the unconditional
 166 dnl addition of libintl to the build, which is both undesired
 167 dnl and breaks on Solaris/Blastwave.org machines.
 168 dnl
 169 dnl AC_CHECK_LIB(intl, gettext,
 170 dnl             [LIBS="$LIBS -lintl"])
 171
 172 AC_REPLACE_FUNCS([strstr strcasecmp memmove stpcpy strlcpy strlcat])
 173
 174 have_md5=no
 175 if test "$ac_cv_header_md5_h" != no ; then
 176     AC_SEARCH_LIBS(MD5Init, [md], [have_md5=yes])
 177 fi
 178
 179 if test "$have_md5" != yes ; then
 180     AC_LIBSOURCE(md5c.c)
 181     EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"
 182 fi
 183
 184 AC_CHECK_FUNC(getopt_long, [],
 185               [AC_LIBSOURCES([getopt.c, getopt1.c])
 186                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 187
 188 AC_FUNC_VPRINTF
 189
 190 AC_SUBST(EXTRAOBJ)
 191
 192 AC_CHECK_FUNCS(tcsetattr stty setsid geteuid seteuid dnl
 193   strerror syslog snprintf vprintf vsnprintf vsyslog dnl
 194   atexit inet_aton strftime setrlimit socketpair dnl
 195   sigaction strdup setlocale)
 196
 197 AC_CHECK_DECLS([strerror,getenv])
 198 dnl INET6 is used by KAME/getnameinfo
 199 AC_CACHE_CHECK(for AF_INET6/PF_INET6,ac_cv_inet6,
 200 AC_COMPILE_IFELSE([
 201   AC_LANG_PROGRAM([[
 202     #ifdef HAVE_SYS_TYPES_H
 203     #include <sys/types.h>
 204     #endif
 205     #ifdef HAVE_SYS_SOCKET_H
 206     #include <sys/socket.h>
 207     #endif
 208   ]],[[
 209     int foo = AF_INET6;
 210     int bar = PF_INET6;
 211   ]])],
 212   ac_cv_inet6=yes , ac_cv_inet6=no
 213 ))
 214 if test "x$ac_cv_inet6" = xyes
 215 then
 216     AC_DEFINE(INET6,1,Define to 1 if your system defines AF_INET6 and PF_INET6.)
 217 fi
 218
 219 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 220 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 221 # library.  So don't add -lresolv to the link list unless it's necessary
 222 # (It will be necessary when using GNU libc6).
 223 old_LIBS="$LIBS"
 224 for lib in '' -lresolv; do
 225     if test -z "$lib"; then
 226        AC_MSG_CHECKING([for res_search in libc])
 227     else
 228        AC_MSG_CHECKING([for res_search in $lib])
 229     fi
 230     LIBS="$old_LIBS $lib"
 231     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 232 #include <sys/types.h>
 233 #ifdef HAVE_NETINET_IN_H
 234 #include <netinet/in.h>
 235 #endif
 236 #ifdef HAVE_ARPA_NAMESER_H
 237 #include <arpa/nameser.h>
 238 #endif
 239 #ifdef HAVE_RESOLV_H
 240 #include <resolv.h>
 241 #endif
 242 extern int res_search();
 243 ]], [[res_search(0, 0, 0, 0, 0); dn_skipname(0,0);]])],
 244     [AC_MSG_RESULT([found])
 245      AC_DEFINE(HAVE_RES_SEARCH, [1],
 246                [Define to 1 if you have the 'res_search' and 'dn_skipname' functions.])
 247      break], [AC_MSG_RESULT([not found])])
 248      LIBS=$old_LIBS
 249 done
 250
 251 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 252 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 253
 254 dnl Check for usable void pointer type
 255 AC_MSG_CHECKING(use of void pointer type)
 256 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[char *p;
 257     void *xmalloc();
 258     p = (char *) xmalloc(1);
 259    ]])],[AC_DEFINE(HAVE_VOIDPOINTER,1,[Define if your C compiler allows void * as a function result]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 260
 261 dnl Check for ANSI volatile
 262 AC_C_VOLATILE
 263
 264 dnl Check out the wait reality.  We have to assume sys/wait.h is present.
 265 AC_CHECK_FUNCS(waitpid wait3)
 266 AC_MSG_CHECKING(for union wait);
 267 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 268 #include <sys/wait.h>]], [[union wait status; int pid; pid = wait (&status);
 269 #ifdef WEXITSTATUS
 270 /* Some POSIXoid systems have both the new-style macros and the old
 271    union wait type, and they do not work together.  If union wait
 272    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 273 if (WEXITSTATUS (status) != 0) pid = -1;
 274 #endif
 275 #ifdef HAVE_WAITPID
 276 /* Make sure union wait works with waitpid.  */
 277 pid = waitpid (-1, &status, 0);
 278 #endif
 279 ]])],[AC_DEFINE(HAVE_UNION_WAIT,1,Define if 'union wait' is the type of the first arg to wait functions.) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 280
 281 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 282 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 283 /* NetBSD declares sys_siglist in <unistd.h>.  */
 284 #ifdef HAVE_UNISTD_H
 285 #include <unistd.h>
 286 #endif]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 287
 288 # Find the right directory to put the root-mode PID file in
 289 for dir in "/var/run" "/etc"
 290 do
 291         if test -d $dir
 292         then
 293                 break;
 294         fi
 295 done
 296 AC_MSG_RESULT(root-mode pid file will go in $dir)
 297 AC_DEFINE_UNQUOTED(PID_DIR, "$dir", directory for PID lock files)
 298
 299 AC_ARG_ENABLE(pwmd,
 300         [  --enable-pwmd           enable Password Manager Daemon support],
 301         , [enable_pwmd=no])
 302
 303 if test "$enable_pwmd" = "yes"; then
 304     PKG_CHECK_EXISTS([libpwmd], have_libpwmd=1,
 305                      AC_MSG_ERROR([Could not find libpwmd pkg-config module.]))
 306
 307
 308     PKG_CHECK_MODULES([libpwmd], [libpwmd >= 6.0.0])
 309     AM_CONDITIONAL(HAVE_LIBPWMD, true)
 310     AC_DEFINE(HAVE_LIBPWMD, 1, [Define if you have libPWMD installed.])
 311 else
 312     AM_CONDITIONAL(HAVE_LIBPWMD, false)
 313 fi
 314
 315 # We may have a fallback MDA available in case the socket open to the
 316 # local SMTP listener fails.  Best to use procmail for this, as we know
 317 # it won't try delivering through local SMTP and cause a mail loop.
 318 # Sendmail without the -t option to use the message headers will work too,
 319 # not just for sendmail itself but for workalikes like exim.
 320 #
 321 # Note1: A disadvantage of using procmail is that local alias expansion
 322 # according to /etc/aliases won't get done if we fall back.  This doesn't
 323 # matter in single-drop mode.
 324 #
 325 # Note2: it would be a very bad idea to use any MDA that doesn't return
 326 # a refuse-to-deliver status on disk- or process-table-full
 327 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 328 # like exim that might be lurking under a sendmail alias) do the right
 329 # thing in this circumstance.  Matthias Andree warns that procmail does
 330 # not.
 331 #
 332 # Note3: Defalt value of fallback is now off.  Matthias writes:
 333 #
 334 # 1. there is no way to predict when the fallback is used. With some MTAs
 335 #    (such as those limiting load average), outer circumstances can cause
 336 #    the fallback to kick in.
 337 #
 338 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 339 #    not only about alias expansion, .forwards to special filters won't
 340 #    work, mail may end up in a different place (users claim "mail loss"
 341 #    for that).
 342 #
 343 # 3. The claim procmail did the right thing with its exit codes is plain
 344 #    wrong. I've seen procmail exit with code 1 when it should have exited
 345 #    with code 75, like, configuration errors. Procmail is a dangerous
 346 #    beast and is best replaced by maildrop.
 347 #
 348 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 349 #    cannot tell which one it should choose. Say, your MTA is configured
 350 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 351 #    chooses procmail, this is plain wrong.
 352 #
 353
 354 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 355 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 356 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 357
 358 ###     use option --disable-fallback to disable fallback MDA
 359 ###     use option --enable-fallback=procmail or
 360 ###                --enable-fallback=sendmail to select
 361 AC_ARG_ENABLE(fallback,
 362         [  --enable-fallback=procmail    enable procmail as fallback
 363   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 364   --enable-fallback=maildrop    enable maildrop as fallback
 365   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 366
 367 case "$enable_fallback" in
 368         sendmail)       if test -z "$sendmail" ; then
 369                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 370                                 #not reached
 371                         fi
 372                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 373                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 374                         ;;
 375         procmail)       if test -z "$procmail" ; then
 376                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 377                                 #not reached
 378                         fi
 379                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 380                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 381                         ;;
 382         maildrop)       if test -z "$maildrop" ; then
 383                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 384                                 #not reached
 385                         fi
 386                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 387                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 388                         ;;
 389         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 390                         ;;
 391         auto|yes|set)   if test -n "$sendmail" ; then
 392                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 393                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 394                         else
 395                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 396                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 397                         fi
 398                         ;;
 399         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 400                         #notreached
 401                         ;;
 402 esac
 403
 404 AC_CHECK_SIZEOF(short)
 405 AC_CHECK_SIZEOF(int)
 406 AC_CHECK_SIZEOF(long)
 407
 408 ###     use option --enable-POP2 to compile in the POP2 support
 409 AC_ARG_ENABLE(POP2,
 410         [  --enable-POP2           compile in POP2 protocol support (obsolete)],
 411         [with_POP2=$enableval],
 412         [with_POP2=no])
 413 test "$with_POP2" = "yes" && AC_DEFINE(POP2_ENABLE,1,Define if you want POP2 support compiled in)
 414 AM_CONDITIONAL(POP2_ENABLE, test "$with_POP2" = yes)
 415
 416 ###     use option --disable-POP3 to omit the POP3 support
 417 AC_ARG_ENABLE(POP3,
 418         [  --disable-POP3          don't compile in POP3 protocol support],
 419         [with_POP3=$enableval],
 420         [with_POP3=yes])
 421 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 422 AM_CONDITIONAL(POP3_ENABLE, test "$with_POP3" = yes)
 423
 424 ###     use option --disable-IMAP to omit the IMAP support
 425 AC_ARG_ENABLE(IMAP,
 426         [  --disable-IMAP          don't compile in IMAP protocol support],
 427         [with_IMAP=$enableval],
 428         [with_IMAP=yes])
 429 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,Define if you want IMAP support compiled in)
 430 AM_CONDITIONAL(IMAP_ENABLE, test "$with_IMAP" = yes)
 431
 432 ###     use option --disable-ETRN to omit the ETRN support
 433 AC_ARG_ENABLE(ETRN,
 434         [  --disable-ETRN          don't compile in ETRN protocol support],
 435         [with_ETRN=$enableval],
 436         [with_ETRN=yes])
 437 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 438 AM_CONDITIONAL(ETRN_ENABLE, test "$with_ETRN" = yes)
 439
 440 ###     use option --disable-ODMR to omit the ODMR support
 441 AC_ARG_ENABLE(ODMR,
 442         [  --disable-ODMR          don't compile in ODMR protocol support],
 443         [with_ODMR=$enableval],
 444         [with_ODMR=yes])
 445 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 446 AM_CONDITIONAL(ODMR_ENABLE, test "$with_ODMR" = yes)
 447
 448 ###     use option --enable-RPA to compile in the RPA support
 449 AC_ARG_ENABLE(RPA,
 450         [  --enable-RPA            compile in RPA protocol support],
 451         [with_RPA=$enableval],
 452         [with_RPA=no])
 453 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 454 AM_CONDITIONAL(RPA_ENABLE, test "$with_RPA" = yes)
 455
 456 ###     use option --enable-NTLM to compile in the NTLM support
 457 AC_ARG_ENABLE(NTLM,
 458         [  --enable-NTLM           compile in NTLM authentication support],
 459         [with_NTLM=$enableval],
 460         [with_NTLM=no])
 461 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 462
 463 ###     use option --enable-SDPS to compile in the SDPS support
 464 AC_ARG_ENABLE(SDPS,
 465         [  --enable-SDPS           compile in SDPS protocol support],
 466         [with_SDPS=$enableval],
 467         [with_SDPS=no])
 468 if test "$with_SDPS" = yes ; then
 469    if test "$with_POP3" != yes ; then
 470        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 471        with_SDPS=no
 472    else
 473        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 474    fi
 475 fi
 476 if test "$with_POP3" != yes && test "$with_POP2" != yes \
 477     && test "$with_IMAP"  != yes ; then
 478     AC_MSG_ERROR([You must enable at least one of POP2, POP3 and IMAP.])
 479 fi
 480
 481 AC_CACHE_SAVE
 482
 483 ###     use option --enable-opie to compile in the OPIE support
 484 AC_ARG_ENABLE(opie,
 485         [  --enable-opie           support OTP through the OPIE library],
 486         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR(cannot find <opie.h>, which is required for OPIE support.)])
 487           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR(cannot find libopie, which is required for OPIE support.)])
 488           with_opie=$enableval],
 489         [with_opie=no])
 490 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 491
 492 dnl Mostly stolen from gnulib's getaddrinfo.m4
 493 AC_SEARCH_LIBS(getaddrinfo, [nsl socket])
 494 AC_CACHE_CHECK([for getaddrinfo],[fm_cv_getaddrinfo],[
 495   AC_TRY_LINK([
 496 #include <sys/types.h>
 497 #ifdef HAVE_SYS_SOCKET_H
 498 #include <sys/socket.h>
 499 #endif
 500 #ifdef HAVE_NETDB_H
 501 #include <netdb.h>
 502 #endif
 503   ], [getaddrinfo(0, 0, 0, 0);],
 504     [ fm_cv_getaddrinfo=yes],
 505     [ fm_cv_getaddrinfo=no ])
 506 ])
 507
 508 if test x"$fm_cv_getaddrinfo" = "xyes"; then
 509      AC_DEFINE(HAVE_GETADDRINFO, 1,
 510       [Define to 1 if you have the getaddrinfo function.])
 511 fi
 512
 513 AC_CACHE_CHECK([for getnameinfo],[fm_cv_getnameinfo],[
 514   AC_TRY_LINK([
 515 #include <sys/types.h>
 516 #ifdef HAVE_SYS_SOCKET_H
 517 #include <sys/socket.h>
 518 #endif
 519 #ifdef HAVE_NETDB_H
 520 #include <netdb.h>
 521 #endif
 522 #ifndef NULL
 523 #define NULL 0
 524 #endif
 525   ], [getnameinfo(NULL,0, NULL,0, NULL, 0, 0);],
 526     [ fm_cv_getnameinfo=yes],
 527     [ fm_cv_getnameinfo=no ])
 528 ])
 529 if test $fm_cv_getnameinfo = yes ; then
 530     AC_DEFINE(HAVE_GETNAMEINFO,1,[Define to 1 if your system has getnameinfo()])
 531 fi
 532
 533 AM_CONDITIONAL(NEED_GETADDRINFO, test "$fm_cv_getaddrinfo" != yes)
 534 AM_CONDITIONAL(NEED_GETNAMEINFO, test "$fm_cv_getnameinfo"   != yes)
 535
 536 AC_CHECK_FUNCS(inet_ntop)
 537 dnl Check if getaddrinfo is async-signal-safe - most implementations aren't
 538 if test "$fm_cv_getaddrinfo" = yes ; then
 539     AC_MSG_CHECKING(if your getaddrinfo is async-signal-safe)
 540     gai_ts=no
 541     dnl we have getaddrinfo() - check if the OS is known to have a async-signal-safe implementation
 542     case $host_os in
 543         darwin9*)                               gai_ts=yes ;;
 544         linux*)                                 gai_ts=yes ;;
 545         freebsd5.5|freebsd6*|freebsd7*)         gai_ts=yes ;;
 546         solaris2.8|solaris2.9|solaris2.10)      gai_ts=yes ;;
 547     esac
 548     AC_MSG_RESULT($gai_ts)
 549     if test $gai_ts = yes ; then
 550         AC_DEFINE(GETADDRINFO_ASYNCSAFE, 1, [define to 1 if you know your getaddrinfo function is async-signal-safe])
 551     fi
 552 fi
 553
 554 # This version of the Kerberos 4 and 5 options addresses the follwing issues:
 555 #
 556 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 557 #   OpenSSL support (Debian's is)
 558 # * Build the kerberos.c stuff (KPOP) only for kerberosIV, to avoid breakage.
 559 #   I don't know if this is 100% correct, but now at least IMAP and POP3
 560 #   behave the same way regarding kerberosV.
 561 # * Build without any fuss for both kerberosIV and V at the same time.
 562 # * Move all the kerberos header mess to kerberos.h, and #include that
 563 #   in driver.c and kerberos.c.
 564 #
 565 # Tested using the Heimdal Kerberos V libs, Kungliga Tekniska Högskolan (the
 566 # Royal Institute of Technology in Stockholm, Sweden)'s kerberos IV libs, and
 567 # the MIT reference implementation of KerberosV (all as packaged in Debian).
 568
 569 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 570 ### make sure --with-ssl is run before --with-kerberos* !
 571 AC_ARG_WITH(kerberos5,
 572        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 573 [
 574 if test "$with_kerberos5" != "no"
 575 then
 576 # Check for a OpenBSD special case
 577 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 578 then
 579   AS_MESSAGE(checking kerberosV for OpenBSD...)
 580   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 581   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 582   CFLAGS="$CFLAGS -I/usr/include/kerberosV"
 583   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 584 elif krb5-config 2> /dev/null >/dev/null ; then
 585   krb5_prefix=`krb5-config --prefix krb5`
 586   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 587   if test -f ${krb5_prefix}/include/et/com_err.h && \
 588    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 589     CFLAGS="$CFLAGS -I${krb5_prefix}/include/et"
 590   fi
 591   unset krb5_prefix
 592   CFLAGS="$CFLAGS `krb5-config --cflags krb5`"
 593   LIBS="$LIBS `krb5-config --libs krb5`"
 594   AC_DEFINE(KERBEROS_V5)
 595 else
 596   if test "$with_kerberos5" != "yes"
 597   then
 598       LDFLAGS="$LDFLAGS -L${with_kerberos5}/lib"
 599       searchdirs="$with_kerberos5"
 600   else
 601       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 602   fi
 603   with_kerberos5=
 604   for dir in $searchdirs
 605   do AC_MSG_CHECKING([for Kerberos V in $dir])
 606      if test -f "$dir/include/krb5.h" || test -f "$dir/include/krb5/krb5.h"
 607      then
 608         if test -d "$dir/include/krb5" ; then CPPFLAGS="$CPPFLAGS -I$dir/include/krb5" ; fi
 609         ac_krblibs=
 610         if test -f "$dir/include/roken.h" || test -f "$dir/include/krb5/roken.h"
 611         then
 612            ac_krblibs="-lasn1 -lroken -lcom_err"
 613            AC_MSG_RESULT([Heimdal found])
 614           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 615           dnl we assume we do if it is available
 616            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 617                 ${LDFLAGS})
 618            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 619               AC_CHECK_LIB(crypto, MD5_Init, [],
 620                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 621                 ${LDFLAGS} ${ac_krblibs}),
 622            ${LDFLAGS} ${ac_krblibs})
 623            AC_DEFINE(HEIMDAL)
 624         else
 625           AC_MSG_RESULT([found])
 626           ac_krblibs="-lcom_err"
 627            AC_CHECK_LIB(crypto,
 628              krb5_des_string_to_key,
 629              libk5crypto=-lcrypto,
 630                 AC_CHECK_LIB(k5crypto,
 631                    krb5_des_string_to_key,
 632                    libk5crypto=-lk5crypto,
 633                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 634                    ${LDFLAGS} ${ac_krblibs}),
 635                  ${LDFLAGS} ${ac_krblibs})
 636         fi
 637         AC_CHECK_LIB(krb5, krb5_init_context,[],
 638            continue,
 639            ${LDFLAGS} ${ac_krblibs})
 640         AC_DEFINE(KERBEROS_V5)
 641         test "$dir" != "/usr" && CFLAGS="$CFLAGS -I$dir/include"
 642         LDFLAGS="$LDFLAGS -L$dir/lib"
 643        LIBS="$LIBS $ac_krblibs $libk5crypto"
 644         with_kerberos5=$dir
 645         break
 646      else
 647         AC_MSG_RESULT([not found])
 648      fi
 649   done
 650   if test -z "$with_kerberos5" ; then
 651      AC_MSG_ERROR([Kerberos 5 libraries not found])
 652   fi
 653 fi
 654 fi
 655 ]) dnl --with-kerberos5=DIR
 656
 657 ###    use option --with-kerberos=DIR to point at a Kerberos 4 directory
 658 KERBEROS_V4=0
 659 AC_ARG_WITH(kerberos,
 660        [  --with-kerberos=DIR     point fetchmail compilation at a Kerberos 4 directory],
 661 [
 662 if test "$with_kerberos" != "no"
 663 then
 664     AC_MSG_WARN([Kerberos IV support is obsolete. Use --with-kerberos5 if possible.])
 665 # Check for a NetBSD/OpenBSD special case
 666 if test "$with_kerberos" = "yes" && ( test `uname` = "NetBSD" || test `uname` = "OpenBSD" )
 667 then
 668   AS_MESSAGE(checking kerberosIV for `uname`...)
 669   KERBEROS_V4=1
 670   CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 671   case `uname` in
 672       NetBSD)  LIBS="$LIBS -lkrb -ldes -lroken -lcom_err" ;;
 673       OpenBSD) LIBS="$LIBS -lkrb -ldes" ;;
 674   esac
 675 elif krb4-config 2> /dev/null >/dev/null ; then
 676   krb4_prefix=`krb4-config --prefix`
 677   AC_MSG_RESULT([krb4-config points to kerberosIV under $krb4_prefix])
 678   unset krb4_prefix
 679   CFLAGS="$CFLAGS `krb4-config --cflags`"
 680   LIBS="$LIBS `krb4-config --libs`"
 681   KERBEROS_V4=1
 682 elif krb5-config 2> /dev/null >/dev/null ; then
 683   krb4_prefix=`krb5-config --prefix krb4`
 684   AC_MSG_RESULT([krb5-config points to kerberosIV under $krb4_prefix])
 685   if test -f ${krb4_prefix}/include/kerberosIV/krb.h ; then
 686     AC_DEFINE(KERBEROS_V4_V5,1,Define if you have Kerberos V4 headers under a kerberosIV directory)
 687   fi
 688   unset krb4_prefix
 689   CFLAGS="$CFLAGS `krb5-config --cflags krb4`"
 690   LIBS="$LIBS `krb5-config --libs krb4`"
 691   KERBEROS_V4=1
 692 else
 693   #we need to detect when we're building under a kerberosV compatibility
 694   #layer, btw...
 695   if test "$with_kerberos" != "yes" ; then
 696      searchdirs="$with_kerberos"
 697   else
 698      searchdirs="$with_kerberos5 /usr/kerberos /usr/kerberosIV /usr/athena /usr"
 699   fi
 700   with_kerberos=
 701   ac_saveLDFLAGS="$LDFLAGS"
 702   for dir in $searchdirs
 703   do
 704      AC_MSG_CHECKING([for Kerberos IV in $dir])
 705      if test -f "$dir/include/krb.h" || test -f "$dir/include/krb4.h" \
 706             || test -f "$dir/include/kerberosIV/krb.h"
 707      then
 708         AC_MSG_RESULT([found])
 709      else
 710         AC_MSG_RESULT([not found])
 711        continue
 712      fi
 713      #Find libs
 714      if test -f "$with_kerberos5/roken.h" ; then
 715        AC_CHECK_LIB(45, krb_mk_req)
 716      fi
 717      LDFLAGS="-L$dir/lib $ac_saveLDFLAGS"
 718      if test `uname` = "FreeBSD"; then
 719         AC_SEARCH_LIBS(_ossl_old_des_string_to_key, [des425 des crypto], [], continue)
 720      else
 721         AC_SEARCH_LIBS(des_string_to_key, [crypto], [], continue)
 722      fi
 723      AC_SEARCH_LIBS(krb_realmofhost, [krb4 krb], [], continue)
 724      with_kerberos="$dir"
 725      if test -f "$dir/include/kerberosIV/krb.h" ; then
 726         dir="$dir/include/kerberosIV"
 727      else
 728        dir="$dir/include"
 729      fi
 730      KERBEROS_V4=1
 731      test -f "$with_kerberos5/roken.h" && AC_DEFINE(HEIMDAL)
 732      test "$dir" != "/usr/include" && CFLAGS="$CFLAGS -I$dir"
 733      LDFLAGS="$LDFLAGS -L$with_kerberos/lib"
 734      break
 735   done
 736   if test -z "$with_kerberos" ; then
 737      AC_MSG_ERROR([Kerberos 4 libraries not found])
 738   fi
 739   LDFLAGS="$ac_saveLDFLAGS"
 740 fi
 741 fi
 742 ]) dnl --with-kerberos=DIR
 743 if test "$KERBEROS_V4" = 1 ; then
 744     AC_DEFINE(KERBEROS_V4,1,Define if you have Kerberos V4)
 745 fi
 746 AM_CONDITIONAL(KERBEROS_V4_ENABLE, test "$KERBEROS_V4" = 1)
 747
 748 ###     use option --with-ssl to compile in the SSL support
 749 AC_ARG_WITH(ssl,
 750         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 751         [with_ssl=$withval],
 752         [with_ssl=no])
 753 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 754
 755 if test "$with_ssl" = "yes"
 756 then
 757     #   User didn't specify an SSL location.  Let's look at some common
 758     #   directories where SSL has been found in the past and try and auto
 759     #   configure for SSL.  OpenSSL determination will be made later.
 760     #   This will screw up if an OpenSSL install is located in a later
 761     #   directory than an older SSLeay install, but the user should fix that
 762     #   anyways and he can override on the configure line.
 763     #   Just testing for directories is not sufficient, /usr exists on
 764     #   all systems!
 765     for ac_dir in \
 766       /usr/local/ssl \
 767       /usr/local \
 768       /usr/ssl \
 769       /usr \
 770       /local/ssl \
 771       /opt/ssl \
 772       /opt/csw \
 773       ; \
 774     do
 775         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 776             with_ssl=$ac_dir
 777             break;
 778         fi
 779     done
 780 fi
 781
 782 if test -n "$with_ssl" -a "$with_ssl" != "no"
 783 then
 784   # With the autoconfigure above, the only time this is going to be
 785   # true is going to be when we could not find the headers.  If they
 786   # are not in system standard locations, we are going to be broken.
 787   if test "$with_ssl" = "yes"
 788   then
 789     # Let's just define the standard location for the SSLeay root
 790     with_ssl="/usr/local/ssl"
 791   fi
 792   if test -r $with_ssl/include/openssl/ssl.h
 793   then
 794     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 795     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 796     test "$with_ssl" != "/usr" && CFLAGS="$CFLAGS -I$with_ssl/include"
 797     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 798     ### force the Kerberos direcory onto the include path so it will build.
 799     CFLAGS="$CFLAGS -I/usr/kerberos/include"
 800     ### OpenBSD comes with ssl headers
 801   else
 802     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 803   fi
 804   LDFLAGS="$LDFLAGS -L$with_ssl/lib"
 805   LIBS="$LIBS -lssl -lcrypto"
 806   dnl check if -ldl is needed
 807   AC_MSG_CHECKING([for additional library dependencies of SSL])
 808   found=0
 809   save_LIBS="$LIBS"
 810   for i in "" "-ldl" ; do
 811       LIBS="$LDFLAGS $save_LIBS $i"
 812       AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <openssl/ssl.h>],[SSL_library_init()])],[found=1; break])
 813   done
 814   if test $found = 0 ; then
 815       AC_MSG_RESULT([error])
 816       AC_MSG_ERROR([cannot link with SSL - check config.log])
 817   fi
 818   LIBS="$save_LIBS $i"
 819   if test "$i" = "" ; then i="(none)" ; fi
 820   AC_MSG_RESULT($i)
 821   dnl XXX FIXME: use pkg-config if available!
 822   AC_DEFINE(SSL_ENABLE)
 823 else
 824   AC_MSG_NOTICE(Disabling SSL support.)
 825 fi
 826
 827 ###     use option --with-socks=DIR to point at SOCKS library
 828 AC_ARG_WITH(socks,
 829         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 830 [
 831 if test "$with_socks" != no
 832 then
 833     if test "$with_socks" != yes
 834     then
 835         LDFLAGS="$LDFLAGS -L$with_socks"
 836     else
 837         AC_CHECK_LIB(socks, Rconnect,,
 838                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 839     fi
 840     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 841     CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 842     LIBS="-lsocks $LIBS"
 843 fi])
 844
 845 ###     use option --with-socks5=DIR to point at SOCKS library
 846 AC_ARG_WITH(socks5,
 847         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 848 [
 849 if test "$with_socks5" != no
 850 then
 851   if test "$with_socks5" != yes
 852   then
 853     LDFLAGS="$LDFLAGS -L$with_socks5"
 854   fi
 855   ac_savedLDFLAGS="$LDFLAGS"
 856   LDFLAGS="$LDFLAGS $LDFLAGS"
 857   AC_CHECK_LIB(socks5, SOCKSconnect,,
 858         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 859   AC_DEFINE(HAVE_SOCKS)
 860   CFLAGS="$CFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 861   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 862   LDFLAGS="$ac_savedLDFLAGS"
 863 fi])
 864
 865 dnl for libesmtp/ modules:
 866 ACX_WHICH_GETHOSTBYNAME_R
 867
 868 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 869 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 870
 871 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 872 AC_ARG_WITH(gssapi,
 873         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 874 [
 875 if test "$with_gssapi" != "no"
 876 then
 877   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 878   then
 879     with_gssapi=$with_kerberos5
 880   fi
 881
 882   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 883   then
 884     CFLAGS="$CFLAGS -I$with_gssapi/include"
 885     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 886   fi
 887
 888   dnl obtain gssapi default libs
 889   if krb5-config --libs gssapi 2>/dev/null >/dev/null ; then
 890       LIBS="$LIBS `krb5-config --libs gssapi`"
 891   else
 892     AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 893     if test -n "$nogss"
 894     then
 895       # -lgss not found
 896       if test "$with_gssapi" = yes ; then
 897           with_gssapi=/usr
 898       fi
 899       if test -f "$with_gssapi/include/roken.h" -o -f "$with_gssapi/include/krb5/roken.h"
 900       then
 901          # have roken.h, assume Heimdal
 902          case `uname` in
 903              NetBSD) LIBS="$LIBS -lkrb5" ;;
 904              *)      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl" ;;
 905          esac
 906          AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 907                       AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 908          AC_DEFINE(HEIMDAL)
 909       else
 910          # no roken.h, assume MIT
 911          AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 912                       AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 913       fi
 914     fi
 915   fi
 916   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 917   if test "$with_gssapi" != yes ; then
 918     CPPFLAGS="$CPPFLAGS -I$with_gssapi/include"
 919   fi
 920   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 921   if test "$ac_cv_header_gssapi_h" = "yes"; then
 922     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 923   else
 924     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 925   fi
 926 fi])
 927
 928 dnl ,------------------------------------------------------------------
 929 dnl Check if we need TRIO
 930 needtrio=0
 931 if test "$FORCE_TRIO" = "yes" ; then
 932     needtrio=1
 933     ac_cv_func_vsnprintf=no
 934     ac_cv_func_snprintf=no
 935 fi
 936 if test "x$ac_cv_func_snprintf" != "xyes" ; then
 937     AC_DEFINE(snprintf, trio_snprintf,
 938               [Define to trio_snprintf if your system lacks snprintf])
 939     needtrio=1
 940 fi
 941 if test "x$ac_cv_func_vsnprintf" != "xyes" ; then
 942     AC_DEFINE(vsnprintf, trio_vsnprintf,
 943               [Define to trio_vsnprintf if your system lacks vsnprintf])
 944     needtrio=1
 945 fi
 946 AM_CONDITIONAL(NEED_TRIO, test "$needtrio" = 1)
 947
 948 dnl TRIO IEEE compiler option for Alpha
 949 dnl
 950 if test "$needtrio" = 1 ; then
 951     AC_MSG_CHECKING(for IEEE compilation options)
 952     AC_CACHE_VAL(ac_cv_ieee_option, [
 953     AC_TRY_COMPILE(,[
 954     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
 955     # error "Option needed"
 956     #endif
 957     ],ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
 958     AC_TRY_COMPILE(,[
 959     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
 960     # error "Option needed"
 961     #endif
 962     ],ac_cv_ieee_option="-ieee",
 963     AC_TRY_COMPILE(,[
 964     #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
 965     # error "Option needed"
 966     #endif
 967     ],ac_cv_ieee_option="-mieee",
 968     ac_cv_ieee_option="none"
 969     )
 970     )
 971     )
 972     ])
 973     AC_MSG_RESULT($ac_cv_ieee_option)
 974     if test $ac_cv_ieee_option != none; then
 975       CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
 976     fi
 977 fi
 978 dnl ----------------------------------------------------------------'
 979
 980 AC_CONFIG_FILES([Makefile po/Makefile.in genlsm.sh])
 981 AC_OUTPUT
 982
 983 dnl Local Variables:
 984 dnl comment-start: "dnl "
 985 dnl comment-end: ""
 986 dnl comment-start-skip: "\\bdnl\\b\\s *"
 987 dnl compile-command: "make configure config.h.in"
 988 dnl End: