Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 #
   3 # Fetchmail automatic configuration support
   4 #
   5 # Eric S. Raymond <esr@thyrsus.com>
   6 # 2004 - 2010 Matthias Andree <matthias.andree@gmx.de>
   7 #
   8 dnl Process this file with autoconf to produce a configure script.
   9 dnl
  10
  11 dnl XXX - if bumping version here, check fetchmail.man, too!
  12 AC_INIT([fetchmail],[6.4.0-alpha1],[fetchmail-devel@lists.berlios.de])
  13 AC_CONFIG_SRCDIR([fetchmail.h])
  14 AC_CONFIG_HEADERS([config.h])
  15 AC_CONFIG_LIBOBJ_DIR([.])
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl keep this before stuff that runs the compiler!
  20 AC_USE_SYSTEM_EXTENSIONS
  21
  22 dnl automake options are in Makefile.am
  23 AC_PREREQ(2.64)
  24 dnl 2.60 required for AC_USE_SYSTEM_EXTENSIONS
  25 AM_INIT_AUTOMAKE
  26
  27 dnl python is optional
  28 #
  29 # you can pass PYTHON=: in environment or on the command line
  30 # to disable python detection and continue without building/installing
  31 # fetchmail.conf -- be sure to check README.packaging, too!
  32 #
  33 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  34 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  35
  36 AC_PROG_AWK
  37 AC_PROG_CC_C99
  38 AC_PROG_INSTALL
  39 AM_PROG_LEX
  40 AC_PROG_MAKE_SET
  41 AC_PROG_RANLIB
  42 AC_PROG_YACC
  43
  44 dnl check for b0rked Solaris (and other shells) and find one that works
  45 AC_MSG_CHECKING(for a working shell...)
  46 for i in /usr/xpg6/bin/sh /usr/xpg4/bin/sh /usr/ccs/bin/sh /bin/sh /usr/bin/sh /bin/ksh /bin/bash /usr/local/bin/bash ; do
  47     $i -c 'if ! false ; then echo $(echo ok) ; fi' >config.$$ 2>/dev/null
  48     j=`cat config.$$`
  49     rm -f config.$$
  50     if test "x$j" = "xok" ; then
  51         SHELL=$i
  52         AC_SUBST(SHELL)
  53         break
  54     fi
  55 done
  56 AC_MSG_RESULT($SHELL)
  57 if test "x$SHELL" = "x" ; then
  58     AC_MSG_ERROR(no SUS compliant shell found - on Solaris, install SUNWxcu4)
  59 fi
  60
  61
  62 AC_CHECK_HEADERS([arpa/nameser.h md5.h])
  63
  64 AC_CHECK_HEADERS([resolv.h],,,[
  65 #include <sys/types.h>
  66 #include <netinet/in.h>
  67 #ifdef HAVE_ARPA_NAMESER_H
  68 #include <arpa/nameser.h>
  69 #endif
  70 ])
  71
  72 AC_CHECK_DECLS([h_errno],,,[
  73         AC_INCLUDES_DEFAULT
  74         #include <netdb.h>
  75 ])
  76
  77 # Check for OS special cases
  78 case $host_os in
  79 darwin*)
  80     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
  81     CPPFLAGS="$CPPFLAGS -DBIND_8_COMPAT"
  82     ;;
  83 # Check for FreeBSD special case: more libs needed
  84 freebsd*)
  85     AC_MSG_NOTICE(found FreeBSD - Adding -lkvm -lcom_err to standard libraries)
  86     LIBS="$LIBS -lkvm -lcom_err"
  87     ;;
  88 esac
  89
  90 AC_CACHE_SAVE
  91
  92 dnl i18n
  93 AM_GNU_GETTEXT([external], [need-ngettext])
  94 AM_GNU_GETTEXT_VERSION([0.17])
  95 dnl end i18n
  96
  97 # Under sysV68, socket and friends are provided by the C library.
  98 # -linet does not provide socket, but causes multiple definition
  99 # errors at link-time.  It is thus better to only use the C library.
 100 # So don't add -linet to the link list unless it's necessary
 101 AC_CHECK_FUNC(socket,
 102     AC_MSG_RESULT(using libc's socket),
 103     AC_CHECK_LIB(socket,socket)
 104     AC_CHECK_LIB(inet,socket))
 105
 106 # The condition in this test copes with the presence of inet_addr in libc6.
 107 AC_CHECK_FUNC(inet_addr,
 108     AC_MSG_RESULT(using libc's inet_addr),
 109     AC_CHECK_LIB(nsl,inet_addr))
 110
 111 AC_REPLACE_FUNCS([stpcpy strlcpy strlcat])
 112
 113 have_md5=no
 114 if test "$ac_cv_header_md5_h" != no ; then
 115     AC_SEARCH_LIBS(MD5Init, [md], [have_md5=yes])
 116 fi
 117
 118 if test "$have_md5" != yes ; then
 119     AC_LIBSOURCE(md5c.c)
 120     EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"
 121 fi
 122
 123 AC_CHECK_FUNC(getopt_long, [],
 124               [AC_LIBSOURCES([getopt.c, getopt1.c])
 125                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 126
 127 AC_SUBST(EXTRAOBJ)
 128
 129 AC_CHECK_FUNCS(vsyslog inet_aton)
 130
 131 dnl INET6 is used by KAME/getnameinfo
 132 AC_CACHE_CHECK(for AF_INET6/PF_INET6,ac_cv_inet6,
 133 AC_COMPILE_IFELSE([
 134   AC_LANG_PROGRAM([[
 135     #include <sys/types.h>
 136     #include <sys/socket.h>
 137   ]],[[
 138     int foo = AF_INET6;
 139     int bar = PF_INET6;
 140   ]])],
 141   ac_cv_inet6=yes , ac_cv_inet6=no
 142 ))
 143 if test "x$ac_cv_inet6" = xyes
 144 then
 145     AC_DEFINE(INET6,1,Define to 1 if your system defines AF_INET6 and PF_INET6.)
 146 fi
 147
 148 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 149 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 150 # library.  So don't add -lresolv to the link list unless it's necessary
 151 # (It will be necessary when using GNU libc6).
 152 old_LIBS="$LIBS"
 153 for lib in '' -lresolv; do
 154     if test -z "$lib"; then
 155        AC_MSG_CHECKING([for res_search in libc])
 156     else
 157        AC_MSG_CHECKING([for res_search in $lib])
 158     fi
 159     LIBS="$old_LIBS $lib"
 160     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 161 #include <sys/types.h>
 162 #include <netinet/in.h>
 163 #ifdef HAVE_ARPA_NAMESER_H
 164 #include <arpa/nameser.h>
 165 #endif
 166 #ifdef HAVE_RESOLV_H
 167 #include <resolv.h>
 168 #endif
 169 extern int res_search();
 170 ]], [[res_search(0, 0, 0, 0, 0); dn_skipname(0,0);]])],
 171     [AC_MSG_RESULT([found])
 172      AC_DEFINE(HAVE_RES_SEARCH, [1],
 173                [Define to 1 if you have the 'res_search' and 'dn_skipname' functions.])
 174      break], [AC_MSG_RESULT([not found])])
 175      LIBS=$old_LIBS
 176 done
 177
 178 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 179 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 180
 181 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 182 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 183 /* NetBSD declares sys_siglist in <unistd.h>.  */
 184 #include <unistd.h>
 185 ]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 186
 187 AC_DEFINE_UNQUOTED(PID_DIR, "/var/run", directory for PID lock files)
 188
 189 # We may have a fallback MDA available in case the socket open to the
 190 # local SMTP listener fails.  Best to use procmail for this, as we know
 191 # it won't try delivering through local SMTP and cause a mail loop.
 192 # Sendmail without the -t option to use the message headers will work too,
 193 # not just for sendmail itself but for workalikes like exim.
 194 #
 195 # Note1: A disadvantage of using procmail is that local alias expansion
 196 # according to /etc/aliases won't get done if we fall back.  This doesn't
 197 # matter in single-drop mode.
 198 #
 199 # Note2: it would be a very bad idea to use any MDA that doesn't return
 200 # a refuse-to-deliver status on disk- or process-table-full
 201 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 202 # like exim that might be lurking under a sendmail alias) do the right
 203 # thing in this circumstance.  Matthias Andree warns that procmail does
 204 # not.
 205 #
 206 # Note3: Defalt value of fallback is now off.  Matthias writes:
 207 #
 208 # 1. there is no way to predict when the fallback is used. With some MTAs
 209 #    (such as those limiting load average), outer circumstances can cause
 210 #    the fallback to kick in.
 211 #
 212 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 213 #    not only about alias expansion, .forwards to special filters won't
 214 #    work, mail may end up in a different place (users claim "mail loss"
 215 #    for that).
 216 #
 217 # 3. The claim procmail did the right thing with its exit codes is plain
 218 #    wrong. I've seen procmail exit with code 1 when it should have exited
 219 #    with code 75, like, configuration errors. Procmail is a dangerous
 220 #    beast and is best replaced by maildrop.
 221 #
 222 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 223 #    cannot tell which one it should choose. Say, your MTA is configured
 224 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 225 #    chooses procmail, this is plain wrong.
 226 #
 227
 228 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 229 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 230 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 231
 232 ###     use option --disable-fallback to disable fallback MDA
 233 ###     use option --enable-fallback=procmail or
 234 ###                --enable-fallback=sendmail to select
 235 AC_ARG_ENABLE(fallback,
 236         [  --enable-fallback=procmail    enable procmail as fallback
 237   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 238   --enable-fallback=maildrop    enable maildrop as fallback
 239   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 240
 241 case "$enable_fallback" in
 242         sendmail)       if test -z "$sendmail" ; then
 243                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 244                                 #not reached
 245                         fi
 246                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 247                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 248                         ;;
 249         procmail)       if test -z "$procmail" ; then
 250                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 251                                 #not reached
 252                         fi
 253                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 254                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 255                         ;;
 256         maildrop)       if test -z "$maildrop" ; then
 257                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 258                                 #not reached
 259                         fi
 260                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 261                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 262                         ;;
 263         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 264                         ;;
 265         auto|yes|set)   if test -n "$sendmail" ; then
 266                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 267                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 268                         else
 269                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 270                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 271                         fi
 272                         ;;
 273         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 274                         #notreached
 275                         ;;
 276 esac
 277
 278 ###     use option --disable-POP3 to omit the POP3 support
 279 AC_ARG_ENABLE(POP3,
 280         [  --disable-POP3          don't compile in POP3 protocol support],
 281         [with_POP3=$enableval],
 282         [with_POP3=yes])
 283 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 284 AM_CONDITIONAL(POP3_ENABLE, test "$with_POP3" = yes)
 285
 286 ###     use option --disable-IMAP to omit the IMAP support
 287 AC_ARG_ENABLE(IMAP,
 288         [  --disable-IMAP          don't compile in IMAP protocol support],
 289         [with_IMAP=$enableval],
 290         [with_IMAP=yes])
 291 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,Define if you want IMAP support compiled in)
 292 AM_CONDITIONAL(IMAP_ENABLE, test "$with_IMAP" = yes)
 293
 294 ###     use option --disable-ETRN to omit the ETRN support
 295 AC_ARG_ENABLE(ETRN,
 296         [  --disable-ETRN          don't compile in ETRN protocol support],
 297         [with_ETRN=$enableval],
 298         [with_ETRN=yes])
 299 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 300 AM_CONDITIONAL(ETRN_ENABLE, test "$with_ETRN" = yes)
 301
 302 ###     use option --disable-ODMR to omit the ODMR support
 303 AC_ARG_ENABLE(ODMR,
 304         [  --disable-ODMR          don't compile in ODMR protocol support],
 305         [with_ODMR=$enableval],
 306         [with_ODMR=yes])
 307 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 308 AM_CONDITIONAL(ODMR_ENABLE, test "$with_ODMR" = yes)
 309
 310 ###     use option --enable-RPA to compile in the RPA support
 311 AC_ARG_ENABLE(RPA,
 312         [  --enable-RPA            compile in RPA protocol support],
 313         [with_RPA=$enableval],
 314         [with_RPA=no])
 315 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 316 AM_CONDITIONAL(RPA_ENABLE, test "$with_RPA" = yes)
 317
 318 ###     use option --enable-NTLM to compile in the NTLM support
 319 AC_ARG_ENABLE(NTLM,
 320         [  --enable-NTLM           compile in NTLM authentication support],
 321         [with_NTLM=$enableval],
 322         [with_NTLM=no])
 323 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 324 AM_CONDITIONAL(NTLM_ENABLE, test "$with_NTLM" = yes)
 325
 326 ###     use option --enable-SDPS to compile in the SDPS support
 327 AC_ARG_ENABLE(SDPS,
 328         [  --enable-SDPS           compile in SDPS protocol support],
 329         [with_SDPS=$enableval],
 330         [with_SDPS=no])
 331 if test "$with_SDPS" = yes ; then
 332    if test "$with_POP3" != yes ; then
 333        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 334        with_SDPS=no
 335    else
 336        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 337    fi
 338 fi
 339 if test "$with_POP3" != yes && test "$with_IMAP"  != yes ; then
 340     AC_MSG_ERROR([You must enable at least one of POP3 and IMAP.])
 341 fi
 342
 343 AC_CACHE_SAVE
 344
 345 ###     use option --enable-opie to compile in the OPIE support
 346 AC_ARG_ENABLE(opie,
 347         [  --enable-opie           support OTP through the OPIE library],
 348         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR(cannot find <opie.h>, which is required for OPIE support.)])
 349           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR(cannot find libopie, which is required for OPIE support.)])
 350           with_opie=$enableval],
 351         [with_opie=no])
 352 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 353
 354 dnl Mostly stolen from gnulib's getaddrinfo.m4
 355 AC_SEARCH_LIBS(getaddrinfo, [nsl socket])
 356 AC_CACHE_CHECK([for getaddrinfo],[fm_cv_getaddrinfo],[
 357   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 358 #include <sys/types.h>
 359 #include <sys/socket.h>
 360 #include <netdb.h>
 361   ]], [[getaddrinfo(0, 0, 0, 0);]])],[ fm_cv_getaddrinfo=yes],[ fm_cv_getaddrinfo=no ])
 362 ])
 363
 364 if test x"$fm_cv_getaddrinfo" = "xyes"; then
 365      AC_DEFINE(HAVE_GETADDRINFO, 1,
 366       [Define to 1 if you have the getaddrinfo function.])
 367 fi
 368
 369 AC_CACHE_CHECK([for getnameinfo],[fm_cv_getnameinfo],[
 370   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 371 #include <sys/types.h>
 372 #include <sys/socket.h>
 373 #include <netdb.h>
 374 #ifndef NULL
 375 #define NULL 0
 376 #endif
 377   ]], [[getnameinfo(NULL,0, NULL,0, NULL, 0, 0);]])],[ fm_cv_getnameinfo=yes],[ fm_cv_getnameinfo=no ])
 378 ])
 379 if test $fm_cv_getnameinfo = yes ; then
 380     AC_DEFINE(HAVE_GETNAMEINFO,1,[Define to 1 if your system has getnameinfo()])
 381 fi
 382
 383 AM_CONDITIONAL(NEED_GETADDRINFO, test "$fm_cv_getaddrinfo" != yes)
 384 AM_CONDITIONAL(NEED_GETNAMEINFO, test "$fm_cv_getnameinfo"   != yes)
 385
 386 AC_CHECK_FUNCS(inet_ntop)
 387 dnl Check if getaddrinfo is async-signal-safe - most implementations aren't
 388 if test "$fm_cv_getaddrinfo" = yes ; then
 389     AC_MSG_CHECKING(if your getaddrinfo is async-signal-safe)
 390     gai_ts=no
 391     dnl we have getaddrinfo() - check if the OS is known to have a async-signal-safe implementation
 392     case $host_os in
 393         darwin9*)                               gai_ts=yes ;;
 394         linux*)                                 gai_ts=yes ;;
 395         freebsd5.5|freebsd6*|freebsd7*)         gai_ts=yes ;;
 396         solaris2.8|solaris2.9|solaris2.10)      gai_ts=yes ;;
 397     esac
 398     AC_MSG_RESULT($gai_ts)
 399     if test $gai_ts = yes ; then
 400         AC_DEFINE(GETADDRINFO_ASYNCSAFE, 1, [define to 1 if you know your getaddrinfo function is async-signal-safe])
 401     fi
 402 fi
 403
 404 # This version of the Kerberos 5 options addresses the follwing issues:
 405 #
 406 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 407 #   OpenSSL support (Debian's is)
 408
 409 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 410 ### make sure --with-ssl is run before --with-kerberos* !
 411 AC_ARG_WITH(kerberos5,
 412        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 413 [
 414 if test "$with_kerberos5" != "no"
 415 then
 416 # Check for a OpenBSD special case
 417 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 418 then
 419   AS_MESSAGE(checking kerberosV for OpenBSD...)
 420   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 421   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 422   CFLAGS="$CFLAGS -I/usr/include/kerberosV"
 423   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 424 elif krb5-config 2> /dev/null >/dev/null ; then
 425   krb5_prefix=`krb5-config --prefix krb5`
 426   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 427   if test -f ${krb5_prefix}/include/et/com_err.h && \
 428    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 429     CFLAGS="$CFLAGS -I${krb5_prefix}/include/et"
 430   fi
 431   unset krb5_prefix
 432   CFLAGS="$CFLAGS `krb5-config --cflags krb5`"
 433   LIBS="$LIBS `krb5-config --libs krb5`"
 434   AC_DEFINE(KERBEROS_V5)
 435 else
 436   if test "$with_kerberos5" != "yes"
 437   then
 438       LDFLAGS="$LDFLAGS -L${with_kerberos5}/lib"
 439       searchdirs="$with_kerberos5"
 440   else
 441       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 442   fi
 443   with_kerberos5=
 444   for dir in $searchdirs
 445   do AC_MSG_CHECKING([for Kerberos V in $dir])
 446      if test -f "$dir/include/krb5.h" || test -f "$dir/include/krb5/krb5.h"
 447      then
 448         if test -d "$dir/include/krb5" ; then CPPFLAGS="$CPPFLAGS -I$dir/include/krb5" ; fi
 449         ac_krblibs=
 450         if test -f "$dir/include/roken.h" || test -f "$dir/include/krb5/roken.h"
 451         then
 452            ac_krblibs="-lasn1 -lroken -lcom_err"
 453            AC_MSG_RESULT([Heimdal found])
 454           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 455           dnl we assume we do if it is available
 456            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 457                 ${LDFLAGS})
 458            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 459               AC_CHECK_LIB(crypto, MD5_Init, [],
 460                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 461                 ${LDFLAGS} ${ac_krblibs}),
 462            ${LDFLAGS} ${ac_krblibs})
 463            AC_DEFINE(HEIMDAL)
 464         else
 465           AC_MSG_RESULT([found])
 466           ac_krblibs="-lcom_err"
 467            AC_CHECK_LIB(crypto,
 468              krb5_des_string_to_key,
 469              libk5crypto=-lcrypto,
 470                 AC_CHECK_LIB(k5crypto,
 471                    krb5_des_string_to_key,
 472                    libk5crypto=-lk5crypto,
 473                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 474                    ${LDFLAGS} ${ac_krblibs}),
 475                  ${LDFLAGS} ${ac_krblibs})
 476         fi
 477         AC_CHECK_LIB(krb5, krb5_init_context,[],
 478            continue,
 479            ${LDFLAGS} ${ac_krblibs})
 480         AC_DEFINE(KERBEROS_V5)
 481         test "$dir" != "/usr" && CFLAGS="$CFLAGS -I$dir/include"
 482         LDFLAGS="$LDFLAGS -L$dir/lib"
 483        LIBS="$LIBS $ac_krblibs $libk5crypto"
 484         with_kerberos5=$dir
 485         break
 486      else
 487         AC_MSG_RESULT([not found])
 488      fi
 489   done
 490   if test -z "$with_kerberos5" ; then
 491      AC_MSG_ERROR([Kerberos 5 libraries not found])
 492   fi
 493 fi
 494 fi
 495 ]) dnl --with-kerberos5=DIR
 496
 497 ###     use option --with-ssl to compile in the SSL support
 498 AC_ARG_WITH(ssl,
 499         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 500         [with_ssl=$withval],
 501         [with_ssl=no])
 502 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 503
 504 if test "$with_ssl" = "yes"
 505 then
 506     #   User didn't specify an SSL location.  Let's look at some common
 507     #   directories where SSL has been found in the past and try and auto
 508     #   configure for SSL.  OpenSSL determination will be made later.
 509     #   This will screw up if an OpenSSL install is located in a later
 510     #   directory than an older SSLeay install, but the user should fix that
 511     #   anyways and he can override on the configure line.
 512     #   Just testing for directories is not sufficient, /usr exists on
 513     #   all systems!
 514     for ac_dir in \
 515       /usr/local/ssl \
 516       /usr/local \
 517       /usr/ssl \
 518       /usr \
 519       /local/ssl \
 520       /opt/ssl \
 521       /opt/csw \
 522       ; \
 523     do
 524         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 525             with_ssl=$ac_dir
 526             break;
 527         fi
 528     done
 529 fi
 530
 531 if test -n "$with_ssl" -a "$with_ssl" != "no"
 532 then
 533   # With the autoconfigure above, the only time this is going to be
 534   # true is going to be when we could not find the headers.  If they
 535   # are not in system standard locations, we are going to be broken.
 536   if test "$with_ssl" = "yes"
 537   then
 538     # Let's just define the standard location for the SSLeay root
 539     with_ssl="/usr/local/ssl"
 540   fi
 541   if test -r $with_ssl/include/openssl/ssl.h
 542   then
 543     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 544     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 545     test "$with_ssl" != "/usr" && CFLAGS="$CFLAGS -I$with_ssl/include"
 546     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 547     ### force the Kerberos direcory onto the include path so it will build.
 548     CFLAGS="$CFLAGS -I/usr/kerberos/include"
 549     ### OpenBSD comes with ssl headers
 550   else
 551     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 552   fi
 553   LDFLAGS="$LDFLAGS -L$with_ssl/lib"
 554   LIBS="$LIBS -lssl -lcrypto"
 555   dnl check if -ldl is needed
 556   AC_MSG_CHECKING([for additional library dependencies of SSL])
 557   found=0
 558   save_LIBS="$LIBS"
 559   for i in "" "-ldl" ; do
 560       LIBS="$LDFLAGS $save_LIBS $i"
 561       AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <openssl/ssl.h>],[SSL_library_init()])],[found=1; break])
 562   done
 563   if test $found = 0 ; then
 564       AC_MSG_RESULT([error])
 565       AC_MSG_ERROR([cannot link with SSL - check config.log])
 566   fi
 567   LIBS="$save_LIBS $i"
 568   if test "$i" = "" ; then i="(none)" ; fi
 569   AC_MSG_RESULT($i)
 570   dnl XXX FIXME: use pkg-config if available!
 571   AC_DEFINE(SSL_ENABLE)
 572 else
 573   AC_MSG_NOTICE(Disabling SSL support.)
 574 fi
 575
 576 ###     use option --with-socks=DIR to point at SOCKS library
 577 AC_ARG_WITH(socks,
 578         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 579 [
 580 if test "$with_socks" != no
 581 then
 582     if test "$with_socks" != yes
 583     then
 584         LDFLAGS="$LDFLAGS -L$with_socks"
 585     else
 586         AC_CHECK_LIB(socks, Rconnect,,
 587                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 588     fi
 589     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 590     CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 591     LIBS="-lsocks $LIBS"
 592 fi])
 593
 594 ###     use option --with-socks5=DIR to point at SOCKS library
 595 AC_ARG_WITH(socks5,
 596         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 597 [
 598 if test "$with_socks5" != no
 599 then
 600   if test "$with_socks5" != yes
 601   then
 602     LDFLAGS="$LDFLAGS -L$with_socks5"
 603   fi
 604   ac_savedLDFLAGS="$LDFLAGS"
 605   LDFLAGS="$LDFLAGS $LDFLAGS"
 606   AC_CHECK_LIB(socks5, SOCKSconnect,,
 607         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 608   AC_DEFINE(HAVE_SOCKS)
 609   CFLAGS="$CFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 610   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 611   LDFLAGS="$ac_savedLDFLAGS"
 612 fi])
 613
 614 dnl for libesmtp/ modules:
 615 ACX_WHICH_GETHOSTBYNAME_R
 616
 617 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 618 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 619
 620 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 621 AC_ARG_WITH(gssapi,
 622         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 623 [
 624 if test "$with_gssapi" != "no"
 625 then
 626   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 627   then
 628     with_gssapi=$with_kerberos5
 629   fi
 630
 631   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 632   then
 633     CFLAGS="$CFLAGS -I$with_gssapi/include"
 634     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 635   fi
 636
 637   dnl obtain gssapi default libs
 638   if krb5-config --libs gssapi 2>/dev/null >/dev/null ; then
 639       LIBS="$LIBS `krb5-config --libs gssapi`"
 640   else
 641     AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 642     if test -n "$nogss"
 643     then
 644       # -lgss not found
 645       if test "$with_gssapi" = yes ; then
 646           with_gssapi=/usr
 647       fi
 648       if test -f "$with_gssapi/include/roken.h" -o -f "$with_gssapi/include/krb5/roken.h"
 649       then
 650          # have roken.h, assume Heimdal
 651          case `uname` in
 652              NetBSD) LIBS="$LIBS -lkrb5" ;;
 653              *)      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl" ;;
 654          esac
 655          AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 656                       AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 657          AC_DEFINE(HEIMDAL)
 658       else
 659          # no roken.h, assume MIT
 660          AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 661                       AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 662       fi
 663     fi
 664   fi
 665   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 666   if test "$with_gssapi" != yes ; then
 667     CPPFLAGS="$CPPFLAGS -I$with_gssapi/include"
 668   fi
 669   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 670   if test "$ac_cv_header_gssapi_h" = "yes"; then
 671     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 672   else
 673     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 674   fi
 675 fi])
 676
 677 AC_CONFIG_FILES([Makefile po/Makefile.in genlsm.sh])
 678 AC_OUTPUT
 679
 680 dnl Local Variables:
 681 dnl comment-start: "dnl "
 682 dnl comment-end: ""
 683 dnl comment-start-skip: "\\bdnl\\b\\s *"
 684 dnl compile-command: "make configure config.h.in"
 685 dnl End: