Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 dnl Eric S. Raymond <esr@thyrsus.com>
   3 dnl Matthias Andree <matthias.andree@gmx.de>
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6 dnl
   7
   8 AC_INIT([fetchmail],[6.3.4+svn],[fetchmail-users@lists.berlios.de])
   9 AC_CONFIG_SRCDIR([fetchmail.h])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_LIBOBJ_DIR([.])
  12
  13 AC_CANONICAL_TARGET
  14
  15 dnl automake options are in Makefile.am
  16 AC_PREREQ(2.59)
  17 AM_INIT_AUTOMAKE
  18
  19 dnl autobuild support, see <http://josefsson.org/autobuild/>
  20 (
  21   TZ=GMT
  22   export TZ
  23   AB_INIT
  24 )
  25
  26 dnl python is optional
  27 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  28 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  29
  30 AC_PROG_AWK
  31 AC_PROG_CC
  32 AC_PROG_INSTALL
  33 AC_PROG_CPP                     dnl Later checks need this.
  34 AC_PROG_RANLIB
  35 AM_PROG_CC_C_O
  36 AC_AIX
  37 AC_ISC_POSIX
  38 AC_MINIX
  39 AC_HEADER_STDC
  40 AC_HEADER_TIME
  41 AC_TYPE_SIZE_T
  42 AC_TYPE_PID_T
  43 AC_TYPE_SIGNAL
  44 AC_CHECK_TYPE(u_int32_t,unsigned int)
  45 AC_CHECK_HEADERS([unistd.h termios.h termio.h sgtty.h stdarg.h \
  46         sys/itimer.h fcntl.h sys/fcntl.h memory.h sys/wait.h \
  47         arpa/inet.h arpa/nameser.h netinet/in.h net/socket.h \
  48         sys/select.h sys/socket.h sys/time.h langinfo.h])
  49 AC_CHECK_HEADERS([resolv.h],,,[
  50 #include <sys/types.h>
  51 #ifdef HAVE_NETINET_IN_H
  52 #include <netinet/in.h>
  53 #endif
  54 #ifdef HAVE_ARPA_NAMESER_H
  55 #include <arpa/nameser.h>
  56 #endif
  57 ])
  58
  59 AC_C_CONST                      dnl getopt needs this.
  60
  61 AM_PROG_LEX
  62 AC_PROG_MAKE_SET
  63 AC_PROG_YACC
  64
  65 # Check for OS special cases
  66 case $target_os in
  67 darwin*)
  68     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
  69     CPFLAGS="-DBIND_8_COMPAT"
  70     ;;
  71 # Check for FreeBSD special case: more libs needed
  72 freebsd*)
  73     AC_MSG_NOTICE(found FreeBSD - Adding -lmd -lkvm -lcom_err to standard libraries)
  74     LIBS="$LIBS -lmd -lkvm -lcom_err"
  75     ;;
  76 # Check for LynxOS special case: -lbsd needed (at least on 2.3.0) and -s
  77 # not working.
  78 lynxos*)
  79     AC_MSG_NOTICE(found LynxOS - Adding -lbsd to standard libraries)
  80     LIBS="$LIBS -lbsd"
  81     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
  82     AC_MSG_NOTICE(found LynxOS - Prepending standard include path to gcc flags)
  83     CPFLAGS="-I/usr/include"
  84     ;;
  85 # Check for Rhapsody special case: it doesn't like -s
  86 rhapsody*)
  87     AC_MSG_NOTICE(found Rhapsody - Removing -s load flag)
  88     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
  89     ;;
  90 esac
  91
  92 dnl i18n
  93 AM_GNU_GETTEXT([external], [need-ngettext])
  94 AM_GNU_GETTEXT_VERSION(0.14.3)
  95 dnl end i18n
  96
  97 # Under sysV68, socket and friends are provided by the C library.
  98 # -linet does not provide socket, but causes multiple definition
  99 # errors at link-time.  It is thus better to only use the C library.
 100 # So don't add -linet to the link list unless it's necessary
 101 AC_CHECK_FUNC(socket,
 102     AC_MSG_RESULT(using libc's socket),
 103     AC_CHECK_LIB(socket,socket)
 104     AC_CHECK_LIB(inet,socket))
 105
 106 # The condition in this test copes with the presence of inet_addr in libc6.
 107 AC_CHECK_FUNC(inet_addr,
 108     AC_MSG_RESULT(using libc's inet_addr),
 109     AC_CHECK_LIB(nsl,inet_addr))
 110
 111 dnl Port hack for Interactive UNIX System V/386 Release 3.2
 112 AC_CHECK_LIB(cposix, strchr,
 113                 [DEFS="$DEFS -D_SYSV3"
 114                 LIBS="$LIBS -lcposix"])
 115
 116 dnl Port hack for Sparc/NetBSD-1.5
 117 dnl
 118 dnl NB: this has been disabled as it causes the unconditional
 119 dnl addition of libintl to the build, which is both undesired
 120 dnl and breaks on Solaris/Blastwave.org machines.
 121 dnl
 122 dnl AC_CHECK_LIB(intl, gettext,
 123 dnl             [LIBS="$LIBS -lintl"])
 124
 125 AC_REPLACE_FUNCS([strstr strcasecmp memmove stpcpy strlcpy strlcat])
 126
 127 AC_CHECK_FUNC(MD5Init, [],
 128               [AC_LIBSOURCE(md5c.c)
 129                EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"])
 130
 131 AC_CHECK_FUNC(getopt_long, [],
 132               [AC_LIBSOURCES([getopt.c, getopt1.c])
 133                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 134
 135 AC_FUNC_VPRINTF
 136
 137 AC_SUBST(EXTRAOBJ)
 138
 139 AC_CHECK_FUNCS(tcsetattr stty setsid geteuid seteuid dnl
 140   strerror syslog snprintf vprintf vsnprintf vsyslog dnl
 141   atexit inet_aton strftime setrlimit socketpair sigprocmask dnl
 142   sigaction strdup setlocale)
 143
 144 AC_CHECK_DECLS(strerror)
 145
 146 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 147 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 148 # library.  So don't add -lresolv to the link list unless it's necessary
 149 # (It will be necessary when using GNU libc6).
 150 old_LIBS="$LIBS"
 151 for lib in '' -lresolv; do
 152     if test -z "$lib"; then
 153        AC_MSG_CHECKING([for res_search in libc])
 154     else
 155        AC_MSG_CHECKING([for res_search in $lib])
 156     fi
 157     LIBS="$old_LIBS $lib"
 158     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 159 #include <sys/types.h>
 160 #ifdef HAVE_NETINET_IN_H
 161 #include <netinet/in.h>
 162 #endif
 163 #ifdef HAVE_ARPA_NAMESER_H
 164 #include <arpa/nameser.h>
 165 #endif
 166 #ifdef HAVE_RESOLV_H
 167 #include <resolv.h>
 168 #endif
 169 extern int res_search();
 170 ]], [[res_search(0, 0, 0, 0, 0);]])],
 171     [AC_MSG_RESULT([found])
 172      AC_DEFINE(HAVE_RES_SEARCH, [1],
 173                [Define to 1 if you have the 'res_search' function.])
 174      break], [AC_MSG_RESULT([not found])])
 175      LIBS=$old_LIBS
 176 done
 177
 178 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 179 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 180
 181 dnl Check for RSA refersence library in case we're using SSL
 182 AC_CHECK_LIB(rsaref, RSAPublicDecrypt)
 183
 184 dnl AC_FUNC_SETVBUF_REVERSED
 185
 186 dnl Check for usable void pointer type
 187 AC_MSG_CHECKING(use of void pointer type)
 188 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[char *p;
 189     void *xmalloc();
 190     p = (char *) xmalloc(1);
 191    ]])],[AC_DEFINE(HAVE_VOIDPOINTER,1,[Define if your C compiler allows void * as a function result]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 192
 193 dnl Check for ANSI volatile
 194 AC_C_VOLATILE
 195
 196 dnl Check out the wait reality.  We have to assume sys/wait.h is present.
 197 AC_CHECK_FUNCS(waitpid wait3)
 198 AC_MSG_CHECKING(for union wait);
 199 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 200 #include <sys/wait.h>]], [[union wait status; int pid; pid = wait (&status);
 201 #ifdef WEXITSTATUS
 202 /* Some POSIXoid systems have both the new-style macros and the old
 203    union wait type, and they do not work together.  If union wait
 204    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 205 if (WEXITSTATUS (status) != 0) pid = -1;
 206 #endif
 207 #ifdef HAVE_WAITPID
 208 /* Make sure union wait works with waitpid.  */
 209 pid = waitpid (-1, &status, 0);
 210 #endif
 211 ]])],[AC_DEFINE(HAVE_UNION_WAIT,1,Define if 'union wait' is the type of the first arg to wait functions.) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 212
 213 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 214 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 215 /* NetBSD declares sys_siglist in <unistd.h>.  */
 216 #ifdef HAVE_UNISTD_H
 217 #include <unistd.h>
 218 #endif]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 219
 220 # Find the right directory to put the root-mode PID file in
 221 for dir in "/var/run" "/etc"
 222 do
 223         if test -d $dir
 224         then
 225                 break;
 226         fi
 227 done
 228 AC_MSG_RESULT(root-mode pid file will go in $dir)
 229 AC_DEFINE_UNQUOTED(PID_DIR, "$dir", directory for PID lock files)
 230
 231 # We may have a fallback MDA available in case the socket open to the
 232 # local SMTP listener fails.  Best to use procmail for this, as we know
 233 # it won't try delivering through local SMTP and cause a mail loop.
 234 # Sendmail without the -t option to use the message headers will work too,
 235 # not just for sendmail itself but for workalikes like exim.
 236 #
 237 # Note1: A disadvantage of using procmail is that local alias expansion
 238 # according to /etc/aliases won't get done if we fall back.  This doesn't
 239 # matter in single-drop mode.
 240 #
 241 # Note2: it would be a very bad idea to use any MDA that doesn't return
 242 # a refuse-to-deliver status on disk- or process-table-full
 243 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 244 # like exim that might be lurking under a sendmail alias) do the right
 245 # thing in this circumstance.  Matthias Andree warns that procmail does
 246 # not.
 247 #
 248 # Note3: Defalt value of fallback is now off.  Matthias writes:
 249 #
 250 # 1. there is no way to predict when the fallback is used. With some MTAs
 251 #    (such as those limiting load average), outer circumstances can cause
 252 #    the fallback to kick in.
 253 #
 254 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 255 #    not only about alias expansion, .forwards to special filters won't
 256 #    work, mail may end up in a different place (users claim "mail loss"
 257 #    for that).
 258 #
 259 # 3. The claim procmail did the right thing with its exit codes is plain
 260 #    wrong. I've seen procmail exit with code 1 when it should have exited
 261 #    with code 75, like, configuration errors. Procmail is a dangerous
 262 #    beast and is best replaced by maildrop.
 263 #
 264 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 265 #    cannot tell which one it should choose. Say, your MTA is configured
 266 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 267 #    chooses procmail, this is plain wrong.
 268 #
 269
 270 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 271 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 272 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 273
 274 ###     use option --disable-fallback to disable fallback MDA
 275 ###     use option --enable-fallback=procmail or
 276 ###                --enable-fallback=sendmail to select
 277 AC_ARG_ENABLE(fallback,
 278         [  --enable-fallback=procmail    enable procmail as fallback
 279   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 280   --enable-fallback=maildrop    enable maildrop as fallback
 281   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 282
 283 case "$enable_fallback" in
 284         sendmail)       if test -z "$sendmail" ; then
 285                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 286                                 #not reached
 287                         fi
 288                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 289                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 290                         ;;
 291         procmail)       if test -z "$procmail" ; then
 292                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 293                                 #not reached
 294                         fi
 295                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 296                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 297                         ;;
 298         maildrop)       if test -z "$maildrop" ; then
 299                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 300                                 #not reached
 301                         fi
 302                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 303                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 304                         ;;
 305         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 306                         ;;
 307         auto|yes|set)   if test -n "$sendmail" ; then
 308                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 309                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 310                         else
 311                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 312                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 313                         fi
 314                         ;;
 315         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 316                         #notreached
 317                         ;;
 318 esac
 319
 320 AC_CHECK_SIZEOF(short)
 321 AC_CHECK_SIZEOF(int)
 322 AC_CHECK_SIZEOF(long)
 323
 324 ###     use option --enable-POP2 to compile in the POP2 support
 325 AC_ARG_ENABLE(POP2,
 326         [  --enable-POP2           compile in POP2 protocol support (obsolete)],
 327         [with_POP2=$enableval],
 328         [with_POP2=no])
 329 test "$with_POP2" = "yes" && AC_DEFINE(POP2_ENABLE,1,Define if you want POP2 support compiled in)
 330
 331 ###     use option --disable-POP3 to omit the POP3 support
 332 AC_ARG_ENABLE(POP3,
 333         [  --disable-POP3          don't compile in POP3 protocol support],
 334         [with_POP3=$enableval],
 335         [with_POP3=yes])
 336 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 337
 338 ###     use option --disable-IMAP to omit the IMAP support
 339 AC_ARG_ENABLE(IMAP,
 340         [  --disable-IMAP          don't compile in IMAP protocol support],
 341         [with_IMAP=$enableval],
 342         [with_IMAP=yes])
 343 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,"Define if you want IMAP support compiled in")
 344
 345 ###     use option --disable-ETRN to omit the ETRN support
 346 AC_ARG_ENABLE(ETRN,
 347         [  --disable-ETRN          don't compile in ETRN protocol support],
 348         [with_ETRN=$enableval],
 349         [with_ETRN=yes])
 350 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 351
 352 ###     use option --disable-ODMR to omit the ODMR support
 353 AC_ARG_ENABLE(ODMR,
 354         [  --disable-ODMR          don't compile in ODMR protocol support],
 355         [with_ODMR=$enableval],
 356         [with_ODMR=yes])
 357 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 358
 359 ###     use option --enable-RPA to compile in the RPA support
 360 AC_ARG_ENABLE(RPA,
 361         [  --enable-RPA            compile in RPA protocol support],
 362         [with_RPA=$enableval],
 363         [with_RPA=no])
 364 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 365
 366 ###     use option --enable-NTLM to compile in the NTLM support
 367 AC_ARG_ENABLE(NTLM,
 368         [  --enable-NTLM           compile in NTLM authentication support],
 369         [with_NTLM=$enableval],
 370         [with_NTLM=no])
 371 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 372
 373 ###     use option --enable-SDPS to compile in the SDPS support
 374 AC_ARG_ENABLE(SDPS,
 375         [  --enable-SDPS           compile in SDPS protocol support],
 376         [with_SDPS=$enableval],
 377         [with_SDPS=no])
 378 if test "$with_SDPS" = yes ; then
 379    if test "$with_POP3" != yes ; then
 380        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 381        with_SDPS=no
 382    else
 383        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 384    fi
 385 fi
 386
 387 ###     use option --enable-opie to compile in the OPIE support
 388 AC_ARG_ENABLE(opie,
 389         [  --enable-opie           support OTP through the OPIE library],
 390         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR(cannot find <opie.h>, which is required for OPIE support.)])
 391           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR(cannot find libopie, which is required for OPIE support.)])
 392           with_opie=$enableval],
 393         [with_opie=no])
 394 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 395
 396 AC_SEARCH_LIBS(getaddrinfo, inet6, [AC_DEFINE(HAVE_GETADDRINFO,1,[define to 1 if you have the getaddrinfo function])])
 397 AC_CHECK_FUNCS(getnameinfo)
 398
 399 # This version of the Kerberos 4 and 5 options addresses the follwing issues:
 400 #
 401 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 402 #   OpenSSL support (Debian's is)
 403 # * Build the kerberos.c stuff (KPOP) only for kerberosIV, to avoid breakage.
 404 #   I don't know if this is 100% correct, but now at least IMAP and POP3
 405 #   behave the same way regarding kerberosV.
 406 # * Build without any fuss for both kerberosIV and V at the same time.
 407 # * Move all the kerberos header mess to kerberos.h, and #include that
 408 #   in driver.c and kerberos.c.
 409 #
 410 # Tested using the Heimdal Kerberos V libs, Kungliga Tekniska Högskolan (the
 411 # Royal Institute of Technology in Stockholm, Sweden)'s kerberos IV libs, and
 412 # the MIT reference implementation of KerberosV (all as packaged in Debian).
 413
 414 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 415 ### make sure --with-ssl is run before --with-kerberos* !
 416 AC_ARG_WITH(kerberos5,
 417        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 418 [
 419 if test "$with_kerberos5" != "no"
 420 then
 421 # Check for a OpenBSD special case
 422 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 423 then
 424   AS_MESSAGE(checking kerberosV for OpenBSD...)
 425   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 426   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 427   CEFLAGS="$CEFLAGS -I/usr/include/kerberosV"
 428   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 429 elif krb5-config 2> /dev/null >/dev/null ; then
 430   krb5_prefix=`krb5-config --prefix krb5`
 431   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 432   if test -f ${krb5_prefix}/include/et/com_err.h && \
 433    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 434     CEFLAGS="$CEFLAGS -I${krb5_prefix}/include/et"
 435   fi
 436   unset krb5_prefix
 437   CEFLAGS="$CEFLAGS `krb5-config --cflags krb5`"
 438   LIBS="$LIBS `krb5-config --libs krb5`"
 439   AC_DEFINE(KERBEROS_V5)
 440 else
 441   if test "$with_kerberos5" != "yes"
 442   then
 443       LDEFLAGS="$LDEFLAGS -L${with_kerberos5}/lib"
 444       searchdirs="$with_kerberos5"
 445   else
 446       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 447   fi
 448   with_kerberos5=
 449   for dir in $searchdirs
 450   do AC_MSG_CHECKING([for Kerberos V in $dir])
 451      if test -f "$dir/include/krb5.h" || test -f "$dir/include/krb5/krb5.h"
 452      then
 453         if test -d "$dir/include/krb5" ; then CPFLAGS="$CPFLAGS -I$dir/include/krb5" ; fi
 454         ac_krblibs=
 455         if test -f "$dir/include/roken.h" || test -f "$dir/include/krb5/roken.h"
 456         then
 457            ac_krblibs="-lasn1 -lroken -lcom_err"
 458            AC_MSG_RESULT([Heimdal found])
 459           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 460           dnl we assume we do if it is available
 461            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 462                 ${LDEFLAGS})
 463            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 464               AC_CHECK_LIB(ssl, MD5_Init, [],
 465                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 466                 ${LDEFLAGS} ${ac_krblibs}),
 467            ${LDEFLAGS} ${ac_krblibs})
 468            AC_DEFINE(HEIMDAL)
 469         else
 470           AC_MSG_RESULT([found])
 471           ac_krblibs="-lcom_err"
 472            AC_CHECK_LIB(crypto,
 473              krb5_des_string_to_key,
 474              libk5crypto=-lcrypto,
 475                 AC_CHECK_LIB(k5crypto,
 476                    krb5_des_string_to_key,
 477                    libk5crypto=-lk5crypto,
 478                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 479                    ${LDEFLAGS} ${ac_krblibs}),
 480                  ${LDEFLAGS} ${ac_krblibs})
 481         fi
 482         AC_CHECK_LIB(krb5, krb5_init_context,[],
 483            continue,
 484            ${LDEFLAGS} ${ac_krblibs})
 485         AC_DEFINE(KERBEROS_V5)
 486         test "$dir" != "/usr" && CEFLAGS="$CEFLAGS -I$dir/include"
 487         LDEFLAGS="$LDEFLAGS -L$dir/lib"
 488        LIBS="$LIBS $ac_krblibs $libk5crypto"
 489         with_kerberos5=$dir
 490         break
 491      else
 492         AC_MSG_RESULT([not found])
 493      fi
 494   done
 495   if test -z "$with_kerberos5" ; then
 496      AC_MSG_ERROR([Kerberos 5 libraries not found])
 497   fi
 498 fi
 499 fi
 500 ]) dnl --with-kerberos5=DIR
 501
 502 ###    use option --with-kerberos=DIR to point at a Kerberos 4 directory
 503 AC_ARG_WITH(kerberos,
 504        [  --with-kerberos=DIR     point fetchmail compilation at a Kerberos 4 directory],
 505 [
 506 if test "$with_kerberos" != "no"
 507 then
 508     AC_MSG_WARN([Kerberos IV support is obsolete. Use --with-kerberos5 if possible.])
 509 # Check for a NetBSD/OpenBSD special case
 510 if test "$with_kerberos" = "yes" && ( test `uname` = "NetBSD" || test `uname` = "OpenBSD" )
 511 then
 512   AS_MESSAGE(checking kerberosIV for `uname`...)
 513   AC_DEFINE(KERBEROS_V4,1,Define if you have Kerberos V4)
 514   CEFLAGS="$CEFLAGS -I/usr/include/kerberosIV"
 515   case `uname` in
 516       NetBSD)  LIBS="$LIBS -lkrb -ldes -lroken -lcom_err" ;;
 517       OpenBSD) LIBS="$LIBS -lkrb -ldes" ;;
 518   esac
 519 elif krb4-config 2> /dev/null >/dev/null ; then
 520   krb4_prefix=`krb4-config --prefix`
 521   AC_MSG_RESULT([krb4-config points to kerberosIV under $krb4_prefix])
 522   unset krb4_prefix
 523   CEFLAGS="$CEFLAGS `krb4-config --cflags`"
 524   LIBS="$LIBS `krb4-config --libs`"
 525   AC_DEFINE(KERBEROS_V4)
 526 elif krb5-config 2> /dev/null >/dev/null ; then
 527   krb4_prefix=`krb5-config --prefix krb4`
 528   AC_MSG_RESULT([krb5-config points to kerberosIV under $krb4_prefix])
 529   if test -f ${krb4_prefix}/include/kerberosIV/krb.h ; then
 530     AC_DEFINE(KERBEROS_V4_V5,1,Define if you have Kerberos V4 headers under a kerberosIV directory)
 531   fi
 532   unset krb4_prefix
 533   CEFLAGS="$CEFLAGS `krb5-config --cflags krb4`"
 534   LIBS="$LIBS `krb5-config --libs krb4`"
 535   AC_DEFINE(KERBEROS_V4)
 536 else
 537   #we need to detect when we're building under a kerberosV compatibility
 538   #layer, btw...
 539   if test "$with_kerberos" != "yes" ; then
 540      searchdirs="$with_kerberos"
 541   else
 542      searchdirs="$with_kerberos5 /usr/kerberos /usr/kerberosIV /usr/athena /usr"
 543   fi
 544   with_kerberos=
 545   ac_saveLDFLAGS="$LDFLAGS"
 546   for dir in $searchdirs
 547   do
 548      AC_MSG_CHECKING([for Kerberos IV in $dir])
 549      if test -f "$dir/include/krb.h" || test -f "$dir/include/krb4.h" \
 550             || test -f "$dir/include/kerberosIV/krb.h"
 551      then
 552         AC_MSG_RESULT([found])
 553      else
 554         AC_MSG_RESULT([not found])
 555        continue
 556      fi
 557      #Find libs
 558      if test -f "$with_kerberos5/roken.h" ; then
 559        AC_CHECK_LIB(45, krb_mk_req)
 560      fi
 561      LDFLAGS="-L$dir/lib $ac_saveLDFLAGS"
 562      if test `uname` = "FreeBSD"; then
 563         AC_SEARCH_LIBS(_ossl_old_des_string_to_key, [des425 des crypto], [], continue)
 564      else
 565         AC_SEARCH_LIBS(des_string_to_key, [crypto], [], continue)
 566      fi
 567      AC_SEARCH_LIBS(krb_realmofhost, [krb4 krb], [], continue)
 568      with_kerberos="$dir"
 569      if test -f "$dir/include/kerberosIV/krb.h" ; then
 570         dir="$dir/include/kerberosIV"
 571      else
 572        dir="$dir/include"
 573      fi
 574      AC_DEFINE(KERBEROS_V4)
 575      test -f "$with_kerberos5/roken.h" && AC_DEFINE(HEIMDAL)
 576      test "$dir" != "/usr/include" && CEFLAGS="$CEFLAGS -I$dir"
 577      LDEFLAGS="$LDEFLAGS -L$with_kerberos/lib"
 578      break
 579   done
 580   if test -z "$with_kerberos" ; then
 581      AC_MSG_ERROR([Kerberos 4 libraries not found])
 582   fi
 583   LDFLAGS="$ac_saveLDFLAGS"
 584 fi
 585 fi
 586 ]) dnl --with-kerberos=DIR
 587
 588 ###     use option --with-ssl to compile in the SSL support
 589 AC_ARG_WITH(ssl,
 590         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 591         [with_ssl=$withval],
 592         [with_ssl=no])
 593 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 594
 595 if test "$with_ssl" = "yes"
 596 then
 597     #   User didn't specify an SSL location.  Let's look at some common
 598     #   directories where SSL has been found in the past and try and auto
 599     #   configure for SSL.  OpenSSL determination will be made later.
 600     #   This will screw up if an OpenSSL install is located in a later
 601     #   directory than an older SSLeay install, but the user should fix that
 602     #   anyways and he can override on the configure line.
 603     #   Just testing for directories is not sufficient, /usr exists on
 604     #   all systems!
 605     for ac_dir in \
 606       /usr/local/ssl \
 607       /usr/local \
 608       /usr/ssl \
 609       /usr \
 610       /local/ssl \
 611       /opt/ssl \
 612       /opt/csw \
 613       ; \
 614     do
 615         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 616             with_ssl=$ac_dir
 617             break;
 618         fi
 619     done
 620 fi
 621
 622 if test -n "$with_ssl" -a "$with_ssl" != "no"
 623 then
 624   # With the autoconfigure above, the only time this is going to be
 625   # true is going to be when we could not find the headers.  If they
 626   # are not in system standard locations, we are going to be broken.
 627   if test "$with_ssl" = "yes"
 628   then
 629     # Let's just define the standard location for the SSLeay root
 630     with_ssl="/usr/local/ssl"
 631   fi
 632   if test -r $with_ssl/include/openssl/ssl.h
 633   then
 634     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 635     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 636     test "$with_ssl" != "/usr" && CEFLAGS="$CEFLAGS -I$with_ssl/include"
 637     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 638     ### force the Kerberos direcory onto the include path so it will build.
 639     CEFLAGS="$CEFLAGS -I/usr/kerberos/include"
 640     ### OpenBSD comes with ssl headers
 641   else
 642     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 643   fi
 644   LDEFLAGS="$LDEFLAGS -L$with_ssl/lib"
 645   LIBS="$LIBS -lssl -lcrypto"
 646   dnl check if -ldl is needed
 647   AC_MSG_CHECKING([for additional library dependencies of SSL])
 648   found=0
 649   save_LIBS="$LIBS"
 650   for i in "" "-ldl" ; do
 651       LIBS="$LDEFLAGS $save_LIBS $i"
 652       AC_LINK_IFELSE([AC_LANG_PROGRAM(,[SSL_library_init()])],[found=1; break])
 653   done
 654   if test $found = 0 ; then
 655       AC_MSG_RESULT([error])
 656       AC_MSG_ERROR([cannot link with SSL - check config.log])
 657   fi
 658   LIBS="$save_LIBS $i"
 659   if test "$i" = "" ; then i="(none)" ; fi
 660   AC_MSG_RESULT($i)
 661   dnl XXX FIXME: use pkg-config if available!
 662   AC_DEFINE(SSL_ENABLE)
 663 else
 664   AC_MSG_NOTICE(Disabling SSL support.)
 665 fi
 666
 667 ###     use option --with-socks=DIR to point at SOCKS library
 668 AC_ARG_WITH(socks,
 669         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 670 [
 671 if test "$with_socks" != no
 672 then
 673     if test "$with_socks" != yes
 674     then
 675         LDEFLAGS="$LDEFLAGS -L$with_socks"
 676     else
 677         AC_CHECK_LIB(socks, Rconnect,,
 678                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 679     fi
 680     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 681     CEFLAGS="$CEFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 682     LIBS="-lsocks $LIBS"
 683 fi])
 684
 685 ###     use option --with-socks5=DIR to point at SOCKS library
 686 AC_ARG_WITH(socks5,
 687         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 688 [
 689 if test "$with_socks5" != no
 690 then
 691   if test "$with_socks5" != yes
 692   then
 693     LDEFLAGS="$LDEFLAGS -L$with_socks5"
 694   fi
 695   ac_savedLDFLAGS="$LDFLAGS"
 696   LDFLAGS="$LDEFLAGS $LDFLAGS"
 697   AC_CHECK_LIB(socks5, SOCKSconnect,,
 698         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 699   AC_DEFINE(HAVE_SOCKS)
 700   CEFLAGS="$CEFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 701   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 702   LDFLAGS="$ac_savedLDFLAGS"
 703 fi])
 704
 705 ACX_WHICH_GETHOSTBYNAME_R
 706
 707 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 708 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 709
 710 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 711 AC_ARG_WITH(gssapi,
 712         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 713 [
 714 if test "$with_gssapi" != "no"
 715 then
 716   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 717   then
 718     with_gssapi=$with_kerberos5
 719   fi
 720
 721   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 722   then
 723     CFLAGS="$CFLAGS -I$with_gssapi/include"
 724     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 725   fi
 726
 727   dnl obtain gssapi default libs
 728   if krb5-config --libs gssapi 2>/dev/null >/dev/null ; then
 729       LIBS="$LIBS `krb5-config --libs gssapi`"
 730   else
 731     AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 732     if test -n "$nogss"
 733     then
 734       # -lgss not found
 735       if test "$with_gssapi" = yes ; then
 736           with_gssapi=/usr
 737       fi
 738       if test -f "$with_gssapi/include/roken.h" -o -f "$with_gssapi/include/krb5/roken.h"
 739       then
 740          # have roken.h, assume Heimdal
 741          case `uname` in
 742              NetBSD) LIBS="$LIBS -lkrb5" ;;
 743              *)      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl" ;;
 744          esac
 745          AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 746                       AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 747          AC_DEFINE(HEIMDAL)
 748       else
 749          # no roken.h, assume MIT
 750          AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 751                       AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 752       fi
 753     fi
 754   fi
 755   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 756   if test "$with_gssapi" != yes ; then
 757     CPPFLAGS="-I$with_gssapi/include"
 758   fi
 759   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 760   if test "$ac_cv_header_gssapi_h" = "yes"; then
 761     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 762   else
 763     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 764   fi
 765 fi])
 766
 767 AC_SUBST(CPFLAGS)
 768 AC_SUBST(CEFLAGS)
 769 AC_SUBST(LDEFLAGS)
 770
 771 dnl ,------------------------------------------------------------------
 772 dnl Check if we need TRIO
 773 needtrio=0
 774 if test "$FORCE_TRIO" = "yes" ; then
 775     needtrio=1
 776     ac_cv_func_vsnprintf=no
 777     ac_cv_func_snprintf=no
 778 fi
 779 if test "x$ac_cv_func_snprintf" != "xyes" ; then
 780     AC_DEFINE(snprintf, trio_snprintf,
 781               [Define to trio_snprintf if your system lacks snprintf])
 782     needtrio=1
 783 fi
 784 if test "x$ac_cv_func_vsnprintf" != "xyes" ; then
 785     AC_DEFINE(vsnprintf, trio_vsnprintf,
 786               [Define to trio_vsnprintf if your system lacks vsnprintf])
 787     needtrio=1
 788 fi
 789 AM_CONDITIONAL(NEED_TRIO, test "$needtrio" = 1)
 790
 791 dnl TRIO IEEE compiler option for Alpha
 792 dnl
 793 if test "$needtrio" = 1 ; then
 794     AC_MSG_CHECKING(for IEEE compilation options)
 795     AC_CACHE_VAL(ac_cv_ieee_option, [
 796     AC_TRY_COMPILE(,[
 797     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
 798     # error "Option needed"
 799     #endif
 800     ],ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
 801     AC_TRY_COMPILE(,[
 802     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
 803     # error "Option needed"
 804     #endif
 805     ],ac_cv_ieee_option="-ieee",
 806     AC_TRY_COMPILE(,[
 807     #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
 808     # error "Option needed"
 809     #endif
 810     ],ac_cv_ieee_option="-mieee",
 811     ac_cv_ieee_option="none"
 812     )
 813     )
 814     )
 815     ])
 816     AC_MSG_RESULT($ac_cv_ieee_option)
 817     if test $ac_cv_ieee_option != none; then
 818       CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
 819     fi
 820 fi
 821 dnl ----------------------------------------------------------------'
 822
 823 AC_CONFIG_FILES([Makefile m4/Makefile po/Makefile.in genlsm.sh])
 824 AC_OUTPUT
 825
 826 dnl Local Variables:
 827 dnl comment-start: "dnl "
 828 dnl comment-end: ""
 829 dnl comment-start-skip: "\\bdnl\\b\\s *"
 830 dnl compile-command: "make configure config.h.in"
 831 dnl End: