Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 #
   3 # Fetchmail automatic configuration support
   4 #
   5 # Eric S. Raymond <esr@thyrsus.com>
   6 # 2004 - 2010 Matthias Andree <matthias.andree@gmx.de>
   7 #
   8 dnl Process this file with autoconf to produce a configure script.
   9 dnl
  10
  11 dnl XXX - if bumping version here, check fetchmail.man, too!
  12 AC_INIT([fetchmail],[6.3.17-pre1],[fetchmail-users@lists.berlios.de])
  13 AC_CONFIG_SRCDIR([fetchmail.h])
  14 AC_CONFIG_HEADERS([config.h])
  15 AC_CONFIG_LIBOBJ_DIR([.])
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl automake options are in Makefile.am
  20 AC_PREREQ(2.60)
  21 dnl 2.60 required for AC_USE_SYSTEM_EXTENSIONS
  22 AM_INIT_AUTOMAKE
  23
  24 dnl python is optional
  25 #
  26 # you can pass PYTHON=: in environment or on the command line
  27 # to disable python detection and continue without building/installing
  28 # fetchmail.conf -- be sure to check README.packaging, too!
  29 #
  30 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  31 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  32
  33 AC_PROG_AWK
  34 AC_PROG_CC
  35 AM_PROG_CC_C_O
  36 AC_PROG_INSTALL
  37 AC_PROG_CPP                     dnl Later checks need this.
  38 AC_PROG_RANLIB
  39 AM_PROG_CC_C_O
  40 AC_USE_SYSTEM_EXTENSIONS
  41
  42 AC_ISC_POSIX
  43 dnl AC_ISC_POSIX: - XXX FIXME: remove in fetchmail 6.4.
  44 dnl This macro adds `-lcposix' to output variable `LIBS' if necessary
  45 dnl for Posix facilities.  Sun dropped support for the obsolete
  46 dnl INTERACTIVE Systems Corporation Unix on 2006-07-23.  New programs
  47 dnl need not use this macro.  It is implemented as
  48 dnl `AC_SEARCH_LIBS([strerror], [cposix])'
  49
  50 dnl check for b0rked Solaris (and other shells) and find one that works
  51 AC_MSG_CHECKING(for a working shell...)
  52 for i in /usr/xpg6/bin/sh /usr/xpg4/bin/sh /usr/ccs/bin/sh /bin/sh /usr/bin/sh /bin/ksh /bin/bash /usr/local/bin/bash ; do
  53     $i -c 'if ! false ; then echo $(echo ok) ; fi' >config.$$ 2>/dev/null
  54     j=`cat config.$$`
  55     rm -f config.$$
  56     if test "x$j" = "xok" ; then
  57         SHELL=$i
  58         AC_SUBST(SHELL)
  59         break
  60     fi
  61 done
  62 AC_MSG_RESULT($SHELL)
  63 if test "x$SHELL" = "x" ; then
  64     AC_MSG_ERROR(no SUS compliant shell found - on Solaris, install SUNWxcu4)
  65 fi
  66
  67
  68 AC_HEADER_STDC
  69 AC_HEADER_TIME
  70 AC_TYPE_SIZE_T
  71 AC_TYPE_PID_T
  72 AC_TYPE_SIGNAL
  73 AC_CHECK_HEADERS([unistd.h termios.h termio.h sgtty.h stdarg.h \
  74         sys/itimer.h fcntl.h sys/fcntl.h memory.h sys/wait.h \
  75         arpa/inet.h arpa/nameser.h netinet/in.h net/socket.h netdb.h \
  76         sys/select.h sys/socket.h sys/time.h langinfo.h md5.h])
  77 if test _$ac_cv_header_stdarg_h != _yes ; then
  78 AC_MSG_WARN([stdarg.h is not defined. Unsupported configuration, proceed at your own risk.])
  79 fi
  80 AC_CHECK_TYPE(u_int32_t,,
  81         AC_DEFINE(u_int32_t,unsigned int,
  82                 [Define to unsigned int if <sys/types.h> does not define.]),
  83         [AC_INCLUDES_DEFAULT
  84 #ifdef HAVE_ARPA_NAMESER_H
  85 #include <arpa/nameser.h>
  86 #endif])
  87 AC_CHECK_HEADERS([resolv.h],,,[
  88 #include <sys/types.h>
  89 #ifdef HAVE_NETINET_IN_H
  90 #include <netinet/in.h>
  91 #endif
  92 #ifdef HAVE_ARPA_NAMESER_H
  93 #include <arpa/nameser.h>
  94 #endif
  95 ])
  96
  97 AC_CHECK_DECLS([h_errno],,,[
  98         AC_INCLUDES_DEFAULT
  99         #ifdef HAVE_NETDB_H
 100         #include <netdb.h>
 101         #endif
 102 ])
 103
 104 AC_C_CONST                      dnl getopt needs this.
 105
 106 AM_PROG_LEX
 107 AC_PROG_MAKE_SET
 108 AC_PROG_YACC
 109
 110 # Check for OS special cases
 111 case $host_os in
 112 darwin*)
 113     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
 114     CPPFLAGS="$CPPFLAGS -DBIND_8_COMPAT"
 115     ;;
 116 # Check for FreeBSD special case: more libs needed
 117 freebsd*)
 118     AC_MSG_NOTICE(found FreeBSD - Adding -lkvm -lcom_err to standard libraries)
 119     LIBS="$LIBS -lkvm -lcom_err"
 120     ;;
 121 # Check for LynxOS special case: -lbsd needed (at least on 2.3.0) and -s
 122 # not working.
 123 lynxos*)
 124     AC_MSG_NOTICE(found LynxOS - Adding -lbsd to standard libraries)
 125     LIBS="$LIBS -lbsd"
 126     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 127     AC_MSG_NOTICE(found LynxOS - Prepending standard include path to gcc flags)
 128     CPPFLAGS="$CPPFLAGS -I/usr/include"
 129     ;;
 130 # Check for Rhapsody special case: it doesn't like -s
 131 rhapsody*)
 132     AC_MSG_NOTICE(found Rhapsody - Removing -s load flag)
 133     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 134     ;;
 135 esac
 136
 137 AC_CACHE_SAVE
 138
 139 dnl i18n
 140 AM_GNU_GETTEXT([external], [need-ngettext])
 141 AM_GNU_GETTEXT_VERSION([0.14.6])
 142 dnl end i18n
 143
 144 # Under sysV68, socket and friends are provided by the C library.
 145 # -linet does not provide socket, but causes multiple definition
 146 # errors at link-time.  It is thus better to only use the C library.
 147 # So don't add -linet to the link list unless it's necessary
 148 AC_CHECK_FUNC(socket,
 149     AC_MSG_RESULT(using libc's socket),
 150     AC_CHECK_LIB(socket,socket)
 151     AC_CHECK_LIB(inet,socket))
 152
 153 # The condition in this test copes with the presence of inet_addr in libc6.
 154 AC_CHECK_FUNC(inet_addr,
 155     AC_MSG_RESULT(using libc's inet_addr),
 156     AC_CHECK_LIB(nsl,inet_addr))
 157
 158 dnl Port hack for Interactive UNIX System V/386 Release 3.2
 159 AC_CHECK_LIB(cposix, strchr,
 160                 [DEFS="$DEFS -D_SYSV3"
 161                 LIBS="$LIBS -lcposix"])
 162
 163 dnl Port hack for Sparc/NetBSD-1.5
 164 dnl
 165 dnl NB: this has been disabled as it causes the unconditional
 166 dnl addition of libintl to the build, which is both undesired
 167 dnl and breaks on Solaris/Blastwave.org machines.
 168 dnl
 169 dnl AC_CHECK_LIB(intl, gettext,
 170 dnl             [LIBS="$LIBS -lintl"])
 171
 172 AC_REPLACE_FUNCS([strstr strcasecmp memmove stpcpy strlcpy strlcat])
 173
 174 AC_SEARCH_LIBS(MD5Init, [md5 md], [],
 175               [AC_LIBSOURCE(md5c.c)
 176                EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"])
 177
 178 AC_CHECK_FUNC(getopt_long, [],
 179               [AC_LIBSOURCES([getopt.c, getopt1.c])
 180                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 181
 182 AC_FUNC_VPRINTF
 183
 184 AC_SUBST(EXTRAOBJ)
 185
 186 AC_CHECK_FUNCS(tcsetattr stty setsid geteuid seteuid dnl
 187   strerror syslog snprintf vprintf vsnprintf vsyslog dnl
 188   atexit inet_aton strftime setrlimit socketpair dnl
 189   sigaction strdup setlocale)
 190
 191 AC_CHECK_DECLS([strerror,getenv])
 192 dnl INET6 is used by KAME/getnameinfo
 193 AC_CACHE_CHECK(for AF_INET6/PF_INET6,ac_cv_inet6,
 194 AC_COMPILE_IFELSE([
 195   AC_LANG_PROGRAM([[
 196     #ifdef HAVE_SYS_TYPES_H
 197     #include <sys/types.h>
 198     #endif
 199     #ifdef HAVE_SYS_SOCKET_H
 200     #include <sys/socket.h>
 201     #endif
 202   ]],[[
 203     int foo = AF_INET6;
 204     int bar = PF_INET6;
 205   ]])],
 206   ac_cv_inet6=yes , ac_cv_inet6=no
 207 ))
 208 if test "x$ac_cv_inet6" = xyes
 209 then
 210     AC_DEFINE(INET6,1,Define to 1 if your system defines AF_INET6 and PF_INET6.)
 211 fi
 212
 213 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 214 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 215 # library.  So don't add -lresolv to the link list unless it's necessary
 216 # (It will be necessary when using GNU libc6).
 217 old_LIBS="$LIBS"
 218 for lib in '' -lresolv; do
 219     if test -z "$lib"; then
 220        AC_MSG_CHECKING([for res_search in libc])
 221     else
 222        AC_MSG_CHECKING([for res_search in $lib])
 223     fi
 224     LIBS="$old_LIBS $lib"
 225     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 226 #include <sys/types.h>
 227 #ifdef HAVE_NETINET_IN_H
 228 #include <netinet/in.h>
 229 #endif
 230 #ifdef HAVE_ARPA_NAMESER_H
 231 #include <arpa/nameser.h>
 232 #endif
 233 #ifdef HAVE_RESOLV_H
 234 #include <resolv.h>
 235 #endif
 236 extern int res_search();
 237 ]], [[res_search(0, 0, 0, 0, 0); dn_skipname(0,0);]])],
 238     [AC_MSG_RESULT([found])
 239      AC_DEFINE(HAVE_RES_SEARCH, [1],
 240                [Define to 1 if you have the 'res_search' and 'dn_skipname' functions.])
 241      break], [AC_MSG_RESULT([not found])])
 242      LIBS=$old_LIBS
 243 done
 244
 245 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 246 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 247
 248 dnl Check for usable void pointer type
 249 AC_MSG_CHECKING(use of void pointer type)
 250 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[char *p;
 251     void *xmalloc();
 252     p = (char *) xmalloc(1);
 253    ]])],[AC_DEFINE(HAVE_VOIDPOINTER,1,[Define if your C compiler allows void * as a function result]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 254
 255 dnl Check for ANSI volatile
 256 AC_C_VOLATILE
 257
 258 dnl Check out the wait reality.  We have to assume sys/wait.h is present.
 259 AC_CHECK_FUNCS(waitpid wait3)
 260 AC_MSG_CHECKING(for union wait);
 261 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 262 #include <sys/wait.h>]], [[union wait status; int pid; pid = wait (&status);
 263 #ifdef WEXITSTATUS
 264 /* Some POSIXoid systems have both the new-style macros and the old
 265    union wait type, and they do not work together.  If union wait
 266    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 267 if (WEXITSTATUS (status) != 0) pid = -1;
 268 #endif
 269 #ifdef HAVE_WAITPID
 270 /* Make sure union wait works with waitpid.  */
 271 pid = waitpid (-1, &status, 0);
 272 #endif
 273 ]])],[AC_DEFINE(HAVE_UNION_WAIT,1,Define if 'union wait' is the type of the first arg to wait functions.) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 274
 275 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 276 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 277 /* NetBSD declares sys_siglist in <unistd.h>.  */
 278 #ifdef HAVE_UNISTD_H
 279 #include <unistd.h>
 280 #endif]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 281
 282 # Find the right directory to put the root-mode PID file in
 283 for dir in "/var/run" "/etc"
 284 do
 285         if test -d $dir
 286         then
 287                 break;
 288         fi
 289 done
 290 AC_MSG_RESULT(root-mode pid file will go in $dir)
 291 AC_DEFINE_UNQUOTED(PID_DIR, "$dir", directory for PID lock files)
 292
 293 # We may have a fallback MDA available in case the socket open to the
 294 # local SMTP listener fails.  Best to use procmail for this, as we know
 295 # it won't try delivering through local SMTP and cause a mail loop.
 296 # Sendmail without the -t option to use the message headers will work too,
 297 # not just for sendmail itself but for workalikes like exim.
 298 #
 299 # Note1: A disadvantage of using procmail is that local alias expansion
 300 # according to /etc/aliases won't get done if we fall back.  This doesn't
 301 # matter in single-drop mode.
 302 #
 303 # Note2: it would be a very bad idea to use any MDA that doesn't return
 304 # a refuse-to-deliver status on disk- or process-table-full
 305 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 306 # like exim that might be lurking under a sendmail alias) do the right
 307 # thing in this circumstance.  Matthias Andree warns that procmail does
 308 # not.
 309 #
 310 # Note3: Defalt value of fallback is now off.  Matthias writes:
 311 #
 312 # 1. there is no way to predict when the fallback is used. With some MTAs
 313 #    (such as those limiting load average), outer circumstances can cause
 314 #    the fallback to kick in.
 315 #
 316 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 317 #    not only about alias expansion, .forwards to special filters won't
 318 #    work, mail may end up in a different place (users claim "mail loss"
 319 #    for that).
 320 #
 321 # 3. The claim procmail did the right thing with its exit codes is plain
 322 #    wrong. I've seen procmail exit with code 1 when it should have exited
 323 #    with code 75, like, configuration errors. Procmail is a dangerous
 324 #    beast and is best replaced by maildrop.
 325 #
 326 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 327 #    cannot tell which one it should choose. Say, your MTA is configured
 328 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 329 #    chooses procmail, this is plain wrong.
 330 #
 331
 332 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 333 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 334 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 335
 336 ###     use option --disable-fallback to disable fallback MDA
 337 ###     use option --enable-fallback=procmail or
 338 ###                --enable-fallback=sendmail to select
 339 AC_ARG_ENABLE(fallback,
 340         [  --enable-fallback=procmail    enable procmail as fallback
 341   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 342   --enable-fallback=maildrop    enable maildrop as fallback
 343   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 344
 345 case "$enable_fallback" in
 346         sendmail)       if test -z "$sendmail" ; then
 347                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 348                                 #not reached
 349                         fi
 350                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 351                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 352                         ;;
 353         procmail)       if test -z "$procmail" ; then
 354                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 355                                 #not reached
 356                         fi
 357                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 358                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 359                         ;;
 360         maildrop)       if test -z "$maildrop" ; then
 361                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 362                                 #not reached
 363                         fi
 364                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 365                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 366                         ;;
 367         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 368                         ;;
 369         auto|yes|set)   if test -n "$sendmail" ; then
 370                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 371                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 372                         else
 373                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 374                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 375                         fi
 376                         ;;
 377         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 378                         #notreached
 379                         ;;
 380 esac
 381
 382 AC_CHECK_SIZEOF(short)
 383 AC_CHECK_SIZEOF(int)
 384 AC_CHECK_SIZEOF(long)
 385
 386 ###     use option --enable-POP2 to compile in the POP2 support
 387 AC_ARG_ENABLE(POP2,
 388         [  --enable-POP2           compile in POP2 protocol support (obsolete)],
 389         [with_POP2=$enableval],
 390         [with_POP2=no])
 391 test "$with_POP2" = "yes" && AC_DEFINE(POP2_ENABLE,1,Define if you want POP2 support compiled in)
 392 AM_CONDITIONAL(POP2_ENABLE, test "$with_POP2" = yes)
 393
 394 ###     use option --disable-POP3 to omit the POP3 support
 395 AC_ARG_ENABLE(POP3,
 396         [  --disable-POP3          don't compile in POP3 protocol support],
 397         [with_POP3=$enableval],
 398         [with_POP3=yes])
 399 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 400 AM_CONDITIONAL(POP3_ENABLE, test "$with_POP3" = yes)
 401
 402 ###     use option --disable-IMAP to omit the IMAP support
 403 AC_ARG_ENABLE(IMAP,
 404         [  --disable-IMAP          don't compile in IMAP protocol support],
 405         [with_IMAP=$enableval],
 406         [with_IMAP=yes])
 407 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,Define if you want IMAP support compiled in)
 408 AM_CONDITIONAL(IMAP_ENABLE, test "$with_IMAP" = yes)
 409
 410 ###     use option --disable-ETRN to omit the ETRN support
 411 AC_ARG_ENABLE(ETRN,
 412         [  --disable-ETRN          don't compile in ETRN protocol support],
 413         [with_ETRN=$enableval],
 414         [with_ETRN=yes])
 415 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 416 AM_CONDITIONAL(ETRN_ENABLE, test "$with_ETRN" = yes)
 417
 418 ###     use option --disable-ODMR to omit the ODMR support
 419 AC_ARG_ENABLE(ODMR,
 420         [  --disable-ODMR          don't compile in ODMR protocol support],
 421         [with_ODMR=$enableval],
 422         [with_ODMR=yes])
 423 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 424 AM_CONDITIONAL(ODMR_ENABLE, test "$with_ODMR" = yes)
 425
 426 ###     use option --enable-RPA to compile in the RPA support
 427 AC_ARG_ENABLE(RPA,
 428         [  --enable-RPA            compile in RPA protocol support],
 429         [with_RPA=$enableval],
 430         [with_RPA=no])
 431 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 432 AM_CONDITIONAL(RPA_ENABLE, test "$with_RPA" = yes)
 433
 434 ###     use option --enable-NTLM to compile in the NTLM support
 435 AC_ARG_ENABLE(NTLM,
 436         [  --enable-NTLM           compile in NTLM authentication support],
 437         [with_NTLM=$enableval],
 438         [with_NTLM=no])
 439 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 440
 441 ###     use option --enable-SDPS to compile in the SDPS support
 442 AC_ARG_ENABLE(SDPS,
 443         [  --enable-SDPS           compile in SDPS protocol support],
 444         [with_SDPS=$enableval],
 445         [with_SDPS=no])
 446 if test "$with_SDPS" = yes ; then
 447    if test "$with_POP3" != yes ; then
 448        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 449        with_SDPS=no
 450    else
 451        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 452    fi
 453 fi
 454 if test "$with_POP3" != yes && test "$with_POP2" != yes \
 455     && test "$with_IMAP"  != yes ; then
 456     AC_MSG_ERROR([You must enable at least one of POP2, POP3 and IMAP.])
 457 fi
 458
 459 AC_CACHE_SAVE
 460
 461 ###     use option --enable-opie to compile in the OPIE support
 462 AC_ARG_ENABLE(opie,
 463         [  --enable-opie           support OTP through the OPIE library],
 464         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR(cannot find <opie.h>, which is required for OPIE support.)])
 465           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR(cannot find libopie, which is required for OPIE support.)])
 466           with_opie=$enableval],
 467         [with_opie=no])
 468 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 469
 470 dnl Mostly stolen from gnulib's getaddrinfo.m4
 471 AC_SEARCH_LIBS(getaddrinfo, [nsl socket])
 472 AC_CACHE_CHECK([for getaddrinfo],[fm_cv_getaddrinfo],[
 473   AC_TRY_LINK([
 474 #include <sys/types.h>
 475 #ifdef HAVE_SYS_SOCKET_H
 476 #include <sys/socket.h>
 477 #endif
 478 #ifdef HAVE_NETDB_H
 479 #include <netdb.h>
 480 #endif
 481   ], [getaddrinfo(0, 0, 0, 0);],
 482     [ fm_cv_getaddrinfo=yes],
 483     [ fm_cv_getaddrinfo=no ])
 484 ])
 485
 486 if test x"$fm_cv_getaddrinfo" = "xyes"; then
 487      AC_DEFINE(HAVE_GETADDRINFO, 1,
 488       [Define to 1 if you have the getaddrinfo function.])
 489 fi
 490
 491 AC_CACHE_CHECK([for getnameinfo],[fm_cv_getnameinfo],[
 492   AC_TRY_LINK([
 493 #include <sys/types.h>
 494 #ifdef HAVE_SYS_SOCKET_H
 495 #include <sys/socket.h>
 496 #endif
 497 #ifdef HAVE_NETDB_H
 498 #include <netdb.h>
 499 #endif
 500 #ifndef NULL
 501 #define NULL 0
 502 #endif
 503   ], [getnameinfo(NULL,0, NULL,0, NULL, 0, 0);],
 504     [ fm_cv_getnameinfo=yes],
 505     [ fm_cv_getnameinfo=no ])
 506 ])
 507 if test $fm_cv_getnameinfo = yes ; then
 508     AC_DEFINE(HAVE_GETNAMEINFO,1,[Define to 1 if your system has getnameinfo()])
 509 fi
 510
 511 AM_CONDITIONAL(NEED_GETADDRINFO, test "$fm_cv_getaddrinfo" != yes)
 512 AM_CONDITIONAL(NEED_GETNAMEINFO, test "$fm_cv_getnameinfo"   != yes)
 513
 514 AC_CHECK_FUNCS(inet_ntop)
 515 dnl Check if getaddrinfo is async-signal-safe - most implementations aren't
 516 if test "$fm_cv_getaddrinfo" = yes ; then
 517     AC_MSG_CHECKING(if your getaddrinfo is async-signal-safe)
 518     gai_ts=no
 519     dnl we have getaddrinfo() - check if the OS is known to have a async-signal-safe implementation
 520     case $host_os in
 521         darwin9*)                               gai_ts=yes ;;
 522         linux*)                                 gai_ts=yes ;;
 523         freebsd5.5|freebsd6*|freebsd7*)         gai_ts=yes ;;
 524         solaris2.8|solaris2.9|solaris2.10)      gai_ts=yes ;;
 525     esac
 526     AC_MSG_RESULT($gai_ts)
 527     if test $gai_ts = yes ; then
 528         AC_DEFINE(GETADDRINFO_ASYNCSAFE, 1, [define to 1 if you know your getaddrinfo function is async-signal-safe])
 529     fi
 530 fi
 531
 532 # This version of the Kerberos 4 and 5 options addresses the follwing issues:
 533 #
 534 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 535 #   OpenSSL support (Debian's is)
 536 # * Build the kerberos.c stuff (KPOP) only for kerberosIV, to avoid breakage.
 537 #   I don't know if this is 100% correct, but now at least IMAP and POP3
 538 #   behave the same way regarding kerberosV.
 539 # * Build without any fuss for both kerberosIV and V at the same time.
 540 # * Move all the kerberos header mess to kerberos.h, and #include that
 541 #   in driver.c and kerberos.c.
 542 #
 543 # Tested using the Heimdal Kerberos V libs, Kungliga Tekniska Högskolan (the
 544 # Royal Institute of Technology in Stockholm, Sweden)'s kerberos IV libs, and
 545 # the MIT reference implementation of KerberosV (all as packaged in Debian).
 546
 547 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 548 ### make sure --with-ssl is run before --with-kerberos* !
 549 AC_ARG_WITH(kerberos5,
 550        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 551 [
 552 if test "$with_kerberos5" != "no"
 553 then
 554 # Check for a OpenBSD special case
 555 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 556 then
 557   AS_MESSAGE(checking kerberosV for OpenBSD...)
 558   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 559   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 560   CFLAGS="$CFLAGS -I/usr/include/kerberosV"
 561   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 562 elif krb5-config 2> /dev/null >/dev/null ; then
 563   krb5_prefix=`krb5-config --prefix krb5`
 564   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 565   if test -f ${krb5_prefix}/include/et/com_err.h && \
 566    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 567     CFLAGS="$CFLAGS -I${krb5_prefix}/include/et"
 568   fi
 569   unset krb5_prefix
 570   CFLAGS="$CFLAGS `krb5-config --cflags krb5`"
 571   LIBS="$LIBS `krb5-config --libs krb5`"
 572   AC_DEFINE(KERBEROS_V5)
 573 else
 574   if test "$with_kerberos5" != "yes"
 575   then
 576       LDFLAGS="$LDFLAGS -L${with_kerberos5}/lib"
 577       searchdirs="$with_kerberos5"
 578   else
 579       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 580   fi
 581   with_kerberos5=
 582   for dir in $searchdirs
 583   do AC_MSG_CHECKING([for Kerberos V in $dir])
 584      if test -f "$dir/include/krb5.h" || test -f "$dir/include/krb5/krb5.h"
 585      then
 586         if test -d "$dir/include/krb5" ; then CPPFLAGS="$CPPFLAGS -I$dir/include/krb5" ; fi
 587         ac_krblibs=
 588         if test -f "$dir/include/roken.h" || test -f "$dir/include/krb5/roken.h"
 589         then
 590            ac_krblibs="-lasn1 -lroken -lcom_err"
 591            AC_MSG_RESULT([Heimdal found])
 592           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 593           dnl we assume we do if it is available
 594            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 595                 ${LDFLAGS})
 596            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 597               AC_CHECK_LIB(crypto, MD5_Init, [],
 598                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 599                 ${LDFLAGS} ${ac_krblibs}),
 600            ${LDFLAGS} ${ac_krblibs})
 601            AC_DEFINE(HEIMDAL)
 602         else
 603           AC_MSG_RESULT([found])
 604           ac_krblibs="-lcom_err"
 605            AC_CHECK_LIB(crypto,
 606              krb5_des_string_to_key,
 607              libk5crypto=-lcrypto,
 608                 AC_CHECK_LIB(k5crypto,
 609                    krb5_des_string_to_key,
 610                    libk5crypto=-lk5crypto,
 611                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 612                    ${LDFLAGS} ${ac_krblibs}),
 613                  ${LDFLAGS} ${ac_krblibs})
 614         fi
 615         AC_CHECK_LIB(krb5, krb5_init_context,[],
 616            continue,
 617            ${LDFLAGS} ${ac_krblibs})
 618         AC_DEFINE(KERBEROS_V5)
 619         test "$dir" != "/usr" && CFLAGS="$CFLAGS -I$dir/include"
 620         LDFLAGS="$LDFLAGS -L$dir/lib"
 621        LIBS="$LIBS $ac_krblibs $libk5crypto"
 622         with_kerberos5=$dir
 623         break
 624      else
 625         AC_MSG_RESULT([not found])
 626      fi
 627   done
 628   if test -z "$with_kerberos5" ; then
 629      AC_MSG_ERROR([Kerberos 5 libraries not found])
 630   fi
 631 fi
 632 fi
 633 ]) dnl --with-kerberos5=DIR
 634
 635 ###    use option --with-kerberos=DIR to point at a Kerberos 4 directory
 636 KERBEROS_V4=0
 637 AC_ARG_WITH(kerberos,
 638        [  --with-kerberos=DIR     point fetchmail compilation at a Kerberos 4 directory],
 639 [
 640 if test "$with_kerberos" != "no"
 641 then
 642     AC_MSG_WARN([Kerberos IV support is obsolete. Use --with-kerberos5 if possible.])
 643 # Check for a NetBSD/OpenBSD special case
 644 if test "$with_kerberos" = "yes" && ( test `uname` = "NetBSD" || test `uname` = "OpenBSD" )
 645 then
 646   AS_MESSAGE(checking kerberosIV for `uname`...)
 647   KERBEROS_V4=1
 648   CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 649   case `uname` in
 650       NetBSD)  LIBS="$LIBS -lkrb -ldes -lroken -lcom_err" ;;
 651       OpenBSD) LIBS="$LIBS -lkrb -ldes" ;;
 652   esac
 653 elif krb4-config 2> /dev/null >/dev/null ; then
 654   krb4_prefix=`krb4-config --prefix`
 655   AC_MSG_RESULT([krb4-config points to kerberosIV under $krb4_prefix])
 656   unset krb4_prefix
 657   CFLAGS="$CFLAGS `krb4-config --cflags`"
 658   LIBS="$LIBS `krb4-config --libs`"
 659   KERBEROS_V4=1
 660 elif krb5-config 2> /dev/null >/dev/null ; then
 661   krb4_prefix=`krb5-config --prefix krb4`
 662   AC_MSG_RESULT([krb5-config points to kerberosIV under $krb4_prefix])
 663   if test -f ${krb4_prefix}/include/kerberosIV/krb.h ; then
 664     AC_DEFINE(KERBEROS_V4_V5,1,Define if you have Kerberos V4 headers under a kerberosIV directory)
 665   fi
 666   unset krb4_prefix
 667   CFLAGS="$CFLAGS `krb5-config --cflags krb4`"
 668   LIBS="$LIBS `krb5-config --libs krb4`"
 669   KERBEROS_V4=1
 670 else
 671   #we need to detect when we're building under a kerberosV compatibility
 672   #layer, btw...
 673   if test "$with_kerberos" != "yes" ; then
 674      searchdirs="$with_kerberos"
 675   else
 676      searchdirs="$with_kerberos5 /usr/kerberos /usr/kerberosIV /usr/athena /usr"
 677   fi
 678   with_kerberos=
 679   ac_saveLDFLAGS="$LDFLAGS"
 680   for dir in $searchdirs
 681   do
 682      AC_MSG_CHECKING([for Kerberos IV in $dir])
 683      if test -f "$dir/include/krb.h" || test -f "$dir/include/krb4.h" \
 684             || test -f "$dir/include/kerberosIV/krb.h"
 685      then
 686         AC_MSG_RESULT([found])
 687      else
 688         AC_MSG_RESULT([not found])
 689        continue
 690      fi
 691      #Find libs
 692      if test -f "$with_kerberos5/roken.h" ; then
 693        AC_CHECK_LIB(45, krb_mk_req)
 694      fi
 695      LDFLAGS="-L$dir/lib $ac_saveLDFLAGS"
 696      if test `uname` = "FreeBSD"; then
 697         AC_SEARCH_LIBS(_ossl_old_des_string_to_key, [des425 des crypto], [], continue)
 698      else
 699         AC_SEARCH_LIBS(des_string_to_key, [crypto], [], continue)
 700      fi
 701      AC_SEARCH_LIBS(krb_realmofhost, [krb4 krb], [], continue)
 702      with_kerberos="$dir"
 703      if test -f "$dir/include/kerberosIV/krb.h" ; then
 704         dir="$dir/include/kerberosIV"
 705      else
 706        dir="$dir/include"
 707      fi
 708      KERBEROS_V4=1
 709      test -f "$with_kerberos5/roken.h" && AC_DEFINE(HEIMDAL)
 710      test "$dir" != "/usr/include" && CFLAGS="$CFLAGS -I$dir"
 711      LDFLAGS="$LDFLAGS -L$with_kerberos/lib"
 712      break
 713   done
 714   if test -z "$with_kerberos" ; then
 715      AC_MSG_ERROR([Kerberos 4 libraries not found])
 716   fi
 717   LDFLAGS="$ac_saveLDFLAGS"
 718 fi
 719 fi
 720 ]) dnl --with-kerberos=DIR
 721 if test "$KERBEROS_V4" = 1 ; then
 722     AC_DEFINE(KERBEROS_V4,1,Define if you have Kerberos V4)
 723 fi
 724 AM_CONDITIONAL(KERBEROS_V4_ENABLE, test "$KERBEROS_V4" = 1)
 725
 726 ###     use option --with-ssl to compile in the SSL support
 727 AC_ARG_WITH(ssl,
 728         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 729         [with_ssl=$withval],
 730         [with_ssl=no])
 731 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 732
 733 if test "$with_ssl" = "yes"
 734 then
 735     #   User didn't specify an SSL location.  Let's look at some common
 736     #   directories where SSL has been found in the past and try and auto
 737     #   configure for SSL.  OpenSSL determination will be made later.
 738     #   This will screw up if an OpenSSL install is located in a later
 739     #   directory than an older SSLeay install, but the user should fix that
 740     #   anyways and he can override on the configure line.
 741     #   Just testing for directories is not sufficient, /usr exists on
 742     #   all systems!
 743     for ac_dir in \
 744       /usr/local/ssl \
 745       /usr/local \
 746       /usr/ssl \
 747       /usr \
 748       /local/ssl \
 749       /opt/ssl \
 750       /opt/csw \
 751       ; \
 752     do
 753         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 754             with_ssl=$ac_dir
 755             break;
 756         fi
 757     done
 758 fi
 759
 760 if test -n "$with_ssl" -a "$with_ssl" != "no"
 761 then
 762   # With the autoconfigure above, the only time this is going to be
 763   # true is going to be when we could not find the headers.  If they
 764   # are not in system standard locations, we are going to be broken.
 765   if test "$with_ssl" = "yes"
 766   then
 767     # Let's just define the standard location for the SSLeay root
 768     with_ssl="/usr/local/ssl"
 769   fi
 770   if test -r $with_ssl/include/openssl/ssl.h
 771   then
 772     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 773     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 774     test "$with_ssl" != "/usr" && CFLAGS="$CFLAGS -I$with_ssl/include"
 775     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 776     ### force the Kerberos direcory onto the include path so it will build.
 777     CFLAGS="$CFLAGS -I/usr/kerberos/include"
 778     ### OpenBSD comes with ssl headers
 779   else
 780     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 781   fi
 782   LDFLAGS="$LDFLAGS -L$with_ssl/lib"
 783   LIBS="$LIBS -lssl -lcrypto"
 784   dnl check if -ldl is needed
 785   AC_MSG_CHECKING([for additional library dependencies of SSL])
 786   found=0
 787   save_LIBS="$LIBS"
 788   for i in "" "-ldl" ; do
 789       LIBS="$LDFLAGS $save_LIBS $i"
 790       AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <openssl/ssl.h>],[SSL_library_init()])],[found=1; break])
 791   done
 792   if test $found = 0 ; then
 793       AC_MSG_RESULT([error])
 794       AC_MSG_ERROR([cannot link with SSL - check config.log])
 795   fi
 796   LIBS="$save_LIBS $i"
 797   if test "$i" = "" ; then i="(none)" ; fi
 798   AC_MSG_RESULT($i)
 799   dnl XXX FIXME: use pkg-config if available!
 800   AC_DEFINE(SSL_ENABLE)
 801 else
 802   AC_MSG_NOTICE(Disabling SSL support.)
 803 fi
 804
 805 ###     use option --with-socks=DIR to point at SOCKS library
 806 AC_ARG_WITH(socks,
 807         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 808 [
 809 if test "$with_socks" != no
 810 then
 811     if test "$with_socks" != yes
 812     then
 813         LDFLAGS="$LDFLAGS -L$with_socks"
 814     else
 815         AC_CHECK_LIB(socks, Rconnect,,
 816                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 817     fi
 818     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 819     CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 820     LIBS="-lsocks $LIBS"
 821 fi])
 822
 823 ###     use option --with-socks5=DIR to point at SOCKS library
 824 AC_ARG_WITH(socks5,
 825         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 826 [
 827 if test "$with_socks5" != no
 828 then
 829   if test "$with_socks5" != yes
 830   then
 831     LDFLAGS="$LDFLAGS -L$with_socks5"
 832   fi
 833   ac_savedLDFLAGS="$LDFLAGS"
 834   LDFLAGS="$LDFLAGS $LDFLAGS"
 835   AC_CHECK_LIB(socks5, SOCKSconnect,,
 836         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 837   AC_DEFINE(HAVE_SOCKS)
 838   CFLAGS="$CFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 839   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 840   LDFLAGS="$ac_savedLDFLAGS"
 841 fi])
 842
 843 dnl for libesmtp/ modules:
 844 ACX_WHICH_GETHOSTBYNAME_R
 845
 846 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 847 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 848
 849 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 850 AC_ARG_WITH(gssapi,
 851         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 852 [
 853 if test "$with_gssapi" != "no"
 854 then
 855   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 856   then
 857     with_gssapi=$with_kerberos5
 858   fi
 859
 860   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 861   then
 862     CFLAGS="$CFLAGS -I$with_gssapi/include"
 863     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 864   fi
 865
 866   dnl obtain gssapi default libs
 867   if krb5-config --libs gssapi 2>/dev/null >/dev/null ; then
 868       LIBS="$LIBS `krb5-config --libs gssapi`"
 869   else
 870     AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 871     if test -n "$nogss"
 872     then
 873       # -lgss not found
 874       if test "$with_gssapi" = yes ; then
 875           with_gssapi=/usr
 876       fi
 877       if test -f "$with_gssapi/include/roken.h" -o -f "$with_gssapi/include/krb5/roken.h"
 878       then
 879          # have roken.h, assume Heimdal
 880          case `uname` in
 881              NetBSD) LIBS="$LIBS -lkrb5" ;;
 882              *)      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl" ;;
 883          esac
 884          AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 885                       AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 886          AC_DEFINE(HEIMDAL)
 887       else
 888          # no roken.h, assume MIT
 889          AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 890                       AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 891       fi
 892     fi
 893   fi
 894   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 895   if test "$with_gssapi" != yes ; then
 896     CPPFLAGS="$CPPFLAGS -I$with_gssapi/include"
 897   fi
 898   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 899   if test "$ac_cv_header_gssapi_h" = "yes"; then
 900     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 901   else
 902     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 903   fi
 904 fi])
 905
 906 dnl ,------------------------------------------------------------------
 907 dnl Check if we need TRIO
 908 needtrio=0
 909 if test "$FORCE_TRIO" = "yes" ; then
 910     needtrio=1
 911     ac_cv_func_vsnprintf=no
 912     ac_cv_func_snprintf=no
 913 fi
 914 if test "x$ac_cv_func_snprintf" != "xyes" ; then
 915     AC_DEFINE(snprintf, trio_snprintf,
 916               [Define to trio_snprintf if your system lacks snprintf])
 917     needtrio=1
 918 fi
 919 if test "x$ac_cv_func_vsnprintf" != "xyes" ; then
 920     AC_DEFINE(vsnprintf, trio_vsnprintf,
 921               [Define to trio_vsnprintf if your system lacks vsnprintf])
 922     needtrio=1
 923 fi
 924 AM_CONDITIONAL(NEED_TRIO, test "$needtrio" = 1)
 925
 926 dnl TRIO IEEE compiler option for Alpha
 927 dnl
 928 if test "$needtrio" = 1 ; then
 929     AC_MSG_CHECKING(for IEEE compilation options)
 930     AC_CACHE_VAL(ac_cv_ieee_option, [
 931     AC_TRY_COMPILE(,[
 932     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
 933     # error "Option needed"
 934     #endif
 935     ],ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
 936     AC_TRY_COMPILE(,[
 937     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
 938     # error "Option needed"
 939     #endif
 940     ],ac_cv_ieee_option="-ieee",
 941     AC_TRY_COMPILE(,[
 942     #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
 943     # error "Option needed"
 944     #endif
 945     ],ac_cv_ieee_option="-mieee",
 946     ac_cv_ieee_option="none"
 947     )
 948     )
 949     )
 950     ])
 951     AC_MSG_RESULT($ac_cv_ieee_option)
 952     if test $ac_cv_ieee_option != none; then
 953       CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
 954     fi
 955 fi
 956 dnl ----------------------------------------------------------------'
 957
 958 AC_CONFIG_FILES([Makefile po/Makefile.in genlsm.sh])
 959 AC_OUTPUT
 960
 961 dnl Local Variables:
 962 dnl comment-start: "dnl "
 963 dnl comment-end: ""
 964 dnl comment-start-skip: "\\bdnl\\b\\s *"
 965 dnl compile-command: "make configure config.h.in"
 966 dnl End: