Pileus Git - ~andy/fetchmail/blob - configure.ac

   1 dnl Autoconfigure input file for fetchmail
   2 #
   3 # Fetchmail automatic configuration support
   4 #
   5 # Eric S. Raymond <esr@thyrsus.com>
   6 # 2004 - 2009 Matthias Andree <matthias.andree@gmx.de>
   7 #
   8 dnl Process this file with autoconf to produce a configure script.
   9 dnl
  10
  11 AC_INIT([fetchmail],[6.3.10-beta1],[fetchmail-users@lists.berlios.de])
  12 AC_CONFIG_SRCDIR([fetchmail.h])
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_LIBOBJ_DIR([.])
  15
  16 AC_CANONICAL_HOST
  17
  18 dnl automake options are in Makefile.am
  19 AC_PREREQ(2.60)
  20 dnl 2.60 required for AC_USE_SYSTEM_EXTENSIONS
  21 AM_INIT_AUTOMAKE
  22
  23 dnl python is optional
  24 #
  25 # you can pass PYTHON=: in environment or on the command line
  26 # to disable python detection and continue without building/installing
  27 # fetchmail.conf -- be sure to check README.packaging, too!
  28 #
  29 AM_PATH_PYTHON(2.0,,AC_MSG_WARN([Disabling fetchmailconf: python 2.0 or greater not found]))
  30 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  31
  32 AC_PROG_AWK
  33 AC_PROG_CC
  34 AC_PROG_INSTALL
  35 AC_PROG_CPP                     dnl Later checks need this.
  36 AC_PROG_RANLIB
  37 AM_PROG_CC_C_O
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 AC_ISC_POSIX
  41 dnl AC_ISC_POSIX: - XXX FIXME: remove in fetchmail 6.4.
  42 dnl This macro adds `-lcposix' to output variable `LIBS' if necessary
  43 dnl for Posix facilities.  Sun dropped support for the obsolete
  44 dnl INTERACTIVE Systems Corporation Unix on 2006-07-23.  New programs
  45 dnl need not use this macro.  It is implemented as
  46 dnl `AC_SEARCH_LIBS([strerror], [cposix])'
  47
  48 AC_HEADER_STDC
  49 AC_HEADER_TIME
  50 AC_TYPE_SIZE_T
  51 AC_TYPE_PID_T
  52 AC_TYPE_SIGNAL
  53 AC_CHECK_HEADERS([unistd.h termios.h termio.h sgtty.h stdarg.h \
  54         sys/itimer.h fcntl.h sys/fcntl.h memory.h sys/wait.h \
  55         arpa/inet.h arpa/nameser.h netinet/in.h net/socket.h netdb.h \
  56         sys/select.h sys/socket.h sys/time.h langinfo.h])
  57 if test _$ac_cv_header_stdarg_h != _yes ; then
  58 AC_MSG_WARN([stdarg.h is not defined. Unsupported configuration, proceed at your own risk.])
  59 fi
  60 AC_CHECK_TYPE(u_int32_t,,
  61         AC_DEFINE(u_int32_t,unsigned int,
  62                 [Define to unsigned int if <sys/types.h> does not define.]),
  63         [AC_INCLUDES_DEFAULT
  64 #ifdef HAVE_ARPA_NAMESER_H
  65 #include <arpa/nameser.h>
  66 #endif])
  67 AC_CHECK_HEADERS([resolv.h],,,[
  68 #include <sys/types.h>
  69 #ifdef HAVE_NETINET_IN_H
  70 #include <netinet/in.h>
  71 #endif
  72 #ifdef HAVE_ARPA_NAMESER_H
  73 #include <arpa/nameser.h>
  74 #endif
  75 ])
  76
  77 AC_C_CONST                      dnl getopt needs this.
  78
  79 AM_PROG_LEX
  80 AC_PROG_MAKE_SET
  81 AC_PROG_YACC
  82
  83 # Check for OS special cases
  84 case $host_os in
  85 darwin*)
  86     AC_MSG_NOTICE(found Darwin - Adding -DBIND_8_COMPAT to CFLAGS)
  87     CPPFLAGS="$CPPFLAGS -DBIND_8_COMPAT"
  88     ;;
  89 # Check for FreeBSD special case: more libs needed
  90 freebsd*)
  91     AC_MSG_NOTICE(found FreeBSD - Adding -lmd -lkvm -lcom_err to standard libraries)
  92     LIBS="$LIBS -lmd -lkvm -lcom_err"
  93     ;;
  94 # Check for LynxOS special case: -lbsd needed (at least on 2.3.0) and -s
  95 # not working.
  96 lynxos*)
  97     AC_MSG_NOTICE(found LynxOS - Adding -lbsd to standard libraries)
  98     LIBS="$LIBS -lbsd"
  99     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 100     AC_MSG_NOTICE(found LynxOS - Prepending standard include path to gcc flags)
 101     CPPFLAGS="$CPPFLAGS -I/usr/include"
 102     ;;
 103 # Check for Rhapsody special case: it doesn't like -s
 104 rhapsody*)
 105     AC_MSG_NOTICE(found Rhapsody - Removing -s load flag)
 106     LDFLAGS=`echo $LDFLAGS | sed "s/-s //"`
 107     ;;
 108 esac
 109
 110 AC_CACHE_SAVE
 111
 112 dnl i18n
 113 AM_GNU_GETTEXT([external], [need-ngettext])
 114 AM_GNU_GETTEXT_VERSION([0.14.6])
 115 dnl end i18n
 116
 117 # Under sysV68, socket and friends are provided by the C library.
 118 # -linet does not provide socket, but causes multiple definition
 119 # errors at link-time.  It is thus better to only use the C library.
 120 # So don't add -linet to the link list unless it's necessary
 121 AC_CHECK_FUNC(socket,
 122     AC_MSG_RESULT(using libc's socket),
 123     AC_CHECK_LIB(socket,socket)
 124     AC_CHECK_LIB(inet,socket))
 125
 126 # The condition in this test copes with the presence of inet_addr in libc6.
 127 AC_CHECK_FUNC(inet_addr,
 128     AC_MSG_RESULT(using libc's inet_addr),
 129     AC_CHECK_LIB(nsl,inet_addr))
 130
 131 dnl Port hack for Interactive UNIX System V/386 Release 3.2
 132 AC_CHECK_LIB(cposix, strchr,
 133                 [DEFS="$DEFS -D_SYSV3"
 134                 LIBS="$LIBS -lcposix"])
 135
 136 dnl Port hack for Sparc/NetBSD-1.5
 137 dnl
 138 dnl NB: this has been disabled as it causes the unconditional
 139 dnl addition of libintl to the build, which is both undesired
 140 dnl and breaks on Solaris/Blastwave.org machines.
 141 dnl
 142 dnl AC_CHECK_LIB(intl, gettext,
 143 dnl             [LIBS="$LIBS -lintl"])
 144
 145 AC_REPLACE_FUNCS([strstr strcasecmp memmove stpcpy strlcpy strlcat])
 146
 147 AC_CHECK_FUNC(MD5Init, [],
 148               [AC_LIBSOURCE(md5c.c)
 149                EXTRAOBJ="$EXTRAOBJ md5c.\$(OBJEXT)"])
 150
 151 AC_CHECK_FUNC(getopt_long, [],
 152               [AC_LIBSOURCES([getopt.c, getopt1.c])
 153                EXTRAOBJ="$EXTRAOBJ getopt.\$(OBJEXT) getopt1.\$(OBJEXT)"])
 154
 155 AC_FUNC_VPRINTF
 156
 157 AC_SUBST(EXTRAOBJ)
 158
 159 AC_CHECK_FUNCS(tcsetattr stty setsid geteuid seteuid dnl
 160   strerror syslog snprintf vprintf vsnprintf vsyslog dnl
 161   atexit inet_aton strftime setrlimit socketpair dnl
 162   sigaction strdup setlocale)
 163
 164 AC_CHECK_DECLS(strerror)
 165 dnl INET6 is used by KAME/getnameinfo
 166 AC_CACHE_CHECK(for AF_INET6/PF_INET6,ac_cv_inet6,
 167 AC_COMPILE_IFELSE([
 168   AC_LANG_PROGRAM([[
 169     #ifdef HAVE_SYS_TYPES_H
 170     #include <sys/types.h>
 171     #endif
 172     #ifdef HAVE_SYS_SOCKET_H
 173     #include <sys/socket.h>
 174     #endif
 175   ]],[[
 176     int foo = AF_INET6;
 177     int bar = PF_INET6;
 178   ]])],
 179   ac_cv_inet6=yes , ac_cv_inet6=no
 180 ))
 181 if test "x$ac_cv_inet6" = xyes
 182 then
 183     AC_DEFINE(INET6,1,Define to 1 if your system defines AF_INET6 and PF_INET6.)
 184 fi
 185
 186 # Under Red Hat 4.0 (and many other Linuxes) -lresolv is seriously flaky
 187 # and breaks gethostbyname(2).  It's better to use the bind stuff in the C
 188 # library.  So don't add -lresolv to the link list unless it's necessary
 189 # (It will be necessary when using GNU libc6).
 190 old_LIBS="$LIBS"
 191 for lib in '' -lresolv; do
 192     if test -z "$lib"; then
 193        AC_MSG_CHECKING([for res_search in libc])
 194     else
 195        AC_MSG_CHECKING([for res_search in $lib])
 196     fi
 197     LIBS="$old_LIBS $lib"
 198     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 199 #include <sys/types.h>
 200 #ifdef HAVE_NETINET_IN_H
 201 #include <netinet/in.h>
 202 #endif
 203 #ifdef HAVE_ARPA_NAMESER_H
 204 #include <arpa/nameser.h>
 205 #endif
 206 #ifdef HAVE_RESOLV_H
 207 #include <resolv.h>
 208 #endif
 209 extern int res_search();
 210 ]], [[res_search(0, 0, 0, 0, 0); dn_skipname(0,0);]])],
 211     [AC_MSG_RESULT([found])
 212      AC_DEFINE(HAVE_RES_SEARCH, [1],
 213                [Define to 1 if you have the 'res_search' and 'dn_skipname' functions.])
 214      break], [AC_MSG_RESULT([not found])])
 215      LIBS=$old_LIBS
 216 done
 217
 218 dnl Check for libcrypt -- it may live in libc or libcrypt, as on IRIX
 219 AC_CHECK_FUNC(crypt, , AC_CHECK_LIB(crypt,crypt))
 220
 221 dnl Check for RSA refersence library in case we're using SSL
 222 AC_CHECK_LIB(rsaref, RSAPublicDecrypt)
 223
 224 dnl AC_FUNC_SETVBUF_REVERSED
 225
 226 dnl Check for usable void pointer type
 227 AC_MSG_CHECKING(use of void pointer type)
 228 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[char *p;
 229     void *xmalloc();
 230     p = (char *) xmalloc(1);
 231    ]])],[AC_DEFINE(HAVE_VOIDPOINTER,1,[Define if your C compiler allows void * as a function result]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 232
 233 dnl Check for ANSI volatile
 234 AC_C_VOLATILE
 235
 236 dnl Check out the wait reality.  We have to assume sys/wait.h is present.
 237 AC_CHECK_FUNCS(waitpid wait3)
 238 AC_MSG_CHECKING(for union wait);
 239 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 240 #include <sys/wait.h>]], [[union wait status; int pid; pid = wait (&status);
 241 #ifdef WEXITSTATUS
 242 /* Some POSIXoid systems have both the new-style macros and the old
 243    union wait type, and they do not work together.  If union wait
 244    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 245 if (WEXITSTATUS (status) != 0) pid = -1;
 246 #endif
 247 #ifdef HAVE_WAITPID
 248 /* Make sure union wait works with waitpid.  */
 249 pid = waitpid (-1, &status, 0);
 250 #endif
 251 ]])],[AC_DEFINE(HAVE_UNION_WAIT,1,Define if 'union wait' is the type of the first arg to wait functions.) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 252
 253 AC_MSG_CHECKING(sys_siglist declaration in signal.h or unistd.h)
 254 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>
 255 /* NetBSD declares sys_siglist in <unistd.h>.  */
 256 #ifdef HAVE_UNISTD_H
 257 #include <unistd.h>
 258 #endif]], [[char *msg = *(sys_siglist + 1);]])],[AC_DEFINE(SYS_SIGLIST_DECLARED,1,[Define if 'sys_siglist' is declared by <signal.h>.]) AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 259
 260 # Find the right directory to put the root-mode PID file in
 261 for dir in "/var/run" "/etc"
 262 do
 263         if test -d $dir
 264         then
 265                 break;
 266         fi
 267 done
 268 AC_MSG_RESULT(root-mode pid file will go in $dir)
 269 AC_DEFINE_UNQUOTED(PID_DIR, "$dir", directory for PID lock files)
 270
 271 # We may have a fallback MDA available in case the socket open to the
 272 # local SMTP listener fails.  Best to use procmail for this, as we know
 273 # it won't try delivering through local SMTP and cause a mail loop.
 274 # Sendmail without the -t option to use the message headers will work too,
 275 # not just for sendmail itself but for workalikes like exim.
 276 #
 277 # Note1: A disadvantage of using procmail is that local alias expansion
 278 # according to /etc/aliases won't get done if we fall back.  This doesn't
 279 # matter in single-drop mode.
 280 #
 281 # Note2: it would be a very bad idea to use any MDA that doesn't return
 282 # a refuse-to-deliver status on disk- or process-table-full
 283 # conditions; mail could get lost that way.  Sendmail and all of the MDAs
 284 # like exim that might be lurking under a sendmail alias) do the right
 285 # thing in this circumstance.  Matthias Andree warns that procmail does
 286 # not.
 287 #
 288 # Note3: Defalt value of fallback is now off.  Matthias writes:
 289 #
 290 # 1. there is no way to predict when the fallback is used. With some MTAs
 291 #    (such as those limiting load average), outer circumstances can cause
 292 #    the fallback to kick in.
 293 #
 294 # 2. the fallback changes fetchmail behaviour in unpredictable ways. It's
 295 #    not only about alias expansion, .forwards to special filters won't
 296 #    work, mail may end up in a different place (users claim "mail loss"
 297 #    for that).
 298 #
 299 # 3. The claim procmail did the right thing with its exit codes is plain
 300 #    wrong. I've seen procmail exit with code 1 when it should have exited
 301 #    with code 75, like, configuration errors. Procmail is a dangerous
 302 #    beast and is best replaced by maildrop.
 303 #
 304 # 4. if multiple choices exist (like procmail and maildrop), fetchmail
 305 #    cannot tell which one it should choose. Say, your MTA is configured
 306 #    to use maildrop to deliver to user's mailboxes, if fetchmail then
 307 #    chooses procmail, this is plain wrong.
 308 #
 309
 310 AC_PATH_PROG(procmail, procmail, "", $PATH:/usr/sbin)
 311 AC_PATH_PROG(sendmail, sendmail, "", $PATH:/usr/sbin:/usr/lib)
 312 AC_PATH_PROG(maildrop, maildrop, "", $PATH:/usr/local/bin)
 313
 314 ###     use option --disable-fallback to disable fallback MDA
 315 ###     use option --enable-fallback=procmail or
 316 ###                --enable-fallback=sendmail to select
 317 AC_ARG_ENABLE(fallback,
 318         [  --enable-fallback=procmail    enable procmail as fallback
 319   --enable-fallback=sendmail    enable /usr/sbin/sendmail as fallback
 320   --enable-fallback=maildrop    enable maildrop as fallback
 321   --enable-fallback=no          disable fallback],,[enable_fallback=no])
 322
 323 case "$enable_fallback" in
 324         sendmail)       if test -z "$sendmail" ; then
 325                                 AC_MSG_ERROR([Sendmail selected as fallback, but not found])
 326                                 #not reached
 327                         fi
 328                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$sendmail -i %T", Fallback MTA to use if defined)
 329                         AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 330                         ;;
 331         procmail)       if test -z "$procmail" ; then
 332                                 AC_MSG_ERROR([procmail selected as fallback, but not found])
 333                                 #not reached
 334                         fi
 335                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$procmail -d %T")
 336                         AC_MSG_NOTICE(Will use $procmail as fallback MDA.)
 337                         ;;
 338         maildrop)       if test -z "$maildrop" ; then
 339                                 AC_MSG_ERROR([maildrop selected as fallback, but not found])
 340                                 #not reached
 341                         fi
 342                         AC_DEFINE_UNQUOTED(FALLBACK_MDA, "$maildrop -d %T")
 343                         AC_MSG_NOTICE(Will use $maildrop as fallback MDA.)
 344                         ;;
 345         no|unset)       AC_MSG_NOTICE(Will not use a fallback MDA.)
 346                         ;;
 347         auto|yes|set)   if test -n "$sendmail" ; then
 348                                 AC_DEFINE_UNQUOTED(FALLBACK_MDA,"$sendmail -i %T")
 349                                 AC_MSG_NOTICE(Will use $sendmail as fallback MDA.)
 350                         else
 351                                 AC_MSG_WARN(No fallback MDA available.  procmail and maildrop are not eligible)
 352                                 AC_MSG_WARN(for automatic fallback MDA configuration for reliability reasons.)
 353                         fi
 354                         ;;
 355         *)              AC_MSG_ERROR([unkown value for --enable-fallback given: $enable_fallback])
 356                         #notreached
 357                         ;;
 358 esac
 359
 360 AC_CHECK_SIZEOF(short)
 361 AC_CHECK_SIZEOF(int)
 362 AC_CHECK_SIZEOF(long)
 363
 364 ###     use option --enable-POP2 to compile in the POP2 support
 365 AC_ARG_ENABLE(POP2,
 366         [  --enable-POP2           compile in POP2 protocol support (obsolete)],
 367         [with_POP2=$enableval],
 368         [with_POP2=no])
 369 test "$with_POP2" = "yes" && AC_DEFINE(POP2_ENABLE,1,Define if you want POP2 support compiled in)
 370 AM_CONDITIONAL(POP2_ENABLE, test "$with_POP2" = yes)
 371
 372 ###     use option --disable-POP3 to omit the POP3 support
 373 AC_ARG_ENABLE(POP3,
 374         [  --disable-POP3          don't compile in POP3 protocol support],
 375         [with_POP3=$enableval],
 376         [with_POP3=yes])
 377 test "$with_POP3" = "yes" && AC_DEFINE(POP3_ENABLE,1,Define if you want POP3 support compiled in)
 378 AM_CONDITIONAL(POP3_ENABLE, test "$with_POP3" = yes)
 379
 380 ###     use option --disable-IMAP to omit the IMAP support
 381 AC_ARG_ENABLE(IMAP,
 382         [  --disable-IMAP          don't compile in IMAP protocol support],
 383         [with_IMAP=$enableval],
 384         [with_IMAP=yes])
 385 test "$with_IMAP" = "yes" && AC_DEFINE(IMAP_ENABLE,1,Define if you want IMAP support compiled in)
 386 AM_CONDITIONAL(IMAP_ENABLE, test "$with_IMAP" = yes)
 387
 388 ###     use option --disable-ETRN to omit the ETRN support
 389 AC_ARG_ENABLE(ETRN,
 390         [  --disable-ETRN          don't compile in ETRN protocol support],
 391         [with_ETRN=$enableval],
 392         [with_ETRN=yes])
 393 test "$with_ETRN" = "yes" && AC_DEFINE(ETRN_ENABLE,1,Define if you want ETRN support compiled in.)
 394 AM_CONDITIONAL(ETRN_ENABLE, test "$with_ETRN" = yes)
 395
 396 ###     use option --disable-ODMR to omit the ODMR support
 397 AC_ARG_ENABLE(ODMR,
 398         [  --disable-ODMR          don't compile in ODMR protocol support],
 399         [with_ODMR=$enableval],
 400         [with_ODMR=yes])
 401 test "$with_ODMR" = "yes" && AC_DEFINE(ODMR_ENABLE,1,Define if you want ODMR support compiled in)
 402 AM_CONDITIONAL(ODMR_ENABLE, test "$with_ODMR" = yes)
 403
 404 ###     use option --enable-RPA to compile in the RPA support
 405 AC_ARG_ENABLE(RPA,
 406         [  --enable-RPA            compile in RPA protocol support],
 407         [with_RPA=$enableval],
 408         [with_RPA=no])
 409 test "$with_RPA" = "yes" && AC_DEFINE(RPA_ENABLE,1,Define if you want RPA support compiled in)
 410 AM_CONDITIONAL(RPA_ENABLE, test "$with_RPA" = yes)
 411
 412 ###     use option --enable-NTLM to compile in the NTLM support
 413 AC_ARG_ENABLE(NTLM,
 414         [  --enable-NTLM           compile in NTLM authentication support],
 415         [with_NTLM=$enableval],
 416         [with_NTLM=no])
 417 test "$with_NTLM" = "yes" && AC_DEFINE(NTLM_ENABLE,1,Define if you want NTLM authentication)
 418
 419 ###     use option --enable-SDPS to compile in the SDPS support
 420 AC_ARG_ENABLE(SDPS,
 421         [  --enable-SDPS           compile in SDPS protocol support],
 422         [with_SDPS=$enableval],
 423         [with_SDPS=no])
 424 if test "$with_SDPS" = yes ; then
 425    if test "$with_POP3" != yes ; then
 426        AC_MSG_WARN([SDPS cannot be enabled with POP3 disabled. Disabling SDPS.])
 427        with_SDPS=no
 428    else
 429        AC_DEFINE(SDPS_ENABLE,1,Define if you want SDPS support compiled in)
 430    fi
 431 fi
 432 if test "$with_POP3" != yes && test "$with_POP2" != yes \
 433     && test "$with_IMAP"  != yes ; then
 434     AC_MSG_ERROR([You must enable at least one of POP2, POP3 and IMAP.])
 435 fi
 436
 437 AC_CACHE_SAVE
 438
 439 ###     use option --enable-opie to compile in the OPIE support
 440 AC_ARG_ENABLE(opie,
 441         [  --enable-opie           support OTP through the OPIE library],
 442         [ AC_CHECK_HEADER(opie.h,, [AC_MSG_ERROR(cannot find <opie.h>, which is required for OPIE support.)])
 443           AC_CHECK_LIB(opie,opiegenerator,, [AC_MSG_ERROR(cannot find libopie, which is required for OPIE support.)])
 444           with_opie=$enableval],
 445         [with_opie=no])
 446 test "$with_opie" = "yes" && AC_DEFINE(OPIE_ENABLE,1,Define if you want OPIE support compiled in)
 447
 448 dnl Mostly stolen from gnulib's getaddrinfo.m4
 449 AC_SEARCH_LIBS(getaddrinfo, [nsl socket])
 450 AC_CACHE_CHECK([for getaddrinfo],[fm_cv_getaddrinfo],[
 451   AC_TRY_LINK([
 452 #include <sys/types.h>
 453 #ifdef HAVE_SYS_SOCKET_H
 454 #include <sys/socket.h>
 455 #endif
 456 #ifdef HAVE_NETDB_H
 457 #include <netdb.h>
 458 #endif
 459   ], [getaddrinfo(0, 0, 0, 0);],
 460     [ fm_cv_getaddrinfo=yes],
 461     [ fm_cv_getaddrinfo=no ])
 462 ])
 463
 464 if test x"$fm_cv_getaddrinfo" = "xyes"; then
 465      AC_DEFINE(HAVE_GETADDRINFO, 1,
 466       [Define to 1 if you have the getaddrinfo function.])
 467 fi
 468
 469 AC_CACHE_CHECK([for getnameinfo],[fm_cv_getnameinfo],[
 470   AC_TRY_LINK([
 471 #include <sys/types.h>
 472 #ifdef HAVE_SYS_SOCKET_H
 473 #include <sys/socket.h>
 474 #endif
 475 #ifdef HAVE_NETDB_H
 476 #include <netdb.h>
 477 #endif
 478 #ifndef NULL
 479 #define NULL ((void *)0)
 480 #endif
 481   ], [getnameinfo(NULL,0, NULL,0, NULL, 0, 0);],
 482     [ fm_cv_getnameinfo=yes],
 483     [ fm_cv_getnameinfo=no ])
 484 ])
 485 if test $fm_cv_getnameinfo = yes ; then
 486     AC_DEFINE(HAVE_GETNAMEINFO,1,[Define to 1 if your system has getnameinfo()])
 487 fi
 488
 489 AM_CONDITIONAL(NEED_GETADDRINFO, test "$fm_cv_getaddrinfo" != yes)
 490 AM_CONDITIONAL(NEED_GETNAMEINFO, test "$fm_cv_getnameinfo"   != yes)
 491
 492 AC_CHECK_FUNCS(inet_ntop)
 493 dnl Check if getaddrinfo is async-signal-safe - most implementations aren't
 494 if test "$fm_cv_getaddrinfo" = yes ; then
 495     AC_MSG_CHECKING(if your getaddrinfo is async-signal-safe)
 496     gai_ts=no
 497     dnl we have getaddrinfo() - check if the OS is known to have a async-signal-safe implementation
 498     case $host_os in
 499         darwin9*)                               gai_ts=yes ;;
 500         linux*)                                 gai_ts=yes ;;
 501         freebsd5.5|freebsd6*|freebsd7*)         gai_ts=yes ;;
 502         solaris2.8|solaris2.9|solaris2.10)      gai_ts=yes ;;
 503     esac
 504     AC_MSG_RESULT($gai_ts)
 505     if test $gai_ts = yes ; then
 506         AC_DEFINE(GETADDRINFO_ASYNCSAFE, 1, [define to 1 if you know your getaddrinfo function is async-signal-safe])
 507     fi
 508 fi
 509
 510 # This version of the Kerberos 4 and 5 options addresses the follwing issues:
 511 #
 512 # * Build correctly under Heimdal kerberos if it is compiled with db2 and
 513 #   OpenSSL support (Debian's is)
 514 # * Build the kerberos.c stuff (KPOP) only for kerberosIV, to avoid breakage.
 515 #   I don't know if this is 100% correct, but now at least IMAP and POP3
 516 #   behave the same way regarding kerberosV.
 517 # * Build without any fuss for both kerberosIV and V at the same time.
 518 # * Move all the kerberos header mess to kerberos.h, and #include that
 519 #   in driver.c and kerberos.c.
 520 #
 521 # Tested using the Heimdal Kerberos V libs, Kungliga Tekniska Högskolan (the
 522 # Royal Institute of Technology in Stockholm, Sweden)'s kerberos IV libs, and
 523 # the MIT reference implementation of KerberosV (all as packaged in Debian).
 524
 525 ###    use option --with-kerberos5=DIR to point at a Kerberos 5 directory
 526 ### make sure --with-ssl is run before --with-kerberos* !
 527 AC_ARG_WITH(kerberos5,
 528        [  --with-kerberos5=DIR    point fetchmail compilation at a Kerberos 5 directory],
 529 [
 530 if test "$with_kerberos5" != "no"
 531 then
 532 # Check for a OpenBSD special case
 533 if test "$with_kerberos5" = "yes" && ( test `uname` = "OpenBSD" )
 534 then
 535   AS_MESSAGE(checking kerberosV for OpenBSD...)
 536   AC_DEFINE(HEIMDAL,1,Define if you have HEIMDAL kerberos 5)
 537   AC_DEFINE(KERBEROS_V5,1,Define if you have Kerberos V5)
 538   CFLAGS="$CFLAGS -I/usr/include/kerberosV"
 539   LIBS="$LIBS -lasn1 -lkrb5 -lcom_err -lkafs"
 540 elif krb5-config 2> /dev/null >/dev/null ; then
 541   krb5_prefix=`krb5-config --prefix krb5`
 542   AC_MSG_RESULT([krb5-config points to kerberosV under $krb5_prefix])
 543   if test -f ${krb5_prefix}/include/et/com_err.h && \
 544    ! test -f ${krb5_prefix}/include/com_err.h  ; then
 545     CFLAGS="$CFLAGS -I${krb5_prefix}/include/et"
 546   fi
 547   unset krb5_prefix
 548   CFLAGS="$CFLAGS `krb5-config --cflags krb5`"
 549   LIBS="$LIBS `krb5-config --libs krb5`"
 550   AC_DEFINE(KERBEROS_V5)
 551 else
 552   if test "$with_kerberos5" != "yes"
 553   then
 554       LDFLAGS="$LDFLAGS -L${with_kerberos5}/lib"
 555       searchdirs="$with_kerberos5"
 556   else
 557       searchdirs="/usr/kerberos /usr/local/krb5 /usr/athena /usr"
 558   fi
 559   with_kerberos5=
 560   for dir in $searchdirs
 561   do AC_MSG_CHECKING([for Kerberos V in $dir])
 562      if test -f "$dir/include/krb5.h" || test -f "$dir/include/krb5/krb5.h"
 563      then
 564         if test -d "$dir/include/krb5" ; then CPPFLAGS="$CPPFLAGS -I$dir/include/krb5" ; fi
 565         ac_krblibs=
 566         if test -f "$dir/include/roken.h" || test -f "$dir/include/krb5/roken.h"
 567         then
 568            ac_krblibs="-lasn1 -lroken -lcom_err"
 569            AC_MSG_RESULT([Heimdal found])
 570           dnl Attempt to detect if we need to -ldb2 to link Heimdal
 571           dnl we assume we do if it is available
 572            AC_CHECK_LIB(db2, db_open, ac_krblibs="$ac_krblibs -ldb2", [],
 573                 ${LDFLAGS})
 574            AC_CHECK_LIB(des, des_string_to_key, libk5crypto=-ldes,
 575               AC_CHECK_LIB(ssl, MD5_Init, [],
 576                 AC_MSG_ERROR([DES libraries not found. Try adding --with-ssl to enable OpenSSL support]),
 577                 ${LDFLAGS} ${ac_krblibs}),
 578            ${LDFLAGS} ${ac_krblibs})
 579            AC_DEFINE(HEIMDAL)
 580         else
 581           AC_MSG_RESULT([found])
 582           ac_krblibs="-lcom_err"
 583            AC_CHECK_LIB(crypto,
 584              krb5_des_string_to_key,
 585              libk5crypto=-lcrypto,
 586                 AC_CHECK_LIB(k5crypto,
 587                    krb5_des_string_to_key,
 588                    libk5crypto=-lk5crypto,
 589                       AC_MSG_ERROR([Kerberos 5 DES libraries not found]),
 590                    ${LDFLAGS} ${ac_krblibs}),
 591                  ${LDFLAGS} ${ac_krblibs})
 592         fi
 593         AC_CHECK_LIB(krb5, krb5_init_context,[],
 594            continue,
 595            ${LDFLAGS} ${ac_krblibs})
 596         AC_DEFINE(KERBEROS_V5)
 597         test "$dir" != "/usr" && CFLAGS="$CFLAGS -I$dir/include"
 598         LDFLAGS="$LDFLAGS -L$dir/lib"
 599        LIBS="$LIBS $ac_krblibs $libk5crypto"
 600         with_kerberos5=$dir
 601         break
 602      else
 603         AC_MSG_RESULT([not found])
 604      fi
 605   done
 606   if test -z "$with_kerberos5" ; then
 607      AC_MSG_ERROR([Kerberos 5 libraries not found])
 608   fi
 609 fi
 610 fi
 611 ]) dnl --with-kerberos5=DIR
 612
 613 ###    use option --with-kerberos=DIR to point at a Kerberos 4 directory
 614 KERBEROS_V4=0
 615 AC_ARG_WITH(kerberos,
 616        [  --with-kerberos=DIR     point fetchmail compilation at a Kerberos 4 directory],
 617 [
 618 if test "$with_kerberos" != "no"
 619 then
 620     AC_MSG_WARN([Kerberos IV support is obsolete. Use --with-kerberos5 if possible.])
 621 # Check for a NetBSD/OpenBSD special case
 622 if test "$with_kerberos" = "yes" && ( test `uname` = "NetBSD" || test `uname` = "OpenBSD" )
 623 then
 624   AS_MESSAGE(checking kerberosIV for `uname`...)
 625   KERBEROS_V4=1
 626   CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 627   case `uname` in
 628       NetBSD)  LIBS="$LIBS -lkrb -ldes -lroken -lcom_err" ;;
 629       OpenBSD) LIBS="$LIBS -lkrb -ldes" ;;
 630   esac
 631 elif krb4-config 2> /dev/null >/dev/null ; then
 632   krb4_prefix=`krb4-config --prefix`
 633   AC_MSG_RESULT([krb4-config points to kerberosIV under $krb4_prefix])
 634   unset krb4_prefix
 635   CFLAGS="$CFLAGS `krb4-config --cflags`"
 636   LIBS="$LIBS `krb4-config --libs`"
 637   KERBEROS_V4=1
 638 elif krb5-config 2> /dev/null >/dev/null ; then
 639   krb4_prefix=`krb5-config --prefix krb4`
 640   AC_MSG_RESULT([krb5-config points to kerberosIV under $krb4_prefix])
 641   if test -f ${krb4_prefix}/include/kerberosIV/krb.h ; then
 642     AC_DEFINE(KERBEROS_V4_V5,1,Define if you have Kerberos V4 headers under a kerberosIV directory)
 643   fi
 644   unset krb4_prefix
 645   CFLAGS="$CFLAGS `krb5-config --cflags krb4`"
 646   LIBS="$LIBS `krb5-config --libs krb4`"
 647   KERBEROS_V4=1
 648 else
 649   #we need to detect when we're building under a kerberosV compatibility
 650   #layer, btw...
 651   if test "$with_kerberos" != "yes" ; then
 652      searchdirs="$with_kerberos"
 653   else
 654      searchdirs="$with_kerberos5 /usr/kerberos /usr/kerberosIV /usr/athena /usr"
 655   fi
 656   with_kerberos=
 657   ac_saveLDFLAGS="$LDFLAGS"
 658   for dir in $searchdirs
 659   do
 660      AC_MSG_CHECKING([for Kerberos IV in $dir])
 661      if test -f "$dir/include/krb.h" || test -f "$dir/include/krb4.h" \
 662             || test -f "$dir/include/kerberosIV/krb.h"
 663      then
 664         AC_MSG_RESULT([found])
 665      else
 666         AC_MSG_RESULT([not found])
 667        continue
 668      fi
 669      #Find libs
 670      if test -f "$with_kerberos5/roken.h" ; then
 671        AC_CHECK_LIB(45, krb_mk_req)
 672      fi
 673      LDFLAGS="-L$dir/lib $ac_saveLDFLAGS"
 674      if test `uname` = "FreeBSD"; then
 675         AC_SEARCH_LIBS(_ossl_old_des_string_to_key, [des425 des crypto], [], continue)
 676      else
 677         AC_SEARCH_LIBS(des_string_to_key, [crypto], [], continue)
 678      fi
 679      AC_SEARCH_LIBS(krb_realmofhost, [krb4 krb], [], continue)
 680      with_kerberos="$dir"
 681      if test -f "$dir/include/kerberosIV/krb.h" ; then
 682         dir="$dir/include/kerberosIV"
 683      else
 684        dir="$dir/include"
 685      fi
 686      KERBEROS_V4=1
 687      test -f "$with_kerberos5/roken.h" && AC_DEFINE(HEIMDAL)
 688      test "$dir" != "/usr/include" && CFLAGS="$CFLAGS -I$dir"
 689      LDFLAGS="$LDFLAGS -L$with_kerberos/lib"
 690      break
 691   done
 692   if test -z "$with_kerberos" ; then
 693      AC_MSG_ERROR([Kerberos 4 libraries not found])
 694   fi
 695   LDFLAGS="$ac_saveLDFLAGS"
 696 fi
 697 fi
 698 ]) dnl --with-kerberos=DIR
 699 if test "$KERBEROS_V4" = 1 ; then
 700     AC_DEFINE(KERBEROS_V4,1,Define if you have Kerberos V4)
 701 fi
 702 AM_CONDITIONAL(KERBEROS_V4_ENABLE, test "$KERBEROS_V4" = 1)
 703
 704 ###     use option --with-ssl to compile in the SSL support
 705 AC_ARG_WITH(ssl,
 706         [  --with-ssl=[DIR]        enable SSL support using libraries in DIR],
 707         [with_ssl=$withval],
 708         [with_ssl=no])
 709 test "$with_ssl" != "no" && AC_DEFINE(SSL_ENABLE,1,Define if you want SSL support compiled in)
 710
 711 if test "$with_ssl" = "yes"
 712 then
 713     #   User didn't specify an SSL location.  Let's look at some common
 714     #   directories where SSL has been found in the past and try and auto
 715     #   configure for SSL.  OpenSSL determination will be made later.
 716     #   This will screw up if an OpenSSL install is located in a later
 717     #   directory than an older SSLeay install, but the user should fix that
 718     #   anyways and he can override on the configure line.
 719     #   Just testing for directories is not sufficient, /usr exists on
 720     #   all systems!
 721     for ac_dir in \
 722       /usr/local/ssl \
 723       /usr/local \
 724       /usr/ssl \
 725       /usr \
 726       /local/ssl \
 727       /opt/ssl \
 728       /opt/csw \
 729       ; \
 730     do
 731         if test -r "$ac_dir/include/openssl/ssl.h" ; then
 732             with_ssl=$ac_dir
 733             break;
 734         fi
 735     done
 736 fi
 737
 738 if test -n "$with_ssl" -a "$with_ssl" != "no"
 739 then
 740   # With the autoconfigure above, the only time this is going to be
 741   # true is going to be when we could not find the headers.  If they
 742   # are not in system standard locations, we are going to be broken.
 743   if test "$with_ssl" = "yes"
 744   then
 745     # Let's just define the standard location for the SSLeay root
 746     with_ssl="/usr/local/ssl"
 747   fi
 748   if test -r $with_ssl/include/openssl/ssl.h
 749   then
 750     ### ssl.h found under openssl.  Use openssl configuration preferentially,
 751     AC_MSG_NOTICE(Enabling OpenSSL support in $with_ssl.)
 752     test "$with_ssl" != "/usr" && CFLAGS="$CFLAGS -I$with_ssl/include"
 753     ### In Red Hat 9, this file includes a reference to <krb5.h>, so we
 754     ### force the Kerberos direcory onto the include path so it will build.
 755     CFLAGS="$CFLAGS -I/usr/kerberos/include"
 756     ### OpenBSD comes with ssl headers
 757   else
 758     AC_MSG_ERROR([SSL support enabled, but OpenSSL not found])
 759   fi
 760   LDFLAGS="$LDFLAGS -L$with_ssl/lib"
 761   LIBS="$LIBS -lssl -lcrypto"
 762   dnl check if -ldl is needed
 763   AC_MSG_CHECKING([for additional library dependencies of SSL])
 764   found=0
 765   save_LIBS="$LIBS"
 766   for i in "" "-ldl" ; do
 767       LIBS="$LDFLAGS $save_LIBS $i"
 768       AC_LINK_IFELSE([AC_LANG_PROGRAM(,[SSL_library_init()])],[found=1; break])
 769   done
 770   if test $found = 0 ; then
 771       AC_MSG_RESULT([error])
 772       AC_MSG_ERROR([cannot link with SSL - check config.log])
 773   fi
 774   LIBS="$save_LIBS $i"
 775   if test "$i" = "" ; then i="(none)" ; fi
 776   AC_MSG_RESULT($i)
 777   dnl XXX FIXME: use pkg-config if available!
 778   AC_DEFINE(SSL_ENABLE)
 779 else
 780   AC_MSG_NOTICE(Disabling SSL support.)
 781 fi
 782
 783 ###     use option --with-socks=DIR to point at SOCKS library
 784 AC_ARG_WITH(socks,
 785         [  --with-socks[=DIR]      add built-in SOCKS firewall access],
 786 [
 787 if test "$with_socks" != no
 788 then
 789     if test "$with_socks" != yes
 790     then
 791         LDFLAGS="$LDFLAGS -L$with_socks"
 792     else
 793         AC_CHECK_LIB(socks, Rconnect,,
 794                AC_MSG_ERROR([could not find libsocks which is needed for built-in SOCKS support]))
 795     fi
 796     AC_DEFINE(HAVE_SOCKS,1,Define if you want built-in SOCKS support)
 797     CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 798     LIBS="-lsocks $LIBS"
 799 fi])
 800
 801 ###     use option --with-socks5=DIR to point at SOCKS library
 802 AC_ARG_WITH(socks5,
 803         [  --with-socks5[=DIR]     add built-in SOCKS5 firewall access],
 804 [
 805 if test "$with_socks5" != no
 806 then
 807   if test "$with_socks5" != yes
 808   then
 809     LDFLAGS="$LDFLAGS -L$with_socks5"
 810   fi
 811   ac_savedLDFLAGS="$LDFLAGS"
 812   LDFLAGS="$LDFLAGS $LDFLAGS"
 813   AC_CHECK_LIB(socks5, SOCKSconnect,,
 814         AC_MSG_ERROR([could not find libsocks5 which is needed for built-in SOCKS5 support]))
 815   AC_DEFINE(HAVE_SOCKS)
 816   CFLAGS="$CFLAGS -Dconnect=SOCKSconnect -Dgetsockname=SOCKSgetsockname -Dbind=SOCKSbind -Daccept=SOCKSaccept -Dlisten=SOCKSlisten -Dselect=SOCKSselect -Drecvfrom=SOCKSrecvfrom -Dsendto=SOCKSsendto -Drecv=SOCKSrecv -Dsend=SOCKSsend -Dread=SOCKSread -Dwrite=SOCKSwrite -Drresvport=SOCKSrresvport -Dshutdown=SOCKSshutdown -Dlisten=SOCKSlisten -Dclose=SOCKSclose -Ddup=SOCKSdup -Ddup2=SOCKSdup2 -Dgethostbyname=SOCKSgethostbyname"
 817   AC_CHECK_FUNC(SOCKSfclose, [CFLAGS="$CFLAGS -Dfclose=SOCKSfclose"])
 818   LDFLAGS="$ac_savedLDFLAGS"
 819 fi])
 820
 821 ACX_WHICH_GETHOSTBYNAME_R
 822
 823 ###     use option --with-hesiod=DIR to point at a HESIOD directory
 824 AC_ma_SEARCH_PACKAGE(hesiod, hesiod_getmailhost, /usr/athena /usr /usr/local,hesiod, hesiod.h)
 825
 826 ###     use option --with-gssapi=DIR to compile in GSSAPI support
 827 AC_ARG_WITH(gssapi,
 828         [  --with-gssapi[=DIR]     compile in GSSAPI support using libraries in DIR],
 829 [
 830 if test "$with_gssapi" != "no"
 831 then
 832   if test "$with_gssapi" = "yes" -a -n "$with_kerberos5"
 833   then
 834     with_gssapi=$with_kerberos5
 835   fi
 836
 837   if test "$with_gssapi" != "yes" -a -n "$with_gssapi"
 838   then
 839     CFLAGS="$CFLAGS -I$with_gssapi/include"
 840     LDFLAGS="$LDFLAGS -L$with_gssapi/lib"
 841   fi
 842
 843   dnl obtain gssapi default libs
 844   if krb5-config --libs gssapi 2>/dev/null >/dev/null ; then
 845       LIBS="$LIBS `krb5-config --libs gssapi`"
 846   else
 847     AC_CHECK_LIB(gss, gss_check_version, LIBS="$LIBS -lgss", nogss=t)
 848     if test -n "$nogss"
 849     then
 850       # -lgss not found
 851       if test "$with_gssapi" = yes ; then
 852           with_gssapi=/usr
 853       fi
 854       if test -f "$with_gssapi/include/roken.h" -o -f "$with_gssapi/include/krb5/roken.h"
 855       then
 856          # have roken.h, assume Heimdal
 857          case `uname` in
 858              NetBSD) LIBS="$LIBS -lkrb5" ;;
 859              *)      LIBS="$LIBS -lkrb5 -lasn1 -ldes -lroken -ldb -ldl" ;;
 860          esac
 861          AC_CHECK_LIB(gssapi, gss_init_sec_context,LIBS="$LIBS -lgssapi",
 862                       AC_MSG_ERROR([could not find libgssapi which is needed for GSSAPI support]), )
 863          AC_DEFINE(HEIMDAL)
 864       else
 865          # no roken.h, assume MIT
 866          AC_CHECK_LIB(gssapi_krb5, gss_init_sec_context,LIBS="$LIBS -lgssapi_krb5",
 867                       AC_MSG_ERROR([could not find libgssapi_krb5 which is needed for GSSAPI support]), -lkrb5)
 868       fi
 869     fi
 870   fi
 871   AC_DEFINE(GSSAPI,1,Define if you want GSSAPI authentication)
 872   if test "$with_gssapi" != yes ; then
 873     CPPFLAGS="$CPPFLAGS-I$with_gssapi/include"
 874   fi
 875   AC_CHECK_HEADERS(gss.h gssapi.h gssapi/gssapi.h gssapi/gssapi_generic.h)
 876   if test "$ac_cv_header_gssapi_h" = "yes"; then
 877     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE,1,Define if you have MIT kerberos))
 878   else
 879     AC_EGREP_HEADER(GSS_C_NT_HOSTBASED_SERVICE, gssapi/gssapi.h, AC_DEFINE(HAVE_GSS_C_NT_HOSTBASED_SERVICE))
 880   fi
 881 fi])
 882
 883 dnl ,------------------------------------------------------------------
 884 dnl Check if we need TRIO
 885 needtrio=0
 886 if test "$FORCE_TRIO" = "yes" ; then
 887     needtrio=1
 888     ac_cv_func_vsnprintf=no
 889     ac_cv_func_snprintf=no
 890 fi
 891 if test "x$ac_cv_func_snprintf" != "xyes" ; then
 892     AC_DEFINE(snprintf, trio_snprintf,
 893               [Define to trio_snprintf if your system lacks snprintf])
 894     needtrio=1
 895 fi
 896 if test "x$ac_cv_func_vsnprintf" != "xyes" ; then
 897     AC_DEFINE(vsnprintf, trio_vsnprintf,
 898               [Define to trio_vsnprintf if your system lacks vsnprintf])
 899     needtrio=1
 900 fi
 901 AM_CONDITIONAL(NEED_TRIO, test "$needtrio" = 1)
 902
 903 dnl TRIO IEEE compiler option for Alpha
 904 dnl
 905 if test "$needtrio" = 1 ; then
 906     AC_MSG_CHECKING(for IEEE compilation options)
 907     AC_CACHE_VAL(ac_cv_ieee_option, [
 908     AC_TRY_COMPILE(,[
 909     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && (defined(VMS) || defined(__VMS)))
 910     # error "Option needed"
 911     #endif
 912     ],ac_cv_ieee_option="/IEEE_MODE=UNDERFLOW_TO_ZERO/FLOAT=IEEE",
 913     AC_TRY_COMPILE(,[
 914     #if !(defined(__alpha) && (defined(__DECC) || defined(__DECCXX) || (defined(__osf__) && defined(__LANGUAGE_C__))) && !(defined(VMS) || defined(__VMS)) && !defined(_CFE))
 915     # error "Option needed"
 916     #endif
 917     ],ac_cv_ieee_option="-ieee",
 918     AC_TRY_COMPILE(,[
 919     #if !(defined(__alpha) && (defined(__GNUC__) && (defined(__osf__) || defined(__linux__))))
 920     # error "Option needed"
 921     #endif
 922     ],ac_cv_ieee_option="-mieee",
 923     ac_cv_ieee_option="none"
 924     )
 925     )
 926     )
 927     ])
 928     AC_MSG_RESULT($ac_cv_ieee_option)
 929     if test $ac_cv_ieee_option != none; then
 930       CFLAGS="${CFLAGS} ${ac_cv_ieee_option}"
 931     fi
 932 fi
 933 dnl ----------------------------------------------------------------'
 934
 935 AC_CONFIG_FILES([Makefile po/Makefile.in genlsm.sh])
 936 AC_OUTPUT
 937
 938 dnl Local Variables:
 939 dnl comment-start: "dnl "
 940 dnl comment-end: ""
 941 dnl comment-start-skip: "\\bdnl\\b\\s *"
 942 dnl compile-command: "make configure config.h.in"
 943 dnl End: