Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 #
   3 # Fetchmail automatic configuration support
   4 #
   5 # Eric S. Raymond <esr@thyrsus.com>
   6 # 2004 - 2010 Matthias Andree <matthias.andree@gmx.de>
   7 #
   8 dnl Process this file with autoconf to produce a configure script.
   9 dnl
  10
  11 dnl XXX - if bumping version here, check fetchmail.man, too!
  12 AC_INIT([fetchmail],[6.4.0-alpha1],[fetchmail-devel@lists.berlios.de])
  13 AC_CONFIG_SRCDIR([fetchmail.h])
  14 AC_CONFIG_HEADERS([config.h])
  15 AC_CONFIG_LIBOBJ_DIR([.])
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl keep this before stuff that runs the compiler!
  20 AC_USE_SYSTEM_EXTENSIONS
  21
  22 dnl automake options are in Makefile.am
  23 AC_PREREQ(2.64)
  24 dnl 2.60 required for AC_USE_SYSTEM_EXTENSIONS
  25 AM_INIT_AUTOMAKE
  26
  27 dnl python is optional
  28 #
  29 # you can pass PYTHON=: in environment or on the command line
  30 # to disable python detection and continue without building/installing
  31 # fetchmail.conf -- be sure to check README.packaging, too!
  32 #
  33 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  34 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  35
  36 AC_PROG_AWK
  37 AC_PROG_CC_C99
  38 AC_PROG_INSTALL
  39 AM_PROG_LEX
  40 AC_PROG_MAKE_SET
  41 AC_PROG_RANLIB
  42 AC_PROG_YACC
  43
  44 dnl check for b0rked Solaris (and other shells) and find one that works
  45 AC_MSG_CHECKING(for a working shell...)
  46 for i in /usr/xpg6/bin/sh /usr/xpg4/bin/sh /usr/ccs/bin/sh /bin/sh /usr/bin/sh /bin/ksh /bin/bash /usr/local/bin/bash ; do
  47     $i -c 'if ! false ; then echo $(echo ok) ; fi' >config.$$ 2>/dev/null
  48     j=`cat config.$$`
  49     rm -f config.$$
  50     if test "x$j" = "xok" ; then
  51         SHELL=$i
  52         AC_SUBST(SHELL)
  53         break
  54     fi
  55 done
  56 AC_MSG_RESULT($SHELL)
  57 if test "x$SHELL" = "x" ; then
  58     AC_MSG_ERROR(no SUS compliant shell found - on Solaris, install SUNWxcu4)
  59 fi
  60
  61 AC_CHECK_HEADERS([arpa/nameser.h])
  62
  63 AC_CHECK_HEADERS([resolv.h],,,[
  64 #include <sys/types.h>
  65 #include <netinet/in.h>
  66 #ifdef HAVE_ARPA_NAMESER_H
  67 #include <arpa/nameser.h>
  68 #endif
  69 ])
  70
  71 AC_CHECK_DECLS([h_errno],,,[
  72         AC_INCLUDES_DEFAULT
  73         #include <netdb.h>
  74 ])
  75
  76 # Check for OS special cases
  77 case $host_os in
  78 darwin*)
  79     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
  80     CPPFLAGS="$CPPFLAGS -DBIND_8_COMPAT"
  81     ;;
  82 # Check for FreeBSD special case: more libs needed
  83 freebsd*)
  84     AC_MSG_NOTICE(found FreeBSD - Adding -lkvm -lcom_err to standard libraries)
  85     LIBS="$LIBS -lkvm -lcom_err"
  86     ;;
  87 esac
  88
  89 AC_CACHE_SAVE
  90
  91 dnl i18n
  92 AM_GNU_GETTEXT([external], [need-ngettext])
  93 AM_GNU_GETTEXT_VERSION([0.17])
  94 dnl end i18n
  95
  96 # Under sysV68, socket and friends are provided by the C library.
  97 # -linet does not provide socket, but causes multiple definition
  98 # errors at link-time.  It is thus better to only use the C library.
  99 # So don't add -linet to the link list unless it's necessary
 100 AC_CHECK_FUNC(socket,
 101     AC_MSG_RESULT(using libc's socket),
 102     AC_CHECK_LIB(socket,socket)
 103     AC_CHECK_LIB(inet,socket))
 104
 105 # The condition in this test copes with the presence of inet_addr in libc6.
 106 AC_CHECK_FUNC(inet_addr,
 107     AC_MSG_RESULT(using libc's inet_addr),
 108     AC_CHECK_LIB(nsl,inet_addr))
 109
 110 AC_REPLACE_FUNCS([stpcpy strlcpy strlcat])
 111
 112 AC_CHECK_FUNC(getopt_long, [],
 113               [AC_LIBSOURCES([getopt.c, getopt1.c])
 114                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 115
 116 AC_SUBST(EXTRAOBJ)
 117
 118 AC_CHECK_FUNCS(vsyslog inet_aton)
 119
 120 dnl INET6 is used by KAME/getnameinfo
 121 AC_CACHE_CHECK(for AF_INET6/PF_INET6,ac_cv_inet6,
 122 AC_COMPILE_IFELSE([
 123   AC_LANG_PROGRAM([[
 124     #include <sys/types.h>
 125     #include <sys/socket.h>
 126   ]],[[
 127     int foo = AF_INET6;
 128     int bar = PF_INET6;
 129   ]])],
 130   ac_cv_inet6=yes , ac_cv_inet6=no
 131 ))
 132 if test "x$ac_cv_inet6" = xyes
 133 then
 134     AC_DEFINE(INET6,1,Define to 1 if your system defines AF_INET6 and PF_INET6.)
 135 fi
 136
 137 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 138 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 139 # library.  So don't add -lresolv to the link list unless it's necessary
 140 # (It will be necessary when using GNU libc6).
 141 old_LIBS="$LIBS"
 142 for lib in '' -lresolv; do
 143     if test -z "$lib"; then
 144        AC_MSG_CHECKING([for res_search in libc])
 145     else
 146        AC_MSG_CHECKING([for res_search in $lib])
 147     fi
 148     LIBS="$old_LIBS $lib"
 149     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 150 #include <sys/types.h>
 151 #include <netinet/in.h>
 152 #ifdef HAVE_ARPA_NAMESER_H
 153 #include <arpa/nameser.h>
 154 #endif
 155 #ifdef HAVE_RESOLV_H
 156 #include <resolv.h>
 157 #endif
 158 extern int res_search();
 159 ]], [[res_search(0, 0, 0, 0, 0); dn_skipname(0,0);]])],
 160     [AC_MSG_RESULT([found])
 161      AC_DEFINE(HAVE_RES_SEARCH, [1],
 162                [Define to 1 if you have the 'res_search' and 'dn_skipname' functions.])
 163      break], [AC_MSG_RESULT([not found])])
 164      LIBS=$old_LIBS
 165 done
 166
 167 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 168 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 169
 170 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 171 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 172 /* NetBSD declares sys_siglist in <unistd.h>.  */
 173 #include <unistd.h>
 174 ]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 175
 176 AC_DEFINE_UNQUOTED(PID_DIR, "/var/run", directory for PID lock files)
 177
 178 # We may have a fallback MDA available in case the socket open to the
 179 # local SMTP listener fails.  Best to use procmail for this, as we know
 180 # it won't try delivering through local SMTP and cause a mail loop.
 181 # Sendmail without the -t option to use the message headers will work too,
 182 # not just for sendmail itself but for workalikes like exim.
 183 #
 184 # Note1: A disadvantage of using procmail is that local alias expansion
 185 # according to /etc/aliases won't get done if we fall back.  This doesn't
 186 # matter in single-drop mode.
 187 #
 188 # Note2: it would be a very bad idea to use any MDA that doesn't return
 189 # a refuse-to-deliver status on disk- or process-table-full
 190 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 191 # like exim that might be lurking under a sendmail alias) do the right
 192 # thing in this circumstance.  Matthias Andree warns that procmail does
 193 # not.
 194 #
 195 # Note3: Defalt value of fallback is now off.  Matthias writes:
 196 #
 197 # 1. there is no way to predict when the fallback is used. With some MTAs
 198 #    (such as those limiting load average), outer circumstances can cause
 199 #    the fallback to kick in.
 200 #
 201 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 202 #    not only about alias expansion, .forwards to special filters won't
 203 #    work, mail may end up in a different place (users claim "mail loss"
 204 #    for that).
 205 #
 206 # 3. The claim procmail did the right thing with its exit codes is plain
 207 #    wrong. I've seen procmail exit with code 1 when it should have exited
 208 #    with code 75, like, configuration errors. Procmail is a dangerous
 209 #    beast and is best replaced by maildrop.
 210 #
 211 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 212 #    cannot tell which one it should choose. Say, your MTA is configured
 213 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 214 #    chooses procmail, this is plain wrong.
 215 #
 216
 217 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 218 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 219 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 220
 221 ###     use option --disable-fallback to disable fallback MDA
 222 ###     use option --enable-fallback=procmail or
 223 ###                --enable-fallback=sendmail to select
 224 AC_ARG_ENABLE(fallback,
 225         [  --enable-fallback=procmail    enable procmail as fallback
 226   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 227   --enable-fallback=maildrop    enable maildrop as fallback
 228   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 229
 230 case "$enable_fallback" in
 231         sendmail)       if test -z "$sendmail" ; then
 232                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 233                                 #not reached
 234                         fi
 235                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 236                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 237                         ;;
 238         procmail)       if test -z "$procmail" ; then
 239                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 240                                 #not reached
 241                         fi
 242                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 243                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 244                         ;;
 245         maildrop)       if test -z "$maildrop" ; then
 246                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 247                                 #not reached
 248                         fi
 249                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 250                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 251                         ;;
 252         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 253                         ;;
 254         auto|yes|set)   if test -n "$sendmail" ; then
 255                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 256                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 257                         else
 258                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 259                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 260                         fi
 261                         ;;
 262         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 263                         #notreached
 264                         ;;
 265 esac
 266
 267 ###     use option --disable-POP3 to omit the POP3 support
 268 AC_ARG_ENABLE(POP3,
 269         [  --disable-POP3          don't compile in POP3 protocol support],
 270         [with_POP3=$enableval],
 271         [with_POP3=yes])
 272 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 273 AM_CONDITIONAL(POP3_ENABLE, test "$with_POP3" = yes)
 274
 275 ###     use option --disable-IMAP to omit the IMAP support
 276 AC_ARG_ENABLE(IMAP,
 277         [  --disable-IMAP          don't compile in IMAP protocol support],
 278         [with_IMAP=$enableval],
 279         [with_IMAP=yes])
 280 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,Define if you want IMAP support compiled in)
 281 AM_CONDITIONAL(IMAP_ENABLE, test "$with_IMAP" = yes)
 282
 283 ###     use option --disable-ETRN to omit the ETRN support
 284 AC_ARG_ENABLE(ETRN,
 285         [  --disable-ETRN          don't compile in ETRN protocol support],
 286         [with_ETRN=$enableval],
 287         [with_ETRN=yes])
 288 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 289 AM_CONDITIONAL(ETRN_ENABLE, test "$with_ETRN" = yes)
 290
 291 ###     use option --disable-ODMR to omit the ODMR support
 292 AC_ARG_ENABLE(ODMR,
 293         [  --disable-ODMR          don't compile in ODMR protocol support],
 294         [with_ODMR=$enableval],
 295         [with_ODMR=yes])
 296 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 297 AM_CONDITIONAL(ODMR_ENABLE, test "$with_ODMR" = yes)
 298
 299 ###     use option --enable-RPA to compile in the RPA support
 300 AC_ARG_ENABLE(RPA,
 301         [  --enable-RPA            compile in RPA protocol support],
 302         [with_RPA=$enableval],
 303         [with_RPA=no])
 304 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 305 AM_CONDITIONAL(RPA_ENABLE, test "$with_RPA" = yes)
 306
 307 ###     use option --enable-NTLM to compile in the NTLM support
 308 AC_ARG_ENABLE(NTLM,
 309         [  --enable-NTLM           compile in NTLM authentication support],
 310         [with_NTLM=$enableval],
 311         [with_NTLM=no])
 312 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 313 AM_CONDITIONAL(NTLM_ENABLE, test "$with_NTLM" = yes)
 314
 315 ###     use option --enable-SDPS to compile in the SDPS support
 316 AC_ARG_ENABLE(SDPS,
 317         [  --enable-SDPS           compile in SDPS protocol support],
 318         [with_SDPS=$enableval],
 319         [with_SDPS=no])
 320 if test "$with_SDPS" = yes ; then
 321    if test "$with_POP3" != yes ; then
 322        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 323        with_SDPS=no
 324    else
 325        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 326    fi
 327 fi
 328 if test "$with_POP3" != yes && test "$with_IMAP"  != yes ; then
 329     AC_MSG_ERROR([You must enable at least one of POP3 and IMAP.])
 330 fi
 331
 332 AC_CACHE_SAVE
 333
 334 ###     use option --enable-opie to compile in the OPIE support
 335 AC_ARG_ENABLE(opie,
 336         [  --enable-opie           support OTP through the OPIE library],
 337         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR(cannot find <opie.h>, which is required for OPIE support.)])
 338           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR(cannot find libopie, which is required for OPIE support.)])
 339           with_opie=$enableval],
 340         [with_opie=no])
 341 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 342
 343 dnl Mostly stolen from gnulib's getaddrinfo.m4
 344 AC_SEARCH_LIBS(getaddrinfo, [nsl socket])
 345 AC_CACHE_CHECK([for getaddrinfo],[fm_cv_getaddrinfo],[
 346   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 347 #include <sys/types.h>
 348 #include <sys/socket.h>
 349 #include <netdb.h>
 350   ]], [[getaddrinfo(0, 0, 0, 0);]])],[ fm_cv_getaddrinfo=yes],[ fm_cv_getaddrinfo=no ])
 351 ])
 352
 353 if test x"$fm_cv_getaddrinfo" = "xyes"; then
 354      AC_DEFINE(HAVE_GETADDRINFO, 1,
 355       [Define to 1 if you have the getaddrinfo function.])
 356 fi
 357
 358 AC_CACHE_CHECK([for getnameinfo],[fm_cv_getnameinfo],[
 359   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 360 #include <sys/types.h>
 361 #include <sys/socket.h>
 362 #include <netdb.h>
 363 #ifndef NULL
 364 #define NULL 0
 365 #endif
 366   ]], [[getnameinfo(NULL,0, NULL,0, NULL, 0, 0);]])],[ fm_cv_getnameinfo=yes],[ fm_cv_getnameinfo=no ])
 367 ])
 368 if test $fm_cv_getnameinfo = yes ; then
 369     AC_DEFINE(HAVE_GETNAMEINFO,1,[Define to 1 if your system has getnameinfo()])
 370 fi
 371
 372 AM_CONDITIONAL(NEED_GETADDRINFO, test "$fm_cv_getaddrinfo" != yes)
 373 AM_CONDITIONAL(NEED_GETNAMEINFO, test "$fm_cv_getnameinfo"   != yes)
 374
 375 AC_CHECK_FUNCS(inet_ntop)
 376 dnl Check if getaddrinfo is async-signal-safe - most implementations aren't
 377 if test "$fm_cv_getaddrinfo" = yes ; then
 378     AC_MSG_CHECKING(if your getaddrinfo is async-signal-safe)
 379     gai_ts=no
 380     dnl we have getaddrinfo() - check if the OS is known to have a async-signal-safe implementation
 381     case $host_os in
 382         darwin9*)                               gai_ts=yes ;;
 383         linux*)                                 gai_ts=yes ;;
 384         freebsd5.5|freebsd6*|freebsd7*)         gai_ts=yes ;;
 385         solaris2.8|solaris2.9|solaris2.10)      gai_ts=yes ;;
 386     esac
 387     AC_MSG_RESULT($gai_ts)
 388     if test $gai_ts = yes ; then
 389         AC_DEFINE(GETADDRINFO_ASYNCSAFE, 1, [define to 1 if you know your getaddrinfo function is async-signal-safe])
 390     fi
 391 fi
 392
 393 # This version of the Kerberos 5 options addresses the follwing issues:
 394 #
 395 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 396 #   OpenSSL support (Debian's is)
 397
 398 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 399 ### make sure --with-ssl is run before --with-kerberos* !
 400 AC_ARG_WITH(kerberos5,
 401        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 402 [
 403 if test "$with_kerberos5" != "no"
 404 then
 405 # Check for a OpenBSD special case
 406 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 407 then
 408   AS_MESSAGE(checking kerberosV for OpenBSD...)
 409   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 410   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 411   CFLAGS="$CFLAGS -I/usr/include/kerberosV"
 412   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 413 elif krb5-config 2> /dev/null >/dev/null ; then
 414   krb5_prefix=`krb5-config --prefix krb5`
 415   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 416   if test -f ${krb5_prefix}/include/et/com_err.h && \
 417    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 418     CFLAGS="$CFLAGS -I${krb5_prefix}/include/et"
 419   fi
 420   unset krb5_prefix
 421   CFLAGS="$CFLAGS `krb5-config --cflags krb5`"
 422   LIBS="$LIBS `krb5-config --libs krb5`"
 423   AC_DEFINE(KERBEROS_V5)
 424 else
 425   if test "$with_kerberos5" != "yes"
 426   then
 427       LDFLAGS="$LDFLAGS -L${with_kerberos5}/lib"
 428       searchdirs="$with_kerberos5"
 429   else
 430       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 431   fi
 432   with_kerberos5=
 433   for dir in $searchdirs
 434   do AC_MSG_CHECKING([for Kerberos V in $dir])
 435      if test -f "$dir/include/krb5.h" || test -f "$dir/include/krb5/krb5.h"
 436      then
 437         if test -d "$dir/include/krb5" ; then CPPFLAGS="$CPPFLAGS -I$dir/include/krb5" ; fi
 438         ac_krblibs=
 439         if test -f "$dir/include/roken.h" || test -f "$dir/include/krb5/roken.h"
 440         then
 441            ac_krblibs="-lasn1 -lroken -lcom_err"
 442            AC_MSG_RESULT([Heimdal found])
 443           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 444           dnl we assume we do if it is available
 445            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 446                 ${LDFLAGS})
 447            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 448               AC_CHECK_LIB(crypto, MD5_Init, [],
 449                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 450                 ${LDFLAGS} ${ac_krblibs}),
 451            ${LDFLAGS} ${ac_krblibs})
 452            AC_DEFINE(HEIMDAL)
 453         else
 454           AC_MSG_RESULT([found])
 455           ac_krblibs="-lcom_err"
 456            AC_CHECK_LIB(crypto,
 457              krb5_des_string_to_key,
 458              libk5crypto=-lcrypto,
 459                 AC_CHECK_LIB(k5crypto,
 460                    krb5_des_string_to_key,
 461                    libk5crypto=-lk5crypto,
 462                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 463                    ${LDFLAGS} ${ac_krblibs}),
 464                  ${LDFLAGS} ${ac_krblibs})
 465         fi
 466         AC_CHECK_LIB(krb5, krb5_init_context,[],
 467            continue,
 468            ${LDFLAGS} ${ac_krblibs})
 469         AC_DEFINE(KERBEROS_V5)
 470         test "$dir" != "/usr" && CFLAGS="$CFLAGS -I$dir/include"
 471         LDFLAGS="$LDFLAGS -L$dir/lib"
 472        LIBS="$LIBS $ac_krblibs $libk5crypto"
 473         with_kerberos5=$dir
 474         break
 475      else
 476         AC_MSG_RESULT([not found])
 477      fi
 478   done
 479   if test -z "$with_kerberos5" ; then
 480      AC_MSG_ERROR([Kerberos 5 libraries not found])
 481   fi
 482 fi
 483 fi
 484 ]) dnl --with-kerberos5=DIR
 485
 486 ###     use option --with-ssl to compile in the SSL support
 487 AC_ARG_WITH(ssl,
 488         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 489         [with_ssl=$withval],
 490         [with_ssl=no])
 491 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 492
 493 if test "$with_ssl" = "yes"
 494 then
 495     #   User didn't specify an SSL location.  Let's look at some common
 496     #   directories where SSL has been found in the past and try and auto
 497     #   configure for SSL.  OpenSSL determination will be made later.
 498     #   This will screw up if an OpenSSL install is located in a later
 499     #   directory than an older SSLeay install, but the user should fix that
 500     #   anyways and he can override on the configure line.
 501     #   Just testing for directories is not sufficient, /usr exists on
 502     #   all systems!
 503     for ac_dir in \
 504       /usr/local/ssl \
 505       /usr/local \
 506       /usr/ssl \
 507       /usr \
 508       /local/ssl \
 509       /opt/ssl \
 510       /opt/csw \
 511       ; \
 512     do
 513         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 514             with_ssl=$ac_dir
 515             break;
 516         fi
 517     done
 518 fi
 519
 520 if test -n "$with_ssl" -a "$with_ssl" != "no"
 521 then
 522   # With the autoconfigure above, the only time this is going to be
 523   # true is going to be when we could not find the headers.  If they
 524   # are not in system standard locations, we are going to be broken.
 525   if test "$with_ssl" = "yes"
 526   then
 527     # Let's just define the standard location for the SSLeay root
 528     with_ssl="/usr/local/ssl"
 529   fi
 530   if test -r $with_ssl/include/openssl/ssl.h
 531   then
 532     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 533     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 534     test "$with_ssl" != "/usr" && CFLAGS="$CFLAGS -I$with_ssl/include"
 535     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 536     ### force the Kerberos direcory onto the include path so it will build.
 537     CFLAGS="$CFLAGS -I/usr/kerberos/include"
 538     ### OpenBSD comes with ssl headers
 539   else
 540     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 541   fi
 542   LDFLAGS="$LDFLAGS -L$with_ssl/lib"
 543   LIBS="$LIBS -lssl -lcrypto"
 544   dnl check if -ldl is needed
 545   AC_MSG_CHECKING([for additional library dependencies of SSL])
 546   found=0
 547   save_LIBS="$LIBS"
 548   for i in "" "-ldl" ; do
 549       LIBS="$LDFLAGS $save_LIBS $i"
 550       AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <openssl/ssl.h>],[SSL_library_init()])],[found=1; break])
 551   done
 552   if test $found = 0 ; then
 553       AC_MSG_RESULT([error])
 554       AC_MSG_ERROR([cannot link with SSL - check config.log])
 555   fi
 556   LIBS="$save_LIBS $i"
 557   if test "$i" = "" ; then i="(none)" ; fi
 558   AC_MSG_RESULT($i)
 559   dnl XXX FIXME: use pkg-config if available!
 560   AC_DEFINE(SSL_ENABLE)
 561 else
 562   AC_MSG_NOTICE(Disabling SSL support.)
 563 fi
 564
 565 ###     use option --with-socks=DIR to point at SOCKS library
 566 AC_ARG_WITH(socks,
 567         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 568 [
 569 if test "$with_socks" != no
 570 then
 571     if test "$with_socks" != yes
 572     then
 573         LDFLAGS="$LDFLAGS -L$with_socks"
 574     else
 575         AC_CHECK_LIB(socks, Rconnect,,
 576                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 577     fi
 578     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 579     CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 580     LIBS="-lsocks $LIBS"
 581 fi])
 582
 583 ###     use option --with-socks5=DIR to point at SOCKS library
 584 AC_ARG_WITH(socks5,
 585         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 586 [
 587 if test "$with_socks5" != no
 588 then
 589   if test "$with_socks5" != yes
 590   then
 591     LDFLAGS="$LDFLAGS -L$with_socks5"
 592   fi
 593   ac_savedLDFLAGS="$LDFLAGS"
 594   LDFLAGS="$LDFLAGS $LDFLAGS"
 595   AC_CHECK_LIB(socks5, SOCKSconnect,,
 596         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 597   AC_DEFINE(HAVE_SOCKS)
 598   CFLAGS="$CFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 599   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 600   LDFLAGS="$ac_savedLDFLAGS"
 601 fi])
 602
 603 dnl for libesmtp/ modules:
 604 ACX_WHICH_GETHOSTBYNAME_R
 605
 606 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 607 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 608
 609 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 610 AC_ARG_WITH(gssapi,
 611         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 612 [
 613 if test "$with_gssapi" != "no"
 614 then
 615   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 616   then
 617     with_gssapi=$with_kerberos5
 618   fi
 619
 620   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 621   then
 622     CFLAGS="$CFLAGS -I$with_gssapi/include"
 623     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 624   fi
 625
 626   dnl obtain gssapi default libs
 627   if krb5-config --libs gssapi 2>/dev/null >/dev/null ; then
 628       LIBS="$LIBS `krb5-config --libs gssapi`"
 629   else
 630     AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 631     if test -n "$nogss"
 632     then
 633       # -lgss not found
 634       if test "$with_gssapi" = yes ; then
 635           with_gssapi=/usr
 636       fi
 637       if test -f "$with_gssapi/include/roken.h" -o -f "$with_gssapi/include/krb5/roken.h"
 638       then
 639          # have roken.h, assume Heimdal
 640          case `uname` in
 641              NetBSD) LIBS="$LIBS -lkrb5" ;;
 642              *)      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl" ;;
 643          esac
 644          AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 645                       AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 646          AC_DEFINE(HEIMDAL)
 647       else
 648          # no roken.h, assume MIT
 649          AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 650                       AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 651       fi
 652     fi
 653   fi
 654   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 655   if test "$with_gssapi" != yes ; then
 656     CPPFLAGS="$CPPFLAGS -I$with_gssapi/include"
 657   fi
 658   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 659   if test "$ac_cv_header_gssapi_h" = "yes"; then
 660     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 661   else
 662     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 663   fi
 664 fi])
 665
 666 AC_CONFIG_FILES([Makefile po/Makefile.in genlsm.sh])
 667 AC_OUTPUT
 668
 669 dnl Local Variables:
 670 dnl comment-start: "dnl "
 671 dnl comment-end: ""
 672 dnl comment-start-skip: "\\bdnl\\b\\s *"
 673 dnl compile-command: "make configure config.h.in"
 674 dnl End: