Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [3])
  12 m4_define([gtk_minor_version], [3])
  13 m4_define([gtk_micro_version], [1])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Define a string for the earliest version that this release has
  33 # backwards binary compatibility with for all interfaces a module
  34 # might. Unless we add module-only API with lower stability
  35 # guarantees, this should be unchanged until we break binary compat
  36 # for GTK+.
  37 #
  38 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  39 m4_define([gtk_binary_version], [3.0.0])
  40
  41 # required versions of other packages
  42 m4_define([glib_required_version], [2.31.0])
  43 m4_define([pango_required_version], [1.29.0])
  44 m4_define([atk_required_version], [2.1.5])
  45 m4_define([cairo_required_version], [1.10.0])
  46 m4_define([gdk_pixbuf_required_version], [2.23.5])
  47 m4_define([introspection_required_version], [0.10.1])
  48 GLIB_REQUIRED_VERSION=glib_required_version
  49 PANGO_REQUIRED_VERSION=pango_required_version
  50 ATK_REQUIRED_VERSION=atk_required_version
  51 CAIRO_REQUIRED_VERSION=cairo_required_version
  52 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  53 INTROSPECTION_REQUIRED_VERSION=introspection_required_version
  54
  55 AC_SUBST(GLIB_REQUIRED_VERSION)
  56 AC_SUBST(PANGO_REQUIRED_VERSION)
  57 AC_SUBST(ATK_REQUIRED_VERSION)
  58 AC_SUBST(CAIRO_REQUIRED_VERSION)
  59 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  60 AC_SUBST(INTROSPECTION_REQUIRED_VERSION)
  61
  62 # Save this value here, since automake will set cflags later
  63 cflags_set=${CFLAGS+set}
  64
  65 AM_INIT_AUTOMAKE([1.11 -Wall no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  66 AM_MAINTAINER_MODE([enable])
  67
  68 # Support silent build rules. Disable
  69 # by either passing --disable-silent-rules to configure or passing V=1
  70 # to make
  71 AM_SILENT_RULES([yes])
  72
  73 #
  74 # For each of the libraries we build, we define the following
  75 # substituted variables:
  76 #
  77 # foo_PACKAGES:     pkg-config packages this library requires
  78 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  79 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  80 # foo_DEP_LIBS:     All libraries this module requires
  81 # foo_DEP_CFLAGS:   All cflags this module requires
  82
  83
  84 GTK_MAJOR_VERSION=gtk_major_version
  85 GTK_MINOR_VERSION=gtk_minor_version
  86 GTK_MICRO_VERSION=gtk_micro_version
  87 GTK_INTERFACE_AGE=gtk_interface_age
  88 GTK_BINARY_AGE=gtk_binary_age
  89 GTK_VERSION=gtk_version
  90 GTK_API_VERSION=gtk_api_version
  91 GTK_BINARY_VERSION=gtk_binary_version
  92 AC_SUBST(GTK_MAJOR_VERSION)
  93 AC_SUBST(GTK_MINOR_VERSION)
  94 AC_SUBST(GTK_MICRO_VERSION)
  95 AC_SUBST(GTK_INTERFACE_AGE)
  96 AC_SUBST(GTK_BINARY_AGE)
  97 AC_SUBST(GTK_API_VERSION)
  98 AC_SUBST(GTK_VERSION)
  99 AC_SUBST(GTK_BINARY_VERSION)
 100
 101 # libtool versioning
 102 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
 103 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 104 #LT_REVISION=$GTK_INTERFACE_AGE
 105 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 106 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 107
 108 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 109 m4_define([lt_revision], [gtk_interface_age])
 110 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 111 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 112 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 113 AC_SUBST(LT_VERSION_INFO)
 114 AC_SUBST(LT_CURRENT_MINUS_AGE)
 115
 116 m4_define([gail_lt_current],[0])
 117 m4_define([gail_lt_revision],[0])
 118 m4_define([gail_lt_age],[0])
 119 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 120 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 121 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 122 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 123
 124 # Checks for programs.
 125 AC_PROG_CC
 126 AC_PROG_CC_C_O
 127 AC_PROG_CC_STDC
 128 AC_PROG_INSTALL
 129 AC_PROG_MAKE_SET
 130
 131
 132 GETTEXT_PACKAGE=gtk30
 133 AC_SUBST(GETTEXT_PACKAGE)
 134 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 135                    [The prefix for our gettext translation domains.])
 136
 137 AC_CANONICAL_HOST
 138
 139 MATH_LIB=-lm
 140 AC_MSG_CHECKING([for native Win32])
 141 LIB_EXE_MACHINE_FLAG=X86
 142 EXE_MANIFEST_ARCHITECTURE=X86
 143 case "$host" in
 144   *-*-mingw*)
 145     os_win32=yes
 146     gio_can_sniff=no
 147     MATH_LIB=
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       EXE_MANIFEST_ARCHITECTURE=AMD64
 152       ;;
 153     esac
 154     ;;
 155   *)
 156     os_win32=no
 157     ;;
 158 esac
 159 AC_MSG_RESULT([$os_win32])
 160
 161 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 162 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 163
 164 case $host in
 165   *-*-linux*)
 166     os_linux=yes
 167     ;;
 168   *-*-openbsd*)
 169     os_openbsd=yes
 170     ;;
 171 esac
 172
 173 dnl
 174 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 175 dnl We use this for an automated test for C++ header correctness.
 176 dnl
 177 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 178 AC_LANG_PUSH([C++])
 179
 180 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]],
 181                                    [[class a { int b; } c;]])],
 182                   [],[CXX=])
 183 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 184
 185 gtk_save_cxxflags="$CXXFLAGS"
 186 CXXFLAGS="$CXXFLAGS -x objective-c++"
 187 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@interface Foo @end]],
 188                                    [[]])],
 189                   [OBJC=yes],[OBJC=no])
 190 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 191 CXXFLAGS="$gtk_save_cxxflags"
 192 AC_LANG_POP([C++])
 193
 194 if test "$os_win32" = "yes"; then
 195   if test x$enable_static = xyes -o x$enable_static = x; then
 196     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 197     enable_static=no
 198   fi
 199   if test x$enable_shared = xno; then
 200     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 201   fi
 202   enable_shared=yes
 203 fi
 204
 205 dnl Initialize libtool
 206 LT_PREREQ([2.2.6])
 207 LT_INIT([disable-static win32-dll])
 208 # Create libtool early, because it's used in configure
 209 LT_OUTPUT
 210
 211 # Make sure we use 64-bit versions of various file stuff.
 212 AC_SYS_LARGEFILE
 213
 214 AM_PROG_AS
 215 AC_PATH_PROG(NM, nm, nm)
 216
 217 AC_MSG_CHECKING([for some Win32 platform])
 218 case "$host" in
 219   *-*-mingw*|*-*-cygwin*)
 220     platform_win32=yes
 221     ;;
 222   *)
 223     platform_win32=no
 224     ;;
 225 esac
 226 AC_MSG_RESULT([$platform_win32])
 227 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 228
 229 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 230 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 231 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 232
 233 if test "$os_win32" = "yes"; then
 234   AC_CHECK_TOOL(WINDRES, windres, no)
 235   if test "$WINDRES" = no; then
 236     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 237   fi
 238   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 239 fi
 240 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 241
 242 m4_define([debug_default],
 243           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 244
 245 dnl declare --enable-* args and collect ac_help strings
 246 AC_ARG_ENABLE(debug,
 247               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 248                               [turn on debugging @<:@default=debug_default@:>@])],,
 249               [enable_debug=debug_default])
 250
 251 AC_ARG_ENABLE(rebuilds,
 252               [AS_HELP_STRING([--disable-rebuilds],
 253                               [disable all source autogeneration rules])],,
 254               [enable_rebuilds=yes])
 255
 256 AC_ARG_ENABLE(gtk2-dependency,
 257               [AS_HELP_STRING([--enable-gtk2-dependency],
 258                               [Do not build gtk-update-icon-cache and other shared tools])],,
 259               [enable_gtk2_dependency=no])
 260
 261 AM_CONDITIONAL(BUILD_ICON_CACHE, [test "x$enable_gtk2_dependency" = xno])
 262
 263 AC_ARG_ENABLE(xkb,
 264               [AS_HELP_STRING([--enable-xkb],
 265                               [support XKB extension [default=maybe]])],,
 266               [enable_xkb="maybe"])
 267 AC_ARG_ENABLE(xinerama,
 268               [AS_HELP_STRING([--enable-xinerama],
 269                               [support Xinerama extension if available [default=maybe]])],,
 270               [enable_xinerama="maybe"])
 271 AC_ARG_ENABLE(xinput,
 272               [AS_HELP_STRING([--enable-xinput],
 273                               [support XInput extension if available [default=yes]])],,
 274               [enable_xinput="maybe"])
 275 AC_ARG_ENABLE(xrandr,
 276               [AS_HELP_STRING([--enable-xrandr],
 277                               [support XRandR extension if available [default=maybe]])],,
 278               [enable_xrandr="maybe"])
 279 AC_ARG_ENABLE(xfixes,
 280               [AS_HELP_STRING([--enable-xfixes],
 281                               [support XFixes extension if available [default=maybe]])],,
 282               [enable_xfixes="maybe"])
 283 AC_ARG_ENABLE(xcomposite,
 284               [AS_HELP_STRING([--enable-xcomposite],
 285                               [support X Composite extension if available [default=maybe]])],,
 286               [enable_xcomposite="maybe"])
 287 AC_ARG_ENABLE(xdamage,
 288               [AS_HELP_STRING([--enable-xdamage],
 289                               [support X Damage extension if available [default=maybe]])],,
 290               [enable_xdamage="maybe"])
 291
 292 AC_ARG_ENABLE(x11-backend,
 293               [AS_HELP_STRING([--enable-x11-backend],
 294                               [enable the X11 gdk backend])],
 295                               [backend_set=yes])
 296 AC_ARG_ENABLE(win32-backend,
 297               [AS_HELP_STRING([--enable-win32-backend],
 298                               [enable the Win32 gdk backend])],
 299                               [backend_set=yes])
 300 AC_ARG_ENABLE(quartz-backend,
 301               [AS_HELP_STRING([--enable-quartz-backend],
 302                               [enable the quartz gdk backend])],
 303                               [backend_set=yes])
 304 AC_ARG_ENABLE(broadway-backend,
 305               [AS_HELP_STRING([--enable-broadway-backend],
 306                               [enable the broadway (HTML5) gdk backend])],
 307                               [backend_set=yes])
 308 AC_ARG_ENABLE(wayland-backend,
 309               [AS_HELP_STRING([--enable-wayland-backend],
 310                               [enable the wayland gdk backend])],
 311                               [backend_set=yes])
 312
 313 if test -z "$backend_set"; then
 314   if test "$platform_win32" = yes; then
 315     enable_win32_backend=yes
 316   else
 317     enable_x11_backend=yes
 318   fi
 319 fi
 320
 321 AC_ARG_ENABLE(quartz-relocation,
 322               [AS_HELP_STRING([--enable-quartz-relocation],
 323                               [enable bundle-based relocation functions])],
 324                               [quartz_relocation=yes])
 325
 326 cairo_backends=
 327 backend_immodules=
 328 GDK_BACKENDS=
 329 GDK_EXTRA_LIBS=
 330 GDK_EXTRA_CFLAGS=
 331 GDK_WINDOWING=
 332 GIO_PACKAGE=gio-2.0
 333 PANGO_PACKAGES="pango pangocairo"
 334
 335 if test "$enable_x11_backend" = "yes"; then
 336   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 337   # backend names are identical.
 338   cairo_backends="$cairo_backends cairo-xlib"
 339   GDK_BACKENDS="$GDK_BACKENDS x11"
 340   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 341   # gdkapplaunchcontext-x11.c
 342   GIO_PACKAGE=gio-unix-2.0
 343   backend_immodules="$backend_immodules,xim"
 344   GDK_WINDOWING="$GDK_WINDOWING
 345 #define GDK_WINDOWING_X11"
 346 fi
 347
 348 if test "$enable_win32_backend" = "yes"; then
 349   cairo_backends="$cairo_backends cairo-win32"
 350   GDK_BACKENDS="$GDK_BACKENDS win32"
 351   backend_immodules="$backend_immodules,ime"
 352   GDK_WINDOWING="$GDK_WINDOWING
 353 #define GDK_WINDOWING_WIN32"
 354   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 355   AM_CONDITIONAL(USE_WIN32, true)
 356   PANGO_PACKAGES="pangowin32 pangocairo"
 357 else
 358   AM_CONDITIONAL(USE_WIN32, false)
 359 fi
 360
 361 if test "x$enable_quartz_backend" = xyes; then
 362   cairo_backends="$cairo_backends cairo-quartz"
 363   GDK_BACKENDS="$GDK_BACKENDS quartz"
 364   GDK_WINDOWING="$GDK_WINDOWING
 365 #define GDK_WINDOWING_QUARTZ"
 366   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 367   AM_CONDITIONAL(USE_QUARTZ, true)
 368   if test "x$quartz_relocation" = xyes; then
 369     AC_DEFINE([QUARTZ_RELOCATION], [1], [Use NSBundle functions to determine load paths for libraries, translations, etc.])
 370   fi
 371
 372 else
 373   AM_CONDITIONAL(USE_QUARTZ, false)
 374 fi
 375
 376
 377 if test "x$enable_broadway_backend" == xyes; then
 378   GDK_BACKENDS="$GDK_BACKENDS broadway"
 379   cairo_backends="$cairo_backends cairo"
 380   GDK_WINDOWING="$GDK_WINDOWING
 381 #define GDK_WINDOWING_BROADWAY"
 382   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lz"
 383   AM_CONDITIONAL(USE_BROADWAY, true)
 384 else
 385   AM_CONDITIONAL(USE_BROADWAY, false)
 386 fi
 387
 388 if test "x$enable_wayland_backend" == "xyes"; then
 389   # Wayland uses cairo-gl
 390   cairo_backends="$cairo_backends cairo-gl"
 391   GDK_BACKENDS="$GDK_BACKENDS wayland"
 392   GIO_PACKAGE=gio-unix-2.0
 393   GDK_WINDOWING="$GDK_WINDOWING
 394 #define GDK_WINDOWING_WAYLAND"
 395   WAYLAND_PACKAGES="wayland-client xkbcommon wayland-egl egl"
 396   AM_CONDITIONAL(USE_WAYLAND, true)
 397 else
 398   AM_CONDITIONAL(USE_WAYLAND, false)
 399 fi
 400
 401 # strip leading space
 402 GDK_BACKENDS=${GDK_BACKENDS#* }
 403
 404 AC_SUBST(GDK_BACKENDS)
 405
 406 if test -z "$GDK_BACKENDS"; then
 407   AC_MSG_ERROR([No GDK backends selected.])
 408 fi
 409
 410 if test "x$enable_debug" = "xyes"; then
 411   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 412   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 413 else
 414   if test "x$enable_debug" = "xno"; then
 415     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 416   else
 417     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 418   fi
 419 fi
 420
 421
 422 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 423                    [Define if debugging is enabled])
 424
 425
 426 # Build time sanity check...
 427 AM_SANITY_CHECK
 428
 429 changequote(,)dnl
 430 if test "x$GCC" = "xyes"; then
 431   case " $CFLAGS " in
 432   *[\ \ ]-Wall[\ \      ]*) ;;
 433   *) CFLAGS="$CFLAGS -Wall" ;;
 434   esac
 435
 436   if test "x$enable_ansi" = "xyes"; then
 437     case " $CFLAGS " in
 438     *[\ \       ]-ansi[\ \      ]*) ;;
 439     *) CFLAGS="$CFLAGS -ansi" ;;
 440     esac
 441
 442     case " $CFLAGS " in
 443     *[\ \       ]-pedantic[\ \  ]*) ;;
 444     *) CFLAGS="$CFLAGS -pedantic" ;;
 445     esac
 446   fi
 447 fi
 448 changequote([,])dnl
 449
 450 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 451
 452 # Ensure MSVC-compatible struct packing convention is used when
 453 # compiling for Win32 with gcc.
 454 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 455 # gcc2 uses "-fnative-struct".
 456 if test x"$os_win32" = xyes; then
 457   if test x"$GCC" = xyes; then
 458     msnative_struct=''
 459     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 460     if test -z "$ac_cv_prog_CC"; then
 461       our_gcc="$CC"
 462     else
 463       our_gcc="$ac_cv_prog_CC"
 464     fi
 465     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 466       2.)
 467         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 468           msnative_struct='-fnative-struct'
 469         fi
 470         ;;
 471       *)
 472         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 473           msnative_struct='-mms-bitfields'
 474         fi
 475         ;;
 476     esac
 477     if test x"$msnative_struct" = x ; then
 478       AC_MSG_RESULT([no way])
 479       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 480     else
 481       CFLAGS="$CFLAGS $msnative_struct"
 482       AC_MSG_RESULT([${msnative_struct}])
 483     fi
 484   fi
 485 fi
 486
 487 ## Initial sanity check, done here so that users get told they
 488 ## have the wrong dependencies as early in the process as possible.
 489 ## Later on we actually use the cflags/libs from separate pkg-config
 490 ## calls. Oh, also the later pkg-config calls don't include
 491 ## the version requirements since those make the module lists
 492 ## annoying to construct
 493 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 494   [glib-2.0 >= glib_required_version dnl
 495    atk >= atk_required_version dnl
 496    pango >= pango_required_version dnl
 497    cairo >= cairo_required_version dnl
 498    cairo-gobject >= cairo_required_version dnl
 499    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 500
 501 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 502
 503 if test "$os_win32" != yes; then
 504     # libtool option to control which symbols are exported
 505     # right now, symbols starting with _ are not exported
 506     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 507 else
 508     # We currently use .def files on Windows (for gdk and gtk)
 509     LIBTOOL_EXPORT_OPTIONS=
 510 fi
 511 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 512
 513 dnl ******************************************************
 514 dnl * See whether to include shared library dependencies *
 515 dnl ******************************************************
 516
 517 AC_ARG_ENABLE(explicit-deps,
 518               [AS_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 519                               [use explicit dependencies in .pc files [default=auto]])],,
 520               [enable_explicit_deps=auto])
 521
 522 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 523 case $enable_explicit_deps in
 524   auto)
 525     export SED
 526     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 527     if test "x$deplibs_check_method" != xpass_all || test "x$enable_static" = xyes ; then
 528       enable_explicit_deps=yes
 529     else
 530       enable_explicit_deps=no
 531     fi
 532   ;;
 533   yes|no)
 534   ;;
 535   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 536   ;;
 537 esac
 538 AC_MSG_RESULT($enable_explicit_deps)
 539
 540 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 541
 542 # define a MAINT-like variable REBUILD which is set if Perl
 543 # and awk are found, so autogenerated sources can be rebuilt
 544
 545 AC_PATH_PROGS(PERL, perl5 perl)
 546
 547 # We would like indent, but don't require it.
 548 AC_CHECK_PROG(INDENT, indent, indent)
 549
 550 REBUILD=\#
 551 if test "x$enable_rebuilds" = "xyes" && \
 552      test -n "$PERL" && \
 553      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 554   REBUILD=
 555 fi
 556 AC_SUBST(REBUILD)
 557
 558 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 559 AC_CHECK_FUNCS(localtime_r)
 560
 561 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 562 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 563 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 564                                 [[char c;
 565                                   c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));]])],
 566                [gtk_ok=yes], [gtk_ok=no])
 567 AC_MSG_RESULT($gtk_ok)
 568 if test "$gtk_ok" = "yes"; then
 569   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 570             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 571 fi
 572
 573 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 574 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 575 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 576                                 [[char c;
 577                                   c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));]])],
 578                [gtk_ok=yes], [gtk_ok=no])
 579 AC_MSG_RESULT($gtk_ok)
 580 if test "$gtk_ok" = "yes"; then
 581   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 582             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 583 fi
 584
 585 # _NL_PAPER_HEIGHT is an enum and not a define
 586 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 587 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 588                                 [[char c;
 589                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));]])],
 590                [gtk_ok=yes], [gtk_ok=no])
 591 AC_MSG_RESULT($gtk_ok)
 592 if test "$gtk_ok" = "yes"; then
 593   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 594             [Define if _NL_PAPER_HEIGHT is available])
 595 fi
 596
 597 # _NL_PAPER_WIDTH is an enum and not a define
 598 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 599 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
 600                                 [[char c;
 601                                   c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));]])],
 602                [gtk_ok=yes], [gtk_ok=no])
 603 AC_MSG_RESULT($gtk_ok)
 604 if test "$gtk_ok" = "yes"; then
 605   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 606             [Define if _NL_PAPER_WIDTH is available])
 607 fi
 608
 609 # i18n stuff
 610 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 611 AM_GLIB_GNU_GETTEXT
 612 LIBS="$LIBS $INTLLIBS"
 613 AC_CONFIG_COMMANDS([po-properties],
 614                    [[case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 615                        sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 616                      esac]],
 617                    [[]])
 618
 619 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 620 dnl po-properties/POTFILES during configure; see GNOME #573515.
 621 dnl
 622 dnl Generate list of files to be processed by xgettext which will
 623 dnl be included in po-properties/Makefile.
 624 test -d po-properties || mkdir po-properties
 625 if test "x$srcdir" != "x."; then
 626   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 627     popropsrcprefix="$srcdir/"
 628   else
 629     popropsrcprefix="../$srcdir/"
 630   fi
 631 else
 632   popropsrcprefix="../"
 633 fi
 634 rm -f po-properties/POTFILES
 635 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 636 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 637 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 638
 639 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 640
 641 dnl The DU4 header files don't provide library prototypes unless
 642 dnl -std1 is given to the native cc.
 643 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 644
 645 gtk_save_LIBS=$LIBS
 646 LIBS="$LIBS -lm"
 647 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 648                                 int main (void) { return (log(1) != log(1.)); }]])],
 649               [AC_MSG_RESULT(none needed)],
 650               [gtk_save_CFLAGS="$CFLAGS"
 651                CFLAGS="$CFLAGS -std1"
 652                AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <math.h>
 653                                                int main (void) { return (log(1) != log(1.)); }]])],
 654                              [AC_MSG_RESULT(-std1)],
 655                              [AC_MSG_RESULT()
 656                               CFLAGS="$gtk_save_CFLAGS"
 657                               AC_MSG_WARN([No ANSI prototypes found in library. (-std1 did not work.)])],
 658                              [true])],
 659               [AC_MSG_RESULT(none needed)])
 660
 661 LIBS=$gtk_save_LIBS
 662
 663 AC_MSG_CHECKING(for the BeOS)
 664 case $host in
 665   *-*-beos*)
 666     AC_MSG_RESULT(yes)
 667     MATH_LIB=
 668   ;;
 669   *)
 670     AC_MSG_RESULT(no)
 671   ;;
 672 esac
 673
 674 AC_SUBST(MATH_LIB)
 675 #
 676 # see bug 162979
 677 #
 678 AC_MSG_CHECKING(for HP-UX)
 679 case $host_os in
 680   hpux9* | hpux10* | hpux11*)
 681     AC_MSG_RESULT(yes)
 682     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 683   ;;
 684   *)
 685     AC_MSG_RESULT(no)
 686   ;;
 687 esac
 688
 689 #
 690 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 691 #
 692
 693 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 694
 695 AM_PATH_GLIB_2_0(glib_required_version, :,
 696   AC_MSG_ERROR([
 697 *** GLIB glib_required_version or better is required. The latest version of
 698 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 699   gobject gmodule-no-export gthread)
 700
 701 dnl
 702 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 703 dnl
 704 gtk_save_LIBS=$LIBS
 705 LIBS="$LIBS $GLIB_LIBS"
 706 AC_CHECK_FUNCS(bind_textdomain_codeset)
 707 LIBS=$gtk_save_LIBS
 708
 709 AC_CHECK_HEADERS(pwd.h,
 710                  AC_DEFINE(HAVE_PWD_H, 1,
 711                            [Define to 1 if pwd.h is available]))
 712 AC_CHECK_HEADERS(sys/time.h,
 713                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 714                            [Define to 1 if time.h is available]))
 715 AC_CHECK_HEADERS(unistd.h,
 716                  AC_DEFINE(HAVE_UNISTD_H, 1,
 717                            [Define to 1 if unistd.h is available]))
 718 AC_CHECK_HEADERS(ftw.h,
 719                  AC_DEFINE(HAVE_FTW_H, 1,
 720                            [Define to 1 if ftw.h is available]))
 721
 722 AC_MSG_CHECKING([for GNU ftw extensions])
 723 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _XOPEN_SOURCE 500
 724                                      #define _GNU_SOURCE
 725                                      #include <ftw.h>]],
 726                                    [[int flags = FTW_ACTIONRETVAL;]])],
 727                   [gtk_ok=yes],[gtk_ok=no])
 728 if test $gtk_ok = yes; then
 729     AC_MSG_RESULT([yes])
 730     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 731 else
 732     AC_MSG_RESULT([no])
 733 fi
 734
 735 saved_cflags="$CFLAGS"
 736 saved_ldflags="$LDFLAGS"
 737
 738
 739 # Checks for library functions.
 740 AC_FUNC_MMAP
 741
 742 AC_CHECK_FUNCS(mallinfo)
 743 AC_CHECK_FUNCS(getresuid)
 744 AC_TYPE_UID_T
 745
 746 # Check for uxtheme.h (for MS-Windows Engine)
 747 AC_MSG_CHECKING(for uxtheme.h)
 748 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <uxtheme.h>]])],
 749                   [gtk_uxtheme_h=yes], [gtk_uxtheme_h=no])
 750 if test $gtk_uxtheme_h = yes; then
 751    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 752 fi
 753 AC_MSG_RESULT($gtk_uxtheme_h)
 754
 755 # Check for round()
 756 AC_CHECK_LIB(m,round,have_round=yes,have_round=no)
 757 if test $have_round = yes; then
 758     AC_DEFINE(HAVE_ROUND, 1, [Define to 1 if round() is available])
 759 fi
 760
 761 # Check for rint()
 762 AC_CHECK_LIB(m,rint,have_rint=yes,have_rint=no)
 763 if test $have_rint = yes; then
 764     AC_DEFINE(HAVE_RINT, 1, [Define to 1 if rint() is available])
 765 fi
 766
 767 # Checks for gdkspawn
 768 AC_CHECK_HEADERS(crt_externs.h)
 769 AC_CHECK_FUNCS(_NSGetEnviron)
 770
 771 AC_MSG_CHECKING(whether to build dynamic modules)
 772
 773 AC_ARG_ENABLE(modules,
 774               [AS_HELP_STRING([--disable-modules],
 775                               [disable dynamic module loading])])
 776
 777 dynworks=false
 778 build_dynamic_modules=no
 779 deps=
 780 if test x$enable_modules = xno; then
 781     AC_MSG_RESULT(no)
 782 else
 783     AC_MSG_RESULT(yes)
 784     AC_MSG_CHECKING(whether dynamic modules work)
 785     ## for loop is to strip newline
 786     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 787     for I in $tmp; do
 788         dynworks=$I
 789     done
 790
 791     dnl Now we check to see if our libtool supports shared lib deps
 792     dnl (in a rather ugly way even)
 793     if $dynworks; then
 794         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 795         module_deplibs_check=`$module_libtool_config | \
 796             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 797             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 798         if test "x$module_deplibs_check" = "xnone" || \
 799            test "x$module_deplibs_check" = "xunknown" || \
 800            test "x$module_deplibs_check" = "x"; then
 801             dynworks=false
 802         fi
 803     fi
 804
 805     if $dynworks; then
 806         build_dynamic_modules=yes
 807         AC_DEFINE(USE_GMODULE, 1,
 808                   [Define to 1 if gmodule works and should be used])
 809         AC_MSG_RESULT(yes)
 810     else
 811         build_dynamic_modules=no
 812         AC_MSG_RESULT(no)
 813     fi
 814 fi
 815
 816 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 817
 818 #
 819 # Allow building some or all immodules included
 820 #
 821 AC_MSG_CHECKING(immodules to build)
 822
 823 AC_ARG_WITH(included_immodules,
 824             [AS_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 825                             [build the specified input methods into gtk])])
 826
 827 if $dynworks; then
 828    :
 829 else
 830    ## if the option was specified, leave it; otherwise disable included immodules
 831    if test x$with_included_immodules = xno; then
 832            with_included_immodules=yes
 833    fi
 834 fi
 835
 836 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 837
 838 included_immodules=""
 839 # If the switch specified without listing any specific ones, include all
 840 if test "x$with_included_immodules" = xyes ; then
 841   included_immodules="$all_immodules"
 842 else
 843   included_immodules="$with_included_immodules"
 844 fi
 845
 846 AC_MSG_RESULT($included_immodules)
 847 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 848
 849 INCLUDED_IMMODULE_OBJ=
 850 INCLUDED_IMMODULE_DEFINE=
 851
 852 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 853 for immodule in $included_immodules; do
 854  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 855  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 856    :
 857  else
 858    AC_MSG_ERROR([the specified input method $immodule does not exist])
 859  fi
 860
 861  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 862  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 863  eval INCLUDE_$immodule_underscores=yes
 864 done
 865 IFS="$gtk_save_ifs"
 866 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 867 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 868
 869 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 870 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 871 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 872 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 873 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 874 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 875 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 876 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 877 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 878 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 879 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 880 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 881
 882 # Checks to see whether we should include mediaLib
 883 # support.
 884 #
 885 AC_CHECK_HEADER(sys/systeminfo.h,
 886                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 887                           [Define to 1 if sys/systeminfo.h is available]))
 888 AC_CHECK_HEADER(sys/sysinfo.h,
 889                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 890                           [Define to 1 if sys/sysinfo.h is available]))
 891
 892 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 893
 894 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 895
 896 if test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes; then
 897   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 898   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 899     REBUILD_PNGS=#
 900   fi
 901 fi
 902
 903 AM_CONDITIONAL(USE_EXTERNAL_ICON_CACHE, [test "x$cross_compiling" = xyes || test "x$enable_gtk2_dependency" = xyes])
 904
 905 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 906
 907 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 908    test "x$REBUILD_PNGS" = "x#" ; then
 909      AC_MSG_ERROR([
 910 *** gtkbuiltincache.h is not in the tree, and cannot be built
 911 *** because you don't have libpng, or (when cross-compiling) you
 912 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 913 fi
 914
 915 ########################################
 916 # Windowing system checks
 917 ########################################
 918
 919 # GTK+ uses some X calls, so needs to link against X directly
 920 GTK_DEP_PACKAGES_FOR_X=
 921 GTK_DEP_LIBS_FOR_X=
 922 X_EXTENSIONS=
 923
 924 if test "x$enable_x11_backend" = xyes; then
 925   X_PACKAGES=fontconfig
 926
 927   #
 928   # We use fontconfig very peripherally when decoding the default
 929   # settings.
 930   #
 931   if $PKG_CONFIG --exists fontconfig; then : ; else
 932     AC_MSG_ERROR([
 933 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 934   fi
 935
 936   #
 937   # Check for basic X packages; we use pkg-config if available
 938   #
 939   if $PKG_CONFIG --exists x11 xext; then
 940     have_base_x_pc=true
 941     X_PACKAGES="$X_PACKAGES x11 xext"
 942     x_libs="`$PKG_CONFIG --libs x11 xext`"
 943     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 944
 945     # Strip out any .la files that pkg-config might give us (this happens
 946     # with -uninstalled.pc files)
 947     x_libs_for_checks=
 948     for I in $x_libs ; do
 949       case $I in
 950         *.la) ;;
 951         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 952       esac
 953     done
 954
 955     GTK_PACKAGES_FOR_X="x11"
 956   else
 957     have_base_x_pc=false
 958     AC_PATH_XTRA
 959     if test x$no_x = xyes ; then
 960       AC_MSG_ERROR([X development libraries not found])
 961     fi
 962
 963     x_cflags="$X_CFLAGS"
 964     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 965
 966     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 967   fi
 968
 969   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 970   x_extra_libs=
 971
 972   gtk_save_cppflags="$CPPFLAGS"
 973   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 974
 975   gtk_save_LIBS=$LIBS
 976   LIBS="$x_libs_for_checks $LIBS"
 977
 978   # Sanity check for the X11 and Xext libraries. While everything we need from
 979   # Xext is optional, the chances a system has *none* of these things is so
 980   # small that we just unconditionally require it.
 981   AC_CHECK_FUNC(XOpenDisplay, :,
 982                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 983   AC_CHECK_FUNC(XextFindDisplay, :,
 984                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 985
 986   # Check for xReply
 987
 988   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 989   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlibint.h>]],
 990                                      [[xReply *rep;]])],
 991                     [AC_MSG_RESULT([no])],
 992                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/XIproto.h>
 993                                                           #include <X11/Xlibint.h>]],
 994                                                         [[xReply *rep;]])],
 995                                        [AC_MSG_RESULT([yes])
 996                                         AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], [1],
 997                                                   [Define if <X11/extensions/XIproto.h> needed for xReply])],
 998                                        [AC_MSG_RESULT([unknown])
 999                                         AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
1000
1001   # Check for XConvertCase, XInternAtoms (X11R6 specific)
1002
1003   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
1004
1005   # Generic X11R6 check needed for XIM support; we could
1006   # probably use this to replace the above, but we'll
1007   # leave the separate checks for XConvertCase and XInternAtoms
1008   # for clarity
1009
1010   have_x11r6=false
1011   AC_CHECK_FUNC(XAddConnectionWatch,
1012       have_x11r6=true)
1013
1014   if $have_x11r6; then
1015     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
1016   fi
1017   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
1018
1019   # Check for XKB support.
1020
1021   if test "x$enable_xkb" = "xyes"; then
1022         AC_CHECK_FUNC(XkbQueryExtension,
1023                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1024                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]),
1025                       AC_MSG_ERROR([*** XKB extension not found. Check 'config.log' for more details.]))
1026   elif test "x$enable_xkb" = "xmaybe"; then
1027         AC_CHECK_FUNC(XkbQueryExtension,
1028                       X_EXTENSIONS="$X_EXTENSIONS XKB"
1029                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
1030   else
1031         AC_MSG_WARN(XKB support explicitly disabled)
1032   fi
1033
1034   # Check for shaped window extension
1035
1036   AC_CHECK_FUNC(XShapeCombineMask, :,
1037      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
1038
1039   # X SYNC check
1040   gtk_save_CFLAGS="$CFLAGS"
1041   CFLAGS="$CFLAGS $x_cflags"
1042
1043   AC_CHECK_FUNC(XSyncQueryExtension,
1044       [AC_CHECK_HEADER(X11/extensions/sync.h,
1045           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1046           :, [#include <X11/Xlib.h>])])
1047
1048   CFLAGS="$gtk_save_CFLAGS"
1049
1050   if test "x$enable_xinerama" != "xno"; then
1051     # Check for Xinerama extension (Solaris impl or Xfree impl)
1052     have_xfree_xinerama=false
1053     have_solaris_xinerama=false
1054
1055     gtk_save_cppflags="$CPPFLAGS"
1056     CPPFLAGS="$CPPFLAGS $x_cflags"
1057
1058     # Check for XFree
1059     AC_MSG_CHECKING(for Xinerama packages)
1060
1061     if $PKG_CONFIG --exists xinerama ; then
1062        AC_MSG_RESULT(yes)
1063        have_xfree_xinerama=true
1064        X_PACKAGES="$X_PACKAGES xinerama"
1065     else
1066        AC_MSG_RESULT(no)
1067        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1068            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1069            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1070            have_xfree_xinerama=true], :,
1071            [#include <X11/Xlib.h>])])
1072     fi
1073
1074     if $have_xfree_xinerama ; then
1075       X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1076       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1077                 [Define to 1 if XFree Xinerama is available])
1078       AC_DEFINE(HAVE_XINERAMA, 1,
1079                 [Define to 1 is Xinerama is available])
1080     else
1081       case "$host" in
1082         *-*-solaris*)
1083             # Check for solaris
1084             AC_MSG_CHECKING(for Xinerama support on Solaris)
1085
1086             have_solaris_xinerama=false
1087             AC_CHECK_FUNC(XineramaGetInfo,
1088                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1089                     [have_solaris_xinerama=true], :,
1090                     [#include <X11/Xlib.h>])])
1091
1092             if $have_solaris_xinerama ; then
1093               X_EXTENSIONS="$X_EXTENSIONS Xinerama"
1094               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1095                         [Define to 1 if solaris xinerama is available])
1096               AC_DEFINE(HAVE_XINERAMA, 1,
1097                         [Define to 1 if xinerama is available])
1098               AC_MSG_RESULT(yes)
1099             else
1100               AC_MSG_RESULT(no)
1101             fi
1102             ;;
1103         *)
1104             ;;
1105       esac
1106     fi
1107   fi
1108   if test "x$enable_xinerama" = "xyes" ; then
1109     if test "x$have_xfree_xinerama" != "xtrue" -a "x$have_solaris_xinerama" != "xtrue" ; then
1110       AC_MSG_ERROR([*** Xinerama extension not found. Check 'config.log' for more details.])
1111     fi
1112   fi
1113
1114   # Check for XGetEventData for GenericEvents
1115   AC_CHECK_FUNC(XGetEventData,
1116                 AC_DEFINE(HAVE_XGENERICEVENTS, 1, [Have XGenericEvent]))
1117
1118   # set up things for XInput
1119   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1120     have_xinput=yes
1121
1122     AC_DEFINE(XINPUT_XFREE, 1,
1123               [Define to 1 if XFree XInput should be used])
1124
1125     X_PACKAGES="$X_PACKAGES xi"
1126
1127     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1128                     have_xinput2=yes
1129                     X_EXTENSIONS="$X_EXTENSIONS XI2"
1130                     AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]),
1131                     X_EXTENSIONS="$X_EXTENSIONS XInput")
1132
1133   else
1134     AC_DEFINE(XINPUT_NONE, 1,
1135               [Define to 1 if no XInput should be used])
1136   fi
1137
1138   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1139   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1140
1141   if test "x$enable_xinput" = "xyes" ; then
1142     if test "x$have_xinput" != "xyes" -a "x$have_xinput2" != "xyes" ; then
1143       AC_MSG_ERROR([*** XInput extension not found. Check 'config.log' for more details.])
1144     fi
1145   fi
1146
1147   # Check for the RANDR extension
1148   if test x"$enable_xrandr" != xno; then
1149     if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1150       AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1151
1152       X_PACKAGES="$X_PACKAGES xrandr"
1153       X_EXTENSIONS="$X_EXTENSIONS XRANDR"
1154     elif test x"$enable_xrandr" = xyes; then
1155       AC_MSG_ERROR([RANDR support requested but xrandr not found])
1156     fi
1157   fi
1158
1159   # Checks for Xcursor library
1160
1161   if $PKG_CONFIG --exists xcursor ; then
1162     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1163
1164     X_PACKAGES="$X_PACKAGES xcursor"
1165   fi
1166
1167   # Checks for XFixes extension
1168
1169   if test x"$enable_xfixes" != xno; then
1170     if $PKG_CONFIG --exists xfixes ; then
1171       AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1172
1173       X_PACKAGES="$X_PACKAGES xfixes"
1174       X_EXTENSIONS="$X_EXTENSIONS XFIXES"
1175       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1176     elif test x"$enable_xfixes" = xyes; then
1177       AC_MSG_ERROR([XFixes support requested but xfixes not found])
1178     fi
1179   fi
1180
1181   # Checks for Xcomposite extension
1182
1183   if test x"$enable_xcomposite" != xno; then
1184     if $PKG_CONFIG --exists xcomposite ; then
1185       AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1186
1187       X_PACKAGES="$X_PACKAGES xcomposite"
1188       X_EXTENSIONS="$X_EXTENSIONS Composite"
1189       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1190     elif test x"$enable_xcomposite" = xyes; then
1191       AC_MSG_ERROR([Xcomposite support requested but xcomposite not found])
1192     fi
1193   fi
1194
1195   # Checks for Xdamage extension
1196
1197   if test x"$enable_xdamage" != xno; then
1198     if $PKG_CONFIG --exists xdamage ; then
1199       AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1200
1201       X_PACKAGES="$X_PACKAGES xdamage"
1202       X_EXTENSIONS="$X_EXTENSIONS DAMAGE"
1203       GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1204     elif test x"$enable_xdamage" = xyes; then
1205       AC_MSG_ERROR([Xdamage support requested but xdamage not found])
1206     fi
1207   fi
1208
1209   if $have_base_x_pc ; then
1210     GDK_EXTRA_LIBS="$x_extra_libs"
1211   else
1212     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1213   fi
1214
1215   CPPFLAGS="$gtk_save_cppflags"
1216   LIBS="$gtk_save_libs"
1217
1218   AM_CONDITIONAL(USE_X11, true)
1219
1220   # strip leading space
1221   X_EXTENSIONS=${X_EXTENSIONS#* }
1222
1223 else
1224   XPACKAGES=
1225
1226   AM_CONDITIONAL(XINPUT_XFREE, false)
1227   AM_CONDITIONAL(XINPUT_2, false)
1228   AM_CONDITIONAL(USE_X11, false)
1229   AM_CONDITIONAL(HAVE_X11R6, false)
1230 fi
1231
1232 # Check for Pango flags
1233
1234 AC_MSG_CHECKING(Pango flags)
1235 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1236         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1237         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1238
1239         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1240 else
1241         AC_MSG_ERROR([
1242 *** Pango not found. Pango built with Cairo support is required
1243 *** to build GTK+. See http://www.pango.org for Pango information.
1244 ])
1245 fi
1246
1247 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1248
1249 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1250         :
1251 else
1252         gtk_save_LIBS="$LIBS"
1253         LIBS="$PANGO_LIBS $LIBS"
1254         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1255 *** Can't link to Pango. Pango is required to build
1256 *** GTK+. For more information see http://www.pango.org]))
1257         LIBS="$gtk_save_LIBS"
1258 fi
1259
1260 CFLAGS="$saved_cflags"
1261 LDFLAGS="$saved_ldflags"
1262
1263 GDK_PACKAGES="$PANGO_PACKAGES $GIO_PACKAGE $X_PACKAGES $WAYLAND_PACKAGES gdk-pixbuf-2.0 $cairo_backends cairo-gobject"
1264
1265 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES` $MATH_LIB"
1266 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1267 #
1268 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1269 # into the pkg-config files
1270 #
1271 if test $enable_explicit_deps != yes ; then
1272   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0 cairo-gobject"
1273   GDK_EXTRA_LIBS=
1274 fi
1275
1276 AC_SUBST(GDK_PACKAGES)
1277 AC_SUBST(GDK_EXTRA_LIBS)
1278 AC_SUBST(GDK_EXTRA_CFLAGS)
1279 AC_SUBST(GDK_DEP_LIBS)
1280 AC_SUBST(GDK_DEP_CFLAGS)
1281
1282
1283 ########################################
1284 # Check for Accessibility Toolkit flags
1285 ########################################
1286
1287 ATK_PACKAGES=atk
1288 AC_MSG_CHECKING(ATK flags)
1289 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1290         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1291         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1292
1293         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1294 else
1295         AC_MSG_ERROR([
1296 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1297 *** to build GTK+.
1298 ])
1299 fi
1300
1301 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1302         :
1303 else
1304         gtk_save_LIBS="$LIBS"
1305         LIBS="$ATK_LIBS $LIBS"
1306         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1307                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1308                 *** to build GTK+]))
1309         LIBS="$gtk_save_LIBS"
1310 fi
1311
1312 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1313 if test "x$enable_x11_backend" = xyes; then
1314   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1315 fi
1316 GTK_EXTRA_LIBS=
1317 if test x"$os_openbsd" = xyes; then
1318   GTK_EXTRA_LIBS="$GTK_EXTRA_LIBS -lkvm"
1319 fi
1320
1321 GTK_EXTRA_CFLAGS=
1322 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS $MATH_LIB"
1323 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1324
1325 if test x"$os_win32" = xyes; then
1326   GTK_EXTRA_CFLAGS="$msnative_struct"
1327 fi
1328
1329 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1330 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1331 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1332 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1333
1334 AC_SUBST(GTK_PACKAGES)
1335 AC_SUBST(GTK_EXTRA_LIBS)
1336 AC_SUBST(GTK_EXTRA_CFLAGS)
1337 AC_SUBST(GTK_DEP_LIBS)
1338 AC_SUBST(GTK_DEP_CFLAGS)
1339
1340 AC_SUBST(GLIB_PREFIX)
1341 AC_SUBST(ATK_PREFIX)
1342 AC_SUBST(PANGO_PREFIX)
1343 AC_SUBST(CAIRO_PREFIX)
1344
1345 AC_SUBST(GTK_DEBUG_FLAGS)
1346 AC_SUBST(GTK_XIM_FLAGS)
1347
1348 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1349 AC_SUBST(GDK_PIXBUF_LIBS)
1350
1351 ########################
1352 # Checks needed for gail
1353 ########################
1354
1355 old_LIBS="$LIBS"
1356 dnl Checks for inet libraries:
1357 AC_SEARCH_LIBS(gethostent, nsl)
1358 AC_SEARCH_LIBS(setsockopt, socket)
1359 AC_SEARCH_LIBS(connect, inet)
1360
1361 dnl check for the sockaddr_un.sun_len member
1362 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1363                 [struct_sockaddr_un_sun_len=true],
1364                 [struct_sockaddr_un_suin_len=false],
1365                 [#include <sys/types.h>
1366                  #include <sys/un.h>]
1367                 )
1368 case $struct_sockaddr_un_sun_len in
1369         true)
1370                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1371                                    [Have the sockaddr_un.sun_len member])
1372                 ;;
1373         *)
1374                 ;;
1375 esac
1376
1377 GAIL_INET_LIBS="$LIBS"
1378 AC_SUBST([GAIL_INET_LIBS])
1379
1380 LIBS="$old_LIBS"
1381
1382 ################################################################
1383 # Printing system checks
1384 ################################################################
1385
1386 PRINT_BACKENDS="file lpr"
1387
1388 AC_ARG_ENABLE(cups,
1389               [AS_HELP_STRING([--disable-cups],
1390                               [disable cups print backend])],,
1391               [enable_cups=auto])
1392
1393 if test "x$enable_cups" = "xno"; then
1394   AM_CONDITIONAL(HAVE_CUPS, false)
1395 else
1396   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1397   if test "x$CUPS_CONFIG" = "xno"; then
1398     if test "x$enable_cups" = "xauto"; then
1399       AM_CONDITIONAL(HAVE_CUPS, false)
1400     else
1401       AC_MSG_ERROR([
1402 *** cups not found.
1403 ])
1404     fi
1405   else
1406     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1407     CUPS_LIBS=`$CUPS_CONFIG --libs`
1408
1409     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1410     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1411     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1412
1413     if test $CUPS_API_MAJOR -gt 1 -o \
1414             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1415       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1416                 [Define to 1 if CUPS 1.2 API is available])
1417     fi
1418
1419     AC_SUBST(CUPS_API_MAJOR)
1420     AC_SUBST(CUPS_API_MINOR)
1421     AC_SUBST(CUPS_CFLAGS)
1422     AC_SUBST(CUPS_LIBS)
1423
1424     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1425
1426     PRINT_BACKENDS="$PRINT_BACKENDS cups"
1427     AM_CONDITIONAL(HAVE_CUPS, true)
1428
1429     gtk_save_cflags="$CFLAGS"
1430     CFLAGS="$CUPS_CFLAGS"
1431     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <cups/http.h>]],
1432                                        [[http_t http; char *s = http.authstring;]])],
1433                       [AC_DEFINE([HAVE_HTTP_AUTHSTRING], [],
1434                                  [Define if cups http_t authstring field is accessible])],
1435                       [])
1436     CFLAGS="$gtk_save_cflags"
1437
1438     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1439
1440     gtk_save_libs="$LIBS"
1441     LIBS="$CUPS_LIBS"
1442     AC_CHECK_FUNCS(httpGetAuthString)
1443     LIBS="$gtk_save_libs"
1444   fi
1445 fi
1446
1447 # Checks to see if we should compile with PAPI backend for GTK+
1448 #
1449
1450 AC_ARG_ENABLE(papi,
1451               [AS_HELP_STRING([--disable-papi],
1452                               [disable papi print backend])],,
1453               [enable_papi=auto])
1454
1455 if test "x$enable_papi" = "xno"; then
1456   AM_CONDITIONAL(HAVE_PAPI, false)
1457 else
1458   AC_MSG_CHECKING(libpapi)
1459   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1460   if test $have_papi = yes; then
1461     PRINT_BACKENDS="$PRINT_BACKENDS papi"
1462     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1463   fi
1464   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1465   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1466     AC_MSG_ERROR([
1467 *** papi not found.
1468 ])
1469   fi
1470 fi
1471
1472 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1473
1474 gtk_save_cppflags="$CPPFLAGS"
1475 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1476
1477 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1478 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1479 *** backend enabled.]))
1480
1481 if test "$os_win32" != "yes"; then
1482   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1483 *** Can't find cairo-ps.h. You must build Cairo with the
1484 *** postscript backend enabled.]))
1485
1486   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1487 *** Cannot find cairo-svg.h. You must build Cairo with the
1488 *** svg backend enabled.]))
1489 fi
1490
1491 CPPFLAGS="$gtk_save_cppflags"
1492
1493
1494 AC_ARG_ENABLE(test-print-backend,
1495               [AS_HELP_STRING([--enable-test-print-backend],
1496                               [build test print backend])],,
1497               [enable_test_print_backend=no])
1498 if test "x$enable_test_print_backend" != "xno" ; then
1499   PRINT_BACKENDS="$PRINT_BACKENDS test"
1500 fi
1501 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1502
1503
1504 ################################################################
1505 # Strip -export-dynamic from the link lines of various libraries
1506 ################################################################
1507
1508 #
1509 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1510 #  but this flag is only meaningful for executables. For libraries
1511 #  the effect is undefined; what it causes on Linux is that the
1512 #  export list from -export-symbols-regex is ignored and everything
1513 #  is exported
1514 #
1515 # We are using gmodule-no-export now, but I'm leaving the stripping
1516 # code in place for now, since pango and atk still require gmodule.
1517 export SED
1518 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1519 if test -n "$export_dynamic"; then
1520   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1521   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1522 fi
1523
1524 #############
1525 # GSettings #
1526 #############
1527
1528 GLIB_GSETTINGS
1529
1530 ##################################################
1531 # GObject introspection
1532 ##################################################
1533
1534 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
1535
1536 ##################################################
1537 # Packagekit module
1538 #################################################
1539
1540 AC_ARG_ENABLE(packagekit,
1541               [AS_HELP_STRING([--enable-packagekit=@<:@yes/no/auto@:>@],
1542                               [build PackageKit open-with module [default=auto]])],
1543               [enable_packagekit="$enableval"],
1544               [enable_packagekit=auto])
1545 if test "$enable_packagekit" = "auto"; then
1546   if test "$os_win32" = "yes"; then
1547     enable_packagekit=no
1548   else
1549     enable_packagekit=yes
1550   fi
1551 fi
1552
1553 AC_MSG_CHECKING([whether to use PackageKit])
1554 build_packagekit=no
1555 if test "x$enable_packagekit" != "xno"; then
1556   if test "$os_win32" != "yes"; then
1557     build_packagekit=yes
1558     AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1559   else
1560     AC_MSG_ERROR([packagekit support is not available on win32])
1561   fi
1562 fi
1563 AC_MSG_RESULT([$build_packagekit])
1564
1565 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$build_packagekit" = "xyes")
1566
1567 ##################################################
1568 # colord module
1569 #################################################
1570
1571 AC_ARG_ENABLE(colord,
1572               [AS_HELP_STRING([--enable-colord=@<:@yes/no/auto@:>@],
1573                               [build colord support code [default=auto]])],
1574               [enable_colord="$enableval"],
1575               [enable_colord=auto])
1576
1577 AC_MSG_CHECKING([whether to use colord])
1578 if test "$enable_colord" = "auto"; then
1579   if test "$os_win32" = "yes"; then
1580     enable_colord=no
1581   fi
1582 fi
1583 if test "$enable_colord" != "no"; then
1584   AC_MSG_RESULT([yes])
1585 else
1586   AC_MSG_RESULT([no])
1587 fi
1588
1589 have_colord=no
1590 if test "$enable_colord" != "no"; then
1591         if test "$os_win32" != "yes"; then
1592                 PKG_CHECK_MODULES(COLORD, colord >= 0.1.9,
1593                                   have_colord=yes, have_colord=no)
1594                 if test "$enable_colord" = "yes"; then
1595                         if test "$have_colord" = "no"; then
1596                                 AC_MSG_ERROR([--enable-colord specified, but not available])
1597                         fi
1598                 fi
1599         else
1600                 AC_MSG_ERROR([colord support is not available on win32])
1601         fi
1602 fi
1603
1604 if test "$have_colord" = "yes"; then
1605         AC_DEFINE(HAVE_COLORD, 1, [define if we have colord])
1606 fi
1607 AM_CONDITIONAL(HAVE_COLORD, test "x$have_colord" = "xyes")
1608
1609 ##################################################
1610 # Checks for gtk-doc and docbook-tools
1611 ##################################################
1612
1613 GTK_DOC_CHECK([1.11],[--flavour no-tmpl])
1614
1615 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1616 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1617
1618 AC_ARG_ENABLE(man,
1619               [AS_HELP_STRING([--enable-man],
1620                               [regenerate man pages from Docbook [default=no]])],
1621               [enable_man=yes],
1622               [enable_man=no])
1623
1624 if test "${enable_man}" != no; then
1625   dnl
1626   dnl Check for xsltproc
1627   dnl
1628   AC_PATH_PROG([XSLTPROC], [xsltproc])
1629   if test -z "$XSLTPROC"; then
1630     enable_man=no
1631   fi
1632
1633   dnl check for DocBook DTD and stylesheets in the local catalog.
1634   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1635      [DocBook XML DTD V4.1.2],,enable_man=no)
1636   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1637      [DocBook XSL Stylesheets],,enable_man=no)
1638 fi
1639
1640 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1641
1642
1643 ##################################################
1644 # Output commands
1645 ##################################################
1646
1647 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1648         outfile=gdkconfig.h-tmp
1649         cat > $outfile <<\_______EOF
1650 /* gdkconfig.h
1651  *
1652  * This is a generated file.  Please modify `configure.ac'
1653  */
1654
1655 #ifndef __GDKCONFIG_H__
1656 #define __GDKCONFIG_H__
1657
1658 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1659 #error "Only <gdk/gdk.h> can be included directly."
1660 #endif
1661
1662 #include <glib.h>
1663
1664 G_BEGIN_DECLS
1665
1666 /* These macros are used to mark deprecated functions in GDK and
1667  * GTK+ headers, and thus have to be exposed in installed headers.
1668  * But please do *not* use them in other projects. Instead, use
1669  * G_DEPRECATED or define your own wrappers around it.
1670  */
1671
1672 #ifdef GDK_DISABLE_DEPRECATION_WARNINGS
1673 #define GDK_DEPRECATED
1674 #define GDK_DEPRECATED_FOR(f)
1675 #else
1676 #define GDK_DEPRECATED G_DEPRECATED
1677 #define GDK_DEPRECATED_FOR(f) G_DEPRECATED_FOR(f)
1678 #endif
1679
1680 _______EOF
1681
1682         cat >>$outfile <<_______EOF
1683 $gdk_windowing
1684 _______EOF
1685
1686         cat >>$outfile <<_______EOF
1687
1688 G_END_DECLS
1689
1690 #endif  /* __GDKCONFIG_H__ */
1691 _______EOF
1692
1693
1694         if cmp -s $outfile gdk/gdkconfig.h; then
1695           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1696           rm -f $outfile
1697         else
1698           mv $outfile gdk/gdkconfig.h
1699         fi
1700 ],[
1701 gdk_windowing='$GDK_WINDOWING'
1702 ])
1703
1704 dnl
1705 dnl Check for -Bsymbolic-functions linker flag used to avoid
1706 dnl intra-library PLT jumps, if available.
1707 dnl
1708 AC_ARG_ENABLE(Bsymbolic,
1709               [AS_HELP_STRING([--disable-Bsymbolic],
1710                               [avoid linking with -Bsymbolic])],,
1711               [SAVED_LDFLAGS="${LDFLAGS}"
1712                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1713                LDFLAGS=-Wl,-Bsymbolic-functions
1714                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1715                                                [[int main (void) { return 0; }]])],
1716                               [AC_MSG_RESULT(yes)
1717                                enable_Bsymbolic=yes],
1718                               [AC_MSG_RESULT(no)
1719                                enable_Bsymbolic=no])
1720                LDFLAGS="${SAVED_LDFLAGS}"])
1721
1722 if test "x${enable_Bsymbolic}" = "xyes" ; then
1723   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1724 fi
1725 AC_SUBST(GTK_LINK_FLAGS)
1726
1727 AC_CONFIG_FILES([
1728 config.h.win32
1729 gtk-zip.sh
1730 Makefile
1731 gdk-3.0.pc
1732 gtk+-3.0.pc
1733 gtk+-unix-print-3.0.pc
1734 gail-3.0.pc
1735 gtk+-3.0-uninstalled.pc
1736 gail-3.0-uninstalled.pc
1737 m4macros/Makefile
1738 po/Makefile.in
1739 po-properties/Makefile.in
1740 demos/Makefile
1741 demos/gtk-demo/Makefile
1742 demos/gtk-demo/geninclude.pl
1743 demos/pixbuf-demo/Makefile
1744 examples/Makefile
1745 tests/Makefile
1746 tests/a11y/Makefile
1747 tests/css/Makefile
1748 tests/css/parser/Makefile
1749 tests/reftests/Makefile
1750 docs/Makefile
1751 docs/reference/Makefile
1752 docs/reference/gdk/Makefile
1753 docs/reference/gdk/version.xml
1754 docs/reference/gtk/Makefile
1755 docs/reference/gtk/version.xml
1756 docs/reference/libgail-util/Makefile
1757 docs/reference/libgail-util/version.xml
1758 docs/tools/Makefile
1759 build/Makefile
1760 build/win32/Makefile
1761 build/win32/vs9/Makefile
1762 build/win32/vs10/Makefile
1763 gdk/Makefile
1764 gdk/broadway/Makefile
1765 gdk/x11/Makefile
1766 gdk/win32/Makefile
1767 gdk/win32/rc/Makefile
1768 gdk/win32/rc/gdk.rc
1769 gdk/quartz/Makefile
1770 gdk/wayland/Makefile
1771 gdk/tests/Makefile
1772 gtk/Makefile
1773 gtk/makefile.msc
1774 gtk/gtkversion.h
1775 gtk/gtk-win32.rc
1776 gtk/a11y/Makefile
1777 gtk/tests/Makefile
1778 libgail-util/Makefile
1779 modules/Makefile
1780 modules/engines/Makefile
1781 modules/engines/pixbuf/Makefile
1782 modules/engines/ms-windows/Makefile
1783 modules/engines/ms-windows/Theme/Makefile
1784 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1785 modules/input/Makefile
1786 modules/printbackends/Makefile
1787 modules/printbackends/cups/Makefile
1788 modules/printbackends/lpr/Makefile
1789 modules/printbackends/file/Makefile
1790 modules/printbackends/papi/Makefile
1791 modules/printbackends/test/Makefile
1792 perf/Makefile
1793 ])
1794
1795 AC_OUTPUT
1796
1797 # beautify the immodule list a bit
1798 included_immodules=$(echo "${included_immodules}" | $SED 's/,/ /g')
1799 if test -z "${included_immodules}"; then included_immodules="none"; fi
1800
1801 echo ""
1802 echo "        GTK+ $GTK_VERSION"
1803 echo "        ==========="
1804 echo ""
1805 echo "        GDK backends:         $GDK_BACKENDS"
1806 if test "$enable_x11_backend" = "yes"; then
1807 echo "        X11 extensions:       $X_EXTENSIONS"
1808 fi
1809 echo "        Print backends:       $PRINT_BACKENDS"
1810 echo "        Dynamic modules:      $build_dynamic_modules"
1811 echo "        Included immodules:   $included_immodules"
1812 echo "        PackageKit support:   $build_packagekit"
1813 echo "        colord support:       $have_colord"
1814 echo "        Introspection:        $found_introspection"
1815 echo "        Debugging:            $enable_debug"
1816 echo "        Documentation:        $enable_gtk_doc"