Pileus Git - ~andy/gtk/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Making releases:
   4 #   GTK_MICRO_VERSION += 1;
   5 #   GTK_INTERFACE_AGE += 1;
   6 #   GTK_BINARY_AGE += 1;
   7 # if any functions have been added, set GTK_INTERFACE_AGE to 0.
   8 # if backwards compatibility has been broken,
   9 # set GTK_BINARY_AGE and GTK_INTERFACE_AGE to 0.
  10
  11 m4_define([gtk_major_version], [2])
  12 m4_define([gtk_minor_version], [91])
  13 m4_define([gtk_micro_version], [8])
  14 m4_define([gtk_interface_age], [0])
  15 m4_define([gtk_binary_age],
  16           [m4_eval(100 * gtk_minor_version + gtk_micro_version)])
  17 m4_define([gtk_version],
  18           [gtk_major_version.gtk_minor_version.gtk_micro_version])
  19 # This is the X.Y used in -lgtk-FOO-X.Y
  20 m4_define([gtk_api_version], [3.0])
  21
  22 AC_PREREQ([2.62])
  23 AC_INIT([gtk+], [gtk_version],
  24         [http://bugzilla.gnome.org/enter_bug.cgi?product=gtk%2B],
  25         [gtk+])
  26
  27 AC_CONFIG_HEADER([config.h])
  28 AC_CONFIG_SRCDIR([gdk/gdktypes.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Define a string for the earliest version that this release has
  32 # backwards binary compatibility with for all interfaces a module
  33 # might. Unless we add module-only API with lower stability
  34 # guarantees, this should be unchanged until we break binary compat
  35 # for GTK+.
  36 #
  37 #GTK_BINARY_VERSION=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION.$LT_CURRENT
  38 m4_define([gtk_binary_version], [3.0.0])
  39
  40 # required versions of other packages
  41 m4_define([glib_required_version], [2.27.5])
  42 m4_define([pango_required_version], [1.20])
  43 m4_define([atk_required_version], [1.29.2])
  44 m4_define([cairo_required_version], [1.10.0])
  45 m4_define([gdk_pixbuf_required_version], [2.21.0])
  46 GLIB_REQUIRED_VERSION=glib_required_version
  47 PANGO_REQUIRED_VERSION=pango_required_version
  48 ATK_REQUIRED_VERSION=atk_required_version
  49 CAIRO_REQUIRED_VERSION=cairo_required_version
  50 GDK_PIXBUF_REQUIRED_VERSION=gdk_pixbuf_required_version
  51 AC_SUBST(GLIB_REQUIRED_VERSION)
  52 AC_SUBST(PANGO_REQUIRED_VERSION)
  53 AC_SUBST(ATK_REQUIRED_VERSION)
  54 AC_SUBST(CAIRO_REQUIRED_VERSION)
  55 AC_SUBST(GDK_PIXBUF_REQUIRED_VERSION)
  56
  57
  58 # Save this value here, since automake will set cflags later
  59 cflags_set=${CFLAGS+set}
  60
  61 AM_INIT_AUTOMAKE([1.10 no-define -Wno-portability dist-bzip2])
  62 AM_MAINTAINER_MODE([enable])
  63
  64 # Support silent build rules, requires at least automake-1.11. Disable
  65 # by either passing --disable-silent-rules to configure or passing V=1
  66 # to make
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69 #
  70 # For each of the libraries we build, we define the following
  71 # substituted variables:
  72 #
  73 # foo_PACKAGES:     pkg-config packages this library requires
  74 # foo_EXTRA_LIBS:   Libraries this module requires not pulled in by pkg-config
  75 # foo_EXTRA_CFLAGS: cflags this module requires not pulled in by pkg-config
  76 # foo_DEP_LIBS:     All libraries this module requires
  77 # foo_DEP_CFLAGS:   All cflags this module requires
  78
  79
  80 GTK_MAJOR_VERSION=gtk_major_version
  81 GTK_MINOR_VERSION=gtk_minor_version
  82 GTK_MICRO_VERSION=gtk_micro_version
  83 GTK_INTERFACE_AGE=gtk_interface_age
  84 GTK_BINARY_AGE=gtk_binary_age
  85 GTK_VERSION=gtk_version
  86 GTK_API_VERSION=gtk_api_version
  87 GTK_BINARY_VERSION=gtk_binary_version
  88 AC_SUBST(GTK_MAJOR_VERSION)
  89 AC_SUBST(GTK_MINOR_VERSION)
  90 AC_SUBST(GTK_MICRO_VERSION)
  91 AC_SUBST(GTK_INTERFACE_AGE)
  92 AC_SUBST(GTK_BINARY_AGE)
  93 AC_SUBST(GTK_API_VERSION)
  94 AC_SUBST(GTK_VERSION)
  95 AC_SUBST(GTK_BINARY_VERSION)
  96
  97 # libtool versioning
  98 #LT_RELEASE=$GTK_MAJOR_VERSION.$GTK_MINOR_VERSION
  99 #LT_CURRENT=`expr $GTK_MICRO_VERSION - $GTK_INTERFACE_AGE`
 100 #LT_REVISION=$GTK_INTERFACE_AGE
 101 #LT_AGE=`expr $GTK_BINARY_AGE - $GTK_INTERFACE_AGE`
 102 #LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
 103
 104 m4_define([lt_current], [m4_eval(100 * gtk_minor_version + gtk_micro_version - gtk_interface_age)])
 105 m4_define([lt_revision], [gtk_interface_age])
 106 m4_define([lt_age], [m4_eval(gtk_binary_age - gtk_interface_age)])
 107 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
 108 LT_CURRENT_MINUS_AGE=m4_eval(lt_current - lt_age)
 109 AC_SUBST(LT_VERSION_INFO)
 110 AC_SUBST(LT_CURRENT_MINUS_AGE)
 111
 112 m4_define([gail_lt_current],[0])
 113 m4_define([gail_lt_revision],[0])
 114 m4_define([gail_lt_age],[0])
 115 m4_define([gail_lt_version_info],[gail_lt_current:gail_lt_revision:gail_lt_age])
 116 m4_define([gail_lt_current_minus_age],[m4_eval(gail_lt_current - gail_lt_age)])
 117 AC_SUBST([GAIL_LT_VERSION_INFO],[gail_lt_version_info])
 118 AC_SUBST([GAIL_LT_CURRENT_MINUS_AGE],[gail_lt_current_minus_age])
 119
 120 # Checks for programs.
 121 AC_PROG_CC
 122 AC_PROG_CC_C_O
 123 AC_PROG_CC_STDC
 124 AC_PROG_INSTALL
 125 AC_PROG_MAKE_SET
 126
 127
 128 GETTEXT_PACKAGE=gtk30
 129 AC_SUBST(GETTEXT_PACKAGE)
 130 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
 131                    [The prefix for our gettext translation domains.])
 132
 133 AC_CANONICAL_HOST
 134
 135 MATH_LIB=-lm
 136 AC_MSG_CHECKING([for native Win32])
 137 LIB_EXE_MACHINE_FLAG=X86
 138 EXE_MANIFEST_ARCHITECTURE=X86
 139 case "$host" in
 140   *-*-mingw*)
 141     os_win32=yes
 142     gio_can_sniff=no
 143     MATH_LIB=
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       EXE_MANIFEST_ARCHITECTURE=AMD64
 148       ;;
 149     esac
 150     ;;
 151   *)
 152     os_win32=no
 153     ;;
 154 esac
 155 AC_MSG_RESULT([$os_win32])
 156
 157 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 158 AC_SUBST(EXE_MANIFEST_ARCHITECTURE)
 159
 160 case $host in
 161   *-*-linux*)
 162     os_linux=yes
 163     ;;
 164 esac
 165
 166 dnl
 167 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 168 dnl We use this for an automated test for C++ header correctness.
 169 dnl
 170 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], gcc)
 171 AC_LANG_PUSH([C++])
 172
 173 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 174 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 175
 176 gtk_save_cxxflags="$CXXFLAGS"
 177 CXXFLAGS="$CXXFLAGS -x objective-c++"
 178 AC_TRY_COMPILE([@interface Foo @end],,OBJC=yes,OBJC=no)
 179 AM_CONDITIONAL(HAVE_OBJC, test "$OBJC" = "yes")
 180 CXXFLAGS="$gtk_save_cxxflags"
 181 AC_LANG_POP([C++])
 182
 183 if test "$os_win32" = "yes"; then
 184   if test x$enable_static = xyes -o x$enable_static = x; then
 185     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 186     enable_static=no
 187   fi
 188   if test x$enable_shared = xno; then
 189     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 190   fi
 191   enable_shared=yes
 192 fi
 193
 194 dnl Initialize libtool
 195 LT_PREREQ([2.2.6])
 196 LT_INIT([disable-static win32-dll])
 197 # Create libtool early, because it's used in configure
 198 LT_OUTPUT
 199
 200 # Make sure we use 64-bit versions of various file stuff.
 201 AC_SYS_LARGEFILE
 202
 203 AM_PROG_AS
 204 AC_PATH_PROG(NM, nm, nm)
 205
 206 AC_MSG_CHECKING([for some Win32 platform])
 207 case "$host" in
 208   *-*-mingw*|*-*-cygwin*)
 209     platform_win32=yes
 210     ;;
 211   *)
 212     platform_win32=no
 213     ;;
 214 esac
 215 AC_MSG_RESULT([$platform_win32])
 216 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 217
 218 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
 219 AM_CONDITIONAL(OS_UNIX, test "$os_win32" != "yes")
 220 AM_CONDITIONAL(OS_LINUX, test "$os_linux" = "yes")
 221
 222 if test "$os_win32" = "yes"; then
 223   AC_CHECK_TOOL(WINDRES, windres, no)
 224   if test "$WINDRES" = no; then
 225     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 226   fi
 227   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 228 fi
 229 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 230
 231 m4_define([debug_default],
 232           m4_if(m4_eval(gtk_minor_version % 2), [1], [yes], [minimum]))
 233
 234 dnl declare --enable-* args and collect ac_help strings
 235 AC_ARG_ENABLE(debug,
 236               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 237                              [turn on debugging @<:@default=debug_default@:>@]),,
 238               enable_debug=debug_default)
 239
 240 AC_ARG_ENABLE(rebuilds,
 241               [AC_HELP_STRING([--disable-rebuilds],
 242                               [disable all source autogeneration rules])],,
 243               [enable_rebuilds=yes])
 244
 245 AC_ARG_ENABLE(xkb,
 246               [AC_HELP_STRING([--enable-xkb],
 247                               [support XKB extension [default=maybe]])],,
 248               [enable_xkb="maybe"])
 249 AC_ARG_ENABLE(xinerama,
 250               [AC_HELP_STRING([--enable-xinerama],
 251                               [support Xinerama extension if available [default=yes]])],,
 252               [enable_xinerama="yes"])
 253 AC_ARG_ENABLE(xinput,
 254               [AC_HELP_STRING([--enable-xinput],
 255                               [support XInput extension if available [default=yes]])],,
 256               [enable_xinput="yes"])
 257
 258 AC_ARG_ENABLE(x11-backend,
 259               [AC_HELP_STRING([--enable-x11-backend],
 260                               [enable the X11 gdk backend])],
 261                               [backend_set=yes])
 262 AC_ARG_ENABLE(win32-backend,
 263               [AC_HELP_STRING([--enable-win32-backend],
 264                               [enable the Win32 gdk backend])],
 265                               [backend_set=yes])
 266 AC_ARG_ENABLE(quartz-backend,
 267               [AC_HELP_STRING([--enable-quartz-backend],
 268                               [enable the quartz gdk backend])],
 269                               [backend_set=yes])
 270
 271 if test -z "$backend_set"; then
 272   if test "$platform_win32" = yes; then
 273     enable_win32_backend=yes
 274   else
 275     enable_x11_backend=yes
 276   fi
 277 fi
 278
 279 cairo_backends=
 280 backend_immodules=
 281 GDK_BACKENDS=
 282 GDK_EXTRA_LIBS=
 283 GDK_EXTRA_CFLAGS=
 284 GDK_WINDOWING=
 285 GIO_PACKAGE=gio-2.0
 286 PANGO_PACKAGES="pango pangocairo"
 287
 288 if test "x$enable_x11_backend" == xyes; then
 289   # GDK calls the xlib backend "x11," cairo calls it "xlib." Other
 290   # backend names are identical.
 291   cairo_backends="$cairo_backends cairo-xlib"
 292   GDK_BACKENDS="$GDK_BACKENDS x11"
 293   # Pull in gio-unix for GDesktopAppInfo usage, see at least
 294   # gdkapplaunchcontext-x11.c
 295   GIO_PACKAGE=gio-unix-2.0
 296   backend_immodules="$backend_immodules,xim"
 297   GDK_WINDOWING="$GDK_WINDOWING
 298 #define GDK_WINDOWING_X11"
 299 fi
 300
 301 if test "x$enable_win32_backend" == xyes; then
 302   cairo_backends="$cairo_backends cairo-win32"
 303   GDK_BACKENDS="$GDK_BACKENDS win32"
 304   backend_immodules="$backend_immodules,ime"
 305   GDK_WINDOWING="$GDK_WINDOWING
 306 #define GDK_NATIVE_WINDOW_POINTER
 307 #define GDK_WINDOWING_WIN32"
 308   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -lgdi32 -limm32 -lshell32 -lole32 -Wl,-luuid"
 309   AM_CONDITIONAL(USE_WIN32, true)
 310   PANGO_PACKAGES="pangowin32 pangocairo"
 311 else
 312   AM_CONDITIONAL(USE_WIN32, false)
 313 fi
 314
 315 if test "x$enable_quartz_backend" == xyes; then
 316   cairo_backends="$cairo_backends cairo-quartz"
 317   GDK_BACKENDS="$GDK_BACKENDS quartz"
 318   GDK_WINDOWING="$GDK_WINDOWING
 319 #define GDK_WINDOWING_QUARTZ"
 320   GDK_EXTRA_LIBS="$GDK_EXTRA_LIBS -framework Cocoa"
 321   AM_CONDITIONAL(USE_QUARTZ, true)
 322 else
 323   AM_CONDITIONAL(USE_QUARTZ, false)
 324 fi
 325
 326
 327 AC_SUBST(GDK_BACKENDS)
 328
 329 if test -z "$GDK_BACKENDS"; then
 330   AC_MSG_ERROR([No GDK backends selected.])
 331 fi
 332
 333 if test "x$enable_debug" = "xyes"; then
 334   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 335   GTK_DEBUG_FLAGS="-DG_ENABLE_DEBUG -DG_ERRORCHECK_MUTEXES"
 336 else
 337   if test "x$enable_debug" = "xno"; then
 338     GTK_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"
 339   else
 340     GTK_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 341   fi
 342 fi
 343
 344
 345 AC_DEFINE_UNQUOTED(GTK_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 346                    [Define if debugging is enabled])
 347
 348
 349 # Build time sanity check...
 350 AM_SANITY_CHECK
 351
 352 changequote(,)dnl
 353 if test "x$GCC" = "xyes"; then
 354   case " $CFLAGS " in
 355   *[\ \ ]-Wall[\ \      ]*) ;;
 356   *) CFLAGS="$CFLAGS -Wall" ;;
 357   esac
 358
 359   if test "x$enable_ansi" = "xyes"; then
 360     case " $CFLAGS " in
 361     *[\ \       ]-ansi[\ \      ]*) ;;
 362     *) CFLAGS="$CFLAGS -ansi" ;;
 363     esac
 364
 365     case " $CFLAGS " in
 366     *[\ \       ]-pedantic[\ \  ]*) ;;
 367     *) CFLAGS="$CFLAGS -pedantic" ;;
 368     esac
 369   fi
 370 fi
 371 changequote([,])dnl
 372
 373 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES -DATK_DISABLE_SINGLE_INCLUDES"
 374
 375 # Ensure MSVC-compatible struct packing convention is used when
 376 # compiling for Win32 with gcc.
 377 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 378 # gcc2 uses "-fnative-struct".
 379 if test x"$os_win32" = xyes; then
 380   if test x"$GCC" = xyes; then
 381     msnative_struct=''
 382     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 383     if test -z "$ac_cv_prog_CC"; then
 384       our_gcc="$CC"
 385     else
 386       our_gcc="$ac_cv_prog_CC"
 387     fi
 388     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 389       2.)
 390         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 391           msnative_struct='-fnative-struct'
 392         fi
 393         ;;
 394       *)
 395         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 396           msnative_struct='-mms-bitfields'
 397         fi
 398         ;;
 399     esac
 400     if test x"$msnative_struct" = x ; then
 401       AC_MSG_RESULT([no way])
 402       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 403     else
 404       CFLAGS="$CFLAGS $msnative_struct"
 405       AC_MSG_RESULT([${msnative_struct}])
 406     fi
 407   fi
 408 fi
 409
 410 ## Initial sanity check, done here so that users get told they
 411 ## have the wrong dependencies as early in the process as possible.
 412 ## Later on we actually use the cflags/libs from separate pkg-config
 413 ## calls. Oh, also the later pkg-config calls don't include
 414 ## the version requirements since those make the module lists
 415 ## annoying to construct
 416 PKG_CHECK_MODULES(BASE_DEPENDENCIES,
 417   [glib-2.0 >= glib_required_version dnl
 418    atk >= atk_required_version dnl
 419    pango >= pango_required_version dnl
 420    cairo >= cairo_required_version dnl
 421    cairo-gobject >= cairo_required_version dnl
 422    gdk-pixbuf-2.0 >= gdk_pixbuf_required_version])
 423
 424 PKG_CHECK_MODULES(CAIRO_BACKEND, [$cairo_backends])
 425
 426 if test "$os_win32" != yes; then
 427     # libtool option to control which symbols are exported
 428     # right now, symbols starting with _ are not exported
 429     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 430 else
 431     # We currently use .def files on Windows (for gdk and gtk)
 432     LIBTOOL_EXPORT_OPTIONS=
 433 fi
 434 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 435
 436 dnl ******************************************************
 437 dnl * See whether to include shared library dependencies *
 438 dnl ******************************************************
 439
 440 AC_ARG_ENABLE(explicit-deps,
 441               [AC_HELP_STRING([--enable-explicit-deps=@<:@yes/no/auto@:>@],
 442                               [use explicit dependencies in .pc files [default=auto]])],,
 443               [enable_explicit_deps=auto])
 444
 445 AC_MSG_CHECKING([Whether to write dependencies into .pc files])
 446 case $enable_explicit_deps in
 447   auto)
 448     export SED
 449     deplibs_check_method=`(./libtool --config; echo 'eval echo \"$deplibs_check_method\"') | sh`
 450     if test "x$deplibs_check_method" '!=' xpass_all || test "x$enable_static" = xyes ; then
 451       enable_explicit_deps=yes
 452     else
 453       enable_explicit_deps=no
 454     fi
 455   ;;
 456   yes|no)
 457   ;;
 458   *) AC_MSG_ERROR([Value given to --enable-explicit-deps must be one of yes, no or auto])
 459   ;;
 460 esac
 461 AC_MSG_RESULT($enable_explicit_deps)
 462
 463 AM_CONDITIONAL(DISABLE_EXPLICIT_DEPS, test $enable_explicit_deps = no)
 464
 465 # define a MAINT-like variable REBUILD which is set if Perl
 466 # and awk are found, so autogenerated sources can be rebuilt
 467
 468 AC_PATH_PROGS(PERL, perl5 perl)
 469
 470 # We would like indent, but don't require it.
 471 AC_CHECK_PROG(INDENT, indent, indent)
 472
 473 REBUILD=\#
 474 if test "x$enable_rebuilds" = "xyes" && \
 475      test -n "$PERL" && \
 476      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 ; then
 477   REBUILD=
 478 fi
 479 AC_SUBST(REBUILD)
 480
 481 AC_CHECK_FUNCS(lstat mkstemp flockfile getc_unlocked)
 482 AC_CHECK_FUNCS(localtime_r)
 483
 484 # _NL_TIME_FIRST_WEEKDAY is an enum and not a define
 485 AC_MSG_CHECKING([for _NL_TIME_FIRST_WEEKDAY])
 486 AC_TRY_LINK([#include <langinfo.h>], [
 487 char c;
 488 c = *((unsigned char *)  nl_langinfo(_NL_TIME_FIRST_WEEKDAY));
 489 ], gtk_ok=yes, gtk_ok=no)
 490 AC_MSG_RESULT($gtk_ok)
 491 if test "$gtk_ok" = "yes"; then
 492   AC_DEFINE([HAVE__NL_TIME_FIRST_WEEKDAY], [1],
 493             [Define if _NL_TIME_FIRST_WEEKDAY is available])
 494 fi
 495
 496 # _NL_MEASUREMENT_MEASUREMENT is an enum and not a define
 497 AC_MSG_CHECKING([for _NL_MEASUREMENT_MEASUREMENT])
 498 AC_TRY_LINK([#include <langinfo.h>], [
 499 char c;
 500 c = *((unsigned char *)  nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
 501 ], gtk_ok=yes, gtk_ok=no)
 502 AC_MSG_RESULT($gtk_ok)
 503 if test "$gtk_ok" = "yes"; then
 504   AC_DEFINE([HAVE__NL_MEASUREMENT_MEASUREMENT], [1],
 505             [Define if _NL_MEASUREMENT_MEASUREMENT is available])
 506 fi
 507
 508 # _NL_PAPER_HEIGHT is an enum and not a define
 509 AC_MSG_CHECKING([for _NL_PAPER_HEIGHT])
 510 AC_TRY_LINK([#include <langinfo.h>], [
 511 char c;
 512 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_HEIGHT));
 513 ], gtk_ok=yes, gtk_ok=no)
 514 AC_MSG_RESULT($gtk_ok)
 515 if test "$gtk_ok" = "yes"; then
 516   AC_DEFINE([HAVE__NL_PAPER_HEIGHT], [1],
 517             [Define if _NL_PAPER_HEIGHT is available])
 518 fi
 519
 520 # _NL_PAPER_WIDTH is an enum and not a define
 521 AC_MSG_CHECKING([for _NL_PAPER_WIDTH])
 522 AC_TRY_LINK([#include <langinfo.h>], [
 523 char c;
 524 c = *((unsigned char *)  nl_langinfo(_NL_PAPER_WIDTH));
 525 ], gtk_ok=yes, gtk_ok=no)
 526 AC_MSG_RESULT($gtk_ok)
 527 if test "$gtk_ok" = "yes"; then
 528   AC_DEFINE([HAVE__NL_PAPER_WIDTH], [1],
 529             [Define if _NL_PAPER_WIDTH is available])
 530 fi
 531
 532 # i18n stuff
 533 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 534 AM_GLIB_GNU_GETTEXT
 535 LIBS="$LIBS $INTLLIBS"
 536 AC_OUTPUT_COMMANDS([case "$CONFIG_FILES" in *po-properties/Makefile.in*)
 537         sed -e "/POTFILES =/r po-properties/POTFILES" po-properties/Makefile.in > po-properties/Makefile
 538       esac])
 539
 540 dnl Snippet below is copied from AM_GLIB_GNU_GETTEXT to generate a first
 541 dnl po-properties/POTFILES during configure; see GNOME #573515.
 542 dnl
 543 dnl Generate list of files to be processed by xgettext which will
 544 dnl be included in po-properties/Makefile.
 545 test -d po-properties || mkdir po-properties
 546 if test "x$srcdir" != "x."; then
 547   if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 548     popropsrcprefix="$srcdir/"
 549   else
 550     popropsrcprefix="../$srcdir/"
 551   fi
 552 else
 553   popropsrcprefix="../"
 554 fi
 555 rm -f po-properties/POTFILES
 556 sed -e "/^#/d" -e "/^\$/d" -e "s,.*,    $popropsrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 557 < $srcdir/po-properties/POTFILES.in > po-properties/POTFILES
 558 dnl (End of adapted AM_GLIB_GNU_GETTEXT snippet.)
 559
 560 AM_GLIB_DEFINE_LOCALEDIR(GTK_LOCALEDIR)
 561
 562 dnl The DU4 header files don't provide library prototypes unless
 563 dnl -std1 is given to the native cc.
 564 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 565
 566 gtk_save_LIBS=$LIBS
 567 LIBS="$LIBS -lm"
 568 AC_TRY_RUN([#include <math.h>
 569              int main (void) { return (log(1) != log(1.)); }],
 570      AC_MSG_RESULT(none needed),
 571      gtk_save_CFLAGS="$CFLAGS"
 572      CFLAGS="$CFLAGS -std1"
 573      AC_TRY_RUN([#include <math.h>
 574                  int main (void) { return (log(1) != log(1.)); }],
 575          AC_MSG_RESULT(-std1),
 576          AC_MSG_RESULT()
 577          CFLAGS="$gtk_save_CFLAGS"
 578          AC_MSG_WARN(
 579                 [No ANSI prototypes found in library. (-std1 didn't work.)]),
 580          true
 581      ),
 582      AC_MSG_RESULT(none needed)
 583 )
 584 LIBS=$gtk_save_LIBS
 585
 586 AC_MSG_CHECKING(for the BeOS)
 587 case $host in
 588   *-*-beos*)
 589     AC_MSG_RESULT(yes)
 590     MATH_LIB=
 591   ;;
 592   *)
 593     AC_MSG_RESULT(no)
 594   ;;
 595 esac
 596
 597 AC_SUBST(MATH_LIB)
 598 #
 599 # see bug 162979
 600 #
 601 AC_MSG_CHECKING(for HP-UX)
 602 case $host_os in
 603   hpux9* | hpux10* | hpux11*)
 604     AC_MSG_RESULT(yes)
 605     CFLAGS="$CFLAGS -DHPPEX -DSHMLINK"
 606   ;;
 607   *)
 608     AC_MSG_RESULT(no)
 609   ;;
 610 esac
 611
 612 dnl NeXTStep cc seems to need this
 613 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 614 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 615   AC_MSG_RESULT(none needed),
 616   gtk_save_CFLAGS="$CFLAGS"
 617   CFLAGS="$CFLAGS -posix"
 618   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 619     AC_MSG_RESULT(-posix),
 620     AC_MSG_RESULT()
 621     CFLAGS="$gtk_save_CFLAGS"
 622     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 623
 624 #
 625 # Run AM_PATH_GLIB_2_0 to make sure that GLib is installed and working
 626 #
 627
 628 GLIB_PACKAGES="gobject-2.0 gio-2.0 gmodule-no-export-2.0"
 629
 630 AM_PATH_GLIB_2_0(glib_required_version, :,
 631   AC_MSG_ERROR([
 632 *** GLIB glib_required_version or better is required. The latest version of
 633 *** GLIB is always available from ftp://ftp.gtk.org/pub/gtk/.]),
 634   gobject gmodule-no-export gthread)
 635
 636 # See if it's safe to turn G_DISABLE_DEPRECATED on.
 637 GLIB_VERSION_MAJOR_MINOR=`$PKG_CONFIG --modversion glib-2.0 | sed "s/\.@<:@^.@:>@*\$//"`
 638 GLIB_REQUIRED_VERSION_MAJOR_MINOR=`echo glib_required_version | sed "s/\.@<:@^.@:>@*\$//"`
 639 if test "x$GLIB_VERSION_MAJOR_MINOR" = "x$GLIB_REQUIRED_VERSION_MAJOR_MINOR"; then
 640   CFLAGS="-DG_DISABLE_DEPRECATED $CFLAGS"
 641 fi
 642
 643 CFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CFLAGS"
 644
 645
 646 dnl
 647 dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.
 648 dnl
 649 gtk_save_LIBS=$LIBS
 650 LIBS="$LIBS $GLIB_LIBS"
 651 AC_CHECK_FUNCS(bind_textdomain_codeset)
 652 LIBS=$gtk_save_LIBS
 653
 654 AC_CHECK_HEADERS(pwd.h,
 655                  AC_DEFINE(HAVE_PWD_H, 1,
 656                            [Define to 1 if pwd.h is available]))
 657 AC_CHECK_HEADERS(sys/time.h,
 658                  AC_DEFINE(HAVE_SYS_TIME_H, 1,
 659                            [Define to 1 if time.h is available]))
 660 AC_CHECK_HEADERS(unistd.h,
 661                  AC_DEFINE(HAVE_UNISTD_H, 1,
 662                            [Define to 1 if unistd.h is available]))
 663 AC_CHECK_HEADERS(ftw.h,
 664                  AC_DEFINE(HAVE_FTW_H, 1,
 665                            [Define to 1 if ftw.h is available]))
 666
 667 AC_MSG_CHECKING([for GNU ftw extensions])
 668 AC_TRY_COMPILE([#define _XOPEN_SOURCE 500
 669 #define _GNU_SOURCE
 670 #include <ftw.h>], [int flags = FTW_ACTIONRETVAL;], gtk_ok=yes, gtk_ok=no)
 671 if test $gtk_ok = yes; then
 672     AC_MSG_RESULT([yes])
 673     AC_DEFINE(HAVE_GNU_FTW, 1, [Have GNU ftw])
 674 else
 675     AC_MSG_RESULT([no])
 676 fi
 677
 678 saved_cflags="$CFLAGS"
 679 saved_ldflags="$LDFLAGS"
 680
 681
 682 # Checks for header files.
 683 AC_HEADER_STDC
 684
 685 # Checks for typedefs, structures, and compiler characteristics.
 686 AC_C_CONST
 687
 688 # Checks for library functions.
 689 AC_TYPE_SIGNAL
 690 AC_FUNC_MMAP
 691
 692 AC_CHECK_FUNCS(mallinfo)
 693 AC_CHECK_FUNCS(getresuid)
 694 AC_TYPE_UID_T
 695
 696 # Check if <sys/select.h> needs to be included for fd_set
 697 AC_MSG_CHECKING([for fd_set])
 698 AC_TRY_COMPILE([#include <sys/types.h>],
 699         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 700 if test $gtk_ok = yes; then
 701     AC_MSG_RESULT([yes, found in sys/types.h])
 702 else
 703     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 704     if test $gtk_ok = yes; then
 705         AC_DEFINE(HAVE_SYS_SELECT_H, 1,
 706                   [Define to 1 if sys/select.h is available])
 707         AC_MSG_RESULT([yes, found in sys/select.h])
 708     else
 709         AC_DEFINE(NO_FD_SET, 1,
 710                   [Define to 1 if fd_set is not available])
 711         AC_MSG_RESULT(no)
 712     fi
 713 fi
 714
 715 # Check for uxtheme.h (for MS-Windows Engine)
 716 AC_MSG_CHECKING(for uxtheme.h)
 717 AC_TRY_CPP([#include <uxtheme.h>], gtk_uxtheme_h=yes, gtk_uxtheme_h=no)
 718 if test $gtk_uxtheme_h = yes; then
 719    AC_DEFINE(HAVE_UXTHEME_H, 1, [Have uxtheme.h include file])
 720 fi
 721 AC_MSG_RESULT($gtk_uxtheme_h)
 722
 723 # Checks for gdkspawn
 724 AC_CHECK_HEADERS(crt_externs.h)
 725 AC_CHECK_FUNCS(_NSGetEnviron)
 726
 727 AC_MSG_CHECKING(whether to build dynamic modules)
 728
 729 AC_ARG_ENABLE(modules,
 730               [AC_HELP_STRING([--disable-modules],
 731                               [disable dynamic module loading])])
 732
 733 dynworks=false
 734 deps=
 735 if test x$enable_modules = xno; then
 736     AC_MSG_RESULT(no)
 737 else
 738     AC_MSG_RESULT(yes)
 739     AC_MSG_CHECKING(whether dynamic modules work)
 740     ## for loop is to strip newline
 741     tmp=`$PKG_CONFIG --variable=gmodule_supported gmodule-no-export-2.0`
 742     for I in $tmp; do
 743         dynworks=$I
 744     done
 745
 746     dnl Now we check to see if our libtool supports shared lib deps
 747     dnl (in a rather ugly way even)
 748     if $dynworks; then
 749         module_libtool_config="${CONFIG_SHELL-/bin/sh} ./libtool --config"
 750         module_deplibs_check=`$module_libtool_config | \
 751             grep '^[[a-z_]]*check[[a-z_]]*_method=[['\''"]]' | \
 752             sed 's/.*[['\''"]]\(.*\)[['\''"]]$/\1/'`
 753         if test "x$module_deplibs_check" = "xnone" || \
 754            test "x$module_deplibs_check" = "xunknown" || \
 755            test "x$module_deplibs_check" = "x"; then
 756             dynworks=false
 757         fi
 758     fi
 759
 760     if $dynworks; then
 761         AC_DEFINE(USE_GMODULE, 1,
 762                   [Define to 1 if gmodule works and should be used])
 763         AC_MSG_RESULT(yes)
 764     else
 765         AC_MSG_RESULT(no)
 766     fi
 767 fi
 768
 769 AM_CONDITIONAL(BUILD_DYNAMIC_MODULES, $dynworks)
 770
 771 #
 772 # Allow building some or all immodules included
 773 #
 774 AC_MSG_CHECKING(immodules to build)
 775
 776 dnl due to an autoconf bug, commas in the first arg to
 777 dnl AC_HELP_STRING cause problems.
 778 dnl AC_HELP_STRING([--with-included-immodules=MODULE1 MODULE2 ...],
 779 dnl                [build the specified input method modules into gtk])
 780 AC_ARG_WITH(included_immodules,
 781             AC_HELP_STRING([--with-included-immodules=MODULE1,MODULE2,...],
 782                            [build the specified input methods into gtk]))
 783
 784 if $dynworks; then
 785    :
 786 else
 787    ## if the option was specified, leave it; otherwise disable included immodules
 788    if test x$with_included_immodules = xno; then
 789            with_included_immodules=yes
 790    fi
 791 fi
 792
 793 all_immodules="am-et,cedilla,cyrillic-translit,inuktitut,ipa,multipress,thai,ti-er,ti-et,viqr$backend_immodules"
 794
 795 included_immodules=""
 796 # If the switch specified without listing any specific ones, include all
 797 if test "x$with_included_immodules" = xyes ; then
 798   included_immodules="$all_immodules"
 799 else
 800   included_immodules="$with_included_immodules"
 801 fi
 802
 803 AC_MSG_RESULT($included_immodules)
 804 AM_CONDITIONAL(HAVE_INCLUDED_IMMMODULES, test "x$included_immodules" != x)
 805
 806 INCLUDED_IMMODULE_OBJ=
 807 INCLUDED_IMMODULE_DEFINE=
 808
 809 IFS="${IFS=     }"; gtk_save_ifs="$IFS"; IFS=","
 810 for immodule in $included_immodules; do
 811  immodule_underscores=`echo $immodule | sed -e 's/-/_/g'`
 812  if echo "$all_immodules" | egrep "(^|,)$immodule(\$|,)" > /dev/null; then
 813    :
 814  else
 815    AC_MSG_ERROR([the specified input method $immodule does not exist])
 816  fi
 817
 818  INCLUDED_IMMODULE_OBJ="$INCLUDED_IMMODULE_OBJ ../modules/input/libstatic-im-$immodule.la"
 819  INCLUDED_IMMODULE_DEFINE="$INCLUDED_IMMODULE_DEFINE -DINCLUDE_IM_$immodule_underscores"
 820  eval INCLUDE_$immodule_underscores=yes
 821 done
 822 IFS="$gtk_save_ifs"
 823 AC_SUBST(INCLUDED_IMMODULE_OBJ)
 824 AC_SUBST(INCLUDED_IMMODULE_DEFINE)
 825
 826 AM_CONDITIONAL(INCLUDE_IM_AM_ET, [test x"$INCLUDE_am_et" = xyes])
 827 AM_CONDITIONAL(INCLUDE_IM_CEDILLA, [test x"$INCLUDE_cedilla" = xyes])
 828 AM_CONDITIONAL(INCLUDE_IM_CYRILLIC_TRANSLIT, [test x"$INCLUDE_cyrillic_translit" = xyes])
 829 AM_CONDITIONAL(INCLUDE_IM_IME, [test x"$INCLUDE_ime" = xyes])
 830 AM_CONDITIONAL(INCLUDE_IM_INUKTITUT, [test x"$INCLUDE_inuktitut" = xyes])
 831 AM_CONDITIONAL(INCLUDE_IM_IPA, [test x"$INCLUDE_ipa" = xyes])
 832 AM_CONDITIONAL(INCLUDE_IM_MULTIPRESS, [test x"$INCLUDE_multipress" = xyes])
 833 AM_CONDITIONAL(INCLUDE_IM_THAI, [test x"$INCLUDE_thai" = xyes])
 834 AM_CONDITIONAL(INCLUDE_IM_TI_ER, [test x"$INCLUDE_ti_er" = xyes])
 835 AM_CONDITIONAL(INCLUDE_IM_TI_ET, [test x"$INCLUDE_ti_et" = xyes])
 836 AM_CONDITIONAL(INCLUDE_IM_VIQR, [test x"$INCLUDE_viqr" = xyes])
 837 AM_CONDITIONAL(INCLUDE_IM_XIM, [test x"$INCLUDE_xim" = xyes])
 838
 839 AC_HEADER_SYS_WAIT
 840
 841 AC_TYPE_SIGNAL
 842
 843 # Checks to see whether we should include mediaLib
 844 # support.
 845 #
 846 AC_CHECK_HEADER(sys/systeminfo.h,
 847                 AC_DEFINE(HAVE_SYS_SYSTEMINFO_H, 1,
 848                           [Define to 1 if sys/systeminfo.h is available]))
 849 AC_CHECK_HEADER(sys/sysinfo.h,
 850                 AC_DEFINE(HAVE_SYS_SYSINFO_H, 1,
 851                           [Define to 1 if sys/sysinfo.h is available]))
 852
 853 dnl Look for a host system's gdk-pixbuf-csource if we are cross-compiling
 854
 855 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 856
 857 if test $cross_compiling = yes; then
 858   AC_PATH_PROG(GTK_UPDATE_ICON_CACHE, gtk-update-icon-cache, no)
 859   if test x$GTK_UPDATE_ICON_CACHE = xno; then
 860     REBUILD_PNGS=#
 861   fi
 862 fi
 863
 864 AC_PATH_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource, no)
 865
 866 if test ! -f $srcdir/gtk/gtkbuiltincache.h &&
 867    test "x$REBUILD_PNGS" = "x#" ; then
 868      AC_MSG_ERROR([
 869 *** gtkbuiltincache.h is not in the tree, and cannot be built
 870 *** because you don't have libpng, or (when cross-compiling) you
 871 *** don't have a prebuilt gtk-update-icon-cache on the build system.])
 872 fi
 873
 874 ########################################
 875 # Windowing system checks
 876 ########################################
 877
 878 # GTK+ uses some X calls, so needs to link against X directly
 879 GTK_DEP_PACKAGES_FOR_X=
 880 GTK_DEP_LIBS_FOR_X=
 881
 882 if test "x$enable_x11_backend" == xyes; then
 883   X_PACKAGES=fontconfig
 884
 885   #
 886   # We use fontconfig very peripherally when decoding the default
 887   # settings.
 888   #
 889   if $PKG_CONFIG --exists fontconfig; then : ; else
 890     AC_MSG_ERROR([
 891 *** fontconfig (http://www.fontconfig.org) is required by the X11 backend.])
 892   fi
 893
 894   #
 895   # Check for basic X packages; we use pkg-config if available
 896   #
 897   if $PKG_CONFIG --exists x11 xext; then
 898     have_base_x_pc=true
 899     X_PACKAGES="$X_PACKAGES x11 xext"
 900     x_libs="`$PKG_CONFIG --libs x11 xext`"
 901     X_CFLAGS="`$PKG_CONFIG --cflags x11 xext`"
 902
 903     # Strip out any .la files that pkg-config might give us (this happens
 904     # with -uninstalled.pc files)
 905     x_libs_for_checks=
 906     for I in $x_libs ; do
 907       case $I in
 908         *.la) ;;
 909         *) x_libs_for_checks="$x_libs_for_checks $I" ;;
 910       esac
 911     done
 912
 913     GTK_PACKAGES_FOR_X="x11"
 914   else
 915     have_base_x_pc=false
 916     AC_PATH_XTRA
 917     if test x$no_x = xyes ; then
 918       AC_MSG_ERROR([X development libraries not found])
 919     fi
 920
 921     x_cflags="$X_CFLAGS"
 922     x_libs_for_checks="$X_LIBS -lXext -lX11 $X_EXTRA_LIBS"
 923
 924     GTK_DEP_LIBS_FOR_X="$X_LIBS -lX11 $X_EXTRA_LIBS"
 925   fi
 926
 927   # Extra libraries found during checks (-lXinerama, etc), not from pkg-config.
 928   x_extra_libs=
 929
 930   gtk_save_cppflags="$CPPFLAGS"
 931   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 932
 933   gtk_save_LIBS=$LIBS
 934   LIBS="$x_libs_for_checks $LIBS"
 935
 936   # Sanity check for the X11 and Xext libraries. While everything we need from
 937   # Xext is optional, the chances a system has *none* of these things is so
 938   # small that we just unconditionally require it.
 939   AC_CHECK_FUNC(XOpenDisplay, :,
 940                 AC_MSG_ERROR([*** libX11 not found. Check 'config.log' for more details.]))
 941   AC_CHECK_FUNC(XextFindDisplay, :,
 942                 AC_MSG_ERROR([*** libXext not found. Check 'config.log' for more details.]))
 943
 944   # Check for xReply
 945
 946   AC_MSG_CHECKING([if <X11/extensions/XIproto.h> is needed for xReply])
 947   AC_TRY_COMPILE([#include <X11/Xlibint.h>],
 948       [xReply *rep;],
 949       [AC_MSG_RESULT([no])],
 950       [AC_TRY_COMPILE([#include <X11/extensions/XIproto.h>
 951 #include <X11/Xlibint.h>],
 952            [xReply *rep;],
 953            [AC_MSG_RESULT([yes])
 954             AC_DEFINE([NEED_XIPROTO_H_FOR_XREPLY], 1,
 955                       [Define if <X11/extensions/XIproto.h> needed for xReply])],
 956            [AC_MSG_RESULT([unknown])
 957             AC_MSG_ERROR([xReply type unavailable. X11 is too old])])])
 958
 959   # Check for XConvertCase, XInternAtoms (X11R6 specific)
 960
 961   AC_CHECK_FUNCS(XConvertCase XInternAtoms)
 962
 963   # Generic X11R6 check needed for XIM support; we could
 964   # probably use this to replace the above, but we'll
 965   # leave the separate checks for XConvertCase and XInternAtoms
 966   # for clarity
 967
 968   have_x11r6=false
 969   AC_CHECK_FUNC(XAddConnectionWatch,
 970       have_x11r6=true)
 971
 972   if $have_x11r6; then
 973     AC_DEFINE(HAVE_X11R6, 1, [Define if we have X11R6])
 974   fi
 975   AM_CONDITIONAL(HAVE_X11R6, $have_x11r6)
 976
 977   # Check for XKB support.
 978
 979   if test "x$enable_xkb" = "xyes"; then
 980         AC_MSG_WARN(XKB support explicitly enabled)
 981         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
 982   elif test "x$enable_xkb" = "xmaybe"; then
 983         AC_CHECK_FUNC(XkbQueryExtension,
 984                       AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension]))
 985   else
 986         AC_MSG_WARN(XKB support explicitly disabled)
 987   fi
 988
 989   # Check for shaped window extension
 990
 991   AC_CHECK_FUNC(XShapeCombineMask, :,
 992      [AC_MSG_ERROR([Shape extension not found, check your development headers])])
 993
 994   # X SYNC check
 995   gtk_save_CFLAGS="$CFLAGS"
 996   CFLAGS="$CFLAGS $x_cflags"
 997
 998   AC_CHECK_FUNC(XSyncQueryExtension,
 999       [AC_CHECK_HEADER(X11/extensions/sync.h,
1000           AC_DEFINE(HAVE_XSYNC, 1, [Have the SYNC extension library]),
1001           :, [#include <X11/Xlib.h>])])
1002
1003   CFLAGS="$gtk_save_CFLAGS"
1004
1005   if test "x$enable_xinerama" = "xyes"; then
1006     # Check for Xinerama extension (Solaris impl or Xfree impl)
1007     gtk_save_cppflags="$CPPFLAGS"
1008     CPPFLAGS="$CPPFLAGS $x_cflags"
1009
1010     # Check for XFree
1011     AC_MSG_CHECKING(for Xinerama support on XFree86)
1012
1013     have_xfree_xinerama=false
1014     if $PKG_CONFIG --exists xinerama ; then
1015        have_xfree_xinerama=true
1016        X_PACKAGES="$X_PACKAGES xinerama"
1017     else
1018        AC_CHECK_LIB(Xinerama, XineramaQueryExtension,
1019            [AC_CHECK_HEADER(X11/extensions/Xinerama.h,
1020            [GTK_ADD_LIB(x_extra_libs,Xinerama)
1021            have_xfree_xinerama=true], :,
1022            [#include <X11/Xlib.h>])])
1023     fi
1024
1025     if $have_xfree_xinerama ; then
1026       AC_DEFINE(HAVE_XFREE_XINERAMA, 1,
1027                 [Define to 1 if XFree Xinerama is available])
1028       AC_DEFINE(HAVE_XINERAMA, 1,
1029                 [Define to 1 is Xinerama is available])
1030       AC_MSG_RESULT(yes)
1031     else
1032       AC_MSG_RESULT(no)
1033
1034       case "$host" in
1035         *-*-solaris*)
1036             # Check for solaris
1037             AC_MSG_CHECKING(for Xinerama support on Solaris)
1038
1039             have_solaris_xinerama=false
1040             AC_CHECK_FUNC(XineramaGetInfo,
1041                 [AC_CHECK_HEADER(X11/extensions/xinerama.h,
1042                     [have_solaris_xinerama=true], :,
1043                     [#include <X11/Xlib.h>])])
1044
1045             if $have_solaris_xinerama ; then
1046               AC_DEFINE(HAVE_SOLARIS_XINERAMA, 1,
1047                         [Define to 1 if solaris xinerama is available])
1048               AC_DEFINE(HAVE_XINERAMA, 1,
1049                         [Define to 1 if xinerama is available])
1050               AC_MSG_RESULT(yes)
1051             else
1052               AC_MSG_RESULT(no)
1053             fi
1054             ;;
1055         *)
1056             ;;
1057       esac
1058     fi
1059   fi
1060
1061   # set up things for XInput
1062   if test "x$enable_xinput" != "xno" && $PKG_CONFIG --exists "xi" ; then
1063     have_xinput=yes
1064
1065     AC_DEFINE(XINPUT_XFREE, 1,
1066               [Define to 1 if XFree XInput should be used])
1067
1068     X_PACKAGES="$X_PACKAGES xi"
1069
1070     AC_CHECK_HEADER(X11/extensions/XInput2.h,
1071                     have_xinput2=yes; AC_DEFINE(XINPUT_2, 1, [Define to 1 if XInput 2.0 is available]))
1072   else
1073     AC_DEFINE(XINPUT_NONE, 1,
1074               [Define to 1 if no XInput should be used])
1075   fi
1076
1077   AM_CONDITIONAL(XINPUT_XFREE, test "x$have_xinput" = "xyes")
1078   AM_CONDITIONAL(XINPUT_2,     test "x$have_xinput2" = "xyes")
1079
1080   # Check for the RANDR extension
1081   if $PKG_CONFIG --exists "xrandr >= 1.2.99" ; then
1082      AC_DEFINE(HAVE_RANDR, 1, [Have the Xrandr extension library])
1083
1084      X_PACKAGES="$X_PACKAGES xrandr"
1085   fi
1086
1087   # Checks for Xcursor library
1088
1089   if $PKG_CONFIG --exists xcursor ; then
1090     AC_DEFINE(HAVE_XCURSOR, 1, [Have the Xcursor library])
1091
1092     X_PACKAGES="$X_PACKAGES xcursor"
1093   fi
1094
1095   # Checks for XFixes extension
1096
1097   if $PKG_CONFIG --exists xfixes ; then
1098     AC_DEFINE(HAVE_XFIXES, 1, [Have the XFIXES X extension])
1099
1100     X_PACKAGES="$X_PACKAGES xfixes"
1101     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xfixes"
1102   fi
1103
1104   # Checks for Xcomposite extension
1105
1106   if $PKG_CONFIG --exists xcomposite ; then
1107     AC_DEFINE(HAVE_XCOMPOSITE, 1, [Have the XCOMPOSITE X extension])
1108
1109     X_PACKAGES="$X_PACKAGES xcomposite"
1110     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xcomposite"
1111   fi
1112
1113   # Checks for Xdamage extension
1114
1115   if $PKG_CONFIG --exists xdamage ; then
1116     AC_DEFINE(HAVE_XDAMAGE, 1, [Have the XDAMAGE X extension])
1117
1118     X_PACKAGES="$X_PACKAGES xdamage"
1119     GTK_PACKAGES_FOR_X="$GTK_PACKAGES_FOR_X xdamage"
1120   fi
1121
1122   if $have_base_x_pc ; then
1123     GDK_EXTRA_LIBS="$x_extra_libs"
1124   else
1125     GDK_EXTRA_LIBS="$X_LIBS $x_extra_libs -lXext -lX11 $GDK_EXTRA_LIBS"
1126   fi
1127
1128   CPPFLAGS="$gtk_save_cppflags"
1129   LIBS="$gtk_save_libs"
1130
1131   AM_CONDITIONAL(USE_X11, true)
1132 else
1133   XPACKAGES=
1134
1135   AM_CONDITIONAL(XINPUT_XFREE, false)
1136   AM_CONDITIONAL(XINPUT_2, false)
1137   AM_CONDITIONAL(USE_X11, false)
1138   AM_CONDITIONAL(HAVE_X11R6, false)
1139 fi
1140
1141 # Check for Pango flags
1142
1143 AC_MSG_CHECKING(Pango flags)
1144 if $PKG_CONFIG --exists $PANGO_PACKAGES ; then
1145         PANGO_CFLAGS=`$PKG_CONFIG --cflags $PANGO_PACKAGES`
1146         PANGO_LIBS=`$PKG_CONFIG --libs $PANGO_PACKAGES`
1147
1148         AC_MSG_RESULT($PANGO_CFLAGS $PANGO_LIBS)
1149 else
1150         AC_MSG_ERROR([
1151 *** Pango not found. Pango built with Cairo support is required
1152 *** to build GTK+. See http://www.pango.org for Pango information.
1153 ])
1154 fi
1155
1156 CFLAGS="$CFLAGS $PANGO_CFLAGS"
1157
1158 if $PKG_CONFIG --uninstalled $PANGO_PACKAGES; then
1159         :
1160 else
1161         gtk_save_LIBS="$LIBS"
1162         LIBS="$PANGO_LIBS $LIBS"
1163         AC_TRY_LINK_FUNC(pango_context_new, :, AC_MSG_ERROR([
1164 *** Can't link to Pango. Pango is required to build
1165 *** GTK+. For more information see http://www.pango.org]))
1166         LIBS="$gtk_save_LIBS"
1167 fi
1168
1169 CFLAGS="$saved_cflags"
1170 LDFLAGS="$saved_ldflags"
1171
1172 GDK_PACKAGES="$PANGO_PACKAGES $GIO_PACKAGE $X_PACKAGES gdk-pixbuf-2.0 $cairo_backends cairo-gobject"
1173
1174 GDK_DEP_LIBS="$GDK_EXTRA_LIBS `$PKG_CONFIG --libs $GDK_PACKAGES`"
1175 GDK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES` $GDK_EXTRA_CFLAGS"
1176 #
1177 # If we aren't writing explicit dependencies, then don't put the extra libraries we need
1178 # into the pkg-config files
1179 #
1180 if test $enable_explicit_deps != yes ; then
1181   GDK_PACKAGES="$PANGO_PACKAGES gdk-pixbuf-2.0"
1182   GDK_EXTRA_LIBS=
1183 fi
1184
1185 AC_SUBST(GDK_PACKAGES)
1186 AC_SUBST(GDK_EXTRA_LIBS)
1187 AC_SUBST(GDK_EXTRA_CFLAGS)
1188 AC_SUBST(GDK_DEP_LIBS)
1189 AC_SUBST(GDK_DEP_CFLAGS)
1190
1191
1192 ########################################
1193 # Check for Accessibility Toolkit flags
1194 ########################################
1195
1196 ATK_PACKAGES=atk
1197 AC_MSG_CHECKING(ATK flags)
1198 if $PKG_CONFIG --exists $ATK_PACKAGES ; then
1199         ATK_CFLAGS=`$PKG_CONFIG --cflags $ATK_PACKAGES`
1200         ATK_LIBS=`$PKG_CONFIG --libs $ATK_PACKAGES`
1201
1202         AC_MSG_RESULT($ATK_CFLAGS $ATK_LIBS)
1203 else
1204         AC_MSG_ERROR([
1205 *** Accessibility Toolkit not found. Accessibility Toolkit is required
1206 *** to build GTK+.
1207 ])
1208 fi
1209
1210 if $PKG_CONFIG --uninstalled $ATK_PACKAGES; then
1211         :
1212 else
1213         gtk_save_LIBS="$LIBS"
1214         LIBS="$ATK_LIBS $LIBS"
1215         AC_TRY_LINK_FUNC(atk_object_get_type, : , AC_MSG_ERROR([
1216                 *** Cannot link to Accessibility Toolkit. Accessibility Toolkit is required
1217                 *** to build GTK+]))
1218         LIBS="$gtk_save_LIBS"
1219 fi
1220
1221 GTK_PACKAGES="atk cairo cairo-gobject gdk-pixbuf-2.0 gio-2.0"
1222 if test "x$enable_x11_backend" == xyes; then
1223   GTK_PACKAGES="$GTK_PACKAGES pangoft2"
1224 fi
1225 GTK_EXTRA_LIBS=
1226 GTK_EXTRA_CFLAGS=
1227 GTK_DEP_LIBS="$GDK_EXTRA_LIBS $GTK_DEP_LIBS_FOR_X `$PKG_CONFIG --libs $PANGO_PACKAGES $GTK_PACKAGES_FOR_X $GTK_PACKAGES` $GTK_EXTRA_LIBS"
1228 GTK_DEP_CFLAGS="`$PKG_CONFIG --cflags  gthread-2.0 $GDK_PACKAGES $GTK_PACKAGES` $GDK_EXTRA_CFLAGS $GTK_EXTRA_CFLAGS"
1229
1230 if test x"$os_win32" = xyes; then
1231   GTK_EXTRA_CFLAGS="$msnative_struct"
1232 fi
1233
1234 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
1235 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
1236 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
1237 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
1238
1239 AC_SUBST(GTK_PACKAGES)
1240 AC_SUBST(GTK_EXTRA_LIBS)
1241 AC_SUBST(GTK_EXTRA_CFLAGS)
1242 AC_SUBST(GTK_DEP_LIBS)
1243 AC_SUBST(GTK_DEP_CFLAGS)
1244
1245 AC_SUBST(GLIB_PREFIX)
1246 AC_SUBST(ATK_PREFIX)
1247 AC_SUBST(PANGO_PREFIX)
1248 AC_SUBST(CAIRO_PREFIX)
1249
1250 AC_SUBST(GTK_DEBUG_FLAGS)
1251 AC_SUBST(GTK_XIM_FLAGS)
1252
1253 GDK_PIXBUF_LIBS=`$PKG_CONFIG --libs gdk-pixbuf-2.0`
1254 AC_SUBST(GDK_PIXBUF_LIBS)
1255
1256 ########################
1257 # Checks needed for gail
1258 ########################
1259
1260 old_LIBS="$LIBS"
1261 dnl Checks for inet libraries:
1262 AC_SEARCH_LIBS(gethostent, nsl)
1263 AC_SEARCH_LIBS(setsockopt, socket)
1264 AC_SEARCH_LIBS(connect, inet)
1265
1266 dnl check for the sockaddr_un.sun_len member
1267 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
1268                 [struct_sockaddr_un_sun_len=true],
1269                 [struct_sockaddr_un_suin_len=false],
1270                 [#include <sys/types.h>
1271                  #include <sys/un.h>]
1272                 )
1273 case $struct_sockaddr_un_sun_len in
1274         true)
1275                 AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_UN_SUN_LEN, 1,
1276                                    [Have the sockaddr_un.sun_len member])
1277                 ;;
1278         *)
1279                 ;;
1280 esac
1281
1282 GAIL_INET_LIBS="$LIBS"
1283 AC_SUBST([GAIL_INET_LIBS])
1284
1285 LIBS="$old_LIBS"
1286
1287 ################################################################
1288 # Printing system checks
1289 ################################################################
1290
1291 AC_ARG_ENABLE(cups,
1292               [AC_HELP_STRING([--disable-cups],
1293                               [disable cups print backend])],,
1294               [enable_cups=auto])
1295
1296 if test "x$enable_cups" = "xno"; then
1297   AM_CONDITIONAL(HAVE_CUPS, false)
1298 else
1299   AC_PATH_PROG(CUPS_CONFIG, cups-config, no)
1300   if test "x$CUPS_CONFIG" = "xno"; then
1301     if test "x$enable_cups" = "xauto"; then
1302       AM_CONDITIONAL(HAVE_CUPS, false)
1303     else
1304       AC_MSG_ERROR([
1305 *** cups not found.
1306 ])
1307     fi
1308   else
1309     CUPS_CFLAGS=`$CUPS_CONFIG --cflags | sed 's/-O[0-9]*//' | sed 's/-m[^\t]*//g'`
1310     CUPS_LIBS=`$CUPS_CONFIG --libs`
1311
1312     CUPS_API_VERSION=`$CUPS_CONFIG --api-version`
1313     CUPS_API_MAJOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $1}'`
1314     CUPS_API_MINOR=`echo $ECHO_N $CUPS_API_VERSION | awk -F. '{print $2}'`
1315
1316     if test $CUPS_API_MAJOR -gt 1 -o \
1317             $CUPS_API_MAJOR -eq 1 -a $CUPS_API_MINOR -ge 2; then
1318       AC_DEFINE(HAVE_CUPS_API_1_2, 1,
1319                 [Define to 1 if CUPS 1.2 API is available])
1320     fi
1321
1322     AC_SUBST(CUPS_API_MAJOR)
1323     AC_SUBST(CUPS_API_MINOR)
1324     AC_SUBST(CUPS_CFLAGS)
1325     AC_SUBST(CUPS_LIBS)
1326
1327     AC_CHECK_HEADER(cups/cups.h,,AC_MSG_ERROR([[*** Sorry, cups-config present but cups/cups.h missing.]]))
1328
1329     AM_CONDITIONAL(HAVE_CUPS, true)
1330
1331     gtk_save_cflags="$CFLAGS"
1332     CFLAGS="$CUPS_CFLAGS"
1333     AC_TRY_COMPILE([#include <cups/http.h>],
1334                    [http_t http; char *s = http.authstring;],
1335                    [AC_DEFINE(HAVE_HTTP_AUTHSTRING, [],
1336                               [Define if cups http_t authstring field is accessible])],)
1337     CFLAGS="$gtk_save_cflags"
1338
1339     AC_SUBST(HAVE_HTTP_AUTHSTRING)
1340
1341     gtk_save_libs="$LIBS"
1342     LIBS="$CUPS_LIBS"
1343     AC_CHECK_FUNCS(httpGetAuthString)
1344     LIBS="$gtk_save_libs"
1345   fi
1346 fi
1347
1348 # Checks to see if we should compile with PAPI backend for GTK+
1349 #
1350
1351 AC_ARG_ENABLE(papi,
1352               [AC_HELP_STRING([--disable-papi],
1353                               [disable papi print backend])],,
1354              [enable_papi=auto])
1355
1356 if test "x$enable_papi" = "xno"; then
1357   AM_CONDITIONAL(HAVE_PAPI, false)
1358 else
1359   AC_MSG_CHECKING(libpapi)
1360   AC_CHECK_LIB(papi, papiServiceCreate, have_papi=yes, have_papi=no)
1361   if test $have_papi = yes; then
1362     AC_DEFINE([HAVE_PAPI], [], [Define to 1 if libpapi available])
1363   fi
1364   AM_CONDITIONAL(HAVE_PAPI, test $have_papi = yes)
1365   if test "x$enable_papi" = "xyes" -a "x$have_papi" = "xno"; then
1366     AC_MSG_ERROR([
1367 *** papi not found.
1368 ])
1369   fi
1370 fi
1371
1372 AM_CONDITIONAL(HAVE_PAPI_CUPS, test "x$have_papi" = "xyes" -a "x$CUPS_CONFIG" != "xno")
1373
1374 gtk_save_cppflags="$CPPFLAGS"
1375 CPPFLAGS="$CPPFLAGS $GTK_DEP_CFLAGS $GDK_DEP_CFLAGS"
1376
1377 AC_CHECK_HEADER(cairo-pdf.h,,AC_MSG_ERROR([
1378 *** Can't find cairo-pdf.h. You must build Cairo with the pdf
1379 *** backend enabled.]))
1380
1381 if test "$os_win32" != "yes"; then
1382   AC_CHECK_HEADER(cairo-ps.h,,AC_MSG_ERROR([
1383 *** Can't find cairo-ps.h. You must build Cairo with the
1384 *** postscript backend enabled.]))
1385
1386   AC_CHECK_HEADER(cairo-svg.h,,AC_MSG_ERROR([
1387 *** Cannot find cairo-svg.h. You must build Cairo with the
1388 *** svg backend enabled.]))
1389 fi
1390
1391 CPPFLAGS="$gtk_save_cppflags"
1392
1393
1394 AC_ARG_ENABLE(test-print-backend,
1395               [AC_HELP_STRING([--enable-test-print-backend],
1396                               [build test print backend])],,
1397               [enable_test_print_backend=no])
1398 AM_CONDITIONAL(TEST_PRINT_BACKEND, test "x$enable_test_print_backend" != "xno")
1399
1400
1401 ################################################################
1402 # Strip -export-dynamic from the link lines of various libraries
1403 ################################################################
1404
1405 #
1406 # pkg-config --libs gmodule includes the "export_dynamic" flag,
1407 #  but this flag is only meaningful for executables. For libraries
1408 #  the effect is undefined; what it causes on Linux is that the
1409 #  export list from -export-symbols-regex is ignored and everything
1410 #  is exported
1411 #
1412 # We are using gmodule-no-export now, but I'm leaving the stripping
1413 # code in place for now, since pango and atk still require gmodule.
1414 export SED
1415 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1416 if test -n "$export_dynamic"; then
1417   GDK_DEP_LIBS=`echo $GDK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1418   GTK_DEP_LIBS=`echo $GTK_DEP_LIBS | sed -e "s/$export_dynamic//"`
1419 fi
1420
1421 #############
1422 # GSettings #
1423 #############
1424
1425 GLIB_GSETTINGS
1426
1427 ##################################################
1428 # GObject introspection
1429 ##################################################
1430
1431 GOBJECT_INTROSPECTION_CHECK([0.9.3])
1432
1433 ##################################################
1434 # Packagekit module
1435 #################################################
1436
1437 AC_ARG_ENABLE(packagekit,
1438               AC_HELP_STRING([--disable-packagekit],
1439                              [build packagekit open-with module]))
1440
1441 ENABLE_PACKAGEKIT=
1442 if test "os_win32" != "yes"; then
1443         if test "x$enable_packagekit" != "xno"; then
1444                 ENABLE_PACKAGEKIT=1
1445                 AC_DEFINE(ENABLE_PACKAGEKIT, 1, [define to enable packagekit])
1446         fi
1447 fi
1448
1449 AC_SUBST(ENABLE_PACKAGEKIT)
1450 AM_CONDITIONAL(ENABLE_PACKAGEKIT, test "x$ENABLE_PACKAGEKIT" = "x1")
1451
1452 ##################################################
1453 # Checks for gtk-doc and docbook-tools
1454 ##################################################
1455
1456 GTK_DOC_CHECK([1.11])
1457
1458 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1459 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1460
1461 AC_ARG_ENABLE(man,
1462               [AC_HELP_STRING([--enable-man],
1463                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1464               enable_man=no)
1465
1466 if test "${enable_man}" != no; then
1467   dnl
1468   dnl Check for xsltproc
1469   dnl
1470   AC_PATH_PROG([XSLTPROC], [xsltproc])
1471   if test -z "$XSLTPROC"; then
1472     enable_man=no
1473   fi
1474
1475   dnl check for DocBook DTD and stylesheets in the local catalog.
1476   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1477      [DocBook XML DTD V4.1.2],,enable_man=no)
1478   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1479      [DocBook XSL Stylesheets],,enable_man=no)
1480 fi
1481
1482 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1483
1484
1485 ##################################################
1486 # Output commands
1487 ##################################################
1488
1489 AC_CONFIG_COMMANDS([gdk/gdkconfig.h], [
1490         outfile=gdkconfig.h-tmp
1491         cat > $outfile <<\_______EOF
1492 /* gdkconfig.h
1493  *
1494  * This is a generated file.  Please modify `configure.ac'
1495  */
1496
1497 #ifndef __GDKCONFIG_H__
1498 #define __GDKCONFIG_H__
1499
1500 #if !defined (__GDK_H_INSIDE__) && !defined (GDK_COMPILATION)
1501 #error "Only <gdk/gdk.h> can be included directly."
1502 #endif
1503
1504 #include <glib.h>
1505
1506 G_BEGIN_DECLS
1507
1508 #ifndef GSEAL
1509 /* introduce GSEAL() here for all of Gdk and Gtk+ without the need to modify GLib */
1510 #  ifdef GSEAL_ENABLE
1511 #    define GSEAL(ident)      _g_sealed__ ## ident
1512 #  else
1513 #    define GSEAL(ident)      ident
1514 #  endif
1515 #endif /* !GSEAL */
1516
1517 _______EOF
1518
1519         cat >>$outfile <<_______EOF
1520 $gdk_windowing
1521 _______EOF
1522
1523         cat >>$outfile <<_______EOF
1524
1525 G_END_DECLS
1526
1527 #endif  /* __GDKCONFIG_H__ */
1528 _______EOF
1529
1530
1531         if cmp -s $outfile gdk/gdkconfig.h; then
1532           AC_MSG_NOTICE([gdk/gdkconfig.h is unchanged])
1533           rm -f $outfile
1534         else
1535           mv $outfile gdk/gdkconfig.h
1536         fi
1537 ],[
1538 gdk_windowing='$GDK_WINDOWING'
1539 ])
1540
1541 dnl
1542 dnl Check for -Bsymbolic-functions linker flag used to avoid
1543 dnl intra-library PLT jumps, if available.
1544 dnl
1545 AC_ARG_ENABLE(Bsymbolic,
1546               [AC_HELP_STRING([--disable-Bsymbolic],
1547                               [avoid linking with -Bsymbolic])],,
1548               [SAVED_LDFLAGS="${LDFLAGS}"
1549                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
1550                LDFLAGS=-Wl,-Bsymbolic-functions
1551                AC_TRY_LINK([], [int main (void) { return 0; }],
1552                            AC_MSG_RESULT(yes)
1553                            enable_Bsymbolic=yes,
1554                            AC_MSG_RESULT(no)
1555                            enable_Bsymbolic=no)
1556                LDFLAGS="${SAVED_LDFLAGS}"])
1557
1558 if test "x${enable_Bsymbolic}" = "xyes" ; then
1559   GTK_LINK_FLAGS=-Wl,-Bsymbolic-functions
1560 fi
1561 AC_SUBST(GTK_LINK_FLAGS)
1562
1563 AC_CONFIG_FILES([
1564 config.h.win32
1565 gtk-zip.sh
1566 Makefile
1567 gdk-3.0.pc
1568 gtk+-3.0.pc
1569 gtk+-unix-print-3.0.pc
1570 gail-3.0.pc
1571 gtk+-3.0-uninstalled.pc
1572 gail-3.0-uninstalled.pc
1573 m4macros/Makefile
1574 po/Makefile.in
1575 po-properties/Makefile.in
1576 demos/Makefile
1577 demos/gtk-demo/Makefile
1578 demos/gtk-demo/geninclude.pl
1579 examples/Makefile
1580 tests/Makefile
1581 docs/Makefile
1582 docs/reference/Makefile
1583 docs/reference/gdk/Makefile
1584 docs/reference/gdk/version.xml
1585 docs/reference/gtk/Makefile
1586 docs/reference/gtk/version.xml
1587 docs/reference/libgail-util/Makefile
1588 docs/tools/Makefile
1589 build/Makefile
1590 build/win32/Makefile
1591 build/win32/vs9/Makefile
1592 gdk/Makefile
1593 gdk/x11/Makefile
1594 gdk/win32/Makefile
1595 gdk/win32/rc/Makefile
1596 gdk/win32/rc/gdk.rc
1597 gdk/quartz/Makefile
1598 gdk/tests/Makefile
1599 gtk/Makefile
1600 gtk/makefile.msc
1601 gtk/gtkversion.h
1602 gtk/gtk-win32.rc
1603 gtk/theme-bits/Makefile
1604 gtk/tests/Makefile
1605 modules/Makefile
1606 modules/other/Makefile
1607 modules/other/gail/Makefile
1608 modules/other/gail/libgail-util/Makefile
1609 modules/other/gail/tests/Makefile
1610 modules/engines/Makefile
1611 modules/engines/pixbuf/Makefile
1612 modules/engines/ms-windows/Makefile
1613 modules/engines/ms-windows/Theme/Makefile
1614 modules/engines/ms-windows/Theme/gtk-3.0/Makefile
1615 modules/input/Makefile
1616 modules/printbackends/Makefile
1617 modules/printbackends/cups/Makefile
1618 modules/printbackends/lpr/Makefile
1619 modules/printbackends/file/Makefile
1620 modules/printbackends/papi/Makefile
1621 modules/printbackends/test/Makefile
1622 perf/Makefile
1623 ])
1624
1625 AC_OUTPUT
1626
1627 echo "configuration:
1628         backends:             $GDK_BACKENDS"