Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 dnl Eric S. Raymond <esr@thyrsus.com>
   3 dnl Matthias Andree <matthias.andree@gmx.de>
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6 dnl
   7
   8 AC_INIT([fetchmail],[6.3.4-rc2],[fetchmail-users@lists.berlios.de])
   9 AC_CONFIG_SRCDIR([fetchmail.h])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_LIBOBJ_DIR([.])
  12
  13 AC_CANONICAL_TARGET
  14
  15 dnl automake options are in Makefile.am
  16 AC_PREREQ(2.59)
  17 AM_INIT_AUTOMAKE
  18
  19 dnl autobuild support, see <http://josefsson.org/autobuild/>
  20 (
  21   TZ=
  22   export TZ
  23   AB_INIT
  24 )
  25
  26 dnl python is optional
  27 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  28 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  29
  30 AC_PROG_AWK
  31 AC_PROG_CC
  32 AC_PROG_INSTALL
  33 AC_PROG_CPP                     dnl Later checks need this.
  34 AC_PROG_RANLIB
  35 AM_PROG_CC_C_O
  36 AC_AIX
  37 AC_ISC_POSIX
  38 AC_MINIX
  39 AC_HEADER_STDC
  40 AC_HEADER_TIME
  41 AC_TYPE_SIZE_T
  42 AC_TYPE_PID_T
  43 AC_TYPE_SIGNAL
  44 AC_CHECK_TYPE(u_int32_t,unsigned int)
  45 AC_CHECK_HEADERS([unistd.h termios.h termio.h sgtty.h stdarg.h \
  46         sys/itimer.h fcntl.h sys/fcntl.h memory.h sys/wait.h \
  47         arpa/inet.h arpa/nameser.h netinet/in.h net/socket.h \
  48         sys/select.h sys/socket.h sys/time.h langinfo.h])
  49 AC_CHECK_HEADERS([resolv.h],,,[
  50 #include <sys/types.h>
  51 #ifdef HAVE_NETINET_IN_H
  52 #include <netinet/in.h>
  53 #endif
  54 #ifdef HAVE_ARPA_NAMESER_H
  55 #include <arpa/nameser.h>
  56 #endif
  57 ])
  58
  59 AC_C_CONST                      dnl getopt needs this.
  60
  61 AM_PROG_LEX
  62 AC_PROG_MAKE_SET
  63 AC_PROG_YACC
  64
  65 # Check for OS special cases
  66 case $target_os in
  67 darwin*)
  68     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
  69     CPFLAGS="-DBIND_8_COMPAT"
  70     ;;
  71 # Check for FreeBSD special case: more libs needed
  72 freebsd*)
  73     AC_MSG_NOTICE(found FreeBSD - Adding -lmd -lkvm -lcom_err to standard libraries)
  74     LIBS="$LIBS -lmd -lkvm -lcom_err"
  75     ;;
  76 # Check for LynxOS special case: -lbsd needed (at least on 2.3.0) and -s
  77 # not working.
  78 lynxos*)
  79     AC_MSG_NOTICE(found LynxOS - Adding -lbsd to standard libraries)
  80     LIBS="$LIBS -lbsd"
  81     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
  82     AC_MSG_NOTICE(found LynxOS - Prepending standard include path to gcc flags)
  83     CPFLAGS="-I/usr/include"
  84     ;;
  85 # Check for Rhapsody special case: it doesn't like -s
  86 rhapsody*)
  87     AC_MSG_NOTICE(found Rhapsody - Removing -s load flag)
  88     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
  89     ;;
  90 esac
  91
  92 dnl i18n
  93 AM_GNU_GETTEXT([external], [need-ngettext])
  94 AM_GNU_GETTEXT_VERSION(0.14.3)
  95 dnl end i18n
  96
  97 # Under sysV68, socket and friends are provided by the C library.
  98 # -linet does not provide socket, but causes multiple definition
  99 # errors at link-time.  It is thus better to only use the C library.
 100 # So don't add -linet to the link list unless it's necessary
 101 AC_CHECK_FUNC(socket,
 102     AC_MSG_RESULT(using libc's socket),
 103     AC_CHECK_LIB(socket,socket)
 104     AC_CHECK_LIB(inet,socket))
 105
 106 # The condition in this test copes with the presence of inet_addr in libc6.
 107 AC_CHECK_FUNC(inet_addr,
 108     AC_MSG_RESULT(using libc's inet_addr),
 109     AC_CHECK_LIB(nsl,inet_addr))
 110
 111 dnl Port hack for Interactive UNIX System V/386 Release 3.2
 112 AC_CHECK_LIB(cposix, strchr,
 113                 [DEFS="$DEFS -D_SYSV3"
 114                 LIBS="$LIBS -lcposix"])
 115
 116 dnl Port hack for Sparc/NetBSD-1.5
 117 dnl
 118 dnl NB: this has been disabled as it causes the unconditional
 119 dnl addition of libintl to the build, which is both undesired
 120 dnl and breaks on Solaris/Blastwave.org machines.
 121 dnl
 122 dnl AC_CHECK_LIB(intl, gettext,
 123 dnl             [LIBS="$LIBS -lintl"])
 124
 125 AC_REPLACE_FUNCS([strstr strcasecmp memmove stpcpy strlcpy strlcat])
 126
 127 AC_CHECK_FUNC(MD5Init, [],
 128               [AC_LIBSOURCE(md5c.c)
 129                EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"])
 130
 131 AC_CHECK_FUNC(getopt_long, [],
 132               [AC_LIBSOURCES([getopt.c, getopt1.c])
 133                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 134
 135 AC_FUNC_VPRINTF
 136
 137 AC_SUBST(EXTRAOBJ)
 138
 139 AC_CHECK_FUNCS(tcsetattr stty setsid geteuid seteuid dnl
 140   strerror syslog snprintf vprintf vsnprintf vsyslog dnl
 141   atexit inet_aton strftime setrlimit socketpair sigprocmask dnl
 142   sigaction strdup setlocale)
 143
 144 AC_CHECK_DECLS(strerror)
 145
 146 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 147 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 148 # library.  So don't add -lresolv to the link list unless it's necessary
 149 # (It will be necessary when using GNU libc6).
 150 old_LIBS="$LIBS"
 151 for lib in '' -lresolv; do
 152     if test -z "$lib"; then
 153        AC_MSG_CHECKING([for res_search in libc])
 154     else
 155        AC_MSG_CHECKING([for res_search in $lib])
 156     fi
 157     LIBS="$old_LIBS $lib"
 158     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 159 #include <sys/types.h>
 160 #ifdef HAVE_NETINET_IN_H
 161 #include <netinet/in.h>
 162 #endif
 163 #ifdef HAVE_ARPA_NAMESER_H
 164 #include <arpa/nameser.h>
 165 #endif
 166 #ifdef HAVE_RESOLV_H
 167 #include <resolv.h>
 168 #endif
 169 extern int res_search();
 170 ]], [[res_search(0, 0, 0, 0, 0);]])],
 171     [AC_MSG_RESULT([found])
 172      AC_DEFINE(HAVE_RES_SEARCH, [1],
 173                [Define to 1 if you have the 'res_search' function.])
 174      break], [AC_MSG_RESULT([not found])])
 175      LIBS=$old_LIBS
 176 done
 177
 178 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 179 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 180
 181 dnl Check for RSA refersence library in case we're using SSL
 182 AC_CHECK_LIB(rsaref, RSAPublicDecrypt)
 183
 184 dnl AC_FUNC_SETVBUF_REVERSED
 185
 186 dnl Check for usable void pointer type
 187 AC_MSG_CHECKING(use of void pointer type)
 188 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[char *p;
 189     void *xmalloc();
 190     p = (char *) xmalloc(1);
 191    ]])],[AC_DEFINE(HAVE_VOIDPOINTER,1,[Define if your C compiler allows void * as a function result]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 192
 193 dnl Check for ANSI volatile
 194 AC_C_VOLATILE
 195
 196 dnl Check out the wait reality.  We have to assume sys/wait.h is present.
 197 AC_CHECK_FUNCS(waitpid wait3)
 198 AC_MSG_CHECKING(for union wait);
 199 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 200 #include <sys/wait.h>]], [[union wait status; int pid; pid = wait (&status);
 201 #ifdef WEXITSTATUS
 202 /* Some POSIXoid systems have both the new-style macros and the old
 203    union wait type, and they do not work together.  If union wait
 204    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 205 if (WEXITSTATUS (status) != 0) pid = -1;
 206 #endif
 207 #ifdef HAVE_WAITPID
 208 /* Make sure union wait works with waitpid.  */
 209 pid = waitpid (-1, &status, 0);
 210 #endif
 211 ]])],[AC_DEFINE(HAVE_UNION_WAIT,1,Define if 'union wait' is the type of the first arg to wait functions.) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 212
 213 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 214 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 215 /* NetBSD declares sys_siglist in <unistd.h>.  */
 216 #ifdef HAVE_UNISTD_H
 217 #include <unistd.h>
 218 #endif]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 219
 220 # Find the right directory to put the root-mode PID file in
 221 for dir in "/var/run" "/etc"
 222 do
 223         if test -d $dir
 224         then
 225                 break;
 226         fi
 227 done
 228 AC_MSG_RESULT(root-mode pid file will go in $dir)
 229 AC_DEFINE_UNQUOTED(PID_DIR, "$dir", directory for PID lock files)
 230
 231 # We may have a fallback MDA available in case the socket open to the
 232 # local SMTP listener fails.  Best to use procmail for this, as we know
 233 # it won't try delivering through local SMTP and cause a mail loop.
 234 # Sendmail without the -t option to use the message headers will work too,
 235 # not just for sendmail itself but for workalikes like exim.
 236 #
 237 # Note1: A disadvantage of using procmail is that local alias expansion
 238 # according to /etc/aliases won't get done if we fall back.  This doesn't
 239 # matter in single-drop mode.
 240 #
 241 # Note2: it would be a very bad idea to use any MDA that doesn't return
 242 # a refuse-to-deliver status on disk- or process-table-full
 243 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 244 # like exim that might be lurking under a sendmail alias) do the right
 245 # thing in this circumstance.  Matthias Andree warns that procmail does
 246 # not.
 247 #
 248 # Note3: Defalt value of fallback is now off.  Matthias writes:
 249 #
 250 # 1. there is no way to predict when the fallback is used. With some MTAs
 251 #    (such as those limiting load average), outer circumstances can cause
 252 #    the fallback to kick in.
 253 #
 254 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 255 #    not only about alias expansion, .forwards to special filters won't
 256 #    work, mail may end up in a different place (users claim "mail loss"
 257 #    for that).
 258 #
 259 # 3. The claim procmail did the right thing with its exit codes is plain
 260 #    wrong. I've seen procmail exit with code 1 when it should have exited
 261 #    with code 75, like, configuration errors. Procmail is a dangerous
 262 #    beast and is best replaced by maildrop.
 263 #
 264 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 265 #    cannot tell which one it should choose. Say, your MTA is configured
 266 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 267 #    chooses procmail, this is plain wrong.
 268 #
 269
 270 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 271 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 272 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 273
 274 ###     use option --disable-fallback to disable fallback MDA
 275 ###     use option --enable-fallback=procmail or
 276 ###                --enable-fallback=sendmail to select
 277 AC_ARG_ENABLE(fallback,
 278         [  --enable-fallback=procmail    enable procmail as fallback
 279   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 280   --enable-fallback=maildrop    enable maildrop as fallback
 281   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 282
 283 case "$enable_fallback" in
 284         sendmail)       if test -z "$sendmail" ; then
 285                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 286                                 #not reached
 287                         fi
 288                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 289                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 290                         ;;
 291         procmail)       if test -z "$procmail" ; then
 292                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 293                                 #not reached
 294                         fi
 295                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 296                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 297                         ;;
 298         maildrop)       if test -z "$maildrop" ; then
 299                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 300                                 #not reached
 301                         fi
 302                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 303                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 304                         ;;
 305         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 306                         ;;
 307         auto|yes|set)   if test -n "$sendmail" ; then
 308                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 309                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 310                         else
 311                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 312                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 313                         fi
 314                         ;;
 315         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 316                         #notreached
 317                         ;;
 318 esac
 319
 320 AC_CHECK_SIZEOF(short)
 321 AC_CHECK_SIZEOF(int)
 322 AC_CHECK_SIZEOF(long)
 323
 324 ###     use option --enable-POP2 to compile in the POP2 support
 325 AC_ARG_ENABLE(POP2,
 326         [  --enable-POP2           compile in POP2 protocol support (obsolete)],
 327         [with_POP2=$enableval],
 328         [with_POP2=no])
 329 test "$with_POP2" = "yes" && AC_DEFINE(POP2_ENABLE,1,Define if you want POP2 support compiled in)
 330
 331 ###     use option --disable-POP3 to omit the POP3 support
 332 AC_ARG_ENABLE(POP3,
 333         [  --disable-POP3          don't compile in POP3 protocol support],
 334         [with_POP3=$enableval],
 335         [with_POP3=yes])
 336 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 337
 338 ###     use option --disable-IMAP to omit the IMAP support
 339 AC_ARG_ENABLE(IMAP,
 340         [  --disable-IMAP          don't compile in IMAP protocol support],
 341         [with_IMAP=$enableval],
 342         [with_IMAP=yes])
 343 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,"Define if you want IMAP support compiled in")
 344
 345 ###     use option --disable-ETRN to omit the ETRN support
 346 AC_ARG_ENABLE(ETRN,
 347         [  --disable-ETRN          don't compile in ETRN protocol support],
 348         [with_ETRN=$enableval],
 349         [with_ETRN=yes])
 350 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 351
 352 ###     use option --disable-ODMR to omit the ODMR support
 353 AC_ARG_ENABLE(ODMR,
 354         [  --disable-ODMR          don't compile in ODMR protocol support],
 355         [with_ODMR=$enableval],
 356         [with_ODMR=yes])
 357 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 358
 359 ###     use option --enable-RPA to compile in the RPA support
 360 AC_ARG_ENABLE(RPA,
 361         [  --enable-RPA            compile in RPA protocol support],
 362         [with_RPA=$enableval],
 363         [with_RPA=no])
 364 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 365
 366 ###     use option --enable-NTLM to compile in the NTLM support
 367 AC_ARG_ENABLE(NTLM,
 368         [  --enable-NTLM           compile in NTLM authentication support],
 369         [with_NTLM=$enableval],
 370         [with_NTLM=no])
 371 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 372
 373 ###     use option --enable-SDPS to compile in the SDPS support
 374 AC_ARG_ENABLE(SDPS,
 375         [  --enable-SDPS           compile in SDPS protocol support],
 376         [with_SDPS=$enableval],
 377         [with_SDPS=no])
 378 if test "$with_SDPS" = yes ; then
 379    if test "$with_POP3" != yes ; then
 380        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 381        with_SDPS=no
 382    else
 383        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 384    fi
 385 fi
 386
 387 ###     use option --enable-opie to compile in the OPIE support
 388 AC_ARG_ENABLE(opie,
 389         [  --enable-opie           support OTP through the OPIE library],
 390         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR(cannot find <opie.h>, which is required for OPIE support.)])
 391           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR(cannot find libopie, which is required for OPIE support.)])
 392           with_opie=$enableval],
 393         [with_opie=no])
 394 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 395
 396 AC_SEARCH_LIBS(getaddrinfo, inet6, [AC_DEFINE(HAVE_GETADDRINFO,1,[define to 1 if you have the getaddrinfo function])])
 397 AC_CHECK_FUNCS(getnameinfo)
 398
 399 # This version of the Kerberos 4 and 5 options addresses the follwing issues:
 400 #
 401 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 402 #   OpenSSL support (Debian's is)
 403 # * Build the kerberos.c stuff (KPOP) only for kerberosIV, to avoid breakage.
 404 #   I don't know if this is 100% correct, but now at least IMAP and POP3
 405 #   behave the same way regarding kerberosV.
 406 # * Build without any fuss for both kerberosIV and V at the same time.
 407 # * Move all the kerberos header mess to kerberos.h, and #include that
 408 #   in driver.c and kerberos.c.
 409 #
 410 # Tested using the Heimdal Kerberos V libs, Kungliga Tekniska Högskolan (the
 411 # Royal Institute of Technology in Stockholm, Sweden)'s kerberos IV libs, and
 412 # the MIT reference implementation of KerberosV (all as packaged in Debian).
 413
 414 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 415 ### make sure --with-ssl is run before --with-kerberos* !
 416 AC_ARG_WITH(kerberos5,
 417        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 418 [
 419 if test "$with_kerberos5" != "no"
 420 then
 421 # Check for a OpenBSD special case
 422 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 423 then
 424   AS_MESSAGE(checking kerberosV for OpenBSD...)
 425   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 426   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 427   CEFLAGS="$CEFLAGS -I/usr/include/kerberosV"
 428   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 429 elif krb5-config 2> /dev/null >/dev/null ; then
 430   krb5_prefix=`krb5-config --prefix krb5`
 431   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 432   if test -f ${krb5_prefix}/include/et/com_err.h && \
 433    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 434     CEFLAGS="$CEFLAGS -I${krb5_prefix}/include/et"
 435   fi
 436   unset krb5_prefix
 437   CEFLAGS="$CEFLAGS `krb5-config --cflags krb5`"
 438   LIBS="$LIBS `krb5-config --libs krb5`"
 439   AC_DEFINE(KERBEROS_V5)
 440 else
 441   if test "$with_kerberos5" != "yes"
 442   then
 443       LDEFLAGS="$LDEFLAGS -L${with_kerberos5}/lib"
 444       searchdirs="$with_kerberos5"
 445   else
 446       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 447   fi
 448   with_kerberos5=
 449   for dir in $searchdirs
 450   do AC_MSG_CHECKING([for Kerberos V in $dir])
 451      if test -f "$dir/include/krb5.h"
 452      then
 453         ac_krblibs=
 454         if test -f "$dir/include/roken.h"
 455         then
 456            ac_krblibs="-lasn1 -lroken -lcom_err"
 457            AC_MSG_RESULT([Heimdal found])
 458           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 459           dnl we assume we do if it is available
 460            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 461                 ${LDEFLAGS})
 462            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 463               AC_CHECK_LIB(ssl, MD5_Init, [],
 464                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 465                 ${LDEFLAGS} ${ac_krblibs}),
 466            ${LDEFLAGS} ${ac_krblibs})
 467            AC_DEFINE(HEIMDAL)
 468         else
 469           AC_MSG_RESULT([found])
 470           ac_krblibs="-lcom_err"
 471            AC_CHECK_LIB(crypto,
 472              krb5_des_string_to_key,
 473              libk5crypto=-lcrypto,
 474                 AC_CHECK_LIB(k5crypto,
 475                    krb5_des_string_to_key,
 476                    libk5crypto=-lk5crypto,
 477                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 478                    ${LDEFLAGS} ${ac_krblibs}),
 479                  ${LDEFLAGS} ${ac_krblibs})
 480         fi
 481         AC_CHECK_LIB(krb5, krb5_init_context,[],
 482            continue,
 483            ${LDEFLAGS} ${ac_krblibs})
 484         AC_DEFINE(KERBEROS_V5)
 485         test "$dir" != "/usr" && CEFLAGS="$CEFLAGS -I$dir/include"
 486         LDEFLAGS="$LDEFLAGS -L$dir/lib"
 487        LIBS="$LIBS $ac_krblibs $libk5crypto"
 488         with_kerberos5=$dir
 489         break
 490      else
 491         AC_MSG_RESULT([not found])
 492      fi
 493   done
 494   if test -z "$with_kerberos5" ; then
 495      AC_MSG_ERROR([Kerberos 5 libraries not found])
 496   fi
 497 fi
 498 fi
 499 ]) dnl --with-kerberos5=DIR
 500
 501 ###    use option --with-kerberos=DIR to point at a Kerberos 4 directory
 502 AC_ARG_WITH(kerberos,
 503        [  --with-kerberos=DIR     point fetchmail compilation at a Kerberos 4 directory],
 504 [
 505 if test "$with_kerberos" != "no"
 506 then
 507 # Check for a NetBSD/OpenBSD special case
 508 if test "$with_kerberos" = "yes" && ( test `uname` = "NetBSD" || test `uname` = "OpenBSD" )
 509 then
 510   AS_MESSAGE(checking kerberosIV for `uname`...)
 511   AC_DEFINE(KERBEROS_V4,1,Define if you have Kerberos V4)
 512   CEFLAGS="$CEFLAGS -I/usr/include/kerberosIV"
 513   LIBS="$LIBS -lkrb -ldes"
 514 elif krb4-config 2> /dev/null >/dev/null ; then
 515   krb4_prefix=`krb4-config --prefix`
 516   AC_MSG_RESULT([krb4-config points to kerberosIV under $krb4_prefix])
 517   unset krb4_prefix
 518   CEFLAGS="$CEFLAGS `krb4-config --cflags`"
 519   LIBS="$LIBS `krb4-config --libs`"
 520   AC_DEFINE(KERBEROS_V4)
 521 elif krb5-config 2> /dev/null >/dev/null ; then
 522   krb4_prefix=`krb5-config --prefix krb4`
 523   AC_MSG_RESULT([krb5-config points to kerberosIV under $krb4_prefix])
 524   if test -f ${krb4_prefix}/include/kerberosIV/krb.h ; then
 525     AC_DEFINE(KERBEROS_V4_V5,1,Define if you have Kerberos V4 headers under a kerberosIV directory)
 526   fi
 527   unset krb4_prefix
 528   CEFLAGS="$CEFLAGS `krb5-config --cflags krb4`"
 529   LIBS="$LIBS `krb5-config --libs krb4`"
 530   AC_DEFINE(KERBEROS_V4)
 531 else
 532   #we need to detect when we're building under a kerberosV compatibility
 533   #layer, btw...
 534   if test "$with_kerberos" != "yes" ; then
 535      searchdirs="$with_kerberos"
 536   else
 537      searchdirs="$with_kerberos5 /usr/kerberos /usr/kerberosIV /usr/athena /usr"
 538   fi
 539   with_kerberos=
 540   ac_saveLDFLAGS="$LDFLAGS"
 541   for dir in $searchdirs
 542   do
 543      AC_MSG_CHECKING([for Kerberos IV in $dir])
 544      if test -f "$dir/include/krb.h" || test -f "$dir/include/krb4.h" \
 545             || test -f "$dir/include/kerberosIV/krb.h"
 546      then
 547         AC_MSG_RESULT([found])
 548      else
 549         AC_MSG_RESULT([not found])
 550        continue
 551      fi
 552      #Find libs
 553      if test -f "$with_kerberos5/roken.h" ; then
 554        AC_CHECK_LIB(45, krb_mk_req)
 555      fi
 556      LDFLAGS="-L$dir/lib $ac_saveLDFLAGS"
 557      if test `uname` = "FreeBSD"; then
 558         AC_SEARCH_LIBS(_ossl_old_des_string_to_key, [des425 des crypto], [], continue)
 559      else
 560         AC_SEARCH_LIBS(des_string_to_key, [crypto], [], continue)
 561      fi
 562      AC_SEARCH_LIBS(krb_realmofhost, [krb4 krb], [], continue)
 563      with_kerberos="$dir"
 564      if test -f "$dir/include/kerberosIV/krb.h" ; then
 565         dir="$dir/include/kerberosIV"
 566      else
 567        dir="$dir/include"
 568      fi
 569      AC_DEFINE(KERBEROS_V4)
 570      test -f "$with_kerberos5/roken.h" && AC_DEFINE(HEIMDAL)
 571      test "$dir" != "/usr/include" && CEFLAGS="$CEFLAGS -I$dir"
 572      LDEFLAGS="$LDEFLAGS -L$with_kerberos/lib"
 573      break
 574   done
 575   if test -z "$with_kerberos" ; then
 576      AC_MSG_ERROR([Kerberos 4 libraries not found])
 577   fi
 578   LDFLAGS="$ac_saveLDFLAGS"
 579 fi
 580 fi
 581 ]) dnl --with-kerberos=DIR
 582
 583 ###     use option --with-ssl to compile in the SSL support
 584 AC_ARG_WITH(ssl,
 585         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 586         [with_ssl=$withval],
 587         [with_ssl=no])
 588 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 589
 590 if test "$with_ssl" = "yes"
 591 then
 592     #   He didn't specify an SSL location.  Let's look at some common
 593     #   directories where SSL has been found in the past and try and auto
 594     #   configure for SSL.  OpenSSL determination will be made later.
 595     #   This will screw up if an OpenSSL install is located in a later
 596     #   directory than an older SSLeay install, but the user should fix that
 597     #   anyways and he can override on the configure line.
 598     #   Just testing for directories is not sufficient, /usr exists on
 599     #   all systems!
 600     for ac_dir in \
 601       /usr/local/ssl \
 602       /usr/local \
 603       /usr/ssl \
 604       /usr \
 605       /local/ssl \
 606       /opt/ssl \
 607       /opt/csw \
 608       ; \
 609     do
 610         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 611             with_ssl=$ac_dir
 612             break;
 613         fi
 614     done
 615 fi
 616
 617 if test -n "$with_ssl" -a "$with_ssl" != "no"
 618 then
 619   # With the autoconfigure above, the only time this is going to be
 620   # true is going to be when we could not find the headers.  If they
 621   # are not in system standard locations, we are going to be broken.
 622   if test "$with_ssl" = "yes"
 623   then
 624     # Let's just define the standard location for the SSLeay root
 625     with_ssl="/usr/local/ssl"
 626   fi
 627   if test -r $with_ssl/include/openssl/ssl.h
 628   then
 629     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 630     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 631     test "$with_ssl" != "/usr" && CEFLAGS="$CEFLAGS -I$with_ssl/include"
 632     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 633     ### force the Kerberos direcory onto the include path so it will build.
 634     CEFLAGS="$CEFLAGS -I/usr/kerberos/include"
 635     ### OpenBSD comes with ssl headers
 636   else
 637     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 638   fi
 639   LDEFLAGS="$LDEFLAGS -L$with_ssl/lib"
 640   LIBS="$LIBS -lssl -lcrypto"
 641   dnl check if -ldl is needed
 642   AC_MSG_CHECKING([for additional library dependencies of SSL])
 643   found=0
 644   save_LIBS="$LIBS"
 645   for i in "" "-ldl" ; do
 646       LIBS="$LDEFLAGS $save_LIBS $i"
 647       AC_LINK_IFELSE([AC_LANG_PROGRAM(,[SSL_library_init()])],[found=1; break])
 648   done
 649   if test $found = 0 ; then
 650       AC_MSG_RESULT([error])
 651       AC_MSG_ERROR([cannot link with SSL - check config.log])
 652   fi
 653   LIBS="$save_LIBS $i"
 654   if test "$i" = "" ; then i="(none)" ; fi
 655   AC_MSG_RESULT($i)
 656   dnl XXX FIXME: use pkg-config if available!
 657   AC_DEFINE(SSL_ENABLE)
 658 else
 659   AC_MSG_NOTICE(Disabling SSL support.)
 660 fi
 661
 662 ###     use option --with-socks=DIR to point at SOCKS library
 663 AC_ARG_WITH(socks,
 664         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 665 [
 666 if test "$with_socks" != no
 667 then
 668     if test "$with_socks" != yes
 669     then
 670         LDEFLAGS="$LDEFLAGS -L$with_socks"
 671     else
 672         AC_CHECK_LIB(socks, Rconnect,,
 673                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 674     fi
 675     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 676     CEFLAGS="$CEFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 677     LIBS="-lsocks $LIBS"
 678 fi])
 679
 680 ###     use option --with-socks5=DIR to point at SOCKS library
 681 AC_ARG_WITH(socks5,
 682         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 683 [
 684 if test "$with_socks5" != no
 685 then
 686   if test "$with_socks5" != yes
 687   then
 688     LDEFLAGS="$LDEFLAGS -L$with_socks5"
 689   fi
 690   ac_savedLDFLAGS="$LDFLAGS"
 691   LDFLAGS="$LDEFLAGS $LDFLAGS"
 692   AC_CHECK_LIB(socks5, SOCKSconnect,,
 693         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 694   AC_DEFINE(HAVE_SOCKS)
 695   CEFLAGS="$CEFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 696   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 697   LDFLAGS="$ac_savedLDFLAGS"
 698 fi])
 699
 700 ACX_WHICH_GETHOSTBYNAME_R
 701
 702 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 703 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 704
 705 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 706 AC_ARG_WITH(gssapi,
 707         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 708 [
 709 if test "$with_gssapi" != "no"
 710 then
 711   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 712   then
 713     with_gssapi=$with_kerberos5
 714   fi
 715   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 716   then
 717     CFLAGS="$CFLAGS -I$with_gssapi/include"
 718     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 719   fi
 720
 721   AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 722   if test -n "$nogss"
 723   then
 724   if test -f "$with_gssapi/include/roken.h"
 725   then
 726      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl"
 727      AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 728                   AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 729      AC_DEFINE(HEIMDAL)
 730   else
 731      AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 732                   AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 733   fi
 734   fi
 735   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 736   save_CPPFLAGS=$CPPFLAGS
 737   CPPFLAGS="-I$with_gssapi/include"
 738   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 739   if test "$ac_cv_header_gssapi_h" = "yes"; then
 740     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 741   else
 742     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 743   fi
 744 fi])
 745
 746 AC_SUBST(CPFLAGS)
 747 AC_SUBST(CEFLAGS)
 748 AC_SUBST(LDEFLAGS)
 749
 750 dnl ,------------------------------------------------------------------
 751 dnl Check if we need TRIO
 752 needtrio=0
 753 if test "$FORCE_TRIO" = "yes" ; then
 754     needtrio=1
 755     ac_cv_func_vsnprintf=no
 756     ac_cv_func_snprintf=no
 757 fi
 758 if test "x$ac_cv_func_snprintf" != "xyes" ; then
 759     AC_DEFINE(snprintf, trio_snprintf,
 760               [Define to trio_snprintf if your system lacks snprintf])
 761     needtrio=1
 762 fi
 763 if test "x$ac_cv_func_vsnprintf" != "xyes" ; then
 764     AC_DEFINE(vsnprintf, trio_vsnprintf,
 765               [Define to trio_vsnprintf if your system lacks vsnprintf])
 766     needtrio=1
 767 fi
 768 AM_CONDITIONAL(NEED_TRIO, test "$needtrio" = 1)
 769
 770 dnl TRIO IEEE compiler option for Alpha
 771 dnl
 772 if test "$needtrio" = 1 ; then
 773     AC_MSG_CHECKING(for IEEE compilation options)
 774     AC_CACHE_VAL(ac_cv_ieee_option, [
 775     AC_TRY_COMPILE(,[
 776     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
 777     # error "Option needed"
 778     #endif
 779     ],ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
 780     AC_TRY_COMPILE(,[
 781     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
 782     # error "Option needed"
 783     #endif
 784     ],ac_cv_ieee_option="-ieee",
 785     AC_TRY_COMPILE(,[
 786     #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
 787     # error "Option needed"
 788     #endif
 789     ],ac_cv_ieee_option="-mieee",
 790     ac_cv_ieee_option="none"
 791     )
 792     )
 793     )
 794     ])
 795     AC_MSG_RESULT($ac_cv_ieee_option)
 796     if test $ac_cv_ieee_option != none; then
 797       CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
 798     fi
 799 fi
 800 dnl ----------------------------------------------------------------'
 801
 802 AC_CONFIG_FILES([Makefile m4/Makefile po/Makefile.in genlsm.sh])
 803 AC_OUTPUT
 804
 805 dnl Local Variables:
 806 dnl comment-start: "dnl "
 807 dnl comment-end: ""
 808 dnl comment-start-skip: "\\bdnl\\b\\s *"
 809 dnl compile-command: "make configure config.h.in"
 810 dnl End: