Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 dnl Eric S. Raymond <esr@thyrsus.com>
   3 dnl Matthias Andree <matthias.andree@gmx.de>
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6 dnl
   7
   8 AC_INIT([fetchmail],[6.3.4.pre1],[fetchmail-users@lists.berlios.de])
   9 AC_CONFIG_SRCDIR([fetchmail.h])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_LIBOBJ_DIR([.])
  12
  13 AC_CANONICAL_TARGET
  14
  15 dnl automake options are in Makefile.am
  16 AC_PREREQ(2.59)
  17 AM_INIT_AUTOMAKE
  18
  19 dnl autobuild support, see <http://josefsson.org/autobuild/>
  20 (
  21   TZ=
  22   export TZ
  23   AB_INIT
  24 )
  25
  26 dnl python is optional
  27 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  28 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  29
  30 AC_PROG_AWK
  31 AC_PROG_CC
  32 AC_PROG_INSTALL
  33 AC_PROG_CPP                     dnl Later checks need this.
  34 AC_PROG_RANLIB
  35 AM_PROG_CC_C_O
  36 AC_AIX
  37 AC_ISC_POSIX
  38 AC_MINIX
  39 AC_HEADER_STDC
  40 AC_HEADER_TIME
  41 AC_TYPE_SIZE_T
  42 AC_TYPE_PID_T
  43 AC_TYPE_SIGNAL
  44 AC_CHECK_TYPE(u_int32_t,unsigned int)
  45 AC_CHECK_HEADERS([unistd.h termios.h termio.h sgtty.h stdarg.h \
  46         sys/itimer.h fcntl.h sys/fcntl.h memory.h sys/wait.h \
  47         arpa/inet.h arpa/nameser.h netinet/in.h net/socket.h \
  48         sys/select.h sys/socket.h sys/time.h langinfo.h])
  49 AC_CHECK_HEADERS([resolv.h],,,[
  50 #include <sys/types.h>
  51 #ifdef HAVE_NETINET_IN_H
  52 #include <netinet/in.h>
  53 #endif
  54 #ifdef HAVE_ARPA_NAMESER_H
  55 #include <arpa/nameser.h>
  56 #endif
  57 ])
  58
  59 AC_C_CONST                      dnl getopt needs this.
  60
  61 AM_PROG_LEX
  62 AC_PROG_MAKE_SET
  63 AC_PROG_YACC
  64
  65 # Check for OS special cases
  66 case $target_os in
  67 darwin*)
  68     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
  69     CPFLAGS="-DBIND_8_COMPAT"
  70     ;;
  71 # Check for FreeBSD special case: more libs needed
  72 freebsd*)
  73     AC_MSG_NOTICE(found FreeBSD - Adding -lmd -lkvm -lcom_err to standard libraries)
  74     LIBS="$LIBS -lmd -lkvm -lcom_err"
  75     ;;
  76 # Check for LynxOS special case: -lbsd needed (at least on 2.3.0) and -s
  77 # not working.
  78 lynxos*)
  79     AC_MSG_NOTICE(found LynxOS - Adding -lbsd to standard libraries)
  80     LIBS="$LIBS -lbsd"
  81     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
  82     AC_MSG_NOTICE(found LynxOS - Prepending standard include path to gcc flags)
  83     CPFLAGS="-I/usr/include"
  84     ;;
  85 # Check for Rhapsody special case: it doesn't like -s
  86 rhapsody*)
  87     AC_MSG_NOTICE(found Rhapsody - Removing -s load flag)
  88     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
  89     ;;
  90 esac
  91
  92 dnl i18n
  93 AM_GNU_GETTEXT([external], [need-ngettext])
  94 AM_GNU_GETTEXT_VERSION(0.14.3)
  95 dnl end i18n
  96
  97 # Under sysV68, socket and friends are provided by the C library.
  98 # -linet does not provide socket, but causes multiple definition
  99 # errors at link-time.  It is thus better to only use the C library.
 100 # So don't add -linet to the link list unless it's necessary
 101 AC_CHECK_FUNC(socket,
 102     AC_MSG_RESULT(using libc's socket),
 103     AC_CHECK_LIB(socket,socket)
 104     AC_CHECK_LIB(inet,socket))
 105
 106 # The condition in this test copes with the presence of inet_addr in libc6.
 107 AC_CHECK_FUNC(inet_addr,
 108     AC_MSG_RESULT(using libc's inet_addr),
 109     AC_CHECK_LIB(nsl,inet_addr))
 110
 111 dnl Port hack for Interactive UNIX System V/386 Release 3.2
 112 AC_CHECK_LIB(cposix, strchr,
 113                 [DEFS="$DEFS -D_SYSV3"
 114                 LIBS="$LIBS -lcposix"])
 115
 116 dnl Port hack for Sparc/NetBSD-1.5
 117 dnl
 118 dnl NB: this has been disabled as it causes the unconditional
 119 dnl addition of libintl to the build, which is both undesired
 120 dnl and breaks on Solaris/Blastwave.org machines.
 121 dnl
 122 dnl AC_CHECK_LIB(intl, gettext,
 123 dnl             [LIBS="$LIBS -lintl"])
 124
 125 AC_REPLACE_FUNCS([strstr strcasecmp memmove stpcpy strlcpy strlcat])
 126
 127 AC_CHECK_FUNC(MD5Init, [],
 128               [AC_LIBSOURCE(md5c.c)
 129                EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"])
 130
 131 AC_CHECK_FUNC(getopt_long, [],
 132               [AC_LIBSOURCES([getopt.c, getopt1.c])
 133                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 134
 135 AC_FUNC_VPRINTF
 136
 137 AC_SUBST(EXTRAOBJ)
 138
 139 AC_CHECK_FUNCS(tcsetattr stty setsid geteuid seteuid dnl
 140   strerror syslog snprintf vprintf vsnprintf vsyslog dnl
 141   atexit inet_aton strftime setrlimit socketpair sigprocmask dnl
 142   sigaction strdup setlocale)
 143
 144 AC_CHECK_DECLS(strerror)
 145
 146 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 147 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 148 # library.  So don't add -lresolv to the link list unless it's necessary
 149 # (It will be necessary when using GNU libc6).
 150 old_libs=$LIBS
 151 for lib in '' -lresolv; do
 152     if test -z "$lib"; then
 153        AC_MSG_CHECKING([for res_search in libc])
 154     else
 155        AC_MSG_CHECKING([for res_search in $lib])
 156     fi
 157     LIBS="$old_LIBS $lib"
 158     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 159 #include <sys/types.h>
 160 #ifdef HAVE_NETINET_IN_H
 161 #include <netinet/in.h>
 162 #endif
 163 #ifdef HAVE_ARPA_NAMESER_H
 164 #include <arpa/nameser.h>
 165 #endif
 166 #ifdef HAVE_RESOLV_H
 167 #include <resolv.h>
 168 #endif
 169 extern int res_search();
 170 ]], [[res_search(0, 0, 0, 0, 0);]])],
 171     [AC_MSG_RESULT([found])
 172      AC_DEFINE(HAVE_RES_SEARCH, [1],
 173                [Define to 1 if you have the `res_search' function.])
 174      break], [AC_MSG_RESULT([not found])])
 175 done
 176
 177 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 178 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 179
 180 dnl Check for RSA refersence library in case we're using SSL
 181 AC_CHECK_LIB(rsaref, RSAPublicDecrypt)
 182
 183 dnl AC_FUNC_SETVBUF_REVERSED
 184
 185 dnl Check for usable void pointer type
 186 AC_MSG_CHECKING(use of void pointer type)
 187 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[char *p;
 188     void *xmalloc();
 189     p = (char *) xmalloc(1);
 190    ]])],[AC_DEFINE(HAVE_VOIDPOINTER,1,[Define if your C compiler allows void * as a function result]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 191
 192 dnl Check for ANSI volatile
 193 AC_C_VOLATILE
 194
 195 dnl Check out the wait reality.  We have to assume sys/wait.h is present.
 196 AC_CHECK_FUNCS(waitpid wait3)
 197 AC_MSG_CHECKING(for union wait);
 198 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 199 #include <sys/wait.h>]], [[union wait status; int pid; pid = wait (&status);
 200 #ifdef WEXITSTATUS
 201 /* Some POSIXoid systems have both the new-style macros and the old
 202    union wait type, and they do not work together.  If union wait
 203    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 204 if (WEXITSTATUS (status) != 0) pid = -1;
 205 #endif
 206 #ifdef HAVE_WAITPID
 207 /* Make sure union wait works with waitpid.  */
 208 pid = waitpid (-1, &status, 0);
 209 #endif
 210 ]])],[AC_DEFINE(HAVE_UNION_WAIT,1,Define if 'union wait' is the type of the first arg to wait functions.) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 211
 212 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 213 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 214 /* NetBSD declares sys_siglist in <unistd.h>.  */
 215 #ifdef HAVE_UNISTD_H
 216 #include <unistd.h>
 217 #endif]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 218
 219 # Find the right directory to put the root-mode PID file in
 220 for dir in "/var/run" "/etc"
 221 do
 222         if test -d $dir
 223         then
 224                 break;
 225         fi
 226 done
 227 AC_MSG_RESULT(root-mode pid file will go in $dir)
 228 AC_DEFINE_UNQUOTED(PID_DIR, "$dir", directory for PID lock files)
 229
 230 # We may have a fallback MDA available in case the socket open to the
 231 # local SMTP listener fails.  Best to use procmail for this, as we know
 232 # it won't try delivering through local SMTP and cause a mail loop.
 233 # Sendmail without the -t option to use the message headers will work too,
 234 # not just for sendmail itself but for workalikes like exim.
 235 #
 236 # Note1: A disadvantage of using procmail is that local alias expansion
 237 # according to /etc/aliases won't get done if we fall back.  This doesn't
 238 # matter in single-drop mode.
 239 #
 240 # Note2: it would be a very bad idea to use any MDA that doesn't return
 241 # a refuse-to-deliver status on disk- or process-table-full
 242 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 243 # like exim that might be lurking under a sendmail alias) do the right
 244 # thing in this circumstance.  Matthias Andree warns that procmail does
 245 # not.
 246 #
 247 # Note3: Defalt value of fallback is now off.  Matthias writes:
 248 #
 249 # 1. there is no way to predict when the fallback is used. With some MTAs
 250 #    (such as those limiting load average), outer circumstances can cause
 251 #    the fallback to kick in.
 252 #
 253 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 254 #    not only about alias expansion, .forwards to special filters won't
 255 #    work, mail may end up in a different place (users claim "mail loss"
 256 #    for that).
 257 #
 258 # 3. The claim procmail did the right thing with its exit codes is plain
 259 #    wrong. I've seen procmail exit with code 1 when it should have exited
 260 #    with code 75, like, configuration errors. Procmail is a dangerous
 261 #    beast and is best replaced by maildrop.
 262 #
 263 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 264 #    cannot tell which one it should choose. Say, your MTA is configured
 265 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 266 #    chooses procmail, this is plain wrong.
 267 #
 268
 269 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 270 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 271 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 272
 273 ###     use option --disable-fallback to disable fallback MDA
 274 ###     use option --enable-fallback=procmail or
 275 ###                --enable-fallback=sendmail to select
 276 AC_ARG_ENABLE(fallback,
 277         [  --enable-fallback=procmail    enable procmail as fallback
 278   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 279   --enable-fallback=maildrop    enable maildrop as fallback
 280   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 281
 282 case "$enable_fallback" in
 283         sendmail)       if test -z "$sendmail" ; then
 284                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 285                                 #not reached
 286                         fi
 287                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 288                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 289                         ;;
 290         procmail)       if test -z "$procmail" ; then
 291                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 292                                 #not reached
 293                         fi
 294                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 295                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 296                         ;;
 297         maildrop)       if test -z "$maildrop" ; then
 298                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 299                                 #not reached
 300                         fi
 301                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 302                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 303                         ;;
 304         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 305                         ;;
 306         auto|yes|set)   if test -n "$sendmail" ; then
 307                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 308                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 309                         else
 310                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 311                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 312                         fi
 313                         ;;
 314         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 315                         #notreached
 316                         ;;
 317 esac
 318
 319 AC_CHECK_SIZEOF(short)
 320 AC_CHECK_SIZEOF(int)
 321 AC_CHECK_SIZEOF(long)
 322
 323 ###     use option --enable-POP2 to compile in the POP2 support
 324 AC_ARG_ENABLE(POP2,
 325         [  --enable-POP2           compile in POP2 protocol support (obsolete)],
 326         [with_POP2=$enableval],
 327         [with_POP2=no])
 328 test "$with_POP2" = "yes" && AC_DEFINE(POP2_ENABLE,1,Define if you want POP2 support compiled in)
 329
 330 ###     use option --disable-POP3 to omit the POP3 support
 331 AC_ARG_ENABLE(POP3,
 332         [  --disable-POP3          don't compile in POP3 protocol support],
 333         [with_POP3=$enableval],
 334         [with_POP3=yes])
 335 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 336
 337 ###     use option --disable-IMAP to omit the IMAP support
 338 AC_ARG_ENABLE(IMAP,
 339         [  --disable-IMAP          don't compile in IMAP protocol support],
 340         [with_IMAP=$enableval],
 341         [with_IMAP=yes])
 342 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,"Define if you want IMAP support compiled in")
 343
 344 ###     use option --disable-ETRN to omit the ETRN support
 345 AC_ARG_ENABLE(ETRN,
 346         [  --disable-ETRN          don't compile in ETRN protocol support],
 347         [with_ETRN=$enableval],
 348         [with_ETRN=yes])
 349 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 350
 351 ###     use option --disable-ODMR to omit the ODMR support
 352 AC_ARG_ENABLE(ODMR,
 353         [  --disable-ODMR          don't compile in ODMR protocol support],
 354         [with_ODMR=$enableval],
 355         [with_ODMR=yes])
 356 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 357
 358 ###     use option --enable-RPA to compile in the RPA support
 359 AC_ARG_ENABLE(RPA,
 360         [  --enable-RPA            compile in RPA protocol support],
 361         [with_RPA=$enableval],
 362         [with_RPA=no])
 363 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 364
 365 ###     use option --enable-NTLM to compile in the NTLM support
 366 AC_ARG_ENABLE(NTLM,
 367         [  --enable-NTLM           compile in NTLM authentication support],
 368         [with_NTLM=$enableval],
 369         [with_NTLM=no])
 370 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 371
 372 ###     use option --enable-SDPS to compile in the SDPS support
 373 AC_ARG_ENABLE(SDPS,
 374         [  --enable-SDPS           compile in SDPS protocol support],
 375         [with_SDPS=$enableval],
 376         [with_SDPS=no])
 377 if test "$with_SDPS" = yes ; then
 378    if test "$with_POP3" != yes ; then
 379        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 380        with_SDPS=no
 381    else
 382        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 383    fi
 384 fi
 385
 386 ###     use option --enable-opie to compile in the OPIE support
 387 AC_ARG_ENABLE(opie,
 388         [  --enable-opie           support OTP through the OPIE library],
 389         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR(cannot find <opie.h>, which is required for OPIE support.)])
 390           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR(cannot find libopie, which is required for OPIE support.)])
 391           with_opie=$enableval],
 392         [with_opie=no])
 393 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 394
 395 AC_SEARCH_LIBS(getaddrinfo, inet6, [AC_DEFINE(HAVE_GETADDRINFO,1,[define to 1 if you have the getaddrinfo function])])
 396 AC_CHECK_FUNCS(getnameinfo)
 397
 398 # This version of the Kerberos 4 and 5 options addresses the follwing issues:
 399 #
 400 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 401 #   OpenSSL support (Debian's is)
 402 # * Build the kerberos.c stuff (KPOP) only for kerberosIV, to avoid breakage.
 403 #   I don't know if this is 100% correct, but now at least IMAP and POP3
 404 #   behave the same way regarding kerberosV.
 405 # * Build without any fuss for both kerberosIV and V at the same time.
 406 # * Move all the kerberos header mess to kerberos.h, and #include that
 407 #   in driver.c and kerberos.c.
 408 #
 409 # Tested using the Heimdal Kerberos V libs, Kungliga Tekniska Högskolan (the
 410 # Royal Institute of Technology in Stockholm, Sweden)'s kerberos IV libs, and
 411 # the MIT reference implementation of KerberosV (all as packaged in Debian).
 412
 413 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 414 ### make sure --with-ssl is run before --with-kerberos* !
 415 AC_ARG_WITH(kerberos5,
 416        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 417 [
 418 if test "$with_kerberos5" != "no"
 419 then
 420 # Check for a OpenBSD special case
 421 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 422 then
 423   AS_MESSAGE(checking kerberosV for OpenBSD...)
 424   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 425   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 426   CEFLAGS="$CEFLAGS -I/usr/include/kerberosV"
 427   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 428 elif krb5-config 2> /dev/null >/dev/null ; then
 429   krb5_prefix=`krb5-config --prefix krb5`
 430   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 431   if test -f ${krb5_prefix}/include/et/com_err.h && \
 432    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 433     CEFLAGS="$CEFLAGS -I${krb5_prefix}/include/et"
 434   fi
 435   unset krb5_prefix
 436   CEFLAGS="$CEFLAGS `krb5-config --cflags krb5`"
 437   LIBS="$LIBS `krb5-config --libs krb5`"
 438   AC_DEFINE(KERBEROS_V5)
 439 else
 440   if test "$with_kerberos5" != "yes"
 441   then
 442       LDEFLAGS="$LDEFLAGS -L${with_kerberos5}/lib"
 443       searchdirs="$with_kerberos5"
 444   else
 445       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 446   fi
 447   with_kerberos5=
 448   for dir in $searchdirs
 449   do AC_MSG_CHECKING([for Kerberos V in $dir])
 450      if test -f "$dir/include/krb5.h"
 451      then
 452         ac_krblibs=
 453         if test -f "$dir/include/roken.h"
 454         then
 455            ac_krblibs="-lasn1 -lroken -lcom_err"
 456            AC_MSG_RESULT([Heimdal found])
 457           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 458           dnl we assume we do if it is available
 459            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 460                 ${LDEFLAGS})
 461            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 462               AC_CHECK_LIB(ssl, MD5_Init, [],
 463                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 464                 ${LDEFLAGS} ${ac_krblibs}),
 465            ${LDEFLAGS} ${ac_krblibs})
 466            AC_DEFINE(HEIMDAL)
 467         else
 468           AC_MSG_RESULT([found])
 469           ac_krblibs="-lcom_err"
 470            AC_CHECK_LIB(crypto,
 471              krb5_des_string_to_key,
 472              libk5crypto=-lcrypto,
 473                 AC_CHECK_LIB(k5crypto,
 474                    krb5_des_string_to_key,
 475                    libk5crypto=-lk5crypto,
 476                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 477                    ${LDEFLAGS} ${ac_krblibs}),
 478                  ${LDEFLAGS} ${ac_krblibs})
 479         fi
 480         AC_CHECK_LIB(krb5, krb5_init_context,[],
 481            continue,
 482            ${LDEFLAGS} ${ac_krblibs})
 483         AC_DEFINE(KERBEROS_V5)
 484         test "$dir" != "/usr" && CEFLAGS="$CEFLAGS -I$dir/include"
 485         LDEFLAGS="$LDEFLAGS -L$dir/lib"
 486        LIBS="$LIBS $ac_krblibs $libk5crypto"
 487         with_kerberos5=$dir
 488         break
 489      else
 490         AC_MSG_RESULT([not found])
 491      fi
 492   done
 493   if test -z "$with_kerberos5" ; then
 494      AC_MSG_ERROR([Kerberos 5 libraries not found])
 495   fi
 496 fi
 497 fi
 498 ]) dnl --with-kerberos5=DIR
 499
 500 ###    use option --with-kerberos=DIR to point at a Kerberos 4 directory
 501 AC_ARG_WITH(kerberos,
 502        [  --with-kerberos=DIR     point fetchmail compilation at a Kerberos 4 directory],
 503 [
 504 if test "$with_kerberos" != "no"
 505 then
 506 # Check for a NetBSD/OpenBSD special case
 507 if test "$with_kerberos" = "yes" && ( test `uname` = "NetBSD" || test `uname` = "OpenBSD" )
 508 then
 509   AS_MESSAGE(checking kerberosIV for `uname`...)
 510   AC_DEFINE(KERBEROS_V4,1,Define if you have Kerberos V4)
 511   CEFLAGS="$CEFLAGS -I/usr/include/kerberosIV"
 512   LIBS="$LIBS -lkrb -ldes"
 513 elif krb4-config 2> /dev/null >/dev/null ; then
 514   krb4_prefix=`krb4-config --prefix`
 515   AC_MSG_RESULT([krb4-config points to kerberosIV under $krb4_prefix])
 516   unset krb4_prefix
 517   CEFLAGS="$CEFLAGS `krb4-config --cflags`"
 518   LIBS="$LIBS `krb4-config --libs`"
 519   AC_DEFINE(KERBEROS_V4)
 520 elif krb5-config 2> /dev/null >/dev/null ; then
 521   krb4_prefix=`krb5-config --prefix krb4`
 522   AC_MSG_RESULT([krb5-config points to kerberosIV under $krb4_prefix])
 523   if test -f ${krb4_prefix}/include/kerberosIV/krb.h ; then
 524     AC_DEFINE(KERBEROS_V4_V5,1,Define if you have Kerberos V4 headers under a kerberosIV directory)
 525   fi
 526   unset krb4_prefix
 527   CEFLAGS="$CEFLAGS `krb5-config --cflags krb4`"
 528   LIBS="$LIBS `krb5-config --libs krb4`"
 529   AC_DEFINE(KERBEROS_V4)
 530 else
 531   #we need to detect when we're building under a kerberosV compatibility
 532   #layer, btw...
 533   if test "$with_kerberos" != "yes" ; then
 534      searchdirs="$with_kerberos"
 535   else
 536      searchdirs="$with_kerberos5 /usr/kerberos /usr/kerberosIV /usr/athena /usr"
 537   fi
 538   with_kerberos=
 539   ac_saveLDFLAGS="$LDFLAGS"
 540   for dir in $searchdirs
 541   do
 542      AC_MSG_CHECKING([for Kerberos IV in $dir])
 543      if test -f "$dir/include/krb.h" || test -f "$dir/include/krb4.h" \
 544             || test -f "$dir/include/kerberosIV/krb.h"
 545      then
 546         AC_MSG_RESULT([found])
 547      else
 548         AC_MSG_RESULT([not found])
 549        continue
 550      fi
 551      #Find libs
 552      if test -f "$with_kerberos5/roken.h" ; then
 553        AC_CHECK_LIB(45, krb_mk_req)
 554      fi
 555      LDFLAGS="-L$dir/lib $ac_saveLDFLAGS"
 556      if test `uname` = "FreeBSD"; then
 557         AC_SEARCH_LIBS(_ossl_old_des_string_to_key, [des425 des crypto], [], continue)
 558      else
 559         AC_SEARCH_LIBS(des_string_to_key, [crypto], [], continue)
 560      fi
 561      AC_SEARCH_LIBS(krb_realmofhost, [krb4 krb], [], continue)
 562      with_kerberos="$dir"
 563      if test -f "$dir/include/kerberosIV/krb.h" ; then
 564         dir="$dir/include/kerberosIV"
 565      else
 566        dir="$dir/include"
 567      fi
 568      AC_DEFINE(KERBEROS_V4)
 569      test -f "$with_kerberos5/roken.h" && AC_DEFINE(HEIMDAL)
 570      test "$dir" != "/usr/include" && CEFLAGS="$CEFLAGS -I$dir"
 571      LDEFLAGS="$LDEFLAGS -L$with_kerberos/lib"
 572      break
 573   done
 574   if test -z "$with_kerberos" ; then
 575      AC_MSG_ERROR([Kerberos 4 libraries not found])
 576   fi
 577   LDFLAGS="$ac_saveLDFLAGS"
 578 fi
 579 fi
 580 ]) dnl --with-kerberos=DIR
 581
 582 ###     use option --with-ssl to compile in the SSL support
 583 AC_ARG_WITH(ssl,
 584         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 585         [with_ssl=$withval],
 586         [with_ssl=no])
 587 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 588
 589 if test "$with_ssl" = "yes"
 590 then
 591     #   He didn't specify an SSL location.  Let's look at some common
 592     #   directories where SSL has been found in the past and try and auto
 593     #   configure for SSL.  OpenSSL determination will be made later.
 594     #   This will screw up if an OpenSSL install is located in a later
 595     #   directory than an older SSLeay install, but the user should fix that
 596     #   anyways and he can override on the configure line.
 597     #   Just testing for directories is not sufficient, /usr exists on
 598     #   all systems!
 599     for ac_dir in \
 600       /usr/local/ssl \
 601       /usr/local \
 602       /usr/ssl \
 603       /usr \
 604       /local/ssl \
 605       /opt/ssl \
 606       /opt/csw \
 607       ; \
 608     do
 609         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 610             with_ssl=$ac_dir
 611             break;
 612         fi
 613     done
 614 fi
 615
 616 if test -n "$with_ssl" -a "$with_ssl" != "no"
 617 then
 618   # With the autoconfigure above, the only time this is going to be
 619   # true is going to be when we could not find the headers.  If they
 620   # are not in system standard locations, we are going to be broken.
 621   if test "$with_ssl" = "yes"
 622   then
 623     # Let's just define the standard location for the SSLeay root
 624     with_ssl="/usr/local/ssl"
 625   fi
 626   if test -r $with_ssl/include/openssl/ssl.h
 627   then
 628     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 629     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 630     test "$with_ssl" != "/usr" && CEFLAGS="$CEFLAGS -I$with_ssl/include"
 631     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 632     ### force the Kerberos direcory onto the include path so it will build.
 633     CEFLAGS="$CEFLAGS -I/usr/kerberos/include"
 634     ### OpenBSD comes with ssl headers
 635   else
 636     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 637   fi
 638   LDEFLAGS="$LDEFLAGS -L$with_ssl/lib"
 639   LIBS="$LIBS -lssl -lcrypto"
 640   dnl check if -ldl is needed
 641   AC_MSG_CHECKING([for additional library dependencies of SSL])
 642   found=0
 643   save_LIBS="$LIBS"
 644   for i in "" "-ldl" ; do
 645       LIBS="$LDEFLAGS $save_LIBS $i"
 646       AC_LINK_IFELSE([AC_LANG_PROGRAM(,[SSL_library_init()])],[found=1; break])
 647   done
 648   if test $found = 0 ; then
 649       AC_MSG_RESULT([error])
 650       AC_MSG_ERROR([cannot link with SSL - check config.log])
 651   fi
 652   LIBS="$save_LIBS $i"
 653   if test "$i" = "" ; then i="(none)" ; fi
 654   AC_MSG_RESULT($i)
 655   dnl XXX FIXME: use pkg-config if available!
 656   AC_DEFINE(SSL_ENABLE)
 657 else
 658   AC_MSG_NOTICE(Disabling SSL support.)
 659 fi
 660
 661 ###     use option --with-socks=DIR to point at SOCKS library
 662 AC_ARG_WITH(socks,
 663         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 664 [
 665 if test "$with_socks" != no
 666 then
 667     if test "$with_socks" != yes
 668     then
 669         LDEFLAGS="$LDEFLAGS -L$with_socks"
 670     else
 671         AC_CHECK_LIB(socks, Rconnect,,
 672                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 673     fi
 674     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 675     CEFLAGS="$CEFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 676     LIBS="-lsocks $LIBS"
 677 fi])
 678
 679 ###     use option --with-socks5=DIR to point at SOCKS library
 680 AC_ARG_WITH(socks5,
 681         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 682 [
 683 if test "$with_socks5" != no
 684 then
 685   if test "$with_socks5" != yes
 686   then
 687     LDEFLAGS="$LDEFLAGS -L$with_socks5"
 688   fi
 689   ac_savedLDFLAGS="$LDFLAGS"
 690   LDFLAGS="$LDEFLAGS $LDFLAGS"
 691   AC_CHECK_LIB(socks5, SOCKSconnect,,
 692         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 693   AC_DEFINE(HAVE_SOCKS)
 694   CEFLAGS="$CEFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 695   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 696   LDFLAGS="$ac_savedLDFLAGS"
 697 fi])
 698
 699 ACX_WHICH_GETHOSTBYNAME_R
 700
 701 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 702 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 703
 704 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 705 AC_ARG_WITH(gssapi,
 706         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 707 [
 708 if test "$with_gssapi" != "no"
 709 then
 710   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 711   then
 712     with_gssapi=$with_kerberos5
 713   fi
 714   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 715   then
 716     CFLAGS="$CFLAGS -I$with_gssapi/include"
 717     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 718   fi
 719
 720   AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 721   if test -n "$nogss"
 722   then
 723   if test -f "$with_gssapi/include/roken.h"
 724   then
 725      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl"
 726      AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 727                   AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 728      AC_DEFINE(HEIMDAL)
 729   else
 730      AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 731                   AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 732   fi
 733   fi
 734   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 735   save_CPPFLAGS=$CPPFLAGS
 736   CPPFLAGS="-I$with_gssapi/include"
 737   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 738   if test "$ac_cv_header_gssapi_h" = "yes"; then
 739     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 740   else
 741     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 742   fi
 743 fi])
 744
 745 AC_SUBST(CPFLAGS)
 746 AC_SUBST(CEFLAGS)
 747 AC_SUBST(LDEFLAGS)
 748
 749 dnl ,------------------------------------------------------------------
 750 dnl Check if we need TRIO
 751 needtrio=0
 752 if test "$FORCE_TRIO" = "yes" ; then
 753     needtrio=1
 754     ac_cv_func_vsnprintf=no
 755     ac_cv_func_snprintf=no
 756 fi
 757 if test "x$ac_cv_func_snprintf" != "xyes" ; then
 758     AC_DEFINE(snprintf, trio_snprintf,
 759               [Define to trio_snprintf if your system lacks snprintf])
 760     needtrio=1
 761 fi
 762 if test "x$ac_cv_func_vsnprintf" != "xyes" ; then
 763     AC_DEFINE(vsnprintf, trio_vsnprintf,
 764               [Define to trio_vsnprintf if your system lacks vsnprintf])
 765     needtrio=1
 766 fi
 767 AM_CONDITIONAL(NEED_TRIO, test "$needtrio" = 1)
 768
 769 dnl TRIO IEEE compiler option for Alpha
 770 dnl
 771 if test "$needtrio" = 1 ; then
 772     AC_MSG_CHECKING(for IEEE compilation options)
 773     AC_CACHE_VAL(ac_cv_ieee_option, [
 774     AC_TRY_COMPILE(,[
 775     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
 776     # error "Option needed"
 777     #endif
 778     ],ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
 779     AC_TRY_COMPILE(,[
 780     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
 781     # error "Option needed"
 782     #endif
 783     ],ac_cv_ieee_option="-ieee",
 784     AC_TRY_COMPILE(,[
 785     #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
 786     # error "Option needed"
 787     #endif
 788     ],ac_cv_ieee_option="-mieee",
 789     ac_cv_ieee_option="none"
 790     )
 791     )
 792     )
 793     ])
 794     AC_MSG_RESULT($ac_cv_ieee_option)
 795     if test $ac_cv_ieee_option != none; then
 796       CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
 797     fi
 798 fi
 799 dnl ----------------------------------------------------------------'
 800
 801 AC_CONFIG_FILES([Makefile m4/Makefile po/Makefile.in genlsm.sh])
 802 AC_OUTPUT
 803
 804 dnl Local Variables:
 805 dnl comment-start: "dnl "
 806 dnl comment-end: ""
 807 dnl comment-start-skip: "\\bdnl\\b\\s *"
 808 dnl compile-command: "make configure config.h.in"
 809 dnl End: