Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [2])
  12 m4_define([gtk_minor_version], [99])
  13 m4_define([gtk_micro_version], [3])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Define a string for the earliest version that this release has
  32 # backwards binary compatibility with for all interfaces a module
  33 # might. Unless we add module-only API with lower stability
  34 # guarantees, this should be unchanged until we break binary compat
  35 # for GTK+.
  36 #
  37 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  38 m4_define([gtk_binary_version], [3.0.0])
  39
  40 # required versions of other packages
  41 m4_define([glib_required_version], [2.27.5])
  42 m4_define([pango_required_version], [1.20])
  43 m4_define([atk_required_version], [1.29.2])
  44 m4_define([cairo_required_version], [1.10.0])
  45 m4_define([gdk_pixbuf_required_version], [2.21.0])
  46 GLIB_REQUIRED_VERSION=glib_required_version
  47 PANGO_REQUIRED_VERSION=pango_required_version
  48 ATK_REQUIRED_VERSION=atk_required_version
  49 CAIRO_REQUIRED_VERSION=cairo_required_version
  50 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  51 AC_SUBST(GLIB_REQUIRED_VERSION)
  52 AC_SUBST(PANGO_REQUIRED_VERSION)
  53 AC_SUBST(ATK_REQUIRED_VERSION)
  54 AC_SUBST(CAIRO_REQUIRED_VERSION)
  55 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  56
  57
  58 # Save this value here, since automake will set cflags later
  59 cflags_set=${CFLAGS+set}
  60
  61 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  62 AM_MAINTAINER_MODE([enable])
  63
  64 # Support silent build rules, requires at least automake-1.11. Disable
  65 # by either passing --disable-silent-rules to configure or passing V=1
  66 # to make
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69 #
  70 # For each of the libraries we build, we define the following
  71 # substituted variables:
  72 #
  73 # foo_PACKAGES:     pkg-config packages this library requires
  74 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  75 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  76 # foo_DEP_LIBS:     All libraries this module requires
  77 # foo_DEP_CFLAGS:   All cflags this module requires
  78
  79
  80 GTK_MAJOR_VERSION=gtk_major_version
  81 GTK_MINOR_VERSION=gtk_minor_version
  82 GTK_MICRO_VERSION=gtk_micro_version
  83 GTK_INTERFACE_AGE=gtk_interface_age
  84 GTK_BINARY_AGE=gtk_binary_age
  85 GTK_VERSION=gtk_version
  86 GTK_API_VERSION=gtk_api_version
  87 GTK_BINARY_VERSION=gtk_binary_version
  88 AC_SUBST(GTK_MAJOR_VERSION)
  89 AC_SUBST(GTK_MINOR_VERSION)
  90 AC_SUBST(GTK_MICRO_VERSION)
  91 AC_SUBST(GTK_INTERFACE_AGE)
  92 AC_SUBST(GTK_BINARY_AGE)
  93 AC_SUBST(GTK_API_VERSION)
  94 AC_SUBST(GTK_VERSION)
  95 AC_SUBST(GTK_BINARY_VERSION)
  96
  97 # libtool versioning
  98 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  99 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 100 #LT_REVISION=$GTK_INTERFACE_AGE
 101 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 102 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 103
 104 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 105 m4_define([lt_revision], [gtk_interface_age])
 106 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 107 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 108 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 109 AC_SUBST(LT_VERSION_INFO)
 110 AC_SUBST(LT_CURRENT_MINUS_AGE)
 111
 112 m4_define([gail_lt_current],[0])
 113 m4_define([gail_lt_revision],[0])
 114 m4_define([gail_lt_age],[0])
 115 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 116 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 117 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 118 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 119
 120 # Checks for programs.
 121 AC_PROG_CC
 122 AC_PROG_CC_C_O
 123 AC_PROG_CC_STDC
 124 AC_PROG_INSTALL
 125 AC_PROG_MAKE_SET
 126
 127
 128 GETTEXT_PACKAGE=gtk30
 129 AC_SUBST(GETTEXT_PACKAGE)
 130 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 131                    [The prefix for our gettext translation domains.])
 132
 133 AC_CANONICAL_HOST
 134
 135 MATH_LIB=-lm
 136 AC_MSG_CHECKING([for native Win32])
 137 LIB_EXE_MACHINE_FLAG=X86
 138 EXE_MANIFEST_ARCHITECTURE=X86
 139 case "$host" in
 140   *-*-mingw*)
 141     os_win32=yes
 142     gio_can_sniff=no
 143     MATH_LIB=
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       EXE_MANIFEST_ARCHITECTURE=AMD64
 148       ;;
 149     esac
 150     ;;
 151   *)
 152     os_win32=no
 153     ;;
 154 esac
 155 AC_MSG_RESULT([$os_win32])
 156
 157 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 158 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 159
 160 case $host in
 161   *-*-linux*)
 162     os_linux=yes
 163     ;;
 164 esac
 165
 166 dnl
 167 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 168 dnl We use this for an automated test for C++ header correctness.
 169 dnl
 170 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 171 AC_LANG_PUSH([C++])
 172
 173 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 174 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 175
 176 gtk_save_cxxflags="$CXXFLAGS"
 177 CXXFLAGS="$CXXFLAGS -x objective-c++"
 178 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 179 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 180 CXXFLAGS="$gtk_save_cxxflags"
 181 AC_LANG_POP([C++])
 182
 183 if test "$os_win32" = "yes"; then
 184   if test x$enable_static = xyes -o x$enable_static = x; then
 185     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 186     enable_static=no
 187   fi
 188   if test x$enable_shared = xno; then
 189     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 190   fi
 191   enable_shared=yes
 192 fi
 193
 194 dnl Initialize libtool
 195 LT_PREREQ([2.2.6])
 196 LT_INIT([disable-static win32-dll])
 197 # Create libtool early, because it's used in configure
 198 LT_OUTPUT
 199
 200 # Make sure we use 64-bit versions of various file stuff.
 201 AC_SYS_LARGEFILE
 202
 203 AM_PROG_AS
 204 AC_PATH_PROG(NM, nm, nm)
 205
 206 AC_MSG_CHECKING([for some Win32 platform])
 207 case "$host" in
 208   *-*-mingw*|*-*-cygwin*)
 209     platform_win32=yes
 210     ;;
 211   *)
 212     platform_win32=no
 213     ;;
 214 esac
 215 AC_MSG_RESULT([$platform_win32])
 216 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 217
 218 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 219 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 220 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 221
 222 if test "$os_win32" = "yes"; then
 223   AC_CHECK_TOOL(WINDRES, windres, no)
 224   if test "$WINDRES" = no; then
 225     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 226   fi
 227   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 228 fi
 229 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 230
 231 m4_define([debug_default],
 232           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 233
 234 dnl declare --enable-* args and collect ac_help strings
 235 AC_ARG_ENABLE(debug,
 236               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 237                              [turn on debugging @<:@default=debug_default@:>@]),,
 238               enable_debug=debug_default)
 239
 240 AC_ARG_ENABLE(rebuilds,
 241               [AC_HELP_STRING([--disable-rebuilds],
 242                               [disable all source autogeneration rules])],,
 243               [enable_rebuilds=yes])
 244
 245 AC_ARG_ENABLE(gtk2-dependency,
 246               AC_HELP_STRING([--enable-gtk2-dependency],
 247                              [Do not build gtk-update-icon-cache and other shared tools]),,
 248               [enable_gtk2_dependency=no])
 249
 250 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 251
 252 AC_ARG_ENABLE(xkb,
 253               [AC_HELP_STRING([--enable-xkb],
 254                               [support XKB extension [default=maybe]])],,
 255               [enable_xkb="maybe"])
 256 AC_ARG_ENABLE(xinerama,
 257               [AC_HELP_STRING([--enable-xinerama],
 258                               [support Xinerama extension if available [default=maybe]])],,
 259               [enable_xinerama="maybe"])
 260 AC_ARG_ENABLE(xinput,
 261               [AC_HELP_STRING([--enable-xinput],
 262                               [support XInput extension if available [default=yes]])],,
 263               [enable_xinput="maybe"])
 264 AC_ARG_ENABLE(xrandr,
 265               [AC_HELP_STRING([--enable-xrandr],
 266                               [support XRandR extension if available [default=maybe]])],,
 267               [enable_xrandr="maybe"])
 268 AC_ARG_ENABLE(xfixes,
 269               [AC_HELP_STRING([--enable-xfixes],
 270                               [support XFixes extension if available [default=maybe]])],,
 271               [enable_xfixes="maybe"])
 272 AC_ARG_ENABLE(xcomposite,
 273               [AC_HELP_STRING([--enable-xcomposite],
 274                               [support X Composite extension if available [default=maybe]])],,
 275               [enable_xcomposite="maybe"])
 276 AC_ARG_ENABLE(xdamage,
 277               [AC_HELP_STRING([--enable-xdamage],
 278                               [support X Damage extension if available [default=maybe]])],,
 279               [enable_xdamage="maybe"])
 280
 281 AC_ARG_ENABLE(x11-backend,
 282               [AC_HELP_STRING([--enable-x11-backend],
 283                               [enable the X11 gdk backend])],
 284                               [backend_set=yes])
 285 AC_ARG_ENABLE(win32-backend,
 286               [AC_HELP_STRING([--enable-win32-backend],
 287                               [enable the Win32 gdk backend])],
 288                               [backend_set=yes])
 289 AC_ARG_ENABLE(quartz-backend,
 290               [AC_HELP_STRING([--enable-quartz-backend],
 291                               [enable the quartz gdk backend])],
 292                               [backend_set=yes])
 293 AC_ARG_ENABLE(broadway-backend,
 294               [AC_HELP_STRING([--enable-broadway-backend],
 295                               [enable the broadway (HTML5) gdk backend])],
 296                               [backend_set=yes])
 297
 298 if test -z "$backend_set"; then
 299   if test "$platform_win32" = yes; then
 300     enable_win32_backend=yes
 301   else
 302     enable_x11_backend=yes
 303   fi
 304 fi
 305
 306 cairo_backends=
 307 backend_immodules=
 308 GDK_BACKENDS=
 309 GDK_EXTRA_LIBS=
 310 GDK_EXTRA_CFLAGS=
 311 GDK_WINDOWING=
 312 GIO_PACKAGE=gio-2.0
 313 PANGO_PACKAGES="pango pangocairo"
 314
 315 if test "x$enable_x11_backend" == xyes; then
 316   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 317   # backend names are identical.
 318   cairo_backends="$cairo_backends cairo-xlib"
 319   GDK_BACKENDS="$GDK_BACKENDS x11"
 320   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 321   # gdkapplaunchcontext-x11.c
 322   GIO_PACKAGE=gio-unix-2.0
 323   backend_immodules="$backend_immodules,xim"
 324   GDK_WINDOWING="$GDK_WINDOWING
 325 #define GDK_WINDOWING_X11"
 326 fi
 327
 328 if test "x$enable_win32_backend" == xyes; then
 329   cairo_backends="$cairo_backends cairo-win32"
 330   GDK_BACKENDS="$GDK_BACKENDS win32"
 331   backend_immodules="$backend_immodules,ime"
 332   GDK_WINDOWING="$GDK_WINDOWING
 333 #define GDK_NATIVE_WINDOW_POINTER
 334 #define GDK_WINDOWING_WIN32"
 335   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 336   AM_CONDITIONAL(USE_WIN32, true)
 337   PANGO_PACKAGES="pangowin32 pangocairo"
 338 else
 339   AM_CONDITIONAL(USE_WIN32, false)
 340 fi
 341
 342 if test "x$enable_quartz_backend" == xyes; then
 343   cairo_backends="$cairo_backends cairo-quartz"
 344   GDK_BACKENDS="$GDK_BACKENDS quartz"
 345   GDK_WINDOWING="$GDK_WINDOWING
 346 #define GDK_WINDOWING_QUARTZ"
 347   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 348   AM_CONDITIONAL(USE_QUARTZ, true)
 349 else
 350   AM_CONDITIONAL(USE_QUARTZ, false)
 351 fi
 352
 353 if test "x$enable_broadway_backend" == xyes; then
 354   GDK_BACKENDS="$GDK_BACKENDS broadway"
 355   cairo_backends="$cairo_backends cairo"
 356   GDK_WINDOWING="$GDK_WINDOWING
 357 #define GDK_WINDOWING_BROADWAY"
 358   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 359   AM_CONDITIONAL(USE_BROADWAY, true)
 360 else
 361   AM_CONDITIONAL(USE_BROADWAY, false)
 362 fi
 363
 364 # strip leading space
 365 GDK_BACKENDS=${GDK_BACKENDS/# }
 366
 367 AC_SUBST(GDK_BACKENDS)
 368
 369 if test -z "$GDK_BACKENDS"; then
 370   AC_MSG_ERROR([No GDK backends selected.])
 371 fi
 372
 373 if test "x$enable_debug" = "xyes"; then
 374   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 375   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 376 else
 377   if test "x$enable_debug" = "xno"; then
 378     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 379   else
 380     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 381   fi
 382 fi
 383
 384
 385 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 386                    [Define if debugging is enabled])
 387
 388
 389 # Build time sanity check...
 390 AM_SANITY_CHECK
 391
 392 changequote(,)dnl
 393 if test "x$GCC" = "xyes"; then
 394   case " $CFLAGS " in
 395   *[\ \ ]-Wall[\ \      ]*) ;;
 396   *) CFLAGS="$CFLAGS -Wall" ;;
 397   esac
 398
 399   if test "x$enable_ansi" = "xyes"; then
 400     case " $CFLAGS " in
 401     *[\ \       ]-ansi[\ \      ]*) ;;
 402     *) CFLAGS="$CFLAGS -ansi" ;;
 403     esac
 404
 405     case " $CFLAGS " in
 406     *[\ \       ]-pedantic[\ \  ]*) ;;
 407     *) CFLAGS="$CFLAGS -pedantic" ;;
 408     esac
 409   fi
 410 fi
 411 changequote([,])dnl
 412
 413 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 414
 415 # Ensure MSVC-compatible struct packing convention is used when
 416 # compiling for Win32 with gcc.
 417 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 418 # gcc2 uses "-fnative-struct".
 419 if test x"$os_win32" = xyes; then
 420   if test x"$GCC" = xyes; then
 421     msnative_struct=''
 422     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 423     if test -z "$ac_cv_prog_CC"; then
 424       our_gcc="$CC"
 425     else
 426       our_gcc="$ac_cv_prog_CC"
 427     fi
 428     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 429       2.)
 430         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 431           msnative_struct='-fnative-struct'
 432         fi
 433         ;;
 434       *)
 435         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 436           msnative_struct='-mms-bitfields'
 437         fi
 438         ;;
 439     esac
 440     if test x"$msnative_struct" = x ; then
 441       AC_MSG_RESULT([no way])
 442       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 443     else
 444       CFLAGS="$CFLAGS $msnative_struct"
 445       AC_MSG_RESULT([${msnative_struct}])
 446     fi
 447   fi
 448 fi
 449
 450 ## Initial sanity check, done here so that users get told they
 451 ## have the wrong dependencies as early in the process as possible.
 452 ## Later on we actually use the cflags/libs from separate pkg-config
 453 ## calls. Oh, also the later pkg-config calls don't include
 454 ## the version requirements since those make the module lists
 455 ## annoying to construct
 456 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 457   [glib-2.0 >= glib_required_version dnl
 458    atk >= atk_required_version dnl
 459    pango >= pango_required_version dnl
 460    cairo >= cairo_required_version dnl
 461    cairo-gobject >= cairo_required_version dnl
 462    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 463
 464 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 465
 466 if test "$os_win32" != yes; then
 467     # libtool option to control which symbols are exported
 468     # right now, symbols starting with _ are not exported
 469     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 470 else
 471     # We currently use .def files on Windows (for gdk and gtk)
 472     LIBTOOL_EXPORT_OPTIONS=
 473 fi
 474 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 475
 476 dnl ******************************************************
 477 dnl * See whether to include shared library dependencies *
 478 dnl ******************************************************
 479
 480 AC_ARG_ENABLE(explicit-deps,
 481               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 482                               [use explicit dependencies in .pc files [default=auto]])],,
 483               [enable_explicit_deps=auto])
 484
 485 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 486 case $enable_explicit_deps in
 487   auto)
 488     export SED
 489     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 490     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 491       enable_explicit_deps=yes
 492     else
 493       enable_explicit_deps=no
 494     fi
 495   ;;
 496   yes|no)
 497   ;;
 498   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 499   ;;
 500 esac
 501 AC_MSG_RESULT($enable_explicit_deps)
 502
 503 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 504
 505 # define a MAINT-like variable REBUILD which is set if Perl
 506 # and awk are found, so autogenerated sources can be rebuilt
 507
 508 AC_PATH_PROGS(PERL, perl5 perl)
 509
 510 # We would like indent, but don't require it.
 511 AC_CHECK_PROG(INDENT, indent, indent)
 512
 513 REBUILD=\#
 514 if test "x$enable_rebuilds" = "xyes" && \
 515      test -n "$PERL" && \
 516      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 517   REBUILD=
 518 fi
 519 AC_SUBST(REBUILD)
 520
 521 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 522 AC_CHECK_FUNCS(localtime_r)
 523
 524 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 525 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 526 AC_TRY_LINK([#include <langinfo.h>], [
 527 char c;
 528 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 529 ], gtk_ok=yes, gtk_ok=no)
 530 AC_MSG_RESULT($gtk_ok)
 531 if test "$gtk_ok" = "yes"; then
 532   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 533             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 534 fi
 535
 536 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 537 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 538 AC_TRY_LINK([#include <langinfo.h>], [
 539 char c;
 540 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 541 ], gtk_ok=yes, gtk_ok=no)
 542 AC_MSG_RESULT($gtk_ok)
 543 if test "$gtk_ok" = "yes"; then
 544   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 545             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 546 fi
 547
 548 # _NL_PAPER_HEIGHT is an enum and not a define
 549 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 550 AC_TRY_LINK([#include <langinfo.h>], [
 551 char c;
 552 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 553 ], gtk_ok=yes, gtk_ok=no)
 554 AC_MSG_RESULT($gtk_ok)
 555 if test "$gtk_ok" = "yes"; then
 556   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 557             [Define if _NL_PAPER_HEIGHT is available])
 558 fi
 559
 560 # _NL_PAPER_WIDTH is an enum and not a define
 561 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 562 AC_TRY_LINK([#include <langinfo.h>], [
 563 char c;
 564 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 565 ], gtk_ok=yes, gtk_ok=no)
 566 AC_MSG_RESULT($gtk_ok)
 567 if test "$gtk_ok" = "yes"; then
 568   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 569             [Define if _NL_PAPER_WIDTH is available])
 570 fi
 571
 572 # i18n stuff
 573 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 574 AM_GLIB_GNU_GETTEXT
 575 LIBS="$LIBS $INTLLIBS"
 576 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 577         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 578       esac])
 579
 580 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 581 dnl po-properties/POTFILES during configure; see GNOME #573515.
 582 dnl
 583 dnl Generate list of files to be processed by xgettext which will
 584 dnl be included in po-properties/Makefile.
 585 test -d po-properties || mkdir po-properties
 586 if test "x$srcdir" != "x."; then
 587   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 588     popropsrcprefix="$srcdir/"
 589   else
 590     popropsrcprefix="../$srcdir/"
 591   fi
 592 else
 593   popropsrcprefix="../"
 594 fi
 595 rm -f po-properties/POTFILES
 596 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 597 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 598 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 599
 600 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 601
 602 dnl The DU4 header files don't provide library prototypes unless
 603 dnl -std1 is given to the native cc.
 604 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 605
 606 gtk_save_LIBS=$LIBS
 607 LIBS="$LIBS -lm"
 608 AC_TRY_RUN([#include <math.h>
 609              int main (void) { return (log(1) != log(1.)); }],
 610      AC_MSG_RESULT(none needed),
 611      gtk_save_CFLAGS="$CFLAGS"
 612      CFLAGS="$CFLAGS -std1"
 613      AC_TRY_RUN([#include <math.h>
 614                  int main (void) { return (log(1) != log(1.)); }],
 615          AC_MSG_RESULT(-std1),
 616          AC_MSG_RESULT()
 617          CFLAGS="$gtk_save_CFLAGS"
 618          AC_MSG_WARN(
 619                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 620          true
 621      ),
 622      AC_MSG_RESULT(none needed)
 623 )
 624 LIBS=$gtk_save_LIBS
 625
 626 AC_MSG_CHECKING(for the BeOS)
 627 case $host in
 628   *-*-beos*)
 629     AC_MSG_RESULT(yes)
 630     MATH_LIB=
 631   ;;
 632   *)
 633     AC_MSG_RESULT(no)
 634   ;;
 635 esac
 636
 637 AC_SUBST(MATH_LIB)
 638 #
 639 # see bug 162979
 640 #
 641 AC_MSG_CHECKING(for HP-UX)
 642 case $host_os in
 643   hpux9* | hpux10* | hpux11*)
 644     AC_MSG_RESULT(yes)
 645     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 646   ;;
 647   *)
 648     AC_MSG_RESULT(no)
 649   ;;
 650 esac
 651
 652 dnl NeXTStep cc seems to need this
 653 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 654 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 655   AC_MSG_RESULT(none needed),
 656   gtk_save_CFLAGS="$CFLAGS"
 657   CFLAGS="$CFLAGS -posix"
 658   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 659     AC_MSG_RESULT(-posix),
 660     AC_MSG_RESULT()
 661     CFLAGS="$gtk_save_CFLAGS"
 662     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 663
 664 #
 665 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 666 #
 667
 668 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 669
 670 AM_PATH_GLIB_2_0(glib_required_version, :,
 671   AC_MSG_ERROR([
 672 *** GLIB glib_required_version or better is required. The latest version of
 673 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 674   gobject gmodule-no-export gthread)
 675
 676 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 677 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 678 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 679 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 680   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 681 fi
 682
 683 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 684
 685
 686 dnl
 687 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 688 dnl
 689 gtk_save_LIBS=$LIBS
 690 LIBS="$LIBS $GLIB_LIBS"
 691 AC_CHECK_FUNCS(bind_textdomain_codeset)
 692 LIBS=$gtk_save_LIBS
 693
 694 AC_CHECK_HEADERS(pwd.h,
 695                  AC_DEFINE(HAVE_PWD_H, 1,
 696                            [Define to 1 if pwd.h is available]))
 697 AC_CHECK_HEADERS(sys/time.h,
 698                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 699                            [Define to 1 if time.h is available]))
 700 AC_CHECK_HEADERS(unistd.h,
 701                  AC_DEFINE(HAVE_UNISTD_H, 1,
 702                            [Define to 1 if unistd.h is available]))
 703 AC_CHECK_HEADERS(ftw.h,
 704                  AC_DEFINE(HAVE_FTW_H, 1,
 705                            [Define to 1 if ftw.h is available]))
 706
 707 AC_MSG_CHECKING([for GNU ftw extensions])
 708 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 709 #define _GNU_SOURCE
 710 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 711 if test $gtk_ok = yes; then
 712     AC_MSG_RESULT([yes])
 713     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 714 else
 715     AC_MSG_RESULT([no])
 716 fi
 717
 718 saved_cflags="$CFLAGS"
 719 saved_ldflags="$LDFLAGS"
 720
 721
 722 # Checks for header files.
 723 AC_HEADER_STDC
 724
 725 # Checks for typedefs, structures, and compiler characteristics.
 726 AC_C_CONST
 727
 728 # Checks for library functions.
 729 AC_TYPE_SIGNAL
 730 AC_FUNC_MMAP
 731
 732 AC_CHECK_FUNCS(mallinfo)
 733 AC_CHECK_FUNCS(getresuid)
 734 AC_TYPE_UID_T
 735
 736 # Check if <sys/select.h> needs to be included for fd_set
 737 AC_MSG_CHECKING([for fd_set])
 738 AC_TRY_COMPILE([#include <sys/types.h>],
 739         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 740 if test $gtk_ok = yes; then
 741     AC_MSG_RESULT([yes, found in sys/types.h])
 742 else
 743     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 744     if test $gtk_ok = yes; then
 745         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 746                   [Define to 1 if sys/select.h is available])
 747         AC_MSG_RESULT([yes, found in sys/select.h])
 748     else
 749         AC_DEFINE(NO_FD_SET, 1,
 750                   [Define to 1 if fd_set is not available])
 751         AC_MSG_RESULT(no)
 752     fi
 753 fi
 754
 755 # Check for uxtheme.h (for MS-Windows Engine)
 756 AC_MSG_CHECKING(for uxtheme.h)
 757 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 758 if test $gtk_uxtheme_h = yes; then
 759    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 760 fi
 761 AC_MSG_RESULT($gtk_uxtheme_h)
 762
 763 # Checks for gdkspawn
 764 AC_CHECK_HEADERS(crt_externs.h)
 765 AC_CHECK_FUNCS(_NSGetEnviron)
 766
 767 AC_MSG_CHECKING(whether to build dynamic modules)
 768
 769 AC_ARG_ENABLE(modules,
 770               [AC_HELP_STRING([--disable-modules],
 771                               [disable dynamic module loading])])
 772
 773 dynworks=false
 774 build_dynamic_modules=no
 775 deps=
 776 if test x$enable_modules = xno; then
 777     AC_MSG_RESULT(no)
 778 else
 779     AC_MSG_RESULT(yes)
 780     AC_MSG_CHECKING(whether dynamic modules work)
 781     ## for loop is to strip newline
 782     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 783     for I in $tmp; do
 784         dynworks=$I
 785     done
 786
 787     dnl Now we check to see if our libtool supports shared lib deps
 788     dnl (in a rather ugly way even)
 789     if $dynworks; then
 790         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 791         module_deplibs_check=`$module_libtool_config | \
 792             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 793             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 794         if test "x$module_deplibs_check" = "xnone" || \
 795            test "x$module_deplibs_check" = "xunknown" || \
 796            test "x$module_deplibs_check" = "x"; then
 797             dynworks=false
 798         fi
 799     fi
 800
 801     if $dynworks; then
 802         build_dynamic_modules=yes
 803         AC_DEFINE(USE_GMODULE, 1,
 804                   [Define to 1 if gmodule works and should be used])
 805         AC_MSG_RESULT(yes)
 806     else
 807         build_dynamic_modules=no
 808         AC_MSG_RESULT(no)
 809     fi
 810 fi
 811
 812 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 813
 814 #
 815 # Allow building some or all immodules included
 816 #
 817 AC_MSG_CHECKING(immodules to build)
 818
 819 dnl due to an autoconf bug, commas in the first arg to
 820 dnl AC_HELP_STRING cause problems.
 821 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
 822 dnl                [build the specified input method modules into gtk])
 823 AC_ARG_WITH(included_immodules,
 824             AC_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 825                            [build the specified input methods into gtk]))
 826
 827 if $dynworks; then
 828    :
 829 else
 830    ## if the option was specified, leave it; otherwise disable included immodules
 831    if test x$with_included_immodules = xno; then
 832            with_included_immodules=yes
 833    fi
 834 fi
 835
 836 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 837
 838 included_immodules=""
 839 # If the switch specified without listing any specific ones, include all
 840 if test "x$with_included_immodules" = xyes ; then
 841   included_immodules="$all_immodules"
 842 else
 843   included_immodules="$with_included_immodules"
 844 fi
 845
 846 AC_MSG_RESULT($included_immodules)
 847 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 848
 849 INCLUDED_IMMODULE_OBJ=
 850 INCLUDED_IMMODULE_DEFINE=
 851
 852 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 853 for immodule in $included_immodules; do
 854  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 855  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 856    :
 857  else
 858    AC_MSG_ERROR([the specified input method $immodule does not exist])
 859  fi
 860
 861  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 862  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 863  eval INCLUDE_$immodule_underscores=yes
 864 done
 865 IFS="$gtk_save_ifs"
 866 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 867 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 868
 869 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 870 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 871 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 872 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 873 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 874 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 875 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 876 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 877 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 878 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 879 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 880 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 881
 882 AC_HEADER_SYS_WAIT
 883
 884 AC_TYPE_SIGNAL
 885
 886 # Checks to see whether we should include mediaLib
 887 # support.
 888 #
 889 AC_CHECK_HEADER(sys/systeminfo.h,
 890                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 891                           [Define to 1 if sys/systeminfo.h is available]))
 892 AC_CHECK_HEADER(sys/sysinfo.h,
 893                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 894                           [Define to 1 if sys/sysinfo.h is available]))
 895
 896 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 897
 898 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 899
 900 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 901   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 902   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 903     REBUILD_PNGS=#
 904   fi
 905 fi
 906
 907 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 908
 909 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 910
 911 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 912    test "x$REBUILD_PNGS" = "x#" ; then
 913      AC_MSG_ERROR([
 914 *** gtkbuiltincache.h is not in the tree, and cannot be built
 915 *** because you don't have libpng, or (when cross-compiling) you
 916 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 917 fi
 918
 919 ########################################
 920 # Windowing system checks
 921 ########################################
 922
 923 # GTK+ uses some X calls, so needs to link against X directly
 924 GTK_DEP_PACKAGES_FOR_X=
 925 GTK_DEP_LIBS_FOR_X=
 926 X_EXTENSIONS=
 927
 928 if test "x$enable_x11_backend" == xyes; then
 929   X_PACKAGES=fontconfig
 930
 931   #
 932   # We use fontconfig very peripherally when decoding the default
 933   # settings.
 934   #
 935   if $PKG_CONFIG --exists fontconfig; then : ; else
 936     AC_MSG_ERROR([
 937 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 938   fi
 939
 940   #
 941   # Check for basic X packages; we use pkg-config if available
 942   #
 943   if $PKG_CONFIG --exists x11 xext; then
 944     have_base_x_pc=true
 945     X_PACKAGES="$X_PACKAGES x11 xext"
 946     x_libs="`$PKG_CONFIG --libs x11 xext`"
 947     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 948
 949     # Strip out any .la files that pkg-config might give us (this happens
 950     # with -uninstalled.pc files)
 951     x_libs_for_checks=
 952     for I in $x_libs ; do
 953       case $I in
 954         *.la) ;;
 955         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 956       esac
 957     done
 958
 959     GTK_PACKAGES_FOR_X="x11"
 960   else
 961     have_base_x_pc=false
 962     AC_PATH_XTRA
 963     if test x$no_x = xyes ; then
 964       AC_MSG_ERROR([X development libraries not found])
 965     fi
 966
 967     x_cflags="$X_CFLAGS"
 968     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 969
 970     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 971   fi
 972
 973   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 974   x_extra_libs=
 975
 976   gtk_save_cppflags="$CPPFLAGS"
 977   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 978
 979   gtk_save_LIBS=$LIBS
 980   LIBS="$x_libs_for_checks $LIBS"
 981
 982   # Sanity check for the X11 and Xext libraries. While everything we need from
 983   # Xext is optional, the chances a system has *none* of these things is so
 984   # small that we just unconditionally require it.
 985   AC_CHECK_FUNC(XOpenDisplay, :,
 986                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 987   AC_CHECK_FUNC(XextFindDisplay, :,
 988                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 989
 990   # Check for xReply
 991
 992   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 993   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
 994       [xReply *rep;],
 995       [AC_MSG_RESULT([no])],
 996       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
 997 #include <X11/Xlibint.h>],
 998            [xReply *rep;],
 999            [AC_MSG_RESULT([yes])
1000             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
1001                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
1002            [AC_MSG_RESULT([unknown])
1003             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1004
1005   # Check for XConvertCase, XInternAtoms (X11R6 specific)
1006
1007   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
1008
1009   # Generic X11R6 check needed for XIM support; we could
1010   # probably use this to replace the above, but we'll
1011   # leave the separate checks for XConvertCase and XInternAtoms
1012   # for clarity
1013
1014   have_x11r6=false
1015   AC_CHECK_FUNC(XAddConnectionWatch,
1016       have_x11r6=true)
1017
1018   if $have_x11r6; then
1019     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1020   fi
1021   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1022
1023   # Check for XKB support.
1024
1025   if test "x$enable_xkb" = "xyes"; then
1026         AC_CHECK_FUNC(XkbQueryExtension,
1027                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1028                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1029                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1030   elif test "x$enable_xkb" = "xmaybe"; then
1031         AC_CHECK_FUNC(XkbQueryExtension,
1032                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1033                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1034   else
1035         AC_MSG_WARN(XKB support explicitly disabled)
1036   fi
1037
1038   # Check for shaped window extension
1039
1040   AC_CHECK_FUNC(XShapeCombineMask, :,
1041      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1042
1043   # X SYNC check
1044   gtk_save_CFLAGS="$CFLAGS"
1045   CFLAGS="$CFLAGS $x_cflags"
1046
1047   AC_CHECK_FUNC(XSyncQueryExtension,
1048       [AC_CHECK_HEADER(X11/extensions/sync.h,
1049           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1050           :, [#include <X11/Xlib.h>])])
1051
1052   CFLAGS="$gtk_save_CFLAGS"
1053
1054   if test "x$enable_xinerama" != "xno"; then
1055     # Check for Xinerama extension (Solaris impl or Xfree impl)
1056     have_xfree_xinerama=false
1057     have_solaris_xinerama=false
1058
1059     gtk_save_cppflags="$CPPFLAGS"
1060     CPPFLAGS="$CPPFLAGS $x_cflags"
1061
1062     # Check for XFree
1063     AC_MSG_CHECKING(for Xinerama packages)
1064
1065     if $PKG_CONFIG --exists xinerama ; then
1066        AC_MSG_RESULT(yes)
1067        have_xfree_xinerama=true
1068        X_PACKAGES="$X_PACKAGES xinerama"
1069     else
1070        AC_MSG_RESULT(no)
1071        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1072            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1073            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1074            have_xfree_xinerama=true], :,
1075            [#include <X11/Xlib.h>])])
1076     fi
1077
1078     if $have_xfree_xinerama ; then
1079       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1080       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1081                 [Define to 1 if XFree Xinerama is available])
1082       AC_DEFINE(HAVE_XINERAMA, 1,
1083                 [Define to 1 is Xinerama is available])
1084     else
1085       case "$host" in
1086         *-*-solaris*)
1087             # Check for solaris
1088             AC_MSG_CHECKING(for Xinerama support on Solaris)
1089
1090             have_solaris_xinerama=false
1091             AC_CHECK_FUNC(XineramaGetInfo,
1092                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1093                     [have_solaris_xinerama=true], :,
1094                     [#include <X11/Xlib.h>])])
1095
1096             if $have_solaris_xinerama ; then
1097               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1098               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1099                         [Define to 1 if solaris xinerama is available])
1100               AC_DEFINE(HAVE_XINERAMA, 1,
1101                         [Define to 1 if xinerama is available])
1102               AC_MSG_RESULT(yes)
1103             else
1104               AC_MSG_RESULT(no)
1105             fi
1106             ;;
1107         *)
1108             ;;
1109       esac
1110     fi
1111   fi
1112   if test "x$enable_xinerama" = "xyes" ; then
1113     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1114       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1115     fi
1116   fi
1117
1118   # set up things for XInput
1119   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1120     have_xinput=yes
1121
1122     AC_DEFINE(XINPUT_XFREE, 1,
1123               [Define to 1 if XFree XInput should be used])
1124
1125     X_PACKAGES="$X_PACKAGES xi"
1126
1127     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1128                     have_xinput2=yes
1129                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1130                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]),
1131                     X_EXTENSIONS="$X_EXTENSIONS XInput")
1132
1133   else
1134     AC_DEFINE(XINPUT_NONE, 1,
1135               [Define to 1 if no XInput should be used])
1136   fi
1137
1138   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1139   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1140
1141   if test "x$enable_xinput" = "xyes" ; then
1142     if test "x$have_xinput" != "xyes" -a "x$have_xinput2" != "xyes" ; then
1143       AC_MSG_ERROR([*** XInput extension not found. Check 'config.log' for more details.])
1144     fi
1145   fi
1146
1147   # Check for the RANDR extension
1148   if test x"$enable_xrandr" != xno; then
1149     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1150       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1151
1152       X_PACKAGES="$X_PACKAGES xrandr"
1153       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1154     elif test x"$enable_xrandr" = xyes; then
1155       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1156     fi
1157   fi
1158
1159   # Checks for Xcursor library
1160
1161   if $PKG_CONFIG --exists xcursor ; then
1162     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1163
1164     X_PACKAGES="$X_PACKAGES xcursor"
1165   fi
1166
1167   # Checks for XFixes extension
1168
1169   if test x"$enable_xfixes" != xno; then
1170     if $PKG_CONFIG --exists xfixes ; then
1171       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1172
1173       X_PACKAGES="$X_PACKAGES xfixes"
1174       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1175       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1176     elif test x"$enable_xfixes" = xyes; then
1177       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1178     fi
1179   fi
1180
1181   # Checks for Xcomposite extension
1182
1183   if test x"$enable_xcomposite" != xno; then
1184     if $PKG_CONFIG --exists xcomposite ; then
1185       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1186
1187       X_PACKAGES="$X_PACKAGES xcomposite"
1188       X_EXTENSIONS="$X_EXTENSIONS Composite"
1189       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1190     elif test x"$enable_xcomposite" = xyes; then
1191       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1192     fi
1193   fi
1194
1195   # Checks for Xdamage extension
1196
1197   if test x"$enable_xdamage" != xno; then
1198     if $PKG_CONFIG --exists xdamage ; then
1199       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1200
1201       X_PACKAGES="$X_PACKAGES xdamage"
1202       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1203       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1204     elif test x"$enable_xdamage" = xyes; then
1205       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1206     fi
1207   fi
1208
1209   if $have_base_x_pc ; then
1210     GDK_EXTRA_LIBS="$x_extra_libs"
1211   else
1212     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1213   fi
1214
1215   CPPFLAGS="$gtk_save_cppflags"
1216   LIBS="$gtk_save_libs"
1217
1218   AM_CONDITIONAL(USE_X11, true)
1219
1220   # strip leading space
1221   X_EXTENSIONS=${X_EXTENSIONS/# }
1222
1223 else
1224   XPACKAGES=
1225
1226   AM_CONDITIONAL(XINPUT_XFREE, false)
1227   AM_CONDITIONAL(XINPUT_2, false)
1228   AM_CONDITIONAL(USE_X11, false)
1229   AM_CONDITIONAL(HAVE_X11R6, false)
1230 fi
1231
1232 # Check for Pango flags
1233
1234 AC_MSG_CHECKING(Pango flags)
1235 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1236         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1237         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1238
1239         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1240 else
1241         AC_MSG_ERROR([
1242 *** Pango not found. Pango built with Cairo support is required
1243 *** to build GTK+. See http://www.pango.org for Pango information.
1244 ])
1245 fi
1246
1247 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1248
1249 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1250         :
1251 else
1252         gtk_save_LIBS="$LIBS"
1253         LIBS="$PANGO_LIBS $LIBS"
1254         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1255 *** Can't link to Pango. Pango is required to build
1256 *** GTK+. For more information see http://www.pango.org]))
1257         LIBS="$gtk_save_LIBS"
1258 fi
1259
1260 CFLAGS="$saved_cflags"
1261 LDFLAGS="$saved_ldflags"
1262
1263 GDK_PACKAGES="$PANGO_PACKAGES $GIO_PACKAGE $X_PACKAGES gdk-pixbuf-2.0 $cairo_backends cairo-gobject"
1264
1265 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1266 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1267 #
1268 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1269 # into the pkg-config files
1270 #
1271 if test $enable_explicit_deps != yes ; then
1272   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo-gobject"
1273   GDK_EXTRA_LIBS=
1274 fi
1275
1276 AC_SUBST(GDK_PACKAGES)
1277 AC_SUBST(GDK_EXTRA_LIBS)
1278 AC_SUBST(GDK_EXTRA_CFLAGS)
1279 AC_SUBST(GDK_DEP_LIBS)
1280 AC_SUBST(GDK_DEP_CFLAGS)
1281
1282
1283 ########################################
1284 # Check for Accessibility Toolkit flags
1285 ########################################
1286
1287 ATK_PACKAGES=atk
1288 AC_MSG_CHECKING(ATK flags)
1289 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1290         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1291         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1292
1293         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1294 else
1295         AC_MSG_ERROR([
1296 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1297 *** to build GTK+.
1298 ])
1299 fi
1300
1301 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1302         :
1303 else
1304         gtk_save_LIBS="$LIBS"
1305         LIBS="$ATK_LIBS $LIBS"
1306         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1307                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1308                 *** to build GTK+]))
1309         LIBS="$gtk_save_LIBS"
1310 fi
1311
1312 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1313 if test "x$enable_x11_backend" == xyes; then
1314   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1315 fi
1316 GTK_EXTRA_LIBS=
1317 GTK_EXTRA_CFLAGS=
1318 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1319 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1320
1321 if test x"$os_win32" = xyes; then
1322   GTK_EXTRA_CFLAGS="$msnative_struct"
1323 fi
1324
1325 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1326 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1327 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1328 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1329
1330 AC_SUBST(GTK_PACKAGES)
1331 AC_SUBST(GTK_EXTRA_LIBS)
1332 AC_SUBST(GTK_EXTRA_CFLAGS)
1333 AC_SUBST(GTK_DEP_LIBS)
1334 AC_SUBST(GTK_DEP_CFLAGS)
1335
1336 AC_SUBST(GLIB_PREFIX)
1337 AC_SUBST(ATK_PREFIX)
1338 AC_SUBST(PANGO_PREFIX)
1339 AC_SUBST(CAIRO_PREFIX)
1340
1341 AC_SUBST(GTK_DEBUG_FLAGS)
1342 AC_SUBST(GTK_XIM_FLAGS)
1343
1344 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1345 AC_SUBST(GDK_PIXBUF_LIBS)
1346
1347 ########################
1348 # Checks needed for gail
1349 ########################
1350
1351 old_LIBS="$LIBS"
1352 dnl Checks for inet libraries:
1353 AC_SEARCH_LIBS(gethostent, nsl)
1354 AC_SEARCH_LIBS(setsockopt, socket)
1355 AC_SEARCH_LIBS(connect, inet)
1356
1357 dnl check for the sockaddr_un.sun_len member
1358 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1359                 [struct_sockaddr_un_sun_len=true],
1360                 [struct_sockaddr_un_suin_len=false],
1361                 [#include <sys/types.h>
1362                  #include <sys/un.h>]
1363                 )
1364 case $struct_sockaddr_un_sun_len in
1365         true)
1366                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1367                                    [Have the sockaddr_un.sun_len member])
1368                 ;;
1369         *)
1370                 ;;
1371 esac
1372
1373 GAIL_INET_LIBS="$LIBS"
1374 AC_SUBST([GAIL_INET_LIBS])
1375
1376 LIBS="$old_LIBS"
1377
1378 ################################################################
1379 # Printing system checks
1380 ################################################################
1381
1382 PRINT_BACKENDS="file lpr"
1383
1384 AC_ARG_ENABLE(cups,
1385               [AC_HELP_STRING([--disable-cups],
1386                               [disable cups print backend])],,
1387               [enable_cups=auto])
1388
1389 if test "x$enable_cups" = "xno"; then
1390   AM_CONDITIONAL(HAVE_CUPS, false)
1391 else
1392   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1393   if test "x$CUPS_CONFIG" = "xno"; then
1394     if test "x$enable_cups" = "xauto"; then
1395       AM_CONDITIONAL(HAVE_CUPS, false)
1396     else
1397       AC_MSG_ERROR([
1398 *** cups not found.
1399 ])
1400     fi
1401   else
1402     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1403     CUPS_LIBS=`$CUPS_CONFIG --libs`
1404
1405     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1406     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1407     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1408
1409     if test $CUPS_API_MAJOR -gt 1 -o \
1410             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1411       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1412                 [Define to 1 if CUPS 1.2 API is available])
1413     fi
1414
1415     AC_SUBST(CUPS_API_MAJOR)
1416     AC_SUBST(CUPS_API_MINOR)
1417     AC_SUBST(CUPS_CFLAGS)
1418     AC_SUBST(CUPS_LIBS)
1419
1420     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1421
1422     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1423     AM_CONDITIONAL(HAVE_CUPS, true)
1424
1425     gtk_save_cflags="$CFLAGS"
1426     CFLAGS="$CUPS_CFLAGS"
1427     AC_TRY_COMPILE([#include <cups/http.h>],
1428                    [http_t http; char *s = http.authstring;],
1429                    [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1430                               [Define if cups http_t authstring field is accessible])],)
1431     CFLAGS="$gtk_save_cflags"
1432
1433     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1434
1435     gtk_save_libs="$LIBS"
1436     LIBS="$CUPS_LIBS"
1437     AC_CHECK_FUNCS(httpGetAuthString)
1438     LIBS="$gtk_save_libs"
1439   fi
1440 fi
1441
1442 # Checks to see if we should compile with PAPI backend for GTK+
1443 #
1444
1445 AC_ARG_ENABLE(papi,
1446               [AC_HELP_STRING([--disable-papi],
1447                               [disable papi print backend])],,
1448              [enable_papi=auto])
1449
1450 if test "x$enable_papi" = "xno"; then
1451   AM_CONDITIONAL(HAVE_PAPI, false)
1452 else
1453   AC_MSG_CHECKING(libpapi)
1454   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1455   if test $have_papi = yes; then
1456     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1457     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1458   fi
1459   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1460   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1461     AC_MSG_ERROR([
1462 *** papi not found.
1463 ])
1464   fi
1465 fi
1466
1467 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1468
1469 gtk_save_cppflags="$CPPFLAGS"
1470 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1471
1472 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1473 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1474 *** backend enabled.]))
1475
1476 if test "$os_win32" != "yes"; then
1477   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1478 *** Can't find cairo-ps.h. You must build Cairo with the
1479 *** postscript backend enabled.]))
1480
1481   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1482 *** Cannot find cairo-svg.h. You must build Cairo with the
1483 *** svg backend enabled.]))
1484 fi
1485
1486 CPPFLAGS="$gtk_save_cppflags"
1487
1488
1489 AC_ARG_ENABLE(test-print-backend,
1490               [AC_HELP_STRING([--enable-test-print-backend],
1491                               [build test print backend])],,
1492               [enable_test_print_backend=no])
1493 if test "x$enable_test_print_backend" != "xno" ; then
1494   PRINT_BACKENDS="$PRINT_BACKENDS test"
1495 fi
1496 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1497
1498
1499 ################################################################
1500 # Strip -export-dynamic from the link lines of various libraries
1501 ################################################################
1502
1503 #
1504 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1505 #  but this flag is only meaningful for executables. For libraries
1506 #  the effect is undefined; what it causes on Linux is that the
1507 #  export list from -export-symbols-regex is ignored and everything
1508 #  is exported
1509 #
1510 # We are using gmodule-no-export now, but I'm leaving the stripping
1511 # code in place for now, since pango and atk still require gmodule.
1512 export SED
1513 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1514 if test -n "$export_dynamic"; then
1515   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1516   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1517 fi
1518
1519 #############
1520 # GSettings #
1521 #############
1522
1523 GLIB_GSETTINGS
1524
1525 ##################################################
1526 # GObject introspection
1527 ##################################################
1528
1529 GOBJECT_INTROSPECTION_CHECK([0.9.3])
1530
1531 ##################################################
1532 # Packagekit module
1533 #################################################
1534
1535 AC_ARG_ENABLE(packagekit,
1536               AC_HELP_STRING([--disable-packagekit],
1537                              [build packagekit open-with module]))
1538
1539 build_packagekit=no
1540 if test "os_win32" != "yes"; then
1541         if test "x$enable_packagekit" != "xno"; then
1542                 build_packagekit=yes
1543                 AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1544         fi
1545 fi
1546
1547 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1548
1549 ##################################################
1550 # Checks for gtk-doc and docbook-tools
1551 ##################################################
1552
1553 GTK_DOC_CHECK([1.11])
1554
1555 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1556 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1557
1558 AC_ARG_ENABLE(man,
1559               [AC_HELP_STRING([--enable-man],
1560                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1561               enable_man=no)
1562
1563 if test "${enable_man}" != no; then
1564   dnl
1565   dnl Check for xsltproc
1566   dnl
1567   AC_PATH_PROG([XSLTPROC], [xsltproc])
1568   if test -z "$XSLTPROC"; then
1569     enable_man=no
1570   fi
1571
1572   dnl check for DocBook DTD and stylesheets in the local catalog.
1573   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1574      [DocBook XML DTD V4.1.2],,enable_man=no)
1575   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1576      [DocBook XSL Stylesheets],,enable_man=no)
1577 fi
1578
1579 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1580
1581
1582 ##################################################
1583 # Output commands
1584 ##################################################
1585
1586 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1587         outfile=gdkconfig.h-tmp
1588         cat > $outfile <<\_______EOF
1589 /* gdkconfig.h
1590  *
1591  * This is a generated file.  Please modify `configure.ac'
1592  */
1593
1594 #ifndef __GDKCONFIG_H__
1595 #define __GDKCONFIG_H__
1596
1597 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1598 #error "Only <gdk/gdk.h> can be included directly."
1599 #endif
1600
1601 #include <glib.h>
1602
1603 G_BEGIN_DECLS
1604
1605 _______EOF
1606
1607         cat >>$outfile <<_______EOF
1608 $gdk_windowing
1609 _______EOF
1610
1611         cat >>$outfile <<_______EOF
1612
1613 G_END_DECLS
1614
1615 #endif  /* __GDKCONFIG_H__ */
1616 _______EOF
1617
1618
1619         if cmp -s $outfile gdk/gdkconfig.h; then
1620           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1621           rm -f $outfile
1622         else
1623           mv $outfile gdk/gdkconfig.h
1624         fi
1625 ],[
1626 gdk_windowing='$GDK_WINDOWING'
1627 ])
1628
1629 dnl
1630 dnl Check for -Bsymbolic-functions linker flag used to avoid
1631 dnl intra-library PLT jumps, if available.
1632 dnl
1633 AC_ARG_ENABLE(Bsymbolic,
1634               [AC_HELP_STRING([--disable-Bsymbolic],
1635                               [avoid linking with -Bsymbolic])],,
1636               [SAVED_LDFLAGS="${LDFLAGS}"
1637                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1638                LDFLAGS=-Wl,-Bsymbolic-functions
1639                AC_TRY_LINK([], [int main (void) { return 0; }],
1640                            AC_MSG_RESULT(yes)
1641                            enable_Bsymbolic=yes,
1642                            AC_MSG_RESULT(no)
1643                            enable_Bsymbolic=no)
1644                LDFLAGS="${SAVED_LDFLAGS}"])
1645
1646 if test "x${enable_Bsymbolic}" = "xyes" ; then
1647   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1648 fi
1649 AC_SUBST(GTK_LINK_FLAGS)
1650
1651 AC_CONFIG_FILES([
1652 config.h.win32
1653 gtk-zip.sh
1654 Makefile
1655 gdk-3.0.pc
1656 gtk+-3.0.pc
1657 gtk+-unix-print-3.0.pc
1658 gail-3.0.pc
1659 gtk+-3.0-uninstalled.pc
1660 gail-3.0-uninstalled.pc
1661 m4macros/Makefile
1662 po/Makefile.in
1663 po-properties/Makefile.in
1664 demos/Makefile
1665 demos/gtk-demo/Makefile
1666 demos/gtk-demo/geninclude.pl
1667 examples/Makefile
1668 tests/Makefile
1669 docs/Makefile
1670 docs/reference/Makefile
1671 docs/reference/gdk/Makefile
1672 docs/reference/gdk/version.xml
1673 docs/reference/gtk/Makefile
1674 docs/reference/gtk/version.xml
1675 docs/reference/libgail-util/Makefile
1676 docs/reference/libgail-util/version.xml
1677 docs/tools/Makefile
1678 build/Makefile
1679 build/win32/Makefile
1680 build/win32/vs9/Makefile
1681 gdk/Makefile
1682 gdk/broadway/Makefile
1683 gdk/x11/Makefile
1684 gdk/win32/Makefile
1685 gdk/win32/rc/Makefile
1686 gdk/win32/rc/gdk.rc
1687 gdk/quartz/Makefile
1688 gdk/tests/Makefile
1689 gtk/Makefile
1690 gtk/makefile.msc
1691 gtk/gtkversion.h
1692 gtk/gtk-win32.rc
1693 gtk/theme-bits/Makefile
1694 gtk/tests/Makefile
1695 modules/Makefile
1696 modules/other/Makefile
1697 modules/other/gail/Makefile
1698 modules/other/gail/libgail-util/Makefile
1699 modules/other/gail/tests/Makefile
1700 modules/engines/Makefile
1701 modules/engines/pixbuf/Makefile
1702 modules/engines/ms-windows/Makefile
1703 modules/engines/ms-windows/Theme/Makefile
1704 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1705 modules/input/Makefile
1706 modules/printbackends/Makefile
1707 modules/printbackends/cups/Makefile
1708 modules/printbackends/lpr/Makefile
1709 modules/printbackends/file/Makefile
1710 modules/printbackends/papi/Makefile
1711 modules/printbackends/test/Makefile
1712 perf/Makefile
1713 ])
1714
1715 AC_OUTPUT
1716
1717 # beautify the immodule list a bit
1718 included_immodules=${included_immodules//,/ }
1719 included_immodules=${included_immodules:-none}
1720
1721 echo "configuration:"
1722 echo "        GDK backends:         $GDK_BACKENDS"
1723 if test "x$enable_x11_backend" = "xyes"; then
1724 echo "        X11 extensions:       $X_EXTENSIONS"
1725 fi
1726 echo "        Print backends:       $PRINT_BACKENDS"
1727 echo "        Dynamic modules:      $build_dynamic_modules"
1728 echo "        Included immodules:   $included_immodules"
1729 echo "        PackageKit support:   $build_packagekit"
1730 echo "        Introspection:        $found_introspection"
1731 echo "        Debugging:            $enable_debug"
1732 echo "        Documentation:        $enable_gtk_doc"