Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 #
   3 # Fetchmail automatic configuration support
   4 #
   5 # Eric S. Raymond <esr@thyrsus.com>
   6 # 2004 - 2009 Matthias Andree <matthias.andree@gmx.de>
   7 #
   8 dnl Process this file with autoconf to produce a configure script.
   9 dnl
  10
  11 dnl XXX - if bumping version here, check fetchmail.man, too!
  12 AC_INIT([fetchmail],[6.3.14],[fetchmail-users@lists.berlios.de])
  13 AC_CONFIG_SRCDIR([fetchmail.h])
  14 AC_CONFIG_HEADERS([config.h])
  15 AC_CONFIG_LIBOBJ_DIR([.])
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl automake options are in Makefile.am
  20 AC_PREREQ(2.60)
  21 dnl 2.60 required for AC_USE_SYSTEM_EXTENSIONS
  22 AM_INIT_AUTOMAKE
  23
  24 dnl python is optional
  25 #
  26 # you can pass PYTHON=: in environment or on the command line
  27 # to disable python detection and continue without building/installing
  28 # fetchmail.conf -- be sure to check README.packaging, too!
  29 #
  30 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  31 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  32
  33 AC_PROG_AWK
  34 AC_PROG_CC
  35 AC_PROG_INSTALL
  36 AC_PROG_CPP                     dnl Later checks need this.
  37 AC_PROG_RANLIB
  38 AM_PROG_CC_C_O
  39 AC_USE_SYSTEM_EXTENSIONS
  40
  41 AC_ISC_POSIX
  42 dnl AC_ISC_POSIX: - XXX FIXME: remove in fetchmail 6.4.
  43 dnl This macro adds `-lcposix' to output variable `LIBS' if necessary
  44 dnl for Posix facilities.  Sun dropped support for the obsolete
  45 dnl INTERACTIVE Systems Corporation Unix on 2006-07-23.  New programs
  46 dnl need not use this macro.  It is implemented as
  47 dnl `AC_SEARCH_LIBS([strerror], [cposix])'
  48
  49 dnl check for b0rked Solaris (and other shells) and find one that works
  50 AC_MSG_CHECKING(for a working shell...)
  51 for i in /usr/xpg6/bin/sh /usr/xpg4/bin/sh /usr/ccs/bin/sh /bin/sh /usr/bin/sh /bin/ksh /bin/bash /usr/local/bin/bash ; do
  52     $i -c 'if ! false ; then echo $(echo ok) ; fi' >config.$$ 2>/dev/null
  53     j=`cat config.$$`
  54     rm -f config.$$
  55     if test "x$j" = "xok" ; then
  56         SHELL=$i
  57         AC_SUBST(SHELL)
  58         break
  59     fi
  60 done
  61 AC_MSG_RESULT($SHELL)
  62 if test "x$SHELL" = "x" ; then
  63     AC_MSG_ERROR(no SUS compliant shell found - on Solaris, install SUNWxcu4)
  64 fi
  65
  66
  67 AC_HEADER_STDC
  68 AC_HEADER_TIME
  69 AC_TYPE_SIZE_T
  70 AC_TYPE_PID_T
  71 AC_TYPE_SIGNAL
  72 AC_CHECK_HEADERS([unistd.h termios.h termio.h sgtty.h stdarg.h \
  73         sys/itimer.h fcntl.h sys/fcntl.h memory.h sys/wait.h \
  74         arpa/inet.h arpa/nameser.h netinet/in.h net/socket.h netdb.h \
  75         sys/select.h sys/socket.h sys/time.h langinfo.h])
  76 if test _$ac_cv_header_stdarg_h != _yes ; then
  77 AC_MSG_WARN([stdarg.h is not defined. Unsupported configuration, proceed at your own risk.])
  78 fi
  79 AC_CHECK_TYPE(u_int32_t,,
  80         AC_DEFINE(u_int32_t,unsigned int,
  81                 [Define to unsigned int if <sys/types.h> does not define.]),
  82         [AC_INCLUDES_DEFAULT
  83 #ifdef HAVE_ARPA_NAMESER_H
  84 #include <arpa/nameser.h>
  85 #endif])
  86 AC_CHECK_HEADERS([resolv.h],,,[
  87 #include <sys/types.h>
  88 #ifdef HAVE_NETINET_IN_H
  89 #include <netinet/in.h>
  90 #endif
  91 #ifdef HAVE_ARPA_NAMESER_H
  92 #include <arpa/nameser.h>
  93 #endif
  94 ])
  95
  96 AC_C_CONST                      dnl getopt needs this.
  97
  98 AM_PROG_LEX
  99 AC_PROG_MAKE_SET
 100 AC_PROG_YACC
 101
 102 # Check for OS special cases
 103 case $host_os in
 104 darwin*)
 105     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
 106     CPPFLAGS="$CPPFLAGS -DBIND_8_COMPAT"
 107     ;;
 108 # Check for FreeBSD special case: more libs needed
 109 freebsd*)
 110     AC_MSG_NOTICE(found FreeBSD - Adding -lmd -lkvm -lcom_err to standard libraries)
 111     LIBS="$LIBS -lmd -lkvm -lcom_err"
 112     ;;
 113 # Check for LynxOS special case: -lbsd needed (at least on 2.3.0) and -s
 114 # not working.
 115 lynxos*)
 116     AC_MSG_NOTICE(found LynxOS - Adding -lbsd to standard libraries)
 117     LIBS="$LIBS -lbsd"
 118     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 119     AC_MSG_NOTICE(found LynxOS - Prepending standard include path to gcc flags)
 120     CPPFLAGS="$CPPFLAGS -I/usr/include"
 121     ;;
 122 # Check for Rhapsody special case: it doesn't like -s
 123 rhapsody*)
 124     AC_MSG_NOTICE(found Rhapsody - Removing -s load flag)
 125     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 126     ;;
 127 esac
 128
 129 AC_CACHE_SAVE
 130
 131 dnl i18n
 132 AM_GNU_GETTEXT([external], [need-ngettext])
 133 AM_GNU_GETTEXT_VERSION([0.14.6])
 134 dnl end i18n
 135
 136 # Under sysV68, socket and friends are provided by the C library.
 137 # -linet does not provide socket, but causes multiple definition
 138 # errors at link-time.  It is thus better to only use the C library.
 139 # So don't add -linet to the link list unless it's necessary
 140 AC_CHECK_FUNC(socket,
 141     AC_MSG_RESULT(using libc's socket),
 142     AC_CHECK_LIB(socket,socket)
 143     AC_CHECK_LIB(inet,socket))
 144
 145 # The condition in this test copes with the presence of inet_addr in libc6.
 146 AC_CHECK_FUNC(inet_addr,
 147     AC_MSG_RESULT(using libc's inet_addr),
 148     AC_CHECK_LIB(nsl,inet_addr))
 149
 150 dnl Port hack for Interactive UNIX System V/386 Release 3.2
 151 AC_CHECK_LIB(cposix, strchr,
 152                 [DEFS="$DEFS -D_SYSV3"
 153                 LIBS="$LIBS -lcposix"])
 154
 155 dnl Port hack for Sparc/NetBSD-1.5
 156 dnl
 157 dnl NB: this has been disabled as it causes the unconditional
 158 dnl addition of libintl to the build, which is both undesired
 159 dnl and breaks on Solaris/Blastwave.org machines.
 160 dnl
 161 dnl AC_CHECK_LIB(intl, gettext,
 162 dnl             [LIBS="$LIBS -lintl"])
 163
 164 AC_REPLACE_FUNCS([strstr strcasecmp memmove stpcpy strlcpy strlcat])
 165
 166 AC_CHECK_FUNC(MD5Init, [],
 167               [AC_LIBSOURCE(md5c.c)
 168                EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"])
 169
 170 AC_CHECK_FUNC(getopt_long, [],
 171               [AC_LIBSOURCES([getopt.c, getopt1.c])
 172                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 173
 174 AC_FUNC_VPRINTF
 175
 176 AC_SUBST(EXTRAOBJ)
 177
 178 AC_CHECK_FUNCS(tcsetattr stty setsid geteuid seteuid dnl
 179   strerror syslog snprintf vprintf vsnprintf vsyslog dnl
 180   atexit inet_aton strftime setrlimit socketpair dnl
 181   sigaction strdup setlocale)
 182
 183 AC_CHECK_DECLS(strerror)
 184 dnl INET6 is used by KAME/getnameinfo
 185 AC_CACHE_CHECK(for AF_INET6/PF_INET6,ac_cv_inet6,
 186 AC_COMPILE_IFELSE([
 187   AC_LANG_PROGRAM([[
 188     #ifdef HAVE_SYS_TYPES_H
 189     #include <sys/types.h>
 190     #endif
 191     #ifdef HAVE_SYS_SOCKET_H
 192     #include <sys/socket.h>
 193     #endif
 194   ]],[[
 195     int foo = AF_INET6;
 196     int bar = PF_INET6;
 197   ]])],
 198   ac_cv_inet6=yes , ac_cv_inet6=no
 199 ))
 200 if test "x$ac_cv_inet6" = xyes
 201 then
 202     AC_DEFINE(INET6,1,Define to 1 if your system defines AF_INET6 and PF_INET6.)
 203 fi
 204
 205 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 206 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 207 # library.  So don't add -lresolv to the link list unless it's necessary
 208 # (It will be necessary when using GNU libc6).
 209 old_LIBS="$LIBS"
 210 for lib in '' -lresolv; do
 211     if test -z "$lib"; then
 212        AC_MSG_CHECKING([for res_search in libc])
 213     else
 214        AC_MSG_CHECKING([for res_search in $lib])
 215     fi
 216     LIBS="$old_LIBS $lib"
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 218 #include <sys/types.h>
 219 #ifdef HAVE_NETINET_IN_H
 220 #include <netinet/in.h>
 221 #endif
 222 #ifdef HAVE_ARPA_NAMESER_H
 223 #include <arpa/nameser.h>
 224 #endif
 225 #ifdef HAVE_RESOLV_H
 226 #include <resolv.h>
 227 #endif
 228 extern int res_search();
 229 ]], [[res_search(0, 0, 0, 0, 0); dn_skipname(0,0);]])],
 230     [AC_MSG_RESULT([found])
 231      AC_DEFINE(HAVE_RES_SEARCH, [1],
 232                [Define to 1 if you have the 'res_search' and 'dn_skipname' functions.])
 233      break], [AC_MSG_RESULT([not found])])
 234      LIBS=$old_LIBS
 235 done
 236
 237 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 238 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 239
 240 dnl Check for RSA refersence library in case we're using SSL
 241 AC_CHECK_LIB(rsaref, RSAPublicDecrypt)
 242
 243 dnl AC_FUNC_SETVBUF_REVERSED
 244
 245 dnl Check for usable void pointer type
 246 AC_MSG_CHECKING(use of void pointer type)
 247 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[char *p;
 248     void *xmalloc();
 249     p = (char *) xmalloc(1);
 250    ]])],[AC_DEFINE(HAVE_VOIDPOINTER,1,[Define if your C compiler allows void * as a function result]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 251
 252 dnl Check for ANSI volatile
 253 AC_C_VOLATILE
 254
 255 dnl Check out the wait reality.  We have to assume sys/wait.h is present.
 256 AC_CHECK_FUNCS(waitpid wait3)
 257 AC_MSG_CHECKING(for union wait);
 258 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 259 #include <sys/wait.h>]], [[union wait status; int pid; pid = wait (&status);
 260 #ifdef WEXITSTATUS
 261 /* Some POSIXoid systems have both the new-style macros and the old
 262    union wait type, and they do not work together.  If union wait
 263    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 264 if (WEXITSTATUS (status) != 0) pid = -1;
 265 #endif
 266 #ifdef HAVE_WAITPID
 267 /* Make sure union wait works with waitpid.  */
 268 pid = waitpid (-1, &status, 0);
 269 #endif
 270 ]])],[AC_DEFINE(HAVE_UNION_WAIT,1,Define if 'union wait' is the type of the first arg to wait functions.) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 271
 272 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 273 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 274 /* NetBSD declares sys_siglist in <unistd.h>.  */
 275 #ifdef HAVE_UNISTD_H
 276 #include <unistd.h>
 277 #endif]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 278
 279 # Find the right directory to put the root-mode PID file in
 280 for dir in "/var/run" "/etc"
 281 do
 282         if test -d $dir
 283         then
 284                 break;
 285         fi
 286 done
 287 AC_MSG_RESULT(root-mode pid file will go in $dir)
 288 AC_DEFINE_UNQUOTED(PID_DIR, "$dir", directory for PID lock files)
 289
 290 AC_ARG_ENABLE(pwmd,
 291         [  --enable-pwmd           enable Password Manager Daemon support],
 292         , [enable_pwmd=no])
 293
 294 if test "$enable_pwmd" = "yes"; then
 295     PKG_CHECK_EXISTS([libpwmd], have_libpwmd=1,
 296                      AC_MSG_ERROR([Could not find libpwmd pkg-config module.]))
 297
 298
 299     PKG_CHECK_MODULES([libpwmd], [libpwmd >= 6.0.0])
 300     AM_CONDITIONAL(HAVE_LIBPWMD, true)
 301     AC_DEFINE(HAVE_LIBPWMD, 1, [Define if you have libPWMD installed.])
 302 else
 303     AM_CONDITIONAL(HAVE_LIBPWMD, false)
 304 fi
 305
 306 # We may have a fallback MDA available in case the socket open to the
 307 # local SMTP listener fails.  Best to use procmail for this, as we know
 308 # it won't try delivering through local SMTP and cause a mail loop.
 309 # Sendmail without the -t option to use the message headers will work too,
 310 # not just for sendmail itself but for workalikes like exim.
 311 #
 312 # Note1: A disadvantage of using procmail is that local alias expansion
 313 # according to /etc/aliases won't get done if we fall back.  This doesn't
 314 # matter in single-drop mode.
 315 #
 316 # Note2: it would be a very bad idea to use any MDA that doesn't return
 317 # a refuse-to-deliver status on disk- or process-table-full
 318 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 319 # like exim that might be lurking under a sendmail alias) do the right
 320 # thing in this circumstance.  Matthias Andree warns that procmail does
 321 # not.
 322 #
 323 # Note3: Defalt value of fallback is now off.  Matthias writes:
 324 #
 325 # 1. there is no way to predict when the fallback is used. With some MTAs
 326 #    (such as those limiting load average), outer circumstances can cause
 327 #    the fallback to kick in.
 328 #
 329 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 330 #    not only about alias expansion, .forwards to special filters won't
 331 #    work, mail may end up in a different place (users claim "mail loss"
 332 #    for that).
 333 #
 334 # 3. The claim procmail did the right thing with its exit codes is plain
 335 #    wrong. I've seen procmail exit with code 1 when it should have exited
 336 #    with code 75, like, configuration errors. Procmail is a dangerous
 337 #    beast and is best replaced by maildrop.
 338 #
 339 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 340 #    cannot tell which one it should choose. Say, your MTA is configured
 341 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 342 #    chooses procmail, this is plain wrong.
 343 #
 344
 345 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 346 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 347 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 348
 349 ###     use option --disable-fallback to disable fallback MDA
 350 ###     use option --enable-fallback=procmail or
 351 ###                --enable-fallback=sendmail to select
 352 AC_ARG_ENABLE(fallback,
 353         [  --enable-fallback=procmail    enable procmail as fallback
 354   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 355   --enable-fallback=maildrop    enable maildrop as fallback
 356   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 357
 358 case "$enable_fallback" in
 359         sendmail)       if test -z "$sendmail" ; then
 360                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 361                                 #not reached
 362                         fi
 363                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 364                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 365                         ;;
 366         procmail)       if test -z "$procmail" ; then
 367                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 368                                 #not reached
 369                         fi
 370                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 371                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 372                         ;;
 373         maildrop)       if test -z "$maildrop" ; then
 374                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 375                                 #not reached
 376                         fi
 377                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 378                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 379                         ;;
 380         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 381                         ;;
 382         auto|yes|set)   if test -n "$sendmail" ; then
 383                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 384                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 385                         else
 386                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 387                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 388                         fi
 389                         ;;
 390         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 391                         #notreached
 392                         ;;
 393 esac
 394
 395 AC_CHECK_SIZEOF(short)
 396 AC_CHECK_SIZEOF(int)
 397 AC_CHECK_SIZEOF(long)
 398
 399 ###     use option --enable-POP2 to compile in the POP2 support
 400 AC_ARG_ENABLE(POP2,
 401         [  --enable-POP2           compile in POP2 protocol support (obsolete)],
 402         [with_POP2=$enableval],
 403         [with_POP2=no])
 404 test "$with_POP2" = "yes" && AC_DEFINE(POP2_ENABLE,1,Define if you want POP2 support compiled in)
 405 AM_CONDITIONAL(POP2_ENABLE, test "$with_POP2" = yes)
 406
 407 ###     use option --disable-POP3 to omit the POP3 support
 408 AC_ARG_ENABLE(POP3,
 409         [  --disable-POP3          don't compile in POP3 protocol support],
 410         [with_POP3=$enableval],
 411         [with_POP3=yes])
 412 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 413 AM_CONDITIONAL(POP3_ENABLE, test "$with_POP3" = yes)
 414
 415 ###     use option --disable-IMAP to omit the IMAP support
 416 AC_ARG_ENABLE(IMAP,
 417         [  --disable-IMAP          don't compile in IMAP protocol support],
 418         [with_IMAP=$enableval],
 419         [with_IMAP=yes])
 420 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,Define if you want IMAP support compiled in)
 421 AM_CONDITIONAL(IMAP_ENABLE, test "$with_IMAP" = yes)
 422
 423 ###     use option --disable-ETRN to omit the ETRN support
 424 AC_ARG_ENABLE(ETRN,
 425         [  --disable-ETRN          don't compile in ETRN protocol support],
 426         [with_ETRN=$enableval],
 427         [with_ETRN=yes])
 428 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 429 AM_CONDITIONAL(ETRN_ENABLE, test "$with_ETRN" = yes)
 430
 431 ###     use option --disable-ODMR to omit the ODMR support
 432 AC_ARG_ENABLE(ODMR,
 433         [  --disable-ODMR          don't compile in ODMR protocol support],
 434         [with_ODMR=$enableval],
 435         [with_ODMR=yes])
 436 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 437 AM_CONDITIONAL(ODMR_ENABLE, test "$with_ODMR" = yes)
 438
 439 ###     use option --enable-RPA to compile in the RPA support
 440 AC_ARG_ENABLE(RPA,
 441         [  --enable-RPA            compile in RPA protocol support],
 442         [with_RPA=$enableval],
 443         [with_RPA=no])
 444 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 445 AM_CONDITIONAL(RPA_ENABLE, test "$with_RPA" = yes)
 446
 447 ###     use option --enable-NTLM to compile in the NTLM support
 448 AC_ARG_ENABLE(NTLM,
 449         [  --enable-NTLM           compile in NTLM authentication support],
 450         [with_NTLM=$enableval],
 451         [with_NTLM=no])
 452 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 453
 454 ###     use option --enable-SDPS to compile in the SDPS support
 455 AC_ARG_ENABLE(SDPS,
 456         [  --enable-SDPS           compile in SDPS protocol support],
 457         [with_SDPS=$enableval],
 458         [with_SDPS=no])
 459 if test "$with_SDPS" = yes ; then
 460    if test "$with_POP3" != yes ; then
 461        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 462        with_SDPS=no
 463    else
 464        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 465    fi
 466 fi
 467 if test "$with_POP3" != yes && test "$with_POP2" != yes \
 468     && test "$with_IMAP"  != yes ; then
 469     AC_MSG_ERROR([You must enable at least one of POP2, POP3 and IMAP.])
 470 fi
 471
 472 AC_CACHE_SAVE
 473
 474 ###     use option --enable-opie to compile in the OPIE support
 475 AC_ARG_ENABLE(opie,
 476         [  --enable-opie           support OTP through the OPIE library],
 477         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR(cannot find <opie.h>, which is required for OPIE support.)])
 478           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR(cannot find libopie, which is required for OPIE support.)])
 479           with_opie=$enableval],
 480         [with_opie=no])
 481 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 482
 483 dnl Mostly stolen from gnulib's getaddrinfo.m4
 484 AC_SEARCH_LIBS(getaddrinfo, [nsl socket])
 485 AC_CACHE_CHECK([for getaddrinfo],[fm_cv_getaddrinfo],[
 486   AC_TRY_LINK([
 487 #include <sys/types.h>
 488 #ifdef HAVE_SYS_SOCKET_H
 489 #include <sys/socket.h>
 490 #endif
 491 #ifdef HAVE_NETDB_H
 492 #include <netdb.h>
 493 #endif
 494   ], [getaddrinfo(0, 0, 0, 0);],
 495     [ fm_cv_getaddrinfo=yes],
 496     [ fm_cv_getaddrinfo=no ])
 497 ])
 498
 499 if test x"$fm_cv_getaddrinfo" = "xyes"; then
 500      AC_DEFINE(HAVE_GETADDRINFO, 1,
 501       [Define to 1 if you have the getaddrinfo function.])
 502 fi
 503
 504 AC_CACHE_CHECK([for getnameinfo],[fm_cv_getnameinfo],[
 505   AC_TRY_LINK([
 506 #include <sys/types.h>
 507 #ifdef HAVE_SYS_SOCKET_H
 508 #include <sys/socket.h>
 509 #endif
 510 #ifdef HAVE_NETDB_H
 511 #include <netdb.h>
 512 #endif
 513 #ifndef NULL
 514 #define NULL ((void *)0)
 515 #endif
 516   ], [getnameinfo(NULL,0, NULL,0, NULL, 0, 0);],
 517     [ fm_cv_getnameinfo=yes],
 518     [ fm_cv_getnameinfo=no ])
 519 ])
 520 if test $fm_cv_getnameinfo = yes ; then
 521     AC_DEFINE(HAVE_GETNAMEINFO,1,[Define to 1 if your system has getnameinfo()])
 522 fi
 523
 524 AM_CONDITIONAL(NEED_GETADDRINFO, test "$fm_cv_getaddrinfo" != yes)
 525 AM_CONDITIONAL(NEED_GETNAMEINFO, test "$fm_cv_getnameinfo"   != yes)
 526
 527 AC_CHECK_FUNCS(inet_ntop)
 528 dnl Check if getaddrinfo is async-signal-safe - most implementations aren't
 529 if test "$fm_cv_getaddrinfo" = yes ; then
 530     AC_MSG_CHECKING(if your getaddrinfo is async-signal-safe)
 531     gai_ts=no
 532     dnl we have getaddrinfo() - check if the OS is known to have a async-signal-safe implementation
 533     case $host_os in
 534         darwin9*)                               gai_ts=yes ;;
 535         linux*)                                 gai_ts=yes ;;
 536         freebsd5.5|freebsd6*|freebsd7*)         gai_ts=yes ;;
 537         solaris2.8|solaris2.9|solaris2.10)      gai_ts=yes ;;
 538     esac
 539     AC_MSG_RESULT($gai_ts)
 540     if test $gai_ts = yes ; then
 541         AC_DEFINE(GETADDRINFO_ASYNCSAFE, 1, [define to 1 if you know your getaddrinfo function is async-signal-safe])
 542     fi
 543 fi
 544
 545 # This version of the Kerberos 4 and 5 options addresses the follwing issues:
 546 #
 547 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 548 #   OpenSSL support (Debian's is)
 549 # * Build the kerberos.c stuff (KPOP) only for kerberosIV, to avoid breakage.
 550 #   I don't know if this is 100% correct, but now at least IMAP and POP3
 551 #   behave the same way regarding kerberosV.
 552 # * Build without any fuss for both kerberosIV and V at the same time.
 553 # * Move all the kerberos header mess to kerberos.h, and #include that
 554 #   in driver.c and kerberos.c.
 555 #
 556 # Tested using the Heimdal Kerberos V libs, Kungliga Tekniska Högskolan (the
 557 # Royal Institute of Technology in Stockholm, Sweden)'s kerberos IV libs, and
 558 # the MIT reference implementation of KerberosV (all as packaged in Debian).
 559
 560 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 561 ### make sure --with-ssl is run before --with-kerberos* !
 562 AC_ARG_WITH(kerberos5,
 563        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 564 [
 565 if test "$with_kerberos5" != "no"
 566 then
 567 # Check for a OpenBSD special case
 568 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 569 then
 570   AS_MESSAGE(checking kerberosV for OpenBSD...)
 571   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 572   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 573   CFLAGS="$CFLAGS -I/usr/include/kerberosV"
 574   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 575 elif krb5-config 2> /dev/null >/dev/null ; then
 576   krb5_prefix=`krb5-config --prefix krb5`
 577   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 578   if test -f ${krb5_prefix}/include/et/com_err.h && \
 579    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 580     CFLAGS="$CFLAGS -I${krb5_prefix}/include/et"
 581   fi
 582   unset krb5_prefix
 583   CFLAGS="$CFLAGS `krb5-config --cflags krb5`"
 584   LIBS="$LIBS `krb5-config --libs krb5`"
 585   AC_DEFINE(KERBEROS_V5)
 586 else
 587   if test "$with_kerberos5" != "yes"
 588   then
 589       LDFLAGS="$LDFLAGS -L${with_kerberos5}/lib"
 590       searchdirs="$with_kerberos5"
 591   else
 592       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 593   fi
 594   with_kerberos5=
 595   for dir in $searchdirs
 596   do AC_MSG_CHECKING([for Kerberos V in $dir])
 597      if test -f "$dir/include/krb5.h" || test -f "$dir/include/krb5/krb5.h"
 598      then
 599         if test -d "$dir/include/krb5" ; then CPPFLAGS="$CPPFLAGS -I$dir/include/krb5" ; fi
 600         ac_krblibs=
 601         if test -f "$dir/include/roken.h" || test -f "$dir/include/krb5/roken.h"
 602         then
 603            ac_krblibs="-lasn1 -lroken -lcom_err"
 604            AC_MSG_RESULT([Heimdal found])
 605           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 606           dnl we assume we do if it is available
 607            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 608                 ${LDFLAGS})
 609            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 610               AC_CHECK_LIB(crypto, MD5_Init, [],
 611                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 612                 ${LDFLAGS} ${ac_krblibs}),
 613            ${LDFLAGS} ${ac_krblibs})
 614            AC_DEFINE(HEIMDAL)
 615         else
 616           AC_MSG_RESULT([found])
 617           ac_krblibs="-lcom_err"
 618            AC_CHECK_LIB(crypto,
 619              krb5_des_string_to_key,
 620              libk5crypto=-lcrypto,
 621                 AC_CHECK_LIB(k5crypto,
 622                    krb5_des_string_to_key,
 623                    libk5crypto=-lk5crypto,
 624                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 625                    ${LDFLAGS} ${ac_krblibs}),
 626                  ${LDFLAGS} ${ac_krblibs})
 627         fi
 628         AC_CHECK_LIB(krb5, krb5_init_context,[],
 629            continue,
 630            ${LDFLAGS} ${ac_krblibs})
 631         AC_DEFINE(KERBEROS_V5)
 632         test "$dir" != "/usr" && CFLAGS="$CFLAGS -I$dir/include"
 633         LDFLAGS="$LDFLAGS -L$dir/lib"
 634        LIBS="$LIBS $ac_krblibs $libk5crypto"
 635         with_kerberos5=$dir
 636         break
 637      else
 638         AC_MSG_RESULT([not found])
 639      fi
 640   done
 641   if test -z "$with_kerberos5" ; then
 642      AC_MSG_ERROR([Kerberos 5 libraries not found])
 643   fi
 644 fi
 645 fi
 646 ]) dnl --with-kerberos5=DIR
 647
 648 ###    use option --with-kerberos=DIR to point at a Kerberos 4 directory
 649 KERBEROS_V4=0
 650 AC_ARG_WITH(kerberos,
 651        [  --with-kerberos=DIR     point fetchmail compilation at a Kerberos 4 directory],
 652 [
 653 if test "$with_kerberos" != "no"
 654 then
 655     AC_MSG_WARN([Kerberos IV support is obsolete. Use --with-kerberos5 if possible.])
 656 # Check for a NetBSD/OpenBSD special case
 657 if test "$with_kerberos" = "yes" && ( test `uname` = "NetBSD" || test `uname` = "OpenBSD" )
 658 then
 659   AS_MESSAGE(checking kerberosIV for `uname`...)
 660   KERBEROS_V4=1
 661   CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 662   case `uname` in
 663       NetBSD)  LIBS="$LIBS -lkrb -ldes -lroken -lcom_err" ;;
 664       OpenBSD) LIBS="$LIBS -lkrb -ldes" ;;
 665   esac
 666 elif krb4-config 2> /dev/null >/dev/null ; then
 667   krb4_prefix=`krb4-config --prefix`
 668   AC_MSG_RESULT([krb4-config points to kerberosIV under $krb4_prefix])
 669   unset krb4_prefix
 670   CFLAGS="$CFLAGS `krb4-config --cflags`"
 671   LIBS="$LIBS `krb4-config --libs`"
 672   KERBEROS_V4=1
 673 elif krb5-config 2> /dev/null >/dev/null ; then
 674   krb4_prefix=`krb5-config --prefix krb4`
 675   AC_MSG_RESULT([krb5-config points to kerberosIV under $krb4_prefix])
 676   if test -f ${krb4_prefix}/include/kerberosIV/krb.h ; then
 677     AC_DEFINE(KERBEROS_V4_V5,1,Define if you have Kerberos V4 headers under a kerberosIV directory)
 678   fi
 679   unset krb4_prefix
 680   CFLAGS="$CFLAGS `krb5-config --cflags krb4`"
 681   LIBS="$LIBS `krb5-config --libs krb4`"
 682   KERBEROS_V4=1
 683 else
 684   #we need to detect when we're building under a kerberosV compatibility
 685   #layer, btw...
 686   if test "$with_kerberos" != "yes" ; then
 687      searchdirs="$with_kerberos"
 688   else
 689      searchdirs="$with_kerberos5 /usr/kerberos /usr/kerberosIV /usr/athena /usr"
 690   fi
 691   with_kerberos=
 692   ac_saveLDFLAGS="$LDFLAGS"
 693   for dir in $searchdirs
 694   do
 695      AC_MSG_CHECKING([for Kerberos IV in $dir])
 696      if test -f "$dir/include/krb.h" || test -f "$dir/include/krb4.h" \
 697             || test -f "$dir/include/kerberosIV/krb.h"
 698      then
 699         AC_MSG_RESULT([found])
 700      else
 701         AC_MSG_RESULT([not found])
 702        continue
 703      fi
 704      #Find libs
 705      if test -f "$with_kerberos5/roken.h" ; then
 706        AC_CHECK_LIB(45, krb_mk_req)
 707      fi
 708      LDFLAGS="-L$dir/lib $ac_saveLDFLAGS"
 709      if test `uname` = "FreeBSD"; then
 710         AC_SEARCH_LIBS(_ossl_old_des_string_to_key, [des425 des crypto], [], continue)
 711      else
 712         AC_SEARCH_LIBS(des_string_to_key, [crypto], [], continue)
 713      fi
 714      AC_SEARCH_LIBS(krb_realmofhost, [krb4 krb], [], continue)
 715      with_kerberos="$dir"
 716      if test -f "$dir/include/kerberosIV/krb.h" ; then
 717         dir="$dir/include/kerberosIV"
 718      else
 719        dir="$dir/include"
 720      fi
 721      KERBEROS_V4=1
 722      test -f "$with_kerberos5/roken.h" && AC_DEFINE(HEIMDAL)
 723      test "$dir" != "/usr/include" && CFLAGS="$CFLAGS -I$dir"
 724      LDFLAGS="$LDFLAGS -L$with_kerberos/lib"
 725      break
 726   done
 727   if test -z "$with_kerberos" ; then
 728      AC_MSG_ERROR([Kerberos 4 libraries not found])
 729   fi
 730   LDFLAGS="$ac_saveLDFLAGS"
 731 fi
 732 fi
 733 ]) dnl --with-kerberos=DIR
 734 if test "$KERBEROS_V4" = 1 ; then
 735     AC_DEFINE(KERBEROS_V4,1,Define if you have Kerberos V4)
 736 fi
 737 AM_CONDITIONAL(KERBEROS_V4_ENABLE, test "$KERBEROS_V4" = 1)
 738
 739 ###     use option --with-ssl to compile in the SSL support
 740 AC_ARG_WITH(ssl,
 741         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 742         [with_ssl=$withval],
 743         [with_ssl=no])
 744 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 745
 746 if test "$with_ssl" = "yes"
 747 then
 748     #   User didn't specify an SSL location.  Let's look at some common
 749     #   directories where SSL has been found in the past and try and auto
 750     #   configure for SSL.  OpenSSL determination will be made later.
 751     #   This will screw up if an OpenSSL install is located in a later
 752     #   directory than an older SSLeay install, but the user should fix that
 753     #   anyways and he can override on the configure line.
 754     #   Just testing for directories is not sufficient, /usr exists on
 755     #   all systems!
 756     for ac_dir in \
 757       /usr/local/ssl \
 758       /usr/local \
 759       /usr/ssl \
 760       /usr \
 761       /local/ssl \
 762       /opt/ssl \
 763       /opt/csw \
 764       ; \
 765     do
 766         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 767             with_ssl=$ac_dir
 768             break;
 769         fi
 770     done
 771 fi
 772
 773 if test -n "$with_ssl" -a "$with_ssl" != "no"
 774 then
 775   # With the autoconfigure above, the only time this is going to be
 776   # true is going to be when we could not find the headers.  If they
 777   # are not in system standard locations, we are going to be broken.
 778   if test "$with_ssl" = "yes"
 779   then
 780     # Let's just define the standard location for the SSLeay root
 781     with_ssl="/usr/local/ssl"
 782   fi
 783   if test -r $with_ssl/include/openssl/ssl.h
 784   then
 785     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 786     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 787     test "$with_ssl" != "/usr" && CFLAGS="$CFLAGS -I$with_ssl/include"
 788     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 789     ### force the Kerberos direcory onto the include path so it will build.
 790     CFLAGS="$CFLAGS -I/usr/kerberos/include"
 791     ### OpenBSD comes with ssl headers
 792   else
 793     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 794   fi
 795   LDFLAGS="$LDFLAGS -L$with_ssl/lib"
 796   LIBS="$LIBS -lssl -lcrypto"
 797   dnl check if -ldl is needed
 798   AC_MSG_CHECKING([for additional library dependencies of SSL])
 799   found=0
 800   save_LIBS="$LIBS"
 801   for i in "" "-ldl" ; do
 802       LIBS="$LDFLAGS $save_LIBS $i"
 803       AC_LINK_IFELSE([AC_LANG_PROGRAM(,[SSL_library_init()])],[found=1; break])
 804   done
 805   if test $found = 0 ; then
 806       AC_MSG_RESULT([error])
 807       AC_MSG_ERROR([cannot link with SSL - check config.log])
 808   fi
 809   LIBS="$save_LIBS $i"
 810   if test "$i" = "" ; then i="(none)" ; fi
 811   AC_MSG_RESULT($i)
 812   dnl XXX FIXME: use pkg-config if available!
 813   AC_DEFINE(SSL_ENABLE)
 814 else
 815   AC_MSG_NOTICE(Disabling SSL support.)
 816 fi
 817
 818 ###     use option --with-socks=DIR to point at SOCKS library
 819 AC_ARG_WITH(socks,
 820         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 821 [
 822 if test "$with_socks" != no
 823 then
 824     if test "$with_socks" != yes
 825     then
 826         LDFLAGS="$LDFLAGS -L$with_socks"
 827     else
 828         AC_CHECK_LIB(socks, Rconnect,,
 829                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 830     fi
 831     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 832     CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 833     LIBS="-lsocks $LIBS"
 834 fi])
 835
 836 ###     use option --with-socks5=DIR to point at SOCKS library
 837 AC_ARG_WITH(socks5,
 838         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 839 [
 840 if test "$with_socks5" != no
 841 then
 842   if test "$with_socks5" != yes
 843   then
 844     LDFLAGS="$LDFLAGS -L$with_socks5"
 845   fi
 846   ac_savedLDFLAGS="$LDFLAGS"
 847   LDFLAGS="$LDFLAGS $LDFLAGS"
 848   AC_CHECK_LIB(socks5, SOCKSconnect,,
 849         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 850   AC_DEFINE(HAVE_SOCKS)
 851   CFLAGS="$CFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 852   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 853   LDFLAGS="$ac_savedLDFLAGS"
 854 fi])
 855
 856 ACX_WHICH_GETHOSTBYNAME_R
 857
 858 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 859 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 860
 861 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 862 AC_ARG_WITH(gssapi,
 863         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 864 [
 865 if test "$with_gssapi" != "no"
 866 then
 867   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 868   then
 869     with_gssapi=$with_kerberos5
 870   fi
 871
 872   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 873   then
 874     CFLAGS="$CFLAGS -I$with_gssapi/include"
 875     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 876   fi
 877
 878   dnl obtain gssapi default libs
 879   if krb5-config --libs gssapi 2>/dev/null >/dev/null ; then
 880       LIBS="$LIBS `krb5-config --libs gssapi`"
 881   else
 882     AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 883     if test -n "$nogss"
 884     then
 885       # -lgss not found
 886       if test "$with_gssapi" = yes ; then
 887           with_gssapi=/usr
 888       fi
 889       if test -f "$with_gssapi/include/roken.h" -o -f "$with_gssapi/include/krb5/roken.h"
 890       then
 891          # have roken.h, assume Heimdal
 892          case `uname` in
 893              NetBSD) LIBS="$LIBS -lkrb5" ;;
 894              *)      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl" ;;
 895          esac
 896          AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 897                       AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 898          AC_DEFINE(HEIMDAL)
 899       else
 900          # no roken.h, assume MIT
 901          AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 902                       AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 903       fi
 904     fi
 905   fi
 906   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 907   if test "$with_gssapi" != yes ; then
 908     CPPFLAGS="$CPPFLAGS -I$with_gssapi/include"
 909   fi
 910   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 911   if test "$ac_cv_header_gssapi_h" = "yes"; then
 912     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 913   else
 914     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 915   fi
 916 fi])
 917
 918 dnl ,------------------------------------------------------------------
 919 dnl Check if we need TRIO
 920 needtrio=0
 921 if test "$FORCE_TRIO" = "yes" ; then
 922     needtrio=1
 923     ac_cv_func_vsnprintf=no
 924     ac_cv_func_snprintf=no
 925 fi
 926 if test "x$ac_cv_func_snprintf" != "xyes" ; then
 927     AC_DEFINE(snprintf, trio_snprintf,
 928               [Define to trio_snprintf if your system lacks snprintf])
 929     needtrio=1
 930 fi
 931 if test "x$ac_cv_func_vsnprintf" != "xyes" ; then
 932     AC_DEFINE(vsnprintf, trio_vsnprintf,
 933               [Define to trio_vsnprintf if your system lacks vsnprintf])
 934     needtrio=1
 935 fi
 936 AM_CONDITIONAL(NEED_TRIO, test "$needtrio" = 1)
 937
 938 dnl TRIO IEEE compiler option for Alpha
 939 dnl
 940 if test "$needtrio" = 1 ; then
 941     AC_MSG_CHECKING(for IEEE compilation options)
 942     AC_CACHE_VAL(ac_cv_ieee_option, [
 943     AC_TRY_COMPILE(,[
 944     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
 945     # error "Option needed"
 946     #endif
 947     ],ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
 948     AC_TRY_COMPILE(,[
 949     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
 950     # error "Option needed"
 951     #endif
 952     ],ac_cv_ieee_option="-ieee",
 953     AC_TRY_COMPILE(,[
 954     #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
 955     # error "Option needed"
 956     #endif
 957     ],ac_cv_ieee_option="-mieee",
 958     ac_cv_ieee_option="none"
 959     )
 960     )
 961     )
 962     ])
 963     AC_MSG_RESULT($ac_cv_ieee_option)
 964     if test $ac_cv_ieee_option != none; then
 965       CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
 966     fi
 967 fi
 968 dnl ----------------------------------------------------------------'
 969
 970 AC_CONFIG_FILES([Makefile po/Makefile.in genlsm.sh])
 971 AC_OUTPUT
 972
 973 dnl Local Variables:
 974 dnl comment-start: "dnl "
 975 dnl comment-end: ""
 976 dnl comment-start-skip: "\\bdnl\\b\\s *"
 977 dnl compile-command: "make configure config.h.in"
 978 dnl End: