Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [2])
  12 m4_define([gtk_minor_version], [91])
  13 m4_define([gtk_micro_version], [5])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.64])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Define a string for the earliest version that this release has
  32 # backwards binary compatibility with for all interfaces a module
  33 # might. Unless we add module-only API with lower stability
  34 # guarantees, this should be unchanged until we break binary compat
  35 # for GTK+.
  36 #
  37 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  38 m4_define([gtk_binary_version], [3.0.0])
  39
  40 # required versions of other packages
  41 m4_define([glib_required_version], [2.27.3])
  42 m4_define([pango_required_version], [1.20])
  43 m4_define([atk_required_version], [1.29.2])
  44 m4_define([cairo_required_version], [1.10.0])
  45 m4_define([gdk_pixbuf_required_version], [2.21.0])
  46 GLIB_REQUIRED_VERSION=glib_required_version
  47 PANGO_REQUIRED_VERSION=pango_required_version
  48 ATK_REQUIRED_VERSION=atk_required_version
  49 CAIRO_REQUIRED_VERSION=cairo_required_version
  50 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  51 AC_SUBST(GLIB_REQUIRED_VERSION)
  52 AC_SUBST(PANGO_REQUIRED_VERSION)
  53 AC_SUBST(ATK_REQUIRED_VERSION)
  54 AC_SUBST(CAIRO_REQUIRED_VERSION)
  55 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  56
  57
  58 # Save this value here, since automake will set cflags later
  59 cflags_set=${CFLAGS+set}
  60
  61 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  62 AM_MAINTAINER_MODE([enable])
  63
  64 # Support silent build rules, requires at least automake-1.11. Enable
  65 # by either passing --enable-silent-rules to configure or passing V=0
  66 # to make
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69 #
  70 # For each of the libraries we build, we define the following
  71 # substituted variables:
  72 #
  73 # foo_PACKAGES:     pkg-config packages this library requires
  74 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  75 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  76 # foo_DEP_LIBS:     All libraries this module requires
  77 # foo_DEP_CFLAGS:   All cflags this module requires
  78
  79
  80 GTK_MAJOR_VERSION=gtk_major_version
  81 GTK_MINOR_VERSION=gtk_minor_version
  82 GTK_MICRO_VERSION=gtk_micro_version
  83 GTK_INTERFACE_AGE=gtk_interface_age
  84 GTK_BINARY_AGE=gtk_binary_age
  85 GTK_VERSION=gtk_version
  86 GTK_API_VERSION=gtk_api_version
  87 GTK_BINARY_VERSION=gtk_binary_version
  88 AC_SUBST(GTK_MAJOR_VERSION)
  89 AC_SUBST(GTK_MINOR_VERSION)
  90 AC_SUBST(GTK_MICRO_VERSION)
  91 AC_SUBST(GTK_INTERFACE_AGE)
  92 AC_SUBST(GTK_BINARY_AGE)
  93 AC_SUBST(GTK_API_VERSION)
  94 AC_SUBST(GTK_VERSION)
  95 AC_SUBST(GTK_BINARY_VERSION)
  96
  97 # libtool versioning
  98 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  99 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 100 #LT_REVISION=$GTK_INTERFACE_AGE
 101 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 102 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 103
 104 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 105 m4_define([lt_revision], [gtk_interface_age])
 106 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 107 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 108 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 109 AC_SUBST(LT_VERSION_INFO)
 110 AC_SUBST(LT_CURRENT_MINUS_AGE)
 111
 112 m4_define([gail_lt_current],[0])
 113 m4_define([gail_lt_revision],[0])
 114 m4_define([gail_lt_age],[0])
 115 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 116 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 117 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 118 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 119
 120 # Checks for programs.
 121 AC_PROG_CC
 122 AC_PROG_CC_C_O
 123 AC_PROG_CC_STDC
 124 AC_PROG_INSTALL
 125 AC_PROG_MAKE_SET
 126
 127
 128 GETTEXT_PACKAGE=gtk30
 129 AC_SUBST(GETTEXT_PACKAGE)
 130 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 131                    [The prefix for our gettext translation domains.])
 132
 133 AC_CANONICAL_HOST
 134
 135 MATH_LIB=-lm
 136 AC_MSG_CHECKING([for native Win32])
 137 LIB_EXE_MACHINE_FLAG=X86
 138 EXE_MANIFEST_ARCHITECTURE=X86
 139 case "$host" in
 140   *-*-mingw*)
 141     os_win32=yes
 142     gio_can_sniff=no
 143     MATH_LIB=
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       EXE_MANIFEST_ARCHITECTURE=AMD64
 148       ;;
 149     esac
 150     ;;
 151   *)
 152     os_win32=no
 153     ;;
 154 esac
 155 AC_MSG_RESULT([$os_win32])
 156
 157 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 158 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 159
 160 case $host in
 161   *-*-linux*)
 162     os_linux=yes
 163     ;;
 164 esac
 165
 166 dnl
 167 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 168 dnl We use this for an automated test for C++ header correctness.
 169 dnl
 170 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 171 AC_LANG_PUSH([C++])
 172
 173 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 174 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 175
 176 gtk_save_cxxflags="$CXXFLAGS"
 177 CXXFLAGS="$CXXFLAGS -x objective-c++"
 178 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 179 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 180 CXXFLAGS="$gtk_save_cxxflags"
 181 AC_LANG_POP([C++])
 182
 183 if test "$os_win32" = "yes"; then
 184   if test x$enable_static = xyes -o x$enable_static = x; then
 185     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 186     enable_static=no
 187   fi
 188   if test x$enable_shared = xno; then
 189     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 190   fi
 191   enable_shared=yes
 192 fi
 193
 194 dnl Initialize libtool
 195 LT_PREREQ([2.2.6])
 196 LT_INIT([disable-static win32-dll])
 197 # Create libtool early, because it's used in configure
 198 LT_OUTPUT
 199
 200 # Make sure we use 64-bit versions of various file stuff.
 201 AC_SYS_LARGEFILE
 202
 203 AM_PROG_AS
 204 AC_PATH_PROG(NM, nm, nm)
 205
 206 AC_MSG_CHECKING([for some Win32 platform])
 207 case "$host" in
 208   *-*-mingw*|*-*-cygwin*)
 209     platform_win32=yes
 210     ;;
 211   *)
 212     platform_win32=no
 213     ;;
 214 esac
 215 AC_MSG_RESULT([$platform_win32])
 216 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 217
 218 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 219 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 220 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 221
 222 if test "$os_win32" = "yes"; then
 223   AC_CHECK_TOOL(WINDRES, windres, no)
 224   if test "$WINDRES" = no; then
 225     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 226   fi
 227   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 228 fi
 229 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 230
 231 m4_define([debug_default],
 232           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 233
 234 dnl declare --enable-* args and collect ac_help strings
 235 AC_ARG_ENABLE(debug,
 236               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 237                              [turn on debugging @<:@default=debug_default@:>@]),,
 238               enable_debug=debug_default)
 239 AC_ARG_ENABLE(xkb,
 240               [AC_HELP_STRING([--enable-xkb],
 241                               [support XKB [default=maybe]])],,
 242               [enable_xkb="maybe"])
 243 AC_ARG_ENABLE(xinerama,
 244               [AC_HELP_STRING([--enable-xinerama],
 245                               [support xinerama extension if available [default=yes]])],,
 246               [enable_xinerama="yes"])
 247 AC_ARG_ENABLE(rebuilds,
 248               [AC_HELP_STRING([--disable-rebuilds],
 249                               [disable all source autogeneration rules])],,
 250               [enable_rebuilds=yes])
 251
 252 AC_ARG_WITH(xinput,
 253             [AC_HELP_STRING([--with-xinput=@<:@no/yes@:>@], [support XInput])])
 254
 255 if test "$platform_win32" = yes; then
 256   gdktarget=win32
 257 else
 258   gdktarget=x11
 259 fi
 260
 261 AC_ARG_WITH(gdktarget, [  --with-gdktarget=[[x11/win32/quartz/broadway]] select non-default GDK target],
 262         gdktarget=$with_gdktarget)
 263
 264 AC_SUBST(gdktarget)
 265 case $gdktarget in
 266   x11|win32|quartz|broadway) ;;
 267   *) AC_MSG_ERROR([Invalid target for GDK: use x11, broadway, quartz or win32.]);;
 268 esac
 269
 270 gdktargetlib=libgdk-$gdktarget-$GTK_API_VERSION.la
 271 gtktargetlib=libgtk-$gdktarget-$GTK_API_VERSION.la
 272
 273 AC_SUBST(gdktargetlib)
 274 AC_SUBST(gtktargetlib)
 275
 276 if test "x$enable_debug" = "xyes"; then
 277   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 278   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 279 else
 280   if test "x$enable_debug" = "xno"; then
 281     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 282   else
 283     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 284   fi
 285 fi
 286
 287
 288 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 289                    [Define if debugging is enabled])
 290
 291
 292 # Build time sanity check...
 293 AM_SANITY_CHECK
 294
 295 changequote(,)dnl
 296 if test "x$GCC" = "xyes"; then
 297   case " $CFLAGS " in
 298   *[\ \ ]-Wall[\ \      ]*) ;;
 299   *) CFLAGS="$CFLAGS -Wall" ;;
 300   esac
 301
 302   if test "x$enable_ansi" = "xyes"; then
 303     case " $CFLAGS " in
 304     *[\ \       ]-ansi[\ \      ]*) ;;
 305     *) CFLAGS="$CFLAGS -ansi" ;;
 306     esac
 307
 308     case " $CFLAGS " in
 309     *[\ \       ]-pedantic[\ \  ]*) ;;
 310     *) CFLAGS="$CFLAGS -pedantic" ;;
 311     esac
 312   fi
 313 fi
 314 changequote([,])dnl
 315
 316 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 317
 318 # Ensure MSVC-compatible struct packing convention is used when
 319 # compiling for Win32 with gcc.
 320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 321 # gcc2 uses "-fnative-struct".
 322 if test x"$os_win32" = xyes; then
 323   if test x"$GCC" = xyes; then
 324     msnative_struct=''
 325     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 326     if test -z "$ac_cv_prog_CC"; then
 327       our_gcc="$CC"
 328     else
 329       our_gcc="$ac_cv_prog_CC"
 330     fi
 331     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 332       2.)
 333         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 334           msnative_struct='-fnative-struct'
 335         fi
 336         ;;
 337       *)
 338         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 339           msnative_struct='-mms-bitfields'
 340         fi
 341         ;;
 342     esac
 343     if test x"$msnative_struct" = x ; then
 344       AC_MSG_RESULT([no way])
 345       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 346     else
 347       CFLAGS="$CFLAGS $msnative_struct"
 348       AC_MSG_RESULT([${msnative_struct}])
 349     fi
 350   fi
 351 fi
 352
 353 ## Initial sanity check, done here so that users get told they
 354 ## have the wrong dependencies as early in the process as possible.
 355 ## Later on we actually use the cflags/libs from separate pkg-config
 356 ## calls. Oh, also the later pkg-config calls don't include
 357 ## the version requirements since those make the module lists
 358 ## annoying to construct
 359 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 360   [glib-2.0 >= glib_required_version dnl
 361    atk >= atk_required_version dnl
 362    pango >= pango_required_version dnl
 363    cairo >= cairo_required_version dnl
 364    cairo-gobject >= cairo_required_version dnl
 365    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 366
 367 ## In addition to checking that cairo is present, we also need to
 368 ## check that the correct cairo backend is there. E.g. if the GDK
 369 ## target is win32 we need the cairo-win32 backend and so on.
 370 cairo_backend=cairo-$gdktarget
 371
 372 # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 373 # backend names are identical.
 374 if test "x$cairo_backend" = "xcairo-x11"; then
 375    cairo_backend=cairo-xlib
 376 fi
 377 if test "x$cairo_backend" = "xcairo-broadway"; then
 378    cairo_backend=cairo
 379 fi
 380 PKG_CHECK_MODULES(CAIRO_BACKEND,
 381   [$cairo_backend >= cairo_required_version])
 382
 383 if test "$os_win32" != yes; then
 384     # libtool option to control which symbols are exported
 385     # right now, symbols starting with _ are not exported
 386     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 387 else
 388     # We currently use .def files on Windows (for gdk and gtk)
 389     LIBTOOL_EXPORT_OPTIONS=
 390 fi
 391 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 392
 393 dnl ******************************************************
 394 dnl * See whether to include shared library dependencies *
 395 dnl ******************************************************
 396
 397 AC_ARG_ENABLE(explicit-deps,
 398               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 399                               [use explicit dependencies in .pc files [default=auto]])],,
 400               [enable_explicit_deps=auto])
 401
 402 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 403 case $enable_explicit_deps in
 404   auto)
 405     export SED
 406     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 407     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 408       enable_explicit_deps=yes
 409     else
 410       enable_explicit_deps=no
 411     fi
 412   ;;
 413   yes|no)
 414   ;;
 415   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 416   ;;
 417 esac
 418 AC_MSG_RESULT($enable_explicit_deps)
 419
 420 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 421
 422 # define a MAINT-like variable REBUILD which is set if Perl
 423 # and awk are found, so autogenerated sources can be rebuilt
 424
 425 AC_PATH_PROGS(PERL, perl5 perl)
 426
 427 # We would like indent, but don't require it.
 428 AC_CHECK_PROG(INDENT, indent, indent)
 429
 430 REBUILD=\#
 431 if test "x$enable_rebuilds" = "xyes" && \
 432      test -n "$PERL" && \
 433      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 434   REBUILD=
 435 fi
 436 AC_SUBST(REBUILD)
 437
 438 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 439 AC_CHECK_FUNCS(localtime_r)
 440
 441 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 442 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 443 AC_TRY_LINK([#include <langinfo.h>], [
 444 char c;
 445 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 446 ], gtk_ok=yes, gtk_ok=no)
 447 AC_MSG_RESULT($gtk_ok)
 448 if test "$gtk_ok" = "yes"; then
 449   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 450             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 451 fi
 452
 453 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 454 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 455 AC_TRY_LINK([#include <langinfo.h>], [
 456 char c;
 457 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 458 ], gtk_ok=yes, gtk_ok=no)
 459 AC_MSG_RESULT($gtk_ok)
 460 if test "$gtk_ok" = "yes"; then
 461   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 462             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 463 fi
 464
 465 # _NL_PAPER_HEIGHT is an enum and not a define
 466 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 467 AC_TRY_LINK([#include <langinfo.h>], [
 468 char c;
 469 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 470 ], gtk_ok=yes, gtk_ok=no)
 471 AC_MSG_RESULT($gtk_ok)
 472 if test "$gtk_ok" = "yes"; then
 473   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 474             [Define if _NL_PAPER_HEIGHT is available])
 475 fi
 476
 477 # _NL_PAPER_WIDTH is an enum and not a define
 478 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 479 AC_TRY_LINK([#include <langinfo.h>], [
 480 char c;
 481 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 482 ], gtk_ok=yes, gtk_ok=no)
 483 AC_MSG_RESULT($gtk_ok)
 484 if test "$gtk_ok" = "yes"; then
 485   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 486             [Define if _NL_PAPER_WIDTH is available])
 487 fi
 488
 489 # i18n stuff
 490 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 491 AM_GLIB_GNU_GETTEXT
 492 LIBS="$LIBS $INTLLIBS"
 493 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 494         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 495       esac])
 496
 497 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 498 dnl po-properties/POTFILES during configure; see GNOME #573515.
 499 dnl
 500 dnl Generate list of files to be processed by xgettext which will
 501 dnl be included in po-properties/Makefile.
 502 test -d po-properties || mkdir po-properties
 503 if test "x$srcdir" != "x."; then
 504   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 505     popropsrcprefix="$srcdir/"
 506   else
 507     popropsrcprefix="../$srcdir/"
 508   fi
 509 else
 510   popropsrcprefix="../"
 511 fi
 512 rm -f po-properties/POTFILES
 513 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 514 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 515 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 516
 517 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 518
 519 dnl The DU4 header files don't provide library prototypes unless
 520 dnl -std1 is given to the native cc.
 521 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 522
 523 gtk_save_LIBS=$LIBS
 524 LIBS="$LIBS -lm"
 525 AC_TRY_RUN([#include <math.h>
 526              int main (void) { return (log(1) != log(1.)); }],
 527      AC_MSG_RESULT(none needed),
 528      gtk_save_CFLAGS="$CFLAGS"
 529      CFLAGS="$CFLAGS -std1"
 530      AC_TRY_RUN([#include <math.h>
 531                  int main (void) { return (log(1) != log(1.)); }],
 532          AC_MSG_RESULT(-std1),
 533          AC_MSG_RESULT()
 534          CFLAGS="$gtk_save_CFLAGS"
 535          AC_MSG_WARN(
 536                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 537          true
 538      ),
 539      AC_MSG_RESULT(none needed)
 540 )
 541 LIBS=$gtk_save_LIBS
 542
 543 AC_MSG_CHECKING(for the BeOS)
 544 case $host in
 545   *-*-beos*)
 546     AC_MSG_RESULT(yes)
 547     MATH_LIB=
 548   ;;
 549   *)
 550     AC_MSG_RESULT(no)
 551   ;;
 552 esac
 553
 554 AC_SUBST(MATH_LIB)
 555 #
 556 # see bug 162979
 557 #
 558 AC_MSG_CHECKING(for HP-UX)
 559 case $host_os in
 560   hpux9* | hpux10* | hpux11*)
 561     AC_MSG_RESULT(yes)
 562     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 563   ;;
 564   *)
 565     AC_MSG_RESULT(no)
 566   ;;
 567 esac
 568
 569 dnl NeXTStep cc seems to need this
 570 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 571 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 572   AC_MSG_RESULT(none needed),
 573   gtk_save_CFLAGS="$CFLAGS"
 574   CFLAGS="$CFLAGS -posix"
 575   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 576     AC_MSG_RESULT(-posix),
 577     AC_MSG_RESULT()
 578     CFLAGS="$gtk_save_CFLAGS"
 579     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 580
 581 #
 582 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 583 #
 584
 585 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 586
 587 AM_PATH_GLIB_2_0(glib_required_version, :,
 588   AC_MSG_ERROR([
 589 *** GLIB glib_required_version or better is required. The latest version of
 590 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 591   gobject gmodule-no-export gthread)
 592
 593 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 594 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 595 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 596 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 597   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 598 fi
 599
 600 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 601
 602
 603 dnl
 604 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 605 dnl
 606 gtk_save_LIBS=$LIBS
 607 LIBS="$LIBS $GLIB_LIBS"
 608 AC_CHECK_FUNCS(bind_textdomain_codeset)
 609 LIBS=$gtk_save_LIBS
 610
 611 AC_CHECK_HEADERS(pwd.h,
 612                  AC_DEFINE(HAVE_PWD_H, 1,
 613                            [Define to 1 if pwd.h is available]))
 614 AC_CHECK_HEADERS(sys/time.h,
 615                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 616                            [Define to 1 if time.h is available]))
 617 AC_CHECK_HEADERS(unistd.h,
 618                  AC_DEFINE(HAVE_UNISTD_H, 1,
 619                            [Define to 1 if unistd.h is available]))
 620 AC_CHECK_HEADERS(ftw.h,
 621                  AC_DEFINE(HAVE_FTW_H, 1,
 622                            [Define to 1 if ftw.h is available]))
 623
 624 AC_MSG_CHECKING([for GNU ftw extensions])
 625 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 626 #define _GNU_SOURCE
 627 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 628 if test $gtk_ok = yes; then
 629     AC_MSG_RESULT([yes])
 630     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 631 else
 632     AC_MSG_RESULT([no])
 633 fi
 634
 635 saved_cflags="$CFLAGS"
 636 saved_ldflags="$LDFLAGS"
 637
 638
 639 # Checks for header files.
 640 AC_HEADER_STDC
 641
 642 # Checks for typedefs, structures, and compiler characteristics.
 643 AC_C_CONST
 644
 645 # Checks for library functions.
 646 AC_TYPE_SIGNAL
 647 AC_FUNC_MMAP
 648
 649 AC_CHECK_FUNCS(mallinfo)
 650 AC_CHECK_FUNCS(getresuid)
 651 AC_TYPE_UID_T
 652
 653 # Check if <sys/select.h> needs to be included for fd_set
 654 AC_MSG_CHECKING([for fd_set])
 655 AC_TRY_COMPILE([#include <sys/types.h>],
 656         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 657 if test $gtk_ok = yes; then
 658     AC_MSG_RESULT([yes, found in sys/types.h])
 659 else
 660     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 661     if test $gtk_ok = yes; then
 662         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 663                   [Define to 1 if sys/select.h is available])
 664         AC_MSG_RESULT([yes, found in sys/select.h])
 665     else
 666         AC_DEFINE(NO_FD_SET, 1,
 667                   [Define to 1 if fd_set is not available])
 668         AC_MSG_RESULT(no)
 669     fi
 670 fi
 671
 672 # `widechar' tests for gdki18n.h
 673 AC_MSG_CHECKING(for wchar.h)
 674 AC_TRY_CPP([#include <wchar.h>], gdk_wchar_h=yes, gdk_wchar_h=no)
 675 if test $gdk_wchar_h = yes; then
 676    AC_DEFINE(HAVE_WCHAR_H, 1, [Have wchar.h include file])
 677 fi
 678 AC_MSG_RESULT($gdk_wchar_h)
 679
 680 # Check for wctype.h (for iswalnum)
 681 AC_MSG_CHECKING(for wctype.h)
 682 AC_TRY_CPP([#include <wctype.h>], gdk_wctype_h=yes, gdk_wctype_h=no)
 683 if test $gdk_wctype_h = yes; then
 684    AC_DEFINE(HAVE_WCTYPE_H, 1, [Have wctype.h include file])
 685 fi
 686 AC_MSG_RESULT($gdk_wctype_h)
 687
 688 # in Solaris 2.5, `iswalnum' is in -lw
 689 GDK_WLIBS=
 690 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum,GDK_WLIBS=-lw)])
 691
 692 oLIBS="$LIBS"
 693 LIBS="$LIBS $GDK_WLIBS"
 694 # The following is necessary for Linux libc-5.4.38
 695 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 696 AC_TRY_LINK([#include <stdlib.h>],[
 697 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 698 #  ifdef HAVE_WCTYPE_H
 699 #    include <wctype.h>
 700 #  else
 701 #    ifdef HAVE_WCHAR_H
 702 #      include <wchar.h>
 703 #    endif
 704 #  endif
 705 #else
 706 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 707 #endif
 708 iswalnum((wchar_t) 0);
 709 ], gdk_working_wctype=yes, gdk_working_wctype=no)
 710 LIBS="$oLIBS"
 711
 712 if test $gdk_working_wctype = no; then
 713    AC_DEFINE(HAVE_BROKEN_WCTYPE, 1, [Is the wctype implementation broken])
 714    GDK_WLIBS=
 715 fi
 716 AC_MSG_RESULT($gdk_working_wctype)
 717 AC_SUBST(GDK_WLIBS)
 718
 719 # Check for uxtheme.h (for MS-Windows Engine)
 720 AC_MSG_CHECKING(for uxtheme.h)
 721 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 722 if test $gtk_uxtheme_h = yes; then
 723    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 724 fi
 725 AC_MSG_RESULT($gtk_uxtheme_h)
 726
 727 # Checks for gdkspawn
 728 AC_CHECK_HEADERS(crt_externs.h)
 729 AC_CHECK_FUNCS(_NSGetEnviron)
 730
 731 AC_MSG_CHECKING(whether to build dynamic modules)
 732
 733 AC_ARG_ENABLE(modules,
 734               [AC_HELP_STRING([--disable-modules],
 735                               [disable dynamic module loading])])
 736
 737 dynworks=false
 738 deps=
 739 if test x$enable_modules = xno; then
 740     AC_MSG_RESULT(no)
 741 else
 742     AC_MSG_RESULT(yes)
 743     AC_MSG_CHECKING(whether dynamic modules work)
 744     ## for loop is to strip newline
 745     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 746     for I in $tmp; do
 747         dynworks=$I
 748     done
 749
 750     dnl Now we check to see if our libtool supports shared lib deps
 751     dnl (in a rather ugly way even)
 752     if $dynworks; then
 753         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 754         module_deplibs_check=`$module_libtool_config | \
 755             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 756             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 757         if test "x$module_deplibs_check" = "xnone" || \
 758            test "x$module_deplibs_check" = "xunknown" || \
 759            test "x$module_deplibs_check" = "x"; then
 760             dynworks=false
 761         fi
 762     fi
 763
 764     if $dynworks; then
 765         AC_DEFINE(USE_GMODULE, 1,
 766                   [Define to 1 if gmodule works and should be used])
 767         AC_MSG_RESULT(yes)
 768     else
 769         AC_MSG_RESULT(no)
 770     fi
 771 fi
 772
 773 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 774
 775 #
 776 # Allow building some or all immodules included
 777 #
 778 AC_MSG_CHECKING(immodules to build)
 779
 780 dnl due to an autoconf bug, commas in the first arg to
 781 dnl AC_HELP_STRING cause problems.
 782 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
 783 dnl                [build the specified input method modules into gtk])
 784 AC_ARG_WITH(included_immodules,
 785 [  --with-included-immodules=MODULE1,MODULE2,...
 786                           build the specified input methods into gtk])
 787
 788 if $dynworks; then
 789    :
 790 else
 791    ## if the option was specified, leave it; otherwise disable included immodules
 792    if test x$with_included_immodules = xno; then
 793            with_included_immodules=yes
 794    fi
 795 fi
 796
 797 all_immodules="am-et,cedilla,cyrillic-translit"
 798 if test "$gdktarget" = "win32"; then
 799    all_immodules="${all_immodules},ime"
 800 fi
 801 all_immodules="${all_immodules},inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr"
 802 if test "$gdktarget" = "x11"; then
 803    all_immodules="${all_immodules},xim"
 804 fi
 805
 806 included_immodules=""
 807 # If the switch specified without listing any specific ones, include all
 808 if test "x$with_included_immodules" = xyes ; then
 809   included_immodules="$all_immodules"
 810 else
 811   included_immodules="$with_included_immodules"
 812 fi
 813
 814 AC_MSG_RESULT($included_immodules)
 815 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 816
 817 INCLUDED_IMMODULE_OBJ=
 818 INCLUDED_IMMODULE_DEFINE=
 819
 820 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 821 for immodule in $included_immodules; do
 822  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 823  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 824    :
 825  else
 826    AC_MSG_ERROR([the specified input method $immodule does not exist])
 827  fi
 828
 829  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 830  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 831  eval INCLUDE_$immodule_underscores=yes
 832 done
 833 IFS="$gtk_save_ifs"
 834 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 835 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 836
 837 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 838 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 839 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 840 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 841 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 842 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 843 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 844 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 845 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 846 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 847 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 848 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 849
 850 AC_HEADER_SYS_WAIT
 851
 852 AC_TYPE_SIGNAL
 853
 854 # Checks to see whether we should include mediaLib
 855 # support.
 856 #
 857 AC_CHECK_HEADER(sys/systeminfo.h,
 858                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 859                           [Define to 1 if sys/systeminfo.h is available]))
 860 AC_CHECK_HEADER(sys/sysinfo.h,
 861                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 862                           [Define to 1 if sys/sysinfo.h is available]))
 863
 864 AC_MSG_CHECKING(for mediaLib 2.3)
 865 use_mlib25=no
 866 # Check for a mediaLib 2.3 function since that is what the GTK+ mediaLib
 867 # patch requires.
 868 AC_CHECK_LIB(mlib, mlib_ImageSetStruct, use_mlib=yes, use_mlib=no)
 869 if test $use_mlib = yes; then
 870     AC_DEFINE(USE_MEDIALIB, 1,
 871               [Define to 1 if medialib is available and should be used])
 872     MEDIA_LIB=-lmlib
 873
 874     AC_MSG_CHECKING(for mediaLib 2.5)
 875     # Check for a mediaLib 2.5 function since that is what is needed for
 876     # gdk_rgb_convert integration.
 877     AC_CHECK_LIB(mlib, mlib_VideoColorRGBint_to_BGRAint, use_mlib25=yes, use_mlib25=no)
 878     if test $use_mlib25 = yes; then
 879         AC_DEFINE(USE_MEDIALIB25, 1,
 880                   [Define to 1 if medialib 2.5 is available])
 881     fi
 882 fi
 883 AM_CONDITIONAL(USE_MEDIALIB, test $use_mlib = yes)
 884 AM_CONDITIONAL(USE_MEDIALIB25, test $use_mlib25 = yes)
 885
 886 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 887
 888 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 889
 890 if test $cross_compiling = yes; then
 891   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 892   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 893     REBUILD_PNGS=#
 894   fi
 895 fi
 896
 897 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 898
 899 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 900    test "x$REBUILD_PNGS" = "x#" ; then
 901      AC_MSG_ERROR([
 902 *** gtkbuiltincache.h is not in the tree, and cannot be built
 903 *** because you don't have libpng, or (when cross-compiling) you
 904 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 905 fi
 906
 907 ########################################
 908 # Windowing system checks
 909 ########################################
 910
 911 GDK_EXTRA_LIBS="$GDK_WLIBS"
 912 GDK_EXTRA_CFLAGS=
 913
 914 # GTK+ uses some X calls, so needs to link against X directly
 915 GTK_DEP_PACKAGES_FOR_X=
 916 GTK_DEP_LIBS_FOR_X=
 917
 918 if test "x$gdktarget" = "xx11"; then
 919   X_PACKAGES=fontconfig
 920
 921   #
 922   # We use fontconfig very peripherally when decoding the default
 923   # settings.
 924   #
 925   if $PKG_CONFIG --exists fontconfig; then : ; else
 926     AC_MSG_ERROR([
 927 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 928   fi
 929
 930   #
 931   # Check for basic X packages; we use pkg-config if available
 932   #
 933   if $PKG_CONFIG --exists x11 xext; then
 934     have_base_x_pc=true
 935     X_PACKAGES="$X_PACKAGES x11 xext"
 936     x_libs="`$PKG_CONFIG --libs x11 xext`"
 937     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 938
 939     # Strip out any .la files that pkg-config might give us (this happens
 940     # with -uninstalled.pc files)
 941     x_libs_for_checks=
 942     for I in $x_libs ; do
 943       case $I in
 944         *.la) ;;
 945         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 946       esac
 947     done
 948
 949     GTK_PACKAGES_FOR_X="x11"
 950   else
 951     have_base_x_pc=false
 952     AC_PATH_XTRA
 953     if test x$no_x = xyes ; then
 954       AC_MSG_ERROR([X development libraries not found])
 955     fi
 956
 957     x_cflags="$X_CFLAGS"
 958     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 959
 960     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 961   fi
 962
 963   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 964   x_extra_libs=
 965
 966   gtk_save_cppflags="$CPPFLAGS"
 967   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 968
 969   gtk_save_LIBS=$LIBS
 970   LIBS="$x_libs_for_checks $LIBS"
 971
 972   # Sanity check for the X11 and Xext libraries. While everything we need from
 973   # Xext is optional, the chances a system has *none* of these things is so
 974   # small that we just unconditionally require it.
 975   AC_CHECK_FUNC(XOpenDisplay, :,
 976                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 977   AC_CHECK_FUNC(XextFindDisplay, :,
 978                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 979
 980   # Check for xReply
 981
 982   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 983   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
 984       [xReply *rep;],
 985       [AC_MSG_RESULT([no])],
 986       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
 987 #include <X11/Xlibint.h>],
 988            [xReply *rep;],
 989            [AC_MSG_RESULT([yes])
 990             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
 991                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
 992            [AC_MSG_RESULT([unknown])
 993             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 994
 995   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 996
 997   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 998
 999   # Generic X11R6 check needed for XIM support; we could
1000   # probably use this to replace the above, but we'll
1001   # leave the separate checks for XConvertCase and XInternAtoms
1002   # for clarity
1003
1004   have_x11r6=false
1005   AC_CHECK_FUNC(XAddConnectionWatch,
1006       have_x11r6=true)
1007
1008   if $have_x11r6; then
1009     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1010   fi
1011   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1012
1013   # Check for XKB support.
1014
1015   if test "x$enable_xkb" = "xyes"; then
1016         AC_MSG_WARN(XKB support explicitly enabled)
1017         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
1018   elif test "x$enable_xkb" = "xmaybe"; then
1019         AC_CHECK_FUNC(XkbQueryExtension,
1020                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1021   else
1022         AC_MSG_WARN(XKB support explicitly disabled)
1023   fi
1024
1025   # Check for shaped window extension
1026
1027   AC_CHECK_FUNC(XShapeCombineMask, :,
1028      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1029
1030   # X SYNC check
1031   gtk_save_CFLAGS="$CFLAGS"
1032   CFLAGS="$CFLAGS $x_cflags"
1033
1034   AC_CHECK_FUNC(XSyncQueryExtension,
1035       [AC_CHECK_HEADER(X11/extensions/sync.h,
1036           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1037           :, [#include <X11/Xlib.h>])])
1038
1039   CFLAGS="$gtk_save_CFLAGS"
1040
1041   if test "x$enable_xinerama" = "xyes"; then
1042     # Check for Xinerama extension (Solaris impl or Xfree impl)
1043     gtk_save_cppflags="$CPPFLAGS"
1044     CPPFLAGS="$CPPFLAGS $x_cflags"
1045
1046     # Check for XFree
1047     AC_MSG_CHECKING(for Xinerama support on XFree86)
1048
1049     have_xfree_xinerama=false
1050     if $PKG_CONFIG --exists xinerama ; then
1051        have_xfree_xinerama=true
1052        X_PACKAGES="$X_PACKAGES xinerama"
1053     else
1054        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1055            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1056            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1057            have_xfree_xinerama=true], :,
1058            [#include <X11/Xlib.h>])])
1059     fi
1060
1061     if $have_xfree_xinerama ; then
1062       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1063                 [Define to 1 if XFree Xinerama is available])
1064       AC_DEFINE(HAVE_XINERAMA, 1,
1065                 [Define to 1 is Xinerama is available])
1066       AC_MSG_RESULT(yes)
1067     else
1068       AC_MSG_RESULT(no)
1069
1070       case "$host" in
1071         *-*-solaris*)
1072             # Check for solaris
1073             AC_MSG_CHECKING(for Xinerama support on Solaris)
1074
1075             have_solaris_xinerama=false
1076             AC_CHECK_FUNC(XineramaGetInfo,
1077                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1078                     [have_solaris_xinerama=true], :,
1079                     [#include <X11/Xlib.h>])])
1080
1081             if $have_solaris_xinerama ; then
1082               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1083                         [Define to 1 if solaris xinerama is available])
1084               AC_DEFINE(HAVE_XINERAMA, 1,
1085                         [Define to 1 if xinerama is available])
1086               AC_MSG_RESULT(yes)
1087             else
1088               AC_MSG_RESULT(no)
1089             fi
1090             ;;
1091         *)
1092             ;;
1093       esac
1094     fi
1095   fi
1096
1097   # set up things for XInput
1098   if test "x$with_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1099     have_xinput=yes
1100
1101     AC_DEFINE(XINPUT_XFREE, 1,
1102               [Define to 1 if XFree XInput should be used])
1103
1104     X_PACKAGES="$X_PACKAGES xi"
1105
1106     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1107                     have_xinput2=yes; AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1108   else
1109     AC_DEFINE(XINPUT_NONE, 1,
1110               [Define to 1 if no XInput should be used])
1111   fi
1112
1113   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1114   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1115
1116   # Check for the RANDR extension
1117   if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1118      AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1119
1120      X_PACKAGES="$X_PACKAGES xrandr"
1121   fi
1122
1123   # Checks for Xcursor library
1124
1125   if $PKG_CONFIG --exists xcursor ; then
1126     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1127
1128     X_PACKAGES="$X_PACKAGES xcursor"
1129   fi
1130
1131   # Checks for XFixes extension
1132
1133   if $PKG_CONFIG --exists xfixes ; then
1134     AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1135
1136     X_PACKAGES="$X_PACKAGES xfixes"
1137     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1138   fi
1139
1140   # Checks for Xcomposite extension
1141
1142   if $PKG_CONFIG --exists xcomposite ; then
1143     AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1144
1145     X_PACKAGES="$X_PACKAGES xcomposite"
1146     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1147   fi
1148
1149   # Checks for Xdamage extension
1150
1151   if $PKG_CONFIG --exists xdamage ; then
1152     AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1153
1154     X_PACKAGES="$X_PACKAGES xdamage"
1155     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1156   fi
1157
1158   if $have_base_x_pc ; then
1159     GDK_EXTRA_LIBS="$x_extra_libs"
1160   else
1161     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1162   fi
1163
1164   CPPFLAGS="$gtk_save_cppflags"
1165   LIBS="$gtk_save_libs"
1166
1167   AM_CONDITIONAL(USE_X11, true)
1168 else
1169   XPACKAGES=
1170
1171   AM_CONDITIONAL(XINPUT_XFREE, false)
1172   AM_CONDITIONAL(XINPUT_2, false)
1173   AM_CONDITIONAL(USE_X11, false)
1174   AM_CONDITIONAL(HAVE_X11R6, false)
1175 fi
1176
1177 if test "x$gdktarget" = "xwin32"; then
1178   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
1179   AM_CONDITIONAL(USE_WIN32, true)
1180 else
1181   AM_CONDITIONAL(USE_WIN32, false)
1182 fi
1183
1184 if test "x$gdktarget" = "xquartz"; then
1185   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
1186   AM_CONDITIONAL(USE_QUARTZ, true)
1187 else
1188   AM_CONDITIONAL(USE_QUARTZ, false)
1189 fi
1190
1191 if test "x$gdktarget" = "xbroadway" ; then
1192   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
1193 fi
1194
1195 # Check for Pango flags
1196
1197 if test "x$gdktarget" = "xwin32"; then
1198         PANGO_PACKAGES="pangowin32 pangocairo"
1199 else
1200         PANGO_PACKAGES="pango pangocairo"
1201 fi
1202
1203 AC_MSG_CHECKING(Pango flags)
1204 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1205         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1206         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1207
1208         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1209 else
1210         AC_MSG_ERROR([
1211 *** Pango not found. Pango built with Cairo support is required
1212 *** to build GTK+. See http://www.pango.org for Pango information.
1213 ])
1214 fi
1215
1216 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1217
1218 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1219         :
1220 else
1221         gtk_save_LIBS="$LIBS"
1222         LIBS="$PANGO_LIBS $LIBS"
1223         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1224 *** Can't link to Pango. Pango is required to build
1225 *** GTK+. For more information see http://www.pango.org]))
1226         LIBS="$gtk_save_LIBS"
1227 fi
1228
1229 CFLAGS="$saved_cflags"
1230 LDFLAGS="$saved_ldflags"
1231
1232 # Pull in gio-unix for GDesktopAppInfo usage, see at least gdkapplaunchcontext-x11.c
1233 if test "x$gdktarget" = "xx11" || test "x$gdktarget" = "xbroadway" ; then
1234   GDK_PACKAGES="$PANGO_PACKAGES gio-unix-2.0 $X_PACKAGES gdk-pixbuf-2.0 $cairo_backend cairo-gobject"
1235 else
1236   GDK_PACKAGES="$PANGO_PACKAGES gio-2.0 gdk-pixbuf-2.0 $cairo_backend cairo-gobject"
1237 fi
1238
1239 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1240 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1241 #
1242 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1243 # into the pkg-config files
1244 #
1245 if test $enable_explicit_deps != yes ; then
1246   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0"
1247   GDK_EXTRA_LIBS=
1248 fi
1249
1250 AC_SUBST(GDK_PACKAGES)
1251 AC_SUBST(GDK_EXTRA_LIBS)
1252 AC_SUBST(GDK_EXTRA_CFLAGS)
1253 AC_SUBST(GDK_DEP_LIBS)
1254 AC_SUBST(GDK_DEP_CFLAGS)
1255
1256
1257 ########################################
1258 # Check for Accessibility Toolkit flags
1259 ########################################
1260
1261 ATK_PACKAGES=atk
1262 AC_MSG_CHECKING(ATK flags)
1263 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1264         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1265         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1266
1267         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1268 else
1269         AC_MSG_ERROR([
1270 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1271 *** to build GTK+.
1272 ])
1273 fi
1274
1275 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1276         :
1277 else
1278         gtk_save_LIBS="$LIBS"
1279         LIBS="$ATK_LIBS $LIBS"
1280         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1281                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1282                 *** to build GTK+]))
1283         LIBS="$gtk_save_LIBS"
1284 fi
1285
1286 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1287 if test "x$gdktarget" = "xx11"; then
1288   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1289 fi
1290 GTK_EXTRA_LIBS=
1291 GTK_EXTRA_CFLAGS=
1292 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1293 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1294
1295 if test x"$os_win32" = xyes; then
1296   GTK_EXTRA_CFLAGS="$msnative_struct"
1297 fi
1298
1299 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1300 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1301 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1302 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1303
1304 AC_SUBST(GTK_PACKAGES)
1305 AC_SUBST(GTK_EXTRA_LIBS)
1306 AC_SUBST(GTK_EXTRA_CFLAGS)
1307 AC_SUBST(GTK_DEP_LIBS)
1308 AC_SUBST(GTK_DEP_CFLAGS)
1309
1310 AC_SUBST(GLIB_PREFIX)
1311 AC_SUBST(ATK_PREFIX)
1312 AC_SUBST(PANGO_PREFIX)
1313 AC_SUBST(CAIRO_PREFIX)
1314
1315 AC_SUBST(GTK_DEBUG_FLAGS)
1316 AC_SUBST(GTK_XIM_FLAGS)
1317
1318 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1319 AC_SUBST(GDK_PIXBUF_LIBS)
1320
1321 ########################
1322 # Checks needed for gail
1323 ########################
1324
1325 old_LIBS="$LIBS"
1326 dnl Checks for inet libraries:
1327 AC_SEARCH_LIBS(gethostent, nsl)
1328 AC_SEARCH_LIBS(setsockopt, socket)
1329 AC_SEARCH_LIBS(connect, inet)
1330
1331 dnl check for the sockaddr_un.sun_len member
1332 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1333                 [struct_sockaddr_un_sun_len=true],
1334                 [struct_sockaddr_un_suin_len=false],
1335                 [#include <sys/types.h>
1336                  #include <sys/un.h>]
1337                 )
1338 case $struct_sockaddr_un_sun_len in
1339         true)
1340                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1341                                    [Have the sockaddr_un.sun_len member])
1342                 ;;
1343         *)
1344                 ;;
1345 esac
1346
1347 GAIL_INET_LIBS="$LIBS"
1348 AC_SUBST([GAIL_INET_LIBS])
1349
1350 LIBS="$old_LIBS"
1351
1352 ################################################################
1353 # Printing system checks
1354 ################################################################
1355
1356 AC_ARG_ENABLE(cups,
1357               [AC_HELP_STRING([--disable-cups]
1358                               [disable cups print backend])],,
1359               [enable_cups=auto])
1360
1361 if test "x$enable_cups" = "xno"; then
1362   AM_CONDITIONAL(HAVE_CUPS, false)
1363 else
1364   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1365   if test "x$CUPS_CONFIG" = "xno"; then
1366     if test "x$enable_cups" = "xauto"; then
1367       AM_CONDITIONAL(HAVE_CUPS, false)
1368     else
1369       AC_MSG_ERROR([
1370 *** cups not found.
1371 ])
1372     fi
1373   else
1374     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1375     CUPS_LIBS=`$CUPS_CONFIG --libs`
1376
1377     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1378     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1379     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1380
1381     if test $CUPS_API_MAJOR -gt 1 -o \
1382             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1383       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1384                 [Define to 1 if CUPS 1.2 API is available])
1385     fi
1386
1387     AC_SUBST(CUPS_API_MAJOR)
1388     AC_SUBST(CUPS_API_MINOR)
1389     AC_SUBST(CUPS_CFLAGS)
1390     AC_SUBST(CUPS_LIBS)
1391
1392     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1393
1394     AM_CONDITIONAL(HAVE_CUPS, true)
1395
1396     gtk_save_cflags="$CFLAGS"
1397     CFLAGS="$CUPS_CFLAGS"
1398     AC_TRY_COMPILE([#include <cups/http.h>],
1399                    [http_t http; char *s = http.authstring;],
1400                    [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1401                               [Define if cups http_t authstring field is accessible])],)
1402     CFLAGS="$gtk_save_cflags"
1403
1404     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1405
1406     gtk_save_libs="$LIBS"
1407     LIBS="$CUPS_LIBS"
1408     AC_CHECK_FUNCS(httpGetAuthString)
1409     LIBS="$gtk_save_libs"
1410   fi
1411 fi
1412
1413 # Checks to see if we should compile with PAPI backend for GTK+
1414 #
1415
1416 AC_ARG_ENABLE(papi,
1417               [AC_HELP_STRING([--disable-papi]
1418                               [disable papi print backend])],,
1419              [enable_papi=auto])
1420
1421 if test "x$enable_papi" = "xno"; then
1422   AM_CONDITIONAL(HAVE_PAPI, false)
1423 else
1424   AC_MSG_CHECKING(libpapi)
1425   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1426   if test $have_papi = yes; then
1427     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1428   fi
1429   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1430   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1431     AC_MSG_ERROR([
1432 *** papi not found.
1433 ])
1434   fi
1435 fi
1436
1437 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1438
1439 gtk_save_cppflags="$CPPFLAGS"
1440 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1441
1442 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1443 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1444 *** backend enabled.]))
1445
1446 if test "$os_win32" != "yes"; then
1447   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1448 *** Can't find cairo-ps.h. You must build Cairo with the
1449 *** postscript backend enabled.]))
1450
1451   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1452 *** Can't find cairo-svg.h. You must build Cairo with the
1453 *** svg backend enabled.]))
1454 fi
1455
1456 CPPFLAGS="$gtk_save_cppflags"
1457
1458
1459 AC_ARG_ENABLE(test-print-backend,
1460               [AC_HELP_STRING([--enable-test-print-backend],
1461                               [build test print backend])],,
1462               [enable_test_print_backend=no])
1463 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1464
1465
1466 ################################################################
1467 # Strip -export-dynamic from the link lines of various libraries
1468 ################################################################
1469
1470 #
1471 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1472 #  but this flag is only meaningful for executables. For libraries
1473 #  the effect is undefined; what it causes on Linux is that the
1474 #  export list from -export-symbols-regex is ignored and everything
1475 #  is exported
1476 #
1477 # We are using gmodule-no-export now, but I'm leaving the stripping
1478 # code in place for now, since pango and atk still require gmodule.
1479 export SED
1480 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1481 if test -n "$export_dynamic"; then
1482   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1483   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1484 fi
1485
1486 #############
1487 # GSettings #
1488 #############
1489
1490 GLIB_GSETTINGS
1491
1492 ##################################################
1493 # GObject introspection
1494 ##################################################
1495
1496 GOBJECT_INTROSPECTION_CHECK([0.9.3])
1497
1498 ##################################################
1499 # Checks for gtk-doc and docbook-tools
1500 ##################################################
1501
1502 GTK_DOC_CHECK([1.11])
1503
1504 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1505 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1506
1507 AC_ARG_ENABLE(man,
1508               [AC_HELP_STRING([--enable-man],
1509                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1510               enable_man=no)
1511
1512 if test "${enable_man}" != no; then
1513   dnl
1514   dnl Check for xsltproc
1515   dnl
1516   AC_PATH_PROG([XSLTPROC], [xsltproc])
1517   if test -z "$XSLTPROC"; then
1518     enable_man=no
1519   fi
1520
1521   dnl check for DocBook DTD and stylesheets in the local catalog.
1522   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1523      [DocBook XML DTD V4.1.2],,enable_man=no)
1524   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1525      [DocBook XSL Stylesheets],,enable_man=no)
1526 fi
1527
1528 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1529
1530
1531 ##################################################
1532 # Output commands
1533 ##################################################
1534
1535 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1536         outfile=gdkconfig.h-tmp
1537         cat > $outfile <<\_______EOF
1538 /* gdkconfig.h
1539  *
1540  * This is a generated file.  Please modify `configure.ac'
1541  */
1542
1543 #ifndef GDKCONFIG_H
1544 #define GDKCONFIG_H
1545
1546 #ifdef __cplusplus
1547 extern "C" {
1548 #endif /* __cplusplus */
1549
1550 #ifndef GSEAL
1551 /* introduce GSEAL() here for all of Gdk and Gtk+ without the need to modify GLib */
1552 #  ifdef GSEAL_ENABLE
1553 #    define GSEAL(ident)      _g_sealed__ ## ident
1554 #  else
1555 #    define GSEAL(ident)      ident
1556 #  endif
1557 #endif /* !GSEAL */
1558
1559 _______EOF
1560
1561         cat >>$outfile <<_______EOF
1562 $gdk_windowing
1563 $gdk_wc
1564 _______EOF
1565
1566         cat >>$outfile <<_______EOF
1567
1568 #ifdef __cplusplus
1569 }
1570 #endif /* __cplusplus */
1571
1572 #endif /* GDKCONFIG_H */
1573 _______EOF
1574
1575
1576         if cmp -s $outfile gdk/gdkconfig.h; then
1577           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1578           rm -f $outfile
1579         else
1580           mv $outfile gdk/gdkconfig.h
1581         fi
1582 ],[
1583 if test "x$gdktarget" = "xx11" ; then
1584   gdk_windowing='
1585 #define GDK_WINDOWING_X11'
1586 elif test "x$gdktarget" = "xwin32" ; then
1587   gdk_windowing='
1588 #define GDK_NATIVE_WINDOW_POINTER
1589
1590 #define GDK_WINDOWING_WIN32'
1591 elif test "x$gdktarget" = "xquartz" ; then
1592   gdk_windowing='
1593 #define GDK_WINDOWING_QUARTZ'
1594 elif test "x$gdktarget" = "xbroadway" ; then
1595   gdk_windowing='
1596 #define GDK_WINDOWING_BROADWAY'
1597 fi
1598
1599 if test x$gdk_wchar_h = xyes; then
1600   gdk_wc='
1601 #define GDK_HAVE_WCHAR_H 1'
1602 fi
1603 if test x$gdk_wctype_h = xyes; then
1604   gdk_wc="\$gdk_wc
1605 #define GDK_HAVE_WCTYPE_H 1"
1606 fi
1607 if test x$gdk_working_wctype = xno; then
1608   gdk_wc="\$gdk_wc
1609 #define GDK_HAVE_BROKEN_WCTYPE 1"
1610 fi
1611 ])
1612
1613 dnl
1614 dnl Check for -Bsymbolic-functions linker flag used to avoid
1615 dnl intra-library PLT jumps, if available.
1616 dnl
1617 AC_ARG_ENABLE(Bsymbolic,
1618               [AC_HELP_STRING([--disable-Bsymbolic],
1619                               [avoid linking with -Bsymbolic])],,
1620               [SAVED_LDFLAGS="${LDFLAGS}"
1621                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1622                LDFLAGS=-Wl,-Bsymbolic-functions
1623                AC_TRY_LINK([], [int main (void) { return 0; }],
1624                            AC_MSG_RESULT(yes)
1625                            enable_Bsymbolic=yes,
1626                            AC_MSG_RESULT(no)
1627                            enable_Bsymbolic=no)
1628                LDFLAGS="${SAVED_LDFLAGS}"])
1629
1630 if test "x${enable_Bsymbolic}" == "xyes"; then
1631   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1632 fi
1633 AC_SUBST(GTK_LINK_FLAGS)
1634
1635 AC_CONFIG_FILES([
1636 config.h.win32
1637 gtk-zip.sh
1638 Makefile
1639 gdk-3.0.pc
1640 gtk+-3.0.pc
1641 gtk+-unix-print-3.0.pc
1642 gail-3.0.pc
1643 gdk-3.0-uninstalled.pc
1644 gtk+-3.0-uninstalled.pc
1645 gail-3.0-uninstalled.pc
1646 m4macros/Makefile
1647 po/Makefile.in
1648 po-properties/Makefile.in
1649 demos/Makefile
1650 demos/gtk-demo/Makefile
1651 demos/gtk-demo/geninclude.pl
1652 examples/Makefile
1653 tests/Makefile
1654 docs/Makefile
1655 docs/reference/Makefile
1656 docs/reference/gdk/Makefile
1657 docs/reference/gdk/version.xml
1658 docs/reference/gtk/Makefile
1659 docs/reference/gtk/version.xml
1660 docs/reference/libgail-util/Makefile
1661 docs/tools/Makefile
1662 build/Makefile
1663 build/win32/Makefile
1664 build/win32/vs9/Makefile
1665 gdk/Makefile
1666 gdk/broadway/Makefile
1667 gdk/x11/Makefile
1668 gdk/win32/Makefile
1669 gdk/win32/rc/Makefile
1670 gdk/win32/rc/gdk.rc
1671 gdk/quartz/Makefile
1672 gdk/tests/Makefile
1673 gtk/Makefile
1674 gtk/makefile.msc
1675 gtk/gtkversion.h
1676 gtk/gtk-win32.rc
1677 gtk/theme-bits/Makefile
1678 gtk/tests/Makefile
1679 modules/Makefile
1680 modules/other/Makefile
1681 modules/other/gail/Makefile
1682 modules/other/gail/libgail-util/Makefile
1683 modules/other/gail/tests/Makefile
1684 modules/engines/Makefile
1685 modules/engines/pixbuf/Makefile
1686 modules/engines/ms-windows/Makefile
1687 modules/engines/ms-windows/Theme/Makefile
1688 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1689 modules/input/Makefile
1690 modules/printbackends/Makefile
1691 modules/printbackends/cups/Makefile
1692 modules/printbackends/lpr/Makefile
1693 modules/printbackends/file/Makefile
1694 modules/printbackends/papi/Makefile
1695 modules/printbackends/test/Makefile
1696 perf/Makefile
1697 ])
1698
1699 AC_OUTPUT
1700
1701 echo "configuration:
1702         target:             $gdktarget"